configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.19-alpha)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  23 AC_ARG_ENABLE(buf-freelists,
  24    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  25 AC_ARG_ENABLE(openbsd-malloc,
  26    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  27 AC_ARG_ENABLE(instrument-downloads,
  28    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  29 AC_ARG_ENABLE(static-openssl,
  30    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  31 AC_ARG_ENABLE(static-libevent,
  32    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  33 AC_ARG_ENABLE(static-zlib,
  34    AS_HELP_STRING(--enable-static-zlib, Link against a static zlib library. Requires --with-zlib-dir))
  35
  36 if test x$enable_buf_freelists != xno; then
  37   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  38             [Defined if we try to use freelists for buffer RAM chunks])
  39 fi
  40 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  41 if test x$enable_instrument_downloads = xyes; then
  42   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  43             [Defined if we want to keep track of how much of each kind of resource we download.])
  44 fi
  45
  46 AC_ARG_ENABLE(transparent,
  47      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  48      [case "${enableval}" in
  49         yes) transparent=true ;;
  50         no)  transparent=false ;;
  51         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  52       esac], [transparent=true])
  53
  54 AC_ARG_ENABLE(asciidoc,
  55      AS_HELP_STRING(--disable-asciidoc, don't use asciidoc (disables building of manpages)),
  56      [case "${enableval}" in
  57         yes) asciidoc=true ;;
  58         no)  asciidoc=false ;;
  59         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  60       esac], [asciidoc=true])
  61
  62
  63 AC_ARG_ENABLE(threads,
  64      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  65
  66 if test x$enable_threads = x; then
  67    case $host in
  68     *-*-solaris* )
  69      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  70      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  71 cpu workers lock up here, so I will disable threads.])
  72      enable_threads="no";;
  73     *)
  74      enable_threads="yes";;
  75    esac
  76 fi
  77
  78 if test "$enable_threads" = "yes"; then
  79   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  80 fi
  81
  82 case $host in
  83    *-*-solaris* )
  84      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  85      ;;
  86 esac
  87
  88 AC_ARG_ENABLE(gcc-warnings,
  89      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  90 AC_ARG_ENABLE(gcc-warnings-advisory,
  91      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
  92
  93 dnl Adam shostack suggests the following for Windows:
  94 dnl -D_FORTIFY_SOURCE=2 -fstack-protector-all
  95 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
  96 dnl This requires that we use gcc and that we add -O2 to the CFLAGS.
  97 AC_ARG_ENABLE(gcc-hardening,
  98      AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
  99 [if test x$enableval = xyes; then
 100     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 101     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 102     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 103     LDFLAGS="$LDFLAGS -pie"
 104 fi])
 105
 106 dnl Linker hardening options
 107 dnl Currently these options are ELF specific - you can't use this with MacOSX
 108 AC_ARG_ENABLE(linker-hardening,
 109         AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 110 [if test x$enableval = xyes; then
 111     LDFLAGS="$LDFLAGS -z relro -z now"
 112 fi])
 113
 114 AC_ARG_ENABLE(local-appdata,
 115    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 116 if test "$enable_local_appdata" = "yes"; then
 117   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 118             [Defined if we default to host local appdata paths on Windows])
 119 fi
 120
 121 dnl check for the correct "ar" when cross-compiling
 122 AN_MAKEVAR([AR], [AC_PROG_AR])
 123 AN_PROGRAM([ar], [AC_PROG_AR])
 124 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
 125 AC_PROG_AR
 126
 127 AC_PROG_CC
 128 AC_PROG_CPP
 129 AC_PROG_MAKE_SET
 130 AC_PROG_RANLIB
 131
 132 dnl autoconf 2.59 appears not to support AC_PROG_SED
 133 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 134
 135 dnl check for asciidoc and a2x
 136 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 137 AC_PATH_PROG([A2X], [a2x], none)
 138
 139 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 140
 141 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 142 AC_PATH_PROG([OPENSSL], [openssl], none)
 143
 144 TORUSER=_tor
 145 AC_ARG_WITH(tor-user,
 146         [  --with-tor-user=NAME    Specify username for tor daemon ],
 147         [
 148            TORUSER=$withval
 149         ]
 150 )
 151 AC_SUBST(TORUSER)
 152
 153 TORGROUP=_tor
 154 AC_ARG_WITH(tor-group,
 155         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 156         [
 157            TORGROUP=$withval
 158         ]
 159 )
 160 AC_SUBST(TORGROUP)
 161
 162
 163 dnl If WIN32 is defined and non-zero, we are building for win32
 164 AC_MSG_CHECKING([for win32])
 165 AC_RUN_IFELSE([AC_LANG_SOURCE([
 166 int main(int c, char **v) {
 167 #ifdef WIN32
 168 #if WIN32
 169   return 0;
 170 #else
 171   return 1;
 172 #endif
 173 #else
 174   return 2;
 175 #endif
 176 }])],
 177 bwin32=true; AC_MSG_RESULT([yes]),
 178 bwin32=false; AC_MSG_RESULT([no]),
 179 bwin32=cross; AC_MSG_RESULT([cross])
 180 )
 181
 182 if test "$bwin32" = cross; then
 183 AC_MSG_CHECKING([for win32 (cross)])
 184 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 185 #ifdef WIN32
 186 int main(int c, char **v) {return 0;}
 187 #else
 188 #error
 189 int main(int c, char **v) {return x(y);}
 190 #endif
 191 ])],
 192 bwin32=true; AC_MSG_RESULT([yes]),
 193 bwin32=false; AC_MSG_RESULT([no]))
 194 fi
 195
 196 if test "$bwin32" = true; then
 197 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 198 fi
 199 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 200
 201 dnl Enable C99 when compiling with MIPSpro
 202 AC_MSG_CHECKING([for MIPSpro compiler])
 203 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 204 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 205 #error
 206   return x(y);
 207 #endif
 208 ])],
 209 bmipspro=false; AC_MSG_RESULT(no),
 210 bmipspro=true; AC_MSG_RESULT(yes))
 211
 212 if test "$bmipspro" = true; then
 213   CFLAGS="$CFLAGS -c99"
 214 fi
 215
 216 AC_C_BIGENDIAN
 217
 218 AC_SEARCH_LIBS(socket, [socket])
 219 AC_SEARCH_LIBS(gethostbyname, [nsl])
 220 AC_SEARCH_LIBS(dlopen, [dl])
 221 AC_SEARCH_LIBS(inet_aton, [resolv])
 222
 223 if test "$enable_threads" = "yes"; then
 224   AC_SEARCH_LIBS(pthread_create, [pthread])
 225   AC_SEARCH_LIBS(pthread_detach, [pthread])
 226 fi
 227
 228 dnl -------------------------------------------------------------------
 229 dnl Check for functions before libevent, since libevent-1.2 apparently
 230 dnl exports strlcpy without defining it in a header.
 231
 232 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl vasprintf lround rint)
 233
 234 using_custom_malloc=no
 235 if test x$enable_openbsd_malloc = xyes ; then
 236    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 237    using_custom_malloc=yes
 238 fi
 239 if test x$tcmalloc = xyes ; then
 240    using_custom_malloc=yes
 241 fi
 242 if test $using_custom_malloc = no ; then
 243    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 244 fi
 245
 246 if test "$enable_threads" = "yes"; then
 247   AC_CHECK_HEADERS(pthread.h)
 248   AC_CHECK_FUNCS(pthread_create)
 249 fi
 250
 251 dnl ------------------------------------------------------
 252 dnl Where do you live, libevent?  And how do we call you?
 253
 254 if test "$bwin32" = true; then
 255   TOR_LIB_WS32=-lws2_32
 256   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 257   # think it's actually necessary.
 258   TOR_LIB_GDI=-lgdi32
 259 else
 260   TOR_LIB_WS32=
 261   TOR_LIB_GDI=
 262 fi
 263 AC_SUBST(TOR_LIB_WS32)
 264 AC_SUBST(TOR_LIB_GDI)
 265
 266 dnl We need to do this before we try our disgusting hack below.
 267 AC_CHECK_HEADERS([sys/types.h])
 268
 269 dnl This is a disgusting hack so we safely include older libevent headers.
 270 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 271 AC_CHECK_TYPE(u_int32_t, unsigned long)
 272 AC_CHECK_TYPE(u_int16_t, unsigned short)
 273 AC_CHECK_TYPE(u_int8_t, unsigned char)
 274
 275 tor_libevent_pkg_redhat="libevent"
 276 tor_libevent_pkg_debian="libevent-dev"
 277 tor_libevent_devpkg_redhat="libevent-devel"
 278 tor_libevent_devpkg_debian="libevent-dev"
 279
 280 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 281 dnl linking for static builds.
 282 STATIC_LIBEVENT_FLAGS=""
 283 if test "$enable_static_libevent" = "yes"; then
 284     dnl Determine if we have clock_gettime in librt
 285     AC_SEARCH_LIBS([clock_gettime], [rt],
 286         [have_rt=yes])
 287     if test "$have_rt" = yes; then
 288       STATIC_LIBEVENT_FLAGS=" -lrt "
 289     fi
 290 fi
 291
 292 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 293 #ifdef WIN32
 294 #include <winsock2.h>
 295 #endif
 296 #include <stdlib.h>
 297 #include <sys/time.h>
 298 #include <sys/types.h>
 299 #include <event.h>], [
 300 #ifdef WIN32
 301 #include <winsock2.h>
 302 #endif
 303 void exit(int); void *event_init(void);],
 304     [
 305 #ifdef WIN32
 306 {WSADATA d; WSAStartup(0x101,&d); }
 307 #endif
 308 event_init(); exit(0);
 309 ], [--with-libevent-dir], [/opt/libevent])
 310
 311 dnl Now check for particular libevent functions.
 312 save_LIBS="$LIBS"
 313 save_LDFLAGS="$LDFLAGS"
 314 save_CPPFLAGS="$CPPFLAGS"
 315 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
 316 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 317 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 318 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 319 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 320 [#include <event.h>
 321 ])
 322
 323 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 324
 325 LIBS="$save_LIBS"
 326 LDFLAGS="$save_LDFLAGS"
 327 CPPFLAGS="$save_CPPFLAGS"
 328
 329
 330 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 331
 332 if test "$enable_static_libevent" = "yes"; then
 333    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 334      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 335    else
 336      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 337    fi
 338 else
 339      TOR_LIBEVENT_LIBS="-levent"
 340 fi
 341 AC_SUBST(TOR_LIBEVENT_LIBS)
 342
 343
 344 dnl ------------------------------------------------------
 345 dnl Where do you live, openssl?  And how do we call you?
 346
 347 tor_openssl_pkg_redhat="openssl"
 348 tor_openssl_pkg_debian="libssl"
 349 tor_openssl_devpkg_redhat="openssl-devel"
 350 tor_openssl_devpkg_debian="libssl-dev"
 351
 352 ALT_openssl_WITHVAL=""
 353 AC_ARG_WITH(ssl-dir,
 354   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 355   [
 356       if test "x$withval" != xno && test "x$withval" != "x" ; then
 357          ALT_openssl_WITHVAL="$withval"
 358       fi
 359   ])
 360
 361 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 362     [#include <openssl/rand.h>],
 363     [void RAND_add(const void *buf, int num, double entropy);],
 364     [RAND_add((void*)0,0,0); exit(0);], [],
 365     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 366
 367 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 368
 369 echo "tor_cv_library_openssl_dir is $tor_cv_library_openssl_dir"
 370 if test "$enable_static_openssl" = "yes"; then
 371    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 372      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 373    else
 374      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 375    fi
 376 else
 377      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 378 fi
 379 AC_SUBST(TOR_OPENSSL_LIBS)
 380
 381 dnl ------------------------------------------------------
 382 dnl Where do you live, zlib?  And how do we call you?
 383
 384 tor_zlib_pkg_redhat="zlib"
 385 tor_zlib_pkg_debian="zlib1g"
 386 tor_zlib_devpkg_redhat="zlib-devel"
 387 tor_zlib_devpkg_debian="zlib1g-dev"
 388
 389 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 390     [#include <zlib.h>],
 391     [const char * zlibVersion(void);],
 392     [zlibVersion(); exit(0);], [--with-zlib-dir],
 393     [/opt/zlib])
 394
 395 if test "$enable_static_zlib" = "yes"; then
 396    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 397      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 398  using --enable-static-zlib")
 399    else
 400      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 401      echo "$TOR_LIBDIR_zlib/libz.a"
 402    fi
 403 else
 404      TOR_ZLIB_LIBS="-lz"
 405 fi
 406 AC_SUBST(TOR_ZLIB_LIBS)
 407
 408 dnl Make sure to enable support for large off_t if available.
 409
 410 AC_SYS_LARGEFILE
 411
 412 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 413
 414 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 415
 416 dnl These headers are not essential
 417
 418 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 419
 420 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 421 [#ifdef HAVE_MALLOC_H
 422 #include <malloc.h>
 423 #endif
 424 #ifdef HAVE_MALLOC_MALLOC_H
 425 #include <malloc/malloc.h>
 426 #endif])
 427
 428 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 429 [#ifdef HAVE_SYS_TYPES_H
 430 #include <sys/types.h>
 431 #endif
 432 #ifdef HAVE_SYS_SOCKET_H
 433 #include <sys/socket.h>
 434 #endif])
 435 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 436 [#ifdef HAVE_SYS_TYPES_H
 437 #include <sys/types.h>
 438 #endif
 439 #ifdef HAVE_SYS_SOCKET_H
 440 #include <sys/socket.h>
 441 #endif
 442 #ifdef HAVE_NET_IF_H
 443 #include <net/if.h>
 444 #endif])
 445 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 446         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 447 [#ifdef HAVE_SYS_TYPES_H
 448 #include <sys/types.h>
 449 #endif
 450 #ifdef HAVE_SYS_SOCKET_H
 451 #include <sys/socket.h>
 452 #endif
 453 #ifdef HAVE_LIMITS_H
 454 #include <limits.h>
 455 #endif
 456 #ifdef HAVE_LINUX_TYPES_H
 457 #include <linux/types.h>
 458 #endif
 459 #ifdef HAVE_NETINET_IN6_H
 460 #include <netinet/in6.h>
 461 #endif
 462 #ifdef HAVE_NETINET_IN_H
 463 #include <netinet/in.h>
 464 #endif])
 465
 466 if test x$transparent = xtrue ; then
 467    transparent_ok=0
 468    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 469      transparent_ok=1
 470    fi
 471    if test x$linux_netfilter_ipv4 = x1 ; then
 472      transparent_ok=1
 473    fi
 474    if test x$transparent_ok = x1 ; then
 475      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 476      case $host in
 477        *-*-openbsd*)
 478          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 479      esac
 480    else
 481      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 482    fi
 483 fi
 484
 485 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 486 [#ifdef HAVE_SYS_TYPES_H
 487 #include <sys/types.h>
 488 #endif
 489 #ifdef HAVE_SYS_TIME_H
 490 #include <sys/time.h>
 491 #endif])
 492
 493 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 494 dnl Watch out.
 495
 496 AC_CHECK_SIZEOF(int8_t)
 497 AC_CHECK_SIZEOF(int16_t)
 498 AC_CHECK_SIZEOF(int32_t)
 499 AC_CHECK_SIZEOF(int64_t)
 500 AC_CHECK_SIZEOF(uint8_t)
 501 AC_CHECK_SIZEOF(uint16_t)
 502 AC_CHECK_SIZEOF(uint32_t)
 503 AC_CHECK_SIZEOF(uint64_t)
 504 AC_CHECK_SIZEOF(intptr_t)
 505 AC_CHECK_SIZEOF(uintptr_t)
 506
 507 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 508
 509 AC_CHECK_SIZEOF(char)
 510 AC_CHECK_SIZEOF(short)
 511 AC_CHECK_SIZEOF(int)
 512 AC_CHECK_SIZEOF(long)
 513 AC_CHECK_SIZEOF(long long)
 514 AC_CHECK_SIZEOF(__int64)
 515 AC_CHECK_SIZEOF(void *)
 516 AC_CHECK_SIZEOF(time_t)
 517 AC_CHECK_SIZEOF(size_t)
 518
 519 AC_CHECK_TYPES([uint, u_char, ssize_t])
 520
 521 dnl used to include sockaddr_storage, but everybody has that.
 522 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 523 [#ifdef HAVE_SYS_TYPES_H
 524 #include <sys/types.h>
 525 #endif
 526 #ifdef HAVE_NETINET_IN_H
 527 #include <netinet/in.h>
 528 #endif
 529 #ifdef HAVE_NETINET_IN6_H
 530 #include <netinet/in6.h>
 531 #endif
 532 #ifdef HAVE_SYS_SOCKET_H
 533 #include <sys/socket.h>
 534 #endif
 535 #ifdef MS_WINDOWS
 536 #define WIN32_WINNT 0x400
 537 #define _WIN32_WINNT 0x400
 538 #define WIN32_LEAN_AND_MEAN
 539 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 540 #include <winsock.h>
 541 #else
 542 #include <winsock2.h>
 543 #include <ws2tcpip.h>
 544 #endif
 545 #endif
 546 ])
 547 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 548 [#ifdef HAVE_SYS_TYPES_H
 549 #include <sys/types.h>
 550 #endif
 551 #ifdef HAVE_NETINET_IN_H
 552 #include <netinet/in.h>
 553 #endif
 554 #ifdef HAVE_NETINET_IN6_H
 555 #include <netinet/in6.h>
 556 #endif
 557 #ifdef HAVE_SYS_SOCKET_H
 558 #include <sys/socket.h>
 559 #endif
 560 #ifdef MS_WINDOWS
 561 #define WIN32_WINNT 0x400
 562 #define _WIN32_WINNT 0x400
 563 #define WIN32_LEAN_AND_MEAN
 564 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 565 #include <winsock.h>
 566 #else
 567 #include <winsock2.h>
 568 #include <ws2tcpip.h>
 569 #endif
 570 #endif
 571 ])
 572
 573 AC_CHECK_TYPES([rlim_t], , ,
 574 [#ifdef HAVE_SYS_TYPES_H
 575 #include <sys/types.h>
 576 #endif
 577 #ifdef HAVE_SYS_TIME_H
 578 #include <sys/time.h>
 579 #endif
 580 #ifdef HAVE_SYS_RESOURCE_H
 581 #include <sys/resource.h>
 582 #endif
 583 ])
 584
 585 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 586 AC_RUN_IFELSE([AC_LANG_SOURCE([
 587 #ifdef HAVE_SYS_TYPES_H
 588 #include <sys/types.h>
 589 #endif
 590 #ifdef HAVE_SYS_TIME_H
 591 #include <sys/time.h>
 592 #endif
 593 #ifdef HAVE_TIME_H
 594 #include <time.h>
 595 #endif
 596 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }])],
 597   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 598 ])
 599
 600 if test "$tor_cv_time_t_signed" = cross; then
 601   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 602 fi
 603
 604 if test "$tor_cv_time_t_signed" != no; then
 605   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 606             [Define to 1 iff time_t is signed])
 607 fi
 608
 609 AC_CACHE_CHECK([whether size_t is signed], tor_cv_size_t_signed, [
 610 AC_RUN_IFELSE([AC_LANG_SOURCE([
 611 #ifdef HAVE_SYS_TYPES_H
 612 #include <sys/types.h>
 613 #endif
 614 int main(int c, char**v) { if (((size_t)-1)<0) return 1; else return 0; }])],
 615   tor_cv_size_t_signed=no, tor_cv_size_t_signed=yes, tor_cv_size_t_signed=cross)
 616 ])
 617
 618 if test "$tor_cv_size_t_signed" = cross; then
 619   AC_MSG_NOTICE([Cross compiling: assuming that size_t is not signed.])
 620 fi
 621
 622 if test "$tor_cv_size_t_signed" = yes; then
 623   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
 624 fi
 625
 626 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 627 #ifdef HAVE_SYS_SOCKET_H
 628 #include <sys/socket.h>
 629 #endif
 630 ])
 631
 632 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 633
 634 AC_CHECK_SIZEOF(cell_t)
 635
 636 # Now make sure that NULL can be represented as zero bytes.
 637 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 638 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 639 [[#include <stdlib.h>
 640 #include <string.h>
 641 #include <stdio.h>
 642 #ifdef HAVE_STDDEF_H
 643 #include <stddef.h>
 644 #endif
 645 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 646 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 647        [tor_cv_null_is_zero=yes],
 648        [tor_cv_null_is_zero=no],
 649        [tor_cv_null_is_zero=cross])])
 650
 651 if test "$tor_cv_null_is_zero" = cross ; then
 652   # Cross-compiling; let's hope that the target isn't raving mad.
 653   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 654 fi
 655
 656 if test "$tor_cv_null_is_zero" != no; then
 657   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 658             [Define to 1 iff memset(0) sets pointers to NULL])
 659 fi
 660
 661 # And what happens when we malloc zero?
 662 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 663 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 664 [[#include <stdlib.h>
 665 #include <string.h>
 666 #include <stdio.h>
 667 #ifdef HAVE_STDDEF_H
 668 #include <stddef.h>
 669 #endif
 670 int main () { return malloc(0)?0:1; }]])],
 671        [tor_cv_malloc_zero_works=yes],
 672        [tor_cv_malloc_zero_works=no],
 673        [tor_cv_malloc_zero_works=cross])])
 674
 675 if test "$tor_cv_malloc_zero_works" = cross; then
 676   # Cross-compiling; let's hope that the target isn't raving mad.
 677   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 678 fi
 679
 680 if test "$tor_cv_malloc_zero_works" = yes; then
 681   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 682             [Define to 1 iff malloc(0) returns a pointer])
 683 fi
 684
 685 # whether we seem to be in a 2s-complement world.
 686 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 687 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 688 [[int main () { int problem = ((-99) != (~99)+1);
 689 return problem ? 1 : 0; }]])],
 690        [tor_cv_twos_complement=yes],
 691        [tor_cv_twos_complement=no],
 692        [tor_cv_twos_complement=cross])])
 693
 694 if test "$tor_cv_twos_complement" = cross ; then
 695   # Cross-compiling; let's hope that the target isn't raving mad.
 696   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 697 fi
 698
 699 if test "$tor_cv_twos_complement" != no ; then
 700   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 701             [Define to 1 iff we represent negative integers with two's complement])
 702 fi
 703
 704 # What does shifting a negative value do?
 705 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
 706 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 707 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
 708        [tor_cv_sign_extend=yes],
 709        [tor_cv_sign_extend=no],
 710        [tor_cv_sign_extend=cross])])
 711
 712 if test "$tor_cv_sign_extend" = cross ; then
 713   # Cross-compiling; let's hope that the target isn't raving mad.
 714   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
 715 fi
 716
 717 if test "$tor_cv_sign_extend" != no ; then
 718   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
 719             [Define to 1 iff right-shifting a negative value performs sign-extension])
 720 fi
 721
 722 # Whether we should use the dmalloc memory allocation debugging library.
 723 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 724 AC_ARG_WITH(dmalloc,
 725 [  --with-dmalloc          Use debug memory allocation library. ],
 726 [if [[ "$withval" = "yes" ]]; then
 727   dmalloc=1
 728   AC_MSG_RESULT(yes)
 729 else
 730   dmalloc=1
 731   AC_MSG_RESULT(no)
 732 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 733 )
 734
 735 if [[ $dmalloc -eq 1 ]]; then
 736   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 737   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 738   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 739   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 740   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 741 fi
 742
 743 AC_ARG_WITH(tcmalloc,
 744 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 745 [ tcmalloc=yes ], [ tcmalloc=no ])
 746
 747 if test x$tcmalloc = xyes ; then
 748    LDFLAGS="-ltcmalloc $LDFLAGS"
 749 fi
 750
 751 # By default, we're going to assume we don't have mlockall()
 752 # bionic and other platforms have various broken mlockall subsystems.
 753 # Some systems don't have a working mlockall, some aren't linkable,
 754 # and some have it but don't declare it.
 755 AC_CHECK_FUNCS(mlockall)
 756 AC_CHECK_DECLS([mlockall], , , [
 757 #ifdef HAVE_SYS_MMAN_H
 758 #include <sys/mman.h>
 759 #endif])
 760
 761 # Allow user to specify an alternate syslog facility
 762 AC_ARG_WITH(syslog-facility,
 763 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 764 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 765 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 766 AC_SUBST(LOGFACILITY)
 767
 768 # Check if we have getresuid and getresgid
 769 AC_CHECK_FUNCS(getresuid getresgid)
 770
 771 # Check for gethostbyname_r in all its glorious incompatible versions.
 772 #   (This logic is based on that in Python's configure.in)
 773 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 774   [Define this if you have any gethostbyname_r()])
 775
 776 AC_CHECK_FUNC(gethostbyname_r, [
 777   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 778   OLD_CFLAGS=$CFLAGS
 779   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 780   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 781 #include <netdb.h>
 782   ], [[
 783     char *cp1, *cp2;
 784     struct hostent *h1, *h2;
 785     int i1, i2;
 786     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 787   ]])],[
 788     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 789     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 790      [Define this if gethostbyname_r takes 6 arguments])
 791     AC_MSG_RESULT(6)
 792   ], [
 793     AC_TRY_COMPILE([
 794 #include <netdb.h>
 795     ], [
 796       char *cp1, *cp2;
 797       struct hostent *h1;
 798       int i1, i2;
 799       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 800     ], [
 801       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 802       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 803         [Define this if gethostbyname_r takes 5 arguments])
 804       AC_MSG_RESULT(5)
 805    ], [
 806       AC_TRY_COMPILE([
 807 #include <netdb.h>
 808      ], [
 809        char *cp1;
 810        struct hostent *h1;
 811        struct hostent_data hd;
 812        (void) gethostbyname_r(cp1,h1,&hd);
 813      ], [
 814        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 815        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 816          [Define this if gethostbyname_r takes 3 arguments])
 817        AC_MSG_RESULT(3)
 818      ], [
 819        AC_MSG_RESULT(0)
 820      ])
 821   ])
 822  ])
 823  CFLAGS=$OLD_CFLAGS
 824 ])
 825
 826 AC_CACHE_CHECK([whether the C compiler supports __func__],
 827   tor_cv_have_func_macro,
 828   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 829 #include <stdio.h>
 830 int main(int c, char **v) { puts(__func__); }])],
 831   tor_cv_have_func_macro=yes,
 832   tor_cv_have_func_macro=no))
 833
 834 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 835   tor_cv_have_FUNC_macro,
 836   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 837 #include <stdio.h>
 838 int main(int c, char **v) { puts(__FUNC__); }])],
 839   tor_cv_have_FUNC_macro=yes,
 840   tor_cv_have_FUNC_macro=no))
 841
 842 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 843   tor_cv_have_FUNCTION_macro,
 844   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 845 #include <stdio.h>
 846 int main(int c, char **v) { puts(__FUNCTION__); }])],
 847   tor_cv_have_FUNCTION_macro=yes,
 848   tor_cv_have_FUNCTION_macro=no))
 849
 850 if test "$tor_cv_have_func_macro" = 'yes'; then
 851   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 852 fi
 853
 854 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 855   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 856 fi
 857
 858 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 859   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 860            [Defined if the compiler supports __FUNCTION__])
 861 fi
 862
 863 # $prefix stores the value of the --prefix command line option, or
 864 # NONE if the option wasn't set.  In the case that it wasn't set, make
 865 # it be the default, so that we can use it to expand directories now.
 866 if test "x$prefix" = "xNONE"; then
 867   prefix=$ac_default_prefix
 868 fi
 869
 870 # and similarly for $exec_prefix
 871 if test "x$exec_prefix" = "xNONE"; then
 872   exec_prefix=$prefix
 873 fi
 874
 875 if test "x$CONFDIR" = "x"; then
 876   CONFDIR=`eval echo $sysconfdir/tor`
 877 fi
 878 AC_SUBST(CONFDIR)
 879 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 880 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 881
 882 BINDIR=`eval echo $bindir`
 883 AC_SUBST(BINDIR)
 884 LOCALSTATEDIR=`eval echo $localstatedir`
 885 AC_SUBST(LOCALSTATEDIR)
 886
 887 if test "$bwin32" = true; then
 888   # Test if the linker supports the --nxcompat and --dynamicbase options
 889   # for Windows
 890   save_LDFLAGS="$LDFLAGS"
 891   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
 892   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
 893   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 894     [AC_MSG_RESULT([yes])]
 895     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
 896     [AC_MSG_RESULT([no])]
 897   )
 898   LDFLAGS="$save_LDFLAGS"
 899 fi
 900
 901 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 902 # than autoconf's macros like.
 903 if test "$GCC" = yes; then
 904   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 905   # accident waiting to happen.
 906   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
 907 else
 908   # Autoconf sets -g -O2 by default. Override optimization level
 909   # for non-gcc compilers
 910   CFLAGS="$CFLAGS -O"
 911   enable_gcc_warnings=no
 912   enable_gcc_warnings_advisory=no
 913 fi
 914
 915 # OS X Lion started deprecating the system openssl. Let's just disable
 916 # all deprecation warnings on OS X.
 917 case "$host_os" in
 918
 919  darwin*)
 920     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
 921     ;;
 922 esac
 923
 924 # Add some more warnings which we use in development but not in the
 925 # released versions.  (Some relevant gcc versions can't handle these.)
 926 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
 927
 928   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 929 #if !defined(__GNUC__) || (__GNUC__ < 4)
 930 #error
 931 #endif])], have_gcc4=yes, have_gcc4=no)
 932
 933   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 934 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 935 #error
 936 #endif])], have_gcc42=yes, have_gcc42=no)
 937
 938   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 939 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 940 #error
 941 #endif])], have_gcc43=yes, have_gcc43=no)
 942
 943   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 944 #if !defined(__clang__) || (__clang_major__ > 2) || (__clang_major__ == 2 && __clang_minor__ > 9)
 945 #error
 946 #endif])], have_clang29orlower=yes, have_clang29orlower=no)
 947
 948   save_CFLAGS="$CFLAGS"
 949   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 950   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
 951                     have_shorten64_flag=no)
 952   CFLAGS="$save_CFLAGS"
 953
 954   case $host in
 955     *-*-openbsd*)
 956       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
 957       # That's fine, except that the headers don't pass -Wredundant-decls.
 958       # Therefore, let's disable -Wsystem-headers when we're building
 959       # with maximal warnings on OpenBSD.
 960       CFLAGS="$CFLAGS -Wno-system-headers" ;;
 961   esac
 962
 963   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum"
 964   if test x$enable_gcc_warnings = xyes; then
 965     CFLAGS="$CFLAGS -Werror"
 966   fi
 967
 968   # Disabled, so we can use mallinfo(): -Waggregate-return
 969
 970   if test x$have_gcc4 = xyes ; then
 971     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 972     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 973   fi
 974
 975   if test x$have_gcc42 = xyes ; then
 976     # These warnings break gcc 4.0.2 and work on gcc 4.2
 977     # XXXX020 See if any of these work with earlier versions.
 978     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wstrict-overflow=1"
 979
 980     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 981   fi
 982
 983   if test x$have_gcc42 = xyes && test x$have_clang29orlower = xno; then
 984     # These warnings break gcc 4.0.2 and clang, but work on gcc 4.2
 985     # We only disable these for clang 2.9 and lower, in case they are
 986     # supported in later versions.
 987     CFLAGS="$CFLAGS -Wnormalized=id -Woverride-init"
 988   fi
 989
 990   if test x$have_gcc43 = xyes ; then
 991     # These warnings break gcc 4.2 and work on gcc 4.3
 992     # XXXX020 See if any of these work with earlier versions.
 993     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 994   fi
 995
 996   if test x$have_shorten64_flag = xyes ; then
 997     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 998   fi
 999
1000 ##This will break the world on some 64-bit architectures
1001 # CFLAGS="$CFLAGS -Winline"
1002 fi
1003
1004
1005
1006 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1007
1008 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile src/config/torrc.sample src/Makefile doc/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/test/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
1009 AC_OUTPUT
1010
1011 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
1012   ./contrib/updateVersions.pl
1013 fi
1014