configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2017, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.3.3-alpha-dev])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56 AC_ARG_ENABLE(memory-sentinels,
  57    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  58 AC_ARG_ENABLE(rust,
  59    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  60 AC_ARG_ENABLE(cargo-online-mode,
  61    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  62 AC_ARG_ENABLE(restart-debugging,
  63    AS_HELP_STRING(--enable-restart-debugging, [Build Tor with support for debugging in-process restart. Developers only.]))
  64
  65 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  66     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  67 fi
  68
  69 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  70 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  71 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  72 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  73 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  74 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  75
  76 if test "$enable_static_tor" = "yes"; then
  77   enable_static_libevent="yes";
  78   enable_static_openssl="yes";
  79   enable_static_zlib="yes";
  80   CFLAGS="$CFLAGS -static"
  81 fi
  82
  83 if test "$enable_system_torrc" = "no"; then
  84   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  85             [Defined if we're not going to look for a torrc in SYSCONF])
  86 fi
  87
  88 if test "$enable_memory_sentinels" = "no"; then
  89   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  90            [Defined if we're turning off memory safety code to look for bugs])
  91 fi
  92
  93 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  94
  95 AC_ARG_ENABLE(asciidoc,
  96      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  97      [case "${enableval}" in
  98         "yes") asciidoc=true ;;
  99         "no")  asciidoc=false ;;
 100         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
 101       esac], [asciidoc=true])
 102
 103 # systemd notify support
 104 AC_ARG_ENABLE(systemd,
 105       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 106       [case "${enableval}" in
 107         "yes") systemd=true ;;
 108         "no")  systemd=false ;;
 109         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 110       esac], [systemd=auto])
 111
 112 if test "$enable_restart_debugging" = "yes"; then
 113   AC_DEFINE(ENABLE_RESTART_DEBUGGING, 1,
 114             [Defined if we're building with support for in-process restart debugging.])
 115 fi
 116
 117
 118 # systemd support
 119 if test "x$enable_systemd" = "xno"; then
 120     have_systemd=no;
 121 else
 122     PKG_CHECK_MODULES(SYSTEMD,
 123         [libsystemd-daemon],
 124         have_systemd=yes,
 125         have_systemd=no)
 126     if test "x$have_systemd" = "xno"; then
 127         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 128         PKG_CHECK_MODULES(SYSTEMD,
 129             [libsystemd],
 130             have_systemd=yes,
 131             have_systemd=no)
 132     fi
 133 fi
 134
 135 if test "x$have_systemd" = "xyes"; then
 136     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 137     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 138     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 139     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 140          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 141 fi
 142 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 143 AC_SUBST(TOR_SYSTEMD_LIBS)
 144
 145 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 146     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 147 fi
 148
 149 case "$host" in
 150    *-*-solaris* )
 151      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 152      ;;
 153 esac
 154
 155 AC_ARG_ENABLE(gcc-warnings,
 156      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 157 AC_ARG_ENABLE(fatal-warnings,
 158      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 159 AC_ARG_ENABLE(gcc-warnings-advisory,
 160      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 161
 162 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 163 AC_ARG_ENABLE(gcc-hardening,
 164     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 165
 166 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 167 AC_ARG_ENABLE(expensive-hardening,
 168     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 169 AC_ARG_ENABLE(fragile-hardening,
 170     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 171 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 172   fragile_hardening="yes"
 173 fi
 174
 175 dnl Linker hardening options
 176 dnl Currently these options are ELF specific - you can't use this with MacOSX
 177 AC_ARG_ENABLE(linker-hardening,
 178     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 179
 180 AC_ARG_ENABLE(local-appdata,
 181    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 182 if test "$enable_local_appdata" = "yes"; then
 183   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 184             [Defined if we default to host local appdata paths on Windows])
 185 fi
 186
 187 # Tor2web mode flag
 188 AC_ARG_ENABLE(tor2web-mode,
 189      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 190 [if test "x$enableval" = "xyes"; then
 191     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 192 fi])
 193
 194 AC_ARG_ENABLE(tool-name-check,
 195      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 196
 197 AC_ARG_ENABLE(seccomp,
 198      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 199
 200 AC_ARG_ENABLE(libscrypt,
 201      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 202
 203 dnl Enable event tracing which are transformed to debug log statement.
 204 AC_ARG_ENABLE(event-tracing-debug,
 205      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 206 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 207
 208 if test x$enable_event_tracing_debug = xyes; then
 209   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 210   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 211 fi
 212
 213 dnl Enable Android only features.
 214 AC_ARG_ENABLE(android,
 215      AS_HELP_STRING(--enable-android, [build with Android features enabled]))
 216 AM_CONDITIONAL([USE_ANDROID], [test "x$enable_android" = "xyes"])
 217
 218 if test "x$enable_android" = "xyes"; then
 219   AC_DEFINE([USE_ANDROID], [1], [Compile with Android specific features enabled])
 220
 221   dnl Check if the Android log library is available.
 222   AC_CHECK_HEADERS([android/log.h])
 223   AC_SEARCH_LIBS(__android_log_write, [log])
 224
 225 fi
 226
 227 dnl check for the correct "ar" when cross-compiling.
 228 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 229 dnl    so kludge up a replacement for the case where it isn't there yet.)
 230 m4_ifdef([AM_PROG_AR],
 231          [AM_PROG_AR],
 232          [AN_MAKEVAR([AR], [AC_PROG_AR])
 233           AN_PROGRAM([ar], [AC_PROG_AR])
 234           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 235           AC_PROG_AR])
 236
 237 dnl Check whether the above macro has settled for a simply named tool even
 238 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 239 dnl because that will find any cc on the system, not only the cross-compiler,
 240 dnl and then verify that a binary built with this compiler runs on the
 241 dnl build system. It will then come to the false conclusion that we're not
 242 dnl cross-compiling.
 243 if test "x$enable_tool_name_check" != "xno"; then
 244     if test "x$ac_tool_warned" = "xyes"; then
 245         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 246         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 247                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 248         fi
 249 fi
 250
 251 AC_PROG_CC
 252 AC_PROG_CPP
 253 AC_PROG_MAKE_SET
 254 AC_PROG_RANLIB
 255 AC_PROG_SED
 256
 257 AC_ARG_VAR([PERL], [path to Perl binary])
 258 AC_CHECK_PROGS([PERL], [perl])
 259 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 260
 261 dnl check for asciidoc and a2x
 262 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 263 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 264
 265 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 266
 267 AM_PROG_CC_C_O
 268 AC_PROG_CC_C99
 269
 270 AC_ARG_VAR([PYTHON], [path to Python binary])
 271 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 272 if test "x$PYTHON" = "x"; then
 273   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 274 fi
 275 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 276
 277 dnl List all external rust crates we depend on here. Include the version
 278 rust_crates="libc-0.2.22"
 279 AC_SUBST(rust_crates)
 280
 281 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 282 AC_C_FLEXIBLE_ARRAY_MEMBER
 283 ], [
 284  dnl Maybe we've got an old autoconf...
 285  AC_CACHE_CHECK([for flexible array members],
 286      tor_cv_c_flexarray,
 287      [AC_COMPILE_IFELSE(
 288        AC_LANG_PROGRAM([
 289  struct abc { int a; char b[]; };
 290 ], [
 291  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 292  def->b[0] = 33;
 293 ]),
 294   [tor_cv_c_flexarray=yes],
 295   [tor_cv_c_flexarray=no])])
 296  if test "$tor_cv_flexarray" = "yes"; then
 297    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 298  else
 299    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 300  fi
 301 ])
 302
 303 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 304       tor_cv_c_c99_decl,
 305       [AC_COMPILE_IFELSE(
 306          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 307          [tor_cv_c_c99_decl=yes],
 308          [tor_cv_c_c99_decl=no] )])
 309 if test "$tor_cv_c_c99_decl" != "yes"; then
 310   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 311 fi
 312
 313 AC_CACHE_CHECK([for working C99 designated initializers],
 314       tor_cv_c_c99_designated_init,
 315       [AC_COMPILE_IFELSE(
 316          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 317                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 318          [tor_cv_c_c99_designated_init=yes],
 319          [tor_cv_c_c99_designated_init=no] )])
 320
 321 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 322   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 323 fi
 324
 325 TORUSER=_tor
 326 AC_ARG_WITH(tor-user,
 327         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 328         [
 329            TORUSER=$withval
 330         ]
 331 )
 332 AC_SUBST(TORUSER)
 333
 334 TORGROUP=_tor
 335 AC_ARG_WITH(tor-group,
 336         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 337         [
 338            TORGROUP=$withval
 339         ]
 340 )
 341 AC_SUBST(TORGROUP)
 342
 343
 344 dnl If _WIN32 is defined and non-zero, we are building for win32
 345 AC_MSG_CHECKING([for win32])
 346 AC_RUN_IFELSE([AC_LANG_SOURCE([
 347 int main(int c, char **v) {
 348 #ifdef _WIN32
 349 #if _WIN32
 350   return 0;
 351 #else
 352   return 1;
 353 #endif
 354 #else
 355   return 2;
 356 #endif
 357 }])],
 358 bwin32=true; AC_MSG_RESULT([yes]),
 359 bwin32=false; AC_MSG_RESULT([no]),
 360 bwin32=cross; AC_MSG_RESULT([cross])
 361 )
 362
 363 if test "$bwin32" = "cross"; then
 364 AC_MSG_CHECKING([for win32 (cross)])
 365 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 366 #ifdef _WIN32
 367 int main(int c, char **v) {return 0;}
 368 #else
 369 #error
 370 int main(int c, char **v) {return x(y);}
 371 #endif
 372 ])],
 373 bwin32=true; AC_MSG_RESULT([yes]),
 374 bwin32=false; AC_MSG_RESULT([no]))
 375 fi
 376
 377 AH_BOTTOM([
 378 #ifdef _WIN32
 379 /* Defined to access windows functions and definitions for >=WinXP */
 380 # ifndef WINVER
 381 #  define WINVER 0x0501
 382 # endif
 383
 384 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 385 # ifndef _WIN32_WINNT
 386 #  define _WIN32_WINNT 0x0501
 387 # endif
 388
 389 /* Defined to avoid including some windows headers as part of Windows.h */
 390 # ifndef WIN32_LEAN_AND_MEAN
 391 #  define WIN32_LEAN_AND_MEAN 1
 392 # endif
 393 #endif
 394 ])
 395
 396
 397 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 398 AM_CONDITIONAL(BUILD_LIBTORRUNNER, test "x$bwin32" != "xtrue")
 399
 400 dnl Enable C99 when compiling with MIPSpro
 401 AC_MSG_CHECKING([for MIPSpro compiler])
 402 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 403 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 404 #error
 405   return x(y);
 406 #endif
 407 ])],
 408 bmipspro=false; AC_MSG_RESULT(no),
 409 bmipspro=true; AC_MSG_RESULT(yes))
 410
 411 if test "$bmipspro" = "true"; then
 412   CFLAGS="$CFLAGS -c99"
 413 fi
 414
 415 AC_C_BIGENDIAN
 416
 417 if test "x$enable_rust" = "xyes"; then
 418   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 419   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 420   if test "x$RUSTC" = "xno"; then
 421     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 422   fi
 423
 424   AC_ARG_VAR([CARGO], [path to the cargo binary])
 425   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 426   if test "x$CARGO" = "xno"; then
 427     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 428   fi
 429
 430   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 431   if test "x$enable_cargo_online_mode" = "xyes"; then
 432     CARGO_ONLINE=
 433     RUST_DL=#
 434   else
 435     CARGO_ONLINE=--frozen
 436     RUST_DL=
 437
 438     dnl When we're not allowed to touch the network, we need crate dependencies
 439     dnl locally available.
 440     AC_MSG_CHECKING([rust crate dependencies])
 441     AC_ARG_VAR([TOR_RUST_DEPENDENCIES], [path to directory with local crate mirror])
 442     if test "x$TOR_RUST_DEPENDENCIES" = "x"; then
 443       TOR_RUST_DEPENDENCIES="$srcdir/src/ext/rust/"
 444       NEED_MOD=1
 445     fi
 446     if test ! -d "$TOR_RUST_DEPENDENCIES"; then
 447       AC_MSG_ERROR([Rust dependency directory $TOR_RUST_DEPENDENCIES does not exist. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 448       ERRORED=1
 449     fi
 450     for dep in $rust_crates; do
 451       if test ! -d "$TOR_RUST_DEPENDENCIES"/"$dep"; then
 452         AC_MSG_ERROR([Failure to find rust dependency $TOR_RUST_DEPENDENCIES/$dep. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 453         ERRORED=1
 454       fi
 455     done
 456     if test "x$NEED_MOD" = "x1"; then
 457       dnl When looking for dependencies from cargo, pick right directory
 458       TOR_RUST_DEPENDENCIES="../../src/ext/rust"
 459     fi
 460     if test "x$ERRORED" = "x"; then
 461       AC_MSG_RESULT([yes])
 462     fi
 463   fi
 464
 465   dnl This is a workaround for #46797
 466   dnl (a.k.a https://github.com/rust-lang/rust/issues/46797 ).  Once the
 467   dnl upstream bug is fixed, we can remove this workaround.
 468   case "$host_os" in
 469       darwin*)
 470         TOR_RUST_EXTRA_LIBS="-lresolv"
 471         ;;
 472   esac
 473
 474   dnl For now both MSVC and MinGW rust libraries will output static libs with
 475   dnl the MSVC naming convention.
 476   if test "$bwin32" = "true"; then
 477     TOR_RUST_STATIC_NAME=tor_rust.lib
 478   else
 479     TOR_RUST_STATIC_NAME=libtor_rust.a
 480   fi
 481
 482   AC_SUBST(TOR_RUST_STATIC_NAME)
 483   AC_SUBST(CARGO_ONLINE)
 484   AC_SUBST(RUST_DL)
 485
 486   dnl Let's check the rustc version, too
 487   AC_MSG_CHECKING([rust version])
 488   RUSTC_VERSION=`$RUSTC --version`
 489   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 490   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 491   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 492     AC_MSG_ERROR([rustc version couldn't be identified])
 493   fi
 494   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 495     AC_MSG_ERROR([rustc must be at least version 1.14])
 496   fi
 497   AC_MSG_RESULT([$RUSTC_VERSION])
 498 fi
 499
 500 AC_SUBST(TOR_RUST_EXTRA_LIBS)
 501
 502 AC_SEARCH_LIBS(socket, [socket network])
 503 AC_SEARCH_LIBS(gethostbyname, [nsl])
 504 AC_SEARCH_LIBS(dlopen, [dl])
 505 AC_SEARCH_LIBS(inet_aton, [resolv])
 506 AC_SEARCH_LIBS(backtrace, [execinfo])
 507 saved_LIBS="$LIBS"
 508 AC_SEARCH_LIBS([clock_gettime], [rt])
 509 if test "$LIBS" != "$saved_LIBS"; then
 510    # Looks like we need -lrt for clock_gettime().
 511    have_rt=yes
 512 fi
 513
 514 AC_SEARCH_LIBS(pthread_create, [pthread])
 515 AC_SEARCH_LIBS(pthread_detach, [pthread])
 516
 517 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 518 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 519
 520 AC_CHECK_FUNCS(
 521         _NSGetEnviron \
 522         RtlSecureZeroMemory \
 523         SecureZeroMemory \
 524         accept4 \
 525         backtrace \
 526         backtrace_symbols_fd \
 527         eventfd \
 528         explicit_bzero \
 529         timingsafe_memcmp \
 530         flock \
 531         ftime \
 532         get_current_dir_name \
 533         getaddrinfo \
 534         getifaddrs \
 535         getpass \
 536         getrlimit \
 537         gettimeofday \
 538         gmtime_r \
 539         gnu_get_libc_version \
 540         htonll \
 541         inet_aton \
 542         ioctl \
 543         issetugid \
 544         llround \
 545         localtime_r \
 546         lround \
 547         mach_approximate_time \
 548         memmem \
 549         memset_s \
 550         pipe \
 551         pipe2 \
 552         prctl \
 553         readpassphrase \
 554         rint \
 555         sigaction \
 556         socketpair \
 557         statvfs \
 558         strlcat \
 559         strlcpy \
 560         strnlen \
 561         strptime \
 562         strtok_r \
 563         strtoull \
 564         sysconf \
 565         sysctl \
 566         truncate \
 567         uname \
 568         usleep \
 569         vasprintf \
 570         _vscprintf
 571 )
 572
 573 # Apple messed up when they added two functions functions in Sierra: they
 574 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 575 # checks. So we should only probe for those functions if we are sure that we
 576 # are not targeting OSX 10.11 or earlier.
 577 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 578 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 579 #ifdef __APPLE__
 580 #  include <AvailabilityMacros.h>
 581 #  ifndef MAC_OS_X_VERSION_10_12
 582 #    define MAC_OS_X_VERSION_10_12 101200
 583 #  endif
 584 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 585 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 586 #      error "Running on Mac OSX 10.11 or earlier"
 587 #    endif
 588 #  endif
 589 #endif
 590 ]], [[]])],
 591    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 592    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 593
 594 if test "$on_macos_pre_10_12" = "no"; then
 595   AC_CHECK_FUNCS(
 596         clock_gettime \
 597         getentropy \
 598   )
 599 fi
 600
 601 if test "$bwin32" != "true"; then
 602   AC_CHECK_HEADERS(pthread.h)
 603   AC_CHECK_FUNCS(pthread_create)
 604   AC_CHECK_FUNCS(pthread_condattr_setclock)
 605 fi
 606
 607 if test "$bwin32" = "true"; then
 608   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 609 #include <windows.h>
 610 #include <conio.h>
 611 #include <wchar.h>
 612                  ])
 613 fi
 614
 615 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 616   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 617
 618 dnl ------------------------------------------------------
 619 dnl Where do you live, libevent?  And how do we call you?
 620
 621 if test "$bwin32" = "true"; then
 622   TOR_LIB_WS32=-lws2_32
 623   TOR_LIB_IPHLPAPI=-liphlpapi
 624   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 625   # think it's actually necessary.
 626   TOR_LIB_GDI=-lgdi32
 627   TOR_LIB_USERENV=-luserenv
 628 else
 629   TOR_LIB_WS32=
 630   TOR_LIB_GDI=
 631   TOR_LIB_USERENV=
 632 fi
 633 AC_SUBST(TOR_LIB_WS32)
 634 AC_SUBST(TOR_LIB_GDI)
 635 AC_SUBST(TOR_LIB_IPHLPAPI)
 636 AC_SUBST(TOR_LIB_USERENV)
 637
 638 tor_libevent_pkg_redhat="libevent"
 639 tor_libevent_pkg_debian="libevent-dev"
 640 tor_libevent_devpkg_redhat="libevent-devel"
 641 tor_libevent_devpkg_debian="libevent-dev"
 642
 643 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 644 dnl linking for static builds.
 645 STATIC_LIBEVENT_FLAGS=""
 646 if test "$enable_static_libevent" = "yes"; then
 647     if test "$have_rt" = "yes"; then
 648       STATIC_LIBEVENT_FLAGS=" -lrt "
 649     fi
 650 fi
 651
 652 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 653 #ifdef _WIN32
 654 #include <winsock2.h>
 655 #endif
 656 #include <sys/time.h>
 657 #include <sys/types.h>
 658 #include <event2/event.h>], [
 659 #ifdef _WIN32
 660 #include <winsock2.h>
 661 #endif
 662 struct event_base;
 663 struct event_base *event_base_new(void);
 664 void event_base_free(struct event_base *);],
 665     [
 666 #ifdef _WIN32
 667 {WSADATA d; WSAStartup(0x101,&d); }
 668 #endif
 669 event_base_free(event_base_new());
 670 ], [--with-libevent-dir], [/opt/libevent])
 671
 672 dnl Determine the incantation needed to link libevent.
 673 save_LIBS="$LIBS"
 674 save_LDFLAGS="$LDFLAGS"
 675 save_CPPFLAGS="$CPPFLAGS"
 676
 677 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 678 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 679 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 680
 681 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 682
 683 if test "$enable_static_libevent" = "yes"; then
 684    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 685      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 686    else
 687      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 688    fi
 689 else
 690      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 691        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 692        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 693
 694        if test "$ac_cv_search_event_new" != "none required"; then
 695          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 696        fi
 697        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 698          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 699        fi
 700      else
 701        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 702      fi
 703 fi
 704
 705 dnl Now check for particular libevent functions.
 706 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 707                 evutil_secure_rng_add_bytes \
 708 ])
 709
 710 LIBS="$save_LIBS"
 711 LDFLAGS="$save_LDFLAGS"
 712 CPPFLAGS="$save_CPPFLAGS"
 713
 714 dnl Check that libevent is at least at version 2.0.10, the first stable
 715 dnl release of its series
 716 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 717 AC_MSG_CHECKING([whether Libevent is new enough])
 718 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 719 #include <event2/event.h>
 720 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 721 #error
 722 int x = y(zz);
 723 #else
 724 int x = 1;
 725 #endif
 726 ])], [ AC_MSG_RESULT([yes]) ],
 727    [ AC_MSG_RESULT([no])
 728      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 729
 730 LIBS="$save_LIBS"
 731 LDFLAGS="$save_LDFLAGS"
 732 CPPFLAGS="$save_CPPFLAGS"
 733
 734 AC_SUBST(TOR_LIBEVENT_LIBS)
 735
 736 dnl ------------------------------------------------------
 737 dnl Where do you live, libm?
 738
 739 dnl On some platforms (Haiku/BeOS) the math library is
 740 dnl part of libroot. In which case don't link against lm
 741 TOR_LIB_MATH=""
 742 save_LIBS="$LIBS"
 743 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 744 if test "$ac_cv_search_pow" != "none required"; then
 745     TOR_LIB_MATH="$ac_cv_search_pow"
 746 fi
 747 LIBS="$save_LIBS"
 748 AC_SUBST(TOR_LIB_MATH)
 749
 750 dnl ------------------------------------------------------
 751 dnl Where do you live, openssl?  And how do we call you?
 752
 753 tor_openssl_pkg_redhat="openssl"
 754 tor_openssl_pkg_debian="libssl-dev"
 755 tor_openssl_devpkg_redhat="openssl-devel"
 756 tor_openssl_devpkg_debian="libssl-dev"
 757
 758 ALT_openssl_WITHVAL=""
 759 AC_ARG_WITH(ssl-dir,
 760   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 761   [
 762       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 763          ALT_openssl_WITHVAL="$withval"
 764       fi
 765   ])
 766
 767 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 768 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 769     [#include <openssl/ssl.h>],
 770     [struct ssl_method_st; const struct ssl_method_st *TLSv1_1_method(void);],
 771     [TLSv1_1_method();], [],
 772     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /opt/openssl])
 773
 774 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 775
 776 if test "$enable_static_openssl" = "yes"; then
 777    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 778      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 779    else
 780      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 781    fi
 782 else
 783      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 784 fi
 785 AC_SUBST(TOR_OPENSSL_LIBS)
 786
 787 dnl Now check for particular openssl functions.
 788 save_LIBS="$LIBS"
 789 save_LDFLAGS="$LDFLAGS"
 790 save_CPPFLAGS="$CPPFLAGS"
 791 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 792 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 793 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 794
 795 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 796 #include <openssl/opensslv.h>
 797 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 798 #error "too old"
 799 #endif
 800    ]], [[]])],
 801    [ : ],
 802    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 803
 804 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 805 #include <openssl/opensslv.h>
 806 #include <openssl/evp.h>
 807 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 808 #error "no ECC"
 809 #endif
 810 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 811 #error "curves unavailable"
 812 #endif
 813    ]], [[]])],
 814    [ : ],
 815    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 816
 817 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 818 [#include <openssl/ssl.h>
 819 ])
 820
 821 AC_CHECK_FUNCS([ \
 822                 SSL_SESSION_get_master_key \
 823                 SSL_get_server_random \
 824                 SSL_get_client_ciphers \
 825                 SSL_get_client_random \
 826                 SSL_CIPHER_find \
 827                 TLS_method
 828                ])
 829
 830 dnl Check if OpenSSL has scrypt implementation.
 831 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 832
 833 dnl Check if OpenSSL structures are opaque
 834 AC_CHECK_MEMBERS([SSL.state], , ,
 835 [#include <openssl/ssl.h>
 836 ])
 837
 838 dnl Define the set of checks for KIST scheduler support.
 839 AC_DEFUN([CHECK_KIST_SUPPORT],[
 840   dnl KIST needs struct tcp_info and for certain members to exist.
 841   AC_CHECK_MEMBERS(
 842     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
 843     , ,[[#include <netinet/tcp.h>]])
 844   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
 845   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 846                      #include <linux/sockios.h>
 847                      #ifndef SIOCOUTQNSD
 848                      #error
 849                      #endif
 850                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
 851   if test "x$have_siocoutqnsd" = "xyes"; then
 852     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
 853       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
 854         have_kist_support=yes
 855       fi
 856     fi
 857   fi
 858 ])
 859 dnl Now, trigger the check.
 860 CHECK_KIST_SUPPORT
 861 AS_IF([test "x$have_kist_support" = "xyes"],
 862       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
 863                                         on this system])],
 864       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
 865
 866 LIBS="$save_LIBS"
 867 LDFLAGS="$save_LDFLAGS"
 868 CPPFLAGS="$save_CPPFLAGS"
 869
 870 dnl ------------------------------------------------------
 871 dnl Where do you live, zlib?  And how do we call you?
 872
 873 tor_zlib_pkg_redhat="zlib"
 874 tor_zlib_pkg_debian="zlib1g"
 875 tor_zlib_devpkg_redhat="zlib-devel"
 876 tor_zlib_devpkg_debian="zlib1g-dev"
 877
 878 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 879     [#include <zlib.h>],
 880     [const char * zlibVersion(void);],
 881     [zlibVersion();], [--with-zlib-dir],
 882     [/opt/zlib])
 883
 884 if test "$enable_static_zlib" = "yes"; then
 885    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 886      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 887  using --enable-static-zlib")
 888    else
 889      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 890    fi
 891 else
 892      TOR_ZLIB_LIBS="-lz"
 893 fi
 894 AC_SUBST(TOR_ZLIB_LIBS)
 895
 896 dnl ------------------------------------------------------
 897 dnl Where we do we find lzma?
 898
 899 AC_ARG_ENABLE(lzma,
 900       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
 901       [case "${enableval}" in
 902         "yes") lzma=true ;;
 903         "no")  lzma=false ;;
 904         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
 905       esac], [lzma=auto])
 906
 907 if test "x$enable_lzma" = "xno"; then
 908     have_lzma=no;
 909 else
 910     PKG_CHECK_MODULES([LZMA],
 911                       [liblzma],
 912                       have_lzma=yes,
 913                       have_lzma=no)
 914
 915     if test "x$have_lzma" = "xno" ; then
 916         AC_MSG_WARN([Unable to find liblzma.])
 917     fi
 918 fi
 919
 920 if test "x$have_lzma" = "xyes"; then
 921     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
 922     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
 923     TOR_LZMA_LIBS="${LZMA_LIBS}"
 924 fi
 925 AC_SUBST(TOR_LZMA_CFLAGS)
 926 AC_SUBST(TOR_LZMA_LIBS)
 927
 928 dnl ------------------------------------------------------
 929 dnl Where we do we find zstd?
 930
 931 AC_ARG_ENABLE(zstd,
 932       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
 933       [case "${enableval}" in
 934         "yes") zstd=true ;;
 935         "no")  zstd=false ;;
 936         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
 937       esac], [zstd=auto])
 938
 939 if test "x$enable_zstd" = "xno"; then
 940     have_zstd=no;
 941 else
 942     PKG_CHECK_MODULES([ZSTD],
 943                       [libzstd >= 1.1],
 944                       have_zstd=yes,
 945                       have_zstd=no)
 946
 947     if test "x$have_zstd" = "xno" ; then
 948         AC_MSG_WARN([Unable to find libzstd.])
 949     fi
 950 fi
 951
 952 if test "x$have_zstd" = "xyes"; then
 953     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
 954     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
 955     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
 956 fi
 957 AC_SUBST(TOR_ZSTD_CFLAGS)
 958 AC_SUBST(TOR_ZSTD_LIBS)
 959
 960 dnl ----------------------------------------------------------------------
 961 dnl Check if libcap is available for capabilities.
 962
 963 tor_cap_pkg_debian="libcap2"
 964 tor_cap_pkg_redhat="libcap"
 965 tor_cap_devpkg_debian="libcap-dev"
 966 tor_cap_devpkg_redhat="libcap-devel"
 967
 968 AC_CHECK_LIB([cap], [cap_init], [],
 969   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 970 )
 971 AC_CHECK_FUNCS(cap_set_proc)
 972
 973 dnl ---------------------------------------------------------------------
 974 dnl Now that we know about our major libraries, we can check for compiler
 975 dnl and linker hardening options.  We need to do this with the libraries known,
 976 dnl since sometimes the linker will like an option but not be willing to
 977 dnl use it with a build of a library.
 978
 979 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 980 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
 981
 982 CFLAGS_FTRAPV=
 983 CFLAGS_FWRAPV=
 984 CFLAGS_ASAN=
 985 CFLAGS_UBSAN=
 986
 987
 988 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 989 #if !defined(__clang__)
 990 #error
 991 #endif])], have_clang=yes, have_clang=no)
 992
 993 if test "x$enable_gcc_hardening" != "xno"; then
 994     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 995     if test "x$have_clang" = "xyes"; then
 996         TOR_CHECK_CFLAGS(-Qunused-arguments)
 997     fi
 998     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 999     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
