configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.1.2.7-alpha)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release; then
  13     CFLAGS="$CFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 AC_ARG_ENABLE(debug,
  17  AC_HELP_STRING(--enable-debug, compile with debugging info),
  18 [if test x$enableval = xyes; then
  19     CFLAGS="$CFLAGS -g"
  20 fi])
  21
  22 AC_ARG_ENABLE(eventdns,
  23      AC_HELP_STRING(--enable-eventdns, enable asynchronous dns module),
  24      [case "${enableval}" in
  25         yes) eventdns=true ;;
  26         no)  eventdns=false ;;
  27         *) AC_MSG_ERROR(bad value for --enable-eventdns) ;;
  28       esac], [eventdns=true])
  29 AM_CONDITIONAL(EVENTDNS, test x$eventdns = xtrue)
  30 if test x$eventdns = xtrue; then
  31    AC_DEFINE([USE_EVENTDNS], 1, "Define to 1 if we'll be using eventdns.c")
  32 fi
  33
  34 AC_ARG_ENABLE(transparent,
  35      AC_HELP_STRING(--disable-transparent, disable transparent proxy support),
  36      [case "${enableval}" in
  37         yes) transparent=true ;;
  38         no)  transparent=false ;;
  39         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  40       esac], [transparent=true])
  41
  42 AC_ARG_ENABLE(threads,
  43      AC_HELP_STRING(--disable-threads, disable multi-threading support))
  44
  45 if test x$enable_threads = x; then
  46    case $host in
  47     *-*-netbsd* | *-*-openbsd* )
  48      # Don't try multithreading on netbsd -- there is no threadsafe DNS
  49      # lookup function there.
  50      if test x$eventdns != xtrue; then
  51         AC_MSG_NOTICE([You are running OpenBSD or NetBSD; I am assuming that
  52 getaddrinfo is not threadsafe here, so I will disable threads.])
  53         enable_threads="no"
  54     fi ;;
  55     *-*-solaris* )
  56      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  57      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  58 cpu workers lock up here, so I will disable threads.])
  59      enable_threads="no";;
  60     *)
  61      enable_threads="yes";;
  62    esac
  63 fi
  64
  65 if test $enable_threads = "yes"; then
  66   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  67 fi
  68
  69 case $host in
  70    *-*-solaris* )
  71      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  72      ;;
  73 esac
  74
  75 AC_ARG_ENABLE(gcc-warnings,
  76      AC_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  77
  78 AC_PROG_CC
  79 AC_PROG_MAKE_SET
  80 AC_PROG_RANLIB
  81
  82 # The big search for OpenSSL
  83 # copied from openssh's configure.ac
  84 tryssldir=""
  85 AC_ARG_WITH(ssl-dir,
  86         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
  87         [
  88                 if test "x$withval" != "xno" ; then
  89                         tryssldir=$withval
  90                 fi
  91         ]
  92 )
  93
  94 trylibeventdir=""
  95 AC_ARG_WITH(libevent-dir,
  96        [  --with-libevent-dir=PATH     Specify path to Libevent installation ],
  97        [
  98                 if test "x$withval" != "xno" ; then
  99                         trylibeventdir=$withval
 100                 fi
 101        ]
 102 )
 103
 104 TORUSER=_tor
 105 AC_ARG_WITH(tor-user,
 106         [  --with-tor-user=NAME    Specify username for tor daemon ],
 107         [
 108            TORUSER=$withval
 109         ]
 110 )
 111 AC_SUBST(TORUSER)
 112
 113 TORGROUP=_tor
 114 AC_ARG_WITH(tor-group,
 115         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 116         [
 117            TORGROUP=$withval
 118         ]
 119 )
 120 AC_SUBST(TORGROUP)
 121
 122
 123 dnl If WIN32 is defined and non-zero, we are building for win32
 124 AC_MSG_CHECKING([for win32])
 125 AC_RUN_IFELSE([
 126 int main(int c, char **v) {
 127 #ifdef WIN32
 128 #if WIN32
 129   return 0;
 130 #else
 131   return 1;
 132 #endif
 133 #else
 134   return 2;
 135 #endif
 136 }],
 137 bwin32=true; AC_MSG_RESULT([yes]),
 138 bwin32=false; AC_MSG_RESULT([no]),
 139 bwin32=cross; AC_MSG_RESULT([cross])
 140 )
 141
 142 if test $bwin32 = cross; then
 143 AC_MSG_CHECKING([for win32 (cross)])
 144 AC_COMPILE_IFELSE([
 145 #ifdef WIN32
 146 int main(int c, char **v) {return 0;}
 147 #else
 148 #error
 149 int main(int c, char **v) {return x(y);}
 150 #endif
 151 ],
 152 bwin32=true; AC_MSG_RESULT([yes]),
 153 bwin32=false; AC_MSG_RESULT([no]))
 154 fi
 155
 156 if test $bwin32 = true; then
 157 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 158 fi
 159
 160 dnl Enable C99 when compiling with MIPSpro
 161 AC_MSG_CHECKING([for MIPSpro compiler])
 162 AC_TRY_COMPILE([], [
 163 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 164 #error
 165   return x(y);
 166 #endif
 167 ],
 168 bmipspro=false; AC_MSG_RESULT([no]),
 169 bmipspro=true; AC_MSG_RESULT([yes]))
 170
 171 if test $bmipspro = true; then
 172   CFLAGS="$CFLAGS -c99"
 173 fi
 174
 175 AC_SEARCH_LIBS(socket, [socket])
 176 AC_SEARCH_LIBS(gethostbyname, [nsl])
 177 AC_SEARCH_LIBS(dlopen, [dl])
 178 AC_SEARCH_LIBS(inet_aton, [resolv])
 179
 180 if test $enable_threads = "yes"; then
 181   AC_SEARCH_LIBS(pthread_create, [pthread])
 182   AC_SEARCH_LIBS(pthread_detach, [pthread])
 183 fi
 184
 185 dnl -------------------------------------------------------------------
 186 dnl Check for functions before libevent, since libevent-1.2 apparently
 187 dnl exports strlcpy without defining it in a header.
 188
 189 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r)
 190
 191 if test $enable_threads = "yes"; then
 192   AC_CHECK_HEADERS(pthread.h)
 193   AC_CHECK_FUNCS(pthread_create)
 194 fi
 195
 196 dnl ------------------------------------------------------
 197 dnl Where do you live, libevent?  And how do we call you?
 198
 199 AC_CACHE_CHECK([for libevent directory], tor_cv_libevent_dir, [
 200   saved_LIBS="$LIBS"
 201   saved_LDFLAGS="$LDFLAGS"
 202   saved_CPPFLAGS="$CPPFLAGS"
 203   le_found=no
 204   for ledir in $trylibeventdir "" $prefix /usr/local /usr/pkg ; do
 205     LDFLAGS="$saved_LDFLAGS"
 206
 207     if test $bwin32 = true; then
 208         LIBS="$saved_LIBS -levent -lws2_32"
 209     else
 210         LIBS="$saved_LIBS -levent"
 211     fi
 212
 213     # Skip the directory if it isn't there.
 214     if test ! -z "$ledir" -a ! -d "$ledir" ; then
 215        continue;
 216     fi
 217     if test ! -z "$ledir" ; then
 218       if test -d "$ledir/lib" ; then
 219         LDFLAGS="-L$ledir/lib $LDFLAGS"
 220       else
 221         LDFLAGS="-L$ledir $LDFLAGS"
 222       fi
 223       if test -d "$ledir/include" ; then
 224         CPPFLAGS="-I$ledir/include $CPPFLAGS"
 225       else
 226         CPPFLAGS="-I$ledir $CPPFLAGS"
 227       fi
 228     fi
 229     # Can I compile and link it?
 230     AC_TRY_LINK([#include <sys/time.h>
 231 #include <sys/types.h>
 232 #include <event.h>], [ event_init(); ],
 233        [ libevent_linked=yes ], [ libevent_linked=no ])
 234     if test $libevent_linked = yes; then
 235        if test ! -z "$ledir" ; then
 236          tor_cv_libevent_dir=$ledir
 237        else
 238          tor_cv_libevent_dir="(system)"
 239        fi
 240        le_found=yes
 241        break
 242     fi
 243   done
 244   LIBS="$saved_LIBS"
 245   LDFLAGS="$saved_LDFLAGS"
 246   CPPFLAGS="$saved_CPPFLAGS"
 247   if test $le_found = no ; then
 248     AC_MSG_ERROR([Could not find a linkable libevent. You can specify an explicit path using --with-libevent-dir])
 249   fi
 250 ])
 251
 252 if test $bwin32 = true; then
 253 LIBS="$LIBS -levent -lws2_32"
 254 else
 255 LIBS="$LIBS -levent"
 256 fi
 257 if test $tor_cv_libevent_dir != "(system)"; then
 258   if test -d "$tor_cv_libevent_dir/lib" ; then
 259     LDFLAGS="-L$tor_cv_libevent_dir/lib $LDFLAGS"
 260     le_libdir="$tor_cv_libevent_dir/lib"
 261   else
 262     LDFLAGS="-L$tor_cv_libevent_dir $LDFLAGS"
 263     le_libdir="$tor_cv_libevent_dir"
 264   fi
 265   if test -d "$tor_cv_libevent_dir/include" ; then
 266     CPPFLAGS="-I$tor_cv_libevent_dir/include $CPPFLAGS"
 267   else
 268     CPPFLAGS="-I$tor_cv_libevent_dir $CPPFLAGS"
 269   fi
 270 fi
 271
 272 if test -z "$CROSS_COMPILE"; then
 273 AC_CACHE_CHECK([whether we need extra options to link libevent],
 274                tor_cv_libevent_linker_option, [
 275     saved_LDFLAGS="$LDFLAGS"
 276     le_runs=no
 277     linked_with=nothing
 278     for le_extra in "" "-Wl,-R$le_libdir" "-R$le_libdir" "-Wl,-rpath,$le_libdir" ; do
 279       LDFLAGS="$le_extra $saved_LDFLAGS"
 280       AC_TRY_RUN([void *event_init(void);
 281                 int main(int c, char **v) {
 282                    event_init(); return 0;
 283                 }],
 284                 libevent_runs=yes, libevent_runs=no, libevent_runs=cross)
 285       if test $libevent_runs != no ; then
 286         if test -z "$le_extra" ; then
 287           tor_cv_libevent_linker_option='(none)'
 288         else
 289           tor_cv_libevent_linker_option=$le_extra
 290         fi
 291         le_runs=yes
 292         break
 293       fi
 294     done
 295     if test $le_runs = no ; then
 296       AC_MSG_ERROR([Found linkable libevent in $tor_cv_libevent_dir, but it doesn't run, even with -R.  Maybe specify another using --with-libevent-dir?])
 297     fi
 298     LDFLAGS="$saved_LDFLAGS"
 299 ])
 300
 301 if test $tor_cv_libevent_linker_option != '(none)' ; then
 302    LDFLAGS="$tor_cv_libevent_linker_option $LDFLAGS"
 303 fi
 304 fi
 305
 306 dnl Now check for particular libevent functions.
 307 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 308
 309 dnl ------------------------------------------------------
 310 dnl Where do you live, openssl?  And how do we call you?
 311
 312 AC_CACHE_CHECK([for OpenSSL directory], tor_cv_openssl_dir, [
 313   saved_LIBS="$LIBS"
 314   saved_LDFLAGS="$LDFLAGS"
 315   saved_CPPFLAGS="$CPPFLAGS"
 316   ssl_found=no
 317   for ssldir in $tryssldir "" $prefix /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /usr/pkg /opt /opt/openssl ; do
 318     LDFLAGS="$saved_LDFLAGS"
 319
 320     if test $bwin32 = true; then
 321       LIBS="$saved_LIBS -lssl -lcrypto -lws2_32 -lgdi32"
 322     else
 323       LIBS="$saved_LIBS -lssl -lcrypto"
 324     fi
 325
 326     # Skip the directory if it isn't there.
 327     if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 328        continue;
 329     fi
 330     if test ! -z "$ssldir" ; then
 331       if test -d "$ssldir/lib" ; then
 332         LDFLAGS="-L$ssldir/lib $LDFLAGS"
 333       else
 334         LDFLAGS="-L$ssldir $LDFLAGS"
 335       fi
 336       if test -d "$ssldir/include" ; then
 337         CPPFLAGS="-I$ssldir/include $CPPFLAGS"
 338       else
 339         CPPFLAGS="-I$ssldir $CPPFLAGS"
 340       fi
 341     fi
 342     # Can I link it?
 343     AC_TRY_LINK([#include <openssl/rand.h>],
 344        [ RAND_add((void*)0,0,0); ],
 345        [ openssl_linked=yes ], [ openssl_linked=no ])
 346     if test $openssl_linked = yes; then
 347        if test ! -z "$ssldir" ; then
 348          tor_cv_openssl_dir=$ssldir
 349        else
 350          tor_cv_openssl_dir="(system)"
 351        fi
 352        ssl_found=yes
 353        break
 354     fi
 355   done
 356   LIBS="$saved_LIBS"
 357   LDFLAGS="$saved_LDFLAGS"
 358   CPPFLAGS="$saved_CPPFLAGS"
 359   if test $ssl_found = no ; then
 360     AC_MSG_ERROR([Could not find a linkable OpenSSL. You can specify an explicit path using --with-ssl-dir])
 361   fi
 362 ])
 363
 364 if test $bwin32 = true; then
 365 LIBS="$LIBS -lssl -lcrypto -lws2_32 -lgdi32"
 366 else
 367 LIBS="$LIBS -lssl -lcrypto"
 368 fi
 369
 370 if test "$tor_cv_openssl_dir" != "(system)"; then
 371   if test -d "$tor_cv_openssl_dir/lib" ; then
 372     LDFLAGS="-L$tor_cv_openssl_dir/lib $LDFLAGS"
 373     ssl_libdir="$tor_cv_openssl_dir/lib"
 374   else
 375     LDFLAGS="-L$tor_cv_openssl_dir $LDFLAGS"
 376     ssl_libdir="$tor_cv_openssl_dir"
 377   fi
 378   if test -d "$tor_cv_openssl_dir/include" ; then
 379     CPPFLAGS="-I$tor_cv_openssl_dir/include $CPPFLAGS"
 380   else
 381     CPPFLAGS="-I$tor_cv_openssl_dir $CPPFLAGS"
 382   fi
 383 fi
 384
 385 if test -z "$CROSS_COMPILE"
 386 then
 387 AC_CACHE_CHECK([whether we need extra options to link OpenSSL],
 388                tor_cv_openssl_linker_option, [
 389     saved_LDFLAGS="$LDFLAGS"
 390     ssl_runs=no
 391     linked_with=nothing
 392     for ssl_extra in "" "-Wl,-R$ssl_libdir" "-R$ssl_libdir" ; do
 393       LDFLAGS="$ssl_extra $saved_LDFLAGS"
 394       AC_TRY_RUN([
 395 #include <string.h>
 396 #include <openssl/rand.h>
 397 int main(void)
 398 {
 399         char a[2048];
 400         memset(a, 0, sizeof(a));
 401         RAND_add(a, sizeof(a), sizeof(a));
 402         return(RAND_status() <= 0);
 403 }
 404                         ],
 405                 openssl_runs=yes, openssl_runs=no, openssl_runs=cross)
 406       if test $openssl_runs != no ; then
 407         if test "$linked_with" = nothing; then
 408            linked_with="$ssl_extra"
 409         fi
 410         AC_TRY_RUN([
 411 #include <openssl/opensslv.h>
 412 #include <openssl/crypto.h>
 413 int main(void) {
 414 return (OPENSSL_VERSION_NUMBER == SSLeay()) == 0;
 415 }],
 416         right_version=yes, right_version=no)
 417         if test "$right_version" = yes; then
 418           if test -z "$ssl_extra" ; then
 419             tor_cv_openssl_linker_option='(none)'
 420           else
 421             tor_cv_openssl_linker_option=$ssl_extra
 422           fi
 423           ssl_runs=yes
 424           break
 425         fi
 426      fi
 427     done
 428     if test $ssl_runs = no ; then
 429       if test "$linked_with" = 'nothing' ; then
 430         AC_MSG_ERROR([Found linkable OpenSSL in $tor_cv_openssl_dir, but it doesn't run, even with -R.  Maybe specify another using --with-ssl-dir?])
 431       else
 432         if test -z "$linked_with" ; then
 433             tor_cv_openssl_linker_option='(none)'
 434         else
 435             tor_cv_openssl_linker_option=$linked_with
 436         fi
 437         AC_MSG_WARN([I managed to make OpenSSL link and run, but I couldn't make it link against the same version I found header files for.])
 438       fi
 439     fi
 440     LDFLAGS="$saved_LDFLAGS"
 441 ])
 442
 443 if test "$tor_cv_openssl_linker_option" != '(none)' ; then
 444    LDFLAGS="$tor_cv_openssl_linker_option $LDFLAGS"
 445 fi
 446 fi
 447
 448 dnl Make sure to enable support for large off_t if avalable.
 449
 450 AC_SYS_LARGEFILE
 451
 452 dnl The warning message here is no longer strictly accurate.
 453
 454 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(some headers were not found, compilation may fail))
 455
 456 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h)
 457
 458 AC_CHECK_HEADERS(event.h, , AC_MSG_ERROR(Libevent header (event.h) not found. Tor requires libevent to build.),
 459 [#ifdef HAVE_SYS_TYPES_H
 460 #include <sys/types.h>
 461 #endif
 462 #ifdef HAVE_SYS_TIME_H
 463 #include <sys/time.h>
 464 #else
 465   struct timeval {
 466     long tv_sec;
 467     long tv_usec;
 468  };
 469 #endif])
 470
 471 AC_CHECK_HEADERS(zlib.h, , AC_MSG_ERROR(Zlib header (zlib.h) not found. Tor requires zlib to build. You may need to install a zlib development package.))
 472
 473 dnl These headers are not essential
 474
 475 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h)
 476
 477 AC_CHECK_HEADERS(net/if.h, [net_if_found=1], [net_if_found=0],
 478 [#ifdef HAVE_SYS_TYPES_H
 479 #include <sys/types.h>
 480 #endif
 481 #ifdef HAVE_SYS_SOCKET_H
 482 #include <sys/socket.h>
 483 #endif])
 484 AC_CHECK_HEADERS(net/pfvar.h, [net_pfvar_found=1], [net_pfvar_found=0],
 485 [#ifdef HAVE_SYS_TYPES_H
 486 #include <sys/types.h>
 487 #endif
 488 #ifdef HAVE_SYS_SOCKET_H
 489 #include <sys/socket.h>
 490 #endif
 491 #ifdef HAVE_NET_IF_H
 492 #include <net/if.h>
 493 #endif])
 494 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 495         [linux_netfilter_ipv4=1], [linux_netfilter_ipv4=0],
 496 [#ifdef HAVE_SYS_TYPES_H
 497 #include <sys/types.h>
 498 #endif
 499 #ifdef HAVE_SYS_SOCKET_H
 500 #include <sys/socket.h>
 501 #endif])
 502
 503 if test x$transparent = xtrue ; then
 504    transparent_ok=0
 505    if test x$net_if_found = x1 -a x$net_pfvar_found = x1 ; then
 506      transparent_ok=1
 507    fi
 508    if test x$linux_netfilter_ipv4 = x1 ; then
 509      transparent_ok=1
 510    fi
 511    if test x$transparent_ok = x1 ; then
 512      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 513      case $host in
 514        *-*-openbsd*)
 515          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 516      esac
 517    else
 518      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 519    fi
 520 fi
 521
 522 AC_FUNC_FSEEKO
 523
 524 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 525 [#ifdef HAVE_SYS_TYPES_H
 526 #include <sys/types.h>
 527 #endif
 528 #ifdef HAVE_SYS_TIME_H
 529 #include <sys/time.h>
 530 #endif])
 531
 532 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 533 dnl Watch out.
 534
 535 AC_CHECK_SIZEOF(int8_t)
 536 AC_CHECK_SIZEOF(int16_t)
 537 AC_CHECK_SIZEOF(int32_t)
 538 AC_CHECK_SIZEOF(int64_t)
 539 AC_CHECK_SIZEOF(uint8_t)
 540 AC_CHECK_SIZEOF(uint16_t)
 541 AC_CHECK_SIZEOF(uint32_t)
 542 AC_CHECK_SIZEOF(uint64_t)
 543 AC_CHECK_SIZEOF(intptr_t)
 544 AC_CHECK_SIZEOF(uintptr_t)
 545
 546 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 547
 548 AC_CHECK_SIZEOF(char)
 549 AC_CHECK_SIZEOF(short)
 550 AC_CHECK_SIZEOF(int)
 551 AC_CHECK_SIZEOF(long)
 552 AC_CHECK_SIZEOF(long long)
 553 AC_CHECK_SIZEOF(__int64)
 554 AC_CHECK_SIZEOF(void *)
 555 AC_CHECK_SIZEOF(time_t)
 556 AC_CHECK_SIZEOF(size_t)
 557
 558 AC_CHECK_TYPES([uint, u_char])
 559
 560 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_storage], , ,
 561 [#ifdef HAVE_SYS_TYPES_H
 562 #include <sys/types.h>
 563 #endif
 564 #ifdef HAVE_NETINET_IN_H
 565 #include <netinet/in.h>
 566 #endif
 567 #ifdef HAVE_NETINET_IN6_H
 568 #include <netinet/in6.h>
 569 #endif
 570 #ifdef HAVE_SYS_SOCKET_H
 571 #include <sys/socket.h>
 572 #endif])
 573
 574 if test -z "$CROSS_COMPILE"; then
 575 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 576 AC_TRY_RUN([
 577 #ifdef HAVE_SYS_TYPES_H
 578 #include <sys/types.h>
 579 #endif
 580 #ifdef HAVE_SYS_TIME_H
 581 #include <sys/time.h>
 582 #endif
 583 #ifdef HAVE_TIME_H
 584 #include <time.h>
 585 #endif
 586 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }],
 587   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes)
 588 ])
 589 else
 590   # Cross-compiling; let's hope the target platform isn't loony.
 591   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 592   tor_cv_time_t_signed=yes
 593 fi
 594
 595 if test $tor_cv_time_t_signed = yes; then
 596   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 597             [Define to 1 iff time_t is signed])
 598 fi
 599
 600 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 601 #ifdef HAVE_SYS_SOCKET_H
 602 #include <sys/socket.h>
 603 #endif
 604 ])
 605
 606 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 607
 608 AC_CHECK_SIZEOF(cell_t)
 609
 610 # Now make sure that NULL can be represented as zero bytes.
 611 if test -z "$CROSS_COMPILE"; then
 612 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 613 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 614 [[#include <stdlib.h>
 615 #include <string.h>
 616 #include <stdio.h>
 617 #ifdef HAVE_STDDEF_H
 618 #include <stddef.h>
 619 #endif
 620 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 621 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 622        [tor_cv_null_is_zero=yes],
 623        [tor_cv_null_is_zero=no],
 624        [tor_cv_null_is_zero=cross])])
 625
 626 else
 627   # Cross-compiling; let's hope that the target isn't raving mad.
 628   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 629   tor_cv_null_is_zero=yes
 630 fi
 631
 632 if test $tor_cv_null_is_zero = yes; then
 633   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 634             [Define to 1 iff memset(0) sets pointers to NULL])
 635 fi
 636
 637 # And what happens when we malloc zero?
 638
 639 if test -z "$CROSS_COMPILE"; then
 640 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 641 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 642 [[#include <stdlib.h>
 643 #include <string.h>
 644 #include <stdio.h>
 645 #ifdef HAVE_STDDEF_H
 646 #include <stddef.h>
 647 #endif
 648 int main () { return malloc(0)?0:1; }]])],
 649        [tor_cv_malloc_zero_works=yes],
 650        [tor_cv_malloc_zero_works=no],
 651        [tor_cv_malloc_zero_works=cross])])
 652
 653 else
 654   # Cross-compiling; let's hope that the target isn't raving mad.
 655   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 656   tor_cv_malloc_zero_works=no
 657 fi
 658
 659 if test $tor_cv_malloc_zero_works = yes; then
 660   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 661             [Define to 1 iff malloc(0) returns a pointer])
 662 fi
 663
 664 # whether we seem to be in a 2s-complement world.
 665 if test -z "$CROSS_COMPILE"; then
 666 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 667 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 668 [[int main () { int problem = ((-99) != (~99)+1);
 669 return problem ? 1 : 0; }]])],
 670        [tor_cv_twos_complement=yes],
 671        [tor_cv_twos_complement=no],
 672        [tor_cv_twos_complement=cross])])
 673
 674 else
 675   # Cross-compiling; let's hope that the target isn't raving mad.
 676   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 677   tor_cv_twos_complement=yes
 678 fi
 679
 680 if test $tor_cv_twos_complement = yes; then
 681   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 682             [Define to 1 iff we represent negative integers with two's complement])
 683 fi
 684
 685 # Whether we should use the dmalloc memory allocation debugging library.
 686 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 687 AC_ARG_WITH(dmalloc,
 688 [  --with-dmalloc          Use debug memory allocation library. ],
 689 [if [[ "$withval" = "yes" ]]; then
 690   dmalloc=1
 691   AC_MSG_RESULT(yes)
 692 else
 693   dmalloc=1
 694   AC_MSG_RESULT(no)
 695 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 696 )
 697
 698 if [[ $dmalloc -eq 1 ]]; then
 699   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 700   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 701   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 702   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 703 fi
 704
 705 # Allow user to specify an alternate syslog facility
 706 AC_ARG_WITH(syslog-facility,
 707 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 708 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 709 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 710 AC_SUBST(LOGFACILITY)
 711
 712 # Check for gethostbyname_r in all its glorious incompatible versions.
 713 #   (This logic is based on that in Python's configure.in)
 714 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 715   [Define this if you have any gethostbyname_r()])
 716
 717 AC_CHECK_FUNC(gethostbyname_r, [
 718   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 719   OLD_CFLAGS=$CFLAGS
 720   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 721   AC_TRY_COMPILE([
 722 #include <netdb.h>
 723   ], [
 724     char *cp1, *cp2;
 725     struct hostent *h1, *h2;
 726     int i1, i2;
 727     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 728   ], [
 729     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 730     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 731      [Define this if gethostbyname_r takes 6 arguments])
 732     AC_MSG_RESULT(6)
 733   ], [
 734     AC_TRY_COMPILE([
 735 #include <netdb.h>
 736     ], [
 737       char *cp1, *cp2;
 738       struct hostent *h1;
 739       int i1, i2;
 740       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 741     ], [
 742       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 743       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 744         [Define this if gethostbyname_r takes 5 arguments])
 745       AC_MSG_RESULT(5)
 746    ], [
 747       AC_TRY_COMPILE([
 748 #include <netdb.h>
 749      ], [
 750        char *cp1;
 751        struct hostent *h1;
 752        struct hostent_data hd;
 753        (void) gethostbyname_r(cp1,h1,&hd);
 754      ], [
 755        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 756        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 757          [Define this if gethostbyname_r takes 3 arguments])
 758        AC_MSG_RESULT(3)
 759      ], [
 760        AC_MSG_RESULT(0)
 761      ])
 762   ])
 763  ])
 764  CFLAGS=$OLD_CFLAGS
 765 ])
 766
 767 AC_CACHE_CHECK([whether the C compiler supports __func__],
 768   tor_cv_have_func_macro,
 769   AC_COMPILE_IFELSE([
 770 #include <stdio.h>
 771 int main(int c, char **v) { puts(__func__); }],
 772   tor_cv_have_func_macro=yes,
 773   tor_cv_have_func_macro=no))
 774
 775 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 776   tor_cv_have_FUNC_macro,
 777   AC_COMPILE_IFELSE([
 778 #include <stdio.h>
 779 int main(int c, char **v) { puts(__FUNC__); }],
 780   tor_cv_have_FUNC_macro=yes,
 781   tor_cv_have_FUNC_macro=no))
 782
 783 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 784   tor_cv_have_FUNCTION_macro,
 785   AC_COMPILE_IFELSE([
 786 #include <stdio.h>
 787 int main(int c, char **v) { puts(__FUNCTION__); }],
 788   tor_cv_have_FUNCTION_macro=yes,
 789   tor_cv_have_FUNCTION_macro=no))
 790
 791 if test $tor_cv_have_func_macro = 'yes'; then
 792   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 793 fi
 794
 795 if test $tor_cv_have_FUNC_macro = 'yes'; then
 796   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 797 fi
 798
 799 if test $tor_cv_have_FUNCTION_macro = 'yes'; then
 800   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 801            [Defined if the compiler supports __FUNCTION__])
 802 fi
 803
 804 # $prefix stores the value of the --prefix command line option, or
 805 # NONE if the option wasn't set.  In the case that it wasn't set, make
 806 # it be the default, so that we can use it to expand directories now.
 807 if test "x$prefix" = "xNONE"; then
 808   prefix=$ac_default_prefix
 809 fi
 810
 811 # and similarly for $exec_prefix
 812 if test "x$exec_prefix" = "xNONE"; then
 813   exec_prefix=$prefix
 814 fi
 815
 816 if test "x$CONFDIR" = "x"; then
 817   CONFDIR=`eval echo $sysconfdir/tor`
 818 fi
 819 AC_SUBST(CONFDIR)
 820 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 821 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 822
 823 BINDIR=`eval echo $bindir`
 824 AC_SUBST(BINDIR)
 825
 826 LOCALSTATEDIR=`eval echo $localstatedir`
 827 AC_SUBST(LOCALSTATEDIR)
 828 AH_TEMPLATE([LOCALSTATEDIR], [Default location to store state files.])
 829 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 830
 831 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 832 # than autoconf's macros like.
 833 if test $ac_cv_c_compiler_gnu = yes; then
 834   CFLAGS="$CFLAGS -Wall -g -O2"
 835 else
 836   CFLAGS="$CFLAGS -g -O"
 837   enable_gcc_warnings=no
 838 fi
 839
 840 # Add some more warnings which we use in the cvs version but not in the
 841 # released versions.  (Some relevant gcc versions can't handle these.)
 842 if test x$enable_gcc_warnings = xyes; then
 843
 844   AC_TRY_COMPILE([], [
 845 #if !defined(__GNUC__) || (__GNUC__ < 4)
 846 #error
 847 #endif], have_gcc4=yes, have_gcc4=no)
 848
 849   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Waggregate-return -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 850
 851   if test x$have_gcc4 = xyes ; then
 852     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 853     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 854   fi
 855
 856 ##This will break the world on some 64-bit architectures
 857 # CFLAGS="$CFLAGS -Winline"
 858
 859 fi
 860
 861 AC_OUTPUT(Makefile tor.spec contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh)
 862
 863 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 864   ./contrib/updateVersions.pl
 865 fi
 866