configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2017, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.2.7-rc-dev])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56 AC_ARG_ENABLE(memory-sentinels,
  57    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  58 AC_ARG_ENABLE(rust,
  59    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  60 AC_ARG_ENABLE(cargo-online-mode,
  61    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  62
  63 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  64     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  65 fi
  66
  67 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  68 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  69 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  70 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  71 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  72 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  73
  74 if test "$enable_static_tor" = "yes"; then
  75   enable_static_libevent="yes";
  76   enable_static_openssl="yes";
  77   enable_static_zlib="yes";
  78   CFLAGS="$CFLAGS -static"
  79 fi
  80
  81 if test "$enable_system_torrc" = "no"; then
  82   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  83             [Defined if we're not going to look for a torrc in SYSCONF])
  84 fi
  85
  86 if test "$enable_memory_sentinels" = "no"; then
  87   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  88            [Defined if we're turning off memory safety code to look for bugs])
  89 fi
  90
  91 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  92
  93 AC_ARG_ENABLE(asciidoc,
  94      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  95      [case "${enableval}" in
  96         "yes") asciidoc=true ;;
  97         "no")  asciidoc=false ;;
  98         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  99       esac], [asciidoc=true])
 100
 101 # systemd notify support
 102 AC_ARG_ENABLE(systemd,
 103       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 104       [case "${enableval}" in
 105         "yes") systemd=true ;;
 106         "no")  systemd=false ;;
 107         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 108       esac], [systemd=auto])
 109
 110
 111
 112 # systemd support
 113 if test "x$enable_systemd" = "xno"; then
 114     have_systemd=no;
 115 else
 116     PKG_CHECK_MODULES(SYSTEMD,
 117         [libsystemd-daemon],
 118         have_systemd=yes,
 119         have_systemd=no)
 120     if test "x$have_systemd" = "xno"; then
 121         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 122         PKG_CHECK_MODULES(SYSTEMD,
 123             [libsystemd],
 124             have_systemd=yes,
 125             have_systemd=no)
 126     fi
 127 fi
 128
 129 if test "x$have_systemd" = "xyes"; then
 130     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 131     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 132     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 133     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 134          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 135 fi
 136 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 137 AC_SUBST(TOR_SYSTEMD_LIBS)
 138
 139 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 140     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 141 fi
 142
 143 case "$host" in
 144    *-*-solaris* )
 145      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 146      ;;
 147 esac
 148
 149 AC_ARG_ENABLE(gcc-warnings,
 150      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 151 AC_ARG_ENABLE(fatal-warnings,
 152      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 153 AC_ARG_ENABLE(gcc-warnings-advisory,
 154      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 155
 156 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 157 AC_ARG_ENABLE(gcc-hardening,
 158     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 159
 160 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 161 AC_ARG_ENABLE(expensive-hardening,
 162     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 163 AC_ARG_ENABLE(fragile-hardening,
 164     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 165 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 166   fragile_hardening="yes"
 167 fi
 168
 169 dnl Linker hardening options
 170 dnl Currently these options are ELF specific - you can't use this with MacOSX
 171 AC_ARG_ENABLE(linker-hardening,
 172     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 173
 174 AC_ARG_ENABLE(local-appdata,
 175    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 176 if test "$enable_local_appdata" = "yes"; then
 177   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 178             [Defined if we default to host local appdata paths on Windows])
 179 fi
 180
 181 # Tor2web mode flag
 182 AC_ARG_ENABLE(tor2web-mode,
 183      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 184 [if test "x$enableval" = "xyes"; then
 185     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 186 fi])
 187
 188 AC_ARG_ENABLE(tool-name-check,
 189      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 190
 191 AC_ARG_ENABLE(seccomp,
 192      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 193
 194 AC_ARG_ENABLE(libscrypt,
 195      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 196
 197 dnl Enable event tracing which are transformed to debug log statement.
 198 AC_ARG_ENABLE(event-tracing-debug,
 199      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 200 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 201
 202 if test x$enable_event_tracing_debug = xyes; then
 203   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 204   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 205 fi
 206
 207 dnl check for the correct "ar" when cross-compiling.
 208 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 209 dnl    so kludge up a replacement for the case where it isn't there yet.)
 210 m4_ifdef([AM_PROG_AR],
 211          [AM_PROG_AR],
 212          [AN_MAKEVAR([AR], [AC_PROG_AR])
 213           AN_PROGRAM([ar], [AC_PROG_AR])
 214           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 215           AC_PROG_AR])
 216
 217 dnl Check whether the above macro has settled for a simply named tool even
 218 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 219 dnl because that will find any cc on the system, not only the cross-compiler,
 220 dnl and then verify that a binary built with this compiler runs on the
 221 dnl build system. It will then come to the false conclusion that we're not
 222 dnl cross-compiling.
 223 if test "x$enable_tool_name_check" != "xno"; then
 224     if test "x$ac_tool_warned" = "xyes"; then
 225         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 226         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 227                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 228         fi
 229 fi
 230
 231 AC_PROG_CC
 232 AC_PROG_CPP
 233 AC_PROG_MAKE_SET
 234 AC_PROG_RANLIB
 235 AC_PROG_SED
 236
 237 AC_ARG_VAR([PERL], [path to Perl binary])
 238 AC_CHECK_PROGS([PERL], [perl])
 239 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 240
 241 dnl check for asciidoc and a2x
 242 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 243 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 244
 245 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 246
 247 AM_PROG_CC_C_O
 248 AC_PROG_CC_C99
 249
 250 AC_ARG_VAR([PYTHON], [path to Python binary])
 251 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 252 if test "x$PYTHON" = "x"; then
 253   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 254 fi
 255 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 256
 257 dnl List all external rust crates we depend on here. Include the version
 258 rust_crates="libc-0.2.22"
 259 AC_SUBST(rust_crates)
 260
 261 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 262 AC_C_FLEXIBLE_ARRAY_MEMBER
 263 ], [
 264  dnl Maybe we've got an old autoconf...
 265  AC_CACHE_CHECK([for flexible array members],
 266      tor_cv_c_flexarray,
 267      [AC_COMPILE_IFELSE(
 268        AC_LANG_PROGRAM([
 269  struct abc { int a; char b[]; };
 270 ], [
 271  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 272  def->b[0] = 33;
 273 ]),
 274   [tor_cv_c_flexarray=yes],
 275   [tor_cv_c_flexarray=no])])
 276  if test "$tor_cv_flexarray" = "yes"; then
 277    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 278  else
 279    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 280  fi
 281 ])
 282
 283 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 284       tor_cv_c_c99_decl,
 285       [AC_COMPILE_IFELSE(
 286          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 287          [tor_cv_c_c99_decl=yes],
 288          [tor_cv_c_c99_decl=no] )])
 289 if test "$tor_cv_c_c99_decl" != "yes"; then
 290   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 291 fi
 292
 293 AC_CACHE_CHECK([for working C99 designated initializers],
 294       tor_cv_c_c99_designated_init,
 295       [AC_COMPILE_IFELSE(
 296          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 297                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 298          [tor_cv_c_c99_designated_init=yes],
 299          [tor_cv_c_c99_designated_init=no] )])
 300
 301 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 302   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 303 fi
 304
 305 TORUSER=_tor
 306 AC_ARG_WITH(tor-user,
 307         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 308         [
 309            TORUSER=$withval
 310         ]
 311 )
 312 AC_SUBST(TORUSER)
 313
 314 TORGROUP=_tor
 315 AC_ARG_WITH(tor-group,
 316         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 317         [
 318            TORGROUP=$withval
 319         ]
 320 )
 321 AC_SUBST(TORGROUP)
 322
 323
 324 dnl If _WIN32 is defined and non-zero, we are building for win32
 325 AC_MSG_CHECKING([for win32])
 326 AC_RUN_IFELSE([AC_LANG_SOURCE([
 327 int main(int c, char **v) {
 328 #ifdef _WIN32
 329 #if _WIN32
 330   return 0;
 331 #else
 332   return 1;
 333 #endif
 334 #else
 335   return 2;
 336 #endif
 337 }])],
 338 bwin32=true; AC_MSG_RESULT([yes]),
 339 bwin32=false; AC_MSG_RESULT([no]),
 340 bwin32=cross; AC_MSG_RESULT([cross])
 341 )
 342
 343 if test "$bwin32" = "cross"; then
 344 AC_MSG_CHECKING([for win32 (cross)])
 345 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 346 #ifdef _WIN32
 347 int main(int c, char **v) {return 0;}
 348 #else
 349 #error
 350 int main(int c, char **v) {return x(y);}
 351 #endif
 352 ])],
 353 bwin32=true; AC_MSG_RESULT([yes]),
 354 bwin32=false; AC_MSG_RESULT([no]))
 355 fi
 356
 357 AH_BOTTOM([
 358 #ifdef _WIN32
 359 /* Defined to access windows functions and definitions for >=WinXP */
 360 # ifndef WINVER
 361 #  define WINVER 0x0501
 362 # endif
 363
 364 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 365 # ifndef _WIN32_WINNT
 366 #  define _WIN32_WINNT 0x0501
 367 # endif
 368
 369 /* Defined to avoid including some windows headers as part of Windows.h */
 370 # ifndef WIN32_LEAN_AND_MEAN
 371 #  define WIN32_LEAN_AND_MEAN 1
 372 # endif
 373 #endif
 374 ])
 375
 376
 377 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 378
 379 dnl Enable C99 when compiling with MIPSpro
 380 AC_MSG_CHECKING([for MIPSpro compiler])
 381 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 382 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 383 #error
 384   return x(y);
 385 #endif
 386 ])],
 387 bmipspro=false; AC_MSG_RESULT(no),
 388 bmipspro=true; AC_MSG_RESULT(yes))
 389
 390 if test "$bmipspro" = "true"; then
 391   CFLAGS="$CFLAGS -c99"
 392 fi
 393
 394 AC_C_BIGENDIAN
 395
 396 if test "x$enable_rust" = "xyes"; then
 397   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 398   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 399   if test "x$RUSTC" = "xno"; then
 400     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 401   fi
 402
 403   AC_ARG_VAR([CARGO], [path to the cargo binary])
 404   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 405   if test "x$CARGO" = "xno"; then
 406     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 407   fi
 408
 409   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 410   if test "x$enable_cargo_online_mode" = "xyes"; then
 411     CARGO_ONLINE=
 412     RUST_DL=#
 413   else
 414     CARGO_ONLINE=--frozen
 415     RUST_DL=
 416
 417     dnl When we're not allowed to touch the network, we need crate dependencies
 418     dnl locally available.
 419     AC_MSG_CHECKING([rust crate dependencies])
 420     AC_ARG_VAR([RUST_DEPENDENCIES], [path to directory with local crate mirror])
 421     if test "x$RUST_DEPENDENCIES" = "x"; then
 422       RUST_DEPENDENCIES="$srcdir/src/ext/rust/"
 423       NEED_MOD=1
 424     fi
 425     if test ! -d "$RUST_DEPENDENCIES"; then
 426       AC_MSG_ERROR([Rust dependency directory $RUST_DEPENDENCIES does not exist. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 427     fi
 428     for dep in $rust_crates; do
 429       if test ! -d "$RUST_DEPENDENCIES"/"$dep"; then
 430         AC_MSG_ERROR([Failure to find rust dependency $RUST_DEPENDENCIES/$dep. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 431       fi
 432     done
 433     if test "x$NEED_MOD" = "x1"; then
 434       dnl When looking for dependencies from cargo, pick right directory
 435       RUST_DEPENDENCIES="../../src/ext/rust"
 436     fi
 437   fi
 438
 439   dnl For now both MSVC and MinGW rust libraries will output static libs with
 440   dnl the MSVC naming convention.
 441   if test "$bwin32" = "true"; then
 442     TOR_RUST_UTIL_STATIC_NAME=tor_util.lib
 443   else
 444     TOR_RUST_UTIL_STATIC_NAME=libtor_util.a
 445   fi
 446
 447   AC_SUBST(TOR_RUST_UTIL_STATIC_NAME)
 448   AC_SUBST(CARGO_ONLINE)
 449   AC_SUBST(RUST_DL)
 450
 451   dnl Let's check the rustc version, too
 452   AC_MSG_CHECKING([rust version])
 453   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 454   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 455   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 456     AC_MSG_ERROR([rustc version couldn't be identified])
 457   fi
 458   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 459     AC_MSG_ERROR([rustc must be at least version 1.14])
 460   fi
 461 fi
 462
 463 AC_SEARCH_LIBS(socket, [socket network])
 464 AC_SEARCH_LIBS(gethostbyname, [nsl])
 465 AC_SEARCH_LIBS(dlopen, [dl])
 466 AC_SEARCH_LIBS(inet_aton, [resolv])
 467 AC_SEARCH_LIBS(backtrace, [execinfo])
 468 saved_LIBS="$LIBS"
 469 AC_SEARCH_LIBS([clock_gettime], [rt])
 470 if test "$LIBS" != "$saved_LIBS"; then
 471    # Looks like we need -lrt for clock_gettime().
 472    have_rt=yes
 473 fi
 474
 475 AC_SEARCH_LIBS(pthread_create, [pthread])
 476 AC_SEARCH_LIBS(pthread_detach, [pthread])
 477
 478 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 479 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 480
 481 AC_CHECK_FUNCS(
 482         _NSGetEnviron \
 483         RtlSecureZeroMemory \
 484         SecureZeroMemory \
 485         accept4 \
 486         backtrace \
 487         backtrace_symbols_fd \
 488         eventfd \
 489         explicit_bzero \
 490         timingsafe_memcmp \
 491         flock \
 492         ftime \
 493         get_current_dir_name \
 494         getaddrinfo \
 495         getifaddrs \
 496         getpass \
 497         getrlimit \
 498         gettimeofday \
 499         gmtime_r \
 500         gnu_get_libc_version \
 501         htonll \
 502         inet_aton \
 503         ioctl \
 504         issetugid \
 505         llround \
 506         localtime_r \
 507         lround \
 508         memmem \
 509         memset_s \
 510         pipe \
 511         pipe2 \
 512         prctl \
 513         readpassphrase \
 514         rint \
 515         sigaction \
 516         socketpair \
 517         statvfs \
 518         strlcat \
 519         strlcpy \
 520         strnlen \
 521         strptime \
 522         strtok_r \
 523         strtoull \
 524         sysconf \
 525         sysctl \
 526         truncate \
 527         uname \
 528         usleep \
 529         vasprintf \
 530         _vscprintf
 531 )
 532
 533 # Apple messed up when they added two functions functions in Sierra: they
 534 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 535 # checks. So we should only probe for those functions if we are sure that we
 536 # are not targetting OSX 10.11 or earlier.
 537 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 538 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 539 #ifdef __APPLE__
 540 #  include <AvailabilityMacros.h>
 541 #  ifndef MAC_OS_X_VERSION_10_12
 542 #    define MAC_OS_X_VERSION_10_12 101200
 543 #  endif
 544 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 545 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 546 #      error "Running on Mac OSX 10.11 or earlier"
 547 #    endif
 548 #  endif
 549 #endif
 550 ]], [[]])],
 551    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 552    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 553
 554 if test "$on_macos_pre_10_12" = "no"; then
 555   AC_CHECK_FUNCS(
 556         clock_gettime \
 557         getentropy \
 558   )
 559 fi
 560
 561 if test "$bwin32" != "true"; then
 562   AC_CHECK_HEADERS(pthread.h)
 563   AC_CHECK_FUNCS(pthread_create)
 564   AC_CHECK_FUNCS(pthread_condattr_setclock)
 565 fi
 566
 567 if test "$bwin32" = "true"; then
 568   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 569 #include <windows.h>
 570 #include <conio.h>
 571 #include <wchar.h>
 572                  ])
 573 fi
 574
 575 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 576   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 577
 578 dnl ------------------------------------------------------
 579 dnl Where do you live, libevent?  And how do we call you?
 580
 581 if test "$bwin32" = "true"; then
 582   TOR_LIB_WS32=-lws2_32
 583   TOR_LIB_IPHLPAPI=-liphlpapi
 584   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 585   # think it's actually necessary.
 586   TOR_LIB_GDI=-lgdi32
 587   TOR_LIB_USERENV=-luserenv
 588 else
 589   TOR_LIB_WS32=
 590   TOR_LIB_GDI=
 591   TOR_LIB_USERENV=
 592 fi
 593 AC_SUBST(TOR_LIB_WS32)
 594 AC_SUBST(TOR_LIB_GDI)
 595 AC_SUBST(TOR_LIB_IPHLPAPI)
 596 AC_SUBST(TOR_LIB_USERENV)
 597
 598 tor_libevent_pkg_redhat="libevent"
 599 tor_libevent_pkg_debian="libevent-dev"
 600 tor_libevent_devpkg_redhat="libevent-devel"
 601 tor_libevent_devpkg_debian="libevent-dev"
 602
 603 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 604 dnl linking for static builds.
 605 STATIC_LIBEVENT_FLAGS=""
 606 if test "$enable_static_libevent" = "yes"; then
 607     if test "$have_rt" = "yes"; then
 608       STATIC_LIBEVENT_FLAGS=" -lrt "
 609     fi
 610 fi
 611
 612 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 613 #ifdef _WIN32
 614 #include <winsock2.h>
 615 #endif
 616 #include <sys/time.h>
 617 #include <sys/types.h>
 618 #include <event2/event.h>], [
 619 #ifdef _WIN32
 620 #include <winsock2.h>
 621 #endif
 622 struct event_base;
 623 struct event_base *event_base_new(void);],
 624     [
 625 #ifdef _WIN32
 626 {WSADATA d; WSAStartup(0x101,&d); }
 627 #endif
 628 event_base_free(event_base_new());
 629 ], [--with-libevent-dir], [/opt/libevent])
 630
 631 dnl Determine the incantation needed to link libevent.
 632 save_LIBS="$LIBS"
 633 save_LDFLAGS="$LDFLAGS"
 634 save_CPPFLAGS="$CPPFLAGS"
 635
 636 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 637 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 638 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 639
 640 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 641
 642 if test "$enable_static_libevent" = "yes"; then
 643    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 644      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 645    else
 646      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 647    fi
 648 else
 649      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 650        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 651        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 652
 653        if test "$ac_cv_search_event_new" != "none required"; then
 654          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 655        fi
 656        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 657          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 658        fi
 659      else
 660        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 661      fi
 662 fi
 663
 664 dnl Now check for particular libevent functions.
 665 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 666                 evutil_secure_rng_add_bytes \
 667 ])
 668
 669 LIBS="$save_LIBS"
 670 LDFLAGS="$save_LDFLAGS"
 671 CPPFLAGS="$save_CPPFLAGS"
 672
 673 dnl Check that libevent is at least at version 2.0.10, the first stable
 674 dnl release of its series
 675 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 676 AC_MSG_CHECKING([whether Libevent is new enough])
 677 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 678 #include <event2/event.h>
 679 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 680 #error
 681 int x = y(zz);
 682 #else
 683 int x = 1;
 684 #endif
 685 ])], [ AC_MSG_RESULT([yes]) ],
 686    [ AC_MSG_RESULT([no])
 687      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 688
 689 LIBS="$save_LIBS"
 690 LDFLAGS="$save_LDFLAGS"
 691 CPPFLAGS="$save_CPPFLAGS"
 692
 693 AC_SUBST(TOR_LIBEVENT_LIBS)
 694
 695 dnl ------------------------------------------------------
 696 dnl Where do you live, libm?
 697
 698 dnl On some platforms (Haiku/BeOS) the math library is
 699 dnl part of libroot. In which case don't link against lm
 700 TOR_LIB_MATH=""
 701 save_LIBS="$LIBS"
 702 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 703 if test "$ac_cv_search_pow" != "none required"; then
 704     TOR_LIB_MATH="$ac_cv_search_pow"
 705 fi
 706 LIBS="$save_LIBS"
 707 AC_SUBST(TOR_LIB_MATH)
 708
 709 dnl ------------------------------------------------------
 710 dnl Where do you live, openssl?  And how do we call you?
 711
 712 tor_openssl_pkg_redhat="openssl"
 713 tor_openssl_pkg_debian="libssl-dev"
 714 tor_openssl_devpkg_redhat="openssl-devel"
 715 tor_openssl_devpkg_debian="libssl-dev"
 716
 717 ALT_openssl_WITHVAL=""
 718 AC_ARG_WITH(ssl-dir,
 719   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 720   [
 721       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 722          ALT_openssl_WITHVAL="$withval"
 723       fi
 724   ])
 725
 726 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 727 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 728     [#include <openssl/ssl.h>],
 729     [struct ssl_method_st; const struct ssl_method_st *TLSv1_1_method(void);],
 730     [TLSv1_1_method();], [],
 731     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 732
 733 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 734
 735 if test "$enable_static_openssl" = "yes"; then
 736    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 737      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 738    else
 739      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 740    fi
 741 else
 742      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 743 fi
 744 AC_SUBST(TOR_OPENSSL_LIBS)
 745
 746 dnl Now check for particular openssl functions.
 747 save_LIBS="$LIBS"
 748 save_LDFLAGS="$LDFLAGS"
 749 save_CPPFLAGS="$CPPFLAGS"
 750 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 751 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 752 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 753
 754 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 755 #include <openssl/opensslv.h>
 756 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 757 #error "too old"
 758 #endif
 759    ]], [[]])],
 760    [ : ],
 761    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 762
 763 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 764 #include <openssl/opensslv.h>
 765 #include <openssl/evp.h>
 766 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 767 #error "no ECC"
 768 #endif
 769 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 770 #error "curves unavailable"
 771 #endif
 772    ]], [[]])],
 773    [ : ],
 774    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 775
 776 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 777 [#include <openssl/ssl.h>
 778 ])
 779
 780 AC_CHECK_FUNCS([ \
 781                 SSL_SESSION_get_master_key \
 782                 SSL_get_server_random \
 783                 SSL_get_client_ciphers \
 784                 SSL_get_client_random \
 785                 SSL_CIPHER_find \
 786                 TLS_method
 787                ])
 788
 789 dnl Check if OpenSSL has scrypt implementation.
 790 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 791
 792 dnl Check if OpenSSL structures are opaque
 793 AC_CHECK_MEMBERS([SSL.state], , ,
 794 [#include <openssl/ssl.h>
 795 ])
 796
 797 dnl Define the set of checks for KIST scheduler support.
 798 AC_DEFUN([CHECK_KIST_SUPPORT],[
 799   dnl KIST needs struct tcp_info and for certain members to exist.
 800   AC_CHECK_MEMBERS(
 801     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
 802     , ,[[#include <netinet/tcp.h>]])
 803   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
 804   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 805                      #include <linux/sockios.h>
 806                      #ifndef SIOCOUTQNSD
 807                      #error
 808                      #endif
 809                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
 810   if test "x$have_siocoutqnsd" = "xyes"; then
 811     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
 812       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
 813         have_kist_support=yes
 814       fi
 815     fi
 816   fi
 817 ])
 818 dnl Now, trigger the check.
 819 CHECK_KIST_SUPPORT
 820 AS_IF([test "x$have_kist_support" = "xyes"],
 821       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
 822                                         on this system])],
 823       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
 824
 825 LIBS="$save_LIBS"
 826 LDFLAGS="$save_LDFLAGS"
 827 CPPFLAGS="$save_CPPFLAGS"
 828
 829 dnl ------------------------------------------------------
 830 dnl Where do you live, zlib?  And how do we call you?
 831
 832 tor_zlib_pkg_redhat="zlib"
 833 tor_zlib_pkg_debian="zlib1g"
 834 tor_zlib_devpkg_redhat="zlib-devel"
 835 tor_zlib_devpkg_debian="zlib1g-dev"
 836
 837 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 838     [#include <zlib.h>],
 839     [const char * zlibVersion(void);],
 840     [zlibVersion();], [--with-zlib-dir],
 841     [/opt/zlib])
 842
 843 if test "$enable_static_zlib" = "yes"; then
 844    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 845      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 846  using --enable-static-zlib")
 847    else
 848      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 849    fi
 850 else
 851      TOR_ZLIB_LIBS="-lz"
 852 fi
 853 AC_SUBST(TOR_ZLIB_LIBS)
 854
 855 dnl ------------------------------------------------------
 856 dnl Where we do we find lzma?
 857
 858 AC_ARG_ENABLE(lzma,
 859       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
 860       [case "${enableval}" in
 861         "yes") lzma=true ;;
 862         "no")  lzma=false ;;
 863         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
 864       esac], [lzma=auto])
 865
 866 if test "x$enable_lzma" = "xno"; then
 867     have_lzma=no;
 868 else
 869     PKG_CHECK_MODULES([LZMA],
 870                       [liblzma],
 871                       have_lzma=yes,
 872                       have_lzma=no)
 873
 874     if test "x$have_lzma" = "xno" ; then
 875         AC_MSG_WARN([Unable to find liblzma.])
 876     fi
 877 fi
 878
 879 if test "x$have_lzma" = "xyes"; then
 880     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
 881     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
 882     TOR_LZMA_LIBS="${LZMA_LIBS}"
 883 fi
 884 AC_SUBST(TOR_LZMA_CFLAGS)
 885 AC_SUBST(TOR_LZMA_LIBS)
 886
 887 dnl ------------------------------------------------------
 888 dnl Where we do we find zstd?
 889
 890 AC_ARG_ENABLE(zstd,
 891       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
 892       [case "${enableval}" in
 893         "yes") zstd=true ;;
 894         "no")  zstd=false ;;
 895         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
 896       esac], [zstd=auto])
 897
 898 if test "x$enable_zstd" = "xno"; then
 899     have_zstd=no;
 900 else
 901     PKG_CHECK_MODULES([ZSTD],
 902                       [libzstd >= 1.1],
 903                       have_zstd=yes,
 904                       have_zstd=no)
 905
 906     if test "x$have_zstd" = "xno" ; then
 907         AC_MSG_WARN([Unable to find libzstd.])
 908     fi
 909 fi
 910
 911 if test "x$have_zstd" = "xyes"; then
 912     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
 913     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
 914     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
 915 fi
 916 AC_SUBST(TOR_ZSTD_CFLAGS)
 917 AC_SUBST(TOR_ZSTD_LIBS)
 918
 919 dnl ----------------------------------------------------------------------
 920 dnl Check if libcap is available for capabilities.
 921
 922 tor_cap_pkg_debian="libcap2"
 923 tor_cap_pkg_redhat="libcap"
 924 tor_cap_devpkg_debian="libcap-dev"
 925 tor_cap_devpkg_redhat="libcap-devel"
 926
 927 AC_CHECK_LIB([cap], [cap_init], [],
 928   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 929 )
 930 AC_CHECK_FUNCS(cap_set_proc)
 931
 932 dnl ---------------------------------------------------------------------
 933 dnl Now that we know about our major libraries, we can check for compiler
 934 dnl and linker hardening options.  We need to do this with the libraries known,
 935 dnl since sometimes the linker will like an option but not be willing to
 936 dnl use it with a build of a library.
 937
 938 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 939 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
 940
 941 CFLAGS_FTRAPV=
 942 CFLAGS_FWRAPV=
 943 CFLAGS_ASAN=
 944 CFLAGS_UBSAN=
 945
 946
 947 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 948 #if !defined(__clang__)
 949 #error
 950 #endif])], have_clang=yes, have_clang=no)
 951
 952 if test "x$enable_gcc_hardening" != "xno"; then
 953     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 954     if test "x$have_clang" = "xyes"; then
 955         TOR_CHECK_CFLAGS(-Qunused-arguments)
 956     fi
 957     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 958     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 959     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 960 m4_ifdef([AS_VAR_IF],[
 961     AS_VAR_IF(can_compile, [yes],
 962         AS_VAR_IF(can_link, [yes],
 963                   [],
 964                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 965         )])
 966     AS_VAR_POPDEF([can_link])
 967     AS_VAR_POPDEF([can_compile])
 968     TOR_CHECK_CFLAGS(-Wstack-protector)
 969     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 970     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
 971        TOR_CHECK_CFLAGS(-fPIE)
 972        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 973     fi
 974     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
 975 fi
 976
 977 if test "$fragile_hardening" = "yes"; then
 978     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
 979    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
 980       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
 981    fi
 982
 983    if test "$tor_cv_cflags__ftrapv" != "yes"; then
 984      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
 985    fi
 986
 987    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
 988     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 989       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
 990     fi
 991
 992    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
 993     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 994       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
 995     fi
 996
 997 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 998 fi
 999
1000 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1001 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1002
1003 mulodi_fixes_ftrapv=no
1004 if test "$have_clang" = "yes"; then
1005   saved_CFLAGS="$CFLAGS"
1006   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1007   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1008   AC_LINK_IFELSE([
1009       AC_LANG_SOURCE([[
1010           #include <stdint.h>
1011           #include <stdlib.h>
1012           int main(int argc, char **argv)
1013           {
1014             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1015                         * (int64_t)atoi(argv[3]);
1016             return x == 9;
1017           } ]])],
1018           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1019           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1020   if test "$ftrapv_can_link" = "no"; then
1021     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1022     AC_LINK_IFELSE([
1023       AC_LANG_SOURCE([[
1024           #include <stdint.h>
1025           #include <stdlib.h>
1026           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1027              *overflow=0;
1028              return a;
1029           }
1030           int main(int argc, char **argv)
1031           {
1032             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1033                         * (int64_t)atoi(argv[3]);
1034             return x == 9;
1035           } ]])],
1036           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1037           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1038   fi
1039   CFLAGS="$saved_CFLAGS"
1040 fi
1041
1042 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1043
1044 dnl These cflags add bunches of branches, and we haven't been able to
1045 dnl persuade ourselves that they're suitable for code that needs to be
1046 dnl constant time.
1047 AC_SUBST(CFLAGS_BUGTRAP)
1048 dnl These cflags are variant ones sutable for code that needs to be
1049 dnl constant-time.
1050 AC_SUBST(CFLAGS_CONSTTIME)
1051
1052 if test "x$enable_linker_hardening" != "xno"; then
1053     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1054 fi
1055
1056 # For backtrace support
1057 TOR_CHECK_LDFLAGS(-rdynamic)
1058
1059 dnl ------------------------------------------------------
1060 dnl Now see if we have a -fomit-frame-pointer compiler option.
1061
1062 saved_CFLAGS="$CFLAGS"
1063 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1064 F_OMIT_FRAME_POINTER=''
1065 if test "$saved_CFLAGS" != "$CFLAGS"; then
1066   if test "$fragile_hardening" = "yes"; then
1067     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1068   fi
1069 fi
1070 CFLAGS="$saved_CFLAGS"
1071 AC_SUBST(F_OMIT_FRAME_POINTER)
1072
1073 dnl ------------------------------------------------------
1074 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1075 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1076 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1077 dnl code will work.
1078 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1079
1080 dnl ============================================================
1081 dnl Check for libseccomp
1082
1083 if test "x$enable_seccomp" != "xno"; then
1084   AC_CHECK_HEADERS([seccomp.h])
1085   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1086 fi
1087
1088 dnl ============================================================
1089 dnl Check for libscrypt
1090
1091 if test "x$enable_libscrypt" != "xno"; then
1092   AC_CHECK_HEADERS([libscrypt.h])
1093   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1094   AC_CHECK_FUNCS([libscrypt_scrypt])
1095 fi
1096
1097 dnl ============================================================
1098 dnl We need an implementation of curve25519.
1099
1100 dnl set these defaults.
1101 build_curve25519_donna=no
1102 build_curve25519_donna_c64=no
1103 use_curve25519_donna=no
1104 use_curve25519_nacl=no
1105 CURVE25519_LIBS=
1106
1107 dnl The best choice is using curve25519-donna-c64, but that requires
1108 dnl that we
1109 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1110   tor_cv_can_use_curve25519_donna_c64,
1111   [AC_RUN_IFELSE(
1112     [AC_LANG_PROGRAM([dnl
1113       #include <stdint.h>
1114       typedef unsigned uint128_t __attribute__((mode(TI)));
1115   int func(uint64_t a, uint64_t b) {
1116            uint128_t c = ((uint128_t)a) * b;
1117            int ok = ((uint64_t)(c>>96)) == 522859 &&
1118              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1119                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1120                  (((uint64_t)(c))&0xffffffffL) == 0;
1121            return ok;
1122       }
1123   ], [dnl
1124     int ok = func( ((uint64_t)2000000000) * 1000000000,
1125                    ((uint64_t)1234567890) << 24);
1126         return !ok;
1127       ])],
1128   [tor_cv_can_use_curve25519_donna_c64=yes],
1129       [tor_cv_can_use_curve25519_donna_c64=no],
1130   [AC_LINK_IFELSE(
1131         [AC_LANG_PROGRAM([dnl
1132       #include <stdint.h>
1133       typedef unsigned uint128_t __attribute__((mode(TI)));
1134   int func(uint64_t a, uint64_t b) {
1135            uint128_t c = ((uint128_t)a) * b;
1136            int ok = ((uint64_t)(c>>96)) == 522859 &&
1137              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1138                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1139                  (((uint64_t)(c))&0xffffffffL) == 0;
1140            return ok;
1141       }
1142   ], [dnl
1143     int ok = func( ((uint64_t)2000000000) * 1000000000,
1144                  ((uint64_t)1234567890) << 24);
1145         return !ok;
1146       ])],
1147           [tor_cv_can_use_curve25519_donna_c64=cross],
1148       [tor_cv_can_use_curve25519_donna_c64=no])])])
1149
1150 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1151                   nacl/crypto_scalarmult_curve25519.h])
1152
1153 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1154   tor_cv_can_use_curve25519_nacl,
1155   [tor_saved_LIBS="$LIBS"
1156    LIBS="$LIBS -lnacl"
1157    AC_LINK_IFELSE(
1158      [AC_LANG_PROGRAM([dnl
1159        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1160        #include <crypto_scalarmult_curve25519.h>
1161    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1162    #include <nacl/crypto_scalarmult_curve25519.h>
1163    #endif
1164        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1165    #error Hey, this is the reference implementation! That's not fast.
1166    #endif
1167      ], [
1168    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1169      ])], [tor_cv_can_use_curve25519_nacl=yes],
1170      [tor_cv_can_use_curve25519_nacl=no])
1171    LIBS="$tor_saved_LIBS" ])
1172
1173  dnl Okay, now we need to figure out which one to actually use. Fall back
1174  dnl to curve25519-donna.c
1175
1176  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1177    build_curve25519_donna_c64=yes
1178    use_curve25519_donna=yes
1179  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1180    use_curve25519_nacl=yes
1181    CURVE25519_LIBS=-lnacl
1182  else
1183    build_curve25519_donna=yes
1184    use_curve25519_donna=yes
1185  fi
1186
1187 if test "x$use_curve25519_donna" = "xyes"; then
1188   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1189             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1190 fi
1191 if test "x$use_curve25519_nacl" = "xyes"; then
1192   AC_DEFINE(USE_CURVE25519_NACL, 1,
1193             [Defined if we should use a curve25519 from nacl])
1194 fi
1195 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1196   test "x$build_curve25519_donna" = "xyes")
1197 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1198   test "x$build_curve25519_donna_c64" = "xyes")
1199 AC_SUBST(CURVE25519_LIBS)
1200
1201 dnl Make sure to enable support for large off_t if available.
1202 AC_SYS_LARGEFILE
1203
1204 AC_CHECK_HEADERS([assert.h \
1205                   errno.h \
1206                   fcntl.h \
1207                   signal.h \
1208                   string.h \
1209                   sys/capability.h \
1210                   sys/fcntl.h \
1211                   sys/stat.h \
1212                   sys/time.h \
1213                   sys/types.h \
1214                   time.h \
1215                   unistd.h \
1216                   arpa/inet.h \
1217                   crt_externs.h \
1218                   execinfo.h \
1219                   gnu/libc-version.h \
1220                   grp.h \
1221                   ifaddrs.h \
1222                   inttypes.h \
1223                   limits.h \
1224                   linux/types.h \
1225                   machine/limits.h \
1226                   malloc.h \
1227                   malloc/malloc.h \
1228                   malloc_np.h \
1229                   netdb.h \
1230                   netinet/in.h \
1231                   netinet/in6.h \
1232                   pwd.h \
1233                   readpassphrase.h \
1234                   stdint.h \
1235                   sys/eventfd.h \
1236                   sys/file.h \
1237                   sys/ioctl.h \
1238                   sys/limits.h \
1239                   sys/mman.h \
1240                   sys/param.h \
1241                   sys/prctl.h \
1242                   sys/random.h \
1243                   sys/resource.h \
1244                   sys/select.h \
1245                   sys/socket.h \
1246                   sys/statvfs.h \
1247                   sys/syscall.h \
1248                   sys/sysctl.h \
1249                   sys/syslimits.h \
1250                   sys/time.h \
1251                   sys/types.h \
1252                   sys/un.h \
1253                   sys/utime.h \
1254                   sys/wait.h \
1255                   syslog.h \
1256                   utime.h])
1257
1258 AC_CHECK_HEADERS(sys/param.h)
1259
1260 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1261 [#ifdef HAVE_SYS_TYPES_H
1262 #include <sys/types.h>
1263 #endif
1264 #ifdef HAVE_SYS_SOCKET_H
1265 #include <sys/socket.h>
1266 #endif])
1267 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1268 [#ifdef HAVE_SYS_TYPES_H
1269 #include <sys/types.h>
1270 #endif
1271 #ifdef HAVE_SYS_SOCKET_H
1272 #include <sys/socket.h>
1273 #endif
1274 #ifdef HAVE_NET_IF_H
1275 #include <net/if.h>
1276 #endif
1277 #ifdef HAVE_NETINET_IN_H
1278 #include <netinet/in.h>
1279 #endif])
1280
1281 AC_CHECK_HEADERS(linux/if.h,[],[],
1282 [
1283 #ifdef HAVE_SYS_SOCKET_H
1284 #include <sys/socket.h>
1285 #endif
1286 ])
1287
1288 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1289         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1290 [#ifdef HAVE_SYS_TYPES_H
1291 #include <sys/types.h>
1292 #endif
1293 #ifdef HAVE_SYS_SOCKET_H
1294 #include <sys/socket.h>
1295 #endif
1296 #ifdef HAVE_LIMITS_H
1297 #include <limits.h>
1298 #endif
1299 #ifdef HAVE_LINUX_TYPES_H
1300 #include <linux/types.h>
1301 #endif
1302 #ifdef HAVE_NETINET_IN6_H
1303 #include <netinet/in6.h>
1304 #endif
1305 #ifdef HAVE_NETINET_IN_H
1306 #include <netinet/in.h>
1307 #endif])
1308
1309 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1310         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1311 [#ifdef HAVE_SYS_TYPES_H
1312 #include <sys/types.h>
1313 #endif
1314 #ifdef HAVE_SYS_SOCKET_H
1315 #include <sys/socket.h>
1316 #endif
1317 #ifdef HAVE_LIMITS_H
1318 #include <limits.h>
1319 #endif
1320 #ifdef HAVE_LINUX_TYPES_H
1321 #include <linux/types.h>
1322 #endif
1323 #ifdef HAVE_NETINET_IN6_H
1324 #include <netinet/in6.h>
1325 #endif
1326 #ifdef HAVE_NETINET_IN_H
1327 #include <netinet/in.h>
1328 #endif
1329 #ifdef HAVE_LINUX_IF_H
1330 #include <linux/if.h>
1331 #endif])
1332
1333 transparent_ok=0
1334 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1335   transparent_ok=1
1336 fi
1337 if test "x$linux_netfilter_ipv4" = "x1"; then
1338   transparent_ok=1
1339 fi
1340 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1341   transparent_ok=1
1342 fi
1343 if test "x$transparent_ok" = "x1"; then
1344   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1345 else
1346   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1347 fi
1348
1349 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1350 [#ifdef HAVE_SYS_TYPES_H
1351 #include <sys/types.h>
1352 #endif
1353 #ifdef HAVE_SYS_TIME_H
1354 #include <sys/time.h>
1355 #endif])
1356
1357 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1358 dnl Watch out.
1359
1360 AC_CHECK_SIZEOF(int8_t)
1361 AC_CHECK_SIZEOF(int16_t)
1362 AC_CHECK_SIZEOF(int32_t)
1363 AC_CHECK_SIZEOF(int64_t)
1364 AC_CHECK_SIZEOF(uint8_t)
1365 AC_CHECK_SIZEOF(uint16_t)
1366 AC_CHECK_SIZEOF(uint32_t)
1367 AC_CHECK_SIZEOF(uint64_t)
1368 AC_CHECK_SIZEOF(intptr_t)
1369 AC_CHECK_SIZEOF(uintptr_t)
1370
1371 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1372
1373 AC_CHECK_SIZEOF(char)
1374 AC_CHECK_SIZEOF(short)
1375 AC_CHECK_SIZEOF(int)
1376 AC_CHECK_SIZEOF(long)
1377 AC_CHECK_SIZEOF(long long)
1378 AC_CHECK_SIZEOF(__int64)
1379 AC_CHECK_SIZEOF(void *)
1380 AC_CHECK_SIZEOF(time_t)
1381 AC_CHECK_SIZEOF(size_t)
1382 AC_CHECK_SIZEOF(pid_t)
1383
1384 AC_CHECK_TYPES([uint, u_char, ssize_t])
1385
1386 AC_PC_FROM_UCONTEXT([:])
1387
1388 dnl used to include sockaddr_storage, but everybody has that.
1389 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1390 [#ifdef HAVE_SYS_TYPES_H
1391 #include <sys/types.h>
1392 #endif
1393 #ifdef HAVE_NETINET_IN_H
1394 #include <netinet/in.h>
1395 #endif
1396 #ifdef HAVE_NETINET_IN6_H
1397 #include <netinet/in6.h>
1398 #endif
1399 #ifdef HAVE_SYS_SOCKET_H
1400 #include <sys/socket.h>
1401 #endif
1402 #ifdef _WIN32
1403 #define _WIN32_WINNT 0x0501
1404 #define WIN32_LEAN_AND_MEAN
1405 #include <winsock2.h>
1406 #include <ws2tcpip.h>
1407 #endif
1408 ])
1409 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1410 [#ifdef HAVE_SYS_TYPES_H
1411 #include <sys/types.h>
1412 #endif
1413 #ifdef HAVE_NETINET_IN_H
1414 #include <netinet/in.h>
1415 #endif
1416 #ifdef HAVE_NETINET_IN6_H
1417 #include <netinet/in6.h>
1418 #endif
1419 #ifdef HAVE_SYS_SOCKET_H
1420 #include <sys/socket.h>
1421 #endif
1422 #ifdef _WIN32
1423 #define _WIN32_WINNT 0x0501
1424 #define WIN32_LEAN_AND_MEAN
1425 #include <winsock2.h>
1426 #include <ws2tcpip.h>
1427 #endif
1428 ])
1429
1430 AC_CHECK_TYPES([rlim_t], , ,
1431 [#ifdef HAVE_SYS_TYPES_H
1432 #include <sys/types.h>
1433 #endif
1434 #ifdef HAVE_SYS_TIME_H
1435 #include <sys/time.h>
1436 #endif
1437 #ifdef HAVE_SYS_RESOURCE_H
1438 #include <sys/resource.h>
1439 #endif
1440 ])
1441
1442 AX_CHECK_SIGN([time_t],
1443        [ : ],
1444        [ : ], [
1445 #ifdef HAVE_SYS_TYPES_H
1446 #include <sys/types.h>
1447 #endif
1448 #ifdef HAVE_SYS_TIME_H
1449 #include <sys/time.h>
1450 #endif
1451 #ifdef HAVE_TIME_H
1452 #include <time.h>
1453 #endif
1454 ])
1455
1456 if test "$ax_cv_decl_time_t_signed" = "no"; then
1457   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1458 fi
1459
1460 AX_CHECK_SIGN([size_t],
1461        [ tor_cv_size_t_signed=yes ],
1462        [ tor_cv_size_t_signed=no ], [
1463 #ifdef HAVE_SYS_TYPES_H
1464 #include <sys/types.h>
1465 #endif
1466 ])
1467
1468 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1469   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1470 fi
1471
1472 AX_CHECK_SIGN([enum always],
1473        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1474        [ : ], [
1475  enum always { AAA, BBB, CCC };
1476 ])
1477
1478 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1479 #ifdef HAVE_SYS_SOCKET_H
1480 #include <sys/socket.h>
1481 #endif
1482 ])
1483
1484 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1485
1486 AC_CHECK_SIZEOF(cell_t)
1487
1488 # Now make sure that NULL can be represented as zero bytes.
1489 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1490 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1491 [[#include <stdlib.h>
1492 #include <string.h>
1493 #include <stdio.h>
1494 #ifdef HAVE_STDDEF_H
1495 #include <stddef.h>
1496 #endif
1497 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1498 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1499        [tor_cv_null_is_zero=yes],
1500        [tor_cv_null_is_zero=no],
1501        [tor_cv_null_is_zero=cross])])
1502
1503 if test "$tor_cv_null_is_zero" = "cross"; then
1504   # Cross-compiling; let's hope that the target isn't raving mad.
1505   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1506 fi
1507
1508 if test "$tor_cv_null_is_zero" != "no"; then
1509   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1510             [Define to 1 iff memset(0) sets pointers to NULL])
1511 fi
1512
1513 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1514 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1515 [[#include <stdlib.h>
1516 #include <string.h>
1517 #include <stdio.h>
1518 #ifdef HAVE_STDDEF_H
1519 #include <stddef.h>
1520 #endif
1521 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1522 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1523        [tor_cv_dbl0_is_zero=yes],
1524        [tor_cv_dbl0_is_zero=no],
1525        [tor_cv_dbl0_is_zero=cross])])
1526
1527 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1528   # Cross-compiling; let's hope that the target isn't raving mad.
1529   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1530 fi
1531
1532 if test "$tor_cv_dbl0_is_zero" != "no"; then
1533   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1534             [Define to 1 iff memset(0) sets doubles to 0.0])
1535 fi
1536
1537 # And what happens when we malloc zero?
1538 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1539 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1540 [[#include <stdlib.h>
1541 #include <string.h>
1542 #include <stdio.h>
1543 #ifdef HAVE_STDDEF_H
1544 #include <stddef.h>
1545 #endif
1546 int main () { return malloc(0)?0:1; }]])],
1547        [tor_cv_malloc_zero_works=yes],
1548        [tor_cv_malloc_zero_works=no],
1549        [tor_cv_malloc_zero_works=cross])])
1550
1551 if test "$tor_cv_malloc_zero_works" = "cross"; then
1552   # Cross-compiling; let's hope that the target isn't raving mad.
1553   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1554 fi
1555
1556 if test "$tor_cv_malloc_zero_works" = "yes"; then
1557   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1558             [Define to 1 iff malloc(0) returns a pointer])
1559 fi
1560
1561 # whether we seem to be in a 2s-complement world.
1562 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1563 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1564 [[int main () { int problem = ((-99) != (~99)+1);
1565 return problem ? 1 : 0; }]])],
1566        [tor_cv_twos_complement=yes],
1567        [tor_cv_twos_complement=no],
1568        [tor_cv_twos_complement=cross])])
1569
1570 if test "$tor_cv_twos_complement" = "cross"; then
1571   # Cross-compiling; let's hope that the target isn't raving mad.
1572   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1573 fi
1574
1575 if test "$tor_cv_twos_complement" != "no"; then
1576   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1577             [Define to 1 iff we represent negative integers with
1578              two's complement])
1579 fi
1580
1581 # What does shifting a negative value do?
1582 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1583 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1584 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1585        [tor_cv_sign_extend=yes],
1586        [tor_cv_sign_extend=no],
1587        [tor_cv_sign_extend=cross])])
1588
1589 if test "$tor_cv_sign_extend" = "cross"; then
1590   # Cross-compiling; let's hope that the target isn't raving mad.
1591   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1592 fi
1593
1594 if test "$tor_cv_sign_extend" != "no"; then
1595   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1596             [Define to 1 iff right-shifting a negative value performs sign-extension])
1597 fi
1598
1599 # Is uint8_t the same type as unsigned char?
1600 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1601 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1602 #include <stdint.h>
1603 extern uint8_t c;
1604 unsigned char c;]])],
1605        [tor_cv_uint8_uchar=yes],
1606        [tor_cv_uint8_uchar=no],
1607        [tor_cv_uint8_uchar=cross])])
1608
1609 if test "$tor_cv_uint8_uchar" = "cross"; then
1610   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1611 fi
1612
1613 if test "$tor_cv_uint8_uchar" = "no"; then
1614   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1615 fi
1616
1617 # Whether we should use the dmalloc memory allocation debugging library.
1618 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1619 AC_ARG_WITH(dmalloc,
1620 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1621 [if [[ "$withval" = "yes" ]]; then
1622   dmalloc=1
1623   AC_MSG_RESULT(yes)
1624 else
1625   dmalloc=1
1626   AC_MSG_RESULT(no)
1627 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1628 )
1629
1630 if [[ $dmalloc -eq 1 ]]; then
1631   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1632   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1633   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1634   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1635 fi
1636
1637 AC_ARG_WITH(tcmalloc,
1638 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1639 [ tcmalloc=yes ], [ tcmalloc=no ])
1640
1641 if test "x$tcmalloc" = "xyes"; then
1642    LDFLAGS="-ltcmalloc $LDFLAGS"
1643 fi
1644
1645 using_custom_malloc=no
1646 if test "x$enable_openbsd_malloc" = "xyes"; then
1647    using_custom_malloc=yes
1648 fi
1649 if test "x$tcmalloc" = "xyes"; then
1650    using_custom_malloc=yes
1651 fi
1652 if test "$using_custom_malloc" = "no"; then
1653    AC_CHECK_FUNCS(mallinfo)
1654 fi
1655
1656 # By default, we're going to assume we don't have mlockall()
1657 # bionic and other platforms have various broken mlockall subsystems.
1658 # Some systems don't have a working mlockall, some aren't linkable,
1659 # and some have it but don't declare it.
1660 AC_CHECK_FUNCS(mlockall)
1661 AC_CHECK_DECLS([mlockall], , , [
1662 #ifdef HAVE_SYS_MMAN_H
1663 #include <sys/mman.h>
1664 #endif])
1665
1666 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1667 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1668 # using macros
1669 AC_CHECK_DECLS([getpagesize], , , [
1670 #ifdef HAVE_UNISTD_H
1671 #include <unistd.h>
1672 #endif])
1673
1674 # Allow user to specify an alternate syslog facility
1675 AC_ARG_WITH(syslog-facility,
1676 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1677 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1678 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1679 AC_SUBST(LOGFACILITY)
1680
1681 # Check if we have getresuid and getresgid
1682 AC_CHECK_FUNCS(getresuid getresgid)
1683
1684 # Check for gethostbyname_r in all its glorious incompatible versions.
1685 #   (This logic is based on that in Python's configure.in)
1686 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1687   [Define this if you have any gethostbyname_r()])
1688
1689 AC_CHECK_FUNC(gethostbyname_r, [
1690   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1691   OLD_CFLAGS=$CFLAGS
1692   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1693   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1694 #include <netdb.h>
1695   ]], [[
1696     char *cp1, *cp2;
1697     struct hostent *h1, *h2;
1698     int i1, i2;
1699     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1700   ]])],[
1701     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1702     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1703      [Define this if gethostbyname_r takes 6 arguments])
1704     AC_MSG_RESULT(6)
1705   ], [
1706     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1707 #include <netdb.h>
1708     ]], [[
1709       char *cp1, *cp2;
1710       struct hostent *h1;
1711       int i1, i2;
1712       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1713     ]])], [
1714       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1715       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1716         [Define this if gethostbyname_r takes 5 arguments])
1717       AC_MSG_RESULT(5)
1718    ], [
1719       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1720 #include <netdb.h>
1721      ]], [[
1722        char *cp1;
1723        struct hostent *h1;
1724        struct hostent_data hd;
1725        (void) gethostbyname_r(cp1,h1,&hd);
1726      ]])], [
1727        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1728        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1729          [Define this if gethostbyname_r takes 3 arguments])
1730        AC_MSG_RESULT(3)
1731      ], [
1732        AC_MSG_RESULT(0)
1733      ])
1734   ])
1735  ])
1736  CFLAGS=$OLD_CFLAGS
1737 ])
1738
1739 AC_CACHE_CHECK([whether the C compiler supports __func__],
1740   tor_cv_have_func_macro,
1741   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1742 #include <stdio.h>
1743 int main(int c, char **v) { puts(__func__); }])],
1744   tor_cv_have_func_macro=yes,
1745   tor_cv_have_func_macro=no))
1746
1747 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1748   tor_cv_have_FUNC_macro,
1749   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1750 #include <stdio.h>
1751 int main(int c, char **v) { puts(__FUNC__); }])],
1752   tor_cv_have_FUNC_macro=yes,
1753   tor_cv_have_FUNC_macro=no))
1754
1755 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1756   tor_cv_have_FUNCTION_macro,
1757   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1758 #include <stdio.h>
1759 int main(int c, char **v) { puts(__FUNCTION__); }])],
1760   tor_cv_have_FUNCTION_macro=yes,
1761   tor_cv_have_FUNCTION_macro=no))
1762
1763 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1764   tor_cv_have_environ_declared,
1765   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1766 #ifdef HAVE_UNISTD_H
1767 #include <unistd.h>
1768 #endif
1769 #include <stdlib.h>
1770 int main(int c, char **v) { char **t = environ; }])],
1771   tor_cv_have_environ_declared=yes,
1772   tor_cv_have_environ_declared=no))
1773
1774 if test "$tor_cv_have_func_macro" = "yes"; then
1775   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1776 fi
1777
1778 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1779   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1780 fi
1781
1782 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1783   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1784            [Defined if the compiler supports __FUNCTION__])
1785 fi
1786
1787 if test "$tor_cv_have_environ_declared" = "yes"; then
1788   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1789            [Defined if we have extern char **environ already declared])
1790 fi
1791
1792 # $prefix stores the value of the --prefix command line option, or
1793 # NONE if the option wasn't set.  In the case that it wasn't set, make
1794 # it be the default, so that we can use it to expand directories now.
1795 if test "x$prefix" = "xNONE"; then
1796   prefix=$ac_default_prefix
1797 fi
1798
1799 # and similarly for $exec_prefix
1800 if test "x$exec_prefix" = "xNONE"; then
1801   exec_prefix=$prefix
1802 fi
1803
1804 if test "x$BUILDDIR" = "x"; then
1805   BUILDDIR=`pwd`
1806 fi
1807 AC_SUBST(BUILDDIR)
1808 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1809 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1810
1811 if test "x$CONFDIR" = "x"; then
1812   CONFDIR=`eval echo $sysconfdir/tor`
1813 fi
1814 AC_SUBST(CONFDIR)
1815 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1816 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1817
1818 BINDIR=`eval echo $bindir`
1819 AC_SUBST(BINDIR)
1820 LOCALSTATEDIR=`eval echo $localstatedir`
1821 AC_SUBST(LOCALSTATEDIR)
1822
1823 if test "$bwin32" = "true"; then
1824   # Test if the linker supports the --nxcompat and --dynamicbase options
1825   # for Windows
1826   save_LDFLAGS="$LDFLAGS"
1827   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1828   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1829   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1830     [AC_MSG_RESULT([yes])]
1831     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1832     [AC_MSG_RESULT([no])]
1833   )
1834   LDFLAGS="$save_LDFLAGS"
1835 fi
1836
1837 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1838 # than autoconf's macros like.
1839 if test "$GCC" = "yes"; then
1840   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1841   # accident waiting to happen.
1842   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1843 else
1844   # Override optimization level for non-gcc compilers
1845   CFLAGS="$CFLAGS -O"
1846   enable_gcc_warnings=no
1847   enable_gcc_warnings_advisory=no
1848 fi
1849
1850 # Warnings implies advisory-warnings and -Werror.
1851 if test "$enable_gcc_warnings" = "yes"; then
1852   enable_gcc_warnings_advisory=yes
1853   enable_fatal_warnings=yes
1854 fi
1855
1856 # OS X Lion started deprecating the system openssl. Let's just disable
1857 # all deprecation warnings on OS X. Also, to potentially make the binary
1858 # a little smaller, let's enable dead_strip.
1859 case "$host_os" in
1860
1861  darwin*)
1862     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1863     LDFLAGS="$LDFLAGS -dead_strip" ;;
1864 esac
1865
1866 # Add some more warnings which we use in development but not in the
1867 # released versions.  (Some relevant gcc versions can't handle these.)
1868 #
1869 # Note that we have to do this near the end  of the autoconf process, or
1870 # else we may run into problems when these warnings hit on the testing C
1871 # programs that autoconf wants to build.
1872 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1873
1874   case "$host" in
1875     *-*-openbsd* | *-*-bitrig*)
1876       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1877       # That's fine, except that the headers don't pass -Wredundant-decls.
1878       # Therefore, let's disable -Wsystem-headers when we're building
1879       # with maximal warnings on OpenBSD.
1880       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1881   esac
1882
1883   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1884   # have it work better.
1885   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1886
1887   # This warning was added in gcc 4.3, but it appears to generate
1888   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1889   #CFLAGS="$CFLAGS -Wlogical-op"
1890
1891   m4_foreach_w([warning_flag], [
1892      -Waddress
1893      -Waddress-of-array-temporary
1894      -Waddress-of-temporary
1895      -Wambiguous-macro
1896      -Wanonymous-pack-parens
1897      -Warc
1898      -Warc-abi
1899      -Warc-bridge-casts-disallowed-in-nonarc
1900      -Warc-maybe-repeated-use-of-weak
1901      -Warc-performSelector-leaks
1902      -Warc-repeated-use-of-weak
1903      -Warray-bounds
1904      -Warray-bounds-pointer-arithmetic
1905      -Wasm
1906      -Wasm-operand-widths
1907      -Watomic-properties
1908      -Watomic-property-with-user-defined-accessor
1909      -Wauto-import
1910      -Wauto-storage-class
1911      -Wauto-var-id
1912      -Wavailability
1913      -Wbackslash-newline-escape
1914      -Wbad-array-new-length
1915      -Wbind-to-temporary-copy
1916      -Wbitfield-constant-conversion
1917      -Wbool-conversion
1918      -Wbool-conversions
1919      -Wbuiltin-requires-header
1920      -Wchar-align
1921      -Wcompare-distinct-pointer-types
1922      -Wcomplex-component-init
1923      -Wconditional-type-mismatch
1924      -Wconfig-macros
1925      -Wconstant-conversion
1926      -Wconstant-logical-operand
1927      -Wconstexpr-not-const
1928      -Wcustom-atomic-properties
1929      -Wdangling-field
1930      -Wdangling-initializer-list
1931      -Wdate-time
1932      -Wdelegating-ctor-cycles
1933      -Wdeprecated-implementations
1934      -Wdeprecated-register
1935      -Wdirect-ivar-access
1936      -Wdiscard-qual
1937      -Wdistributed-object-modifiers
1938      -Wdivision-by-zero
1939      -Wdollar-in-identifier-extension
1940      -Wdouble-promotion
1941      -Wduplicate-decl-specifier
1942      -Wduplicate-enum
1943      -Wduplicate-method-arg
1944      -Wduplicate-method-match
1945      -Wduplicated-cond
1946      -Wdynamic-class-memaccess
1947      -Wembedded-directive
1948      -Wempty-translation-unit
1949      -Wenum-conversion
1950      -Wexit-time-destructors
1951      -Wexplicit-ownership-type
1952      -Wextern-initializer
1953      -Wextra
1954      -Wextra-semi
1955      -Wextra-tokens
1956      -Wflexible-array-extensions
1957      -Wfloat-conversion
1958      -Wformat-non-iso
1959      -Wfour-char-constants
1960      -Wgcc-compat
1961      -Wglobal-constructors
1962      -Wgnu-array-member-paren-init
1963      -Wgnu-designator
1964      -Wgnu-static-float-init
1965      -Wheader-guard
1966      -Wheader-hygiene
1967      -Widiomatic-parentheses
1968      -Wignored-attributes
1969      -Wimplicit-atomic-properties
1970      -Wimplicit-conversion-floating-point-to-bool
1971      -Wimplicit-exception-spec-mismatch
1972      -Wimplicit-fallthrough
1973      -Wimplicit-fallthrough-per-function
1974      -Wimplicit-retain-self
1975      -Wimport-preprocessor-directive-pedantic
1976      -Wincompatible-library-redeclaration
1977      -Wincompatible-pointer-types-discards-qualifiers
1978      -Wincomplete-implementation
1979      -Wincomplete-module
1980      -Wincomplete-umbrella
1981      -Winit-self
1982      -Wint-conversions
1983      -Wint-to-void-pointer-cast
1984      -Winteger-overflow
1985      -Winvalid-constexpr
1986      -Winvalid-iboutlet
1987      -Winvalid-noreturn
1988      -Winvalid-pp-token
1989      -Winvalid-source-encoding
1990      -Winvalid-token-paste
1991      -Wknr-promoted-parameter
1992      -Wlanguage-extension-token
1993      -Wlarge-by-value-copy
1994      -Wliteral-conversion
1995      -Wliteral-range
1996      -Wlocal-type-template-args
1997      -Wlogical-op
1998      -Wloop-analysis
1999      -Wmain-return-type
2000      -Wmalformed-warning-check
2001      -Wmethod-signatures
2002      -Wmicrosoft
2003      -Wmicrosoft-exists
2004      -Wmismatched-parameter-types
2005      -Wmismatched-return-types
2006      -Wmissing-field-initializers
2007      -Wmissing-format-attribute
2008      -Wmissing-noreturn
2009      -Wmissing-selector-name
2010      -Wmissing-sysroot
2011      -Wmissing-variable-declarations
2012      -Wmodule-conflict
2013      -Wnested-anon-types
2014      -Wnewline-eof
2015      -Wnon-literal-null-conversion
2016      -Wnon-pod-varargs
2017      -Wnonportable-cfstrings
2018      -Wnormalized=id
2019      -Wnull-arithmetic
2020      -Wnull-character
2021      -Wnull-conversion
2022      -Wnull-dereference
2023      -Wout-of-line-declaration
2024      -Wover-aligned
2025      -Woverlength-strings
2026      -Woverride-init
2027      -Woverriding-method-mismatch
2028      -Wpointer-type-mismatch
2029      -Wpredefined-identifier-outside-function
2030      -Wprotocol-property-synthesis-ambiguity
2031      -Wreadonly-iboutlet-property
2032      -Wreadonly-setter-attrs
2033      -Wreceiver-expr
2034      -Wreceiver-forward-class
2035      -Wreceiver-is-weak
2036      -Wreinterpret-base-class
2037      -Wrequires-super-attribute
2038      -Wreserved-user-defined-literal
2039      -Wreturn-stack-address
2040      -Wsection
2041      -Wselector-type-mismatch
2042      -Wsentinel
2043      -Wserialized-diagnostics
2044      -Wshadow
2045      -Wshift-count-negative
2046      -Wshift-count-overflow
2047      -Wshift-negative-value
2048      -Wshift-overflow=2
2049      -Wshift-sign-overflow
2050      -Wshorten-64-to-32
2051      -Wsizeof-array-argument
2052      -Wsource-uses-openmp
2053      -Wstatic-float-init
2054      -Wstatic-in-inline
2055      -Wstatic-local-in-inline
2056      -Wstrict-overflow=1
2057      -Wstring-compare
2058      -Wstring-conversion
2059      -Wstrlcpy-strlcat-size
2060      -Wstrncat-size
2061      -Wsuggest-attribute=format
2062      -Wsuggest-attribute=noreturn
2063      -Wsuper-class-method-mismatch
2064      -Wswitch-bool
2065      -Wsync-nand
2066      -Wtautological-constant-out-of-range-compare
2067      -Wtentative-definition-incomplete-type
2068      -Wtrampolines
2069      -Wtype-safety
2070      -Wtypedef-redefinition
2071      -Wtypename-missing
2072      -Wundefined-inline
2073      -Wundefined-internal
2074      -Wundefined-reinterpret-cast
2075      -Wunicode
2076      -Wunicode-whitespace
2077      -Wunknown-warning-option
2078      -Wunnamed-type-template-args
2079      -Wunneeded-member-function
2080      -Wunsequenced
2081      -Wunsupported-visibility
2082      -Wunused-but-set-parameter
2083      -Wunused-but-set-variable
2084      -Wunused-command-line-argument
2085      -Wunused-const-variable=2
2086      -Wunused-exception-parameter
2087      -Wunused-local-typedefs
2088      -Wunused-member-function
2089      -Wunused-sanitize-argument
2090      -Wunused-volatile-lvalue
2091      -Wuser-defined-literals
2092      -Wvariadic-macros
2093      -Wvector-conversion
2094      -Wvector-conversions
2095      -Wvexing-parse
2096      -Wvisibility
2097      -Wvla-extension
2098      -Wzero-length-array
2099   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
2100
2101 dnl    We should re-enable this in some later version.  Clang doesn't
2102 dnl    mind, but it causes trouble with GCC.
2103 dnl     -Wstrict-overflow=2
2104
2105 dnl    These seem to require annotations that we don't currently use,
2106 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2107 dnl     -Wthread-safety
2108 dnl     -Wthread-safety-analysis
2109 dnl     -Wthread-safety-attributes
2110 dnl     -Wthread-safety-beta
2111 dnl     -Wthread-safety-precise
2112
2113   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2114   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2115   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2116   CFLAGS="$CFLAGS -Wwrite-strings"
2117   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2118   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
2119   CFLAGS="$CFLAGS -Wunused-parameter "
2120   # These interfere with building main() { return 0; }, which autoconf
2121   # likes to use as its default program.
2122   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
2123
2124   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2125     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2126   fi
2127   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2128     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2129   fi
2130
2131   if test "x$enable_fatal_warnings" = "xyes"; then
2132     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2133     # default autoconf programs are full of errors.
2134     CFLAGS="$CFLAGS -Werror"
2135   fi
2136
2137 fi
2138
2139 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2140    case "$host_os" in
2141     darwin*)
2142       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2143    esac
2144 fi
2145
2146 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2147
2148 AC_CONFIG_FILES([
2149         Doxyfile
2150         Makefile
2151         contrib/dist/suse/tor.sh
2152         contrib/operator-tools/tor.logrotate
2153         contrib/dist/tor.sh
2154         contrib/dist/torctl
2155         contrib/dist/tor.service
2156         src/config/torrc.sample
2157         src/config/torrc.minimal
2158         src/rust/.cargo/config
2159         scripts/maint/checkOptionDocs.pl
2160         scripts/maint/updateVersions.pl
2161 ])
2162
2163 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2164   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2165   for file in $regular_mans ; do
2166     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2167       echo "==================================";
2168       echo;
2169       echo "Building Tor has failed since manpages cannot be built.";
2170       echo;
2171       echo "You need asciidoc installed to be able to build the manpages.";
2172       echo "To build without manpages, use the --disable-asciidoc argument";
2173       echo "when calling configure.";
2174       echo;
2175       echo "==================================";
2176       exit 1;
2177     fi
2178   done
2179 fi
2180
2181 if test "$fragile_hardening" = "yes"; then
2182   AC_MSG_WARN([
2183
2184 ============
2185 Warning!  Building Tor with --enable-fragile-hardening (also known as
2186 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2187 other kinds of attacks easier. A Tor instance build with this option will be
2188 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2189 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2190 denial of service attacks. For more information, see
2191 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2192 ============
2193   ])
2194 fi
2195
2196 AC_OUTPUT