configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2017, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.1.0-alpha-dev])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56 AC_ARG_ENABLE(memory-sentinels,
  57    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  58
  59 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  60     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  61 fi
  62
  63 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  64 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  65 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  66 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  67 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  68
  69 if test "$enable_static_tor" = "yes"; then
  70   enable_static_libevent="yes";
  71   enable_static_openssl="yes";
  72   enable_static_zlib="yes";
  73   CFLAGS="$CFLAGS -static"
  74 fi
  75
  76 if test "$enable_system_torrc" = "no"; then
  77   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  78             [Defined if we're not going to look for a torrc in SYSCONF])
  79 fi
  80
  81 if test "$enable_memory_sentinels" = "no"; then
  82   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  83            [Defined if we're turning off memory safety code to look for bugs])
  84 fi
  85
  86 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  87
  88 AC_ARG_ENABLE(asciidoc,
  89      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  90      [case "${enableval}" in
  91         "yes") asciidoc=true ;;
  92         "no")  asciidoc=false ;;
  93         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  94       esac], [asciidoc=true])
  95
  96 # systemd notify support
  97 AC_ARG_ENABLE(systemd,
  98       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  99       [case "${enableval}" in
 100         "yes") systemd=true ;;
 101         "no")  systemd=false ;;
 102         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 103       esac], [systemd=auto])
 104
 105
 106
 107 # systemd support
 108 if test "x$enable_systemd" = "xno"; then
 109     have_systemd=no;
 110 else
 111     PKG_CHECK_MODULES(SYSTEMD,
 112         [libsystemd-daemon],
 113         have_systemd=yes,
 114         have_systemd=no)
 115     if test "x$have_systemd" = "xno"; then
 116         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 117         PKG_CHECK_MODULES(SYSTEMD,
 118             [libsystemd],
 119             have_systemd=yes,
 120             have_systemd=no)
 121     fi
 122 fi
 123
 124 if test "x$have_systemd" = "xyes"; then
 125     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 126     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 127     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 128     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 129          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 130 fi
 131 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 132 AC_SUBST(TOR_SYSTEMD_LIBS)
 133
 134 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 135     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 136 fi
 137
 138 case "$host" in
 139    *-*-solaris* )
 140      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 141      ;;
 142 esac
 143
 144 AC_ARG_ENABLE(gcc-warnings,
 145      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 146 AC_ARG_ENABLE(fatal-warnings,
 147      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 148 AC_ARG_ENABLE(gcc-warnings-advisory,
 149      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 150
 151 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 152 AC_ARG_ENABLE(gcc-hardening,
 153     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 154
 155 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 156 AC_ARG_ENABLE(expensive-hardening,
 157     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 158 AC_ARG_ENABLE(fragile-hardening,
 159     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 160 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 161   fragile_hardening="yes"
 162 fi
 163
 164 dnl Linker hardening options
 165 dnl Currently these options are ELF specific - you can't use this with MacOSX
 166 AC_ARG_ENABLE(linker-hardening,
 167     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 168
 169 AC_ARG_ENABLE(local-appdata,
 170    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 171 if test "$enable_local_appdata" = "yes"; then
 172   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 173             [Defined if we default to host local appdata paths on Windows])
 174 fi
 175
 176 # Tor2web mode flag
 177 AC_ARG_ENABLE(tor2web-mode,
 178      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 179 [if test "x$enableval" = "xyes"; then
 180     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 181 fi])
 182
 183 AC_ARG_ENABLE(tool-name-check,
 184      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 185
 186 AC_ARG_ENABLE(seccomp,
 187      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 188
 189 AC_ARG_ENABLE(libscrypt,
 190      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 191
 192 dnl Enable event tracing which are transformed to debug log statement.
 193 AC_ARG_ENABLE(event-tracing-debug,
 194      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 195 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 196
 197 if test x$enable_event_tracing_debug = xyes; then
 198   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 199   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 200 fi
 201
 202 dnl check for the correct "ar" when cross-compiling.
 203 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 204 dnl    so kludge up a replacement for the case where it isn't there yet.)
 205 m4_ifdef([AM_PROG_AR],
 206          [AM_PROG_AR],
 207          [AN_MAKEVAR([AR], [AC_PROG_AR])
 208           AN_PROGRAM([ar], [AC_PROG_AR])
 209           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 210           AC_PROG_AR])
 211
 212 dnl Check whether the above macro has settled for a simply named tool even
 213 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 214 dnl because that will find any cc on the system, not only the cross-compiler,
 215 dnl and then verify that a binary built with this compiler runs on the
 216 dnl build system. It will then come to the false conclusion that we're not
 217 dnl cross-compiling.
 218 if test "x$enable_tool_name_check" != "xno"; then
 219     if test "x$ac_tool_warned" = "xyes"; then
 220         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 221         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 222                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 223         fi
 224 fi
 225
 226 AC_PROG_CC
 227 AC_PROG_CPP
 228 AC_PROG_MAKE_SET
 229 AC_PROG_RANLIB
 230 AC_PROG_SED
 231
 232 AC_ARG_VAR([PERL], [path to Perl binary])
 233 AC_CHECK_PROGS([PERL], [perl])
 234 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 235
 236 dnl check for asciidoc and a2x
 237 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 238 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 239
 240 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 241
 242 AM_PROG_CC_C_O
 243 AC_PROG_CC_C99
 244
 245 AC_ARG_VAR([PYTHON], [path to Python binary])
 246 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 247 if test "x$PYTHON" = "x"; then
 248   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 249 fi
 250 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 251
 252 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 253 AC_C_FLEXIBLE_ARRAY_MEMBER
 254 ], [
 255  dnl Maybe we've got an old autoconf...
 256  AC_CACHE_CHECK([for flexible array members],
 257      tor_cv_c_flexarray,
 258      [AC_COMPILE_IFELSE(
 259        AC_LANG_PROGRAM([
 260  struct abc { int a; char b[]; };
 261 ], [
 262  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 263  def->b[0] = 33;
 264 ]),
 265   [tor_cv_c_flexarray=yes],
 266   [tor_cv_c_flexarray=no])])
 267  if test "$tor_cv_flexarray" = "yes"; then
 268    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 269  else
 270    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 271  fi
 272 ])
 273
 274 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 275       tor_cv_c_c99_decl,
 276       [AC_COMPILE_IFELSE(
 277          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 278          [tor_cv_c_c99_decl=yes],
 279          [tor_cv_c_c99_decl=no] )])
 280 if test "$tor_cv_c_c99_decl" != "yes"; then
 281   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 282 fi
 283
 284 AC_CACHE_CHECK([for working C99 designated initializers],
 285       tor_cv_c_c99_designated_init,
 286       [AC_COMPILE_IFELSE(
 287          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 288                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 289          [tor_cv_c_c99_designated_init=yes],
 290          [tor_cv_c_c99_designated_init=no] )])
 291
 292 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 293   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 294 fi
 295
 296 TORUSER=_tor
 297 AC_ARG_WITH(tor-user,
 298         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 299         [
 300            TORUSER=$withval
 301         ]
 302 )
 303 AC_SUBST(TORUSER)
 304
 305 TORGROUP=_tor
 306 AC_ARG_WITH(tor-group,
 307         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 308         [
 309            TORGROUP=$withval
 310         ]
 311 )
 312 AC_SUBST(TORGROUP)
 313
 314
 315 dnl If _WIN32 is defined and non-zero, we are building for win32
 316 AC_MSG_CHECKING([for win32])
 317 AC_RUN_IFELSE([AC_LANG_SOURCE([
 318 int main(int c, char **v) {
 319 #ifdef _WIN32
 320 #if _WIN32
 321   return 0;
 322 #else
 323   return 1;
 324 #endif
 325 #else
 326   return 2;
 327 #endif
 328 }])],
 329 bwin32=true; AC_MSG_RESULT([yes]),
 330 bwin32=false; AC_MSG_RESULT([no]),
 331 bwin32=cross; AC_MSG_RESULT([cross])
 332 )
 333
 334 if test "$bwin32" = "cross"; then
 335 AC_MSG_CHECKING([for win32 (cross)])
 336 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 337 #ifdef _WIN32
 338 int main(int c, char **v) {return 0;}
 339 #else
 340 #error
 341 int main(int c, char **v) {return x(y);}
 342 #endif
 343 ])],
 344 bwin32=true; AC_MSG_RESULT([yes]),
 345 bwin32=false; AC_MSG_RESULT([no]))
 346 fi
 347
 348 AH_BOTTOM([
 349 #ifdef _WIN32
 350 /* Defined to access windows functions and definitions for >=WinXP */
 351 # ifndef WINVER
 352 #  define WINVER 0x0501
 353 # endif
 354
 355 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 356 # ifndef _WIN32_WINNT
 357 #  define _WIN32_WINNT 0x0501
 358 # endif
 359
 360 /* Defined to avoid including some windows headers as part of Windows.h */
 361 # ifndef WIN32_LEAN_AND_MEAN
 362 #  define WIN32_LEAN_AND_MEAN 1
 363 # endif
 364 #endif
 365 ])
 366
 367
 368 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 369
 370 dnl Enable C99 when compiling with MIPSpro
 371 AC_MSG_CHECKING([for MIPSpro compiler])
 372 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 373 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 374 #error
 375   return x(y);
 376 #endif
 377 ])],
 378 bmipspro=false; AC_MSG_RESULT(no),
 379 bmipspro=true; AC_MSG_RESULT(yes))
 380
 381 if test "$bmipspro" = "true"; then
 382   CFLAGS="$CFLAGS -c99"
 383 fi
 384
 385 AC_C_BIGENDIAN
 386
 387 AC_SEARCH_LIBS(socket, [socket network])
 388 AC_SEARCH_LIBS(gethostbyname, [nsl])
 389 AC_SEARCH_LIBS(dlopen, [dl])
 390 AC_SEARCH_LIBS(inet_aton, [resolv])
 391 AC_SEARCH_LIBS(backtrace, [execinfo])
 392 saved_LIBS="$LIBS"
 393 AC_SEARCH_LIBS([clock_gettime], [rt])
 394 if test "$LIBS" != "$saved_LIBS"; then
 395    # Looks like we need -lrt for clock_gettime().
 396    have_rt=yes
 397 fi
 398
 399 AC_SEARCH_LIBS(pthread_create, [pthread])
 400 AC_SEARCH_LIBS(pthread_detach, [pthread])
 401
 402 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 403 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 404
 405 AC_CHECK_FUNCS(
 406         _NSGetEnviron \
 407         RtlSecureZeroMemory \
 408         SecureZeroMemory \
 409         accept4 \
 410         backtrace \
 411         backtrace_symbols_fd \
 412         eventfd \
 413         explicit_bzero \
 414         timingsafe_memcmp \
 415         flock \
 416         ftime \
 417         getaddrinfo \
 418         getifaddrs \
 419         getpass \
 420         getrlimit \
 421         gettimeofday \
 422         gmtime_r \
 423         htonll \
 424         inet_aton \
 425         ioctl \
 426         issetugid \
 427         llround \
 428         localtime_r \
 429         lround \
 430         memmem \
 431         memset_s \
 432         pipe \
 433         pipe2 \
 434         prctl \
 435         readpassphrase \
 436         rint \
 437         sigaction \
 438         socketpair \
 439         statvfs \
 440         strlcat \
 441         strlcpy \
 442         strnlen \
 443         strptime \
 444         strtok_r \
 445         strtoull \
 446         sysconf \
 447         sysctl \
 448         truncate \
 449         uname \
 450         usleep \
 451         vasprintf \
 452         _vscprintf
 453 )
 454
 455 # Apple messed up when they added two functions functions in Sierra: they
 456 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 457 # checks. So we should only probe for those functions if we are sure that we
 458 # are not targetting OSX 10.11 or earlier.
 459 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 460 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 461 #ifdef __APPLE__
 462 #  include <AvailabilityMacros.h>
 463 #  ifndef MAC_OS_X_VERSION_10_12
 464 #    define MAC_OS_X_VERSION_10_12 101200
 465 #  endif
 466 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 467 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 468 #      error "Running on Mac OSX 10.11 or earlier"
 469 #    endif
 470 #  endif
 471 #endif
 472 ]], [[]])],
 473    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 474    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 475
 476 if test "$on_macos_pre_10_12" = "no"; then
 477   AC_CHECK_FUNCS(
 478         clock_gettime \
 479         getentropy \
 480   )
 481 fi
 482
 483 if test "$bwin32" != "true"; then
 484   AC_CHECK_HEADERS(pthread.h)
 485   AC_CHECK_FUNCS(pthread_create)
 486   AC_CHECK_FUNCS(pthread_condattr_setclock)
 487 fi
 488
 489 if test "$bwin32" = "true"; then
 490   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 491 #include <windows.h>
 492 #include <conio.h>
 493 #include <wchar.h>
 494                  ])
 495 fi
 496
 497 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 498   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 499
 500 dnl ------------------------------------------------------
 501 dnl Where do you live, libevent?  And how do we call you?
 502
 503 if test "$bwin32" = "true"; then
 504   TOR_LIB_WS32=-lws2_32
 505   TOR_LIB_IPHLPAPI=-liphlpapi
 506   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 507   # think it's actually necessary.
 508   TOR_LIB_GDI=-lgdi32
 509 else
 510   TOR_LIB_WS32=
 511   TOR_LIB_GDI=
 512 fi
 513 AC_SUBST(TOR_LIB_WS32)
 514 AC_SUBST(TOR_LIB_GDI)
 515 AC_SUBST(TOR_LIB_IPHLPAPI)
 516
 517 tor_libevent_pkg_redhat="libevent"
 518 tor_libevent_pkg_debian="libevent-dev"
 519 tor_libevent_devpkg_redhat="libevent-devel"
 520 tor_libevent_devpkg_debian="libevent-dev"
 521
 522 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 523 dnl linking for static builds.
 524 STATIC_LIBEVENT_FLAGS=""
 525 if test "$enable_static_libevent" = "yes"; then
 526     if test "$have_rt" = "yes"; then
 527       STATIC_LIBEVENT_FLAGS=" -lrt "
 528     fi
 529 fi
 530
 531 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 532 #ifdef _WIN32
 533 #include <winsock2.h>
 534 #endif
 535 #include <sys/time.h>
 536 #include <sys/types.h>
 537 #include <event2/event.h>], [
 538 #ifdef _WIN32
 539 #include <winsock2.h>
 540 #endif
 541 struct event_base;
 542 struct event_base *event_base_new(void);],
 543     [
 544 #ifdef _WIN32
 545 {WSADATA d; WSAStartup(0x101,&d); }
 546 #endif
 547 event_base_new();
 548 ], [--with-libevent-dir], [/opt/libevent])
 549
 550 dnl Determine the incantation needed to link libevent.
 551 save_LIBS="$LIBS"
 552 save_LDFLAGS="$LDFLAGS"
 553 save_CPPFLAGS="$CPPFLAGS"
 554
 555 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 556 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 557 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 558
 559 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 560
 561 if test "$enable_static_libevent" = "yes"; then
 562    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 563      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 564    else
 565      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 566    fi
 567 else
 568      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 569        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 570        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 571
 572        if test "$ac_cv_search_event_new" != "none required"; then
 573          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 574        fi
 575        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 576          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 577        fi
 578      else
 579        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 580      fi
 581 fi
 582
 583 dnl Now check for particular libevent functions.
 584 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 585                 evutil_secure_rng_add_bytes \
 586 ])
 587
 588 LIBS="$save_LIBS"
 589 LDFLAGS="$save_LDFLAGS"
 590 CPPFLAGS="$save_CPPFLAGS"
 591
 592 dnl Check that libevent is at least at version 2.0.10, the first stable
 593 dnl release of its series
 594 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 595 AC_MSG_CHECKING([whether Libevent is new enough])
 596 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 597 #include <event2/event.h>
 598 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 599 #error
 600 int x = y(zz);
 601 #else
 602 int x = 1;
 603 #endif
 604 ])], [ AC_MSG_RESULT([yes]) ],
 605    [ AC_MSG_RESULT([no])
 606      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 607
 608 LIBS="$save_LIBS"
 609 LDFLAGS="$save_LDFLAGS"
 610 CPPFLAGS="$save_CPPFLAGS"
 611
 612 AC_SUBST(TOR_LIBEVENT_LIBS)
 613
 614 dnl ------------------------------------------------------
 615 dnl Where do you live, libm?
 616
 617 dnl On some platforms (Haiku/BeOS) the math library is
 618 dnl part of libroot. In which case don't link against lm
 619 TOR_LIB_MATH=""
 620 save_LIBS="$LIBS"
 621 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 622 if test "$ac_cv_search_pow" != "none required"; then
 623     TOR_LIB_MATH="$ac_cv_search_pow"
 624 fi
 625 LIBS="$save_LIBS"
 626 AC_SUBST(TOR_LIB_MATH)
 627
 628 dnl ------------------------------------------------------
 629 dnl Where do you live, openssl?  And how do we call you?
 630
 631 tor_openssl_pkg_redhat="openssl"
 632 tor_openssl_pkg_debian="libssl-dev"
 633 tor_openssl_devpkg_redhat="openssl-devel"
 634 tor_openssl_devpkg_debian="libssl-dev"
 635
 636 ALT_openssl_WITHVAL=""
 637 AC_ARG_WITH(ssl-dir,
 638   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 639   [
 640       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 641          ALT_openssl_WITHVAL="$withval"
 642       fi
 643   ])
 644
 645 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 646     [#include <openssl/rand.h>],
 647     [void RAND_add(const void *buf, int num, double entropy);],
 648     [RAND_add((void*)0,0,0);], [],
 649     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 650
 651 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 652
 653 if test "$enable_static_openssl" = "yes"; then
 654    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 655      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 656    else
 657      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 658    fi
 659 else
 660      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 661 fi
 662 AC_SUBST(TOR_OPENSSL_LIBS)
 663
 664 dnl Now check for particular openssl functions.
 665 save_LIBS="$LIBS"
 666 save_LDFLAGS="$LDFLAGS"
 667 save_CPPFLAGS="$CPPFLAGS"
 668 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 669 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 670 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 671
 672 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 673 #include <openssl/opensslv.h>
 674 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 675 #error "too old"
 676 #endif
 677    ]], [[]])],
 678    [ : ],
 679    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 680
 681 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 682 #include <openssl/opensslv.h>
 683 #include <openssl/evp.h>
 684 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 685 #error "no ECC"
 686 #endif
 687 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 688 #error "curves unavailable"
 689 #endif
 690    ]], [[]])],
 691    [ : ],
 692    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 693
 694 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 695 [#include <openssl/ssl.h>
 696 ])
 697
 698 AC_CHECK_FUNCS([ \
 699                 SSL_SESSION_get_master_key \
 700                 SSL_get_server_random \
 701                 SSL_get_client_ciphers \
 702                 SSL_get_client_random \
 703                 SSL_CIPHER_find \
 704                 TLS_method
 705                ])
 706
 707 dnl Check if OpenSSL has scrypt implementation.
 708 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 709
 710 dnl Check if OpenSSL structures are opaque
 711 AC_CHECK_MEMBERS([SSL.state], , ,
 712 [#include <openssl/ssl.h>
 713 ])
 714
 715 LIBS="$save_LIBS"
 716 LDFLAGS="$save_LDFLAGS"
 717 CPPFLAGS="$save_CPPFLAGS"
 718
 719 dnl ------------------------------------------------------
 720 dnl Where do you live, zlib?  And how do we call you?
 721
 722 tor_zlib_pkg_redhat="zlib"
 723 tor_zlib_pkg_debian="zlib1g"
 724 tor_zlib_devpkg_redhat="zlib-devel"
 725 tor_zlib_devpkg_debian="zlib1g-dev"
 726
 727 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 728     [#include <zlib.h>],
 729     [const char * zlibVersion(void);],
 730     [zlibVersion();], [--with-zlib-dir],
 731     [/opt/zlib])
 732
 733 if test "$enable_static_zlib" = "yes"; then
 734    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 735      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 736  using --enable-static-zlib")
 737    else
 738      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 739    fi
 740 else
 741      TOR_ZLIB_LIBS="-lz"
 742 fi
 743 AC_SUBST(TOR_ZLIB_LIBS)
 744
 745 dnl ------------------------------------------------------
 746 dnl Where we do we find lzma?
 747
 748 AC_ARG_ENABLE(lzma,
 749       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
 750       [case "${enableval}" in
 751         "yes") lzma=true ;;
 752         "no")  lzma=false ;;
 753         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
 754       esac], [lzma=auto])
 755
 756 if test "x$enable_lzma" = "xno"; then
 757     have_lzma=no;
 758 else
 759     PKG_CHECK_MODULES([LZMA],
 760                       [liblzma],
 761                       have_lzma=yes,
 762                       have_lzma=no)
 763
 764     if test "x$have_lzma" = "xno" ; then
 765         AC_MSG_WARN([Unable to find liblzma.])
 766     fi
 767 fi
 768
 769 if test "x$have_lzma" = "xyes"; then
 770     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
 771     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
 772     TOR_LZMA_LIBS="${LZMA_LIBS}"
 773 fi
 774 AC_SUBST(TOR_LZMA_CFLAGS)
 775 AC_SUBST(TOR_LZMA_LIBS)
 776
 777 dnl ------------------------------------------------------
 778 dnl Where we do we find zstd?
 779
 780 AC_ARG_ENABLE(zstd,
 781       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
 782       [case "${enableval}" in
 783         "yes") zstd=true ;;
 784         "no")  zstd=false ;;
 785         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
 786       esac], [zstd=auto])
 787
 788 if test "x$enable_zstd" = "xno"; then
 789     have_zstd=no;
 790 else
 791     PKG_CHECK_MODULES([ZSTD],
 792                       [libzstd],
 793                       have_zstd=yes,
 794                       have_zstd=no)
 795
 796     if test "x$have_zstd" = "xno" ; then
 797         AC_MSG_WARN([Unable to find libzstd.])
 798     fi
 799 fi
 800
 801 if test "x$have_zstd" = "xyes"; then
 802     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
 803     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
 804     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
 805 fi
 806 AC_SUBST(TOR_ZSTD_CFLAGS)
 807 AC_SUBST(TOR_ZSTD_LIBS)
 808
 809 dnl ----------------------------------------------------------------------
 810 dnl Check if libcap is available for capabilities.
 811
 812 tor_cap_pkg_debian="libcap2"
 813 tor_cap_pkg_redhat="libcap"
 814 tor_cap_devpkg_debian="libcap-dev"
 815 tor_cap_devpkg_redhat="libcap-devel"
 816
 817 AC_CHECK_LIB([cap], [cap_init], [],
 818   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 819 )
 820 AC_CHECK_FUNCS(cap_set_proc)
 821
 822 dnl ---------------------------------------------------------------------
 823 dnl Now that we know about our major libraries, we can check for compiler
 824 dnl and linker hardening options.  We need to do this with the libraries known,
 825 dnl since sometimes the linker will like an option but not be willing to
 826 dnl use it with a build of a library.
 827
 828 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 829 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_CAP_LIBS"
 830
 831 CFLAGS_FTRAPV=
 832 CFLAGS_FWRAPV=
 833 CFLAGS_ASAN=
 834 CFLAGS_UBSAN=
 835
 836
 837 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 838 #if !defined(__clang__)
 839 #error
 840 #endif])], have_clang=yes, have_clang=no)
 841
 842 if test "x$enable_gcc_hardening" != "xno"; then
 843     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 844     if test "x$have_clang" = "xyes"; then
 845         TOR_CHECK_CFLAGS(-Qunused-arguments)
 846     fi
 847     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 848     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 849     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 850 m4_ifdef([AS_VAR_IF],[
 851     AS_VAR_IF(can_compile, [yes],
 852         AS_VAR_IF(can_link, [yes],
 853                   [],
 854                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 855         )])
 856     AS_VAR_POPDEF([can_link])
 857     AS_VAR_POPDEF([can_compile])
 858     TOR_CHECK_CFLAGS(-Wstack-protector)
 859     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 860     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
 861        TOR_CHECK_CFLAGS(-fPIE)
 862        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 863     fi
 864     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
 865 fi
 866
 867 if test "$fragile_hardening" = "yes"; then
 868     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
 869    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
 870       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
 871    fi
 872
 873    if test "$tor_cv_cflags__ftrapv" != "yes"; then
 874      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
 875    fi
 876
 877    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
 878     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 879       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
 880     fi
 881
 882    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
 883     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 884       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
 885     fi
 886
 887 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 888 fi
 889
 890 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
 891 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
 892
 893 mulodi_fixes_ftrapv=no
 894 if test "$have_clang" = "yes"; then
 895   saved_CFLAGS="$CFLAGS"
 896   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
 897   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
 898   AC_LINK_IFELSE([
 899       AC_LANG_SOURCE([[
 900           #include <stdint.h>
 901           #include <stdlib.h>
 902           int main(int argc, char **argv)
 903           {
 904             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
 905                         * (int64_t)atoi(argv[3]);
 906             return x == 9;
 907           } ]])],
 908           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
 909           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
 910   if test "$ftrapv_can_link" = "no"; then
 911     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
 912     AC_LINK_IFELSE([
 913       AC_LANG_SOURCE([[
 914           #include <stdint.h>
 915           #include <stdlib.h>
 916           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
 917              *overflow=0;
 918              return a;
 919           }
 920           int main(int argc, char **argv)
 921           {
 922             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
 923                         * (int64_t)atoi(argv[3]);
 924             return x == 9;
 925           } ]])],
 926           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
 927           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
 928   fi
 929   CFLAGS="$saved_CFLAGS"
 930 fi
 931
 932 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
 933
 934 dnl These cflags add bunches of branches, and we haven't been able to
 935 dnl persuade ourselves that they're suitable for code that needs to be
 936 dnl constant time.
 937 AC_SUBST(CFLAGS_BUGTRAP)
 938 dnl These cflags are variant ones sutable for code that needs to be
 939 dnl constant-time.
 940 AC_SUBST(CFLAGS_CONSTTIME)
 941
 942 if test "x$enable_linker_hardening" != "xno"; then
 943     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
 944 fi
 945
 946 # For backtrace support
 947 TOR_CHECK_LDFLAGS(-rdynamic)
 948
 949 dnl ------------------------------------------------------
 950 dnl Now see if we have a -fomit-frame-pointer compiler option.
 951
 952 saved_CFLAGS="$CFLAGS"
 953 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
 954 F_OMIT_FRAME_POINTER=''
 955 if test "$saved_CFLAGS" != "$CFLAGS"; then
 956   if test "$fragile_hardening" = "yes"; then
 957     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
 958   fi
 959 fi
 960 CFLAGS="$saved_CFLAGS"
 961 AC_SUBST(F_OMIT_FRAME_POINTER)
 962
 963 dnl ------------------------------------------------------
 964 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
 965 dnl for us, as GCC 4.6 and later do at many optimization levels), then
 966 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
 967 dnl code will work.
 968 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
 969
 970 dnl ============================================================
 971 dnl Check for libseccomp
 972
 973 if test "x$enable_seccomp" != "xno"; then
 974   AC_CHECK_HEADERS([seccomp.h])
 975   AC_SEARCH_LIBS(seccomp_init, [seccomp])
 976 fi
 977
 978 dnl ============================================================
 979 dnl Check for libscrypt
 980
 981 if test "x$enable_libscrypt" != "xno"; then
 982   AC_CHECK_HEADERS([libscrypt.h])
 983   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
 984   AC_CHECK_FUNCS([libscrypt_scrypt])
 985 fi
 986
 987 dnl ============================================================
 988 dnl We need an implementation of curve25519.
 989
 990 dnl set these defaults.
 991 build_curve25519_donna=no
 992 build_curve25519_donna_c64=no
 993 use_curve25519_donna=no
 994 use_curve25519_nacl=no
 995 CURVE25519_LIBS=
 996
 997 dnl The best choice is using curve25519-donna-c64, but that requires
 998 dnl that we
 999 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1000   tor_cv_can_use_curve25519_donna_c64,
1001   [AC_RUN_IFELSE(
1002     [AC_LANG_PROGRAM([dnl
1003       #include <stdint.h>
1004       typedef unsigned uint128_t __attribute__((mode(TI)));
1005   int func(uint64_t a, uint64_t b) {
1006            uint128_t c = ((uint128_t)a) * b;
1007            int ok = ((uint64_t)(c>>96)) == 522859 &&
1008              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1009                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1010                  (((uint64_t)(c))&0xffffffffL) == 0;
1011            return ok;
1012       }
1013   ], [dnl
1014     int ok = func( ((uint64_t)2000000000) * 1000000000,
1015                    ((uint64_t)1234567890) << 24);
1016         return !ok;
1017       ])],
1018   [tor_cv_can_use_curve25519_donna_c64=yes],
1019       [tor_cv_can_use_curve25519_donna_c64=no],
1020   [AC_LINK_IFELSE(
1021         [AC_LANG_PROGRAM([dnl
1022       #include <stdint.h>
1023       typedef unsigned uint128_t __attribute__((mode(TI)));
1024   int func(uint64_t a, uint64_t b) {
1025            uint128_t c = ((uint128_t)a) * b;
1026            int ok = ((uint64_t)(c>>96)) == 522859 &&
1027              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1028                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1029                  (((uint64_t)(c))&0xffffffffL) == 0;
1030            return ok;
1031       }
1032   ], [dnl
1033     int ok = func( ((uint64_t)2000000000) * 1000000000,
1034                  ((uint64_t)1234567890) << 24);
1035         return !ok;
1036       ])],
1037           [tor_cv_can_use_curve25519_donna_c64=cross],
1038       [tor_cv_can_use_curve25519_donna_c64=no])])])
1039
1040 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1041                   nacl/crypto_scalarmult_curve25519.h])
1042
1043 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1044   tor_cv_can_use_curve25519_nacl,
1045   [tor_saved_LIBS="$LIBS"
1046    LIBS="$LIBS -lnacl"
1047    AC_LINK_IFELSE(
1048      [AC_LANG_PROGRAM([dnl
1049        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1050        #include <crypto_scalarmult_curve25519.h>
1051    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1052    #include <nacl/crypto_scalarmult_curve25519.h>
1053    #endif
1054        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1055    #error Hey, this is the reference implementation! That's not fast.
1056    #endif
1057      ], [
1058    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1059      ])], [tor_cv_can_use_curve25519_nacl=yes],
1060      [tor_cv_can_use_curve25519_nacl=no])
1061    LIBS="$tor_saved_LIBS" ])
1062
1063  dnl Okay, now we need to figure out which one to actually use. Fall back
1064  dnl to curve25519-donna.c
1065
1066  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1067    build_curve25519_donna_c64=yes
1068    use_curve25519_donna=yes
1069  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1070    use_curve25519_nacl=yes
1071    CURVE25519_LIBS=-lnacl
1072  else
1073    build_curve25519_donna=yes
1074    use_curve25519_donna=yes
1075  fi
1076
1077 if test "x$use_curve25519_donna" = "xyes"; then
1078   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1079             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1080 fi
1081 if test "x$use_curve25519_nacl" = "xyes"; then
1082   AC_DEFINE(USE_CURVE25519_NACL, 1,
1083             [Defined if we should use a curve25519 from nacl])
1084 fi
1085 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1086   test "x$build_curve25519_donna" = "xyes")
1087 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1088   test "x$build_curve25519_donna_c64" = "xyes")
1089 AC_SUBST(CURVE25519_LIBS)
1090
1091 dnl Make sure to enable support for large off_t if available.
1092 AC_SYS_LARGEFILE
1093
1094 AC_CHECK_HEADERS([assert.h \
1095                   errno.h \
1096                   fcntl.h \
1097                   signal.h \
1098                   string.h \
1099                   sys/capability.h \
1100                   sys/fcntl.h \
1101                   sys/stat.h \
1102                   sys/time.h \
1103                   sys/types.h \
1104                   time.h \
1105                   unistd.h \
1106                   arpa/inet.h \
1107                   crt_externs.h \
1108                   execinfo.h \
1109                   grp.h \
1110                   ifaddrs.h \
1111                   inttypes.h \
1112                   limits.h \
1113                   linux/types.h \
1114                   machine/limits.h \
1115                   malloc.h \
1116                   malloc/malloc.h \
1117                   malloc_np.h \
1118                   netdb.h \
1119                   netinet/in.h \
1120                   netinet/in6.h \
1121                   pwd.h \
1122                   readpassphrase.h \
1123                   stdint.h \
1124                   sys/eventfd.h \
1125                   sys/file.h \
1126                   sys/ioctl.h \
1127                   sys/limits.h \
1128                   sys/mman.h \
1129                   sys/param.h \
1130                   sys/prctl.h \
1131                   sys/random.h \
1132                   sys/resource.h \
1133                   sys/select.h \
1134                   sys/socket.h \
1135                   sys/statvfs.h \
1136                   sys/syscall.h \
1137                   sys/sysctl.h \
1138                   sys/syslimits.h \
1139                   sys/time.h \
1140                   sys/types.h \
1141                   sys/un.h \
1142                   sys/utime.h \
1143                   sys/wait.h \
1144                   syslog.h \
1145                   utime.h])
1146
1147 AC_CHECK_HEADERS(sys/param.h)
1148
1149 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1150 [#ifdef HAVE_SYS_TYPES_H
1151 #include <sys/types.h>
1152 #endif
1153 #ifdef HAVE_SYS_SOCKET_H
1154 #include <sys/socket.h>
1155 #endif])
1156 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1157 [#ifdef HAVE_SYS_TYPES_H
1158 #include <sys/types.h>
1159 #endif
1160 #ifdef HAVE_SYS_SOCKET_H
1161 #include <sys/socket.h>
1162 #endif
1163 #ifdef HAVE_NET_IF_H
1164 #include <net/if.h>
1165 #endif
1166 #ifdef HAVE_NETINET_IN_H
1167 #include <netinet/in.h>
1168 #endif])
1169
1170 AC_CHECK_HEADERS(linux/if.h,[],[],
1171 [
1172 #ifdef HAVE_SYS_SOCKET_H
1173 #include <sys/socket.h>
1174 #endif
1175 ])
1176
1177 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1178         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1179 [#ifdef HAVE_SYS_TYPES_H
1180 #include <sys/types.h>
1181 #endif
1182 #ifdef HAVE_SYS_SOCKET_H
1183 #include <sys/socket.h>
1184 #endif
1185 #ifdef HAVE_LIMITS_H
1186 #include <limits.h>
1187 #endif
1188 #ifdef HAVE_LINUX_TYPES_H
1189 #include <linux/types.h>
1190 #endif
1191 #ifdef HAVE_NETINET_IN6_H
1192 #include <netinet/in6.h>
1193 #endif
1194 #ifdef HAVE_NETINET_IN_H
1195 #include <netinet/in.h>
1196 #endif])
1197
1198 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1199         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1200 [#ifdef HAVE_SYS_TYPES_H
1201 #include <sys/types.h>
1202 #endif
1203 #ifdef HAVE_SYS_SOCKET_H
1204 #include <sys/socket.h>
1205 #endif
1206 #ifdef HAVE_LIMITS_H
1207 #include <limits.h>
1208 #endif
1209 #ifdef HAVE_LINUX_TYPES_H
1210 #include <linux/types.h>
1211 #endif
1212 #ifdef HAVE_NETINET_IN6_H
1213 #include <netinet/in6.h>
1214 #endif
1215 #ifdef HAVE_NETINET_IN_H
1216 #include <netinet/in.h>
1217 #endif
1218 #ifdef HAVE_LINUX_IF_H
1219 #include <linux/if.h>
1220 #endif])
1221
1222 transparent_ok=0
1223 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1224   transparent_ok=1
1225 fi
1226 if test "x$linux_netfilter_ipv4" = "x1"; then
1227   transparent_ok=1
1228 fi
1229 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1230   transparent_ok=1
1231 fi
1232 if test "x$transparent_ok" = "x1"; then
1233   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1234 else
1235   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1236 fi
1237
1238 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1239 [#ifdef HAVE_SYS_TYPES_H
1240 #include <sys/types.h>
1241 #endif
1242 #ifdef HAVE_SYS_TIME_H
1243 #include <sys/time.h>
1244 #endif])
1245
1246 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1247 dnl Watch out.
1248
1249 AC_CHECK_SIZEOF(int8_t)
1250 AC_CHECK_SIZEOF(int16_t)
1251 AC_CHECK_SIZEOF(int32_t)
1252 AC_CHECK_SIZEOF(int64_t)
1253 AC_CHECK_SIZEOF(uint8_t)
1254 AC_CHECK_SIZEOF(uint16_t)
1255 AC_CHECK_SIZEOF(uint32_t)
1256 AC_CHECK_SIZEOF(uint64_t)
1257 AC_CHECK_SIZEOF(intptr_t)
1258 AC_CHECK_SIZEOF(uintptr_t)
1259
1260 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1261
1262 AC_CHECK_SIZEOF(char)
1263 AC_CHECK_SIZEOF(short)
1264 AC_CHECK_SIZEOF(int)
1265 AC_CHECK_SIZEOF(long)
1266 AC_CHECK_SIZEOF(long long)
1267 AC_CHECK_SIZEOF(__int64)
1268 AC_CHECK_SIZEOF(void *)
1269 AC_CHECK_SIZEOF(time_t)
1270 AC_CHECK_SIZEOF(size_t)
1271 AC_CHECK_SIZEOF(pid_t)
1272
1273 AC_CHECK_TYPES([uint, u_char, ssize_t])
1274
1275 AC_PC_FROM_UCONTEXT([:])
1276
1277 dnl used to include sockaddr_storage, but everybody has that.
1278 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1279 [#ifdef HAVE_SYS_TYPES_H
1280 #include <sys/types.h>
1281 #endif
1282 #ifdef HAVE_NETINET_IN_H
1283 #include <netinet/in.h>
1284 #endif
1285 #ifdef HAVE_NETINET_IN6_H
1286 #include <netinet/in6.h>
1287 #endif
1288 #ifdef HAVE_SYS_SOCKET_H
1289 #include <sys/socket.h>
1290 #endif
1291 #ifdef _WIN32
1292 #define _WIN32_WINNT 0x0501
1293 #define WIN32_LEAN_AND_MEAN
1294 #include <winsock2.h>
1295 #include <ws2tcpip.h>
1296 #endif
1297 ])
1298 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1299 [#ifdef HAVE_SYS_TYPES_H
1300 #include <sys/types.h>
1301 #endif
1302 #ifdef HAVE_NETINET_IN_H
1303 #include <netinet/in.h>
1304 #endif
1305 #ifdef HAVE_NETINET_IN6_H
1306 #include <netinet/in6.h>
1307 #endif
1308 #ifdef HAVE_SYS_SOCKET_H
1309 #include <sys/socket.h>
1310 #endif
1311 #ifdef _WIN32
1312 #define _WIN32_WINNT 0x0501
1313 #define WIN32_LEAN_AND_MEAN
1314 #include <winsock2.h>
1315 #include <ws2tcpip.h>
1316 #endif
1317 ])
1318
1319 AC_CHECK_TYPES([rlim_t], , ,
1320 [#ifdef HAVE_SYS_TYPES_H
1321 #include <sys/types.h>
1322 #endif
1323 #ifdef HAVE_SYS_TIME_H
1324 #include <sys/time.h>
1325 #endif
1326 #ifdef HAVE_SYS_RESOURCE_H
1327 #include <sys/resource.h>
1328 #endif
1329 ])
1330
1331 AX_CHECK_SIGN([time_t],
1332        [ : ],
1333        [ : ], [
1334 #ifdef HAVE_SYS_TYPES_H
1335 #include <sys/types.h>
1336 #endif
1337 #ifdef HAVE_SYS_TIME_H
1338 #include <sys/time.h>
1339 #endif
1340 #ifdef HAVE_TIME_H
1341 #include <time.h>
1342 #endif
1343 ])
1344
1345 if test "$ax_cv_decl_time_t_signed" = "no"; then
1346   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1347 fi
1348
1349 AX_CHECK_SIGN([size_t],
1350        [ tor_cv_size_t_signed=yes ],
1351        [ tor_cv_size_t_signed=no ], [
1352 #ifdef HAVE_SYS_TYPES_H
1353 #include <sys/types.h>
1354 #endif
1355 ])
1356
1357 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1358   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1359 fi
1360
1361 AX_CHECK_SIGN([enum always],
1362        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1363        [ : ], [
1364  enum always { AAA, BBB, CCC };
1365 ])
1366
1367 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1368 #ifdef HAVE_SYS_SOCKET_H
1369 #include <sys/socket.h>
1370 #endif
1371 ])
1372
1373 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1374
1375 AC_CHECK_SIZEOF(cell_t)
1376
1377 # Now make sure that NULL can be represented as zero bytes.
1378 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1379 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1380 [[#include <stdlib.h>
1381 #include <string.h>
1382 #include <stdio.h>
1383 #ifdef HAVE_STDDEF_H
1384 #include <stddef.h>
1385 #endif
1386 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1387 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1388        [tor_cv_null_is_zero=yes],
1389        [tor_cv_null_is_zero=no],
1390        [tor_cv_null_is_zero=cross])])
1391
1392 if test "$tor_cv_null_is_zero" = "cross"; then
1393   # Cross-compiling; let's hope that the target isn't raving mad.
1394   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1395 fi
1396
1397 if test "$tor_cv_null_is_zero" != "no"; then
1398   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1399             [Define to 1 iff memset(0) sets pointers to NULL])
1400 fi
1401
1402 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1403 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1404 [[#include <stdlib.h>
1405 #include <string.h>
1406 #include <stdio.h>
1407 #ifdef HAVE_STDDEF_H
1408 #include <stddef.h>
1409 #endif
1410 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1411 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1412        [tor_cv_dbl0_is_zero=yes],
1413        [tor_cv_dbl0_is_zero=no],
1414        [tor_cv_dbl0_is_zero=cross])])
1415
1416 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1417   # Cross-compiling; let's hope that the target isn't raving mad.
1418   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1419 fi
1420
1421 if test "$tor_cv_dbl0_is_zero" != "no"; then
1422   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1423             [Define to 1 iff memset(0) sets doubles to 0.0])
1424 fi
1425
1426 # And what happens when we malloc zero?
1427 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1428 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1429 [[#include <stdlib.h>
1430 #include <string.h>
1431 #include <stdio.h>
1432 #ifdef HAVE_STDDEF_H
1433 #include <stddef.h>
1434 #endif
1435 int main () { return malloc(0)?0:1; }]])],
1436        [tor_cv_malloc_zero_works=yes],
1437        [tor_cv_malloc_zero_works=no],
1438        [tor_cv_malloc_zero_works=cross])])
1439
1440 if test "$tor_cv_malloc_zero_works" = "cross"; then
1441   # Cross-compiling; let's hope that the target isn't raving mad.
1442   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1443 fi
1444
1445 if test "$tor_cv_malloc_zero_works" = "yes"; then
1446   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1447             [Define to 1 iff malloc(0) returns a pointer])
1448 fi
1449
1450 # whether we seem to be in a 2s-complement world.
1451 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1452 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1453 [[int main () { int problem = ((-99) != (~99)+1);
1454 return problem ? 1 : 0; }]])],
1455        [tor_cv_twos_complement=yes],
1456        [tor_cv_twos_complement=no],
1457        [tor_cv_twos_complement=cross])])
1458
1459 if test "$tor_cv_twos_complement" = "cross"; then
1460   # Cross-compiling; let's hope that the target isn't raving mad.
1461   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1462 fi
1463
1464 if test "$tor_cv_twos_complement" != "no"; then
1465   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1466             [Define to 1 iff we represent negative integers with
1467              two's complement])
1468 fi
1469
1470 # What does shifting a negative value do?
1471 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1472 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1473 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1474        [tor_cv_sign_extend=yes],
1475        [tor_cv_sign_extend=no],
1476        [tor_cv_sign_extend=cross])])
1477
1478 if test "$tor_cv_sign_extend" = "cross"; then
1479   # Cross-compiling; let's hope that the target isn't raving mad.
1480   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1481 fi
1482
1483 if test "$tor_cv_sign_extend" != "no"; then
1484   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1485             [Define to 1 iff right-shifting a negative value performs sign-extension])
1486 fi
1487
1488 # Whether we should use the dmalloc memory allocation debugging library.
1489 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1490 AC_ARG_WITH(dmalloc,
1491 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1492 [if [[ "$withval" = "yes" ]]; then
1493   dmalloc=1
1494   AC_MSG_RESULT(yes)
1495 else
1496   dmalloc=1
1497   AC_MSG_RESULT(no)
1498 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1499 )
1500
1501 if [[ $dmalloc -eq 1 ]]; then
1502   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1503   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1504   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1505   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1506 fi
1507
1508 AC_ARG_WITH(tcmalloc,
1509 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1510 [ tcmalloc=yes ], [ tcmalloc=no ])
1511
1512 if test "x$tcmalloc" = "xyes"; then
1513    LDFLAGS="-ltcmalloc $LDFLAGS"
1514 fi
1515
1516 using_custom_malloc=no
1517 if test "x$enable_openbsd_malloc" = "xyes"; then
1518    using_custom_malloc=yes
1519 fi
1520 if test "x$tcmalloc" = "xyes"; then
1521    using_custom_malloc=yes
1522 fi
1523 if test "$using_custom_malloc" = "no"; then
1524    AC_CHECK_FUNCS(mallinfo)
1525 fi
1526
1527 # By default, we're going to assume we don't have mlockall()
1528 # bionic and other platforms have various broken mlockall subsystems.
1529 # Some systems don't have a working mlockall, some aren't linkable,
1530 # and some have it but don't declare it.
1531 AC_CHECK_FUNCS(mlockall)
1532 AC_CHECK_DECLS([mlockall], , , [
1533 #ifdef HAVE_SYS_MMAN_H
1534 #include <sys/mman.h>
1535 #endif])
1536
1537 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1538 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1539 # using macros
1540 AC_CHECK_DECLS([getpagesize], , , [
1541 #ifdef HAVE_UNISTD_H
1542 #include <unistd.h>
1543 #endif])
1544
1545 # Allow user to specify an alternate syslog facility
1546 AC_ARG_WITH(syslog-facility,
1547 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1548 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1549 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1550 AC_SUBST(LOGFACILITY)
1551
1552 # Check if we have getresuid and getresgid
1553 AC_CHECK_FUNCS(getresuid getresgid)
1554
1555 # Check for gethostbyname_r in all its glorious incompatible versions.
1556 #   (This logic is based on that in Python's configure.in)
1557 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1558   [Define this if you have any gethostbyname_r()])
1559
1560 AC_CHECK_FUNC(gethostbyname_r, [
1561   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1562   OLD_CFLAGS=$CFLAGS
1563   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1564   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1565 #include <netdb.h>
1566   ]], [[
1567     char *cp1, *cp2;
1568     struct hostent *h1, *h2;
1569     int i1, i2;
1570     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1571   ]])],[
1572     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1573     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1574      [Define this if gethostbyname_r takes 6 arguments])
1575     AC_MSG_RESULT(6)
1576   ], [
1577     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1578 #include <netdb.h>
1579     ]], [[
1580       char *cp1, *cp2;
1581       struct hostent *h1;
1582       int i1, i2;
1583       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1584     ]])], [
1585       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1586       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1587         [Define this if gethostbyname_r takes 5 arguments])
1588       AC_MSG_RESULT(5)
1589    ], [
1590       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1591 #include <netdb.h>
1592      ]], [[
1593        char *cp1;
1594        struct hostent *h1;
1595        struct hostent_data hd;
1596        (void) gethostbyname_r(cp1,h1,&hd);
1597      ]])], [
1598        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1599        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1600          [Define this if gethostbyname_r takes 3 arguments])
1601        AC_MSG_RESULT(3)
1602      ], [
1603        AC_MSG_RESULT(0)
1604      ])
1605   ])
1606  ])
1607  CFLAGS=$OLD_CFLAGS
1608 ])
1609
1610 AC_CACHE_CHECK([whether the C compiler supports __func__],
1611   tor_cv_have_func_macro,
1612   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1613 #include <stdio.h>
1614 int main(int c, char **v) { puts(__func__); }])],
1615   tor_cv_have_func_macro=yes,
1616   tor_cv_have_func_macro=no))
1617
1618 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1619   tor_cv_have_FUNC_macro,
1620   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1621 #include <stdio.h>
1622 int main(int c, char **v) { puts(__FUNC__); }])],
1623   tor_cv_have_FUNC_macro=yes,
1624   tor_cv_have_FUNC_macro=no))
1625
1626 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1627   tor_cv_have_FUNCTION_macro,
1628   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1629 #include <stdio.h>
1630 int main(int c, char **v) { puts(__FUNCTION__); }])],
1631   tor_cv_have_FUNCTION_macro=yes,
1632   tor_cv_have_FUNCTION_macro=no))
1633
1634 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1635   tor_cv_have_environ_declared,
1636   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1637 #ifdef HAVE_UNISTD_H
1638 #include <unistd.h>
1639 #endif
1640 #include <stdlib.h>
1641 int main(int c, char **v) { char **t = environ; }])],
1642   tor_cv_have_environ_declared=yes,
1643   tor_cv_have_environ_declared=no))
1644
1645 if test "$tor_cv_have_func_macro" = "yes"; then
1646   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1647 fi
1648
1649 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1650   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1651 fi
1652
1653 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1654   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1655            [Defined if the compiler supports __FUNCTION__])
1656 fi
1657
1658 if test "$tor_cv_have_environ_declared" = "yes"; then
1659   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1660            [Defined if we have extern char **environ already declared])
1661 fi
1662
1663 # $prefix stores the value of the --prefix command line option, or
1664 # NONE if the option wasn't set.  In the case that it wasn't set, make
1665 # it be the default, so that we can use it to expand directories now.
1666 if test "x$prefix" = "xNONE"; then
1667   prefix=$ac_default_prefix
1668 fi
1669
1670 # and similarly for $exec_prefix
1671 if test "x$exec_prefix" = "xNONE"; then
1672   exec_prefix=$prefix
1673 fi
1674
1675 if test "x$BUILDDIR" = "x"; then
1676   BUILDDIR=`pwd`
1677 fi
1678 AC_SUBST(BUILDDIR)
1679 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1680 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1681
1682 if test "x$CONFDIR" = "x"; then
1683   CONFDIR=`eval echo $sysconfdir/tor`
1684 fi
1685 AC_SUBST(CONFDIR)
1686 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1687 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1688
1689 BINDIR=`eval echo $bindir`
1690 AC_SUBST(BINDIR)
1691 LOCALSTATEDIR=`eval echo $localstatedir`
1692 AC_SUBST(LOCALSTATEDIR)
1693
1694 if test "$bwin32" = "true"; then
1695   # Test if the linker supports the --nxcompat and --dynamicbase options
1696   # for Windows
1697   save_LDFLAGS="$LDFLAGS"
1698   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1699   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1700   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1701     [AC_MSG_RESULT([yes])]
1702     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1703     [AC_MSG_RESULT([no])]
1704   )
1705   LDFLAGS="$save_LDFLAGS"
1706 fi
1707
1708 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1709 # than autoconf's macros like.
1710 if test "$GCC" = "yes"; then
1711   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1712   # accident waiting to happen.
1713   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1714 else
1715   # Override optimization level for non-gcc compilers
1716   CFLAGS="$CFLAGS -O"
1717   enable_gcc_warnings=no
1718   enable_gcc_warnings_advisory=no
1719 fi
1720
1721 # Warnings implies advisory-warnings and -Werror.
1722 if test "$enable_gcc_warnings" = "yes"; then
1723   enable_gcc_warnings_advisory=yes
1724   enable_fatal_warnings=yes
1725 fi
1726
1727 # OS X Lion started deprecating the system openssl. Let's just disable
1728 # all deprecation warnings on OS X. Also, to potentially make the binary
1729 # a little smaller, let's enable dead_strip.
1730 case "$host_os" in
1731
1732  darwin*)
1733     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1734     LDFLAGS="$LDFLAGS -dead_strip" ;;
1735 esac
1736
1737 # Add some more warnings which we use in development but not in the
1738 # released versions.  (Some relevant gcc versions can't handle these.)
1739 #
1740 # Note that we have to do this near the end  of the autoconf process, or
1741 # else we may run into problems when these warnings hit on the testing C
1742 # programs that autoconf wants to build.
1743 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1744
1745   case "$host" in
1746     *-*-openbsd* | *-*-bitrig*)
1747       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1748       # That's fine, except that the headers don't pass -Wredundant-decls.
1749       # Therefore, let's disable -Wsystem-headers when we're building
1750       # with maximal warnings on OpenBSD.
1751       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1752   esac
1753
1754   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1755   # have it work better.
1756   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1757
1758   # This warning was added in gcc 4.3, but it appears to generate
1759   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1760   #CFLAGS="$CFLAGS -Wlogical-op"
1761
1762   m4_foreach_w([warning_flag], [
1763      -Waddress
1764      -Waddress-of-array-temporary
1765      -Waddress-of-temporary
1766      -Wambiguous-macro
1767      -Wanonymous-pack-parens
1768      -Warc
1769      -Warc-abi
1770      -Warc-bridge-casts-disallowed-in-nonarc
1771      -Warc-maybe-repeated-use-of-weak
1772      -Warc-performSelector-leaks
1773      -Warc-repeated-use-of-weak
1774      -Warray-bounds
1775      -Warray-bounds-pointer-arithmetic
1776      -Wasm
1777      -Wasm-operand-widths
1778      -Watomic-properties
1779      -Watomic-property-with-user-defined-accessor
1780      -Wauto-import
1781      -Wauto-storage-class
1782      -Wauto-var-id
1783      -Wavailability
1784      -Wbackslash-newline-escape
1785      -Wbad-array-new-length
1786      -Wbind-to-temporary-copy
1787      -Wbitfield-constant-conversion
1788      -Wbool-conversion
1789      -Wbool-conversions
1790      -Wbuiltin-requires-header
1791      -Wchar-align
1792      -Wcompare-distinct-pointer-types
1793      -Wcomplex-component-init
1794      -Wconditional-type-mismatch
1795      -Wconfig-macros
1796      -Wconstant-conversion
1797      -Wconstant-logical-operand
1798      -Wconstexpr-not-const
1799      -Wcustom-atomic-properties
1800      -Wdangling-field
1801      -Wdangling-initializer-list
1802      -Wdate-time
1803      -Wdelegating-ctor-cycles
1804      -Wdeprecated-implementations
1805      -Wdeprecated-register
1806      -Wdirect-ivar-access
1807      -Wdiscard-qual
1808      -Wdistributed-object-modifiers
1809      -Wdivision-by-zero
1810      -Wdollar-in-identifier-extension
1811      -Wdouble-promotion
1812      -Wduplicate-decl-specifier
1813      -Wduplicate-enum
1814      -Wduplicate-method-arg
1815      -Wduplicate-method-match
1816      -Wduplicated-cond
1817      -Wdynamic-class-memaccess
1818      -Wembedded-directive
1819      -Wempty-translation-unit
1820      -Wenum-conversion
1821      -Wexit-time-destructors
1822      -Wexplicit-ownership-type
1823      -Wextern-initializer
1824      -Wextra
1825      -Wextra-semi
1826      -Wextra-tokens
1827      -Wflexible-array-extensions
1828      -Wfloat-conversion
1829      -Wformat-non-iso
1830      -Wfour-char-constants
1831      -Wgcc-compat
1832      -Wglobal-constructors
1833      -Wgnu-array-member-paren-init
1834      -Wgnu-designator
1835      -Wgnu-static-float-init
1836      -Wheader-guard
1837      -Wheader-hygiene
1838      -Widiomatic-parentheses
1839      -Wignored-attributes
1840      -Wimplicit-atomic-properties
1841      -Wimplicit-conversion-floating-point-to-bool
1842      -Wimplicit-exception-spec-mismatch
1843      -Wimplicit-fallthrough
1844      -Wimplicit-fallthrough-per-function
1845      -Wimplicit-retain-self
1846      -Wimport-preprocessor-directive-pedantic
1847      -Wincompatible-library-redeclaration
1848      -Wincompatible-pointer-types-discards-qualifiers
1849      -Wincomplete-implementation
1850      -Wincomplete-module
1851      -Wincomplete-umbrella
1852      -Winit-self
1853      -Wint-conversions
1854      -Wint-to-void-pointer-cast
1855      -Winteger-overflow
1856      -Winvalid-constexpr
1857      -Winvalid-iboutlet
1858      -Winvalid-noreturn
1859      -Winvalid-pp-token
1860      -Winvalid-source-encoding
1861      -Winvalid-token-paste
1862      -Wknr-promoted-parameter
1863      -Wlanguage-extension-token
1864      -Wlarge-by-value-copy
1865      -Wliteral-conversion
1866      -Wliteral-range
1867      -Wlocal-type-template-args
1868      -Wlogical-op
1869      -Wloop-analysis
1870      -Wmain-return-type
1871      -Wmalformed-warning-check
1872      -Wmethod-signatures
1873      -Wmicrosoft
1874      -Wmicrosoft-exists
1875      -Wmismatched-parameter-types
1876      -Wmismatched-return-types
1877      -Wmissing-field-initializers
1878      -Wmissing-format-attribute
1879      -Wmissing-noreturn
1880      -Wmissing-selector-name
1881      -Wmissing-sysroot
1882      -Wmissing-variable-declarations
1883      -Wmodule-conflict
1884      -Wnested-anon-types
1885      -Wnewline-eof
1886      -Wnon-literal-null-conversion
1887      -Wnon-pod-varargs
1888      -Wnonportable-cfstrings
1889      -Wnormalized=id
1890      -Wnull-arithmetic
1891      -Wnull-character
1892      -Wnull-conversion
1893      -Wnull-dereference
1894      -Wout-of-line-declaration
1895      -Wover-aligned
1896      -Woverlength-strings
1897      -Woverride-init
1898      -Woverriding-method-mismatch
1899      -Wpointer-type-mismatch
1900      -Wpredefined-identifier-outside-function
1901      -Wprotocol-property-synthesis-ambiguity
1902      -Wreadonly-iboutlet-property
1903      -Wreadonly-setter-attrs
1904      -Wreceiver-expr
1905      -Wreceiver-forward-class
1906      -Wreceiver-is-weak
1907      -Wreinterpret-base-class
1908      -Wrequires-super-attribute
1909      -Wreserved-user-defined-literal
1910      -Wreturn-stack-address
1911      -Wsection
1912      -Wselector-type-mismatch
1913      -Wsentinel
1914      -Wserialized-diagnostics
1915      -Wshadow
1916      -Wshift-count-negative
1917      -Wshift-count-overflow
1918      -Wshift-negative-value
1919      -Wshift-overflow=2
1920      -Wshift-sign-overflow
1921      -Wshorten-64-to-32
1922      -Wsizeof-array-argument
1923      -Wsource-uses-openmp
1924      -Wstatic-float-init
1925      -Wstatic-in-inline
1926      -Wstatic-local-in-inline
1927      -Wstrict-overflow=1
1928      -Wstring-compare
1929      -Wstring-conversion
1930      -Wstrlcpy-strlcat-size
1931      -Wstrncat-size
1932      -Wsuggest-attribute=format
1933      -Wsuggest-attribute=noreturn
1934      -Wsuper-class-method-mismatch
1935      -Wswitch-bool
1936      -Wsync-nand
1937      -Wtautological-constant-out-of-range-compare
1938      -Wtentative-definition-incomplete-type
1939      -Wtrampolines
1940      -Wtype-safety
1941      -Wtypedef-redefinition
1942      -Wtypename-missing
1943      -Wundefined-inline
1944      -Wundefined-internal
1945      -Wundefined-reinterpret-cast
1946      -Wunicode
1947      -Wunicode-whitespace
1948      -Wunknown-warning-option
1949      -Wunnamed-type-template-args
1950      -Wunneeded-member-function
1951      -Wunsequenced
1952      -Wunsupported-visibility
1953      -Wunused-but-set-parameter
1954      -Wunused-but-set-variable
1955      -Wunused-command-line-argument
1956      -Wunused-const-variable=2
1957      -Wunused-exception-parameter
1958      -Wunused-local-typedefs
1959      -Wunused-member-function
1960      -Wunused-sanitize-argument
1961      -Wunused-volatile-lvalue
1962      -Wuser-defined-literals
1963      -Wvariadic-macros
1964      -Wvector-conversion
1965      -Wvector-conversions
1966      -Wvexing-parse
1967      -Wvisibility
1968      -Wvla-extension
1969      -Wzero-length-array
1970   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
1971
1972 dnl    We should re-enable this in some later version.  Clang doesn't
1973 dnl    mind, but it causes trouble with GCC.
1974 dnl     -Wstrict-overflow=2
1975
1976 dnl    These seem to require annotations that we don't currently use,
1977 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
1978 dnl     -Wthread-safety
1979 dnl     -Wthread-safety-analysis
1980 dnl     -Wthread-safety-attributes
1981 dnl     -Wthread-safety-beta
1982 dnl     -Wthread-safety-precise
1983
1984   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1985   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1986   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1987   CFLAGS="$CFLAGS -Wwrite-strings"
1988   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1989   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
1990   CFLAGS="$CFLAGS -Wunused-parameter "
1991   # These interfere with building main() { return 0; }, which autoconf
1992   # likes to use as its default program.
1993   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
1994
1995   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
1996     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
1997   fi
1998   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
1999     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2000   fi
2001
2002   if test "x$enable_fatal_warnings" = "xyes"; then
2003     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2004     # default autoconf programs are full of errors.
2005     CFLAGS="$CFLAGS -Werror"
2006   fi
2007
2008 fi
2009
2010 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2011    case "$host_os" in
2012     darwin*)
2013       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2014    esac
2015 fi
2016
2017 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2018
2019 AC_CONFIG_FILES([
2020         Doxyfile
2021         Makefile
2022         contrib/dist/suse/tor.sh
2023         contrib/operator-tools/tor.logrotate
2024         contrib/dist/tor.sh
2025         contrib/dist/torctl
2026         contrib/dist/tor.service
2027         src/config/torrc.sample
2028         src/config/torrc.minimal
2029         scripts/maint/checkOptionDocs.pl
2030         scripts/maint/updateVersions.pl
2031 ])
2032
2033 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2034   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2035   for file in $regular_mans ; do
2036     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2037       echo "==================================";
2038       echo;
2039       echo "Building Tor has failed since manpages cannot be built.";
2040       echo;
2041       echo "You need asciidoc installed to be able to build the manpages.";
2042       echo "To build without manpages, use the --disable-asciidoc argument";
2043       echo "when calling configure.";
2044       echo;
2045       echo "==================================";
2046       exit 1;
2047     fi
2048   done
2049 fi
2050
2051 if test "$fragile_hardening" = "yes"; then
2052   AC_MSG_WARN([
2053
2054 ============
2055 Warning!  Building Tor with --enable-fragile-hardening (also known as
2056 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2057 other kinds of attacks easier. A Tor instance build with this option will be
2058 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2059 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2060 denial of service attacks. For more information, see
2061 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2062 ============
2063   ])
2064 fi
2065
2066 AC_OUTPUT