configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.2.0-alpha-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(buf-freelists,
  40    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  41 AC_ARG_ENABLE(openbsd-malloc,
  42    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  43 AC_ARG_ENABLE(instrument-downloads,
  44    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  45
  46 if test x$enable_buf_freelists != xno; then
  47   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  48             [Defined if we try to use freelists for buffer RAM chunks])
  49 fi
  50 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  51 if test x$enable_instrument_downloads = xyes; then
  52   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  53             [Defined if we want to keep track of how much of each kind of resource we download.])
  54 fi
  55
  56 AC_ARG_ENABLE(transparent,
  57      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  58      [case "${enableval}" in
  59         yes) transparent=true ;;
  60         no)  transparent=false ;;
  61         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  62       esac], [transparent=true])
  63
  64 AC_ARG_ENABLE(threads,
  65      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  66
  67 if test x$enable_threads = x; then
  68    case $host in
  69     *-*-solaris* )
  70      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  71      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  72 cpu workers lock up here, so I will disable threads.])
  73      enable_threads="no";;
  74     *)
  75      enable_threads="yes";;
  76    esac
  77 fi
  78
  79 if test "$enable_threads" = "yes"; then
  80   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  81 fi
  82
  83 case $host in
  84    *-*-solaris* )
  85      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  86      ;;
  87 esac
  88
  89 AC_ARG_ENABLE(geoip-stats,
  90      AS_HELP_STRING(--enable-geoip-stats, enable code for directories to collect per-country statistics))
  91
  92 if test "$enable_geoip_stats" = "yes"; then
  93   AC_DEFINE(ENABLE_GEOIP_STATS, 1, [Defined if we try to collect per-country statistics])
  94 fi
  95
  96 AC_ARG_ENABLE(gcc-warnings,
  97      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  98
  99 AC_ARG_ENABLE(local-appdata,
 100    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 101 if test "$enable_local_appdata" = "yes"; then
 102   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 103             [Defined if we default to host local appdata paths on Windows])
 104 fi
 105
 106 AC_PROG_CC
 107 AC_PROG_CPP
 108 AC_PROG_MAKE_SET
 109 AC_PROG_RANLIB
 110 AC_PROG_SED
 111
 112 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 113 AC_PATH_PROG([OPENSSL], [openssl], none)
 114
 115 TORUSER=_tor
 116 AC_ARG_WITH(tor-user,
 117         [  --with-tor-user=NAME    Specify username for tor daemon ],
 118         [
 119            TORUSER=$withval
 120         ]
 121 )
 122 AC_SUBST(TORUSER)
 123
 124 TORGROUP=_tor
 125 AC_ARG_WITH(tor-group,
 126         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 127         [
 128            TORGROUP=$withval
 129         ]
 130 )
 131 AC_SUBST(TORGROUP)
 132
 133
 134 dnl If WIN32 is defined and non-zero, we are building for win32
 135 AC_MSG_CHECKING([for win32])
 136 AC_RUN_IFELSE([
 137 int main(int c, char **v) {
 138 #ifdef WIN32
 139 #if WIN32
 140   return 0;
 141 #else
 142   return 1;
 143 #endif
 144 #else
 145   return 2;
 146 #endif
 147 }],
 148 bwin32=true; AC_MSG_RESULT([yes]),
 149 bwin32=false; AC_MSG_RESULT([no]),
 150 bwin32=cross; AC_MSG_RESULT([cross])
 151 )
 152
 153 if test "$bwin32" = cross; then
 154 AC_MSG_CHECKING([for win32 (cross)])
 155 AC_COMPILE_IFELSE([
 156 #ifdef WIN32
 157 int main(int c, char **v) {return 0;}
 158 #else
 159 #error
 160 int main(int c, char **v) {return x(y);}
 161 #endif
 162 ],
 163 bwin32=true; AC_MSG_RESULT([yes]),
 164 bwin32=false; AC_MSG_RESULT([no]))
 165 fi
 166
 167 if test "$bwin32" = true; then
 168 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 169 fi
 170 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 171
 172 dnl Enable C99 when compiling with MIPSpro
 173 AC_MSG_CHECKING([for MIPSpro compiler])
 174 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 175 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 176 #error
 177   return x(y);
 178 #endif
 179 ]),
 180 bmipspro=false; AC_MSG_RESULT(no),
 181 bmipspro=true; AC_MSG_RESULT(yes))
 182
 183 if test "$bmipspro" = true; then
 184   CFLAGS="$CFLAGS -c99"
 185 fi
 186
 187 AC_C_BIGENDIAN
 188
 189 AC_SEARCH_LIBS(socket, [socket])
 190 AC_SEARCH_LIBS(gethostbyname, [nsl])
 191 AC_SEARCH_LIBS(dlopen, [dl])
 192 AC_SEARCH_LIBS(inet_aton, [resolv])
 193
 194 if test "$enable_threads" = "yes"; then
 195   AC_SEARCH_LIBS(pthread_create, [pthread])
 196   AC_SEARCH_LIBS(pthread_detach, [pthread])
 197 fi
 198
 199 dnl -------------------------------------------------------------------
 200 dnl Check for functions before libevent, since libevent-1.2 apparently
 201 dnl exports strlcpy without defining it in a header.
 202
 203 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl)
 204
 205 using_custom_malloc=no
 206 if test x$enable_openbsd_malloc = xyes ; then
 207    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 208    using_custom_malloc=yes
 209 fi
 210 if test x$tcmalloc = xyes ; then
 211    using_custom_malloc=yes
 212 fi
 213 if test $using_custom_malloc = no ; then
 214    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 215 fi
 216
 217 if test "$enable_threads" = "yes"; then
 218   AC_CHECK_HEADERS(pthread.h)
 219   AC_CHECK_FUNCS(pthread_create)
 220 fi
 221
 222 dnl ------------------------------------------------------
 223 dnl Where do you live, libevent?  And how do we call you?
 224
 225 if test "$bwin32" = true; then
 226   TOR_LIB_WS32=-lws2_32
 227   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 228   # think it's actually necessary.
 229   TOR_LIB_GDI=-lgdi32
 230 else
 231   TOR_LIB_WS32=
 232   TOR_LIB_GDI=
 233 fi
 234 AC_SUBST(TOR_LIB_WS32)
 235 AC_SUBST(TOR_LIB_GDI)
 236
 237 dnl We need to do this before we try our disgusting hack below.
 238 AC_CHECK_HEADERS([sys/types.h])
 239
 240 dnl This is a disgusting hack so we safely include older libevent headers.
 241 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 242 AC_CHECK_TYPE(u_int32_t, unsigned long)
 243 AC_CHECK_TYPE(u_int16_t, unsigned short)
 244 AC_CHECK_TYPE(u_int8_t, unsigned char)
 245
 246 tor_libevent_pkg_redhat="libevent"
 247 tor_libevent_pkg_debian="libevent-dev"
 248 tor_libevent_devpkg_redhat="libevent-devel"
 249 tor_libevent_devpkg_debian="libevent-dev"
 250
 251 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 252 #ifdef WIN32
 253 #include <winsock2.h>
 254 #endif
 255 #include <stdlib.h>
 256 #include <sys/time.h>
 257 #include <sys/types.h>
 258 #include <event.h>], [
 259 #ifdef WIN32
 260 #include <winsock2.h>
 261 #endif
 262 void exit(int); void *event_init(void);],
 263     [
 264 #ifdef WIN32
 265 {WSADATA d; WSAStartup(0x101,&d); }
 266 #endif
 267 event_init(); exit(0);
 268 ], [--with-libevent-dir], [/opt/libevent])
 269
 270 dnl Now check for particular libevent functions.
 271 save_LIBS="$LIBS"
 272 save_LDFLAGS="$LDFLAGS"
 273 save_CPPFLAGS="$CPPFLAGS"
 274 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 275 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 276 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 277 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 278 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 279 [#include <event.h>
 280 ])
 281
 282 LIBS="$save_LIBS"
 283 LDFLAGS="$save_LDFLAGS"
 284 CPPFLAGS="$save_CPPFLAGS"
 285
 286 dnl ------------------------------------------------------
 287 dnl Where do you live, openssl?  And how do we call you?
 288
 289 tor_openssl_pkg_redhat="openssl"
 290 tor_openssl_pkg_debian="libssl"
 291 tor_openssl_devpkg_redhat="openssl-devel"
 292 tor_openssl_devpkg_debian="libssl-dev"
 293
 294 ALT_openssl_WITHVAL=""
 295 AC_ARG_WITH(ssl-dir,
 296   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 297   [
 298       if test "x$withval" != xno && test "x$withval" != "x" ; then
 299          ALT_openssl_WITHVAL="$withval"
 300       fi
 301   ])
 302
 303 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 304     [#include <openssl/rand.h>],
 305     [void RAND_add(const void *buf, int num, double entropy);],
 306     [RAND_add((void*)0,0,0); exit(0);], [],
 307     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 308
 309 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 310
 311 dnl ------------------------------------------------------
 312 dnl Where do you live, zlib?  And how do we call you?
 313
 314 tor_openssl_pkg_redhat="zlib"
 315 tor_openssl_pkg_debian="zlib1g"
 316 tor_openssl_devpkg_redhat="zlib-devel"
 317 tor_openssl_devpkg_debian="zlib1g-dev"
 318
 319 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 320     [#include <zlib.h>],
 321     [const char * zlibVersion(void);],
 322     [zlibVersion(); exit(0);], [--with-zlib-dir],
 323     [/opt/zlib])
 324
 325 dnl Make sure to enable support for large off_t if available.
 326
 327 AC_SYS_LARGEFILE
 328
 329 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 330
 331 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 332
 333 dnl These headers are not essential
 334
 335 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 336
 337 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 338 [#ifdef HAVE_MALLOC_H
 339 #include <malloc.h>
 340 #endif
 341 #ifdef HAVE_MALLOC_MALLOC_H
 342 #include <malloc/malloc.h>
 343 #endif])
 344
 345 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 346 [#ifdef HAVE_SYS_TYPES_H
 347 #include <sys/types.h>
 348 #endif
 349 #ifdef HAVE_SYS_SOCKET_H
 350 #include <sys/socket.h>
 351 #endif])
 352 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 353 [#ifdef HAVE_SYS_TYPES_H
 354 #include <sys/types.h>
 355 #endif
 356 #ifdef HAVE_SYS_SOCKET_H
 357 #include <sys/socket.h>
 358 #endif
 359 #ifdef HAVE_NET_IF_H
 360 #include <net/if.h>
 361 #endif])
 362 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 363         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 364 [#ifdef HAVE_SYS_TYPES_H
 365 #include <sys/types.h>
 366 #endif
 367 #ifdef HAVE_SYS_SOCKET_H
 368 #include <sys/socket.h>
 369 #endif
 370 #ifdef HAVE_LIMITS_H
 371 #include <limits.h>
 372 #endif
 373 #ifdef HAVE_LINUX_TYPES_H
 374 #include <linux/types.h>
 375 #endif
 376 #ifdef HAVE_NETINET_IN6_H
 377 #include <netinet/in6.h>
 378 #endif
 379 #ifdef HAVE_NETINET_IN_H
 380 #include <netinet/in.h>
 381 #endif])
 382
 383 if test x$transparent = xtrue ; then
 384    transparent_ok=0
 385    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 386      transparent_ok=1
 387    fi
 388    if test x$linux_netfilter_ipv4 = x1 ; then
 389      transparent_ok=1
 390    fi
 391    if test x$transparent_ok = x1 ; then
 392      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 393      case $host in
 394        *-*-openbsd*)
 395          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 396      esac
 397    else
 398      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 399    fi
 400 fi
 401
 402 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 403 [#ifdef HAVE_SYS_TYPES_H
 404 #include <sys/types.h>
 405 #endif
 406 #ifdef HAVE_SYS_TIME_H
 407 #include <sys/time.h>
 408 #endif])
 409
 410 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 411 dnl Watch out.
 412
 413 AC_CHECK_SIZEOF(int8_t)
 414 AC_CHECK_SIZEOF(int16_t)
 415 AC_CHECK_SIZEOF(int32_t)
 416 AC_CHECK_SIZEOF(int64_t)
 417 AC_CHECK_SIZEOF(uint8_t)
 418 AC_CHECK_SIZEOF(uint16_t)
 419 AC_CHECK_SIZEOF(uint32_t)
 420 AC_CHECK_SIZEOF(uint64_t)
 421 AC_CHECK_SIZEOF(intptr_t)
 422 AC_CHECK_SIZEOF(uintptr_t)
 423
 424 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 425
 426 AC_CHECK_SIZEOF(char)
 427 AC_CHECK_SIZEOF(short)
 428 AC_CHECK_SIZEOF(int)
 429 AC_CHECK_SIZEOF(long)
 430 AC_CHECK_SIZEOF(long long)
 431 AC_CHECK_SIZEOF(__int64)
 432 AC_CHECK_SIZEOF(void *)
 433 AC_CHECK_SIZEOF(time_t)
 434 AC_CHECK_SIZEOF(size_t)
 435
 436 AC_CHECK_TYPES([uint, u_char, ssize_t])
 437
 438 dnl used to include sockaddr_storage, but everybody has that.
 439 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 440 [#ifdef HAVE_SYS_TYPES_H
 441 #include <sys/types.h>
 442 #endif
 443 #ifdef HAVE_NETINET_IN_H
 444 #include <netinet/in.h>
 445 #endif
 446 #ifdef HAVE_NETINET_IN6_H
 447 #include <netinet/in6.h>
 448 #endif
 449 #ifdef HAVE_SYS_SOCKET_H
 450 #include <sys/socket.h>
 451 #endif
 452 #ifdef MS_WINDOWS
 453 #define WIN32_WINNT 0x400
 454 #define _WIN32_WINNT 0x400
 455 #define WIN32_LEAN_AND_MEAN
 456 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 457 #include <winsock.h>
 458 #else
 459 #include <winsock2.h>
 460 #include <ws2tcpip.h>
 461 #endif
 462 #endif
 463 ])
 464 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 465 [#ifdef HAVE_SYS_TYPES_H
 466 #include <sys/types.h>
 467 #endif
 468 #ifdef HAVE_NETINET_IN_H
 469 #include <netinet/in.h>
 470 #endif
 471 #ifdef HAVE_NETINET_IN6_H
 472 #include <netinet/in6.h>
 473 #endif
 474 #ifdef HAVE_SYS_SOCKET_H
 475 #include <sys/socket.h>
 476 #endif
 477 #ifdef MS_WINDOWS
 478 #define WIN32_WINNT 0x400
 479 #define _WIN32_WINNT 0x400
 480 #define WIN32_LEAN_AND_MEAN
 481 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 482 #include <winsock.h>
 483 #else
 484 #include <winsock2.h>
 485 #include <ws2tcpip.h>
 486 #endif
 487 #endif
 488 ])
 489
 490 AC_CHECK_TYPES([rlim_t], , ,
 491 [#ifdef HAVE_SYS_TYPES_H
 492 #include <sys/types.h>
 493 #endif
 494 #ifdef HAVE_SYS_TIME_H
 495 #include <sys/time.h>
 496 #endif
 497 #ifdef HAVE_SYS_RESOURCE_H
 498 #include <sys/resource.h>
 499 #endif
 500 ])
 501
 502 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 503 AC_RUN_IFELSE(AC_LANG_SOURCE([
 504 #ifdef HAVE_SYS_TYPES_H
 505 #include <sys/types.h>
 506 #endif
 507 #ifdef HAVE_SYS_TIME_H
 508 #include <sys/time.h>
 509 #endif
 510 #ifdef HAVE_TIME_H
 511 #include <time.h>
 512 #endif
 513 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 514   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 515 ])
 516
 517 if test "$tor_cv_time_t_signed" = cross; then
 518   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 519 fi
 520
 521 if test "$tor_cv_time_t_signed" != no; then
 522   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 523             [Define to 1 iff time_t is signed])
 524 fi
 525
 526 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 527 #ifdef HAVE_SYS_SOCKET_H
 528 #include <sys/socket.h>
 529 #endif
 530 ])
 531
 532 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 533
 534 AC_CHECK_SIZEOF(cell_t)
 535
 536 # Now make sure that NULL can be represented as zero bytes.
 537 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 538 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 539 [[#include <stdlib.h>
 540 #include <string.h>
 541 #include <stdio.h>
 542 #ifdef HAVE_STDDEF_H
 543 #include <stddef.h>
 544 #endif
 545 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 546 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 547        [tor_cv_null_is_zero=yes],
 548        [tor_cv_null_is_zero=no],
 549        [tor_cv_null_is_zero=cross])])
 550
 551 if test "$tor_cv_null_is_zero" = cross ; then
 552   # Cross-compiling; let's hope that the target isn't raving mad.
 553   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 554 fi
 555
 556 if test "$tor_cv_null_is_zero" != no; then
 557   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 558             [Define to 1 iff memset(0) sets pointers to NULL])
 559 fi
 560
 561 # And what happens when we malloc zero?
 562 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 563 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 564 [[#include <stdlib.h>
 565 #include <string.h>
 566 #include <stdio.h>
 567 #ifdef HAVE_STDDEF_H
 568 #include <stddef.h>
 569 #endif
 570 int main () { return malloc(0)?0:1; }]])],
 571        [tor_cv_malloc_zero_works=yes],
 572        [tor_cv_malloc_zero_works=no],
 573        [tor_cv_malloc_zero_works=cross])])
 574
 575 if test "$tor_cv_malloc_zero_works" = cross; then
 576   # Cross-compiling; let's hope that the target isn't raving mad.
 577   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 578 fi
 579
 580 if test "$tor_cv_malloc_zero_works" = yes; then
 581   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 582             [Define to 1 iff malloc(0) returns a pointer])
 583 fi
 584
 585 # whether we seem to be in a 2s-complement world.
 586 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 587 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 588 [[int main () { int problem = ((-99) != (~99)+1);
 589 return problem ? 1 : 0; }]])],
 590        [tor_cv_twos_complement=yes],
 591        [tor_cv_twos_complement=no],
 592        [tor_cv_twos_complement=cross])])
 593
 594 if test "$tor_cv_twos_complement" = cross ; then
 595   # Cross-compiling; let's hope that the target isn't raving mad.
 596   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 597 fi
 598
 599 if test "$tor_cv_twos_complement" != no ; then
 600   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 601             [Define to 1 iff we represent negative integers with two's complement])
 602 fi
 603
 604 # Whether we should use the dmalloc memory allocation debugging library.
 605 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 606 AC_ARG_WITH(dmalloc,
 607 [  --with-dmalloc          Use debug memory allocation library. ],
 608 [if [[ "$withval" = "yes" ]]; then
 609   dmalloc=1
 610   AC_MSG_RESULT(yes)
 611 else
 612   dmalloc=1
 613   AC_MSG_RESULT(no)
 614 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 615 )
 616
 617 if [[ $dmalloc -eq 1 ]]; then
 618   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 619   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 620   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 621   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 622   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 623 fi
 624
 625 AC_ARG_WITH(tcmalloc,
 626 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 627 [ tcmalloc=yes ], [ tcmalloc=no ])
 628
 629 if test x$tcmalloc = xyes ; then
 630    LDFLAGS="-ltcmalloc $LDFLAGS"
 631 fi
 632
 633 # Allow user to specify an alternate syslog facility
 634 AC_ARG_WITH(syslog-facility,
 635 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 636 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 637 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 638 AC_SUBST(LOGFACILITY)
 639
 640 # Check if we have getresuid and getresgid
 641 AC_CHECK_FUNCS(getresuid getresgid)
 642
 643 # Check for gethostbyname_r in all its glorious incompatible versions.
 644 #   (This logic is based on that in Python's configure.in)
 645 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 646   [Define this if you have any gethostbyname_r()])
 647
 648 AC_CHECK_FUNC(gethostbyname_r, [
 649   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 650   OLD_CFLAGS=$CFLAGS
 651   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 652   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 653 #include <netdb.h>
 654   ], [[
 655     char *cp1, *cp2;
 656     struct hostent *h1, *h2;
 657     int i1, i2;
 658     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 659   ]]),[
 660     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 661     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 662      [Define this if gethostbyname_r takes 6 arguments])
 663     AC_MSG_RESULT(6)
 664   ], [
 665     AC_TRY_COMPILE([
 666 #include <netdb.h>
 667     ], [
 668       char *cp1, *cp2;
 669       struct hostent *h1;
 670       int i1, i2;
 671       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 672     ], [
 673       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 674       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 675         [Define this if gethostbyname_r takes 5 arguments])
 676       AC_MSG_RESULT(5)
 677    ], [
 678       AC_TRY_COMPILE([
 679 #include <netdb.h>
 680      ], [
 681        char *cp1;
 682        struct hostent *h1;
 683        struct hostent_data hd;
 684        (void) gethostbyname_r(cp1,h1,&hd);
 685      ], [
 686        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 687        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 688          [Define this if gethostbyname_r takes 3 arguments])
 689        AC_MSG_RESULT(3)
 690      ], [
 691        AC_MSG_RESULT(0)
 692      ])
 693   ])
 694  ])
 695  CFLAGS=$OLD_CFLAGS
 696 ])
 697
 698 AC_CACHE_CHECK([whether the C compiler supports __func__],
 699   tor_cv_have_func_macro,
 700   AC_COMPILE_IFELSE([
 701 #include <stdio.h>
 702 int main(int c, char **v) { puts(__func__); }],
 703   tor_cv_have_func_macro=yes,
 704   tor_cv_have_func_macro=no))
 705
 706 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 707   tor_cv_have_FUNC_macro,
 708   AC_COMPILE_IFELSE([
 709 #include <stdio.h>
 710 int main(int c, char **v) { puts(__FUNC__); }],
 711   tor_cv_have_FUNC_macro=yes,
 712   tor_cv_have_FUNC_macro=no))
 713
 714 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 715   tor_cv_have_FUNCTION_macro,
 716   AC_COMPILE_IFELSE([
 717 #include <stdio.h>
 718 int main(int c, char **v) { puts(__FUNCTION__); }],
 719   tor_cv_have_FUNCTION_macro=yes,
 720   tor_cv_have_FUNCTION_macro=no))
 721
 722 if test "$tor_cv_have_func_macro" = 'yes'; then
 723   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 724 fi
 725
 726 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 727   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 728 fi
 729
 730 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 731   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 732            [Defined if the compiler supports __FUNCTION__])
 733 fi
 734
 735 # $prefix stores the value of the --prefix command line option, or
 736 # NONE if the option wasn't set.  In the case that it wasn't set, make
 737 # it be the default, so that we can use it to expand directories now.
 738 if test "x$prefix" = "xNONE"; then
 739   prefix=$ac_default_prefix
 740 fi
 741
 742 # and similarly for $exec_prefix
 743 if test "x$exec_prefix" = "xNONE"; then
 744   exec_prefix=$prefix
 745 fi
 746
 747 if test "x$CONFDIR" = "x"; then
 748   CONFDIR=`eval echo $sysconfdir/tor`
 749 fi
 750 AC_SUBST(CONFDIR)
 751 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 752 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 753
 754 BINDIR=`eval echo $bindir`
 755 AC_SUBST(BINDIR)
 756 LOCALSTATEDIR=`eval echo $localstatedir`
 757 AC_SUBST(LOCALSTATEDIR)
 758
 759 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 760 # than autoconf's macros like.
 761 if test "$GCC" = yes; then
 762   CFLAGS="$CFLAGS -Wall -g -O2"
 763   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 764   # accident waiting to happen.
 765   CFLAGS="$CFLAGS -fno-strict-aliasing"
 766 else
 767   CFLAGS="$CFLAGS -g -O"
 768   enable_gcc_warnings=no
 769 fi
 770
 771 # Add some more warnings which we use in development but not in the
 772 # released versions.  (Some relevant gcc versions can't handle these.)
 773 if test x$enable_gcc_warnings = xyes; then
 774
 775   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 776 #if !defined(__GNUC__) || (__GNUC__ < 4)
 777 #error
 778 #endif]), have_gcc4=yes, have_gcc4=no)
 779
 780   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 781 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 782 #error
 783 #endif]), have_gcc42=yes, have_gcc42=no)
 784
 785   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 786 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 787 #error
 788 #endif]), have_gcc43=yes, have_gcc43=no)
 789
 790   save_CFLAGS="$CFLAGS"
 791   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 792   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 793                     have_shorten64_flag=no)
 794   CFLAGS="$save_CFLAGS"
 795
 796   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 797
 798   # Disabled, so we can use mallinfo(): -Waggregate-return
 799
 800   if test x$have_gcc4 = xyes ; then
 801     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 802     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 803   fi
 804
 805   if test x$have_gcc42 = xyes ; then
 806     # These warnings break gcc 4.0.2 and work on gcc 4.2
 807     # XXXX020 Use -fstack-protector.
 808     # XXXX020 See if any of these work with earlier versions.
 809     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 810     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 811   fi
 812
 813   if test x$have_gcc43 = xyes ; then
 814     # These warnings break gcc 4.2 and work on gcc 4.3
 815     # XXXX020 See if any of these work with earlier versions.
 816     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 817   fi
 818
 819   if test x$have_shorten64_flag = xyes ; then
 820     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 821   fi
 822
 823 ##This will break the world on some 64-bit architectures
 824 # CFLAGS="$CFLAGS -Winline"
 825 fi
 826
 827
 828
 829 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 830
 831 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 832 AC_OUTPUT
 833
 834 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 835   ./contrib/updateVersions.pl
 836 fi
 837