1000     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
1001 m4_ifdef([AS_VAR_IF],[
1002     AS_VAR_IF(can_compile, [yes],
1003         AS_VAR_IF(can_link, [yes],
1004                   [],
1005                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
1006         )])
1007     AS_VAR_POPDEF([can_link])
1008     AS_VAR_POPDEF([can_compile])
1009     TOR_CHECK_CFLAGS(-Wstack-protector)
1010     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
1011     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
1012        TOR_CHECK_CFLAGS(-fPIE)
1013        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
1014     fi
1015     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
1016 fi
1017
1018 if test "$fragile_hardening" = "yes"; then
1019     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
1020    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
1021       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
1022    fi
1023
1024    if test "$tor_cv_cflags__ftrapv" != "yes"; then
1025      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
1026    fi
1027
1028    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
1029     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1030       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.*, and with Clang you need libclang_rt.ubsan*])
1031     fi
1032
1033    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1034     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1035       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1036     fi
1037
1038 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1039 fi
1040
1041 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1042 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1043
1044 mulodi_fixes_ftrapv=no
1045 if test "$have_clang" = "yes"; then
1046   saved_CFLAGS="$CFLAGS"
1047   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1048   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1049   AC_LINK_IFELSE([
1050       AC_LANG_SOURCE([[
1051           #include <stdint.h>
1052           #include <stdlib.h>
1053           int main(int argc, char **argv)
1054           {
1055             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1056                         * (int64_t)atoi(argv[3]);
1057             return x == 9;
1058           } ]])],
1059           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1060           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1061   if test "$ftrapv_can_link" = "no"; then
1062     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1063     AC_LINK_IFELSE([
1064       AC_LANG_SOURCE([[
1065           #include <stdint.h>
1066           #include <stdlib.h>
1067           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1068              *overflow=0;
1069              return a;
1070           }
1071           int main(int argc, char **argv)
1072           {
1073             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1074                         * (int64_t)atoi(argv[3]);
1075             return x == 9;
1076           } ]])],
1077           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1078           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1079   fi
1080   CFLAGS="$saved_CFLAGS"
1081 fi
1082
1083 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1084
1085 dnl These cflags add bunches of branches, and we haven't been able to
1086 dnl persuade ourselves that they're suitable for code that needs to be
1087 dnl constant time.
1088 AC_SUBST(CFLAGS_BUGTRAP)
1089 dnl These cflags are variant ones sutable for code that needs to be
1090 dnl constant-time.
1091 AC_SUBST(CFLAGS_CONSTTIME)
1092
1093 if test "x$enable_linker_hardening" != "xno"; then
1094     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1095 fi
1096
1097 # For backtrace support
1098 TOR_CHECK_LDFLAGS(-rdynamic)
1099
1100 dnl ------------------------------------------------------
1101 dnl Now see if we have a -fomit-frame-pointer compiler option.
1102
1103 saved_CFLAGS="$CFLAGS"
1104 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1105 F_OMIT_FRAME_POINTER=''
1106 if test "$saved_CFLAGS" != "$CFLAGS"; then
1107   if test "$fragile_hardening" = "yes"; then
1108     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1109   fi
1110 fi
1111 CFLAGS="$saved_CFLAGS"
1112 AC_SUBST(F_OMIT_FRAME_POINTER)
1113
1114 dnl ------------------------------------------------------
1115 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1116 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1117 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1118 dnl code will work.
1119 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1120
1121 dnl ============================================================
1122 dnl Check for libseccomp
1123
1124 if test "x$enable_seccomp" != "xno"; then
1125   AC_CHECK_HEADERS([seccomp.h])
1126   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1127 fi
1128
1129 dnl ============================================================
1130 dnl Check for libscrypt
1131
1132 if test "x$enable_libscrypt" != "xno"; then
1133   AC_CHECK_HEADERS([libscrypt.h])
1134   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1135   AC_CHECK_FUNCS([libscrypt_scrypt])
1136 fi
1137
1138 dnl ============================================================
1139 dnl We need an implementation of curve25519.
1140
1141 dnl set these defaults.
1142 build_curve25519_donna=no
1143 build_curve25519_donna_c64=no
1144 use_curve25519_donna=no
1145 use_curve25519_nacl=no
1146 CURVE25519_LIBS=
1147
1148 dnl The best choice is using curve25519-donna-c64, but that requires
1149 dnl that we
1150 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1151   tor_cv_can_use_curve25519_donna_c64,
1152   [AC_RUN_IFELSE(
1153     [AC_LANG_PROGRAM([dnl
1154       #include <stdint.h>
1155       typedef unsigned uint128_t __attribute__((mode(TI)));
1156   int func(uint64_t a, uint64_t b) {
1157            uint128_t c = ((uint128_t)a) * b;
1158            int ok = ((uint64_t)(c>>96)) == 522859 &&
1159              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1160                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1161                  (((uint64_t)(c))&0xffffffffL) == 0;
1162            return ok;
1163       }
1164   ], [dnl
1165     int ok = func( ((uint64_t)2000000000) * 1000000000,
1166                    ((uint64_t)1234567890) << 24);
1167         return !ok;
1168       ])],
1169   [tor_cv_can_use_curve25519_donna_c64=yes],
1170       [tor_cv_can_use_curve25519_donna_c64=no],
1171   [AC_LINK_IFELSE(
1172         [AC_LANG_PROGRAM([dnl
1173       #include <stdint.h>
1174       typedef unsigned uint128_t __attribute__((mode(TI)));
1175   int func(uint64_t a, uint64_t b) {
1176            uint128_t c = ((uint128_t)a) * b;
1177            int ok = ((uint64_t)(c>>96)) == 522859 &&
1178              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1179                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1180                  (((uint64_t)(c))&0xffffffffL) == 0;
1181            return ok;
1182       }
1183   ], [dnl
1184     int ok = func( ((uint64_t)2000000000) * 1000000000,
1185                  ((uint64_t)1234567890) << 24);
1186         return !ok;
1187       ])],
1188           [tor_cv_can_use_curve25519_donna_c64=cross],
1189       [tor_cv_can_use_curve25519_donna_c64=no])])])
1190
1191 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1192                   nacl/crypto_scalarmult_curve25519.h])
1193
1194 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1195   tor_cv_can_use_curve25519_nacl,
1196   [tor_saved_LIBS="$LIBS"
1197    LIBS="$LIBS -lnacl"
1198    AC_LINK_IFELSE(
1199      [AC_LANG_PROGRAM([dnl
1200        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1201        #include <crypto_scalarmult_curve25519.h>
1202    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1203    #include <nacl/crypto_scalarmult_curve25519.h>
1204    #endif
1205        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1206    #error Hey, this is the reference implementation! That's not fast.
1207    #endif
1208      ], [
1209    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1210      ])], [tor_cv_can_use_curve25519_nacl=yes],
1211      [tor_cv_can_use_curve25519_nacl=no])
1212    LIBS="$tor_saved_LIBS" ])
1213
1214  dnl Okay, now we need to figure out which one to actually use. Fall back
1215  dnl to curve25519-donna.c
1216
1217  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1218    build_curve25519_donna_c64=yes
1219    use_curve25519_donna=yes
1220  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1221    use_curve25519_nacl=yes
1222    CURVE25519_LIBS=-lnacl
1223  else
1224    build_curve25519_donna=yes
1225    use_curve25519_donna=yes
1226  fi
1227
1228 if test "x$use_curve25519_donna" = "xyes"; then
1229   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1230             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1231 fi
1232 if test "x$use_curve25519_nacl" = "xyes"; then
1233   AC_DEFINE(USE_CURVE25519_NACL, 1,
1234             [Defined if we should use a curve25519 from nacl])
1235 fi
1236 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1237   test "x$build_curve25519_donna" = "xyes")
1238 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1239   test "x$build_curve25519_donna_c64" = "xyes")
1240 AC_SUBST(CURVE25519_LIBS)
1241
1242 dnl Make sure to enable support for large off_t if available.
1243 AC_SYS_LARGEFILE
1244
1245 AC_CHECK_HEADERS([assert.h \
1246                   errno.h \
1247                   fcntl.h \
1248                   signal.h \
1249                   string.h \
1250                   sys/capability.h \
1251                   sys/fcntl.h \
1252                   sys/stat.h \
1253                   sys/time.h \
1254                   sys/types.h \
1255                   time.h \
1256                   unistd.h \
1257                   arpa/inet.h \
1258                   crt_externs.h \
1259                   execinfo.h \
1260                   gnu/libc-version.h \
1261                   grp.h \
1262                   ifaddrs.h \
1263                   inttypes.h \
1264                   limits.h \
1265                   linux/types.h \
1266                   machine/limits.h \
1267                   malloc.h \
1268                   malloc/malloc.h \
1269                   malloc_np.h \
1270                   netdb.h \
1271                   netinet/in.h \
1272                   netinet/in6.h \
1273                   pwd.h \
1274                   readpassphrase.h \
1275                   stdint.h \
1276                   stdatomic.h \
1277                   sys/eventfd.h \
1278                   sys/file.h \
1279                   sys/ioctl.h \
1280                   sys/limits.h \
1281                   sys/mman.h \
1282                   sys/param.h \
1283                   sys/prctl.h \
1284                   sys/random.h \
1285                   sys/resource.h \
1286                   sys/select.h \
1287                   sys/socket.h \
1288                   sys/statvfs.h \
1289                   sys/syscall.h \
1290                   sys/sysctl.h \
1291                   sys/syslimits.h \
1292                   sys/time.h \
1293                   sys/types.h \
1294                   sys/un.h \
1295                   sys/utime.h \
1296                   sys/wait.h \
1297                   syslog.h \
1298                   utime.h])
1299
1300 AC_CHECK_HEADERS(sys/param.h)
1301
1302 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1303 [#ifdef HAVE_SYS_TYPES_H
1304 #include <sys/types.h>
1305 #endif
1306 #ifdef HAVE_SYS_SOCKET_H
1307 #include <sys/socket.h>
1308 #endif])
1309 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1310 [#ifdef HAVE_SYS_TYPES_H
1311 #include <sys/types.h>
1312 #endif
1313 #ifdef HAVE_SYS_SOCKET_H
1314 #include <sys/socket.h>
1315 #endif
1316 #ifdef HAVE_NET_IF_H
1317 #include <net/if.h>
1318 #endif
1319 #ifdef HAVE_NETINET_IN_H
1320 #include <netinet/in.h>
1321 #endif])
1322
1323 AC_CHECK_HEADERS(linux/if.h,[],[],
1324 [
1325 #ifdef HAVE_SYS_SOCKET_H
1326 #include <sys/socket.h>
1327 #endif
1328 ])
1329
1330 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1331         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1332 [#ifdef HAVE_SYS_TYPES_H
1333 #include <sys/types.h>
1334 #endif
1335 #ifdef HAVE_SYS_SOCKET_H
1336 #include <sys/socket.h>
1337 #endif
1338 #ifdef HAVE_LIMITS_H
1339 #include <limits.h>
1340 #endif
1341 #ifdef HAVE_LINUX_TYPES_H
1342 #include <linux/types.h>
1343 #endif
1344 #ifdef HAVE_NETINET_IN6_H
1345 #include <netinet/in6.h>
1346 #endif
1347 #ifdef HAVE_NETINET_IN_H
1348 #include <netinet/in.h>
1349 #endif])
1350
1351 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1352         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1353 [#ifdef HAVE_SYS_TYPES_H
1354 #include <sys/types.h>
1355 #endif
1356 #ifdef HAVE_SYS_SOCKET_H
1357 #include <sys/socket.h>
1358 #endif
1359 #ifdef HAVE_LIMITS_H
1360 #include <limits.h>
1361 #endif
1362 #ifdef HAVE_LINUX_TYPES_H
1363 #include <linux/types.h>
1364 #endif
1365 #ifdef HAVE_NETINET_IN6_H
1366 #include <netinet/in6.h>
1367 #endif
1368 #ifdef HAVE_NETINET_IN_H
1369 #include <netinet/in.h>
1370 #endif
1371 #ifdef HAVE_LINUX_IF_H
1372 #include <linux/if.h>
1373 #endif])
1374
1375 transparent_ok=0
1376 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1377   transparent_ok=1
1378 fi
1379 if test "x$linux_netfilter_ipv4" = "x1"; then
1380   transparent_ok=1
1381 fi
1382 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1383   transparent_ok=1
1384 fi
1385 if test "x$transparent_ok" = "x1"; then
1386   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1387 else
1388   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1389 fi
1390
1391 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1392 [#ifdef HAVE_SYS_TYPES_H
1393 #include <sys/types.h>
1394 #endif
1395 #ifdef HAVE_SYS_TIME_H
1396 #include <sys/time.h>
1397 #endif])
1398
1399 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1400 dnl Watch out.
1401
1402 AC_CHECK_SIZEOF(int8_t)
1403 AC_CHECK_SIZEOF(int16_t)
1404 AC_CHECK_SIZEOF(int32_t)
1405 AC_CHECK_SIZEOF(int64_t)
1406 AC_CHECK_SIZEOF(uint8_t)
1407 AC_CHECK_SIZEOF(uint16_t)
1408 AC_CHECK_SIZEOF(uint32_t)
1409 AC_CHECK_SIZEOF(uint64_t)
1410 AC_CHECK_SIZEOF(intptr_t)
1411 AC_CHECK_SIZEOF(uintptr_t)
1412
1413 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1414
1415 AC_CHECK_SIZEOF(char)
1416 AC_CHECK_SIZEOF(short)
1417 AC_CHECK_SIZEOF(int)
1418 AC_CHECK_SIZEOF(long)
1419 AC_CHECK_SIZEOF(long long)
1420 AC_CHECK_SIZEOF(__int64)
1421 AC_CHECK_SIZEOF(void *)
1422 AC_CHECK_SIZEOF(time_t)
1423 AC_CHECK_SIZEOF(size_t)
1424 AC_CHECK_SIZEOF(pid_t)
1425
1426 AC_CHECK_TYPES([uint, u_char, ssize_t])
1427
1428 AC_PC_FROM_UCONTEXT([:])
1429
1430 dnl used to include sockaddr_storage, but everybody has that.
1431 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1432 [#ifdef HAVE_SYS_TYPES_H
1433 #include <sys/types.h>
1434 #endif
1435 #ifdef HAVE_NETINET_IN_H
1436 #include <netinet/in.h>
1437 #endif
1438 #ifdef HAVE_NETINET_IN6_H
1439 #include <netinet/in6.h>
1440 #endif
1441 #ifdef HAVE_SYS_SOCKET_H
1442 #include <sys/socket.h>
1443 #endif
1444 #ifdef _WIN32
1445 #define _WIN32_WINNT 0x0501
1446 #define WIN32_LEAN_AND_MEAN
1447 #include <winsock2.h>
1448 #include <ws2tcpip.h>
1449 #endif
1450 ])
1451 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1452 [#ifdef HAVE_SYS_TYPES_H
1453 #include <sys/types.h>
1454 #endif
1455 #ifdef HAVE_NETINET_IN_H
1456 #include <netinet/in.h>
1457 #endif
1458 #ifdef HAVE_NETINET_IN6_H
1459 #include <netinet/in6.h>
1460 #endif
1461 #ifdef HAVE_SYS_SOCKET_H
1462 #include <sys/socket.h>
1463 #endif
1464 #ifdef _WIN32
1465 #define _WIN32_WINNT 0x0501
1466 #define WIN32_LEAN_AND_MEAN
1467 #include <winsock2.h>
1468 #include <ws2tcpip.h>
1469 #endif
1470 ])
1471
1472 AC_CHECK_TYPES([rlim_t], , ,
1473 [#ifdef HAVE_SYS_TYPES_H
1474 #include <sys/types.h>
1475 #endif
1476 #ifdef HAVE_SYS_TIME_H
1477 #include <sys/time.h>
1478 #endif
1479 #ifdef HAVE_SYS_RESOURCE_H
1480 #include <sys/resource.h>
1481 #endif
1482 ])
1483
1484 AX_CHECK_SIGN([time_t],
1485        [ : ],
1486        [ : ], [
1487 #ifdef HAVE_SYS_TYPES_H
1488 #include <sys/types.h>
1489 #endif
1490 #ifdef HAVE_SYS_TIME_H
1491 #include <sys/time.h>
1492 #endif
1493 #ifdef HAVE_TIME_H
1494 #include <time.h>
1495 #endif
1496 ])
1497
1498 if test "$ax_cv_decl_time_t_signed" = "no"; then
1499   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1500 fi
1501
1502 AX_CHECK_SIGN([size_t],
1503        [ tor_cv_size_t_signed=yes ],
1504        [ tor_cv_size_t_signed=no ], [
1505 #ifdef HAVE_SYS_TYPES_H
1506 #include <sys/types.h>
1507 #endif
1508 ])
1509
1510 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1511   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1512 fi
1513
1514 AX_CHECK_SIGN([enum always],
1515        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1516        [ : ], [
1517  enum always { AAA, BBB, CCC };
1518 ])
1519
1520 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1521 #ifdef HAVE_SYS_SOCKET_H
1522 #include <sys/socket.h>
1523 #endif
1524 ])
1525
1526 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1527
1528 AC_CHECK_SIZEOF(cell_t)
1529
1530 # Now make sure that NULL can be represented as zero bytes.
1531 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1532 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1533 [[#include <stdlib.h>
1534 #include <string.h>
1535 #include <stdio.h>
1536 #ifdef HAVE_STDDEF_H
1537 #include <stddef.h>
1538 #endif
1539 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1540 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1541        [tor_cv_null_is_zero=yes],
1542        [tor_cv_null_is_zero=no],
1543        [tor_cv_null_is_zero=cross])])
1544
1545 if test "$tor_cv_null_is_zero" = "cross"; then
1546   # Cross-compiling; let's hope that the target isn't raving mad.
1547   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1548 fi
1549
1550 if test "$tor_cv_null_is_zero" != "no"; then
1551   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1552             [Define to 1 iff memset(0) sets pointers to NULL])
1553 fi
1554
1555 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1556 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1557 [[#include <stdlib.h>
1558 #include <string.h>
1559 #include <stdio.h>
1560 #ifdef HAVE_STDDEF_H
1561 #include <stddef.h>
1562 #endif
1563 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1564 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1565        [tor_cv_dbl0_is_zero=yes],
1566        [tor_cv_dbl0_is_zero=no],
1567        [tor_cv_dbl0_is_zero=cross])])
1568
1569 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1570   # Cross-compiling; let's hope that the target isn't raving mad.
1571   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1572 fi
1573
1574 if test "$tor_cv_dbl0_is_zero" != "no"; then
1575   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1576             [Define to 1 iff memset(0) sets doubles to 0.0])
1577 fi
1578
1579 # And what happens when we malloc zero?
1580 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1581 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1582 [[#include <stdlib.h>
1583 #include <string.h>
1584 #include <stdio.h>
1585 #ifdef HAVE_STDDEF_H
1586 #include <stddef.h>
1587 #endif
1588 int main () { return malloc(0)?0:1; }]])],
1589        [tor_cv_malloc_zero_works=yes],
1590        [tor_cv_malloc_zero_works=no],
1591        [tor_cv_malloc_zero_works=cross])])
1592
1593 if test "$tor_cv_malloc_zero_works" = "cross"; then
1594   # Cross-compiling; let's hope that the target isn't raving mad.
1595   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1596 fi
1597
1598 if test "$tor_cv_malloc_zero_works" = "yes"; then
1599   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1600             [Define to 1 iff malloc(0) returns a pointer])
1601 fi
1602
1603 # whether we seem to be in a 2s-complement world.
1604 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1605 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1606 [[int main () { int problem = ((-99) != (~99)+1);
1607 return problem ? 1 : 0; }]])],
1608        [tor_cv_twos_complement=yes],
1609        [tor_cv_twos_complement=no],
1610        [tor_cv_twos_complement=cross])])
1611
1612 if test "$tor_cv_twos_complement" = "cross"; then
1613   # Cross-compiling; let's hope that the target isn't raving mad.
1614   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1615 fi
1616
1617 if test "$tor_cv_twos_complement" != "no"; then
1618   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1619             [Define to 1 iff we represent negative integers with
1620              two's complement])
1621 fi
1622
1623 # What does shifting a negative value do?
1624 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1625 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1626 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1627        [tor_cv_sign_extend=yes],
1628        [tor_cv_sign_extend=no],
1629        [tor_cv_sign_extend=cross])])
1630
1631 if test "$tor_cv_sign_extend" = "cross"; then
1632   # Cross-compiling; let's hope that the target isn't raving mad.
1633   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1634 fi
1635
1636 if test "$tor_cv_sign_extend" != "no"; then
1637   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1638             [Define to 1 iff right-shifting a negative value performs sign-extension])
1639 fi
1640
1641 # Is uint8_t the same type as unsigned char?
1642 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1643 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1644 #include <stdint.h>
1645 extern uint8_t c;
1646 unsigned char c;]])],
1647        [tor_cv_uint8_uchar=yes],
1648        [tor_cv_uint8_uchar=no],
1649        [tor_cv_uint8_uchar=cross])])
1650
1651 if test "$tor_cv_uint8_uchar" = "cross"; then
1652   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1653 fi
1654
1655 if test "$tor_cv_uint8_uchar" = "no"; then
1656   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1657 fi
1658
1659 # Whether we should use the dmalloc memory allocation debugging library.
1660 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1661 AC_ARG_WITH(dmalloc,
1662 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1663 [if [[ "$withval" = "yes" ]]; then
1664   dmalloc=1
1665   AC_MSG_RESULT(yes)
1666 else
1667   dmalloc=1
1668   AC_MSG_RESULT(no)
1669 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1670 )
1671
1672 if [[ $dmalloc -eq 1 ]]; then
1673   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1674   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1675   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1676   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1677 fi
1678
1679 AC_ARG_WITH(tcmalloc,
1680 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1681 [ tcmalloc=yes ], [ tcmalloc=no ])
1682
1683 if test "x$tcmalloc" = "xyes"; then
1684    LDFLAGS="-ltcmalloc $LDFLAGS"
1685 fi
1686
1687 using_custom_malloc=no
1688 if test "x$enable_openbsd_malloc" = "xyes"; then
1689    using_custom_malloc=yes
1690 fi
1691 if test "x$tcmalloc" = "xyes"; then
1692    using_custom_malloc=yes
1693 fi
1694 if test "$using_custom_malloc" = "no"; then
1695    AC_CHECK_FUNCS(mallinfo)
1696 fi
1697
1698 # By default, we're going to assume we don't have mlockall()
1699 # bionic and other platforms have various broken mlockall subsystems.
1700 # Some systems don't have a working mlockall, some aren't linkable,
1701 # and some have it but don't declare it.
1702 AC_CHECK_FUNCS(mlockall)
1703 AC_CHECK_DECLS([mlockall], , , [
1704 #ifdef HAVE_SYS_MMAN_H
1705 #include <sys/mman.h>
1706 #endif])
1707
1708 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1709 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1710 # using macros
1711 AC_CHECK_DECLS([getpagesize], , , [
1712 #ifdef HAVE_UNISTD_H
1713 #include <unistd.h>
1714 #endif])
1715
1716 # Allow user to specify an alternate syslog facility
1717 AC_ARG_WITH(syslog-facility,
1718 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1719 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1720 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1721 AC_SUBST(LOGFACILITY)
1722
1723 # Check if we have getresuid and getresgid
1724 AC_CHECK_FUNCS(getresuid getresgid)
1725
1726 # Check for gethostbyname_r in all its glorious incompatible versions.
1727 #   (This logic is based on that in Python's configure.in)
1728 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1729   [Define this if you have any gethostbyname_r()])
1730
1731 AC_CHECK_FUNC(gethostbyname_r, [
1732   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1733   OLD_CFLAGS=$CFLAGS
1734   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1735   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1736 #include <netdb.h>
1737   ]], [[
1738     char *cp1, *cp2;
1739     struct hostent *h1, *h2;
1740     int i1, i2;
1741     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1742   ]])],[
1743     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1744     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1745      [Define this if gethostbyname_r takes 6 arguments])
1746     AC_MSG_RESULT(6)
1747   ], [
1748     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1749 #include <netdb.h>
1750     ]], [[
1751       char *cp1, *cp2;
1752       struct hostent *h1;
1753       int i1, i2;
1754       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1755     ]])], [
1756       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1757       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1758         [Define this if gethostbyname_r takes 5 arguments])
1759       AC_MSG_RESULT(5)
1760    ], [
1761       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1762 #include <netdb.h>
1763      ]], [[
1764        char *cp1;
1765        struct hostent *h1;
1766        struct hostent_data hd;
1767        (void) gethostbyname_r(cp1,h1,&hd);
1768      ]])], [
1769        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1770        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1771          [Define this if gethostbyname_r takes 3 arguments])
1772        AC_MSG_RESULT(3)
1773      ], [
1774        AC_MSG_RESULT(0)
1775      ])
1776   ])
1777  ])
1778  CFLAGS=$OLD_CFLAGS
1779 ])
1780
1781 AC_CACHE_CHECK([whether the C compiler supports __func__],
1782   tor_cv_have_func_macro,
1783   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1784 #include <stdio.h>
1785 int main(int c, char **v) { puts(__func__); }])],
1786   tor_cv_have_func_macro=yes,
1787   tor_cv_have_func_macro=no))
1788
1789 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1790   tor_cv_have_FUNC_macro,
1791   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1792 #include <stdio.h>
1793 int main(int c, char **v) { puts(__FUNC__); }])],
1794   tor_cv_have_FUNC_macro=yes,
1795   tor_cv_have_FUNC_macro=no))
1796
1797 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1798   tor_cv_have_FUNCTION_macro,
1799   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1800 #include <stdio.h>
1801 int main(int c, char **v) { puts(__FUNCTION__); }])],
1802   tor_cv_have_FUNCTION_macro=yes,
1803   tor_cv_have_FUNCTION_macro=no))
1804
1805 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1806   tor_cv_have_environ_declared,
1807   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1808 #ifdef HAVE_UNISTD_H
1809 #include <unistd.h>
1810 #endif
1811 #include <stdlib.h>
1812 int main(int c, char **v) { char **t = environ; }])],
1813   tor_cv_have_environ_declared=yes,
1814   tor_cv_have_environ_declared=no))
1815
1816 if test "$tor_cv_have_func_macro" = "yes"; then
1817   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1818 fi
1819
1820 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1821   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1822 fi
1823
1824 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1825   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1826            [Defined if the compiler supports __FUNCTION__])
1827 fi
1828
1829 if test "$tor_cv_have_environ_declared" = "yes"; then
1830   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1831            [Defined if we have extern char **environ already declared])
1832 fi
1833
1834 # $prefix stores the value of the --prefix command line option, or
1835 # NONE if the option wasn't set.  In the case that it wasn't set, make
1836 # it be the default, so that we can use it to expand directories now.
1837 if test "x$prefix" = "xNONE"; then
1838   prefix=$ac_default_prefix
1839 fi
1840
1841 # and similarly for $exec_prefix
1842 if test "x$exec_prefix" = "xNONE"; then
1843   exec_prefix=$prefix
1844 fi
1845
1846 if test "x$BUILDDIR" = "x"; then
1847   BUILDDIR=`pwd`
1848 fi
1849 AC_SUBST(BUILDDIR)
1850 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1851 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1852
1853 if test "x$CONFDIR" = "x"; then
1854   CONFDIR=`eval echo $sysconfdir/tor`
1855 fi
1856 AC_SUBST(CONFDIR)
1857 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1858 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1859
1860 BINDIR=`eval echo $bindir`
1861 AC_SUBST(BINDIR)
1862 LOCALSTATEDIR=`eval echo $localstatedir`
1863 AC_SUBST(LOCALSTATEDIR)
1864
1865 if test "$bwin32" = "true"; then
1866   # Test if the linker supports the --nxcompat and --dynamicbase options
1867   # for Windows
1868   save_LDFLAGS="$LDFLAGS"
1869   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1870   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1871   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1872     [AC_MSG_RESULT([yes])]
1873     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1874     [AC_MSG_RESULT([no])]
1875   )
1876   LDFLAGS="$save_LDFLAGS"
1877 fi
1878
1879 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1880 # than autoconf's macros like.
1881 if test "$GCC" = "yes"; then
1882   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1883   # accident waiting to happen.
1884   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1885 else
1886   # Override optimization level for non-gcc compilers
1887   CFLAGS="$CFLAGS -O"
1888   enable_gcc_warnings=no
1889   enable_gcc_warnings_advisory=no
1890 fi
1891
1892 # Warnings implies advisory-warnings and -Werror.
1893 if test "$enable_gcc_warnings" = "yes"; then
1894   enable_gcc_warnings_advisory=yes
1895   enable_fatal_warnings=yes
1896 fi
1897
1898 # OS X Lion started deprecating the system openssl. Let's just disable
1899 # all deprecation warnings on OS X. Also, to potentially make the binary
1900 # a little smaller, let's enable dead_strip.
1901 case "$host_os" in
1902
1903  darwin*)
1904     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1905     LDFLAGS="$LDFLAGS -dead_strip" ;;
1906 esac
1907
1908 # Add some more warnings which we use in development but not in the
1909 # released versions.  (Some relevant gcc versions can't handle these.)
1910 #
1911 # Note that we have to do this near the end  of the autoconf process, or
1912 # else we may run into problems when these warnings hit on the testing C
1913 # programs that autoconf wants to build.
1914 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1915
1916   case "$host" in
1917     *-*-openbsd* | *-*-bitrig*)
1918       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1919       # That's fine, except that the headers don't pass -Wredundant-decls.
1920       # Therefore, let's disable -Wsystem-headers when we're building
1921       # with maximal warnings on OpenBSD.
1922       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1923   esac
1924
1925   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1926   # have it work better.
1927   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1928
1929   # This warning was added in gcc 4.3, but it appears to generate
1930   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1931   #CFLAGS="$CFLAGS -Wlogical-op"
1932
1933   m4_foreach_w([warning_flag], [
1934      -Waddress
1935      -Waddress-of-array-temporary
1936      -Waddress-of-temporary
1937      -Wambiguous-macro
1938      -Wanonymous-pack-parens
1939      -Warc
1940      -Warc-abi
1941      -Warc-bridge-casts-disallowed-in-nonarc
1942      -Warc-maybe-repeated-use-of-weak
1943      -Warc-performSelector-leaks
1944      -Warc-repeated-use-of-weak
1945      -Warray-bounds
1946      -Warray-bounds-pointer-arithmetic
1947      -Wasm
1948      -Wasm-operand-widths
1949      -Watomic-properties
1950      -Watomic-property-with-user-defined-accessor
1951      -Wauto-import
1952      -Wauto-storage-class
1953      -Wauto-var-id
1954      -Wavailability
1955      -Wbackslash-newline-escape
1956      -Wbad-array-new-length
1957      -Wbind-to-temporary-copy
1958      -Wbitfield-constant-conversion
1959      -Wbool-conversion
1960      -Wbool-conversions
1961      -Wbuiltin-requires-header
1962      -Wchar-align
1963      -Wcompare-distinct-pointer-types
1964      -Wcomplex-component-init
1965      -Wconditional-type-mismatch
1966      -Wconfig-macros
1967      -Wconstant-conversion
1968      -Wconstant-logical-operand
1969      -Wconstexpr-not-const
1970      -Wcustom-atomic-properties
1971      -Wdangling-field
1972      -Wdangling-initializer-list
1973      -Wdate-time
1974      -Wdelegating-ctor-cycles
1975      -Wdeprecated-implementations
1976      -Wdeprecated-register
1977      -Wdirect-ivar-access
1978      -Wdiscard-qual
1979      -Wdistributed-object-modifiers
1980      -Wdivision-by-zero
1981      -Wdollar-in-identifier-extension
1982      -Wdouble-promotion
1983      -Wduplicate-decl-specifier
1984      -Wduplicate-enum
1985      -Wduplicate-method-arg
1986      -Wduplicate-method-match
1987      -Wduplicated-cond
1988      -Wdynamic-class-memaccess
1989      -Wembedded-directive
1990      -Wempty-translation-unit
1991      -Wenum-conversion
1992      -Wexit-time-destructors
1993      -Wexplicit-ownership-type
1994      -Wextern-initializer
1995      -Wextra
1996      -Wextra-semi
1997      -Wextra-tokens
1998      -Wflexible-array-extensions
1999      -Wfloat-conversion
2000      -Wformat-non-iso
2001      -Wfour-char-constants
2002      -Wgcc-compat
2003      -Wglobal-constructors
2004      -Wgnu-array-member-paren-init
2005      -Wgnu-designator
2006      -Wgnu-static-float-init
2007      -Wheader-guard
2008      -Wheader-hygiene
2009      -Widiomatic-parentheses
2010      -Wignored-attributes
2011      -Wimplicit-atomic-properties
2012      -Wimplicit-conversion-floating-point-to-bool
2013      -Wimplicit-exception-spec-mismatch
2014      -Wimplicit-fallthrough
2015      -Wimplicit-fallthrough-per-function
2016      -Wimplicit-retain-self
2017      -Wimport-preprocessor-directive-pedantic
2018      -Wincompatible-library-redeclaration
2019      -Wincompatible-pointer-types-discards-qualifiers
2020      -Wincomplete-implementation
2021      -Wincomplete-module
2022      -Wincomplete-umbrella
2023      -Winit-self
2024      -Wint-conversions
2025      -Wint-to-void-pointer-cast
2026      -Winteger-overflow
2027      -Winvalid-constexpr
2028      -Winvalid-iboutlet
2029      -Winvalid-noreturn
2030      -Winvalid-pp-token
2031      -Winvalid-source-encoding
2032      -Winvalid-token-paste
2033      -Wknr-promoted-parameter
2034      -Wlarge-by-value-copy
2035      -Wliteral-conversion
2036      -Wliteral-range
2037      -Wlocal-type-template-args
2038      -Wlogical-op
2039      -Wloop-analysis
2040      -Wmain-return-type
2041      -Wmalformed-warning-check
2042      -Wmethod-signatures
2043      -Wmicrosoft
2044      -Wmicrosoft-exists
2045      -Wmismatched-parameter-types
2046      -Wmismatched-return-types
2047      -Wmissing-field-initializers
2048      -Wmissing-format-attribute
2049      -Wmissing-noreturn
2050      -Wmissing-selector-name
2051      -Wmissing-sysroot
2052      -Wmissing-variable-declarations
2053      -Wmodule-conflict
2054      -Wnested-anon-types
2055      -Wnewline-eof
2056      -Wnon-literal-null-conversion
2057      -Wnon-pod-varargs
2058      -Wnonportable-cfstrings
2059      -Wnormalized=nfkc
2060      -Wnull-arithmetic
2061      -Wnull-character
2062      -Wnull-conversion
2063      -Wnull-dereference
2064      -Wout-of-line-declaration
2065      -Wover-aligned
2066      -Woverlength-strings
2067      -Woverride-init
2068      -Woverriding-method-mismatch
2069      -Wpointer-type-mismatch
2070      -Wpredefined-identifier-outside-function
2071      -Wprotocol-property-synthesis-ambiguity
2072      -Wreadonly-iboutlet-property
2073      -Wreadonly-setter-attrs
2074      -Wreceiver-expr
2075      -Wreceiver-forward-class
2076      -Wreceiver-is-weak
2077      -Wreinterpret-base-class
2078      -Wrequires-super-attribute
2079      -Wreserved-user-defined-literal
2080      -Wreturn-stack-address
2081      -Wsection
2082      -Wselector-type-mismatch
2083      -Wsentinel
2084      -Wserialized-diagnostics
2085      -Wshadow
2086      -Wshift-count-negative
2087      -Wshift-count-overflow
2088      -Wshift-negative-value
2089      -Wshift-overflow=2
2090      -Wshift-sign-overflow
2091      -Wshorten-64-to-32
2092      -Wsizeof-array-argument
2093      -Wsource-uses-openmp
2094      -Wstatic-float-init
2095      -Wstatic-in-inline
2096      -Wstatic-local-in-inline
2097      -Wstrict-overflow=1
2098      -Wstring-compare
2099      -Wstring-conversion
2100      -Wstrlcpy-strlcat-size
2101      -Wstrncat-size
2102      -Wsuggest-attribute=format
2103      -Wsuggest-attribute=noreturn
2104      -Wsuper-class-method-mismatch
2105      -Wswitch-bool
2106      -Wsync-nand
2107      -Wtautological-constant-out-of-range-compare
2108      -Wtentative-definition-incomplete-type
2109      -Wtrampolines
2110      -Wtype-safety
2111      -Wtypedef-redefinition
2112      -Wtypename-missing
2113      -Wundefined-inline
2114      -Wundefined-internal
2115      -Wundefined-reinterpret-cast
2116      -Wunicode
2117      -Wunicode-whitespace
2118      -Wunknown-warning-option
2119      -Wunnamed-type-template-args
2120      -Wunneeded-member-function
2121      -Wunsequenced
2122      -Wunsupported-visibility
2123      -Wunused-but-set-parameter
2124      -Wunused-but-set-variable
2125      -Wunused-command-line-argument
2126      -Wunused-const-variable=2
2127      -Wunused-exception-parameter
2128      -Wunused-local-typedefs
2129      -Wunused-member-function
2130      -Wunused-sanitize-argument
2131      -Wunused-volatile-lvalue
2132      -Wuser-defined-literals
2133      -Wvariadic-macros
2134      -Wvector-conversion
2135      -Wvector-conversions
2136      -Wvexing-parse
2137      -Wvisibility
2138      -Wvla-extension
2139      -Wzero-length-array
2140   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
2141
2142 dnl    We should re-enable this in some later version.  Clang doesn't
2143 dnl    mind, but it causes trouble with GCC.
2144 dnl     -Wstrict-overflow=2
2145
2146 dnl    These seem to require annotations that we don't currently use,
2147 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2148 dnl     -Wthread-safety
2149 dnl     -Wthread-safety-analysis
2150 dnl     -Wthread-safety-attributes
2151 dnl     -Wthread-safety-beta
2152 dnl     -Wthread-safety-precise
2153
2154   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2155   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2156   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2157   CFLAGS="$CFLAGS -Wwrite-strings"
2158   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2159   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
2160   CFLAGS="$CFLAGS -Wunused-parameter "
2161   # These interfere with building main() { return 0; }, which autoconf
2162   # likes to use as its default program.
2163   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
2164
2165   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2166     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2167   fi
2168   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2169     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2170   fi
2171
2172   if test "x$enable_fatal_warnings" = "xyes"; then
2173     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2174     # default autoconf programs are full of errors.
2175     CFLAGS="$CFLAGS -Werror"
2176   fi
2177
2178 fi
2179
2180 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2181    case "$host_os" in
2182     darwin*)
2183       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2184    esac
2185 fi
2186
2187 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2188
2189 AC_CONFIG_FILES([
2190         Doxyfile
2191         Makefile
2192         contrib/dist/suse/tor.sh
2193         contrib/operator-tools/tor.logrotate
2194         contrib/dist/tor.sh
2195         contrib/dist/torctl
2196         contrib/dist/tor.service
2197         src/config/torrc.sample
2198         src/config/torrc.minimal
2199         src/rust/.cargo/config
2200         scripts/maint/checkOptionDocs.pl
2201         scripts/maint/updateVersions.pl
2202 ])
2203
2204 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2205   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2206   for file in $regular_mans ; do
2207     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2208       echo "==================================";
2209       echo;
2210       echo "Building Tor has failed since manpages cannot be built.";
2211       echo;
2212       echo "You need asciidoc installed to be able to build the manpages.";
2213       echo "To build without manpages, use the --disable-asciidoc argument";
2214       echo "when calling configure.";
2215       echo;
2216       echo "==================================";
2217       exit 1;
2218     fi
2219   done
2220 fi
2221
2222 if test "$fragile_hardening" = "yes"; then
2223   AC_MSG_WARN([
2224
2225 ============
2226 Warning!  Building Tor with --enable-fragile-hardening (also known as
2227 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2228 other kinds of attacks easier. A Tor instance build with this option will be
2229 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2230 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2231 denial of service attacks. For more information, see
2232 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2233 ============
2234   ])
2235 fi
2236
2237 AC_OUTPUT