configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2017, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.2.9-dev])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56 AC_ARG_ENABLE(memory-sentinels,
  57    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  58 AC_ARG_ENABLE(rust,
  59    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  60 AC_ARG_ENABLE(cargo-online-mode,
  61    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  62
  63 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  64     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  65 fi
  66
  67 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  68 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  69 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  70 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  71 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  72 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  73
  74 if test "$enable_static_tor" = "yes"; then
  75   enable_static_libevent="yes";
  76   enable_static_openssl="yes";
  77   enable_static_zlib="yes";
  78   CFLAGS="$CFLAGS -static"
  79 fi
  80
  81 if test "$enable_system_torrc" = "no"; then
  82   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  83             [Defined if we're not going to look for a torrc in SYSCONF])
  84 fi
  85
  86 if test "$enable_memory_sentinels" = "no"; then
  87   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  88            [Defined if we're turning off memory safety code to look for bugs])
  89 fi
  90
  91 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  92
  93 AC_ARG_ENABLE(asciidoc,
  94      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  95      [case "${enableval}" in
  96         "yes") asciidoc=true ;;
  97         "no")  asciidoc=false ;;
  98         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  99       esac], [asciidoc=true])
 100
 101 # systemd notify support
 102 AC_ARG_ENABLE(systemd,
 103       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 104       [case "${enableval}" in
 105         "yes") systemd=true ;;
 106         "no")  systemd=false ;;
 107         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 108       esac], [systemd=auto])
 109
 110
 111
 112 # systemd support
 113 if test "x$enable_systemd" = "xno"; then
 114     have_systemd=no;
 115 else
 116     PKG_CHECK_MODULES(SYSTEMD,
 117         [libsystemd-daemon],
 118         have_systemd=yes,
 119         have_systemd=no)
 120     if test "x$have_systemd" = "xno"; then
 121         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 122         PKG_CHECK_MODULES(SYSTEMD,
 123             [libsystemd],
 124             have_systemd=yes,
 125             have_systemd=no)
 126     fi
 127 fi
 128
 129 if test "x$have_systemd" = "xyes"; then
 130     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 131     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 132     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 133     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 134          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 135 fi
 136 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 137 AC_SUBST(TOR_SYSTEMD_LIBS)
 138
 139 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 140     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 141 fi
 142
 143 case "$host" in
 144    *-*-solaris* )
 145      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 146      ;;
 147 esac
 148
 149 AC_ARG_ENABLE(gcc-warnings,
 150      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 151 AC_ARG_ENABLE(fatal-warnings,
 152      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 153 AC_ARG_ENABLE(gcc-warnings-advisory,
 154      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 155
 156 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 157 AC_ARG_ENABLE(gcc-hardening,
 158     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 159
 160 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 161 AC_ARG_ENABLE(expensive-hardening,
 162     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 163 AC_ARG_ENABLE(fragile-hardening,
 164     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 165 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 166   fragile_hardening="yes"
 167 fi
 168
 169 dnl Linker hardening options
 170 dnl Currently these options are ELF specific - you can't use this with MacOSX
 171 AC_ARG_ENABLE(linker-hardening,
 172     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 173
 174 AC_ARG_ENABLE(local-appdata,
 175    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 176 if test "$enable_local_appdata" = "yes"; then
 177   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 178             [Defined if we default to host local appdata paths on Windows])
 179 fi
 180
 181 # Tor2web mode flag
 182 AC_ARG_ENABLE(tor2web-mode,
 183      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 184 [if test "x$enableval" = "xyes"; then
 185     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 186 fi])
 187
 188 AC_ARG_ENABLE(tool-name-check,
 189      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 190
 191 AC_ARG_ENABLE(seccomp,
 192      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 193
 194 AC_ARG_ENABLE(libscrypt,
 195      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 196
 197 dnl Enable event tracing which are transformed to debug log statement.
 198 AC_ARG_ENABLE(event-tracing-debug,
 199      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 200 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 201
 202 if test x$enable_event_tracing_debug = xyes; then
 203   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 204   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 205 fi
 206
 207 dnl check for the correct "ar" when cross-compiling.
 208 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 209 dnl    so kludge up a replacement for the case where it isn't there yet.)
 210 m4_ifdef([AM_PROG_AR],
 211          [AM_PROG_AR],
 212          [AN_MAKEVAR([AR], [AC_PROG_AR])
 213           AN_PROGRAM([ar], [AC_PROG_AR])
 214           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 215           AC_PROG_AR])
 216
 217 dnl Check whether the above macro has settled for a simply named tool even
 218 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 219 dnl because that will find any cc on the system, not only the cross-compiler,
 220 dnl and then verify that a binary built with this compiler runs on the
 221 dnl build system. It will then come to the false conclusion that we're not
 222 dnl cross-compiling.
 223 if test "x$enable_tool_name_check" != "xno"; then
 224     if test "x$ac_tool_warned" = "xyes"; then
 225         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 226         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 227                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 228         fi
 229 fi
 230
 231 AC_PROG_CC
 232 AC_PROG_CPP
 233 AC_PROG_MAKE_SET
 234 AC_PROG_RANLIB
 235 AC_PROG_SED
 236
 237 AC_ARG_VAR([PERL], [path to Perl binary])
 238 AC_CHECK_PROGS([PERL], [perl])
 239 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 240
 241 dnl check for asciidoc and a2x
 242 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 243 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 244
 245 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 246
 247 AM_PROG_CC_C_O
 248 AC_PROG_CC_C99
 249
 250 AC_ARG_VAR([PYTHON], [path to Python binary])
 251 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 252 if test "x$PYTHON" = "x"; then
 253   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 254 fi
 255 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 256
 257 dnl List all external rust crates we depend on here. Include the version
 258 rust_crates="libc-0.2.22"
 259 AC_SUBST(rust_crates)
 260
 261 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 262 AC_C_FLEXIBLE_ARRAY_MEMBER
 263 ], [
 264  dnl Maybe we've got an old autoconf...
 265  AC_CACHE_CHECK([for flexible array members],
 266      tor_cv_c_flexarray,
 267      [AC_COMPILE_IFELSE(
 268        AC_LANG_PROGRAM([
 269  struct abc { int a; char b[]; };
 270 ], [
 271  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 272  def->b[0] = 33;
 273 ]),
 274   [tor_cv_c_flexarray=yes],
 275   [tor_cv_c_flexarray=no])])
 276  if test "$tor_cv_flexarray" = "yes"; then
 277    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 278  else
 279    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 280  fi
 281 ])
 282
 283 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 284       tor_cv_c_c99_decl,
 285       [AC_COMPILE_IFELSE(
 286          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 287          [tor_cv_c_c99_decl=yes],
 288          [tor_cv_c_c99_decl=no] )])
 289 if test "$tor_cv_c_c99_decl" != "yes"; then
 290   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 291 fi
 292
 293 AC_CACHE_CHECK([for working C99 designated initializers],
 294       tor_cv_c_c99_designated_init,
 295       [AC_COMPILE_IFELSE(
 296          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 297                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 298          [tor_cv_c_c99_designated_init=yes],
 299          [tor_cv_c_c99_designated_init=no] )])
 300
 301 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 302   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 303 fi
 304
 305 TORUSER=_tor
 306 AC_ARG_WITH(tor-user,
 307         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 308         [
 309            TORUSER=$withval
 310         ]
 311 )
 312 AC_SUBST(TORUSER)
 313
 314 TORGROUP=_tor
 315 AC_ARG_WITH(tor-group,
 316         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 317         [
 318            TORGROUP=$withval
 319         ]
 320 )
 321 AC_SUBST(TORGROUP)
 322
 323
 324 dnl If _WIN32 is defined and non-zero, we are building for win32
 325 AC_MSG_CHECKING([for win32])
 326 AC_RUN_IFELSE([AC_LANG_SOURCE([
 327 int main(int c, char **v) {
 328 #ifdef _WIN32
 329 #if _WIN32
 330   return 0;
 331 #else
 332   return 1;
 333 #endif
 334 #else
 335   return 2;
 336 #endif
 337 }])],
 338 bwin32=true; AC_MSG_RESULT([yes]),
 339 bwin32=false; AC_MSG_RESULT([no]),
 340 bwin32=cross; AC_MSG_RESULT([cross])
 341 )
 342
 343 if test "$bwin32" = "cross"; then
 344 AC_MSG_CHECKING([for win32 (cross)])
 345 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 346 #ifdef _WIN32
 347 int main(int c, char **v) {return 0;}
 348 #else
 349 #error
 350 int main(int c, char **v) {return x(y);}
 351 #endif
 352 ])],
 353 bwin32=true; AC_MSG_RESULT([yes]),
 354 bwin32=false; AC_MSG_RESULT([no]))
 355 fi
 356
 357 AH_BOTTOM([
 358 #ifdef _WIN32
 359 /* Defined to access windows functions and definitions for >=WinXP */
 360 # ifndef WINVER
 361 #  define WINVER 0x0501
 362 # endif
 363
 364 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 365 # ifndef _WIN32_WINNT
 366 #  define _WIN32_WINNT 0x0501
 367 # endif
 368
 369 /* Defined to avoid including some windows headers as part of Windows.h */
 370 # ifndef WIN32_LEAN_AND_MEAN
 371 #  define WIN32_LEAN_AND_MEAN 1
 372 # endif
 373 #endif
 374 ])
 375
 376
 377 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 378
 379 dnl Enable C99 when compiling with MIPSpro
 380 AC_MSG_CHECKING([for MIPSpro compiler])
 381 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 382 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 383 #error
 384   return x(y);
 385 #endif
 386 ])],
 387 bmipspro=false; AC_MSG_RESULT(no),
 388 bmipspro=true; AC_MSG_RESULT(yes))
 389
 390 if test "$bmipspro" = "true"; then
 391   CFLAGS="$CFLAGS -c99"
 392 fi
 393
 394 AC_C_BIGENDIAN
 395
 396 if test "x$enable_rust" = "xyes"; then
 397   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 398   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 399   if test "x$RUSTC" = "xno"; then
 400     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 401   fi
 402
 403   AC_ARG_VAR([CARGO], [path to the cargo binary])
 404   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 405   if test "x$CARGO" = "xno"; then
 406     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 407   fi
 408
 409   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 410   if test "x$enable_cargo_online_mode" = "xyes"; then
 411     CARGO_ONLINE=
 412     RUST_DL=#
 413   else
 414     CARGO_ONLINE=--frozen
 415     RUST_DL=
 416
 417     dnl When we're not allowed to touch the network, we need crate dependencies
 418     dnl locally available.
 419     AC_MSG_CHECKING([rust crate dependencies])
 420     AC_ARG_VAR([RUST_DEPENDENCIES], [path to directory with local crate mirror])
 421     if test "x$RUST_DEPENDENCIES" = "x"; then
 422       RUST_DEPENDENCIES="$srcdir/src/ext/rust/"
 423       NEED_MOD=1
 424     fi
 425     if test ! -d "$RUST_DEPENDENCIES"; then
 426       AC_MSG_ERROR([Rust dependency directory $RUST_DEPENDENCIES does not exist. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 427     fi
 428     for dep in $rust_crates; do
 429       if test ! -d "$RUST_DEPENDENCIES"/"$dep"; then
 430         AC_MSG_ERROR([Failure to find rust dependency $RUST_DEPENDENCIES/$dep. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 431       fi
 432     done
 433     if test "x$NEED_MOD" = "x1"; then
 434       dnl When looking for dependencies from cargo, pick right directory
 435       RUST_DEPENDENCIES="../../src/ext/rust"
 436     fi
 437   fi
 438
 439   dnl This is a workaround for #46797
 440   dnl (a.k.a https://github.com/rust-lang/rust/issues/46797 ).  Once the
 441   dnl upstream bug is fixed, we can remove this workaround.
 442   case "$host_os" in
 443       darwin*)
 444         TOR_RUST_EXTRA_LIBS="-lresolv"
 445         ;;
 446   esac
 447
 448   dnl For now both MSVC and MinGW rust libraries will output static libs with
 449   dnl the MSVC naming convention.
 450   if test "$bwin32" = "true"; then
 451     TOR_RUST_UTIL_STATIC_NAME=tor_util.lib
 452   else
 453     TOR_RUST_UTIL_STATIC_NAME=libtor_util.a
 454   fi
 455
 456   AC_SUBST(TOR_RUST_UTIL_STATIC_NAME)
 457   AC_SUBST(CARGO_ONLINE)
 458   AC_SUBST(RUST_DL)
 459
 460   dnl Let's check the rustc version, too
 461   AC_MSG_CHECKING([rust version])
 462   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 463   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 464   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 465     AC_MSG_ERROR([rustc version couldn't be identified])
 466   fi
 467   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 468     AC_MSG_ERROR([rustc must be at least version 1.14])
 469   fi
 470 fi
 471
 472 AC_SUBST(TOR_RUST_EXTRA_LIBS)
 473
 474 AC_SEARCH_LIBS(socket, [socket network])
 475 AC_SEARCH_LIBS(gethostbyname, [nsl])
 476 AC_SEARCH_LIBS(dlopen, [dl])
 477 AC_SEARCH_LIBS(inet_aton, [resolv])
 478 AC_SEARCH_LIBS(backtrace, [execinfo])
 479 saved_LIBS="$LIBS"
 480 AC_SEARCH_LIBS([clock_gettime], [rt])
 481 if test "$LIBS" != "$saved_LIBS"; then
 482    # Looks like we need -lrt for clock_gettime().
 483    have_rt=yes
 484 fi
 485
 486 AC_SEARCH_LIBS(pthread_create, [pthread])
 487 AC_SEARCH_LIBS(pthread_detach, [pthread])
 488
 489 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 490 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 491
 492 AC_CHECK_FUNCS(
 493         _NSGetEnviron \
 494         RtlSecureZeroMemory \
 495         SecureZeroMemory \
 496         accept4 \
 497         backtrace \
 498         backtrace_symbols_fd \
 499         eventfd \
 500         explicit_bzero \
 501         timingsafe_memcmp \
 502         flock \
 503         ftime \
 504         get_current_dir_name \
 505         getaddrinfo \
 506         getifaddrs \
 507         getpass \
 508         getrlimit \
 509         gettimeofday \
 510         gmtime_r \
 511         gnu_get_libc_version \
 512         htonll \
 513         inet_aton \
 514         ioctl \
 515         issetugid \
 516         llround \
 517         localtime_r \
 518         lround \
 519         memmem \
 520         memset_s \
 521         pipe \
 522         pipe2 \
 523         prctl \
 524         readpassphrase \
 525         rint \
 526         sigaction \
 527         socketpair \
 528         statvfs \
 529         strlcat \
 530         strlcpy \
 531         strnlen \
 532         strptime \
 533         strtok_r \
 534         strtoull \
 535         sysconf \
 536         sysctl \
 537         truncate \
 538         uname \
 539         usleep \
 540         vasprintf \
 541         _vscprintf
 542 )
 543
 544 # Apple messed up when they added two functions functions in Sierra: they
 545 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 546 # checks. So we should only probe for those functions if we are sure that we
 547 # are not targetting OSX 10.11 or earlier.
 548 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 549 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 550 #ifdef __APPLE__
 551 #  include <AvailabilityMacros.h>
 552 #  ifndef MAC_OS_X_VERSION_10_12
 553 #    define MAC_OS_X_VERSION_10_12 101200
 554 #  endif
 555 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 556 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 557 #      error "Running on Mac OSX 10.11 or earlier"
 558 #    endif
 559 #  endif
 560 #endif
 561 ]], [[]])],
 562    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 563    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 564
 565 if test "$on_macos_pre_10_12" = "no"; then
 566   AC_CHECK_FUNCS(
 567         clock_gettime \
 568         getentropy \
 569   )
 570 fi
 571
 572 if test "$bwin32" != "true"; then
 573   AC_CHECK_HEADERS(pthread.h)
 574   AC_CHECK_FUNCS(pthread_create)
 575   AC_CHECK_FUNCS(pthread_condattr_setclock)
 576 fi
 577
 578 if test "$bwin32" = "true"; then
 579   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 580 #include <windows.h>
 581 #include <conio.h>
 582 #include <wchar.h>
 583                  ])
 584 fi
 585
 586 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 587   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 588
 589 dnl ------------------------------------------------------
 590 dnl Where do you live, libevent?  And how do we call you?
 591
 592 if test "$bwin32" = "true"; then
 593   TOR_LIB_WS32=-lws2_32
 594   TOR_LIB_IPHLPAPI=-liphlpapi
 595   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 596   # think it's actually necessary.
 597   TOR_LIB_GDI=-lgdi32
 598   TOR_LIB_USERENV=-luserenv
 599 else
 600   TOR_LIB_WS32=
 601   TOR_LIB_GDI=
 602   TOR_LIB_USERENV=
 603 fi
 604 AC_SUBST(TOR_LIB_WS32)
 605 AC_SUBST(TOR_LIB_GDI)
 606 AC_SUBST(TOR_LIB_IPHLPAPI)
 607 AC_SUBST(TOR_LIB_USERENV)
 608
 609 tor_libevent_pkg_redhat="libevent"
 610 tor_libevent_pkg_debian="libevent-dev"
 611 tor_libevent_devpkg_redhat="libevent-devel"
 612 tor_libevent_devpkg_debian="libevent-dev"
 613
 614 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 615 dnl linking for static builds.
 616 STATIC_LIBEVENT_FLAGS=""
 617 if test "$enable_static_libevent" = "yes"; then
 618     if test "$have_rt" = "yes"; then
 619       STATIC_LIBEVENT_FLAGS=" -lrt "
 620     fi
 621 fi
 622
 623 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 624 #ifdef _WIN32
 625 #include <winsock2.h>
 626 #endif
 627 #include <sys/time.h>
 628 #include <sys/types.h>
 629 #include <event2/event.h>], [
 630 #ifdef _WIN32
 631 #include <winsock2.h>
 632 #endif
 633 struct event_base;
 634 struct event_base *event_base_new(void);],
 635     [
 636 #ifdef _WIN32
 637 {WSADATA d; WSAStartup(0x101,&d); }
 638 #endif
 639 event_base_free(event_base_new());
 640 ], [--with-libevent-dir], [/opt/libevent])
 641
 642 dnl Determine the incantation needed to link libevent.
 643 save_LIBS="$LIBS"
 644 save_LDFLAGS="$LDFLAGS"
 645 save_CPPFLAGS="$CPPFLAGS"
 646
 647 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 648 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 649 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 650
 651 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 652
 653 if test "$enable_static_libevent" = "yes"; then
 654    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 655      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 656    else
 657      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 658    fi
 659 else
 660      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 661        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 662        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 663
 664        if test "$ac_cv_search_event_new" != "none required"; then
 665          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 666        fi
 667        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 668          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 669        fi
 670      else
 671        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 672      fi
 673 fi
 674
 675 dnl Now check for particular libevent functions.
 676 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 677                 evutil_secure_rng_add_bytes \
 678 ])
 679
 680 LIBS="$save_LIBS"
 681 LDFLAGS="$save_LDFLAGS"
 682 CPPFLAGS="$save_CPPFLAGS"
 683
 684 dnl Check that libevent is at least at version 2.0.10, the first stable
 685 dnl release of its series
 686 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 687 AC_MSG_CHECKING([whether Libevent is new enough])
 688 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 689 #include <event2/event.h>
 690 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 691 #error
 692 int x = y(zz);
 693 #else
 694 int x = 1;
 695 #endif
 696 ])], [ AC_MSG_RESULT([yes]) ],
 697    [ AC_MSG_RESULT([no])
 698      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 699
 700 LIBS="$save_LIBS"
 701 LDFLAGS="$save_LDFLAGS"
 702 CPPFLAGS="$save_CPPFLAGS"
 703
 704 AC_SUBST(TOR_LIBEVENT_LIBS)
 705
 706 dnl ------------------------------------------------------
 707 dnl Where do you live, libm?
 708
 709 dnl On some platforms (Haiku/BeOS) the math library is
 710 dnl part of libroot. In which case don't link against lm
 711 TOR_LIB_MATH=""
 712 save_LIBS="$LIBS"
 713 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 714 if test "$ac_cv_search_pow" != "none required"; then
 715     TOR_LIB_MATH="$ac_cv_search_pow"
 716 fi
 717 LIBS="$save_LIBS"
 718 AC_SUBST(TOR_LIB_MATH)
 719
 720 dnl ------------------------------------------------------
 721 dnl Where do you live, openssl?  And how do we call you?
 722
 723 tor_openssl_pkg_redhat="openssl"
 724 tor_openssl_pkg_debian="libssl-dev"
 725 tor_openssl_devpkg_redhat="openssl-devel"
 726 tor_openssl_devpkg_debian="libssl-dev"
 727
 728 ALT_openssl_WITHVAL=""
 729 AC_ARG_WITH(ssl-dir,
 730   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 731   [
 732       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 733          ALT_openssl_WITHVAL="$withval"
 734       fi
 735   ])
 736
 737 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 738 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 739     [#include <openssl/ssl.h>],
 740     [struct ssl_method_st; const struct ssl_method_st *TLSv1_1_method(void);],
 741     [TLSv1_1_method();], [],
 742     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 743
 744 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 745
 746 if test "$enable_static_openssl" = "yes"; then
 747    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 748      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 749    else
 750      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 751    fi
 752 else
 753      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 754 fi
 755 AC_SUBST(TOR_OPENSSL_LIBS)
 756
 757 dnl Now check for particular openssl functions.
 758 save_LIBS="$LIBS"
 759 save_LDFLAGS="$LDFLAGS"
 760 save_CPPFLAGS="$CPPFLAGS"
 761 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 762 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 763 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 764
 765 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 766 #include <openssl/opensslv.h>
 767 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 768 #error "too old"
 769 #endif
 770    ]], [[]])],
 771    [ : ],
 772    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 773
 774 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 775 #include <openssl/opensslv.h>
 776 #include <openssl/evp.h>
 777 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 778 #error "no ECC"
 779 #endif
 780 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 781 #error "curves unavailable"
 782 #endif
 783    ]], [[]])],
 784    [ : ],
 785    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 786
 787 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 788 [#include <openssl/ssl.h>
 789 ])
 790
 791 AC_CHECK_FUNCS([ \
 792                 SSL_SESSION_get_master_key \
 793                 SSL_get_server_random \
 794                 SSL_get_client_ciphers \
 795                 SSL_get_client_random \
 796                 SSL_CIPHER_find \
 797                 TLS_method
 798                ])
 799
 800 dnl Check if OpenSSL has scrypt implementation.
 801 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 802
 803 dnl Check if OpenSSL structures are opaque
 804 AC_CHECK_MEMBERS([SSL.state], , ,
 805 [#include <openssl/ssl.h>
 806 ])
 807
 808 dnl Define the set of checks for KIST scheduler support.
 809 AC_DEFUN([CHECK_KIST_SUPPORT],[
 810   dnl KIST needs struct tcp_info and for certain members to exist.
 811   AC_CHECK_MEMBERS(
 812     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
 813     , ,[[#include <netinet/tcp.h>]])
 814   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
 815   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 816                      #include <linux/sockios.h>
 817                      #ifndef SIOCOUTQNSD
 818                      #error
 819                      #endif
 820                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
 821   if test "x$have_siocoutqnsd" = "xyes"; then
 822     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
 823       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
 824         have_kist_support=yes
 825       fi
 826     fi
 827   fi
 828 ])
 829 dnl Now, trigger the check.
 830 CHECK_KIST_SUPPORT
 831 AS_IF([test "x$have_kist_support" = "xyes"],
 832       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
 833                                         on this system])],
 834       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
 835
 836 LIBS="$save_LIBS"
 837 LDFLAGS="$save_LDFLAGS"
 838 CPPFLAGS="$save_CPPFLAGS"
 839
 840 dnl ------------------------------------------------------
 841 dnl Where do you live, zlib?  And how do we call you?
 842
 843 tor_zlib_pkg_redhat="zlib"
 844 tor_zlib_pkg_debian="zlib1g"
 845 tor_zlib_devpkg_redhat="zlib-devel"
 846 tor_zlib_devpkg_debian="zlib1g-dev"
 847
 848 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 849     [#include <zlib.h>],
 850     [const char * zlibVersion(void);],
 851     [zlibVersion();], [--with-zlib-dir],
 852     [/opt/zlib])
 853
 854 if test "$enable_static_zlib" = "yes"; then
 855    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 856      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 857  using --enable-static-zlib")
 858    else
 859      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 860    fi
 861 else
 862      TOR_ZLIB_LIBS="-lz"
 863 fi
 864 AC_SUBST(TOR_ZLIB_LIBS)
 865
 866 dnl ------------------------------------------------------
 867 dnl Where we do we find lzma?
 868
 869 AC_ARG_ENABLE(lzma,
 870       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
 871       [case "${enableval}" in
 872         "yes") lzma=true ;;
 873         "no")  lzma=false ;;
 874         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
 875       esac], [lzma=auto])
 876
 877 if test "x$enable_lzma" = "xno"; then
 878     have_lzma=no;
 879 else
 880     PKG_CHECK_MODULES([LZMA],
 881                       [liblzma],
 882                       have_lzma=yes,
 883                       have_lzma=no)
 884
 885     if test "x$have_lzma" = "xno" ; then
 886         AC_MSG_WARN([Unable to find liblzma.])
 887     fi
 888 fi
 889
 890 if test "x$have_lzma" = "xyes"; then
 891     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
 892     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
 893     TOR_LZMA_LIBS="${LZMA_LIBS}"
 894 fi
 895 AC_SUBST(TOR_LZMA_CFLAGS)
 896 AC_SUBST(TOR_LZMA_LIBS)
 897
 898 dnl ------------------------------------------------------
 899 dnl Where we do we find zstd?
 900
 901 AC_ARG_ENABLE(zstd,
 902       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
 903       [case "${enableval}" in
 904         "yes") zstd=true ;;
 905         "no")  zstd=false ;;
 906         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
 907       esac], [zstd=auto])
 908
 909 if test "x$enable_zstd" = "xno"; then
 910     have_zstd=no;
 911 else
 912     PKG_CHECK_MODULES([ZSTD],
 913                       [libzstd >= 1.1],
 914                       have_zstd=yes,
 915                       have_zstd=no)
 916
 917     if test "x$have_zstd" = "xno" ; then
 918         AC_MSG_WARN([Unable to find libzstd.])
 919     fi
 920 fi
 921
 922 if test "x$have_zstd" = "xyes"; then
 923     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
 924     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
 925     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
 926 fi
 927 AC_SUBST(TOR_ZSTD_CFLAGS)
 928 AC_SUBST(TOR_ZSTD_LIBS)
 929
 930 dnl ----------------------------------------------------------------------
 931 dnl Check if libcap is available for capabilities.
 932
 933 tor_cap_pkg_debian="libcap2"
 934 tor_cap_pkg_redhat="libcap"
 935 tor_cap_devpkg_debian="libcap-dev"
 936 tor_cap_devpkg_redhat="libcap-devel"
 937
 938 AC_CHECK_LIB([cap], [cap_init], [],
 939   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 940 )
 941 AC_CHECK_FUNCS(cap_set_proc)
 942
 943 dnl ---------------------------------------------------------------------
 944 dnl Now that we know about our major libraries, we can check for compiler
 945 dnl and linker hardening options.  We need to do this with the libraries known,
 946 dnl since sometimes the linker will like an option but not be willing to
 947 dnl use it with a build of a library.
 948
 949 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 950 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
 951
 952 CFLAGS_FTRAPV=
 953 CFLAGS_FWRAPV=
 954 CFLAGS_ASAN=
 955 CFLAGS_UBSAN=
 956
 957
 958 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 959 #if !defined(__clang__)
 960 #error
 961 #endif])], have_clang=yes, have_clang=no)
 962
 963 if test "x$enable_gcc_hardening" != "xno"; then
 964     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 965     if test "x$have_clang" = "xyes"; then
 966         TOR_CHECK_CFLAGS(-Qunused-arguments)
 967     fi
 968     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 969     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 970     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 971 m4_ifdef([AS_VAR_IF],[
 972     AS_VAR_IF(can_compile, [yes],
 973         AS_VAR_IF(can_link, [yes],
 974                   [],
 975                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 976         )])
 977     AS_VAR_POPDEF([can_link])
 978     AS_VAR_POPDEF([can_compile])
 979     TOR_CHECK_CFLAGS(-Wstack-protector)
 980     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 981     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
 982        TOR_CHECK_CFLAGS(-fPIE)
 983        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 984     fi
 985     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
 986 fi
 987
 988 if test "$fragile_hardening" = "yes"; then
 989     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
 990    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
 991       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
 992    fi
 993
 994    if test "$tor_cv_cflags__ftrapv" != "yes"; then
 995      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
 996    fi
 997
 998    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
 999     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1000       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
1001     fi
1002
1003    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1004     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1005       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
1006     fi
1007
1008 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1009 fi
1010
1011 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1012 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1013
1014 mulodi_fixes_ftrapv=no
1015 if test "$have_clang" = "yes"; then
1016   saved_CFLAGS="$CFLAGS"
1017   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1018   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1019   AC_LINK_IFELSE([
1020       AC_LANG_SOURCE([[
1021           #include <stdint.h>
1022           #include <stdlib.h>
1023           int main(int argc, char **argv)
1024           {
1025             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1026                         * (int64_t)atoi(argv[3]);
1027             return x == 9;
1028           } ]])],
1029           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1030           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1031   if test "$ftrapv_can_link" = "no"; then
1032     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1033     AC_LINK_IFELSE([
1034       AC_LANG_SOURCE([[
1035           #include <stdint.h>
1036           #include <stdlib.h>
1037           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1038              *overflow=0;
1039              return a;
1040           }
1041           int main(int argc, char **argv)
1042           {
1043             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1044                         * (int64_t)atoi(argv[3]);
1045             return x == 9;
1046           } ]])],
1047           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1048           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1049   fi
1050   CFLAGS="$saved_CFLAGS"
1051 fi
1052
1053 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1054
1055 dnl These cflags add bunches of branches, and we haven't been able to
1056 dnl persuade ourselves that they're suitable for code that needs to be
1057 dnl constant time.
1058 AC_SUBST(CFLAGS_BUGTRAP)
1059 dnl These cflags are variant ones sutable for code that needs to be
1060 dnl constant-time.
1061 AC_SUBST(CFLAGS_CONSTTIME)
1062
1063 if test "x$enable_linker_hardening" != "xno"; then
1064     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1065 fi
1066
1067 # For backtrace support
1068 TOR_CHECK_LDFLAGS(-rdynamic)
1069
1070 dnl ------------------------------------------------------
1071 dnl Now see if we have a -fomit-frame-pointer compiler option.
1072
1073 saved_CFLAGS="$CFLAGS"
1074 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1075 F_OMIT_FRAME_POINTER=''
1076 if test "$saved_CFLAGS" != "$CFLAGS"; then
1077   if test "$fragile_hardening" = "yes"; then
1078     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1079   fi
1080 fi
1081 CFLAGS="$saved_CFLAGS"
1082 AC_SUBST(F_OMIT_FRAME_POINTER)
1083
1084 dnl ------------------------------------------------------
1085 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1086 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1087 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1088 dnl code will work.
1089 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1090
1091 dnl ============================================================
1092 dnl Check for libseccomp
1093
1094 if test "x$enable_seccomp" != "xno"; then
1095   AC_CHECK_HEADERS([seccomp.h])
1096   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1097 fi
1098
1099 dnl ============================================================
1100 dnl Check for libscrypt
1101
1102 if test "x$enable_libscrypt" != "xno"; then
1103   AC_CHECK_HEADERS([libscrypt.h])
1104   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1105   AC_CHECK_FUNCS([libscrypt_scrypt])
1106 fi
1107
1108 dnl ============================================================
1109 dnl We need an implementation of curve25519.
1110
1111 dnl set these defaults.
1112 build_curve25519_donna=no
1113 build_curve25519_donna_c64=no
1114 use_curve25519_donna=no
1115 use_curve25519_nacl=no
1116 CURVE25519_LIBS=
1117
1118 dnl The best choice is using curve25519-donna-c64, but that requires
1119 dnl that we
1120 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1121   tor_cv_can_use_curve25519_donna_c64,
1122   [AC_RUN_IFELSE(
1123     [AC_LANG_PROGRAM([dnl
1124       #include <stdint.h>
1125       typedef unsigned uint128_t __attribute__((mode(TI)));
1126   int func(uint64_t a, uint64_t b) {
1127            uint128_t c = ((uint128_t)a) * b;
1128            int ok = ((uint64_t)(c>>96)) == 522859 &&
1129              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1130                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1131                  (((uint64_t)(c))&0xffffffffL) == 0;
1132            return ok;
1133       }
1134   ], [dnl
1135     int ok = func( ((uint64_t)2000000000) * 1000000000,
1136                    ((uint64_t)1234567890) << 24);
1137         return !ok;
1138       ])],
1139   [tor_cv_can_use_curve25519_donna_c64=yes],
1140       [tor_cv_can_use_curve25519_donna_c64=no],
1141   [AC_LINK_IFELSE(
1142         [AC_LANG_PROGRAM([dnl
1143       #include <stdint.h>
1144       typedef unsigned uint128_t __attribute__((mode(TI)));
1145   int func(uint64_t a, uint64_t b) {
1146            uint128_t c = ((uint128_t)a) * b;
1147            int ok = ((uint64_t)(c>>96)) == 522859 &&
1148              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1149                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1150                  (((uint64_t)(c))&0xffffffffL) == 0;
1151            return ok;
1152       }
1153   ], [dnl
1154     int ok = func( ((uint64_t)2000000000) * 1000000000,
1155                  ((uint64_t)1234567890) << 24);
1156         return !ok;
1157       ])],
1158           [tor_cv_can_use_curve25519_donna_c64=cross],
1159       [tor_cv_can_use_curve25519_donna_c64=no])])])
1160
1161 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1162                   nacl/crypto_scalarmult_curve25519.h])
1163
1164 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1165   tor_cv_can_use_curve25519_nacl,
1166   [tor_saved_LIBS="$LIBS"
1167    LIBS="$LIBS -lnacl"
1168    AC_LINK_IFELSE(
1169      [AC_LANG_PROGRAM([dnl
1170        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1171        #include <crypto_scalarmult_curve25519.h>
1172    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1173    #include <nacl/crypto_scalarmult_curve25519.h>
1174    #endif
1175        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1176    #error Hey, this is the reference implementation! That's not fast.
1177    #endif
1178      ], [
1179    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1180      ])], [tor_cv_can_use_curve25519_nacl=yes],
1181      [tor_cv_can_use_curve25519_nacl=no])
1182    LIBS="$tor_saved_LIBS" ])
1183
1184  dnl Okay, now we need to figure out which one to actually use. Fall back
1185  dnl to curve25519-donna.c
1186
1187  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1188    build_curve25519_donna_c64=yes
1189    use_curve25519_donna=yes
1190  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1191    use_curve25519_nacl=yes
1192    CURVE25519_LIBS=-lnacl
1193  else
1194    build_curve25519_donna=yes
1195    use_curve25519_donna=yes
1196  fi
1197
1198 if test "x$use_curve25519_donna" = "xyes"; then
1199   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1200             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1201 fi
1202 if test "x$use_curve25519_nacl" = "xyes"; then
1203   AC_DEFINE(USE_CURVE25519_NACL, 1,
1204             [Defined if we should use a curve25519 from nacl])
1205 fi
1206 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1207   test "x$build_curve25519_donna" = "xyes")
1208 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1209   test "x$build_curve25519_donna_c64" = "xyes")
1210 AC_SUBST(CURVE25519_LIBS)
1211
1212 dnl Make sure to enable support for large off_t if available.
1213 AC_SYS_LARGEFILE
1214
1215 AC_CHECK_HEADERS([assert.h \
1216                   errno.h \
1217                   fcntl.h \
1218                   signal.h \
1219                   string.h \
1220                   sys/capability.h \
1221                   sys/fcntl.h \
1222                   sys/stat.h \
1223                   sys/time.h \
1224                   sys/types.h \
1225                   time.h \
1226                   unistd.h \
1227                   arpa/inet.h \
1228                   crt_externs.h \
1229                   execinfo.h \
1230                   gnu/libc-version.h \
1231                   grp.h \
1232                   ifaddrs.h \
1233                   inttypes.h \
1234                   limits.h \
1235                   linux/types.h \
1236                   machine/limits.h \
1237                   malloc.h \
1238                   malloc/malloc.h \
1239                   malloc_np.h \
1240                   netdb.h \
1241                   netinet/in.h \
1242                   netinet/in6.h \
1243                   pwd.h \
1244                   readpassphrase.h \
1245                   stdint.h \
1246                   sys/eventfd.h \
1247                   sys/file.h \
1248                   sys/ioctl.h \
1249                   sys/limits.h \
1250                   sys/mman.h \
1251                   sys/param.h \
1252                   sys/prctl.h \
1253                   sys/random.h \
1254                   sys/resource.h \
1255                   sys/select.h \
1256                   sys/socket.h \
1257                   sys/statvfs.h \
1258                   sys/syscall.h \
1259                   sys/sysctl.h \
1260                   sys/syslimits.h \
1261                   sys/time.h \
1262                   sys/types.h \
1263                   sys/un.h \
1264                   sys/utime.h \
1265                   sys/wait.h \
1266                   syslog.h \
1267                   utime.h])
1268
1269 AC_CHECK_HEADERS(sys/param.h)
1270
1271 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1272 [#ifdef HAVE_SYS_TYPES_H
1273 #include <sys/types.h>
1274 #endif
1275 #ifdef HAVE_SYS_SOCKET_H
1276 #include <sys/socket.h>
1277 #endif])
1278 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1279 [#ifdef HAVE_SYS_TYPES_H
1280 #include <sys/types.h>
1281 #endif
1282 #ifdef HAVE_SYS_SOCKET_H
1283 #include <sys/socket.h>
1284 #endif
1285 #ifdef HAVE_NET_IF_H
1286 #include <net/if.h>
1287 #endif
1288 #ifdef HAVE_NETINET_IN_H
1289 #include <netinet/in.h>
1290 #endif])
1291
1292 AC_CHECK_HEADERS(linux/if.h,[],[],
1293 [
1294 #ifdef HAVE_SYS_SOCKET_H
1295 #include <sys/socket.h>
1296 #endif
1297 ])
1298
1299 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1300         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1301 [#ifdef HAVE_SYS_TYPES_H
1302 #include <sys/types.h>
1303 #endif
1304 #ifdef HAVE_SYS_SOCKET_H
1305 #include <sys/socket.h>
1306 #endif
1307 #ifdef HAVE_LIMITS_H
1308 #include <limits.h>
1309 #endif
1310 #ifdef HAVE_LINUX_TYPES_H
1311 #include <linux/types.h>
1312 #endif
1313 #ifdef HAVE_NETINET_IN6_H
1314 #include <netinet/in6.h>
1315 #endif
1316 #ifdef HAVE_NETINET_IN_H
1317 #include <netinet/in.h>
1318 #endif])
1319
1320 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1321         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1322 [#ifdef HAVE_SYS_TYPES_H
1323 #include <sys/types.h>
1324 #endif
1325 #ifdef HAVE_SYS_SOCKET_H
1326 #include <sys/socket.h>
1327 #endif
1328 #ifdef HAVE_LIMITS_H
1329 #include <limits.h>
1330 #endif
1331 #ifdef HAVE_LINUX_TYPES_H
1332 #include <linux/types.h>
1333 #endif
1334 #ifdef HAVE_NETINET_IN6_H
1335 #include <netinet/in6.h>
1336 #endif
1337 #ifdef HAVE_NETINET_IN_H
1338 #include <netinet/in.h>
1339 #endif
1340 #ifdef HAVE_LINUX_IF_H
1341 #include <linux/if.h>
1342 #endif])
1343
1344 transparent_ok=0
1345 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1346   transparent_ok=1
1347 fi
1348 if test "x$linux_netfilter_ipv4" = "x1"; then
1349   transparent_ok=1
1350 fi
1351 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1352   transparent_ok=1
1353 fi
1354 if test "x$transparent_ok" = "x1"; then
1355   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1356 else
1357   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1358 fi
1359
1360 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1361 [#ifdef HAVE_SYS_TYPES_H
1362 #include <sys/types.h>
1363 #endif
1364 #ifdef HAVE_SYS_TIME_H
1365 #include <sys/time.h>
1366 #endif])
1367
1368 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1369 dnl Watch out.
1370
1371 AC_CHECK_SIZEOF(int8_t)
1372 AC_CHECK_SIZEOF(int16_t)
1373 AC_CHECK_SIZEOF(int32_t)
1374 AC_CHECK_SIZEOF(int64_t)
1375 AC_CHECK_SIZEOF(uint8_t)
1376 AC_CHECK_SIZEOF(uint16_t)
1377 AC_CHECK_SIZEOF(uint32_t)
1378 AC_CHECK_SIZEOF(uint64_t)
1379 AC_CHECK_SIZEOF(intptr_t)
1380 AC_CHECK_SIZEOF(uintptr_t)
1381
1382 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1383
1384 AC_CHECK_SIZEOF(char)
1385 AC_CHECK_SIZEOF(short)
1386 AC_CHECK_SIZEOF(int)
1387 AC_CHECK_SIZEOF(long)
1388 AC_CHECK_SIZEOF(long long)
1389 AC_CHECK_SIZEOF(__int64)
1390 AC_CHECK_SIZEOF(void *)
1391 AC_CHECK_SIZEOF(time_t)
1392 AC_CHECK_SIZEOF(size_t)
1393 AC_CHECK_SIZEOF(pid_t)
1394
1395 AC_CHECK_TYPES([uint, u_char, ssize_t])
1396
1397 AC_PC_FROM_UCONTEXT([:])
1398
1399 dnl used to include sockaddr_storage, but everybody has that.
1400 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1401 [#ifdef HAVE_SYS_TYPES_H
1402 #include <sys/types.h>
1403 #endif
1404 #ifdef HAVE_NETINET_IN_H
1405 #include <netinet/in.h>
1406 #endif
1407 #ifdef HAVE_NETINET_IN6_H
1408 #include <netinet/in6.h>
1409 #endif
1410 #ifdef HAVE_SYS_SOCKET_H
1411 #include <sys/socket.h>
1412 #endif
1413 #ifdef _WIN32
1414 #define _WIN32_WINNT 0x0501
1415 #define WIN32_LEAN_AND_MEAN
1416 #include <winsock2.h>
1417 #include <ws2tcpip.h>
1418 #endif
1419 ])
1420 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1421 [#ifdef HAVE_SYS_TYPES_H
1422 #include <sys/types.h>
1423 #endif
1424 #ifdef HAVE_NETINET_IN_H
1425 #include <netinet/in.h>
1426 #endif
1427 #ifdef HAVE_NETINET_IN6_H
1428 #include <netinet/in6.h>
1429 #endif
1430 #ifdef HAVE_SYS_SOCKET_H
1431 #include <sys/socket.h>
1432 #endif
1433 #ifdef _WIN32
1434 #define _WIN32_WINNT 0x0501
1435 #define WIN32_LEAN_AND_MEAN
1436 #include <winsock2.h>
1437 #include <ws2tcpip.h>
1438 #endif
1439 ])
1440
1441 AC_CHECK_TYPES([rlim_t], , ,
1442 [#ifdef HAVE_SYS_TYPES_H
1443 #include <sys/types.h>
1444 #endif
1445 #ifdef HAVE_SYS_TIME_H
1446 #include <sys/time.h>
1447 #endif
1448 #ifdef HAVE_SYS_RESOURCE_H
1449 #include <sys/resource.h>
1450 #endif
1451 ])
1452
1453 AX_CHECK_SIGN([time_t],
1454        [ : ],
1455        [ : ], [
1456 #ifdef HAVE_SYS_TYPES_H
1457 #include <sys/types.h>
1458 #endif
1459 #ifdef HAVE_SYS_TIME_H
1460 #include <sys/time.h>
1461 #endif
1462 #ifdef HAVE_TIME_H
1463 #include <time.h>
1464 #endif
1465 ])
1466
1467 if test "$ax_cv_decl_time_t_signed" = "no"; then
1468   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1469 fi
1470
1471 AX_CHECK_SIGN([size_t],
1472        [ tor_cv_size_t_signed=yes ],
1473        [ tor_cv_size_t_signed=no ], [
1474 #ifdef HAVE_SYS_TYPES_H
1475 #include <sys/types.h>
1476 #endif
1477 ])
1478
1479 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1480   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1481 fi
1482
1483 AX_CHECK_SIGN([enum always],
1484        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1485        [ : ], [
1486  enum always { AAA, BBB, CCC };
1487 ])
1488
1489 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1490 #ifdef HAVE_SYS_SOCKET_H
1491 #include <sys/socket.h>
1492 #endif
1493 ])
1494
1495 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1496
1497 AC_CHECK_SIZEOF(cell_t)
1498
1499 # Now make sure that NULL can be represented as zero bytes.
1500 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1501 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1502 [[#include <stdlib.h>
1503 #include <string.h>
1504 #include <stdio.h>
1505 #ifdef HAVE_STDDEF_H
1506 #include <stddef.h>
1507 #endif
1508 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1509 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1510        [tor_cv_null_is_zero=yes],
1511        [tor_cv_null_is_zero=no],
1512        [tor_cv_null_is_zero=cross])])
1513
1514 if test "$tor_cv_null_is_zero" = "cross"; then
1515   # Cross-compiling; let's hope that the target isn't raving mad.
1516   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1517 fi
1518
1519 if test "$tor_cv_null_is_zero" != "no"; then
1520   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1521             [Define to 1 iff memset(0) sets pointers to NULL])
1522 fi
1523
1524 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1525 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1526 [[#include <stdlib.h>
1527 #include <string.h>
1528 #include <stdio.h>
1529 #ifdef HAVE_STDDEF_H
1530 #include <stddef.h>
1531 #endif
1532 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1533 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1534        [tor_cv_dbl0_is_zero=yes],
1535        [tor_cv_dbl0_is_zero=no],
1536        [tor_cv_dbl0_is_zero=cross])])
1537
1538 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1539   # Cross-compiling; let's hope that the target isn't raving mad.
1540   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1541 fi
1542
1543 if test "$tor_cv_dbl0_is_zero" != "no"; then
1544   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1545             [Define to 1 iff memset(0) sets doubles to 0.0])
1546 fi
1547
1548 # And what happens when we malloc zero?
1549 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1550 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1551 [[#include <stdlib.h>
1552 #include <string.h>
1553 #include <stdio.h>
1554 #ifdef HAVE_STDDEF_H
1555 #include <stddef.h>
1556 #endif
1557 int main () { return malloc(0)?0:1; }]])],
1558        [tor_cv_malloc_zero_works=yes],
1559        [tor_cv_malloc_zero_works=no],
1560        [tor_cv_malloc_zero_works=cross])])
1561
1562 if test "$tor_cv_malloc_zero_works" = "cross"; then
1563   # Cross-compiling; let's hope that the target isn't raving mad.
1564   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1565 fi
1566
1567 if test "$tor_cv_malloc_zero_works" = "yes"; then
1568   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1569             [Define to 1 iff malloc(0) returns a pointer])
1570 fi
1571
1572 # whether we seem to be in a 2s-complement world.
1573 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1574 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1575 [[int main () { int problem = ((-99) != (~99)+1);
1576 return problem ? 1 : 0; }]])],
1577        [tor_cv_twos_complement=yes],
1578        [tor_cv_twos_complement=no],
1579        [tor_cv_twos_complement=cross])])
1580
1581 if test "$tor_cv_twos_complement" = "cross"; then
1582   # Cross-compiling; let's hope that the target isn't raving mad.
1583   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1584 fi
1585
1586 if test "$tor_cv_twos_complement" != "no"; then
1587   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1588             [Define to 1 iff we represent negative integers with
1589              two's complement])
1590 fi
1591
1592 # What does shifting a negative value do?
1593 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1594 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1595 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1596        [tor_cv_sign_extend=yes],
1597        [tor_cv_sign_extend=no],
1598        [tor_cv_sign_extend=cross])])
1599
1600 if test "$tor_cv_sign_extend" = "cross"; then
1601   # Cross-compiling; let's hope that the target isn't raving mad.
1602   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1603 fi
1604
1605 if test "$tor_cv_sign_extend" != "no"; then
1606   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1607             [Define to 1 iff right-shifting a negative value performs sign-extension])
1608 fi
1609
1610 # Is uint8_t the same type as unsigned char?
1611 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1612 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1613 #include <stdint.h>
1614 extern uint8_t c;
1615 unsigned char c;]])],
1616        [tor_cv_uint8_uchar=yes],
1617        [tor_cv_uint8_uchar=no],
1618        [tor_cv_uint8_uchar=cross])])
1619
1620 if test "$tor_cv_uint8_uchar" = "cross"; then
1621   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1622 fi
1623
1624 if test "$tor_cv_uint8_uchar" = "no"; then
1625   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1626 fi
1627
1628 # Whether we should use the dmalloc memory allocation debugging library.
1629 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1630 AC_ARG_WITH(dmalloc,
1631 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1632 [if [[ "$withval" = "yes" ]]; then
1633   dmalloc=1
1634   AC_MSG_RESULT(yes)
1635 else
1636   dmalloc=1
1637   AC_MSG_RESULT(no)
1638 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1639 )
1640
1641 if [[ $dmalloc -eq 1 ]]; then
1642   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1643   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1644   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1645   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1646 fi
1647
1648 AC_ARG_WITH(tcmalloc,
1649 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1650 [ tcmalloc=yes ], [ tcmalloc=no ])
1651
1652 if test "x$tcmalloc" = "xyes"; then
1653    LDFLAGS="-ltcmalloc $LDFLAGS"
1654 fi
1655
1656 using_custom_malloc=no
1657 if test "x$enable_openbsd_malloc" = "xyes"; then
1658    using_custom_malloc=yes
1659 fi
1660 if test "x$tcmalloc" = "xyes"; then
1661    using_custom_malloc=yes
1662 fi
1663 if test "$using_custom_malloc" = "no"; then
1664    AC_CHECK_FUNCS(mallinfo)
1665 fi
1666
1667 # By default, we're going to assume we don't have mlockall()
1668 # bionic and other platforms have various broken mlockall subsystems.
1669 # Some systems don't have a working mlockall, some aren't linkable,
1670 # and some have it but don't declare it.
1671 AC_CHECK_FUNCS(mlockall)
1672 AC_CHECK_DECLS([mlockall], , , [
1673 #ifdef HAVE_SYS_MMAN_H
1674 #include <sys/mman.h>
1675 #endif])
1676
1677 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1678 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1679 # using macros
1680 AC_CHECK_DECLS([getpagesize], , , [
1681 #ifdef HAVE_UNISTD_H
1682 #include <unistd.h>
1683 #endif])
1684
1685 # Allow user to specify an alternate syslog facility
1686 AC_ARG_WITH(syslog-facility,
1687 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1688 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1689 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1690 AC_SUBST(LOGFACILITY)
1691
1692 # Check if we have getresuid and getresgid
1693 AC_CHECK_FUNCS(getresuid getresgid)
1694
1695 # Check for gethostbyname_r in all its glorious incompatible versions.
1696 #   (This logic is based on that in Python's configure.in)
1697 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1698   [Define this if you have any gethostbyname_r()])
1699
1700 AC_CHECK_FUNC(gethostbyname_r, [
1701   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1702   OLD_CFLAGS=$CFLAGS
1703   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1704   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1705 #include <netdb.h>
1706   ]], [[
1707     char *cp1, *cp2;
1708     struct hostent *h1, *h2;
1709     int i1, i2;
1710     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1711   ]])],[
1712     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1713     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1714      [Define this if gethostbyname_r takes 6 arguments])
1715     AC_MSG_RESULT(6)
1716   ], [
1717     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1718 #include <netdb.h>
1719     ]], [[
1720       char *cp1, *cp2;
1721       struct hostent *h1;
1722       int i1, i2;
1723       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1724     ]])], [
1725       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1726       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1727         [Define this if gethostbyname_r takes 5 arguments])
1728       AC_MSG_RESULT(5)
1729    ], [
1730       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1731 #include <netdb.h>
1732      ]], [[
1733        char *cp1;
1734        struct hostent *h1;
1735        struct hostent_data hd;
1736        (void) gethostbyname_r(cp1,h1,&hd);
1737      ]])], [
1738        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1739        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1740          [Define this if gethostbyname_r takes 3 arguments])
1741        AC_MSG_RESULT(3)
1742      ], [
1743        AC_MSG_RESULT(0)
1744      ])
1745   ])
1746  ])
1747  CFLAGS=$OLD_CFLAGS
1748 ])
1749
1750 AC_CACHE_CHECK([whether the C compiler supports __func__],
1751   tor_cv_have_func_macro,
1752   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1753 #include <stdio.h>
1754 int main(int c, char **v) { puts(__func__); }])],
1755   tor_cv_have_func_macro=yes,
1756   tor_cv_have_func_macro=no))
1757
1758 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1759   tor_cv_have_FUNC_macro,
1760   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1761 #include <stdio.h>
1762 int main(int c, char **v) { puts(__FUNC__); }])],
1763   tor_cv_have_FUNC_macro=yes,
1764   tor_cv_have_FUNC_macro=no))
1765
1766 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1767   tor_cv_have_FUNCTION_macro,
1768   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1769 #include <stdio.h>
1770 int main(int c, char **v) { puts(__FUNCTION__); }])],
1771   tor_cv_have_FUNCTION_macro=yes,
1772   tor_cv_have_FUNCTION_macro=no))
1773
1774 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1775   tor_cv_have_environ_declared,
1776   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1777 #ifdef HAVE_UNISTD_H
1778 #include <unistd.h>
1779 #endif
1780 #include <stdlib.h>
1781 int main(int c, char **v) { char **t = environ; }])],
1782   tor_cv_have_environ_declared=yes,
1783   tor_cv_have_environ_declared=no))
1784
1785 if test "$tor_cv_have_func_macro" = "yes"; then
1786   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1787 fi
1788
1789 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1790   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1791 fi
1792
1793 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1794   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1795            [Defined if the compiler supports __FUNCTION__])
1796 fi
1797
1798 if test "$tor_cv_have_environ_declared" = "yes"; then
1799   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1800            [Defined if we have extern char **environ already declared])
1801 fi
1802
1803 # $prefix stores the value of the --prefix command line option, or
1804 # NONE if the option wasn't set.  In the case that it wasn't set, make
1805 # it be the default, so that we can use it to expand directories now.
1806 if test "x$prefix" = "xNONE"; then
1807   prefix=$ac_default_prefix
1808 fi
1809
1810 # and similarly for $exec_prefix
1811 if test "x$exec_prefix" = "xNONE"; then
1812   exec_prefix=$prefix
1813 fi
1814
1815 if test "x$BUILDDIR" = "x"; then
1816   BUILDDIR=`pwd`
1817 fi
1818 AC_SUBST(BUILDDIR)
1819 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1820 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1821
1822 if test "x$CONFDIR" = "x"; then
1823   CONFDIR=`eval echo $sysconfdir/tor`
1824 fi
1825 AC_SUBST(CONFDIR)
1826 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1827 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1828
1829 BINDIR=`eval echo $bindir`
1830 AC_SUBST(BINDIR)
1831 LOCALSTATEDIR=`eval echo $localstatedir`
1832 AC_SUBST(LOCALSTATEDIR)
1833
1834 if test "$bwin32" = "true"; then
1835   # Test if the linker supports the --nxcompat and --dynamicbase options
1836   # for Windows
1837   save_LDFLAGS="$LDFLAGS"
1838   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1839   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1840   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1841     [AC_MSG_RESULT([yes])]
1842     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1843     [AC_MSG_RESULT([no])]
1844   )
1845   LDFLAGS="$save_LDFLAGS"
1846 fi
1847
1848 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1849 # than autoconf's macros like.
1850 if test "$GCC" = "yes"; then
1851   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1852   # accident waiting to happen.
1853   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1854 else
1855   # Override optimization level for non-gcc compilers
1856   CFLAGS="$CFLAGS -O"
1857   enable_gcc_warnings=no
1858   enable_gcc_warnings_advisory=no
1859 fi
1860
1861 # Warnings implies advisory-warnings and -Werror.
1862 if test "$enable_gcc_warnings" = "yes"; then
1863   enable_gcc_warnings_advisory=yes
1864   enable_fatal_warnings=yes
1865 fi
1866
1867 # OS X Lion started deprecating the system openssl. Let's just disable
1868 # all deprecation warnings on OS X. Also, to potentially make the binary
1869 # a little smaller, let's enable dead_strip.
1870 case "$host_os" in
1871
1872  darwin*)
1873     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1874     LDFLAGS="$LDFLAGS -dead_strip" ;;
1875 esac
1876
1877 # Add some more warnings which we use in development but not in the
1878 # released versions.  (Some relevant gcc versions can't handle these.)
1879 #
1880 # Note that we have to do this near the end  of the autoconf process, or
1881 # else we may run into problems when these warnings hit on the testing C
1882 # programs that autoconf wants to build.
1883 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1884
1885   case "$host" in
1886     *-*-openbsd* | *-*-bitrig*)
1887       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1888       # That's fine, except that the headers don't pass -Wredundant-decls.
1889       # Therefore, let's disable -Wsystem-headers when we're building
1890       # with maximal warnings on OpenBSD.
1891       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1892   esac
1893
1894   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1895   # have it work better.
1896   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1897
1898   # This warning was added in gcc 4.3, but it appears to generate
1899   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1900   #CFLAGS="$CFLAGS -Wlogical-op"
1901
1902   m4_foreach_w([warning_flag], [
1903      -Waddress
1904      -Waddress-of-array-temporary
1905      -Waddress-of-temporary
1906      -Wambiguous-macro
1907      -Wanonymous-pack-parens
1908      -Warc
1909      -Warc-abi
1910      -Warc-bridge-casts-disallowed-in-nonarc
1911      -Warc-maybe-repeated-use-of-weak
1912      -Warc-performSelector-leaks
1913      -Warc-repeated-use-of-weak
1914      -Warray-bounds
1915      -Warray-bounds-pointer-arithmetic
1916      -Wasm
1917      -Wasm-operand-widths
1918      -Watomic-properties
1919      -Watomic-property-with-user-defined-accessor
1920      -Wauto-import
1921      -Wauto-storage-class
1922      -Wauto-var-id
1923      -Wavailability
1924      -Wbackslash-newline-escape
1925      -Wbad-array-new-length
1926      -Wbind-to-temporary-copy
1927      -Wbitfield-constant-conversion
1928      -Wbool-conversion
1929      -Wbool-conversions
1930      -Wbuiltin-requires-header
1931      -Wchar-align
1932      -Wcompare-distinct-pointer-types
1933      -Wcomplex-component-init
1934      -Wconditional-type-mismatch
1935      -Wconfig-macros
1936      -Wconstant-conversion
1937      -Wconstant-logical-operand
1938      -Wconstexpr-not-const
1939      -Wcustom-atomic-properties
1940      -Wdangling-field
1941      -Wdangling-initializer-list
1942      -Wdate-time
1943      -Wdelegating-ctor-cycles
1944      -Wdeprecated-implementations
1945      -Wdeprecated-register
1946      -Wdirect-ivar-access
1947      -Wdiscard-qual
1948      -Wdistributed-object-modifiers
1949      -Wdivision-by-zero
1950      -Wdollar-in-identifier-extension
1951      -Wdouble-promotion
1952      -Wduplicate-decl-specifier
1953      -Wduplicate-enum
1954      -Wduplicate-method-arg
1955      -Wduplicate-method-match
1956      -Wduplicated-cond
1957      -Wdynamic-class-memaccess
1958      -Wembedded-directive
1959      -Wempty-translation-unit
1960      -Wenum-conversion
1961      -Wexit-time-destructors
1962      -Wexplicit-ownership-type
1963      -Wextern-initializer
1964      -Wextra
1965      -Wextra-semi
1966      -Wextra-tokens
1967      -Wflexible-array-extensions
1968      -Wfloat-conversion
1969      -Wformat-non-iso
1970      -Wfour-char-constants
1971      -Wgcc-compat
1972      -Wglobal-constructors
1973      -Wgnu-array-member-paren-init
1974      -Wgnu-designator
1975      -Wgnu-static-float-init
1976      -Wheader-guard
1977      -Wheader-hygiene
1978      -Widiomatic-parentheses
1979      -Wignored-attributes
1980      -Wimplicit-atomic-properties
1981      -Wimplicit-conversion-floating-point-to-bool
1982      -Wimplicit-exception-spec-mismatch
1983      -Wimplicit-fallthrough
1984      -Wimplicit-fallthrough-per-function
1985      -Wimplicit-retain-self
1986      -Wimport-preprocessor-directive-pedantic
1987      -Wincompatible-library-redeclaration
1988      -Wincompatible-pointer-types-discards-qualifiers
1989      -Wincomplete-implementation
1990      -Wincomplete-module
1991      -Wincomplete-umbrella
1992      -Winit-self
1993      -Wint-conversions
1994      -Wint-to-void-pointer-cast
1995      -Winteger-overflow
1996      -Winvalid-constexpr
1997      -Winvalid-iboutlet
1998      -Winvalid-noreturn
1999      -Winvalid-pp-token
2000      -Winvalid-source-encoding
2001      -Winvalid-token-paste
2002      -Wknr-promoted-parameter
2003      -Wlanguage-extension-token
2004      -Wlarge-by-value-copy
2005      -Wliteral-conversion
2006      -Wliteral-range
2007      -Wlocal-type-template-args
2008      -Wlogical-op
2009      -Wloop-analysis
2010      -Wmain-return-type
2011      -Wmalformed-warning-check
2012      -Wmethod-signatures
2013      -Wmicrosoft
2014      -Wmicrosoft-exists
2015      -Wmismatched-parameter-types
2016      -Wmismatched-return-types
2017      -Wmissing-field-initializers
2018      -Wmissing-format-attribute
2019      -Wmissing-noreturn
2020      -Wmissing-selector-name
2021      -Wmissing-sysroot
2022      -Wmissing-variable-declarations
2023      -Wmodule-conflict
2024      -Wnested-anon-types
2025      -Wnewline-eof
2026      -Wnon-literal-null-conversion
2027      -Wnon-pod-varargs
2028      -Wnonportable-cfstrings
2029      -Wnormalized=id
2030      -Wnull-arithmetic
2031      -Wnull-character
2032      -Wnull-conversion
2033      -Wnull-dereference
2034      -Wout-of-line-declaration
2035      -Wover-aligned
2036      -Woverlength-strings
2037      -Woverride-init
2038      -Woverriding-method-mismatch
2039      -Wpointer-type-mismatch
2040      -Wpredefined-identifier-outside-function
2041      -Wprotocol-property-synthesis-ambiguity
2042      -Wreadonly-iboutlet-property
2043      -Wreadonly-setter-attrs
2044      -Wreceiver-expr
2045      -Wreceiver-forward-class
2046      -Wreceiver-is-weak
2047      -Wreinterpret-base-class
2048      -Wrequires-super-attribute
2049      -Wreserved-user-defined-literal
2050      -Wreturn-stack-address
2051      -Wsection
2052      -Wselector-type-mismatch
2053      -Wsentinel
2054      -Wserialized-diagnostics
2055      -Wshadow
2056      -Wshift-count-negative
2057      -Wshift-count-overflow
2058      -Wshift-negative-value
2059      -Wshift-overflow=2
2060      -Wshift-sign-overflow
2061      -Wshorten-64-to-32
2062      -Wsizeof-array-argument
2063      -Wsource-uses-openmp
2064      -Wstatic-float-init
2065      -Wstatic-in-inline
2066      -Wstatic-local-in-inline
2067      -Wstrict-overflow=1
2068      -Wstring-compare
2069      -Wstring-conversion
2070      -Wstrlcpy-strlcat-size
2071      -Wstrncat-size
2072      -Wsuggest-attribute=format
2073      -Wsuggest-attribute=noreturn
2074      -Wsuper-class-method-mismatch
2075      -Wswitch-bool
2076      -Wsync-nand
2077      -Wtautological-constant-out-of-range-compare
2078      -Wtentative-definition-incomplete-type
2079      -Wtrampolines
2080      -Wtype-safety
2081      -Wtypedef-redefinition
2082      -Wtypename-missing
2083      -Wundefined-inline
2084      -Wundefined-internal
2085      -Wundefined-reinterpret-cast
2086      -Wunicode
2087      -Wunicode-whitespace
2088      -Wunknown-warning-option
2089      -Wunnamed-type-template-args
2090      -Wunneeded-member-function
2091      -Wunsequenced
2092      -Wunsupported-visibility
2093      -Wunused-but-set-parameter
2094      -Wunused-but-set-variable
2095      -Wunused-command-line-argument
2096      -Wunused-const-variable=2
2097      -Wunused-exception-parameter
2098      -Wunused-local-typedefs
2099      -Wunused-member-function
2100      -Wunused-sanitize-argument
2101      -Wunused-volatile-lvalue
2102      -Wuser-defined-literals
2103      -Wvariadic-macros
2104      -Wvector-conversion
2105      -Wvector-conversions
2106      -Wvexing-parse
2107      -Wvisibility
2108      -Wvla-extension
2109      -Wzero-length-array
2110   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
2111
2112 dnl    We should re-enable this in some later version.  Clang doesn't
2113 dnl    mind, but it causes trouble with GCC.
2114 dnl     -Wstrict-overflow=2
2115
2116 dnl    These seem to require annotations that we don't currently use,
2117 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2118 dnl     -Wthread-safety
2119 dnl     -Wthread-safety-analysis
2120 dnl     -Wthread-safety-attributes
2121 dnl     -Wthread-safety-beta
2122 dnl     -Wthread-safety-precise
2123
2124   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2125   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2126   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2127   CFLAGS="$CFLAGS -Wwrite-strings"
2128   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2129   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
2130   CFLAGS="$CFLAGS -Wunused-parameter "
2131   # These interfere with building main() { return 0; }, which autoconf
2132   # likes to use as its default program.
2133   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
2134
2135   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2136     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2137   fi
2138   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2139     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2140   fi
2141
2142   if test "x$enable_fatal_warnings" = "xyes"; then
2143     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2144     # default autoconf programs are full of errors.
2145     CFLAGS="$CFLAGS -Werror"
2146   fi
2147
2148 fi
2149
2150 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2151    case "$host_os" in
2152     darwin*)
2153       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2154    esac
2155 fi
2156
2157 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2158
2159 AC_CONFIG_FILES([
2160         Doxyfile
2161         Makefile
2162         contrib/dist/suse/tor.sh
2163         contrib/operator-tools/tor.logrotate
2164         contrib/dist/tor.sh
2165         contrib/dist/torctl
2166         contrib/dist/tor.service
2167         src/config/torrc.sample
2168         src/config/torrc.minimal
2169         src/rust/.cargo/config
2170         scripts/maint/checkOptionDocs.pl
2171         scripts/maint/updateVersions.pl
2172 ])
2173
2174 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2175   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2176   for file in $regular_mans ; do
2177     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2178       echo "==================================";
2179       echo;
2180       echo "Building Tor has failed since manpages cannot be built.";
2181       echo;
2182       echo "You need asciidoc installed to be able to build the manpages.";
2183       echo "To build without manpages, use the --disable-asciidoc argument";
2184       echo "when calling configure.";
2185       echo;
2186       echo "==================================";
2187       exit 1;
2188     fi
2189   done
2190 fi
2191
2192 if test "$fragile_hardening" = "yes"; then
2193   AC_MSG_WARN([
2194
2195 ============
2196 Warning!  Building Tor with --enable-fragile-hardening (also known as
2197 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2198 other kinds of attacks easier. A Tor instance build with this option will be
2199 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2200 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2201 denial of service attacks. For more information, see
2202 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2203 ============
2204   ])
2205 fi
2206
2207 AC_OUTPUT