configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2017, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.2.0-alpha-dev])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56 AC_ARG_ENABLE(memory-sentinels,
  57    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  58 AC_ARG_ENABLE(rust,
  59    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  60 AC_ARG_ENABLE(cargo-online-mode,
  61    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  62
  63 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  64     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  65 fi
  66
  67 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  68 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  69 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  70 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  71 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  72 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  73
  74 if test "$enable_static_tor" = "yes"; then
  75   enable_static_libevent="yes";
  76   enable_static_openssl="yes";
  77   enable_static_zlib="yes";
  78   CFLAGS="$CFLAGS -static"
  79 fi
  80
  81 if test "$enable_system_torrc" = "no"; then
  82   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  83             [Defined if we're not going to look for a torrc in SYSCONF])
  84 fi
  85
  86 if test "$enable_memory_sentinels" = "no"; then
  87   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  88            [Defined if we're turning off memory safety code to look for bugs])
  89 fi
  90
  91 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  92
  93 AC_ARG_ENABLE(asciidoc,
  94      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  95      [case "${enableval}" in
  96         "yes") asciidoc=true ;;
  97         "no")  asciidoc=false ;;
  98         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  99       esac], [asciidoc=true])
 100
 101 # systemd notify support
 102 AC_ARG_ENABLE(systemd,
 103       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 104       [case "${enableval}" in
 105         "yes") systemd=true ;;
 106         "no")  systemd=false ;;
 107         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 108       esac], [systemd=auto])
 109
 110
 111
 112 # systemd support
 113 if test "x$enable_systemd" = "xno"; then
 114     have_systemd=no;
 115 else
 116     PKG_CHECK_MODULES(SYSTEMD,
 117         [libsystemd-daemon],
 118         have_systemd=yes,
 119         have_systemd=no)
 120     if test "x$have_systemd" = "xno"; then
 121         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 122         PKG_CHECK_MODULES(SYSTEMD,
 123             [libsystemd],
 124             have_systemd=yes,
 125             have_systemd=no)
 126     fi
 127 fi
 128
 129 if test "x$have_systemd" = "xyes"; then
 130     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 131     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 132     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 133     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 134          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 135 fi
 136 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 137 AC_SUBST(TOR_SYSTEMD_LIBS)
 138
 139 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 140     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 141 fi
 142
 143 case "$host" in
 144    *-*-solaris* )
 145      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 146      ;;
 147 esac
 148
 149 AC_ARG_ENABLE(gcc-warnings,
 150      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 151 AC_ARG_ENABLE(fatal-warnings,
 152      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 153 AC_ARG_ENABLE(gcc-warnings-advisory,
 154      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 155
 156 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 157 AC_ARG_ENABLE(gcc-hardening,
 158     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 159
 160 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 161 AC_ARG_ENABLE(expensive-hardening,
 162     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 163 AC_ARG_ENABLE(fragile-hardening,
 164     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 165 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 166   fragile_hardening="yes"
 167 fi
 168
 169 dnl Linker hardening options
 170 dnl Currently these options are ELF specific - you can't use this with MacOSX
 171 AC_ARG_ENABLE(linker-hardening,
 172     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 173
 174 AC_ARG_ENABLE(local-appdata,
 175    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 176 if test "$enable_local_appdata" = "yes"; then
 177   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 178             [Defined if we default to host local appdata paths on Windows])
 179 fi
 180
 181 # Tor2web mode flag
 182 AC_ARG_ENABLE(tor2web-mode,
 183      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 184 [if test "x$enableval" = "xyes"; then
 185     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 186 fi])
 187
 188 AC_ARG_ENABLE(tool-name-check,
 189      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 190
 191 AC_ARG_ENABLE(seccomp,
 192      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 193
 194 AC_ARG_ENABLE(libscrypt,
 195      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 196
 197 dnl Enable event tracing which are transformed to debug log statement.
 198 AC_ARG_ENABLE(event-tracing-debug,
 199      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 200 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 201
 202 if test x$enable_event_tracing_debug = xyes; then
 203   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 204   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 205 fi
 206
 207 dnl check for the correct "ar" when cross-compiling.
 208 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 209 dnl    so kludge up a replacement for the case where it isn't there yet.)
 210 m4_ifdef([AM_PROG_AR],
 211          [AM_PROG_AR],
 212          [AN_MAKEVAR([AR], [AC_PROG_AR])
 213           AN_PROGRAM([ar], [AC_PROG_AR])
 214           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 215           AC_PROG_AR])
 216
 217 dnl Check whether the above macro has settled for a simply named tool even
 218 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 219 dnl because that will find any cc on the system, not only the cross-compiler,
 220 dnl and then verify that a binary built with this compiler runs on the
 221 dnl build system. It will then come to the false conclusion that we're not
 222 dnl cross-compiling.
 223 if test "x$enable_tool_name_check" != "xno"; then
 224     if test "x$ac_tool_warned" = "xyes"; then
 225         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 226         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 227                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 228         fi
 229 fi
 230
 231 AC_PROG_CC
 232 AC_PROG_CPP
 233 AC_PROG_MAKE_SET
 234 AC_PROG_RANLIB
 235 AC_PROG_SED
 236
 237 AC_ARG_VAR([PERL], [path to Perl binary])
 238 AC_CHECK_PROGS([PERL], [perl])
 239 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 240
 241 dnl check for asciidoc and a2x
 242 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 243 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 244
 245 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 246
 247 AM_PROG_CC_C_O
 248 AC_PROG_CC_C99
 249
 250 AC_ARG_VAR([PYTHON], [path to Python binary])
 251 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 252 if test "x$PYTHON" = "x"; then
 253   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 254 fi
 255 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 256
 257 dnl List all external rust crates we depend on here. Include the version
 258 rust_crates="libc-0.2.22"
 259 AC_SUBST(rust_crates)
 260
 261 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 262 AC_C_FLEXIBLE_ARRAY_MEMBER
 263 ], [
 264  dnl Maybe we've got an old autoconf...
 265  AC_CACHE_CHECK([for flexible array members],
 266      tor_cv_c_flexarray,
 267      [AC_COMPILE_IFELSE(
 268        AC_LANG_PROGRAM([
 269  struct abc { int a; char b[]; };
 270 ], [
 271  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 272  def->b[0] = 33;
 273 ]),
 274   [tor_cv_c_flexarray=yes],
 275   [tor_cv_c_flexarray=no])])
 276  if test "$tor_cv_flexarray" = "yes"; then
 277    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 278  else
 279    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 280  fi
 281 ])
 282
 283 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 284       tor_cv_c_c99_decl,
 285       [AC_COMPILE_IFELSE(
 286          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 287          [tor_cv_c_c99_decl=yes],
 288          [tor_cv_c_c99_decl=no] )])
 289 if test "$tor_cv_c_c99_decl" != "yes"; then
 290   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 291 fi
 292
 293 AC_CACHE_CHECK([for working C99 designated initializers],
 294       tor_cv_c_c99_designated_init,
 295       [AC_COMPILE_IFELSE(
 296          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 297                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 298          [tor_cv_c_c99_designated_init=yes],
 299          [tor_cv_c_c99_designated_init=no] )])
 300
 301 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 302   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 303 fi
 304
 305 TORUSER=_tor
 306 AC_ARG_WITH(tor-user,
 307         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 308         [
 309            TORUSER=$withval
 310         ]
 311 )
 312 AC_SUBST(TORUSER)
 313
 314 TORGROUP=_tor
 315 AC_ARG_WITH(tor-group,
 316         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 317         [
 318            TORGROUP=$withval
 319         ]
 320 )
 321 AC_SUBST(TORGROUP)
 322
 323
 324 dnl If _WIN32 is defined and non-zero, we are building for win32
 325 AC_MSG_CHECKING([for win32])
 326 AC_RUN_IFELSE([AC_LANG_SOURCE([
 327 int main(int c, char **v) {
 328 #ifdef _WIN32
 329 #if _WIN32
 330   return 0;
 331 #else
 332   return 1;
 333 #endif
 334 #else
 335   return 2;
 336 #endif
 337 }])],
 338 bwin32=true; AC_MSG_RESULT([yes]),
 339 bwin32=false; AC_MSG_RESULT([no]),
 340 bwin32=cross; AC_MSG_RESULT([cross])
 341 )
 342
 343 if test "$bwin32" = "cross"; then
 344 AC_MSG_CHECKING([for win32 (cross)])
 345 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 346 #ifdef _WIN32
 347 int main(int c, char **v) {return 0;}
 348 #else
 349 #error
 350 int main(int c, char **v) {return x(y);}
 351 #endif
 352 ])],
 353 bwin32=true; AC_MSG_RESULT([yes]),
 354 bwin32=false; AC_MSG_RESULT([no]))
 355 fi
 356
 357 AH_BOTTOM([
 358 #ifdef _WIN32
 359 /* Defined to access windows functions and definitions for >=WinXP */
 360 # ifndef WINVER
 361 #  define WINVER 0x0501
 362 # endif
 363
 364 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 365 # ifndef _WIN32_WINNT
 366 #  define _WIN32_WINNT 0x0501
 367 # endif
 368
 369 /* Defined to avoid including some windows headers as part of Windows.h */
 370 # ifndef WIN32_LEAN_AND_MEAN
 371 #  define WIN32_LEAN_AND_MEAN 1
 372 # endif
 373 #endif
 374 ])
 375
 376
 377 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 378
 379 dnl Enable C99 when compiling with MIPSpro
 380 AC_MSG_CHECKING([for MIPSpro compiler])
 381 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 382 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 383 #error
 384   return x(y);
 385 #endif
 386 ])],
 387 bmipspro=false; AC_MSG_RESULT(no),
 388 bmipspro=true; AC_MSG_RESULT(yes))
 389
 390 if test "$bmipspro" = "true"; then
 391   CFLAGS="$CFLAGS -c99"
 392 fi
 393
 394 AC_C_BIGENDIAN
 395
 396 if test "x$enable_rust" = "xyes"; then
 397   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 398   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 399   if test "x$RUSTC" = "xno"; then
 400     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 401   fi
 402
 403   AC_ARG_VAR([CARGO], [path to the cargo binary])
 404   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 405   if test "x$CARGO" = "xno"; then
 406     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 407   fi
 408
 409   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 410   if test "x$enable_cargo_online_mode" = "xyes"; then
 411     CARGO_ONLINE=
 412     RUST_DL=#
 413   else
 414     CARGO_ONLINE=--frozen
 415     RUST_DL=
 416
 417     dnl When we're not allowed to touch the network, we need crate dependencies
 418     dnl locally available.
 419     AC_MSG_CHECKING([rust crate dependencies])
 420     AC_ARG_VAR([RUST_DEPENDENCIES], [path to directory with local crate mirror])
 421     if test "x$RUST_DEPENDENCIES" = "x"; then
 422       RUST_DEPENDENCIES="$srcdir/src/ext/rust/"
 423       NEED_MOD=1
 424     fi
 425     if test ! -d "$RUST_DEPENDENCIES"; then
 426       AC_MSG_ERROR([Rust dependency directory $RUST_DEPENDENCIES does not exist. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 427     fi
 428     for dep in $rust_crates; do
 429       if test ! -d "$RUST_DEPENDENCIES"/"$dep"; then
 430         AC_MSG_ERROR([Failure to find rust dependency $RUST_DEPENDENCIES/$dep. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 431       fi
 432     done
 433     if test "x$NEED_MOD" = "x1"; then
 434       dnl When looking for dependencies from cargo, pick right directory
 435       RUST_DEPENDENCIES="../../src/ext/rust"
 436     fi
 437   fi
 438
 439   dnl For now both MSVC and MinGW rust libraries will output static libs with
 440   dnl the MSVC naming convention.
 441   if test "$bwin32" = "true"; then
 442     TOR_RUST_UTIL_STATIC_NAME=tor_util.lib
 443   else
 444     TOR_RUST_UTIL_STATIC_NAME=libtor_util.a
 445   fi
 446
 447   AC_SUBST(TOR_RUST_UTIL_STATIC_NAME)
 448   AC_SUBST(CARGO_ONLINE)
 449   AC_SUBST(RUST_DL)
 450
 451   dnl Let's check the rustc version, too
 452   AC_MSG_CHECKING([rust version])
 453   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 454   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 455   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 456     AC_MSG_ERROR([rustc version couldn't be identified])
 457   fi
 458   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 459     AC_MSG_ERROR([rustc must be at least version 1.14])
 460   fi
 461 fi
 462
 463 AC_SEARCH_LIBS(socket, [socket network])
 464 AC_SEARCH_LIBS(gethostbyname, [nsl])
 465 AC_SEARCH_LIBS(dlopen, [dl])
 466 AC_SEARCH_LIBS(inet_aton, [resolv])
 467 AC_SEARCH_LIBS(backtrace, [execinfo])
 468 saved_LIBS="$LIBS"
 469 AC_SEARCH_LIBS([clock_gettime], [rt])
 470 if test "$LIBS" != "$saved_LIBS"; then
 471    # Looks like we need -lrt for clock_gettime().
 472    have_rt=yes
 473 fi
 474
 475 AC_SEARCH_LIBS(pthread_create, [pthread])
 476 AC_SEARCH_LIBS(pthread_detach, [pthread])
 477
 478 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 479 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 480
 481 AC_CHECK_FUNCS(
 482         _NSGetEnviron \
 483         RtlSecureZeroMemory \
 484         SecureZeroMemory \
 485         accept4 \
 486         backtrace \
 487         backtrace_symbols_fd \
 488         eventfd \
 489         explicit_bzero \
 490         timingsafe_memcmp \
 491         flock \
 492         ftime \
 493         get_current_dir_name \
 494         getaddrinfo \
 495         getifaddrs \
 496         getpass \
 497         getrlimit \
 498         gettimeofday \
 499         gmtime_r \
 500         htonll \
 501         inet_aton \
 502         ioctl \
 503         issetugid \
 504         llround \
 505         localtime_r \
 506         lround \
 507         memmem \
 508         memset_s \
 509         pipe \
 510         pipe2 \
 511         prctl \
 512         readpassphrase \
 513         rint \
 514         sigaction \
 515         socketpair \
 516         statvfs \
 517         strlcat \
 518         strlcpy \
 519         strnlen \
 520         strptime \
 521         strtok_r \
 522         strtoull \
 523         sysconf \
 524         sysctl \
 525         truncate \
 526         uname \
 527         usleep \
 528         vasprintf \
 529         _vscprintf
 530 )
 531
 532 # Apple messed up when they added two functions functions in Sierra: they
 533 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 534 # checks. So we should only probe for those functions if we are sure that we
 535 # are not targetting OSX 10.11 or earlier.
 536 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 537 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 538 #ifdef __APPLE__
 539 #  include <AvailabilityMacros.h>
 540 #  ifndef MAC_OS_X_VERSION_10_12
 541 #    define MAC_OS_X_VERSION_10_12 101200
 542 #  endif
 543 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 544 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 545 #      error "Running on Mac OSX 10.11 or earlier"
 546 #    endif
 547 #  endif
 548 #endif
 549 ]], [[]])],
 550    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 551    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 552
 553 if test "$on_macos_pre_10_12" = "no"; then
 554   AC_CHECK_FUNCS(
 555         clock_gettime \
 556         getentropy \
 557   )
 558 fi
 559
 560 if test "$bwin32" != "true"; then
 561   AC_CHECK_HEADERS(pthread.h)
 562   AC_CHECK_FUNCS(pthread_create)
 563   AC_CHECK_FUNCS(pthread_condattr_setclock)
 564 fi
 565
 566 if test "$bwin32" = "true"; then
 567   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 568 #include <windows.h>
 569 #include <conio.h>
 570 #include <wchar.h>
 571                  ])
 572 fi
 573
 574 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 575   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 576
 577 dnl ------------------------------------------------------
 578 dnl Where do you live, libevent?  And how do we call you?
 579
 580 if test "$bwin32" = "true"; then
 581   TOR_LIB_WS32=-lws2_32
 582   TOR_LIB_IPHLPAPI=-liphlpapi
 583   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 584   # think it's actually necessary.
 585   TOR_LIB_GDI=-lgdi32
 586   TOR_LIB_USERENV=-luserenv
 587 else
 588   TOR_LIB_WS32=
 589   TOR_LIB_GDI=
 590   TOR_LIB_USERENV=
 591 fi
 592 AC_SUBST(TOR_LIB_WS32)
 593 AC_SUBST(TOR_LIB_GDI)
 594 AC_SUBST(TOR_LIB_IPHLPAPI)
 595 AC_SUBST(TOR_LIB_USERENV)
 596
 597 tor_libevent_pkg_redhat="libevent"
 598 tor_libevent_pkg_debian="libevent-dev"
 599 tor_libevent_devpkg_redhat="libevent-devel"
 600 tor_libevent_devpkg_debian="libevent-dev"
 601
 602 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 603 dnl linking for static builds.
 604 STATIC_LIBEVENT_FLAGS=""
 605 if test "$enable_static_libevent" = "yes"; then
 606     if test "$have_rt" = "yes"; then
 607       STATIC_LIBEVENT_FLAGS=" -lrt "
 608     fi
 609 fi
 610
 611 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 612 #ifdef _WIN32
 613 #include <winsock2.h>
 614 #endif
 615 #include <sys/time.h>
 616 #include <sys/types.h>
 617 #include <event2/event.h>], [
 618 #ifdef _WIN32
 619 #include <winsock2.h>
 620 #endif
 621 struct event_base;
 622 struct event_base *event_base_new(void);],
 623     [
 624 #ifdef _WIN32
 625 {WSADATA d; WSAStartup(0x101,&d); }
 626 #endif
 627 event_base_new();
 628 ], [--with-libevent-dir], [/opt/libevent])
 629
 630 dnl Determine the incantation needed to link libevent.
 631 save_LIBS="$LIBS"
 632 save_LDFLAGS="$LDFLAGS"
 633 save_CPPFLAGS="$CPPFLAGS"
 634
 635 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 636 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 637 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 638
 639 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 640
 641 if test "$enable_static_libevent" = "yes"; then
 642    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 643      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 644    else
 645      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 646    fi
 647 else
 648      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 649        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 650        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 651
 652        if test "$ac_cv_search_event_new" != "none required"; then
 653          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 654        fi
 655        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 656          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 657        fi
 658      else
 659        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 660      fi
 661 fi
 662
 663 dnl Now check for particular libevent functions.
 664 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 665                 evutil_secure_rng_add_bytes \
 666 ])
 667
 668 LIBS="$save_LIBS"
 669 LDFLAGS="$save_LDFLAGS"
 670 CPPFLAGS="$save_CPPFLAGS"
 671
 672 dnl Check that libevent is at least at version 2.0.10, the first stable
 673 dnl release of its series
 674 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 675 AC_MSG_CHECKING([whether Libevent is new enough])
 676 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 677 #include <event2/event.h>
 678 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 679 #error
 680 int x = y(zz);
 681 #else
 682 int x = 1;
 683 #endif
 684 ])], [ AC_MSG_RESULT([yes]) ],
 685    [ AC_MSG_RESULT([no])
 686      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 687
 688 LIBS="$save_LIBS"
 689 LDFLAGS="$save_LDFLAGS"
 690 CPPFLAGS="$save_CPPFLAGS"
 691
 692 AC_SUBST(TOR_LIBEVENT_LIBS)
 693
 694 dnl ------------------------------------------------------
 695 dnl Where do you live, libm?
 696
 697 dnl On some platforms (Haiku/BeOS) the math library is
 698 dnl part of libroot. In which case don't link against lm
 699 TOR_LIB_MATH=""
 700 save_LIBS="$LIBS"
 701 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 702 if test "$ac_cv_search_pow" != "none required"; then
 703     TOR_LIB_MATH="$ac_cv_search_pow"
 704 fi
 705 LIBS="$save_LIBS"
 706 AC_SUBST(TOR_LIB_MATH)
 707
 708 dnl ------------------------------------------------------
 709 dnl Where do you live, openssl?  And how do we call you?
 710
 711 tor_openssl_pkg_redhat="openssl"
 712 tor_openssl_pkg_debian="libssl-dev"
 713 tor_openssl_devpkg_redhat="openssl-devel"
 714 tor_openssl_devpkg_debian="libssl-dev"
 715
 716 ALT_openssl_WITHVAL=""
 717 AC_ARG_WITH(ssl-dir,
 718   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 719   [
 720       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 721          ALT_openssl_WITHVAL="$withval"
 722       fi
 723   ])
 724
 725 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 726     [#include <openssl/rand.h>],
 727     [void RAND_add(const void *buf, int num, double entropy);],
 728     [RAND_add((void*)0,0,0);], [],
 729     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 730
 731 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 732
 733 if test "$enable_static_openssl" = "yes"; then
 734    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 735      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 736    else
 737      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 738    fi
 739 else
 740      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 741 fi
 742 AC_SUBST(TOR_OPENSSL_LIBS)
 743
 744 dnl Now check for particular openssl functions.
 745 save_LIBS="$LIBS"
 746 save_LDFLAGS="$LDFLAGS"
 747 save_CPPFLAGS="$CPPFLAGS"
 748 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 749 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 750 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 751
 752 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 753 #include <openssl/opensslv.h>
 754 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 755 #error "too old"
 756 #endif
 757    ]], [[]])],
 758    [ : ],
 759    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 760
 761 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 762 #include <openssl/opensslv.h>
 763 #include <openssl/evp.h>
 764 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 765 #error "no ECC"
 766 #endif
 767 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 768 #error "curves unavailable"
 769 #endif
 770    ]], [[]])],
 771    [ : ],
 772    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 773
 774 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 775 [#include <openssl/ssl.h>
 776 ])
 777
 778 AC_CHECK_FUNCS([ \
 779                 SSL_SESSION_get_master_key \
 780                 SSL_get_server_random \
 781                 SSL_get_client_ciphers \
 782                 SSL_get_client_random \
 783                 SSL_CIPHER_find \
 784                 TLS_method
 785                ])
 786
 787 dnl Check if OpenSSL has scrypt implementation.
 788 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 789
 790 dnl Check if OpenSSL structures are opaque
 791 AC_CHECK_MEMBERS([SSL.state], , ,
 792 [#include <openssl/ssl.h>
 793 ])
 794
 795 LIBS="$save_LIBS"
 796 LDFLAGS="$save_LDFLAGS"
 797 CPPFLAGS="$save_CPPFLAGS"
 798
 799 dnl ------------------------------------------------------
 800 dnl Where do you live, zlib?  And how do we call you?
 801
 802 tor_zlib_pkg_redhat="zlib"
 803 tor_zlib_pkg_debian="zlib1g"
 804 tor_zlib_devpkg_redhat="zlib-devel"
 805 tor_zlib_devpkg_debian="zlib1g-dev"
 806
 807 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 808     [#include <zlib.h>],
 809     [const char * zlibVersion(void);],
 810     [zlibVersion();], [--with-zlib-dir],
 811     [/opt/zlib])
 812
 813 if test "$enable_static_zlib" = "yes"; then
 814    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 815      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 816  using --enable-static-zlib")
 817    else
 818      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 819    fi
 820 else
 821      TOR_ZLIB_LIBS="-lz"
 822 fi
 823 AC_SUBST(TOR_ZLIB_LIBS)
 824
 825 dnl ------------------------------------------------------
 826 dnl Where we do we find lzma?
 827
 828 AC_ARG_ENABLE(lzma,
 829       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
 830       [case "${enableval}" in
 831         "yes") lzma=true ;;
 832         "no")  lzma=false ;;
 833         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
 834       esac], [lzma=auto])
 835
 836 if test "x$enable_lzma" = "xno"; then
 837     have_lzma=no;
 838 else
 839     PKG_CHECK_MODULES([LZMA],
 840                       [liblzma],
 841                       have_lzma=yes,
 842                       have_lzma=no)
 843
 844     if test "x$have_lzma" = "xno" ; then
 845         AC_MSG_WARN([Unable to find liblzma.])
 846     fi
 847 fi
 848
 849 if test "x$have_lzma" = "xyes"; then
 850     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
 851     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
 852     TOR_LZMA_LIBS="${LZMA_LIBS}"
 853 fi
 854 AC_SUBST(TOR_LZMA_CFLAGS)
 855 AC_SUBST(TOR_LZMA_LIBS)
 856
 857 dnl ------------------------------------------------------
 858 dnl Where we do we find zstd?
 859
 860 AC_ARG_ENABLE(zstd,
 861       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
 862       [case "${enableval}" in
 863         "yes") zstd=true ;;
 864         "no")  zstd=false ;;
 865         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
 866       esac], [zstd=auto])
 867
 868 if test "x$enable_zstd" = "xno"; then
 869     have_zstd=no;
 870 else
 871     PKG_CHECK_MODULES([ZSTD],
 872                       [libzstd >= 1.1],
 873                       have_zstd=yes,
 874                       have_zstd=no)
 875
 876     if test "x$have_zstd" = "xno" ; then
 877         AC_MSG_WARN([Unable to find libzstd.])
 878     fi
 879 fi
 880
 881 if test "x$have_zstd" = "xyes"; then
 882     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
 883     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
 884     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
 885 fi
 886 AC_SUBST(TOR_ZSTD_CFLAGS)
 887 AC_SUBST(TOR_ZSTD_LIBS)
 888
 889 dnl ----------------------------------------------------------------------
 890 dnl Check if libcap is available for capabilities.
 891
 892 tor_cap_pkg_debian="libcap2"
 893 tor_cap_pkg_redhat="libcap"
 894 tor_cap_devpkg_debian="libcap-dev"
 895 tor_cap_devpkg_redhat="libcap-devel"
 896
 897 AC_CHECK_LIB([cap], [cap_init], [],
 898   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 899 )
 900 AC_CHECK_FUNCS(cap_set_proc)
 901
 902 dnl ---------------------------------------------------------------------
 903 dnl Now that we know about our major libraries, we can check for compiler
 904 dnl and linker hardening options.  We need to do this with the libraries known,
 905 dnl since sometimes the linker will like an option but not be willing to
 906 dnl use it with a build of a library.
 907
 908 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 909 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
 910
 911 CFLAGS_FTRAPV=
 912 CFLAGS_FWRAPV=
 913 CFLAGS_ASAN=
 914 CFLAGS_UBSAN=
 915
 916
 917 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 918 #if !defined(__clang__)
 919 #error
 920 #endif])], have_clang=yes, have_clang=no)
 921
 922 if test "x$enable_gcc_hardening" != "xno"; then
 923     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 924     if test "x$have_clang" = "xyes"; then
 925         TOR_CHECK_CFLAGS(-Qunused-arguments)
 926     fi
 927     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 928     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 929     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 930 m4_ifdef([AS_VAR_IF],[
 931     AS_VAR_IF(can_compile, [yes],
 932         AS_VAR_IF(can_link, [yes],
 933                   [],
 934                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 935         )])
 936     AS_VAR_POPDEF([can_link])
 937     AS_VAR_POPDEF([can_compile])
 938     TOR_CHECK_CFLAGS(-Wstack-protector)
 939     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 940     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
 941        TOR_CHECK_CFLAGS(-fPIE)
 942        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 943     fi
 944     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
 945 fi
 946
 947 if test "$fragile_hardening" = "yes"; then
 948     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
 949    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
 950       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
 951    fi
 952
 953    if test "$tor_cv_cflags__ftrapv" != "yes"; then
 954      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
 955    fi
 956
 957    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
 958     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 959       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
 960     fi
 961
 962    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
 963     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 964       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
 965     fi
 966
 967 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 968 fi
 969
 970 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
 971 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
 972
 973 mulodi_fixes_ftrapv=no
 974 if test "$have_clang" = "yes"; then
 975   saved_CFLAGS="$CFLAGS"
 976   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
 977   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
 978   AC_LINK_IFELSE([
 979       AC_LANG_SOURCE([[
 980           #include <stdint.h>
 981           #include <stdlib.h>
 982           int main(int argc, char **argv)
 983           {
 984             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
 985                         * (int64_t)atoi(argv[3]);
 986             return x == 9;
 987           } ]])],
 988           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
 989           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
 990   if test "$ftrapv_can_link" = "no"; then
 991     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
 992     AC_LINK_IFELSE([
 993       AC_LANG_SOURCE([[
 994           #include <stdint.h>
 995           #include <stdlib.h>
 996           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
 997              *overflow=0;
 998              return a;
 999           }
1000           int main(int argc, char **argv)
1001           {
1002             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1003                         * (int64_t)atoi(argv[3]);
1004             return x == 9;
1005           } ]])],
1006           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1007           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1008   fi
1009   CFLAGS="$saved_CFLAGS"
1010 fi
1011
1012 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1013
1014 dnl These cflags add bunches of branches, and we haven't been able to
1015 dnl persuade ourselves that they're suitable for code that needs to be
1016 dnl constant time.
1017 AC_SUBST(CFLAGS_BUGTRAP)
1018 dnl These cflags are variant ones sutable for code that needs to be
1019 dnl constant-time.
1020 AC_SUBST(CFLAGS_CONSTTIME)
1021
1022 if test "x$enable_linker_hardening" != "xno"; then
1023     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1024 fi
1025
1026 # For backtrace support
1027 TOR_CHECK_LDFLAGS(-rdynamic)
1028
1029 dnl ------------------------------------------------------
1030 dnl Now see if we have a -fomit-frame-pointer compiler option.
1031
1032 saved_CFLAGS="$CFLAGS"
1033 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1034 F_OMIT_FRAME_POINTER=''
1035 if test "$saved_CFLAGS" != "$CFLAGS"; then
1036   if test "$fragile_hardening" = "yes"; then
1037     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1038   fi
1039 fi
1040 CFLAGS="$saved_CFLAGS"
1041 AC_SUBST(F_OMIT_FRAME_POINTER)
1042
1043 dnl ------------------------------------------------------
1044 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1045 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1046 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1047 dnl code will work.
1048 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1049
1050 dnl ============================================================
1051 dnl Check for libseccomp
1052
1053 if test "x$enable_seccomp" != "xno"; then
1054   AC_CHECK_HEADERS([seccomp.h])
1055   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1056 fi
1057
1058 dnl ============================================================
1059 dnl Check for libscrypt
1060
1061 if test "x$enable_libscrypt" != "xno"; then
1062   AC_CHECK_HEADERS([libscrypt.h])
1063   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1064   AC_CHECK_FUNCS([libscrypt_scrypt])
1065 fi
1066
1067 dnl ============================================================
1068 dnl We need an implementation of curve25519.
1069
1070 dnl set these defaults.
1071 build_curve25519_donna=no
1072 build_curve25519_donna_c64=no
1073 use_curve25519_donna=no
1074 use_curve25519_nacl=no
1075 CURVE25519_LIBS=
1076
1077 dnl The best choice is using curve25519-donna-c64, but that requires
1078 dnl that we
1079 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1080   tor_cv_can_use_curve25519_donna_c64,
1081   [AC_RUN_IFELSE(
1082     [AC_LANG_PROGRAM([dnl
1083       #include <stdint.h>
1084       typedef unsigned uint128_t __attribute__((mode(TI)));
1085   int func(uint64_t a, uint64_t b) {
1086            uint128_t c = ((uint128_t)a) * b;
1087            int ok = ((uint64_t)(c>>96)) == 522859 &&
1088              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1089                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1090                  (((uint64_t)(c))&0xffffffffL) == 0;
1091            return ok;
1092       }
1093   ], [dnl
1094     int ok = func( ((uint64_t)2000000000) * 1000000000,
1095                    ((uint64_t)1234567890) << 24);
1096         return !ok;
1097       ])],
1098   [tor_cv_can_use_curve25519_donna_c64=yes],
1099       [tor_cv_can_use_curve25519_donna_c64=no],
1100   [AC_LINK_IFELSE(
1101         [AC_LANG_PROGRAM([dnl
1102       #include <stdint.h>
1103       typedef unsigned uint128_t __attribute__((mode(TI)));
1104   int func(uint64_t a, uint64_t b) {
1105            uint128_t c = ((uint128_t)a) * b;
1106            int ok = ((uint64_t)(c>>96)) == 522859 &&
1107              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1108                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1109                  (((uint64_t)(c))&0xffffffffL) == 0;
1110            return ok;
1111       }
1112   ], [dnl
1113     int ok = func( ((uint64_t)2000000000) * 1000000000,
1114                  ((uint64_t)1234567890) << 24);
1115         return !ok;
1116       ])],
1117           [tor_cv_can_use_curve25519_donna_c64=cross],
1118       [tor_cv_can_use_curve25519_donna_c64=no])])])
1119
1120 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1121                   nacl/crypto_scalarmult_curve25519.h])
1122
1123 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1124   tor_cv_can_use_curve25519_nacl,
1125   [tor_saved_LIBS="$LIBS"
1126    LIBS="$LIBS -lnacl"
1127    AC_LINK_IFELSE(
1128      [AC_LANG_PROGRAM([dnl
1129        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1130        #include <crypto_scalarmult_curve25519.h>
1131    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1132    #include <nacl/crypto_scalarmult_curve25519.h>
1133    #endif
1134        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1135    #error Hey, this is the reference implementation! That's not fast.
1136    #endif
1137      ], [
1138    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1139      ])], [tor_cv_can_use_curve25519_nacl=yes],
1140      [tor_cv_can_use_curve25519_nacl=no])
1141    LIBS="$tor_saved_LIBS" ])
1142
1143  dnl Okay, now we need to figure out which one to actually use. Fall back
1144  dnl to curve25519-donna.c
1145
1146  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1147    build_curve25519_donna_c64=yes
1148    use_curve25519_donna=yes
1149  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1150    use_curve25519_nacl=yes
1151    CURVE25519_LIBS=-lnacl
1152  else
1153    build_curve25519_donna=yes
1154    use_curve25519_donna=yes
1155  fi
1156
1157 if test "x$use_curve25519_donna" = "xyes"; then
1158   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1159             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1160 fi
1161 if test "x$use_curve25519_nacl" = "xyes"; then
1162   AC_DEFINE(USE_CURVE25519_NACL, 1,
1163             [Defined if we should use a curve25519 from nacl])
1164 fi
1165 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1166   test "x$build_curve25519_donna" = "xyes")
1167 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1168   test "x$build_curve25519_donna_c64" = "xyes")
1169 AC_SUBST(CURVE25519_LIBS)
1170
1171 dnl Make sure to enable support for large off_t if available.
1172 AC_SYS_LARGEFILE
1173
1174 AC_CHECK_HEADERS([assert.h \
1175                   errno.h \
1176                   fcntl.h \
1177                   signal.h \
1178                   string.h \
1179                   sys/capability.h \
1180                   sys/fcntl.h \
1181                   sys/stat.h \
1182                   sys/time.h \
1183                   sys/types.h \
1184                   time.h \
1185                   unistd.h \
1186                   arpa/inet.h \
1187                   crt_externs.h \
1188                   execinfo.h \
1189                   grp.h \
1190                   ifaddrs.h \
1191                   inttypes.h \
1192                   limits.h \
1193                   linux/types.h \
1194                   machine/limits.h \
1195                   malloc.h \
1196                   malloc/malloc.h \
1197                   malloc_np.h \
1198                   netdb.h \
1199                   netinet/in.h \
1200                   netinet/in6.h \
1201                   pwd.h \
1202                   readpassphrase.h \
1203                   stdint.h \
1204                   sys/eventfd.h \
1205                   sys/file.h \
1206                   sys/ioctl.h \
1207                   sys/limits.h \
1208                   sys/mman.h \
1209                   sys/param.h \
1210                   sys/prctl.h \
1211                   sys/random.h \
1212                   sys/resource.h \
1213                   sys/select.h \
1214                   sys/socket.h \
1215                   sys/statvfs.h \
1216                   sys/syscall.h \
1217                   sys/sysctl.h \
1218                   sys/syslimits.h \
1219                   sys/time.h \
1220                   sys/types.h \
1221                   sys/un.h \
1222                   sys/utime.h \
1223                   sys/wait.h \
1224                   syslog.h \
1225                   utime.h])
1226
1227 AC_CHECK_HEADERS(sys/param.h)
1228
1229 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1230 [#ifdef HAVE_SYS_TYPES_H
1231 #include <sys/types.h>
1232 #endif
1233 #ifdef HAVE_SYS_SOCKET_H
1234 #include <sys/socket.h>
1235 #endif])
1236 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1237 [#ifdef HAVE_SYS_TYPES_H
1238 #include <sys/types.h>
1239 #endif
1240 #ifdef HAVE_SYS_SOCKET_H
1241 #include <sys/socket.h>
1242 #endif
1243 #ifdef HAVE_NET_IF_H
1244 #include <net/if.h>
1245 #endif
1246 #ifdef HAVE_NETINET_IN_H
1247 #include <netinet/in.h>
1248 #endif])
1249
1250 AC_CHECK_HEADERS(linux/if.h,[],[],
1251 [
1252 #ifdef HAVE_SYS_SOCKET_H
1253 #include <sys/socket.h>
1254 #endif
1255 ])
1256
1257 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1258         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1259 [#ifdef HAVE_SYS_TYPES_H
1260 #include <sys/types.h>
1261 #endif
1262 #ifdef HAVE_SYS_SOCKET_H
1263 #include <sys/socket.h>
1264 #endif
1265 #ifdef HAVE_LIMITS_H
1266 #include <limits.h>
1267 #endif
1268 #ifdef HAVE_LINUX_TYPES_H
1269 #include <linux/types.h>
1270 #endif
1271 #ifdef HAVE_NETINET_IN6_H
1272 #include <netinet/in6.h>
1273 #endif
1274 #ifdef HAVE_NETINET_IN_H
1275 #include <netinet/in.h>
1276 #endif])
1277
1278 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1279         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1280 [#ifdef HAVE_SYS_TYPES_H
1281 #include <sys/types.h>
1282 #endif
1283 #ifdef HAVE_SYS_SOCKET_H
1284 #include <sys/socket.h>
1285 #endif
1286 #ifdef HAVE_LIMITS_H
1287 #include <limits.h>
1288 #endif
1289 #ifdef HAVE_LINUX_TYPES_H
1290 #include <linux/types.h>
1291 #endif
1292 #ifdef HAVE_NETINET_IN6_H
1293 #include <netinet/in6.h>
1294 #endif
1295 #ifdef HAVE_NETINET_IN_H
1296 #include <netinet/in.h>
1297 #endif
1298 #ifdef HAVE_LINUX_IF_H
1299 #include <linux/if.h>
1300 #endif])
1301
1302 transparent_ok=0
1303 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1304   transparent_ok=1
1305 fi
1306 if test "x$linux_netfilter_ipv4" = "x1"; then
1307   transparent_ok=1
1308 fi
1309 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1310   transparent_ok=1
1311 fi
1312 if test "x$transparent_ok" = "x1"; then
1313   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1314 else
1315   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1316 fi
1317
1318 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1319 [#ifdef HAVE_SYS_TYPES_H
1320 #include <sys/types.h>
1321 #endif
1322 #ifdef HAVE_SYS_TIME_H
1323 #include <sys/time.h>
1324 #endif])
1325
1326 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1327 dnl Watch out.
1328
1329 AC_CHECK_SIZEOF(int8_t)
1330 AC_CHECK_SIZEOF(int16_t)
1331 AC_CHECK_SIZEOF(int32_t)
1332 AC_CHECK_SIZEOF(int64_t)
1333 AC_CHECK_SIZEOF(uint8_t)
1334 AC_CHECK_SIZEOF(uint16_t)
1335 AC_CHECK_SIZEOF(uint32_t)
1336 AC_CHECK_SIZEOF(uint64_t)
1337 AC_CHECK_SIZEOF(intptr_t)
1338 AC_CHECK_SIZEOF(uintptr_t)
1339
1340 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1341
1342 AC_CHECK_SIZEOF(char)
1343 AC_CHECK_SIZEOF(short)
1344 AC_CHECK_SIZEOF(int)
1345 AC_CHECK_SIZEOF(long)
1346 AC_CHECK_SIZEOF(long long)
1347 AC_CHECK_SIZEOF(__int64)
1348 AC_CHECK_SIZEOF(void *)
1349 AC_CHECK_SIZEOF(time_t)
1350 AC_CHECK_SIZEOF(size_t)
1351 AC_CHECK_SIZEOF(pid_t)
1352
1353 AC_CHECK_TYPES([uint, u_char, ssize_t])
1354
1355 AC_PC_FROM_UCONTEXT([:])
1356
1357 dnl used to include sockaddr_storage, but everybody has that.
1358 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1359 [#ifdef HAVE_SYS_TYPES_H
1360 #include <sys/types.h>
1361 #endif
1362 #ifdef HAVE_NETINET_IN_H
1363 #include <netinet/in.h>
1364 #endif
1365 #ifdef HAVE_NETINET_IN6_H
1366 #include <netinet/in6.h>
1367 #endif
1368 #ifdef HAVE_SYS_SOCKET_H
1369 #include <sys/socket.h>
1370 #endif
1371 #ifdef _WIN32
1372 #define _WIN32_WINNT 0x0501
1373 #define WIN32_LEAN_AND_MEAN
1374 #include <winsock2.h>
1375 #include <ws2tcpip.h>
1376 #endif
1377 ])
1378 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1379 [#ifdef HAVE_SYS_TYPES_H
1380 #include <sys/types.h>
1381 #endif
1382 #ifdef HAVE_NETINET_IN_H
1383 #include <netinet/in.h>
1384 #endif
1385 #ifdef HAVE_NETINET_IN6_H
1386 #include <netinet/in6.h>
1387 #endif
1388 #ifdef HAVE_SYS_SOCKET_H
1389 #include <sys/socket.h>
1390 #endif
1391 #ifdef _WIN32
1392 #define _WIN32_WINNT 0x0501
1393 #define WIN32_LEAN_AND_MEAN
1394 #include <winsock2.h>
1395 #include <ws2tcpip.h>
1396 #endif
1397 ])
1398
1399 AC_CHECK_TYPES([rlim_t], , ,
1400 [#ifdef HAVE_SYS_TYPES_H
1401 #include <sys/types.h>
1402 #endif
1403 #ifdef HAVE_SYS_TIME_H
1404 #include <sys/time.h>
1405 #endif
1406 #ifdef HAVE_SYS_RESOURCE_H
1407 #include <sys/resource.h>
1408 #endif
1409 ])
1410
1411 AX_CHECK_SIGN([time_t],
1412        [ : ],
1413        [ : ], [
1414 #ifdef HAVE_SYS_TYPES_H
1415 #include <sys/types.h>
1416 #endif
1417 #ifdef HAVE_SYS_TIME_H
1418 #include <sys/time.h>
1419 #endif
1420 #ifdef HAVE_TIME_H
1421 #include <time.h>
1422 #endif
1423 ])
1424
1425 if test "$ax_cv_decl_time_t_signed" = "no"; then
1426   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1427 fi
1428
1429 AX_CHECK_SIGN([size_t],
1430        [ tor_cv_size_t_signed=yes ],
1431        [ tor_cv_size_t_signed=no ], [
1432 #ifdef HAVE_SYS_TYPES_H
1433 #include <sys/types.h>
1434 #endif
1435 ])
1436
1437 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1438   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1439 fi
1440
1441 AX_CHECK_SIGN([enum always],
1442        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1443        [ : ], [
1444  enum always { AAA, BBB, CCC };
1445 ])
1446
1447 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1448 #ifdef HAVE_SYS_SOCKET_H
1449 #include <sys/socket.h>
1450 #endif
1451 ])
1452
1453 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1454
1455 AC_CHECK_SIZEOF(cell_t)
1456
1457 # Now make sure that NULL can be represented as zero bytes.
1458 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1459 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1460 [[#include <stdlib.h>
1461 #include <string.h>
1462 #include <stdio.h>
1463 #ifdef HAVE_STDDEF_H
1464 #include <stddef.h>
1465 #endif
1466 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1467 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1468        [tor_cv_null_is_zero=yes],
1469        [tor_cv_null_is_zero=no],
1470        [tor_cv_null_is_zero=cross])])
1471
1472 if test "$tor_cv_null_is_zero" = "cross"; then
1473   # Cross-compiling; let's hope that the target isn't raving mad.
1474   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1475 fi
1476
1477 if test "$tor_cv_null_is_zero" != "no"; then
1478   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1479             [Define to 1 iff memset(0) sets pointers to NULL])
1480 fi
1481
1482 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1483 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1484 [[#include <stdlib.h>
1485 #include <string.h>
1486 #include <stdio.h>
1487 #ifdef HAVE_STDDEF_H
1488 #include <stddef.h>
1489 #endif
1490 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1491 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1492        [tor_cv_dbl0_is_zero=yes],
1493        [tor_cv_dbl0_is_zero=no],
1494        [tor_cv_dbl0_is_zero=cross])])
1495
1496 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1497   # Cross-compiling; let's hope that the target isn't raving mad.
1498   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1499 fi
1500
1501 if test "$tor_cv_dbl0_is_zero" != "no"; then
1502   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1503             [Define to 1 iff memset(0) sets doubles to 0.0])
1504 fi
1505
1506 # And what happens when we malloc zero?
1507 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1508 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1509 [[#include <stdlib.h>
1510 #include <string.h>
1511 #include <stdio.h>
1512 #ifdef HAVE_STDDEF_H
1513 #include <stddef.h>
1514 #endif
1515 int main () { return malloc(0)?0:1; }]])],
1516        [tor_cv_malloc_zero_works=yes],
1517        [tor_cv_malloc_zero_works=no],
1518        [tor_cv_malloc_zero_works=cross])])
1519
1520 if test "$tor_cv_malloc_zero_works" = "cross"; then
1521   # Cross-compiling; let's hope that the target isn't raving mad.
1522   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1523 fi
1524
1525 if test "$tor_cv_malloc_zero_works" = "yes"; then
1526   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1527             [Define to 1 iff malloc(0) returns a pointer])
1528 fi
1529
1530 # whether we seem to be in a 2s-complement world.
1531 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1532 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1533 [[int main () { int problem = ((-99) != (~99)+1);
1534 return problem ? 1 : 0; }]])],
1535        [tor_cv_twos_complement=yes],
1536        [tor_cv_twos_complement=no],
1537        [tor_cv_twos_complement=cross])])
1538
1539 if test "$tor_cv_twos_complement" = "cross"; then
1540   # Cross-compiling; let's hope that the target isn't raving mad.
1541   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1542 fi
1543
1544 if test "$tor_cv_twos_complement" != "no"; then
1545   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1546             [Define to 1 iff we represent negative integers with
1547              two's complement])
1548 fi
1549
1550 # What does shifting a negative value do?
1551 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1552 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1553 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1554        [tor_cv_sign_extend=yes],
1555        [tor_cv_sign_extend=no],
1556        [tor_cv_sign_extend=cross])])
1557
1558 if test "$tor_cv_sign_extend" = "cross"; then
1559   # Cross-compiling; let's hope that the target isn't raving mad.
1560   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1561 fi
1562
1563 if test "$tor_cv_sign_extend" != "no"; then
1564   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1565             [Define to 1 iff right-shifting a negative value performs sign-extension])
1566 fi
1567
1568 # Is uint8_t the same type as unsigned char?
1569 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1570 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1571 #include <stdint.h>
1572 extern uint8_t c;
1573 unsigned char c;]])],
1574        [tor_cv_uint8_uchar=yes],
1575        [tor_cv_uint8_uchar=no],
1576        [tor_cv_uint8_uchar=cross])])
1577
1578 if test "$tor_cv_uint8_uchar" = "cross"; then
1579   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1580 fi
1581
1582 if test "$tor_cv_uint8_uchar" = "no"; then
1583   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1584 fi
1585
1586 # Whether we should use the dmalloc memory allocation debugging library.
1587 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1588 AC_ARG_WITH(dmalloc,
1589 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1590 [if [[ "$withval" = "yes" ]]; then
1591   dmalloc=1
1592   AC_MSG_RESULT(yes)
1593 else
1594   dmalloc=1
1595   AC_MSG_RESULT(no)
1596 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1597 )
1598
1599 if [[ $dmalloc -eq 1 ]]; then
1600   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1601   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1602   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1603   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1604 fi
1605
1606 AC_ARG_WITH(tcmalloc,
1607 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1608 [ tcmalloc=yes ], [ tcmalloc=no ])
1609
1610 if test "x$tcmalloc" = "xyes"; then
1611    LDFLAGS="-ltcmalloc $LDFLAGS"
1612 fi
1613
1614 using_custom_malloc=no
1615 if test "x$enable_openbsd_malloc" = "xyes"; then
1616    using_custom_malloc=yes
1617 fi
1618 if test "x$tcmalloc" = "xyes"; then
1619    using_custom_malloc=yes
1620 fi
1621 if test "$using_custom_malloc" = "no"; then
1622    AC_CHECK_FUNCS(mallinfo)
1623 fi
1624
1625 # By default, we're going to assume we don't have mlockall()
1626 # bionic and other platforms have various broken mlockall subsystems.
1627 # Some systems don't have a working mlockall, some aren't linkable,
1628 # and some have it but don't declare it.
1629 AC_CHECK_FUNCS(mlockall)
1630 AC_CHECK_DECLS([mlockall], , , [
1631 #ifdef HAVE_SYS_MMAN_H
1632 #include <sys/mman.h>
1633 #endif])
1634
1635 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1636 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1637 # using macros
1638 AC_CHECK_DECLS([getpagesize], , , [
1639 #ifdef HAVE_UNISTD_H
1640 #include <unistd.h>
1641 #endif])
1642
1643 # Allow user to specify an alternate syslog facility
1644 AC_ARG_WITH(syslog-facility,
1645 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1646 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1647 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1648 AC_SUBST(LOGFACILITY)
1649
1650 # Check if we have getresuid and getresgid
1651 AC_CHECK_FUNCS(getresuid getresgid)
1652
1653 # Check for gethostbyname_r in all its glorious incompatible versions.
1654 #   (This logic is based on that in Python's configure.in)
1655 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1656   [Define this if you have any gethostbyname_r()])
1657
1658 AC_CHECK_FUNC(gethostbyname_r, [
1659   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1660   OLD_CFLAGS=$CFLAGS
1661   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1662   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1663 #include <netdb.h>
1664   ]], [[
1665     char *cp1, *cp2;
1666     struct hostent *h1, *h2;
1667     int i1, i2;
1668     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1669   ]])],[
1670     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1671     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1672      [Define this if gethostbyname_r takes 6 arguments])
1673     AC_MSG_RESULT(6)
1674   ], [
1675     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1676 #include <netdb.h>
1677     ]], [[
1678       char *cp1, *cp2;
1679       struct hostent *h1;
1680       int i1, i2;
1681       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1682     ]])], [
1683       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1684       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1685         [Define this if gethostbyname_r takes 5 arguments])
1686       AC_MSG_RESULT(5)
1687    ], [
1688       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1689 #include <netdb.h>
1690      ]], [[
1691        char *cp1;
1692        struct hostent *h1;
1693        struct hostent_data hd;
1694        (void) gethostbyname_r(cp1,h1,&hd);
1695      ]])], [
1696        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1697        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1698          [Define this if gethostbyname_r takes 3 arguments])
1699        AC_MSG_RESULT(3)
1700      ], [
1701        AC_MSG_RESULT(0)
1702      ])
1703   ])
1704  ])
1705  CFLAGS=$OLD_CFLAGS
1706 ])
1707
1708 AC_CACHE_CHECK([whether the C compiler supports __func__],
1709   tor_cv_have_func_macro,
1710   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1711 #include <stdio.h>
1712 int main(int c, char **v) { puts(__func__); }])],
1713   tor_cv_have_func_macro=yes,
1714   tor_cv_have_func_macro=no))
1715
1716 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1717   tor_cv_have_FUNC_macro,
1718   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1719 #include <stdio.h>
1720 int main(int c, char **v) { puts(__FUNC__); }])],
1721   tor_cv_have_FUNC_macro=yes,
1722   tor_cv_have_FUNC_macro=no))
1723
1724 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1725   tor_cv_have_FUNCTION_macro,
1726   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1727 #include <stdio.h>
1728 int main(int c, char **v) { puts(__FUNCTION__); }])],
1729   tor_cv_have_FUNCTION_macro=yes,
1730   tor_cv_have_FUNCTION_macro=no))
1731
1732 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1733   tor_cv_have_environ_declared,
1734   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1735 #ifdef HAVE_UNISTD_H
1736 #include <unistd.h>
1737 #endif
1738 #include <stdlib.h>
1739 int main(int c, char **v) { char **t = environ; }])],
1740   tor_cv_have_environ_declared=yes,
1741   tor_cv_have_environ_declared=no))
1742
1743 if test "$tor_cv_have_func_macro" = "yes"; then
1744   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1745 fi
1746
1747 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1748   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1749 fi
1750
1751 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1752   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1753            [Defined if the compiler supports __FUNCTION__])
1754 fi
1755
1756 if test "$tor_cv_have_environ_declared" = "yes"; then
1757   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1758            [Defined if we have extern char **environ already declared])
1759 fi
1760
1761 # $prefix stores the value of the --prefix command line option, or
1762 # NONE if the option wasn't set.  In the case that it wasn't set, make
1763 # it be the default, so that we can use it to expand directories now.
1764 if test "x$prefix" = "xNONE"; then
1765   prefix=$ac_default_prefix
1766 fi
1767
1768 # and similarly for $exec_prefix
1769 if test "x$exec_prefix" = "xNONE"; then
1770   exec_prefix=$prefix
1771 fi
1772
1773 if test "x$BUILDDIR" = "x"; then
1774   BUILDDIR=`pwd`
1775 fi
1776 AC_SUBST(BUILDDIR)
1777 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1778 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1779
1780 if test "x$CONFDIR" = "x"; then
1781   CONFDIR=`eval echo $sysconfdir/tor`
1782 fi
1783 AC_SUBST(CONFDIR)
1784 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1785 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1786
1787 BINDIR=`eval echo $bindir`
1788 AC_SUBST(BINDIR)
1789 LOCALSTATEDIR=`eval echo $localstatedir`
1790 AC_SUBST(LOCALSTATEDIR)
1791
1792 if test "$bwin32" = "true"; then
1793   # Test if the linker supports the --nxcompat and --dynamicbase options
1794   # for Windows
1795   save_LDFLAGS="$LDFLAGS"
1796   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1797   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1798   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1799     [AC_MSG_RESULT([yes])]
1800     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1801     [AC_MSG_RESULT([no])]
1802   )
1803   LDFLAGS="$save_LDFLAGS"
1804 fi
1805
1806 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1807 # than autoconf's macros like.
1808 if test "$GCC" = "yes"; then
1809   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1810   # accident waiting to happen.
1811   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1812 else
1813   # Override optimization level for non-gcc compilers
1814   CFLAGS="$CFLAGS -O"
1815   enable_gcc_warnings=no
1816   enable_gcc_warnings_advisory=no
1817 fi
1818
1819 # Warnings implies advisory-warnings and -Werror.
1820 if test "$enable_gcc_warnings" = "yes"; then
1821   enable_gcc_warnings_advisory=yes
1822   enable_fatal_warnings=yes
1823 fi
1824
1825 # OS X Lion started deprecating the system openssl. Let's just disable
1826 # all deprecation warnings on OS X. Also, to potentially make the binary
1827 # a little smaller, let's enable dead_strip.
1828 case "$host_os" in
1829
1830  darwin*)
1831     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1832     LDFLAGS="$LDFLAGS -dead_strip" ;;
1833 esac
1834
1835 # Add some more warnings which we use in development but not in the
1836 # released versions.  (Some relevant gcc versions can't handle these.)
1837 #
1838 # Note that we have to do this near the end  of the autoconf process, or
1839 # else we may run into problems when these warnings hit on the testing C
1840 # programs that autoconf wants to build.
1841 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1842
1843   case "$host" in
1844     *-*-openbsd* | *-*-bitrig*)
1845       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1846       # That's fine, except that the headers don't pass -Wredundant-decls.
1847       # Therefore, let's disable -Wsystem-headers when we're building
1848       # with maximal warnings on OpenBSD.
1849       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1850   esac
1851
1852   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1853   # have it work better.
1854   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1855
1856   # This warning was added in gcc 4.3, but it appears to generate
1857   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1858   #CFLAGS="$CFLAGS -Wlogical-op"
1859
1860   m4_foreach_w([warning_flag], [
1861      -Waddress
1862      -Waddress-of-array-temporary
1863      -Waddress-of-temporary
1864      -Wambiguous-macro
1865      -Wanonymous-pack-parens
1866      -Warc
1867      -Warc-abi
1868      -Warc-bridge-casts-disallowed-in-nonarc
1869      -Warc-maybe-repeated-use-of-weak
1870      -Warc-performSelector-leaks
1871      -Warc-repeated-use-of-weak
1872      -Warray-bounds
1873      -Warray-bounds-pointer-arithmetic
1874      -Wasm
1875      -Wasm-operand-widths
1876      -Watomic-properties
1877      -Watomic-property-with-user-defined-accessor
1878      -Wauto-import
1879      -Wauto-storage-class
1880      -Wauto-var-id
1881      -Wavailability
1882      -Wbackslash-newline-escape
1883      -Wbad-array-new-length
1884      -Wbind-to-temporary-copy
1885      -Wbitfield-constant-conversion
1886      -Wbool-conversion
1887      -Wbool-conversions
1888      -Wbuiltin-requires-header
1889      -Wchar-align
1890      -Wcompare-distinct-pointer-types
1891      -Wcomplex-component-init
1892      -Wconditional-type-mismatch
1893      -Wconfig-macros
1894      -Wconstant-conversion
1895      -Wconstant-logical-operand
1896      -Wconstexpr-not-const
1897      -Wcustom-atomic-properties
1898      -Wdangling-field
1899      -Wdangling-initializer-list
1900      -Wdate-time
1901      -Wdelegating-ctor-cycles
1902      -Wdeprecated-implementations
1903      -Wdeprecated-register
1904      -Wdirect-ivar-access
1905      -Wdiscard-qual
1906      -Wdistributed-object-modifiers
1907      -Wdivision-by-zero
1908      -Wdollar-in-identifier-extension
1909      -Wdouble-promotion
1910      -Wduplicate-decl-specifier
1911      -Wduplicate-enum
1912      -Wduplicate-method-arg
1913      -Wduplicate-method-match
1914      -Wduplicated-cond
1915      -Wdynamic-class-memaccess
1916      -Wembedded-directive
1917      -Wempty-translation-unit
1918      -Wenum-conversion
1919      -Wexit-time-destructors
1920      -Wexplicit-ownership-type
1921      -Wextern-initializer
1922      -Wextra
1923      -Wextra-semi
1924      -Wextra-tokens
1925      -Wflexible-array-extensions
1926      -Wfloat-conversion
1927      -Wformat-non-iso
1928      -Wfour-char-constants
1929      -Wgcc-compat
1930      -Wglobal-constructors
1931      -Wgnu-array-member-paren-init
1932      -Wgnu-designator
1933      -Wgnu-static-float-init
1934      -Wheader-guard
1935      -Wheader-hygiene
1936      -Widiomatic-parentheses
1937      -Wignored-attributes
1938      -Wimplicit-atomic-properties
1939      -Wimplicit-conversion-floating-point-to-bool
1940      -Wimplicit-exception-spec-mismatch
1941      -Wimplicit-fallthrough
1942      -Wimplicit-fallthrough-per-function
1943      -Wimplicit-retain-self
1944      -Wimport-preprocessor-directive-pedantic
1945      -Wincompatible-library-redeclaration
1946      -Wincompatible-pointer-types-discards-qualifiers
1947      -Wincomplete-implementation
1948      -Wincomplete-module
1949      -Wincomplete-umbrella
1950      -Winit-self
1951      -Wint-conversions
1952      -Wint-to-void-pointer-cast
1953      -Winteger-overflow
1954      -Winvalid-constexpr
1955      -Winvalid-iboutlet
1956      -Winvalid-noreturn
1957      -Winvalid-pp-token
1958      -Winvalid-source-encoding
1959      -Winvalid-token-paste
1960      -Wknr-promoted-parameter
1961      -Wlanguage-extension-token
1962      -Wlarge-by-value-copy
1963      -Wliteral-conversion
1964      -Wliteral-range
1965      -Wlocal-type-template-args
1966      -Wlogical-op
1967      -Wloop-analysis
1968      -Wmain-return-type
1969      -Wmalformed-warning-check
1970      -Wmethod-signatures
1971      -Wmicrosoft
1972      -Wmicrosoft-exists
1973      -Wmismatched-parameter-types
1974      -Wmismatched-return-types
1975      -Wmissing-field-initializers
1976      -Wmissing-format-attribute
1977      -Wmissing-noreturn
1978      -Wmissing-selector-name
1979      -Wmissing-sysroot
1980      -Wmissing-variable-declarations
1981      -Wmodule-conflict
1982      -Wnested-anon-types
1983      -Wnewline-eof
1984      -Wnon-literal-null-conversion
1985      -Wnon-pod-varargs
1986      -Wnonportable-cfstrings
1987      -Wnormalized=id
1988      -Wnull-arithmetic
1989      -Wnull-character
1990      -Wnull-conversion
1991      -Wnull-dereference
1992      -Wout-of-line-declaration
1993      -Wover-aligned
1994      -Woverlength-strings
1995      -Woverride-init
1996      -Woverriding-method-mismatch
1997      -Wpointer-type-mismatch
1998      -Wpredefined-identifier-outside-function
1999      -Wprotocol-property-synthesis-ambiguity
2000      -Wreadonly-iboutlet-property
2001      -Wreadonly-setter-attrs
2002      -Wreceiver-expr
2003      -Wreceiver-forward-class
2004      -Wreceiver-is-weak
2005      -Wreinterpret-base-class
2006      -Wrequires-super-attribute
2007      -Wreserved-user-defined-literal
2008      -Wreturn-stack-address
2009      -Wsection
2010      -Wselector-type-mismatch
2011      -Wsentinel
2012      -Wserialized-diagnostics
2013      -Wshadow
2014      -Wshift-count-negative
2015      -Wshift-count-overflow
2016      -Wshift-negative-value
2017      -Wshift-overflow=2
2018      -Wshift-sign-overflow
2019      -Wshorten-64-to-32
2020      -Wsizeof-array-argument
2021      -Wsource-uses-openmp
2022      -Wstatic-float-init
2023      -Wstatic-in-inline
2024      -Wstatic-local-in-inline
2025      -Wstrict-overflow=1
2026      -Wstring-compare
2027      -Wstring-conversion
2028      -Wstrlcpy-strlcat-size
2029      -Wstrncat-size
2030      -Wsuggest-attribute=format
2031      -Wsuggest-attribute=noreturn
2032      -Wsuper-class-method-mismatch
2033      -Wswitch-bool
2034      -Wsync-nand
2035      -Wtautological-constant-out-of-range-compare
2036      -Wtentative-definition-incomplete-type
2037      -Wtrampolines
2038      -Wtype-safety
2039      -Wtypedef-redefinition
2040      -Wtypename-missing
2041      -Wundefined-inline
2042      -Wundefined-internal
2043      -Wundefined-reinterpret-cast
2044      -Wunicode
2045      -Wunicode-whitespace
2046      -Wunknown-warning-option
2047      -Wunnamed-type-template-args
2048      -Wunneeded-member-function
2049      -Wunsequenced
2050      -Wunsupported-visibility
2051      -Wunused-but-set-parameter
2052      -Wunused-but-set-variable
2053      -Wunused-command-line-argument
2054      -Wunused-const-variable=2
2055      -Wunused-exception-parameter
2056      -Wunused-local-typedefs
2057      -Wunused-member-function
2058      -Wunused-sanitize-argument
2059      -Wunused-volatile-lvalue
2060      -Wuser-defined-literals
2061      -Wvariadic-macros
2062      -Wvector-conversion
2063      -Wvector-conversions
2064      -Wvexing-parse
2065      -Wvisibility
2066      -Wvla-extension
2067      -Wzero-length-array
2068   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
2069
2070 dnl    We should re-enable this in some later version.  Clang doesn't
2071 dnl    mind, but it causes trouble with GCC.
2072 dnl     -Wstrict-overflow=2
2073
2074 dnl    These seem to require annotations that we don't currently use,
2075 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2076 dnl     -Wthread-safety
2077 dnl     -Wthread-safety-analysis
2078 dnl     -Wthread-safety-attributes
2079 dnl     -Wthread-safety-beta
2080 dnl     -Wthread-safety-precise
2081
2082   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2083   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2084   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2085   CFLAGS="$CFLAGS -Wwrite-strings"
2086   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2087   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
2088   CFLAGS="$CFLAGS -Wunused-parameter "
2089   # These interfere with building main() { return 0; }, which autoconf
2090   # likes to use as its default program.
2091   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
2092
2093   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2094     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2095   fi
2096   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2097     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2098   fi
2099
2100   if test "x$enable_fatal_warnings" = "xyes"; then
2101     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2102     # default autoconf programs are full of errors.
2103     CFLAGS="$CFLAGS -Werror"
2104   fi
2105
2106 fi
2107
2108 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2109    case "$host_os" in
2110     darwin*)
2111       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2112    esac
2113 fi
2114
2115 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2116
2117 AC_CONFIG_FILES([
2118         Doxyfile
2119         Makefile
2120         contrib/dist/suse/tor.sh
2121         contrib/operator-tools/tor.logrotate
2122         contrib/dist/tor.sh
2123         contrib/dist/torctl
2124         contrib/dist/tor.service
2125         src/config/torrc.sample
2126         src/config/torrc.minimal
2127         src/rust/.cargo/config
2128         scripts/maint/checkOptionDocs.pl
2129         scripts/maint/updateVersions.pl
2130 ])
2131
2132 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2133   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2134   for file in $regular_mans ; do
2135     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2136       echo "==================================";
2137       echo;
2138       echo "Building Tor has failed since manpages cannot be built.";
2139       echo;
2140       echo "You need asciidoc installed to be able to build the manpages.";
2141       echo "To build without manpages, use the --disable-asciidoc argument";
2142       echo "when calling configure.";
2143       echo;
2144       echo "==================================";
2145       exit 1;
2146     fi
2147   done
2148 fi
2149
2150 if test "$fragile_hardening" = "yes"; then
2151   AC_MSG_WARN([
2152
2153 ============
2154 Warning!  Building Tor with --enable-fragile-hardening (also known as
2155 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2156 other kinds of attacks easier. A Tor instance build with this option will be
2157 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2158 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2159 denial of service attacks. For more information, see
2160 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2161 ============
2162   ])
2163 fi
2164
2165 AC_OUTPUT