configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2017, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.3.0-alpha-dev])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56 AC_ARG_ENABLE(memory-sentinels,
  57    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  58 AC_ARG_ENABLE(rust,
  59    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  60 AC_ARG_ENABLE(cargo-online-mode,
  61    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  62
  63 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  64     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  65 fi
  66
  67 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  68 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  69 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  70 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  71 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  72 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  73
  74 if test "$enable_static_tor" = "yes"; then
  75   enable_static_libevent="yes";
  76   enable_static_openssl="yes";
  77   enable_static_zlib="yes";
  78   CFLAGS="$CFLAGS -static"
  79 fi
  80
  81 if test "$enable_system_torrc" = "no"; then
  82   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  83             [Defined if we're not going to look for a torrc in SYSCONF])
  84 fi
  85
  86 if test "$enable_memory_sentinels" = "no"; then
  87   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  88            [Defined if we're turning off memory safety code to look for bugs])
  89 fi
  90
  91 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  92
  93 AC_ARG_ENABLE(asciidoc,
  94      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  95      [case "${enableval}" in
  96         "yes") asciidoc=true ;;
  97         "no")  asciidoc=false ;;
  98         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  99       esac], [asciidoc=true])
 100
 101 # systemd notify support
 102 AC_ARG_ENABLE(systemd,
 103       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 104       [case "${enableval}" in
 105         "yes") systemd=true ;;
 106         "no")  systemd=false ;;
 107         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 108       esac], [systemd=auto])
 109
 110
 111
 112 # systemd support
 113 if test "x$enable_systemd" = "xno"; then
 114     have_systemd=no;
 115 else
 116     PKG_CHECK_MODULES(SYSTEMD,
 117         [libsystemd-daemon],
 118         have_systemd=yes,
 119         have_systemd=no)
 120     if test "x$have_systemd" = "xno"; then
 121         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 122         PKG_CHECK_MODULES(SYSTEMD,
 123             [libsystemd],
 124             have_systemd=yes,
 125             have_systemd=no)
 126     fi
 127 fi
 128
 129 if test "x$have_systemd" = "xyes"; then
 130     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 131     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 132     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 133     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 134          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 135 fi
 136 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 137 AC_SUBST(TOR_SYSTEMD_LIBS)
 138
 139 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 140     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 141 fi
 142
 143 case "$host" in
 144    *-*-solaris* )
 145      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 146      ;;
 147 esac
 148
 149 AC_ARG_ENABLE(gcc-warnings,
 150      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 151 AC_ARG_ENABLE(fatal-warnings,
 152      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 153 AC_ARG_ENABLE(gcc-warnings-advisory,
 154      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 155
 156 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 157 AC_ARG_ENABLE(gcc-hardening,
 158     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 159
 160 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 161 AC_ARG_ENABLE(expensive-hardening,
 162     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 163 AC_ARG_ENABLE(fragile-hardening,
 164     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 165 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 166   fragile_hardening="yes"
 167 fi
 168
 169 dnl Linker hardening options
 170 dnl Currently these options are ELF specific - you can't use this with MacOSX
 171 AC_ARG_ENABLE(linker-hardening,
 172     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 173
 174 AC_ARG_ENABLE(local-appdata,
 175    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 176 if test "$enable_local_appdata" = "yes"; then
 177   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 178             [Defined if we default to host local appdata paths on Windows])
 179 fi
 180
 181 # Tor2web mode flag
 182 AC_ARG_ENABLE(tor2web-mode,
 183      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 184 [if test "x$enableval" = "xyes"; then
 185     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 186 fi])
 187
 188 AC_ARG_ENABLE(tool-name-check,
 189      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 190
 191 AC_ARG_ENABLE(seccomp,
 192      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 193
 194 AC_ARG_ENABLE(libscrypt,
 195      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 196
 197 dnl Enable event tracing which are transformed to debug log statement.
 198 AC_ARG_ENABLE(event-tracing-debug,
 199      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 200 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 201
 202 if test x$enable_event_tracing_debug = xyes; then
 203   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 204   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 205 fi
 206
 207 dnl Enable Android only features.
 208 AC_ARG_ENABLE(android,
 209      AS_HELP_STRING(--enable-android, [build with Android features enabled]))
 210 AM_CONDITIONAL([USE_ANDROID], [test "x$enable_android" = "xyes"])
 211
 212 if test "x$enable_android" = "xyes"; then
 213   AC_DEFINE([USE_ANDROID], [1], [Compile with Android specific features enabled])
 214
 215   dnl Check if the Android log library is available.
 216   AC_CHECK_HEADERS([android/log.h])
 217   AC_SEARCH_LIBS(__android_log_write, [log])
 218
 219 fi
 220
 221 dnl check for the correct "ar" when cross-compiling.
 222 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 223 dnl    so kludge up a replacement for the case where it isn't there yet.)
 224 m4_ifdef([AM_PROG_AR],
 225          [AM_PROG_AR],
 226          [AN_MAKEVAR([AR], [AC_PROG_AR])
 227           AN_PROGRAM([ar], [AC_PROG_AR])
 228           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 229           AC_PROG_AR])
 230
 231 dnl Check whether the above macro has settled for a simply named tool even
 232 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 233 dnl because that will find any cc on the system, not only the cross-compiler,
 234 dnl and then verify that a binary built with this compiler runs on the
 235 dnl build system. It will then come to the false conclusion that we're not
 236 dnl cross-compiling.
 237 if test "x$enable_tool_name_check" != "xno"; then
 238     if test "x$ac_tool_warned" = "xyes"; then
 239         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 240         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 241                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 242         fi
 243 fi
 244
 245 AC_PROG_CC
 246 AC_PROG_CPP
 247 AC_PROG_MAKE_SET
 248 AC_PROG_RANLIB
 249 AC_PROG_SED
 250
 251 AC_ARG_VAR([PERL], [path to Perl binary])
 252 AC_CHECK_PROGS([PERL], [perl])
 253 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 254
 255 dnl check for asciidoc and a2x
 256 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 257 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 258
 259 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 260
 261 AM_PROG_CC_C_O
 262 AC_PROG_CC_C99
 263
 264 AC_ARG_VAR([PYTHON], [path to Python binary])
 265 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 266 if test "x$PYTHON" = "x"; then
 267   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 268 fi
 269 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 270
 271 dnl List all external rust crates we depend on here. Include the version
 272 rust_crates="libc-0.2.22"
 273 AC_SUBST(rust_crates)
 274
 275 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 276 AC_C_FLEXIBLE_ARRAY_MEMBER
 277 ], [
 278  dnl Maybe we've got an old autoconf...
 279  AC_CACHE_CHECK([for flexible array members],
 280      tor_cv_c_flexarray,
 281      [AC_COMPILE_IFELSE(
 282        AC_LANG_PROGRAM([
 283  struct abc { int a; char b[]; };
 284 ], [
 285  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 286  def->b[0] = 33;
 287 ]),
 288   [tor_cv_c_flexarray=yes],
 289   [tor_cv_c_flexarray=no])])
 290  if test "$tor_cv_flexarray" = "yes"; then
 291    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 292  else
 293    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 294  fi
 295 ])
 296
 297 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 298       tor_cv_c_c99_decl,
 299       [AC_COMPILE_IFELSE(
 300          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 301          [tor_cv_c_c99_decl=yes],
 302          [tor_cv_c_c99_decl=no] )])
 303 if test "$tor_cv_c_c99_decl" != "yes"; then
 304   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 305 fi
 306
 307 AC_CACHE_CHECK([for working C99 designated initializers],
 308       tor_cv_c_c99_designated_init,
 309       [AC_COMPILE_IFELSE(
 310          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 311                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 312          [tor_cv_c_c99_designated_init=yes],
 313          [tor_cv_c_c99_designated_init=no] )])
 314
 315 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 316   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 317 fi
 318
 319 TORUSER=_tor
 320 AC_ARG_WITH(tor-user,
 321         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 322         [
 323            TORUSER=$withval
 324         ]
 325 )
 326 AC_SUBST(TORUSER)
 327
 328 TORGROUP=_tor
 329 AC_ARG_WITH(tor-group,
 330         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 331         [
 332            TORGROUP=$withval
 333         ]
 334 )
 335 AC_SUBST(TORGROUP)
 336
 337
 338 dnl If _WIN32 is defined and non-zero, we are building for win32
 339 AC_MSG_CHECKING([for win32])
 340 AC_RUN_IFELSE([AC_LANG_SOURCE([
 341 int main(int c, char **v) {
 342 #ifdef _WIN32
 343 #if _WIN32
 344   return 0;
 345 #else
 346   return 1;
 347 #endif
 348 #else
 349   return 2;
 350 #endif
 351 }])],
 352 bwin32=true; AC_MSG_RESULT([yes]),
 353 bwin32=false; AC_MSG_RESULT([no]),
 354 bwin32=cross; AC_MSG_RESULT([cross])
 355 )
 356
 357 if test "$bwin32" = "cross"; then
 358 AC_MSG_CHECKING([for win32 (cross)])
 359 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 360 #ifdef _WIN32
 361 int main(int c, char **v) {return 0;}
 362 #else
 363 #error
 364 int main(int c, char **v) {return x(y);}
 365 #endif
 366 ])],
 367 bwin32=true; AC_MSG_RESULT([yes]),
 368 bwin32=false; AC_MSG_RESULT([no]))
 369 fi
 370
 371 AH_BOTTOM([
 372 #ifdef _WIN32
 373 /* Defined to access windows functions and definitions for >=WinXP */
 374 # ifndef WINVER
 375 #  define WINVER 0x0501
 376 # endif
 377
 378 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 379 # ifndef _WIN32_WINNT
 380 #  define _WIN32_WINNT 0x0501
 381 # endif
 382
 383 /* Defined to avoid including some windows headers as part of Windows.h */
 384 # ifndef WIN32_LEAN_AND_MEAN
 385 #  define WIN32_LEAN_AND_MEAN 1
 386 # endif
 387 #endif
 388 ])
 389
 390
 391 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 392 AM_CONDITIONAL(BUILD_LIBTORRUNNER, test "x$bwin32" != "xtrue")
 393
 394 dnl Enable C99 when compiling with MIPSpro
 395 AC_MSG_CHECKING([for MIPSpro compiler])
 396 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 397 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 398 #error
 399   return x(y);
 400 #endif
 401 ])],
 402 bmipspro=false; AC_MSG_RESULT(no),
 403 bmipspro=true; AC_MSG_RESULT(yes))
 404
 405 if test "$bmipspro" = "true"; then
 406   CFLAGS="$CFLAGS -c99"
 407 fi
 408
 409 AC_C_BIGENDIAN
 410
 411 if test "x$enable_rust" = "xyes"; then
 412   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 413   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 414   if test "x$RUSTC" = "xno"; then
 415     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 416   fi
 417
 418   AC_ARG_VAR([CARGO], [path to the cargo binary])
 419   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 420   if test "x$CARGO" = "xno"; then
 421     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 422   fi
 423
 424   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 425   if test "x$enable_cargo_online_mode" = "xyes"; then
 426     CARGO_ONLINE=
 427     RUST_DL=#
 428   else
 429     CARGO_ONLINE=--frozen
 430     RUST_DL=
 431
 432     dnl When we're not allowed to touch the network, we need crate dependencies
 433     dnl locally available.
 434     AC_MSG_CHECKING([rust crate dependencies])
 435     AC_ARG_VAR([TOR_RUST_DEPENDENCIES], [path to directory with local crate mirror])
 436     if test "x$TOR_RUST_DEPENDENCIES" = "x"; then
 437       TOR_RUST_DEPENDENCIES="$srcdir/src/ext/rust/"
 438       NEED_MOD=1
 439     fi
 440     if test ! -d "$TOR_RUST_DEPENDENCIES"; then
 441       AC_MSG_ERROR([Rust dependency directory $TOR_RUST_DEPENDENCIES does not exist. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 442       ERRORED=1
 443     fi
 444     for dep in $rust_crates; do
 445       if test ! -d "$TOR_RUST_DEPENDENCIES"/"$dep"; then
 446         AC_MSG_ERROR([Failure to find rust dependency $TOR_RUST_DEPENDENCIES/$dep. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 447         ERRORED=1
 448       fi
 449     done
 450     if test "x$NEED_MOD" = "x1"; then
 451       dnl When looking for dependencies from cargo, pick right directory
 452       TOR_RUST_DEPENDENCIES="../../src/ext/rust"
 453     fi
 454     if test "x$ERRORED" = "x"; then
 455       AC_MSG_RESULT([yes])
 456     fi
 457   fi
 458
 459   dnl For now both MSVC and MinGW rust libraries will output static libs with
 460   dnl the MSVC naming convention.
 461   if test "$bwin32" = "true"; then
 462     TOR_RUST_STATIC_NAME=tor_rust.lib
 463   else
 464     TOR_RUST_STATIC_NAME=libtor_rust.a
 465   fi
 466
 467   AC_SUBST(TOR_RUST_STATIC_NAME)
 468   AC_SUBST(CARGO_ONLINE)
 469   AC_SUBST(RUST_DL)
 470
 471   dnl Let's check the rustc version, too
 472   AC_MSG_CHECKING([rust version])
 473   RUSTC_VERSION=`$RUSTC --version`
 474   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 475   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 476   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 477     AC_MSG_ERROR([rustc version couldn't be identified])
 478   fi
 479   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 480     AC_MSG_ERROR([rustc must be at least version 1.14])
 481   fi
 482   AC_MSG_RESULT([$RUSTC_VERSION])
 483 fi
 484
 485 AC_SEARCH_LIBS(socket, [socket network])
 486 AC_SEARCH_LIBS(gethostbyname, [nsl])
 487 AC_SEARCH_LIBS(dlopen, [dl])
 488 AC_SEARCH_LIBS(inet_aton, [resolv])
 489 AC_SEARCH_LIBS(backtrace, [execinfo])
 490 saved_LIBS="$LIBS"
 491 AC_SEARCH_LIBS([clock_gettime], [rt])
 492 if test "$LIBS" != "$saved_LIBS"; then
 493    # Looks like we need -lrt for clock_gettime().
 494    have_rt=yes
 495 fi
 496
 497 AC_SEARCH_LIBS(pthread_create, [pthread])
 498 AC_SEARCH_LIBS(pthread_detach, [pthread])
 499
 500 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 501 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 502
 503 AC_CHECK_FUNCS(
 504         _NSGetEnviron \
 505         RtlSecureZeroMemory \
 506         SecureZeroMemory \
 507         accept4 \
 508         backtrace \
 509         backtrace_symbols_fd \
 510         eventfd \
 511         explicit_bzero \
 512         timingsafe_memcmp \
 513         flock \
 514         ftime \
 515         get_current_dir_name \
 516         getaddrinfo \
 517         getifaddrs \
 518         getpass \
 519         getrlimit \
 520         gettimeofday \
 521         gmtime_r \
 522         gnu_get_libc_version \
 523         htonll \
 524         inet_aton \
 525         ioctl \
 526         issetugid \
 527         llround \
 528         localtime_r \
 529         lround \
 530         mach_approximate_time \
 531         memmem \
 532         memset_s \
 533         pipe \
 534         pipe2 \
 535         prctl \
 536         readpassphrase \
 537         rint \
 538         sigaction \
 539         socketpair \
 540         statvfs \
 541         strlcat \
 542         strlcpy \
 543         strnlen \
 544         strptime \
 545         strtok_r \
 546         strtoull \
 547         sysconf \
 548         sysctl \
 549         truncate \
 550         uname \
 551         usleep \
 552         vasprintf \
 553         _vscprintf
 554 )
 555
 556 # Apple messed up when they added two functions functions in Sierra: they
 557 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 558 # checks. So we should only probe for those functions if we are sure that we
 559 # are not targetting OSX 10.11 or earlier.
 560 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 561 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 562 #ifdef __APPLE__
 563 #  include <AvailabilityMacros.h>
 564 #  ifndef MAC_OS_X_VERSION_10_12
 565 #    define MAC_OS_X_VERSION_10_12 101200
 566 #  endif
 567 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 568 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 569 #      error "Running on Mac OSX 10.11 or earlier"
 570 #    endif
 571 #  endif
 572 #endif
 573 ]], [[]])],
 574    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 575    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 576
 577 if test "$on_macos_pre_10_12" = "no"; then
 578   AC_CHECK_FUNCS(
 579         clock_gettime \
 580         getentropy \
 581   )
 582 fi
 583
 584 if test "$bwin32" != "true"; then
 585   AC_CHECK_HEADERS(pthread.h)
 586   AC_CHECK_FUNCS(pthread_create)
 587   AC_CHECK_FUNCS(pthread_condattr_setclock)
 588 fi
 589
 590 if test "$bwin32" = "true"; then
 591   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 592 #include <windows.h>
 593 #include <conio.h>
 594 #include <wchar.h>
 595                  ])
 596 fi
 597
 598 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 599   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 600
 601 dnl ------------------------------------------------------
 602 dnl Where do you live, libevent?  And how do we call you?
 603
 604 if test "$bwin32" = "true"; then
 605   TOR_LIB_WS32=-lws2_32
 606   TOR_LIB_IPHLPAPI=-liphlpapi
 607   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 608   # think it's actually necessary.
 609   TOR_LIB_GDI=-lgdi32
 610   TOR_LIB_USERENV=-luserenv
 611 else
 612   TOR_LIB_WS32=
 613   TOR_LIB_GDI=
 614   TOR_LIB_USERENV=
 615 fi
 616 AC_SUBST(TOR_LIB_WS32)
 617 AC_SUBST(TOR_LIB_GDI)
 618 AC_SUBST(TOR_LIB_IPHLPAPI)
 619 AC_SUBST(TOR_LIB_USERENV)
 620
 621 tor_libevent_pkg_redhat="libevent"
 622 tor_libevent_pkg_debian="libevent-dev"
 623 tor_libevent_devpkg_redhat="libevent-devel"
 624 tor_libevent_devpkg_debian="libevent-dev"
 625
 626 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 627 dnl linking for static builds.
 628 STATIC_LIBEVENT_FLAGS=""
 629 if test "$enable_static_libevent" = "yes"; then
 630     if test "$have_rt" = "yes"; then
 631       STATIC_LIBEVENT_FLAGS=" -lrt "
 632     fi
 633 fi
 634
 635 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 636 #ifdef _WIN32
 637 #include <winsock2.h>
 638 #endif
 639 #include <sys/time.h>
 640 #include <sys/types.h>
 641 #include <event2/event.h>], [
 642 #ifdef _WIN32
 643 #include <winsock2.h>
 644 #endif
 645 struct event_base;
 646 struct event_base *event_base_new(void);],
 647     [
 648 #ifdef _WIN32
 649 {WSADATA d; WSAStartup(0x101,&d); }
 650 #endif
 651 event_base_free(event_base_new());
 652 ], [--with-libevent-dir], [/opt/libevent])
 653
 654 dnl Determine the incantation needed to link libevent.
 655 save_LIBS="$LIBS"
 656 save_LDFLAGS="$LDFLAGS"
 657 save_CPPFLAGS="$CPPFLAGS"
 658
 659 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 660 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 661 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 662
 663 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 664
 665 if test "$enable_static_libevent" = "yes"; then
 666    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 667      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 668    else
 669      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 670    fi
 671 else
 672      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 673        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 674        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 675
 676        if test "$ac_cv_search_event_new" != "none required"; then
 677          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 678        fi
 679        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 680          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 681        fi
 682      else
 683        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 684      fi
 685 fi
 686
 687 dnl Now check for particular libevent functions.
 688 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 689                 evutil_secure_rng_add_bytes \
 690 ])
 691
 692 LIBS="$save_LIBS"
 693 LDFLAGS="$save_LDFLAGS"
 694 CPPFLAGS="$save_CPPFLAGS"
 695
 696 dnl Check that libevent is at least at version 2.0.10, the first stable
 697 dnl release of its series
 698 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 699 AC_MSG_CHECKING([whether Libevent is new enough])
 700 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 701 #include <event2/event.h>
 702 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 703 #error
 704 int x = y(zz);
 705 #else
 706 int x = 1;
 707 #endif
 708 ])], [ AC_MSG_RESULT([yes]) ],
 709    [ AC_MSG_RESULT([no])
 710      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 711
 712 LIBS="$save_LIBS"
 713 LDFLAGS="$save_LDFLAGS"
 714 CPPFLAGS="$save_CPPFLAGS"
 715
 716 AC_SUBST(TOR_LIBEVENT_LIBS)
 717
 718 dnl ------------------------------------------------------
 719 dnl Where do you live, libm?
 720
 721 dnl On some platforms (Haiku/BeOS) the math library is
 722 dnl part of libroot. In which case don't link against lm
 723 TOR_LIB_MATH=""
 724 save_LIBS="$LIBS"
 725 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 726 if test "$ac_cv_search_pow" != "none required"; then
 727     TOR_LIB_MATH="$ac_cv_search_pow"
 728 fi
 729 LIBS="$save_LIBS"
 730 AC_SUBST(TOR_LIB_MATH)
 731
 732 dnl ------------------------------------------------------
 733 dnl Where do you live, openssl?  And how do we call you?
 734
 735 tor_openssl_pkg_redhat="openssl"
 736 tor_openssl_pkg_debian="libssl-dev"
 737 tor_openssl_devpkg_redhat="openssl-devel"
 738 tor_openssl_devpkg_debian="libssl-dev"
 739
 740 ALT_openssl_WITHVAL=""
 741 AC_ARG_WITH(ssl-dir,
 742   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 743   [
 744       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 745          ALT_openssl_WITHVAL="$withval"
 746       fi
 747   ])
 748
 749 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 750 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 751     [#include <openssl/ssl.h>],
 752     [struct ssl_method_st; const struct ssl_method_st *TLSv1_1_method(void);],
 753     [TLSv1_1_method();], [],
 754     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /opt/openssl])
 755
 756 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 757
 758 if test "$enable_static_openssl" = "yes"; then
 759    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 760      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 761    else
 762      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 763    fi
 764 else
 765      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 766 fi
 767 AC_SUBST(TOR_OPENSSL_LIBS)
 768
 769 dnl Now check for particular openssl functions.
 770 save_LIBS="$LIBS"
 771 save_LDFLAGS="$LDFLAGS"
 772 save_CPPFLAGS="$CPPFLAGS"
 773 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 774 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 775 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 776
 777 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 778 #include <openssl/opensslv.h>
 779 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 780 #error "too old"
 781 #endif
 782    ]], [[]])],
 783    [ : ],
 784    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 785
 786 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 787 #include <openssl/opensslv.h>
 788 #include <openssl/evp.h>
 789 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 790 #error "no ECC"
 791 #endif
 792 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 793 #error "curves unavailable"
 794 #endif
 795    ]], [[]])],
 796    [ : ],
 797    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 798
 799 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 800 [#include <openssl/ssl.h>
 801 ])
 802
 803 AC_CHECK_FUNCS([ \
 804                 SSL_SESSION_get_master_key \
 805                 SSL_get_server_random \
 806                 SSL_get_client_ciphers \
 807                 SSL_get_client_random \
 808                 SSL_CIPHER_find \
 809                 TLS_method
 810                ])
 811
 812 dnl Check if OpenSSL has scrypt implementation.
 813 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 814
 815 dnl Check if OpenSSL structures are opaque
 816 AC_CHECK_MEMBERS([SSL.state], , ,
 817 [#include <openssl/ssl.h>
 818 ])
 819
 820 dnl Define the set of checks for KIST scheduler support.
 821 AC_DEFUN([CHECK_KIST_SUPPORT],[
 822   dnl KIST needs struct tcp_info and for certain members to exist.
 823   AC_CHECK_MEMBERS(
 824     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
 825     , ,[[#include <netinet/tcp.h>]])
 826   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
 827   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 828                      #include <linux/sockios.h>
 829                      #ifndef SIOCOUTQNSD
 830                      #error
 831                      #endif
 832                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
 833   if test "x$have_siocoutqnsd" = "xyes"; then
 834     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
 835       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
 836         have_kist_support=yes
 837       fi
 838     fi
 839   fi
 840 ])
 841 dnl Now, trigger the check.
 842 CHECK_KIST_SUPPORT
 843 AS_IF([test "x$have_kist_support" = "xyes"],
 844       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
 845                                         on this system])],
 846       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
 847
 848 LIBS="$save_LIBS"
 849 LDFLAGS="$save_LDFLAGS"
 850 CPPFLAGS="$save_CPPFLAGS"
 851
 852 dnl ------------------------------------------------------
 853 dnl Where do you live, zlib?  And how do we call you?
 854
 855 tor_zlib_pkg_redhat="zlib"
 856 tor_zlib_pkg_debian="zlib1g"
 857 tor_zlib_devpkg_redhat="zlib-devel"
 858 tor_zlib_devpkg_debian="zlib1g-dev"
 859
 860 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 861     [#include <zlib.h>],
 862     [const char * zlibVersion(void);],
 863     [zlibVersion();], [--with-zlib-dir],
 864     [/opt/zlib])
 865
 866 if test "$enable_static_zlib" = "yes"; then
 867    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 868      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 869  using --enable-static-zlib")
 870    else
 871      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 872    fi
 873 else
 874      TOR_ZLIB_LIBS="-lz"
 875 fi
 876 AC_SUBST(TOR_ZLIB_LIBS)
 877
 878 dnl ------------------------------------------------------
 879 dnl Where we do we find lzma?
 880
 881 AC_ARG_ENABLE(lzma,
 882       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
 883       [case "${enableval}" in
 884         "yes") lzma=true ;;
 885         "no")  lzma=false ;;
 886         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
 887       esac], [lzma=auto])
 888
 889 if test "x$enable_lzma" = "xno"; then
 890     have_lzma=no;
 891 else
 892     PKG_CHECK_MODULES([LZMA],
 893                       [liblzma],
 894                       have_lzma=yes,
 895                       have_lzma=no)
 896
 897     if test "x$have_lzma" = "xno" ; then
 898         AC_MSG_WARN([Unable to find liblzma.])
 899     fi
 900 fi
 901
 902 if test "x$have_lzma" = "xyes"; then
 903     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
 904     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
 905     TOR_LZMA_LIBS="${LZMA_LIBS}"
 906 fi
 907 AC_SUBST(TOR_LZMA_CFLAGS)
 908 AC_SUBST(TOR_LZMA_LIBS)
 909
 910 dnl ------------------------------------------------------
 911 dnl Where we do we find zstd?
 912
 913 AC_ARG_ENABLE(zstd,
 914       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
 915       [case "${enableval}" in
 916         "yes") zstd=true ;;
 917         "no")  zstd=false ;;
 918         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
 919       esac], [zstd=auto])
 920
 921 if test "x$enable_zstd" = "xno"; then
 922     have_zstd=no;
 923 else
 924     PKG_CHECK_MODULES([ZSTD],
 925                       [libzstd >= 1.1],
 926                       have_zstd=yes,
 927                       have_zstd=no)
 928
 929     if test "x$have_zstd" = "xno" ; then
 930         AC_MSG_WARN([Unable to find libzstd.])
 931     fi
 932 fi
 933
 934 if test "x$have_zstd" = "xyes"; then
 935     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
 936     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
 937     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
 938 fi
 939 AC_SUBST(TOR_ZSTD_CFLAGS)
 940 AC_SUBST(TOR_ZSTD_LIBS)
 941
 942 dnl ----------------------------------------------------------------------
 943 dnl Check if libcap is available for capabilities.
 944
 945 tor_cap_pkg_debian="libcap2"
 946 tor_cap_pkg_redhat="libcap"
 947 tor_cap_devpkg_debian="libcap-dev"
 948 tor_cap_devpkg_redhat="libcap-devel"
 949
 950 AC_CHECK_LIB([cap], [cap_init], [],
 951   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 952 )
 953 AC_CHECK_FUNCS(cap_set_proc)
 954
 955 dnl ---------------------------------------------------------------------
 956 dnl Now that we know about our major libraries, we can check for compiler
 957 dnl and linker hardening options.  We need to do this with the libraries known,
 958 dnl since sometimes the linker will like an option but not be willing to
 959 dnl use it with a build of a library.
 960
 961 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 962 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
 963
 964 CFLAGS_FTRAPV=
 965 CFLAGS_FWRAPV=
 966 CFLAGS_ASAN=
 967 CFLAGS_UBSAN=
 968
 969
 970 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 971 #if !defined(__clang__)
 972 #error
 973 #endif])], have_clang=yes, have_clang=no)
 974
 975 if test "x$enable_gcc_hardening" != "xno"; then
 976     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 977     if test "x$have_clang" = "xyes"; then
 978         TOR_CHECK_CFLAGS(-Qunused-arguments)
 979     fi
 980     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 981     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 982     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 983 m4_ifdef([AS_VAR_IF],[
 984     AS_VAR_IF(can_compile, [yes],
 985         AS_VAR_IF(can_link, [yes],
 986                   [],
 987                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 988         )])
 989     AS_VAR_POPDEF([can_link])
 990     AS_VAR_POPDEF([can_compile])
 991     TOR_CHECK_CFLAGS(-Wstack-protector)
 992     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 993     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
 994        TOR_CHECK_CFLAGS(-fPIE)
 995        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 996     fi
 997     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
 998 fi
 999
1000 if test "$fragile_hardening" = "yes"; then
1001     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
1002    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
1003       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
1004    fi
1005
1006    if test "$tor_cv_cflags__ftrapv" != "yes"; then
1007      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
1008    fi
1009
1010    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
1011     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1012       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.*, and with Clang you need libclang_rt.ubsan*])
1013     fi
1014
1015    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1016     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1017       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1018     fi
1019
1020 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1021 fi
1022
1023 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1024 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1025
1026 mulodi_fixes_ftrapv=no
1027 if test "$have_clang" = "yes"; then
1028   saved_CFLAGS="$CFLAGS"
1029   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1030   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1031   AC_LINK_IFELSE([
1032       AC_LANG_SOURCE([[
1033           #include <stdint.h>
1034           #include <stdlib.h>
1035           int main(int argc, char **argv)
1036           {
1037             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1038                         * (int64_t)atoi(argv[3]);
1039             return x == 9;
1040           } ]])],
1041           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1042           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1043   if test "$ftrapv_can_link" = "no"; then
1044     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1045     AC_LINK_IFELSE([
1046       AC_LANG_SOURCE([[
1047           #include <stdint.h>
1048           #include <stdlib.h>
1049           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1050              *overflow=0;
1051              return a;
1052           }
1053           int main(int argc, char **argv)
1054           {
1055             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1056                         * (int64_t)atoi(argv[3]);
1057             return x == 9;
1058           } ]])],
1059           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1060           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1061   fi
1062   CFLAGS="$saved_CFLAGS"
1063 fi
1064
1065 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1066
1067 dnl These cflags add bunches of branches, and we haven't been able to
1068 dnl persuade ourselves that they're suitable for code that needs to be
1069 dnl constant time.
1070 AC_SUBST(CFLAGS_BUGTRAP)
1071 dnl These cflags are variant ones sutable for code that needs to be
1072 dnl constant-time.
1073 AC_SUBST(CFLAGS_CONSTTIME)
1074
1075 if test "x$enable_linker_hardening" != "xno"; then
1076     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1077 fi
1078
1079 # For backtrace support
1080 TOR_CHECK_LDFLAGS(-rdynamic)
1081
1082 dnl ------------------------------------------------------
1083 dnl Now see if we have a -fomit-frame-pointer compiler option.
1084
1085 saved_CFLAGS="$CFLAGS"
1086 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1087 F_OMIT_FRAME_POINTER=''
1088 if test "$saved_CFLAGS" != "$CFLAGS"; then
1089   if test "$fragile_hardening" = "yes"; then
1090     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1091   fi
1092 fi
1093 CFLAGS="$saved_CFLAGS"
1094 AC_SUBST(F_OMIT_FRAME_POINTER)
1095
1096 dnl ------------------------------------------------------
1097 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1098 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1099 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1100 dnl code will work.
1101 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1102
1103 dnl ============================================================
1104 dnl Check for libseccomp
1105
1106 if test "x$enable_seccomp" != "xno"; then
1107   AC_CHECK_HEADERS([seccomp.h])
1108   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1109 fi
1110
1111 dnl ============================================================
1112 dnl Check for libscrypt
1113
1114 if test "x$enable_libscrypt" != "xno"; then
1115   AC_CHECK_HEADERS([libscrypt.h])
1116   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1117   AC_CHECK_FUNCS([libscrypt_scrypt])
1118 fi
1119
1120 dnl ============================================================
1121 dnl We need an implementation of curve25519.
1122
1123 dnl set these defaults.
1124 build_curve25519_donna=no
1125 build_curve25519_donna_c64=no
1126 use_curve25519_donna=no
1127 use_curve25519_nacl=no
1128 CURVE25519_LIBS=
1129
1130 dnl The best choice is using curve25519-donna-c64, but that requires
1131 dnl that we
1132 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1133   tor_cv_can_use_curve25519_donna_c64,
1134   [AC_RUN_IFELSE(
1135     [AC_LANG_PROGRAM([dnl
1136       #include <stdint.h>
1137       typedef unsigned uint128_t __attribute__((mode(TI)));
1138   int func(uint64_t a, uint64_t b) {
1139            uint128_t c = ((uint128_t)a) * b;
1140            int ok = ((uint64_t)(c>>96)) == 522859 &&
1141              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1142                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1143                  (((uint64_t)(c))&0xffffffffL) == 0;
1144            return ok;
1145       }
1146   ], [dnl
1147     int ok = func( ((uint64_t)2000000000) * 1000000000,
1148                    ((uint64_t)1234567890) << 24);
1149         return !ok;
1150       ])],
1151   [tor_cv_can_use_curve25519_donna_c64=yes],
1152       [tor_cv_can_use_curve25519_donna_c64=no],
1153   [AC_LINK_IFELSE(
1154         [AC_LANG_PROGRAM([dnl
1155       #include <stdint.h>
1156       typedef unsigned uint128_t __attribute__((mode(TI)));
1157   int func(uint64_t a, uint64_t b) {
1158            uint128_t c = ((uint128_t)a) * b;
1159            int ok = ((uint64_t)(c>>96)) == 522859 &&
1160              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1161                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1162                  (((uint64_t)(c))&0xffffffffL) == 0;
1163            return ok;
1164       }
1165   ], [dnl
1166     int ok = func( ((uint64_t)2000000000) * 1000000000,
1167                  ((uint64_t)1234567890) << 24);
1168         return !ok;
1169       ])],
1170           [tor_cv_can_use_curve25519_donna_c64=cross],
1171       [tor_cv_can_use_curve25519_donna_c64=no])])])
1172
1173 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1174                   nacl/crypto_scalarmult_curve25519.h])
1175
1176 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1177   tor_cv_can_use_curve25519_nacl,
1178   [tor_saved_LIBS="$LIBS"
1179    LIBS="$LIBS -lnacl"
1180    AC_LINK_IFELSE(
1181      [AC_LANG_PROGRAM([dnl
1182        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1183        #include <crypto_scalarmult_curve25519.h>
1184    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1185    #include <nacl/crypto_scalarmult_curve25519.h>
1186    #endif
1187        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1188    #error Hey, this is the reference implementation! That's not fast.
1189    #endif
1190      ], [
1191    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1192      ])], [tor_cv_can_use_curve25519_nacl=yes],
1193      [tor_cv_can_use_curve25519_nacl=no])
1194    LIBS="$tor_saved_LIBS" ])
1195
1196  dnl Okay, now we need to figure out which one to actually use. Fall back
1197  dnl to curve25519-donna.c
1198
1199  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1200    build_curve25519_donna_c64=yes
1201    use_curve25519_donna=yes
1202  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1203    use_curve25519_nacl=yes
1204    CURVE25519_LIBS=-lnacl
1205  else
1206    build_curve25519_donna=yes
1207    use_curve25519_donna=yes
1208  fi
1209
1210 if test "x$use_curve25519_donna" = "xyes"; then
1211   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1212             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1213 fi
1214 if test "x$use_curve25519_nacl" = "xyes"; then
1215   AC_DEFINE(USE_CURVE25519_NACL, 1,
1216             [Defined if we should use a curve25519 from nacl])
1217 fi
1218 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1219   test "x$build_curve25519_donna" = "xyes")
1220 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1221   test "x$build_curve25519_donna_c64" = "xyes")
1222 AC_SUBST(CURVE25519_LIBS)
1223
1224 dnl Make sure to enable support for large off_t if available.
1225 AC_SYS_LARGEFILE
1226
1227 AC_CHECK_HEADERS([assert.h \
1228                   errno.h \
1229                   fcntl.h \
1230                   signal.h \
1231                   string.h \
1232                   sys/capability.h \
1233                   sys/fcntl.h \
1234                   sys/stat.h \
1235                   sys/time.h \
1236                   sys/types.h \
1237                   time.h \
1238                   unistd.h \
1239                   arpa/inet.h \
1240                   crt_externs.h \
1241                   execinfo.h \
1242                   gnu/libc-version.h \
1243                   grp.h \
1244                   ifaddrs.h \
1245                   inttypes.h \
1246                   limits.h \
1247                   linux/types.h \
1248                   machine/limits.h \
1249                   malloc.h \
1250                   malloc/malloc.h \
1251                   malloc_np.h \
1252                   netdb.h \
1253                   netinet/in.h \
1254                   netinet/in6.h \
1255                   pwd.h \
1256                   readpassphrase.h \
1257                   stdint.h \
1258                   stdatomic.h \
1259                   sys/eventfd.h \
1260                   sys/file.h \
1261                   sys/ioctl.h \
1262                   sys/limits.h \
1263                   sys/mman.h \
1264                   sys/param.h \
1265                   sys/prctl.h \
1266                   sys/random.h \
1267                   sys/resource.h \
1268                   sys/select.h \
1269                   sys/socket.h \
1270                   sys/statvfs.h \
1271                   sys/syscall.h \
1272                   sys/sysctl.h \
1273                   sys/syslimits.h \
1274                   sys/time.h \
1275                   sys/types.h \
1276                   sys/un.h \
1277                   sys/utime.h \
1278                   sys/wait.h \
1279                   syslog.h \
1280                   utime.h])
1281
1282 AC_CHECK_HEADERS(sys/param.h)
1283
1284 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1285 [#ifdef HAVE_SYS_TYPES_H
1286 #include <sys/types.h>
1287 #endif
1288 #ifdef HAVE_SYS_SOCKET_H
1289 #include <sys/socket.h>
1290 #endif])
1291 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1292 [#ifdef HAVE_SYS_TYPES_H
1293 #include <sys/types.h>
1294 #endif
1295 #ifdef HAVE_SYS_SOCKET_H
1296 #include <sys/socket.h>
1297 #endif
1298 #ifdef HAVE_NET_IF_H
1299 #include <net/if.h>
1300 #endif
1301 #ifdef HAVE_NETINET_IN_H
1302 #include <netinet/in.h>
1303 #endif])
1304
1305 AC_CHECK_HEADERS(linux/if.h,[],[],
1306 [
1307 #ifdef HAVE_SYS_SOCKET_H
1308 #include <sys/socket.h>
1309 #endif
1310 ])
1311
1312 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1313         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1314 [#ifdef HAVE_SYS_TYPES_H
1315 #include <sys/types.h>
1316 #endif
1317 #ifdef HAVE_SYS_SOCKET_H
1318 #include <sys/socket.h>
1319 #endif
1320 #ifdef HAVE_LIMITS_H
1321 #include <limits.h>
1322 #endif
1323 #ifdef HAVE_LINUX_TYPES_H
1324 #include <linux/types.h>
1325 #endif
1326 #ifdef HAVE_NETINET_IN6_H
1327 #include <netinet/in6.h>
1328 #endif
1329 #ifdef HAVE_NETINET_IN_H
1330 #include <netinet/in.h>
1331 #endif])
1332
1333 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1334         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1335 [#ifdef HAVE_SYS_TYPES_H
1336 #include <sys/types.h>
1337 #endif
1338 #ifdef HAVE_SYS_SOCKET_H
1339 #include <sys/socket.h>
1340 #endif
1341 #ifdef HAVE_LIMITS_H
1342 #include <limits.h>
1343 #endif
1344 #ifdef HAVE_LINUX_TYPES_H
1345 #include <linux/types.h>
1346 #endif
1347 #ifdef HAVE_NETINET_IN6_H
1348 #include <netinet/in6.h>
1349 #endif
1350 #ifdef HAVE_NETINET_IN_H
1351 #include <netinet/in.h>
1352 #endif
1353 #ifdef HAVE_LINUX_IF_H
1354 #include <linux/if.h>
1355 #endif])
1356
1357 transparent_ok=0
1358 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1359   transparent_ok=1
1360 fi
1361 if test "x$linux_netfilter_ipv4" = "x1"; then
1362   transparent_ok=1
1363 fi
1364 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1365   transparent_ok=1
1366 fi
1367 if test "x$transparent_ok" = "x1"; then
1368   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1369 else
1370   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1371 fi
1372
1373 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1374 [#ifdef HAVE_SYS_TYPES_H
1375 #include <sys/types.h>
1376 #endif
1377 #ifdef HAVE_SYS_TIME_H
1378 #include <sys/time.h>
1379 #endif])
1380
1381 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1382 dnl Watch out.
1383
1384 AC_CHECK_SIZEOF(int8_t)
1385 AC_CHECK_SIZEOF(int16_t)
1386 AC_CHECK_SIZEOF(int32_t)
1387 AC_CHECK_SIZEOF(int64_t)
1388 AC_CHECK_SIZEOF(uint8_t)
1389 AC_CHECK_SIZEOF(uint16_t)
1390 AC_CHECK_SIZEOF(uint32_t)
1391 AC_CHECK_SIZEOF(uint64_t)
1392 AC_CHECK_SIZEOF(intptr_t)
1393 AC_CHECK_SIZEOF(uintptr_t)
1394
1395 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1396
1397 AC_CHECK_SIZEOF(char)
1398 AC_CHECK_SIZEOF(short)
1399 AC_CHECK_SIZEOF(int)
1400 AC_CHECK_SIZEOF(long)
1401 AC_CHECK_SIZEOF(long long)
1402 AC_CHECK_SIZEOF(__int64)
1403 AC_CHECK_SIZEOF(void *)
1404 AC_CHECK_SIZEOF(time_t)
1405 AC_CHECK_SIZEOF(size_t)
1406 AC_CHECK_SIZEOF(pid_t)
1407
1408 AC_CHECK_TYPES([uint, u_char, ssize_t])
1409
1410 AC_PC_FROM_UCONTEXT([:])
1411
1412 dnl used to include sockaddr_storage, but everybody has that.
1413 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1414 [#ifdef HAVE_SYS_TYPES_H
1415 #include <sys/types.h>
1416 #endif
1417 #ifdef HAVE_NETINET_IN_H
1418 #include <netinet/in.h>
1419 #endif
1420 #ifdef HAVE_NETINET_IN6_H
1421 #include <netinet/in6.h>
1422 #endif
1423 #ifdef HAVE_SYS_SOCKET_H
1424 #include <sys/socket.h>
1425 #endif
1426 #ifdef _WIN32
1427 #define _WIN32_WINNT 0x0501
1428 #define WIN32_LEAN_AND_MEAN
1429 #include <winsock2.h>
1430 #include <ws2tcpip.h>
1431 #endif
1432 ])
1433 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1434 [#ifdef HAVE_SYS_TYPES_H
1435 #include <sys/types.h>
1436 #endif
1437 #ifdef HAVE_NETINET_IN_H
1438 #include <netinet/in.h>
1439 #endif
1440 #ifdef HAVE_NETINET_IN6_H
1441 #include <netinet/in6.h>
1442 #endif
1443 #ifdef HAVE_SYS_SOCKET_H
1444 #include <sys/socket.h>
1445 #endif
1446 #ifdef _WIN32
1447 #define _WIN32_WINNT 0x0501
1448 #define WIN32_LEAN_AND_MEAN
1449 #include <winsock2.h>
1450 #include <ws2tcpip.h>
1451 #endif
1452 ])
1453
1454 AC_CHECK_TYPES([rlim_t], , ,
1455 [#ifdef HAVE_SYS_TYPES_H
1456 #include <sys/types.h>
1457 #endif
1458 #ifdef HAVE_SYS_TIME_H
1459 #include <sys/time.h>
1460 #endif
1461 #ifdef HAVE_SYS_RESOURCE_H
1462 #include <sys/resource.h>
1463 #endif
1464 ])
1465
1466 AX_CHECK_SIGN([time_t],
1467        [ : ],
1468        [ : ], [
1469 #ifdef HAVE_SYS_TYPES_H
1470 #include <sys/types.h>
1471 #endif
1472 #ifdef HAVE_SYS_TIME_H
1473 #include <sys/time.h>
1474 #endif
1475 #ifdef HAVE_TIME_H
1476 #include <time.h>
1477 #endif
1478 ])
1479
1480 if test "$ax_cv_decl_time_t_signed" = "no"; then
1481   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1482 fi
1483
1484 AX_CHECK_SIGN([size_t],
1485        [ tor_cv_size_t_signed=yes ],
1486        [ tor_cv_size_t_signed=no ], [
1487 #ifdef HAVE_SYS_TYPES_H
1488 #include <sys/types.h>
1489 #endif
1490 ])
1491
1492 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1493   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1494 fi
1495
1496 AX_CHECK_SIGN([enum always],
1497        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1498        [ : ], [
1499  enum always { AAA, BBB, CCC };
1500 ])
1501
1502 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1503 #ifdef HAVE_SYS_SOCKET_H
1504 #include <sys/socket.h>
1505 #endif
1506 ])
1507
1508 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1509
1510 AC_CHECK_SIZEOF(cell_t)
1511
1512 # Now make sure that NULL can be represented as zero bytes.
1513 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1514 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1515 [[#include <stdlib.h>
1516 #include <string.h>
1517 #include <stdio.h>
1518 #ifdef HAVE_STDDEF_H
1519 #include <stddef.h>
1520 #endif
1521 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1522 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1523        [tor_cv_null_is_zero=yes],
1524        [tor_cv_null_is_zero=no],
1525        [tor_cv_null_is_zero=cross])])
1526
1527 if test "$tor_cv_null_is_zero" = "cross"; then
1528   # Cross-compiling; let's hope that the target isn't raving mad.
1529   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1530 fi
1531
1532 if test "$tor_cv_null_is_zero" != "no"; then
1533   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1534             [Define to 1 iff memset(0) sets pointers to NULL])
1535 fi
1536
1537 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1538 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1539 [[#include <stdlib.h>
1540 #include <string.h>
1541 #include <stdio.h>
1542 #ifdef HAVE_STDDEF_H
1543 #include <stddef.h>
1544 #endif
1545 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1546 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1547        [tor_cv_dbl0_is_zero=yes],
1548        [tor_cv_dbl0_is_zero=no],
1549        [tor_cv_dbl0_is_zero=cross])])
1550
1551 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1552   # Cross-compiling; let's hope that the target isn't raving mad.
1553   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1554 fi
1555
1556 if test "$tor_cv_dbl0_is_zero" != "no"; then
1557   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1558             [Define to 1 iff memset(0) sets doubles to 0.0])
1559 fi
1560
1561 # And what happens when we malloc zero?
1562 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1563 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1564 [[#include <stdlib.h>
1565 #include <string.h>
1566 #include <stdio.h>
1567 #ifdef HAVE_STDDEF_H
1568 #include <stddef.h>
1569 #endif
1570 int main () { return malloc(0)?0:1; }]])],
1571        [tor_cv_malloc_zero_works=yes],
1572        [tor_cv_malloc_zero_works=no],
1573        [tor_cv_malloc_zero_works=cross])])
1574
1575 if test "$tor_cv_malloc_zero_works" = "cross"; then
1576   # Cross-compiling; let's hope that the target isn't raving mad.
1577   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1578 fi
1579
1580 if test "$tor_cv_malloc_zero_works" = "yes"; then
1581   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1582             [Define to 1 iff malloc(0) returns a pointer])
1583 fi
1584
1585 # whether we seem to be in a 2s-complement world.
1586 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1587 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1588 [[int main () { int problem = ((-99) != (~99)+1);
1589 return problem ? 1 : 0; }]])],
1590        [tor_cv_twos_complement=yes],
1591        [tor_cv_twos_complement=no],
1592        [tor_cv_twos_complement=cross])])
1593
1594 if test "$tor_cv_twos_complement" = "cross"; then
1595   # Cross-compiling; let's hope that the target isn't raving mad.
1596   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1597 fi
1598
1599 if test "$tor_cv_twos_complement" != "no"; then
1600   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1601             [Define to 1 iff we represent negative integers with
1602              two's complement])
1603 fi
1604
1605 # What does shifting a negative value do?
1606 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1607 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1608 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1609        [tor_cv_sign_extend=yes],
1610        [tor_cv_sign_extend=no],
1611        [tor_cv_sign_extend=cross])])
1612
1613 if test "$tor_cv_sign_extend" = "cross"; then
1614   # Cross-compiling; let's hope that the target isn't raving mad.
1615   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1616 fi
1617
1618 if test "$tor_cv_sign_extend" != "no"; then
1619   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1620             [Define to 1 iff right-shifting a negative value performs sign-extension])
1621 fi
1622
1623 # Is uint8_t the same type as unsigned char?
1624 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1625 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1626 #include <stdint.h>
1627 extern uint8_t c;
1628 unsigned char c;]])],
1629        [tor_cv_uint8_uchar=yes],
1630        [tor_cv_uint8_uchar=no],
1631        [tor_cv_uint8_uchar=cross])])
1632
1633 if test "$tor_cv_uint8_uchar" = "cross"; then
1634   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1635 fi
1636
1637 if test "$tor_cv_uint8_uchar" = "no"; then
1638   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1639 fi
1640
1641 # Whether we should use the dmalloc memory allocation debugging library.
1642 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1643 AC_ARG_WITH(dmalloc,
1644 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1645 [if [[ "$withval" = "yes" ]]; then
1646   dmalloc=1
1647   AC_MSG_RESULT(yes)
1648 else
1649   dmalloc=1
1650   AC_MSG_RESULT(no)
1651 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1652 )
1653
1654 if [[ $dmalloc -eq 1 ]]; then
1655   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1656   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1657   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1658   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1659 fi
1660
1661 AC_ARG_WITH(tcmalloc,
1662 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1663 [ tcmalloc=yes ], [ tcmalloc=no ])
1664
1665 if test "x$tcmalloc" = "xyes"; then
1666    LDFLAGS="-ltcmalloc $LDFLAGS"
1667 fi
1668
1669 using_custom_malloc=no
1670 if test "x$enable_openbsd_malloc" = "xyes"; then
1671    using_custom_malloc=yes
1672 fi
1673 if test "x$tcmalloc" = "xyes"; then
1674    using_custom_malloc=yes
1675 fi
1676 if test "$using_custom_malloc" = "no"; then
1677    AC_CHECK_FUNCS(mallinfo)
1678 fi
1679
1680 # By default, we're going to assume we don't have mlockall()
1681 # bionic and other platforms have various broken mlockall subsystems.
1682 # Some systems don't have a working mlockall, some aren't linkable,
1683 # and some have it but don't declare it.
1684 AC_CHECK_FUNCS(mlockall)
1685 AC_CHECK_DECLS([mlockall], , , [
1686 #ifdef HAVE_SYS_MMAN_H
1687 #include <sys/mman.h>
1688 #endif])
1689
1690 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1691 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1692 # using macros
1693 AC_CHECK_DECLS([getpagesize], , , [
1694 #ifdef HAVE_UNISTD_H
1695 #include <unistd.h>
1696 #endif])
1697
1698 # Allow user to specify an alternate syslog facility
1699 AC_ARG_WITH(syslog-facility,
1700 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1701 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1702 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1703 AC_SUBST(LOGFACILITY)
1704
1705 # Check if we have getresuid and getresgid
1706 AC_CHECK_FUNCS(getresuid getresgid)
1707
1708 # Check for gethostbyname_r in all its glorious incompatible versions.
1709 #   (This logic is based on that in Python's configure.in)
1710 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1711   [Define this if you have any gethostbyname_r()])
1712
1713 AC_CHECK_FUNC(gethostbyname_r, [
1714   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1715   OLD_CFLAGS=$CFLAGS
1716   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1717   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1718 #include <netdb.h>
1719   ]], [[
1720     char *cp1, *cp2;
1721     struct hostent *h1, *h2;
1722     int i1, i2;
1723     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1724   ]])],[
1725     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1726     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1727      [Define this if gethostbyname_r takes 6 arguments])
1728     AC_MSG_RESULT(6)
1729   ], [
1730     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1731 #include <netdb.h>
1732     ]], [[
1733       char *cp1, *cp2;
1734       struct hostent *h1;
1735       int i1, i2;
1736       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1737     ]])], [
1738       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1739       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1740         [Define this if gethostbyname_r takes 5 arguments])
1741       AC_MSG_RESULT(5)
1742    ], [
1743       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1744 #include <netdb.h>
1745      ]], [[
1746        char *cp1;
1747        struct hostent *h1;
1748        struct hostent_data hd;
1749        (void) gethostbyname_r(cp1,h1,&hd);
1750      ]])], [
1751        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1752        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1753          [Define this if gethostbyname_r takes 3 arguments])
1754        AC_MSG_RESULT(3)
1755      ], [
1756        AC_MSG_RESULT(0)
1757      ])
1758   ])
1759  ])
1760  CFLAGS=$OLD_CFLAGS
1761 ])
1762
1763 AC_CACHE_CHECK([whether the C compiler supports __func__],
1764   tor_cv_have_func_macro,
1765   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1766 #include <stdio.h>
1767 int main(int c, char **v) { puts(__func__); }])],
1768   tor_cv_have_func_macro=yes,
1769   tor_cv_have_func_macro=no))
1770
1771 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1772   tor_cv_have_FUNC_macro,
1773   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1774 #include <stdio.h>
1775 int main(int c, char **v) { puts(__FUNC__); }])],
1776   tor_cv_have_FUNC_macro=yes,
1777   tor_cv_have_FUNC_macro=no))
1778
1779 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1780   tor_cv_have_FUNCTION_macro,
1781   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1782 #include <stdio.h>
1783 int main(int c, char **v) { puts(__FUNCTION__); }])],
1784   tor_cv_have_FUNCTION_macro=yes,
1785   tor_cv_have_FUNCTION_macro=no))
1786
1787 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1788   tor_cv_have_environ_declared,
1789   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1790 #ifdef HAVE_UNISTD_H
1791 #include <unistd.h>
1792 #endif
1793 #include <stdlib.h>
1794 int main(int c, char **v) { char **t = environ; }])],
1795   tor_cv_have_environ_declared=yes,
1796   tor_cv_have_environ_declared=no))
1797
1798 if test "$tor_cv_have_func_macro" = "yes"; then
1799   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1800 fi
1801
1802 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1803   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1804 fi
1805
1806 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1807   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1808            [Defined if the compiler supports __FUNCTION__])
1809 fi
1810
1811 if test "$tor_cv_have_environ_declared" = "yes"; then
1812   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1813            [Defined if we have extern char **environ already declared])
1814 fi
1815
1816 # $prefix stores the value of the --prefix command line option, or
1817 # NONE if the option wasn't set.  In the case that it wasn't set, make
1818 # it be the default, so that we can use it to expand directories now.
1819 if test "x$prefix" = "xNONE"; then
1820   prefix=$ac_default_prefix
1821 fi
1822
1823 # and similarly for $exec_prefix
1824 if test "x$exec_prefix" = "xNONE"; then
1825   exec_prefix=$prefix
1826 fi
1827
1828 if test "x$BUILDDIR" = "x"; then
1829   BUILDDIR=`pwd`
1830 fi
1831 AC_SUBST(BUILDDIR)
1832 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1833 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1834
1835 if test "x$CONFDIR" = "x"; then
1836   CONFDIR=`eval echo $sysconfdir/tor`
1837 fi
1838 AC_SUBST(CONFDIR)
1839 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1840 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1841
1842 BINDIR=`eval echo $bindir`
1843 AC_SUBST(BINDIR)
1844 LOCALSTATEDIR=`eval echo $localstatedir`
1845 AC_SUBST(LOCALSTATEDIR)
1846
1847 if test "$bwin32" = "true"; then
1848   # Test if the linker supports the --nxcompat and --dynamicbase options
1849   # for Windows
1850   save_LDFLAGS="$LDFLAGS"
1851   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1852   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1853   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1854     [AC_MSG_RESULT([yes])]
1855     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1856     [AC_MSG_RESULT([no])]
1857   )
1858   LDFLAGS="$save_LDFLAGS"
1859 fi
1860
1861 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1862 # than autoconf's macros like.
1863 if test "$GCC" = "yes"; then
1864   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1865   # accident waiting to happen.
1866   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1867 else
1868   # Override optimization level for non-gcc compilers
1869   CFLAGS="$CFLAGS -O"
1870   enable_gcc_warnings=no
1871   enable_gcc_warnings_advisory=no
1872 fi
1873
1874 # Warnings implies advisory-warnings and -Werror.
1875 if test "$enable_gcc_warnings" = "yes"; then
1876   enable_gcc_warnings_advisory=yes
1877   enable_fatal_warnings=yes
1878 fi
1879
1880 # OS X Lion started deprecating the system openssl. Let's just disable
1881 # all deprecation warnings on OS X. Also, to potentially make the binary
1882 # a little smaller, let's enable dead_strip.
1883 case "$host_os" in
1884
1885  darwin*)
1886     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1887     LDFLAGS="$LDFLAGS -dead_strip" ;;
1888 esac
1889
1890 # Add some more warnings which we use in development but not in the
1891 # released versions.  (Some relevant gcc versions can't handle these.)
1892 #
1893 # Note that we have to do this near the end  of the autoconf process, or
1894 # else we may run into problems when these warnings hit on the testing C
1895 # programs that autoconf wants to build.
1896 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1897
1898   case "$host" in
1899     *-*-openbsd* | *-*-bitrig*)
1900       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1901       # That's fine, except that the headers don't pass -Wredundant-decls.
1902       # Therefore, let's disable -Wsystem-headers when we're building
1903       # with maximal warnings on OpenBSD.
1904       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1905   esac
1906
1907   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1908   # have it work better.
1909   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1910
1911   # This warning was added in gcc 4.3, but it appears to generate
1912   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1913   #CFLAGS="$CFLAGS -Wlogical-op"
1914
1915   m4_foreach_w([warning_flag], [
1916      -Waddress
1917      -Waddress-of-array-temporary
1918      -Waddress-of-temporary
1919      -Wambiguous-macro
1920      -Wanonymous-pack-parens
1921      -Warc
1922      -Warc-abi
1923      -Warc-bridge-casts-disallowed-in-nonarc
1924      -Warc-maybe-repeated-use-of-weak
1925      -Warc-performSelector-leaks
1926      -Warc-repeated-use-of-weak
1927      -Warray-bounds
1928      -Warray-bounds-pointer-arithmetic
1929      -Wasm
1930      -Wasm-operand-widths
1931      -Watomic-properties
1932      -Watomic-property-with-user-defined-accessor
1933      -Wauto-import
1934      -Wauto-storage-class
1935      -Wauto-var-id
1936      -Wavailability
1937      -Wbackslash-newline-escape
1938      -Wbad-array-new-length
1939      -Wbind-to-temporary-copy
1940      -Wbitfield-constant-conversion
1941      -Wbool-conversion
1942      -Wbool-conversions
1943      -Wbuiltin-requires-header
1944      -Wchar-align
1945      -Wcompare-distinct-pointer-types
1946      -Wcomplex-component-init
1947      -Wconditional-type-mismatch
1948      -Wconfig-macros
1949      -Wconstant-conversion
1950      -Wconstant-logical-operand
1951      -Wconstexpr-not-const
1952      -Wcustom-atomic-properties
1953      -Wdangling-field
1954      -Wdangling-initializer-list
1955      -Wdate-time
1956      -Wdelegating-ctor-cycles
1957      -Wdeprecated-implementations
1958      -Wdeprecated-register
1959      -Wdirect-ivar-access
1960      -Wdiscard-qual
1961      -Wdistributed-object-modifiers
1962      -Wdivision-by-zero
1963      -Wdollar-in-identifier-extension
1964      -Wdouble-promotion
1965      -Wduplicate-decl-specifier
1966      -Wduplicate-enum
1967      -Wduplicate-method-arg
1968      -Wduplicate-method-match
1969      -Wduplicated-cond
1970      -Wdynamic-class-memaccess
1971      -Wembedded-directive
1972      -Wempty-translation-unit
1973      -Wenum-conversion
1974      -Wexit-time-destructors
1975      -Wexplicit-ownership-type
1976      -Wextern-initializer
1977      -Wextra
1978      -Wextra-semi
1979      -Wextra-tokens
1980      -Wflexible-array-extensions
1981      -Wfloat-conversion
1982      -Wformat-non-iso
1983      -Wfour-char-constants
1984      -Wgcc-compat
1985      -Wglobal-constructors
1986      -Wgnu-array-member-paren-init
1987      -Wgnu-designator
1988      -Wgnu-static-float-init
1989      -Wheader-guard
1990      -Wheader-hygiene
1991      -Widiomatic-parentheses
1992      -Wignored-attributes
1993      -Wimplicit-atomic-properties
1994      -Wimplicit-conversion-floating-point-to-bool
1995      -Wimplicit-exception-spec-mismatch
1996      -Wimplicit-fallthrough
1997      -Wimplicit-fallthrough-per-function
1998      -Wimplicit-retain-self
1999      -Wimport-preprocessor-directive-pedantic
2000      -Wincompatible-library-redeclaration
2001      -Wincompatible-pointer-types-discards-qualifiers
2002      -Wincomplete-implementation
2003      -Wincomplete-module
2004      -Wincomplete-umbrella
2005      -Winit-self
2006      -Wint-conversions
2007      -Wint-to-void-pointer-cast
2008      -Winteger-overflow
2009      -Winvalid-constexpr
2010      -Winvalid-iboutlet
2011      -Winvalid-noreturn
2012      -Winvalid-pp-token
2013      -Winvalid-source-encoding
2014      -Winvalid-token-paste
2015      -Wknr-promoted-parameter
2016      -Wlarge-by-value-copy
2017      -Wliteral-conversion
2018      -Wliteral-range
2019      -Wlocal-type-template-args
2020      -Wlogical-op
2021      -Wloop-analysis
2022      -Wmain-return-type
2023      -Wmalformed-warning-check
2024      -Wmethod-signatures
2025      -Wmicrosoft
2026      -Wmicrosoft-exists
2027      -Wmismatched-parameter-types
2028      -Wmismatched-return-types
2029      -Wmissing-field-initializers
2030      -Wmissing-format-attribute
2031      -Wmissing-noreturn
2032      -Wmissing-selector-name
2033      -Wmissing-sysroot
2034      -Wmissing-variable-declarations
2035      -Wmodule-conflict
2036      -Wnested-anon-types
2037      -Wnewline-eof
2038      -Wnon-literal-null-conversion
2039      -Wnon-pod-varargs
2040      -Wnonportable-cfstrings
2041      -Wnormalized=nfkc
2042      -Wnull-arithmetic
2043      -Wnull-character
2044      -Wnull-conversion
2045      -Wnull-dereference
2046      -Wout-of-line-declaration
2047      -Wover-aligned
2048      -Woverlength-strings
2049      -Woverride-init
2050      -Woverriding-method-mismatch
2051      -Wpointer-type-mismatch
2052      -Wpredefined-identifier-outside-function
2053      -Wprotocol-property-synthesis-ambiguity
2054      -Wreadonly-iboutlet-property
2055      -Wreadonly-setter-attrs
2056      -Wreceiver-expr
2057      -Wreceiver-forward-class
2058      -Wreceiver-is-weak
2059      -Wreinterpret-base-class
2060      -Wrequires-super-attribute
2061      -Wreserved-user-defined-literal
2062      -Wreturn-stack-address
2063      -Wsection
2064      -Wselector-type-mismatch
2065      -Wsentinel
2066      -Wserialized-diagnostics
2067      -Wshadow
2068      -Wshift-count-negative
2069      -Wshift-count-overflow
2070      -Wshift-negative-value
2071      -Wshift-overflow=2
2072      -Wshift-sign-overflow
2073      -Wshorten-64-to-32
2074      -Wsizeof-array-argument
2075      -Wsource-uses-openmp
2076      -Wstatic-float-init
2077      -Wstatic-in-inline
2078      -Wstatic-local-in-inline
2079      -Wstrict-overflow=1
2080      -Wstring-compare
2081      -Wstring-conversion
2082      -Wstrlcpy-strlcat-size
2083      -Wstrncat-size
2084      -Wsuggest-attribute=format
2085      -Wsuggest-attribute=noreturn
2086      -Wsuper-class-method-mismatch
2087      -Wswitch-bool
2088      -Wsync-nand
2089      -Wtautological-constant-out-of-range-compare
2090      -Wtentative-definition-incomplete-type
2091      -Wtrampolines
2092      -Wtype-safety
2093      -Wtypedef-redefinition
2094      -Wtypename-missing
2095      -Wundefined-inline
2096      -Wundefined-internal
2097      -Wundefined-reinterpret-cast
2098      -Wunicode
2099      -Wunicode-whitespace
2100      -Wunknown-warning-option
2101      -Wunnamed-type-template-args
2102      -Wunneeded-member-function
2103      -Wunsequenced
2104      -Wunsupported-visibility
2105      -Wunused-but-set-parameter
2106      -Wunused-but-set-variable
2107      -Wunused-command-line-argument
2108      -Wunused-const-variable=2
2109      -Wunused-exception-parameter
2110      -Wunused-local-typedefs
2111      -Wunused-member-function
2112      -Wunused-sanitize-argument
2113      -Wunused-volatile-lvalue
2114      -Wuser-defined-literals
2115      -Wvariadic-macros
2116      -Wvector-conversion
2117      -Wvector-conversions
2118      -Wvexing-parse
2119      -Wvisibility
2120      -Wvla-extension
2121      -Wzero-length-array
2122   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
2123
2124 dnl    We should re-enable this in some later version.  Clang doesn't
2125 dnl    mind, but it causes trouble with GCC.
2126 dnl     -Wstrict-overflow=2
2127
2128 dnl    These seem to require annotations that we don't currently use,
2129 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2130 dnl     -Wthread-safety
2131 dnl     -Wthread-safety-analysis
2132 dnl     -Wthread-safety-attributes
2133 dnl     -Wthread-safety-beta
2134 dnl     -Wthread-safety-precise
2135
2136   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2137   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2138   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2139   CFLAGS="$CFLAGS -Wwrite-strings"
2140   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2141   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
2142   CFLAGS="$CFLAGS -Wunused-parameter "
2143   # These interfere with building main() { return 0; }, which autoconf
2144   # likes to use as its default program.
2145   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
2146
2147   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2148     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2149   fi
2150   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2151     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2152   fi
2153
2154   if test "x$enable_fatal_warnings" = "xyes"; then
2155     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2156     # default autoconf programs are full of errors.
2157     CFLAGS="$CFLAGS -Werror"
2158   fi
2159
2160 fi
2161
2162 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2163    case "$host_os" in
2164     darwin*)
2165       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2166    esac
2167 fi
2168
2169 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2170
2171 AC_CONFIG_FILES([
2172         Doxyfile
2173         Makefile
2174         contrib/dist/suse/tor.sh
2175         contrib/operator-tools/tor.logrotate
2176         contrib/dist/tor.sh
2177         contrib/dist/torctl
2178         contrib/dist/tor.service
2179         src/config/torrc.sample
2180         src/config/torrc.minimal
2181         src/rust/.cargo/config
2182         scripts/maint/checkOptionDocs.pl
2183         scripts/maint/updateVersions.pl
2184 ])
2185
2186 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2187   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2188   for file in $regular_mans ; do
2189     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2190       echo "==================================";
2191       echo;
2192       echo "Building Tor has failed since manpages cannot be built.";
2193       echo;
2194       echo "You need asciidoc installed to be able to build the manpages.";
2195       echo "To build without manpages, use the --disable-asciidoc argument";
2196       echo "when calling configure.";
2197       echo;
2198       echo "==================================";
2199       exit 1;
2200     fi
2201   done
2202 fi
2203
2204 if test "$fragile_hardening" = "yes"; then
2205   AC_MSG_WARN([
2206
2207 ============
2208 Warning!  Building Tor with --enable-fragile-hardening (also known as
2209 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2210 other kinds of attacks easier. A Tor instance build with this option will be
2211 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2212 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2213 denial of service attacks. For more information, see
2214 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2215 ============
2216   ])
2217 fi
2218
2219 AC_OUTPUT