configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.0.26-rc-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45
  46
  47 if test x$enable_cell_pool != xno; then
  48   AC_DEFINE(ENABLE_CELL_POOL, 1,
  49             [Defined if we try to use the pool allocator for queued cells])
  50 fi
  51 if test x$enable_buf_freelists != xno; then
  52   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  53             [Defined if we try to use freelists for buffer RAM chunks])
  54 fi
  55 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  56
  57 AC_ARG_ENABLE(transparent,
  58      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  59      [case "${enableval}" in
  60         yes) transparent=true ;;
  61         no)  transparent=false ;;
  62         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  63       esac], [transparent=true])
  64
  65 AC_ARG_ENABLE(threads,
  66      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  67
  68 if test x$enable_threads = x; then
  69    case $host in
  70     *-*-solaris* )
  71      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  72      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  73 cpu workers lock up here, so I will disable threads.])
  74      enable_threads="no";;
  75     *)
  76      enable_threads="yes";;
  77    esac
  78 fi
  79
  80 if test "$enable_threads" = "yes"; then
  81   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  82 fi
  83
  84 case $host in
  85    *-*-solaris* )
  86      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  87      ;;
  88 esac
  89
  90 AC_ARG_ENABLE(gcc-warnings,
  91      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  92
  93 AC_PROG_CC
  94 AC_PROG_CPP
  95 AC_PROG_MAKE_SET
  96 AC_PROG_RANLIB
  97
  98 TORUSER=_tor
  99 AC_ARG_WITH(tor-user,
 100         [  --with-tor-user=NAME    Specify username for tor daemon ],
 101         [
 102            TORUSER=$withval
 103         ]
 104 )
 105 AC_SUBST(TORUSER)
 106
 107 TORGROUP=_tor
 108 AC_ARG_WITH(tor-group,
 109         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 110         [
 111            TORGROUP=$withval
 112         ]
 113 )
 114 AC_SUBST(TORGROUP)
 115
 116
 117 dnl If WIN32 is defined and non-zero, we are building for win32
 118 AC_MSG_CHECKING([for win32])
 119 AC_RUN_IFELSE([
 120 int main(int c, char **v) {
 121 #ifdef WIN32
 122 #if WIN32
 123   return 0;
 124 #else
 125   return 1;
 126 #endif
 127 #else
 128   return 2;
 129 #endif
 130 }],
 131 bwin32=true; AC_MSG_RESULT([yes]),
 132 bwin32=false; AC_MSG_RESULT([no]),
 133 bwin32=cross; AC_MSG_RESULT([cross])
 134 )
 135
 136 if test "$bwin32" = cross; then
 137 AC_MSG_CHECKING([for win32 (cross)])
 138 AC_COMPILE_IFELSE([
 139 #ifdef WIN32
 140 int main(int c, char **v) {return 0;}
 141 #else
 142 #error
 143 int main(int c, char **v) {return x(y);}
 144 #endif
 145 ],
 146 bwin32=true; AC_MSG_RESULT([yes]),
 147 bwin32=false; AC_MSG_RESULT([no]))
 148 fi
 149
 150 if test "$bwin32" = true; then
 151 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 152 fi
 153 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 154
 155 dnl Enable C99 when compiling with MIPSpro
 156 AC_MSG_CHECKING([for MIPSpro compiler])
 157 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 158 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 159 #error
 160   return x(y);
 161 #endif
 162 ]),
 163 bmipspro=false; AC_MSG_RESULT(no),
 164 bmipspro=true; AC_MSG_RESULT(yes))
 165
 166 if test "$bmipspro" = true; then
 167   CFLAGS="$CFLAGS -c99"
 168 fi
 169
 170 AC_C_BIGENDIAN
 171
 172 AC_SEARCH_LIBS(socket, [socket])
 173 AC_SEARCH_LIBS(gethostbyname, [nsl])
 174 AC_SEARCH_LIBS(dlopen, [dl])
 175 AC_SEARCH_LIBS(inet_aton, [resolv])
 176
 177 if test "$enable_threads" = "yes"; then
 178   AC_SEARCH_LIBS(pthread_create, [pthread])
 179   AC_SEARCH_LIBS(pthread_detach, [pthread])
 180 fi
 181
 182 dnl -------------------------------------------------------------------
 183 dnl Check for functions before libevent, since libevent-1.2 apparently
 184 dnl exports strlcpy without defining it in a header.
 185
 186 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop)
 187
 188 using_custom_malloc=no
 189 if test x$enable_openbsd_malloc = xyes ; then
 190    using_custom_malloc=yes
 191 fi
 192 if test x$tcmalloc = xyes ; then
 193    using_custom_malloc=yes
 194 fi
 195 if test $using_custom_malloc = no ; then
 196    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 197 fi
 198
 199 if test "$enable_threads" = "yes"; then
 200   AC_CHECK_HEADERS(pthread.h)
 201   AC_CHECK_FUNCS(pthread_create)
 202 fi
 203
 204 dnl ------------------------------------------------------
 205 dnl Where do you live, libevent?  And how do we call you?
 206
 207 if test "$bwin32" = true; then
 208   TOR_LIB_WS32=-lws2_32
 209   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 210   # think it's actually necessary.
 211   TOR_LIB_GDI=-lgdi32
 212 else
 213   TOR_LIB_WS32=
 214   TOR_LIB_GDI=
 215 fi
 216 AC_SUBST(TOR_LIB_WS32)
 217 AC_SUBST(TOR_LIB_GDI)
 218
 219 dnl We need to do this before we try our disgusting hack below.
 220 AC_CHECK_HEADERS([sys/types.h])
 221
 222 dnl This is a disgusting hack so we safely include older libevent headers.
 223 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 224 AC_CHECK_TYPE(u_int32_t, unsigned long)
 225 AC_CHECK_TYPE(u_int16_t, unsigned short)
 226 AC_CHECK_TYPE(u_int8_t, unsigned char)
 227
 228 tor_libevent_pkg_redhat="libevent"
 229 tor_libevent_pkg_debian="libevent-dev"
 230 tor_libevent_devpkg_redhat="libevent-devel"
 231 tor_libevent_devpkg_debian="libevent-dev"
 232
 233 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 234 #ifdef WIN32
 235 #include <winsock2.h>
 236 #endif
 237 #include <stdlib.h>
 238 #include <sys/time.h>
 239 #include <sys/types.h>
 240 #include <event.h>], [void exit(int); void *event_init(void);],
 241     [
 242 #ifdef WIN32
 243 {WSAData d; WSAStartup(0x101,&d); }
 244 #endif
 245 event_init(); exit(0);
 246 ], [--with-libevent-dir], [/opt/libevent])
 247
 248 dnl Now check for particular libevent functions.
 249 save_LIBS="$LIBS"
 250 save_LDFLAGS="$LDFLAGS"
 251 save_CPPFLAGS="$CPPFLAGS"
 252 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 253 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 254 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 255 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 256 LIBS="$save_LIBS"
 257 LDFLAGS="$save_LDFLAGS"
 258 CPPFLAGS="$save_CPPFLAGS"
 259
 260 dnl ------------------------------------------------------
 261 dnl Where do you live, openssl?  And how do we call you?
 262
 263 tor_openssl_pkg_redhat="openssl"
 264 tor_openssl_pkg_debian="libssl"
 265 tor_openssl_devpkg_redhat="openssl-devel"
 266 tor_openssl_devpkg_debian="libssl-dev"
 267
 268 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 269     [#include <openssl/rand.h>],
 270     [void RAND_add(const void *buf, int num, double entropy);],
 271     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 272     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 273
 274 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 275
 276 dnl ------------------------------------------------------
 277 dnl Where do you live, zlib?  And how do we call you?
 278
 279 tor_openssl_pkg_redhat="zlib"
 280 tor_openssl_pkg_debian="zlib1g"
 281 tor_openssl_devpkg_redhat="zlib-devel"
 282 tor_openssl_devpkg_debian="zlib1g-dev"
 283
 284 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 285     [#include <zlib.h>],
 286     [const char * zlibVersion(void);],
 287     [zlibVersion(); exit(0);], [--with-zlib-dir],
 288     [/opt/zlib])
 289
 290 dnl Make sure to enable support for large off_t if available.
 291
 292 AC_SYS_LARGEFILE
 293
 294 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 295
 296 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 297
 298 dnl These headers are not essential
 299
 300 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 301
 302 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 303 [#ifdef HAVE_MALLOC_H
 304 #include <malloc.h>
 305 #endif
 306 #ifdef HAVE_MALLOC_MALLOC_H
 307 #include <malloc/malloc.h>
 308 #endif])
 309
 310 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 311 [#ifdef HAVE_SYS_TYPES_H
 312 #include <sys/types.h>
 313 #endif
 314 #ifdef HAVE_SYS_SOCKET_H
 315 #include <sys/socket.h>
 316 #endif])
 317 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 318 [#ifdef HAVE_SYS_TYPES_H
 319 #include <sys/types.h>
 320 #endif
 321 #ifdef HAVE_SYS_SOCKET_H
 322 #include <sys/socket.h>
 323 #endif
 324 #ifdef HAVE_NET_IF_H
 325 #include <net/if.h>
 326 #endif])
 327 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 328         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 329 [#ifdef HAVE_SYS_TYPES_H
 330 #include <sys/types.h>
 331 #endif
 332 #ifdef HAVE_SYS_SOCKET_H
 333 #include <sys/socket.h>
 334 #endif])
 335
 336 if test x$transparent = xtrue ; then
 337    transparent_ok=0
 338    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 339      transparent_ok=1
 340    fi
 341    if test x$linux_netfilter_ipv4 = x1 ; then
 342      transparent_ok=1
 343    fi
 344    if test x$transparent_ok = x1 ; then
 345      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 346      case $host in
 347        *-*-openbsd*)
 348          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 349      esac
 350    else
 351      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 352    fi
 353 fi
 354
 355 AC_FUNC_FSEEKO
 356
 357 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 358 [#ifdef HAVE_SYS_TYPES_H
 359 #include <sys/types.h>
 360 #endif
 361 #ifdef HAVE_SYS_TIME_H
 362 #include <sys/time.h>
 363 #endif])
 364
 365 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 366 dnl Watch out.
 367
 368 AC_CHECK_SIZEOF(int8_t)
 369 AC_CHECK_SIZEOF(int16_t)
 370 AC_CHECK_SIZEOF(int32_t)
 371 AC_CHECK_SIZEOF(int64_t)
 372 AC_CHECK_SIZEOF(uint8_t)
 373 AC_CHECK_SIZEOF(uint16_t)
 374 AC_CHECK_SIZEOF(uint32_t)
 375 AC_CHECK_SIZEOF(uint64_t)
 376 AC_CHECK_SIZEOF(intptr_t)
 377 AC_CHECK_SIZEOF(uintptr_t)
 378
 379 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 380
 381 AC_CHECK_SIZEOF(char)
 382 AC_CHECK_SIZEOF(short)
 383 AC_CHECK_SIZEOF(int)
 384 AC_CHECK_SIZEOF(long)
 385 AC_CHECK_SIZEOF(long long)
 386 AC_CHECK_SIZEOF(__int64)
 387 AC_CHECK_SIZEOF(void *)
 388 AC_CHECK_SIZEOF(time_t)
 389 AC_CHECK_SIZEOF(size_t)
 390
 391 AC_CHECK_TYPES([uint, u_char, ssize_t])
 392
 393 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 394 [#ifdef HAVE_SYS_TYPES_H
 395 #include <sys/types.h>
 396 #endif
 397 #ifdef HAVE_NETINET_IN_H
 398 #include <netinet/in.h>
 399 #endif
 400 #ifdef HAVE_NETINET_IN6_H
 401 #include <netinet/in6.h>
 402 #endif
 403 #ifdef HAVE_SYS_SOCKET_H
 404 #include <sys/socket.h>
 405 #endif
 406 #ifdef MS_WINDOWS
 407 #define WIN32_WINNT 0x400
 408 #define _WIN32_WINNT 0x400
 409 #define WIN32_LEAN_AND_MEAN
 410 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 411 #include <winsock.h>
 412 #else
 413 #include <winsock2.h>
 414 #include <ws2tcpip.h>
 415 #endif
 416 #endif
 417 ])
 418 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 419 [#ifdef HAVE_SYS_TYPES_H
 420 #include <sys/types.h>
 421 #endif
 422 #ifdef HAVE_NETINET_IN_H
 423 #include <netinet/in.h>
 424 #endif
 425 #ifdef HAVE_NETINET_IN6_H
 426 #include <netinet/in6.h>
 427 #endif
 428 #ifdef HAVE_SYS_SOCKET_H
 429 #include <sys/socket.h>
 430 #endif
 431 #ifdef MS_WINDOWS
 432 #define WIN32_WINNT 0x400
 433 #define _WIN32_WINNT 0x400
 434 #define WIN32_LEAN_AND_MEAN
 435 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 436 #include <winsock.h>
 437 #else
 438 #include <winsock2.h>
 439 #include <ws2tcpip.h>
 440 #endif
 441 #endif
 442 ])
 443
 444 AC_CHECK_TYPES([rlim_t], , ,
 445 [#ifdef HAVE_SYS_TYPES_H
 446 #include <sys/types.h>
 447 #endif
 448 #ifdef HAVE_SYS_TIME_H
 449 #include <sys/time.h>
 450 #endif
 451 #ifdef HAVE_SYS_RESOURCE_H
 452 #include <sys/resource.h>
 453 #endif
 454 ])
 455
 456 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 457 AC_RUN_IFELSE(AC_LANG_SOURCE([
 458 #ifdef HAVE_SYS_TYPES_H
 459 #include <sys/types.h>
 460 #endif
 461 #ifdef HAVE_SYS_TIME_H
 462 #include <sys/time.h>
 463 #endif
 464 #ifdef HAVE_TIME_H
 465 #include <time.h>
 466 #endif
 467 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 468   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 469 ])
 470
 471 if test "$tor_cv_time_t_signed" = cross; then
 472   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 473 fi
 474
 475 if test "$tor_cv_time_t_signed" != no; then
 476   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 477             [Define to 1 iff time_t is signed])
 478 fi
 479
 480 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 481 #ifdef HAVE_SYS_SOCKET_H
 482 #include <sys/socket.h>
 483 #endif
 484 ])
 485
 486 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 487
 488 AC_CHECK_SIZEOF(cell_t)
 489
 490 # Now make sure that NULL can be represented as zero bytes.
 491 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 492 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 493 [[#include <stdlib.h>
 494 #include <string.h>
 495 #include <stdio.h>
 496 #ifdef HAVE_STDDEF_H
 497 #include <stddef.h>
 498 #endif
 499 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 500 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 501        [tor_cv_null_is_zero=yes],
 502        [tor_cv_null_is_zero=no],
 503        [tor_cv_null_is_zero=cross])])
 504
 505 if test "$tor_cv_null_is_zero" = cross ; then
 506   # Cross-compiling; let's hope that the target isn't raving mad.
 507   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 508 fi
 509
 510 if test "$tor_cv_null_is_zero" != no; then
 511   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 512             [Define to 1 iff memset(0) sets pointers to NULL])
 513 fi
 514
 515 # And what happens when we malloc zero?
 516 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 517 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 518 [[#include <stdlib.h>
 519 #include <string.h>
 520 #include <stdio.h>
 521 #ifdef HAVE_STDDEF_H
 522 #include <stddef.h>
 523 #endif
 524 int main () { return malloc(0)?0:1; }]])],
 525        [tor_cv_malloc_zero_works=yes],
 526        [tor_cv_malloc_zero_works=no],
 527        [tor_cv_malloc_zero_works=cross])])
 528
 529 if test "$tor_cv_malloc_zero_works" = cross; then
 530   # Cross-compiling; let's hope that the target isn't raving mad.
 531   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 532 fi
 533
 534 if test "$tor_cv_malloc_zero_works" = yes; then
 535   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 536             [Define to 1 iff malloc(0) returns a pointer])
 537 fi
 538
 539 # whether we seem to be in a 2s-complement world.
 540 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 541 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 542 [[int main () { int problem = ((-99) != (~99)+1);
 543 return problem ? 1 : 0; }]])],
 544        [tor_cv_twos_complement=yes],
 545        [tor_cv_twos_complement=no],
 546        [tor_cv_twos_complement=cross])])
 547
 548 if test "$tor_cv_twos_complement" = cross ; then
 549   # Cross-compiling; let's hope that the target isn't raving mad.
 550   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 551 fi
 552
 553 if test "$tor_cv_twos_complement" != no ; then
 554   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 555             [Define to 1 iff we represent negative integers with two's complement])
 556 fi
 557
 558 # Whether we should use the dmalloc memory allocation debugging library.
 559 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 560 AC_ARG_WITH(dmalloc,
 561 [  --with-dmalloc          Use debug memory allocation library. ],
 562 [if [[ "$withval" = "yes" ]]; then
 563   dmalloc=1
 564   AC_MSG_RESULT(yes)
 565 else
 566   dmalloc=1
 567   AC_MSG_RESULT(no)
 568 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 569 )
 570
 571 if [[ $dmalloc -eq 1 ]]; then
 572   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 573   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 574   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 575   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 576   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 577 fi
 578
 579 AC_ARG_WITH(tcmalloc,
 580 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 581 [ tcmalloc=yes ], [ tcmalloc=no ])
 582
 583 if test x$tcmalloc = xyes ; then
 584    LDFLAGS="-ltcmalloc $LDFLAGS"
 585 fi
 586
 587 # Allow user to specify an alternate syslog facility
 588 AC_ARG_WITH(syslog-facility,
 589 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 590 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 591 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 592 AC_SUBST(LOGFACILITY)
 593
 594 # Check for gethostbyname_r in all its glorious incompatible versions.
 595 #   (This logic is based on that in Python's configure.in)
 596 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 597   [Define this if you have any gethostbyname_r()])
 598
 599 AC_CHECK_FUNC(gethostbyname_r, [
 600   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 601   OLD_CFLAGS=$CFLAGS
 602   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 603   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 604 #include <netdb.h>
 605   ], [[
 606     char *cp1, *cp2;
 607     struct hostent *h1, *h2;
 608     int i1, i2;
 609     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 610   ]]),[
 611     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 612     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 613      [Define this if gethostbyname_r takes 6 arguments])
 614     AC_MSG_RESULT(6)
 615   ], [
 616     AC_TRY_COMPILE([
 617 #include <netdb.h>
 618     ], [
 619       char *cp1, *cp2;
 620       struct hostent *h1;
 621       int i1, i2;
 622       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 623     ], [
 624       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 625       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 626         [Define this if gethostbyname_r takes 5 arguments])
 627       AC_MSG_RESULT(5)
 628    ], [
 629       AC_TRY_COMPILE([
 630 #include <netdb.h>
 631      ], [
 632        char *cp1;
 633        struct hostent *h1;
 634        struct hostent_data hd;
 635        (void) gethostbyname_r(cp1,h1,&hd);
 636      ], [
 637        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 638        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 639          [Define this if gethostbyname_r takes 3 arguments])
 640        AC_MSG_RESULT(3)
 641      ], [
 642        AC_MSG_RESULT(0)
 643      ])
 644   ])
 645  ])
 646  CFLAGS=$OLD_CFLAGS
 647 ])
 648
 649 AC_CACHE_CHECK([whether the C compiler supports __func__],
 650   tor_cv_have_func_macro,
 651   AC_COMPILE_IFELSE([
 652 #include <stdio.h>
 653 int main(int c, char **v) { puts(__func__); }],
 654   tor_cv_have_func_macro=yes,
 655   tor_cv_have_func_macro=no))
 656
 657 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 658   tor_cv_have_FUNC_macro,
 659   AC_COMPILE_IFELSE([
 660 #include <stdio.h>
 661 int main(int c, char **v) { puts(__FUNC__); }],
 662   tor_cv_have_FUNC_macro=yes,
 663   tor_cv_have_FUNC_macro=no))
 664
 665 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 666   tor_cv_have_FUNCTION_macro,
 667   AC_COMPILE_IFELSE([
 668 #include <stdio.h>
 669 int main(int c, char **v) { puts(__FUNCTION__); }],
 670   tor_cv_have_FUNCTION_macro=yes,
 671   tor_cv_have_FUNCTION_macro=no))
 672
 673 if test "$tor_cv_have_func_macro" = 'yes'; then
 674   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 675 fi
 676
 677 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 678   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 679 fi
 680
 681 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 682   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 683            [Defined if the compiler supports __FUNCTION__])
 684 fi
 685
 686 # $prefix stores the value of the --prefix command line option, or
 687 # NONE if the option wasn't set.  In the case that it wasn't set, make
 688 # it be the default, so that we can use it to expand directories now.
 689 if test "x$prefix" = "xNONE"; then
 690   prefix=$ac_default_prefix
 691 fi
 692
 693 # and similarly for $exec_prefix
 694 if test "x$exec_prefix" = "xNONE"; then
 695   exec_prefix=$prefix
 696 fi
 697
 698 if test "x$CONFDIR" = "x"; then
 699   CONFDIR=`eval echo $sysconfdir/tor`
 700 fi
 701 AC_SUBST(CONFDIR)
 702 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 703 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 704
 705 BINDIR=`eval echo $bindir`
 706 AC_SUBST(BINDIR)
 707 LOCALSTATEDIR=`eval echo $localstatedir`
 708 AC_SUBST(LOCALSTATEDIR)
 709
 710 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 711 # than autoconf's macros like.
 712 if test "$ac_cv_c_compiler_gnu" = yes; then
 713   CFLAGS="$CFLAGS -Wall -g -O2"
 714 else
 715   CFLAGS="$CFLAGS -g -O"
 716   enable_gcc_warnings=no
 717 fi
 718
 719 # Add some more warnings which we use in development but not in the
 720 # released versions.  (Some relevant gcc versions can't handle these.)
 721 if test x$enable_gcc_warnings = xyes; then
 722
 723   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 724 #if !defined(__GNUC__) || (__GNUC__ < 4)
 725 #error
 726 #endif]), have_gcc4=yes, have_gcc4=no)
 727
 728   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 729 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 730 #error
 731 #endif]), have_gcc42=yes, have_gcc42=no)
 732
 733   save_CFLAGS="$CFLAGS"
 734   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 735   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 736                     have_shorten64_flag=no)
 737   CFLAGS="$save_CFLAGS"
 738
 739   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 740   # Disabled, so we can use mallinfo(): -Waggregate-return
 741
 742   if test x$have_gcc4 = xyes ; then
 743     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 744     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 745   fi
 746
 747   if test x$have_gcc42 = xyes ; then
 748     # These warnings break gcc 4.0.2 and work on gcc 4.2
 749     # XXXX020 Use -fstack-protector.
 750     # XXXX020 See if any of these work with earlier versions.
 751     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 752   fi
 753
 754   if test x$have_shorten64_flag = xyes ; then
 755     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 756   fi
 757
 758 ##This will break the world on some 64-bit architectures
 759 # CFLAGS="$CFLAGS -Winline"
 760 fi
 761
 762
 763
 764 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 765
 766 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 767 AC_OUTPUT
 768
 769 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 770   ./contrib/updateVersions.pl
 771 fi
 772