configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.1-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 AC_ARG_ENABLE(debug,
  23  AS_HELP_STRING(--enable-debug, compile with debugging info),
  24 [if test x$enableval = xyes; then
  25     CFLAGS="$CFLAGS -g"
  26 fi])
  27
  28 #XXXX ideally, we should make this into a no-op, and detect whether we're
  29 #compiling for the iphone by using $target.
  30 AC_ARG_ENABLE(iphone,
  31  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  32  [if test x$enableval = xyes ; then
  33    tor_cv_iphone=true
  34    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  35   fi])
  36
  37 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  38 AC_ARG_ENABLE(buf-freelists,
  39    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  40 AC_ARG_ENABLE(openbsd-malloc,
  41    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  42 AC_ARG_ENABLE(instrument-downloads,
  43    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  44
  45 if test x$enable_buf_freelists != xno; then
  46   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  47             [Defined if we try to use freelists for buffer RAM chunks])
  48 fi
  49 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  50 if test x$enable_instrument_downloads = xyes; then
  51   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  52             [Defined if we want to keep track of how much of each kind of resource we download.])
  53 fi
  54
  55 AC_ARG_ENABLE(transparent,
  56      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  57      [case "${enableval}" in
  58         yes) transparent=true ;;
  59         no)  transparent=false ;;
  60         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  61       esac], [transparent=true])
  62
  63 AC_ARG_ENABLE(threads,
  64      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  65
  66 if test x$enable_threads = x; then
  67    case $host in
  68     *-*-solaris* )
  69      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  70      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  71 cpu workers lock up here, so I will disable threads.])
  72      enable_threads="no";;
  73     *)
  74      enable_threads="yes";;
  75    esac
  76 fi
  77
  78 if test "$enable_threads" = "yes"; then
  79   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  80 fi
  81
  82 case $host in
  83    *-*-solaris* )
  84      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  85      ;;
  86 esac
  87
  88 AC_ARG_ENABLE(gcc-warnings,
  89      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  90
  91 AC_ARG_ENABLE(local-appdata,
  92    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
  93 if test "$enable_local_appdata" = "yes"; then
  94   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
  95             [Defined if we default to host local appdata paths on Windows])
  96 fi
  97
  98 AC_PROG_CC
  99 AC_PROG_CPP
 100 AC_PROG_MAKE_SET
 101 AC_PROG_RANLIB
 102
 103 dnl autoconf 2.59 appears not to support AC_PROG_SED
 104 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 105
 106 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 107 AC_PATH_PROG([OPENSSL], [openssl], none)
 108
 109 TORUSER=_tor
 110 AC_ARG_WITH(tor-user,
 111         [  --with-tor-user=NAME    Specify username for tor daemon ],
 112         [
 113            TORUSER=$withval
 114         ]
 115 )
 116 AC_SUBST(TORUSER)
 117
 118 TORGROUP=_tor
 119 AC_ARG_WITH(tor-group,
 120         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 121         [
 122            TORGROUP=$withval
 123         ]
 124 )
 125 AC_SUBST(TORGROUP)
 126
 127
 128 dnl If WIN32 is defined and non-zero, we are building for win32
 129 AC_MSG_CHECKING([for win32])
 130 AC_RUN_IFELSE([
 131 int main(int c, char **v) {
 132 #ifdef WIN32
 133 #if WIN32
 134   return 0;
 135 #else
 136   return 1;
 137 #endif
 138 #else
 139   return 2;
 140 #endif
 141 }],
 142 bwin32=true; AC_MSG_RESULT([yes]),
 143 bwin32=false; AC_MSG_RESULT([no]),
 144 bwin32=cross; AC_MSG_RESULT([cross])
 145 )
 146
 147 if test "$bwin32" = cross; then
 148 AC_MSG_CHECKING([for win32 (cross)])
 149 AC_COMPILE_IFELSE([
 150 #ifdef WIN32
 151 int main(int c, char **v) {return 0;}
 152 #else
 153 #error
 154 int main(int c, char **v) {return x(y);}
 155 #endif
 156 ],
 157 bwin32=true; AC_MSG_RESULT([yes]),
 158 bwin32=false; AC_MSG_RESULT([no]))
 159 fi
 160
 161 if test "$bwin32" = true; then
 162 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 163 fi
 164 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 165
 166 dnl Enable C99 when compiling with MIPSpro
 167 AC_MSG_CHECKING([for MIPSpro compiler])
 168 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 169 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 170 #error
 171   return x(y);
 172 #endif
 173 ]),
 174 bmipspro=false; AC_MSG_RESULT(no),
 175 bmipspro=true; AC_MSG_RESULT(yes))
 176
 177 if test "$bmipspro" = true; then
 178   CFLAGS="$CFLAGS -c99"
 179 fi
 180
 181 AC_C_BIGENDIAN
 182
 183 AC_SEARCH_LIBS(socket, [socket])
 184 AC_SEARCH_LIBS(gethostbyname, [nsl])
 185 AC_SEARCH_LIBS(dlopen, [dl])
 186 AC_SEARCH_LIBS(inet_aton, [resolv])
 187
 188 if test "$enable_threads" = "yes"; then
 189   AC_SEARCH_LIBS(pthread_create, [pthread])
 190   AC_SEARCH_LIBS(pthread_detach, [pthread])
 191 fi
 192
 193 dnl -------------------------------------------------------------------
 194 dnl Check for functions before libevent, since libevent-1.2 apparently
 195 dnl exports strlcpy without defining it in a header.
 196
 197 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl)
 198
 199 using_custom_malloc=no
 200 if test x$enable_openbsd_malloc = xyes ; then
 201    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 202    using_custom_malloc=yes
 203 fi
 204 if test x$tcmalloc = xyes ; then
 205    using_custom_malloc=yes
 206 fi
 207 if test $using_custom_malloc = no ; then
 208    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 209 fi
 210
 211 if test "$enable_threads" = "yes"; then
 212   AC_CHECK_HEADERS(pthread.h)
 213   AC_CHECK_FUNCS(pthread_create)
 214 fi
 215
 216 dnl ------------------------------------------------------
 217 dnl Where do you live, libevent?  And how do we call you?
 218
 219 if test "$bwin32" = true; then
 220   TOR_LIB_WS32=-lws2_32
 221   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 222   # think it's actually necessary.
 223   TOR_LIB_GDI=-lgdi32
 224 else
 225   TOR_LIB_WS32=
 226   TOR_LIB_GDI=
 227 fi
 228 AC_SUBST(TOR_LIB_WS32)
 229 AC_SUBST(TOR_LIB_GDI)
 230
 231 dnl We need to do this before we try our disgusting hack below.
 232 AC_CHECK_HEADERS([sys/types.h])
 233
 234 dnl This is a disgusting hack so we safely include older libevent headers.
 235 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 236 AC_CHECK_TYPE(u_int32_t, unsigned long)
 237 AC_CHECK_TYPE(u_int16_t, unsigned short)
 238 AC_CHECK_TYPE(u_int8_t, unsigned char)
 239
 240 tor_libevent_pkg_redhat="libevent"
 241 tor_libevent_pkg_debian="libevent-dev"
 242 tor_libevent_devpkg_redhat="libevent-devel"
 243 tor_libevent_devpkg_debian="libevent-dev"
 244
 245 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 246 #ifdef WIN32
 247 #include <winsock2.h>
 248 #endif
 249 #include <stdlib.h>
 250 #include <sys/time.h>
 251 #include <sys/types.h>
 252 #include <event.h>], [
 253 #ifdef WIN32
 254 #include <winsock2.h>
 255 #endif
 256 void exit(int); void *event_init(void);],
 257     [
 258 #ifdef WIN32
 259 {WSADATA d; WSAStartup(0x101,&d); }
 260 #endif
 261 event_init(); exit(0);
 262 ], [--with-libevent-dir], [/opt/libevent])
 263
 264 dnl Now check for particular libevent functions.
 265 save_LIBS="$LIBS"
 266 save_LDFLAGS="$LDFLAGS"
 267 save_CPPFLAGS="$CPPFLAGS"
 268 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 269 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 270 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 271 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 272 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 273 [#include <event.h>
 274 ])
 275
 276 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 277
 278 LIBS="$save_LIBS"
 279 LDFLAGS="$save_LDFLAGS"
 280 CPPFLAGS="$save_CPPFLAGS"
 281
 282 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 283
 284 dnl ------------------------------------------------------
 285 dnl Where do you live, openssl?  And how do we call you?
 286
 287 tor_openssl_pkg_redhat="openssl"
 288 tor_openssl_pkg_debian="libssl"
 289 tor_openssl_devpkg_redhat="openssl-devel"
 290 tor_openssl_devpkg_debian="libssl-dev"
 291
 292 ALT_openssl_WITHVAL=""
 293 AC_ARG_WITH(ssl-dir,
 294   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 295   [
 296       if test "x$withval" != xno && test "x$withval" != "x" ; then
 297          ALT_openssl_WITHVAL="$withval"
 298       fi
 299   ])
 300
 301 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 302     [#include <openssl/rand.h>],
 303     [void RAND_add(const void *buf, int num, double entropy);],
 304     [RAND_add((void*)0,0,0); exit(0);], [],
 305     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 306
 307 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 308
 309 dnl ------------------------------------------------------
 310 dnl Where do you live, zlib?  And how do we call you?
 311
 312 tor_openssl_pkg_redhat="zlib"
 313 tor_openssl_pkg_debian="zlib1g"
 314 tor_openssl_devpkg_redhat="zlib-devel"
 315 tor_openssl_devpkg_debian="zlib1g-dev"
 316
 317 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 318     [#include <zlib.h>],
 319     [const char * zlibVersion(void);],
 320     [zlibVersion(); exit(0);], [--with-zlib-dir],
 321     [/opt/zlib])
 322
 323 dnl Make sure to enable support for large off_t if available.
 324
 325 AC_SYS_LARGEFILE
 326
 327 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 328
 329 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 330
 331 dnl These headers are not essential
 332
 333 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 334
 335 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 336 [#ifdef HAVE_MALLOC_H
 337 #include <malloc.h>
 338 #endif
 339 #ifdef HAVE_MALLOC_MALLOC_H
 340 #include <malloc/malloc.h>
 341 #endif])
 342
 343 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 344 [#ifdef HAVE_SYS_TYPES_H
 345 #include <sys/types.h>
 346 #endif
 347 #ifdef HAVE_SYS_SOCKET_H
 348 #include <sys/socket.h>
 349 #endif])
 350 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 351 [#ifdef HAVE_SYS_TYPES_H
 352 #include <sys/types.h>
 353 #endif
 354 #ifdef HAVE_SYS_SOCKET_H
 355 #include <sys/socket.h>
 356 #endif
 357 #ifdef HAVE_NET_IF_H
 358 #include <net/if.h>
 359 #endif])
 360 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 361         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 362 [#ifdef HAVE_SYS_TYPES_H
 363 #include <sys/types.h>
 364 #endif
 365 #ifdef HAVE_SYS_SOCKET_H
 366 #include <sys/socket.h>
 367 #endif
 368 #ifdef HAVE_LIMITS_H
 369 #include <limits.h>
 370 #endif
 371 #ifdef HAVE_LINUX_TYPES_H
 372 #include <linux/types.h>
 373 #endif
 374 #ifdef HAVE_NETINET_IN6_H
 375 #include <netinet/in6.h>
 376 #endif
 377 #ifdef HAVE_NETINET_IN_H
 378 #include <netinet/in.h>
 379 #endif])
 380
 381 if test x$transparent = xtrue ; then
 382    transparent_ok=0
 383    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 384      transparent_ok=1
 385    fi
 386    if test x$linux_netfilter_ipv4 = x1 ; then
 387      transparent_ok=1
 388    fi
 389    if test x$transparent_ok = x1 ; then
 390      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 391      case $host in
 392        *-*-openbsd*)
 393          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 394      esac
 395    else
 396      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 397    fi
 398 fi
 399
 400 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 401 [#ifdef HAVE_SYS_TYPES_H
 402 #include <sys/types.h>
 403 #endif
 404 #ifdef HAVE_SYS_TIME_H
 405 #include <sys/time.h>
 406 #endif])
 407
 408 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 409 dnl Watch out.
 410
 411 AC_CHECK_SIZEOF(int8_t)
 412 AC_CHECK_SIZEOF(int16_t)
 413 AC_CHECK_SIZEOF(int32_t)
 414 AC_CHECK_SIZEOF(int64_t)
 415 AC_CHECK_SIZEOF(uint8_t)
 416 AC_CHECK_SIZEOF(uint16_t)
 417 AC_CHECK_SIZEOF(uint32_t)
 418 AC_CHECK_SIZEOF(uint64_t)
 419 AC_CHECK_SIZEOF(intptr_t)
 420 AC_CHECK_SIZEOF(uintptr_t)
 421
 422 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 423
 424 AC_CHECK_SIZEOF(char)
 425 AC_CHECK_SIZEOF(short)
 426 AC_CHECK_SIZEOF(int)
 427 AC_CHECK_SIZEOF(long)
 428 AC_CHECK_SIZEOF(long long)
 429 AC_CHECK_SIZEOF(__int64)
 430 AC_CHECK_SIZEOF(void *)
 431 AC_CHECK_SIZEOF(time_t)
 432 AC_CHECK_SIZEOF(size_t)
 433
 434 AC_CHECK_TYPES([uint, u_char, ssize_t])
 435
 436 dnl used to include sockaddr_storage, but everybody has that.
 437 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 438 [#ifdef HAVE_SYS_TYPES_H
 439 #include <sys/types.h>
 440 #endif
 441 #ifdef HAVE_NETINET_IN_H
 442 #include <netinet/in.h>
 443 #endif
 444 #ifdef HAVE_NETINET_IN6_H
 445 #include <netinet/in6.h>
 446 #endif
 447 #ifdef HAVE_SYS_SOCKET_H
 448 #include <sys/socket.h>
 449 #endif
 450 #ifdef MS_WINDOWS
 451 #define WIN32_WINNT 0x400
 452 #define _WIN32_WINNT 0x400
 453 #define WIN32_LEAN_AND_MEAN
 454 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 455 #include <winsock.h>
 456 #else
 457 #include <winsock2.h>
 458 #include <ws2tcpip.h>
 459 #endif
 460 #endif
 461 ])
 462 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 463 [#ifdef HAVE_SYS_TYPES_H
 464 #include <sys/types.h>
 465 #endif
 466 #ifdef HAVE_NETINET_IN_H
 467 #include <netinet/in.h>
 468 #endif
 469 #ifdef HAVE_NETINET_IN6_H
 470 #include <netinet/in6.h>
 471 #endif
 472 #ifdef HAVE_SYS_SOCKET_H
 473 #include <sys/socket.h>
 474 #endif
 475 #ifdef MS_WINDOWS
 476 #define WIN32_WINNT 0x400
 477 #define _WIN32_WINNT 0x400
 478 #define WIN32_LEAN_AND_MEAN
 479 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 480 #include <winsock.h>
 481 #else
 482 #include <winsock2.h>
 483 #include <ws2tcpip.h>
 484 #endif
 485 #endif
 486 ])
 487
 488 AC_CHECK_TYPES([rlim_t], , ,
 489 [#ifdef HAVE_SYS_TYPES_H
 490 #include <sys/types.h>
 491 #endif
 492 #ifdef HAVE_SYS_TIME_H
 493 #include <sys/time.h>
 494 #endif
 495 #ifdef HAVE_SYS_RESOURCE_H
 496 #include <sys/resource.h>
 497 #endif
 498 ])
 499
 500 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 501 AC_RUN_IFELSE(AC_LANG_SOURCE([
 502 #ifdef HAVE_SYS_TYPES_H
 503 #include <sys/types.h>
 504 #endif
 505 #ifdef HAVE_SYS_TIME_H
 506 #include <sys/time.h>
 507 #endif
 508 #ifdef HAVE_TIME_H
 509 #include <time.h>
 510 #endif
 511 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 512   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 513 ])
 514
 515 if test "$tor_cv_time_t_signed" = cross; then
 516   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 517 fi
 518
 519 if test "$tor_cv_time_t_signed" != no; then
 520   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 521             [Define to 1 iff time_t is signed])
 522 fi
 523
 524 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 525 #ifdef HAVE_SYS_SOCKET_H
 526 #include <sys/socket.h>
 527 #endif
 528 ])
 529
 530 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 531
 532 AC_CHECK_SIZEOF(cell_t)
 533
 534 # Now make sure that NULL can be represented as zero bytes.
 535 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 536 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 537 [[#include <stdlib.h>
 538 #include <string.h>
 539 #include <stdio.h>
 540 #ifdef HAVE_STDDEF_H
 541 #include <stddef.h>
 542 #endif
 543 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 544 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 545        [tor_cv_null_is_zero=yes],
 546        [tor_cv_null_is_zero=no],
 547        [tor_cv_null_is_zero=cross])])
 548
 549 if test "$tor_cv_null_is_zero" = cross ; then
 550   # Cross-compiling; let's hope that the target isn't raving mad.
 551   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 552 fi
 553
 554 if test "$tor_cv_null_is_zero" != no; then
 555   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 556             [Define to 1 iff memset(0) sets pointers to NULL])
 557 fi
 558
 559 # And what happens when we malloc zero?
 560 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 561 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 562 [[#include <stdlib.h>
 563 #include <string.h>
 564 #include <stdio.h>
 565 #ifdef HAVE_STDDEF_H
 566 #include <stddef.h>
 567 #endif
 568 int main () { return malloc(0)?0:1; }]])],
 569        [tor_cv_malloc_zero_works=yes],
 570        [tor_cv_malloc_zero_works=no],
 571        [tor_cv_malloc_zero_works=cross])])
 572
 573 if test "$tor_cv_malloc_zero_works" = cross; then
 574   # Cross-compiling; let's hope that the target isn't raving mad.
 575   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 576 fi
 577
 578 if test "$tor_cv_malloc_zero_works" = yes; then
 579   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 580             [Define to 1 iff malloc(0) returns a pointer])
 581 fi
 582
 583 # whether we seem to be in a 2s-complement world.
 584 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 585 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 586 [[int main () { int problem = ((-99) != (~99)+1);
 587 return problem ? 1 : 0; }]])],
 588        [tor_cv_twos_complement=yes],
 589        [tor_cv_twos_complement=no],
 590        [tor_cv_twos_complement=cross])])
 591
 592 if test "$tor_cv_twos_complement" = cross ; then
 593   # Cross-compiling; let's hope that the target isn't raving mad.
 594   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 595 fi
 596
 597 if test "$tor_cv_twos_complement" != no ; then
 598   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 599             [Define to 1 iff we represent negative integers with two's complement])
 600 fi
 601
 602 # Whether we should use the dmalloc memory allocation debugging library.
 603 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 604 AC_ARG_WITH(dmalloc,
 605 [  --with-dmalloc          Use debug memory allocation library. ],
 606 [if [[ "$withval" = "yes" ]]; then
 607   dmalloc=1
 608   AC_MSG_RESULT(yes)
 609 else
 610   dmalloc=1
 611   AC_MSG_RESULT(no)
 612 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 613 )
 614
 615 if [[ $dmalloc -eq 1 ]]; then
 616   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 617   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 618   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 619   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 620   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 621 fi
 622
 623 AC_ARG_WITH(tcmalloc,
 624 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 625 [ tcmalloc=yes ], [ tcmalloc=no ])
 626
 627 if test x$tcmalloc = xyes ; then
 628    LDFLAGS="-ltcmalloc $LDFLAGS"
 629 fi
 630
 631 # Allow user to specify an alternate syslog facility
 632 AC_ARG_WITH(syslog-facility,
 633 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 634 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 635 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 636 AC_SUBST(LOGFACILITY)
 637
 638 # Check if we have getresuid and getresgid
 639 AC_CHECK_FUNCS(getresuid getresgid)
 640
 641 # Check for gethostbyname_r in all its glorious incompatible versions.
 642 #   (This logic is based on that in Python's configure.in)
 643 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 644   [Define this if you have any gethostbyname_r()])
 645
 646 AC_CHECK_FUNC(gethostbyname_r, [
 647   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 648   OLD_CFLAGS=$CFLAGS
 649   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 650   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 651 #include <netdb.h>
 652   ], [[
 653     char *cp1, *cp2;
 654     struct hostent *h1, *h2;
 655     int i1, i2;
 656     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 657   ]]),[
 658     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 659     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 660      [Define this if gethostbyname_r takes 6 arguments])
 661     AC_MSG_RESULT(6)
 662   ], [
 663     AC_TRY_COMPILE([
 664 #include <netdb.h>
 665     ], [
 666       char *cp1, *cp2;
 667       struct hostent *h1;
 668       int i1, i2;
 669       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 670     ], [
 671       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 672       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 673         [Define this if gethostbyname_r takes 5 arguments])
 674       AC_MSG_RESULT(5)
 675    ], [
 676       AC_TRY_COMPILE([
 677 #include <netdb.h>
 678      ], [
 679        char *cp1;
 680        struct hostent *h1;
 681        struct hostent_data hd;
 682        (void) gethostbyname_r(cp1,h1,&hd);
 683      ], [
 684        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 685        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 686          [Define this if gethostbyname_r takes 3 arguments])
 687        AC_MSG_RESULT(3)
 688      ], [
 689        AC_MSG_RESULT(0)
 690      ])
 691   ])
 692  ])
 693  CFLAGS=$OLD_CFLAGS
 694 ])
 695
 696 AC_CACHE_CHECK([whether the C compiler supports __func__],
 697   tor_cv_have_func_macro,
 698   AC_COMPILE_IFELSE([
 699 #include <stdio.h>
 700 int main(int c, char **v) { puts(__func__); }],
 701   tor_cv_have_func_macro=yes,
 702   tor_cv_have_func_macro=no))
 703
 704 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 705   tor_cv_have_FUNC_macro,
 706   AC_COMPILE_IFELSE([
 707 #include <stdio.h>
 708 int main(int c, char **v) { puts(__FUNC__); }],
 709   tor_cv_have_FUNC_macro=yes,
 710   tor_cv_have_FUNC_macro=no))
 711
 712 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 713   tor_cv_have_FUNCTION_macro,
 714   AC_COMPILE_IFELSE([
 715 #include <stdio.h>
 716 int main(int c, char **v) { puts(__FUNCTION__); }],
 717   tor_cv_have_FUNCTION_macro=yes,
 718   tor_cv_have_FUNCTION_macro=no))
 719
 720 if test "$tor_cv_have_func_macro" = 'yes'; then
 721   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 722 fi
 723
 724 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 725   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 726 fi
 727
 728 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 729   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 730            [Defined if the compiler supports __FUNCTION__])
 731 fi
 732
 733 # $prefix stores the value of the --prefix command line option, or
 734 # NONE if the option wasn't set.  In the case that it wasn't set, make
 735 # it be the default, so that we can use it to expand directories now.
 736 if test "x$prefix" = "xNONE"; then
 737   prefix=$ac_default_prefix
 738 fi
 739
 740 # and similarly for $exec_prefix
 741 if test "x$exec_prefix" = "xNONE"; then
 742   exec_prefix=$prefix
 743 fi
 744
 745 if test "x$CONFDIR" = "x"; then
 746   CONFDIR=`eval echo $sysconfdir/tor`
 747 fi
 748 AC_SUBST(CONFDIR)
 749 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 750 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 751
 752 BINDIR=`eval echo $bindir`
 753 AC_SUBST(BINDIR)
 754 LOCALSTATEDIR=`eval echo $localstatedir`
 755 AC_SUBST(LOCALSTATEDIR)
 756
 757 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 758 # than autoconf's macros like.
 759 if test "$GCC" = yes; then
 760   CFLAGS="$CFLAGS -Wall -g -O2"
 761   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 762   # accident waiting to happen.
 763   CFLAGS="$CFLAGS -fno-strict-aliasing"
 764 else
 765   CFLAGS="$CFLAGS -g -O"
 766   enable_gcc_warnings=no
 767 fi
 768
 769 # Add some more warnings which we use in development but not in the
 770 # released versions.  (Some relevant gcc versions can't handle these.)
 771 if test x$enable_gcc_warnings = xyes; then
 772
 773   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 774 #if !defined(__GNUC__) || (__GNUC__ < 4)
 775 #error
 776 #endif]), have_gcc4=yes, have_gcc4=no)
 777
 778   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 779 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 780 #error
 781 #endif]), have_gcc42=yes, have_gcc42=no)
 782
 783   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 784 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 785 #error
 786 #endif]), have_gcc43=yes, have_gcc43=no)
 787
 788   save_CFLAGS="$CFLAGS"
 789   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 790   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 791                     have_shorten64_flag=no)
 792   CFLAGS="$save_CFLAGS"
 793
 794   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 795
 796   # Disabled, so we can use mallinfo(): -Waggregate-return
 797
 798   if test x$have_gcc4 = xyes ; then
 799     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 800     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 801   fi
 802
 803   if test x$have_gcc42 = xyes ; then
 804     # These warnings break gcc 4.0.2 and work on gcc 4.2
 805     # XXXX020 Use -fstack-protector.
 806     # XXXX020 See if any of these work with earlier versions.
 807     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 808     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 809   fi
 810
 811   if test x$have_gcc43 = xyes ; then
 812     # These warnings break gcc 4.2 and work on gcc 4.3
 813     # XXXX020 See if any of these work with earlier versions.
 814     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 815   fi
 816
 817   if test x$have_shorten64_flag = xyes ; then
 818     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 819   fi
 820
 821 ##This will break the world on some 64-bit architectures
 822 # CFLAGS="$CFLAGS -Winline"
 823 fi
 824
 825
 826
 827 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 828
 829 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 830 AC_OUTPUT
 831
 832 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 833   ./contrib/updateVersions.pl
 834 fi
 835