configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.0.19-alpha)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43
  44 if test x$enable_cell_pool != xno; then
  45   AC_DEFINE(ENABLE_CELL_POOL, 1,
  46             [Defined if we try to use the pool allocator for queued cells])
  47 fi
  48 if test x$enable_buf_freelists != xno; then
  49   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  50             [Defined if we try to use freelists for buffer RAM chunks])
  51 fi
  52
  53 AC_ARG_ENABLE(transparent,
  54      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  55      [case "${enableval}" in
  56         yes) transparent=true ;;
  57         no)  transparent=false ;;
  58         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  59       esac], [transparent=true])
  60
  61 AC_ARG_ENABLE(threads,
  62      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  63
  64 if test x$enable_threads = x; then
  65    case $host in
  66     *-*-solaris* )
  67      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  68      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  69 cpu workers lock up here, so I will disable threads.])
  70      enable_threads="no";;
  71     *)
  72      enable_threads="yes";;
  73    esac
  74 fi
  75
  76 if test "$enable_threads" = "yes"; then
  77   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  78 fi
  79
  80 case $host in
  81    *-*-solaris* )
  82      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  83      ;;
  84 esac
  85
  86 AC_ARG_ENABLE(gcc-warnings,
  87      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  88
  89 AC_PROG_CC
  90 AC_PROG_CPP
  91 AC_PROG_MAKE_SET
  92 AC_PROG_RANLIB
  93
  94 TORUSER=_tor
  95 AC_ARG_WITH(tor-user,
  96         [  --with-tor-user=NAME    Specify username for tor daemon ],
  97         [
  98            TORUSER=$withval
  99         ]
 100 )
 101 AC_SUBST(TORUSER)
 102
 103 TORGROUP=_tor
 104 AC_ARG_WITH(tor-group,
 105         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 106         [
 107            TORGROUP=$withval
 108         ]
 109 )
 110 AC_SUBST(TORGROUP)
 111
 112
 113 dnl If WIN32 is defined and non-zero, we are building for win32
 114 AC_MSG_CHECKING([for win32])
 115 AC_RUN_IFELSE([
 116 int main(int c, char **v) {
 117 #ifdef WIN32
 118 #if WIN32
 119   return 0;
 120 #else
 121   return 1;
 122 #endif
 123 #else
 124   return 2;
 125 #endif
 126 }],
 127 bwin32=true; AC_MSG_RESULT([yes]),
 128 bwin32=false; AC_MSG_RESULT([no]),
 129 bwin32=cross; AC_MSG_RESULT([cross])
 130 )
 131
 132 if test "$bwin32" = cross; then
 133 AC_MSG_CHECKING([for win32 (cross)])
 134 AC_COMPILE_IFELSE([
 135 #ifdef WIN32
 136 int main(int c, char **v) {return 0;}
 137 #else
 138 #error
 139 int main(int c, char **v) {return x(y);}
 140 #endif
 141 ],
 142 bwin32=true; AC_MSG_RESULT([yes]),
 143 bwin32=false; AC_MSG_RESULT([no]))
 144 fi
 145
 146 if test "$bwin32" = true; then
 147 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 148 fi
 149 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 150
 151 dnl Enable C99 when compiling with MIPSpro
 152 AC_MSG_CHECKING([for MIPSpro compiler])
 153 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 154 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 155 #error
 156   return x(y);
 157 #endif
 158 ]),
 159 bmipspro=false; AC_MSG_RESULT(no),
 160 bmipspro=true; AC_MSG_RESULT(yes))
 161
 162 if test "$bmipspro" = true; then
 163   CFLAGS="$CFLAGS -c99"
 164 fi
 165
 166 AC_C_BIGENDIAN
 167
 168 AC_SEARCH_LIBS(socket, [socket])
 169 AC_SEARCH_LIBS(gethostbyname, [nsl])
 170 AC_SEARCH_LIBS(dlopen, [dl])
 171 AC_SEARCH_LIBS(inet_aton, [resolv])
 172
 173 if test "$enable_threads" = "yes"; then
 174   AC_SEARCH_LIBS(pthread_create, [pthread])
 175   AC_SEARCH_LIBS(pthread_detach, [pthread])
 176 fi
 177
 178 dnl -------------------------------------------------------------------
 179 dnl Check for functions before libevent, since libevent-1.2 apparently
 180 dnl exports strlcpy without defining it in a header.
 181
 182 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop mallinfo malloc_good_size malloc_usable_size)
 183
 184 if test "$enable_threads" = "yes"; then
 185   AC_CHECK_HEADERS(pthread.h)
 186   AC_CHECK_FUNCS(pthread_create)
 187 fi
 188
 189 dnl ------------------------------------------------------
 190 dnl Where do you live, libevent?  And how do we call you?
 191
 192 if test "$bwin32" = true; then
 193   TOR_LIB_WS32=-lws2_32
 194   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 195   # think it's actually necessary.
 196   TOR_LIB_GDI=-lgdi32
 197 else
 198   TOR_LIB_WS32=
 199   TOR_LIB_GDI=
 200 fi
 201 AC_SUBST(TOR_LIB_WS32)
 202 AC_SUBST(TOR_LIB_GDI)
 203
 204 dnl We need to do this before we try our disgusting hack below.
 205 AC_CHECK_HEADERS([sys/types.h])
 206
 207 dnl This is a disgusting hack so we safely include older libevent headers.
 208 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 209 AC_CHECK_TYPE(u_int32_t, unsigned long)
 210 AC_CHECK_TYPE(u_int16_t, unsigned short)
 211 AC_CHECK_TYPE(u_int8_t, unsigned char)
 212
 213 tor_libevent_pkg_redhat="libevent"
 214 tor_libevent_pkg_debian="libevent-dev"
 215 tor_libevent_devpkg_redhat="libevent-devel"
 216 tor_libevent_devpkg_debian="libevent-dev"
 217
 218 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 219 #include <stdlib.h>
 220 #include <sys/time.h>
 221 #include <sys/types.h>
 222 #include <event.h>], [void exit(int); void *event_init(void);],
 223     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 224
 225 dnl Now check for particular libevent functions.
 226 save_LIBS="$LIBS"
 227 save_LDFLAGS="$LDFLAGS"
 228 save_CPPFLAGS="$CPPFLAGS"
 229 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 230 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 231 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 232 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 233 LIBS="$save_LIBS"
 234 LDFLAGS="$save_LDFLAGS"
 235 CPPFLAGS="$save_CPPFLAGS"
 236
 237 dnl ------------------------------------------------------
 238 dnl Where do you live, openssl?  And how do we call you?
 239
 240 tor_openssl_pkg_redhat="openssl"
 241 tor_openssl_pkg_debian="libssl"
 242 tor_openssl_devpkg_redhat="openssl-devel"
 243 tor_openssl_devpkg_debian="libssl-dev"
 244
 245 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 246     [#include <openssl/rand.h>],
 247     [void RAND_add(const void *buf, int num, double entropy);],
 248     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 249     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 250
 251 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 252
 253 dnl ------------------------------------------------------
 254 dnl Where do you live, zlib?  And how do we call you?
 255
 256 tor_openssl_pkg_redhat="zlib"
 257 tor_openssl_pkg_debian="zlib1g"
 258 tor_openssl_devpkg_redhat="zlib-devel"
 259 tor_openssl_devpkg_debian="zlib1g-dev"
 260
 261 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 262     [#include <zlib.h>],
 263     [const char * zlibVersion(void);],
 264     [zlibVersion(); exit(0);], [--with-zlib-dir],
 265     [/opt/zlib])
 266
 267 dnl Make sure to enable support for large off_t if available.
 268
 269 AC_SYS_LARGEFILE
 270
 271 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 272
 273 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 274
 275 dnl These headers are not essential
 276
 277 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 278
 279 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 280 [#ifdef HAVE_MALLOC_H
 281 #include <malloc.h>
 282 #endif
 283 #ifdef HAVE_MALLOC_MALLOC_H
 284 #include <malloc/malloc.h>
 285 #endif])
 286
 287 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 288 [#ifdef HAVE_SYS_TYPES_H
 289 #include <sys/types.h>
 290 #endif
 291 #ifdef HAVE_SYS_SOCKET_H
 292 #include <sys/socket.h>
 293 #endif])
 294 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 295 [#ifdef HAVE_SYS_TYPES_H
 296 #include <sys/types.h>
 297 #endif
 298 #ifdef HAVE_SYS_SOCKET_H
 299 #include <sys/socket.h>
 300 #endif
 301 #ifdef HAVE_NET_IF_H
 302 #include <net/if.h>
 303 #endif])
 304 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 305         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 306 [#ifdef HAVE_SYS_TYPES_H
 307 #include <sys/types.h>
 308 #endif
 309 #ifdef HAVE_SYS_SOCKET_H
 310 #include <sys/socket.h>
 311 #endif])
 312
 313 if test x$transparent = xtrue ; then
 314    transparent_ok=0
 315    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 316      transparent_ok=1
 317    fi
 318    if test x$linux_netfilter_ipv4 = x1 ; then
 319      transparent_ok=1
 320    fi
 321    if test x$transparent_ok = x1 ; then
 322      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 323      case $host in
 324        *-*-openbsd*)
 325          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 326      esac
 327    else
 328      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 329    fi
 330 fi
 331
 332 AC_FUNC_FSEEKO
 333
 334 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 335 [#ifdef HAVE_SYS_TYPES_H
 336 #include <sys/types.h>
 337 #endif
 338 #ifdef HAVE_SYS_TIME_H
 339 #include <sys/time.h>
 340 #endif])
 341
 342 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 343 dnl Watch out.
 344
 345 AC_CHECK_SIZEOF(int8_t)
 346 AC_CHECK_SIZEOF(int16_t)
 347 AC_CHECK_SIZEOF(int32_t)
 348 AC_CHECK_SIZEOF(int64_t)
 349 AC_CHECK_SIZEOF(uint8_t)
 350 AC_CHECK_SIZEOF(uint16_t)
 351 AC_CHECK_SIZEOF(uint32_t)
 352 AC_CHECK_SIZEOF(uint64_t)
 353 AC_CHECK_SIZEOF(intptr_t)
 354 AC_CHECK_SIZEOF(uintptr_t)
 355
 356 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 357
 358 AC_CHECK_SIZEOF(char)
 359 AC_CHECK_SIZEOF(short)
 360 AC_CHECK_SIZEOF(int)
 361 AC_CHECK_SIZEOF(long)
 362 AC_CHECK_SIZEOF(long long)
 363 AC_CHECK_SIZEOF(__int64)
 364 AC_CHECK_SIZEOF(void *)
 365 AC_CHECK_SIZEOF(time_t)
 366 AC_CHECK_SIZEOF(size_t)
 367
 368 AC_CHECK_TYPES([uint, u_char])
 369
 370 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 371 [#ifdef HAVE_SYS_TYPES_H
 372 #include <sys/types.h>
 373 #endif
 374 #ifdef HAVE_NETINET_IN_H
 375 #include <netinet/in.h>
 376 #endif
 377 #ifdef HAVE_NETINET_IN6_H
 378 #include <netinet/in6.h>
 379 #endif
 380 #ifdef HAVE_SYS_SOCKET_H
 381 #include <sys/socket.h>
 382 #endif
 383 #ifdef MS_WINDOWS
 384 #define WIN32_WINNT 0x400
 385 #define _WIN32_WINNT 0x400
 386 #define WIN32_LEAN_AND_MEAN
 387 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 388 #include <winsock.h>
 389 #else
 390 #include <winsock2.h>
 391 #include <ws2tcpip.h>
 392 #endif
 393 #endif
 394 ])
 395 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 396 [#ifdef HAVE_SYS_TYPES_H
 397 #include <sys/types.h>
 398 #endif
 399 #ifdef HAVE_NETINET_IN_H
 400 #include <netinet/in.h>
 401 #endif
 402 #ifdef HAVE_NETINET_IN6_H
 403 #include <netinet/in6.h>
 404 #endif
 405 #ifdef HAVE_SYS_SOCKET_H
 406 #include <sys/socket.h>
 407 #endif
 408 #ifdef MS_WINDOWS
 409 #define WIN32_WINNT 0x400
 410 #define _WIN32_WINNT 0x400
 411 #define WIN32_LEAN_AND_MEAN
 412 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 413 #include <winsock.h>
 414 #else
 415 #include <winsock2.h>
 416 #include <ws2tcpip.h>
 417 #endif
 418 #endif
 419 ])
 420
 421 AC_CHECK_TYPES([rlim_t], , ,
 422 [#ifdef HAVE_SYS_TYPES_H
 423 #include <sys/types.h>
 424 #endif
 425 #ifdef HAVE_SYS_TIME_H
 426 #include <sys/time.h>
 427 #endif
 428 #ifdef HAVE_SYS_RESOURCE_H
 429 #include <sys/resource.h>
 430 #endif
 431 ])
 432
 433 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 434 AC_RUN_IFELSE(AC_LANG_SOURCE([
 435 #ifdef HAVE_SYS_TYPES_H
 436 #include <sys/types.h>
 437 #endif
 438 #ifdef HAVE_SYS_TIME_H
 439 #include <sys/time.h>
 440 #endif
 441 #ifdef HAVE_TIME_H
 442 #include <time.h>
 443 #endif
 444 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 445   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 446 ])
 447
 448 if test "$tor_cv_time_t_signed" = cross; then
 449   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 450 fi
 451
 452 if test "$tor_cv_time_t_signed" != no; then
 453   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 454             [Define to 1 iff time_t is signed])
 455 fi
 456
 457 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 458 #ifdef HAVE_SYS_SOCKET_H
 459 #include <sys/socket.h>
 460 #endif
 461 ])
 462
 463 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 464
 465 AC_CHECK_SIZEOF(cell_t)
 466
 467 # Now make sure that NULL can be represented as zero bytes.
 468 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 469 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 470 [[#include <stdlib.h>
 471 #include <string.h>
 472 #include <stdio.h>
 473 #ifdef HAVE_STDDEF_H
 474 #include <stddef.h>
 475 #endif
 476 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 477 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 478        [tor_cv_null_is_zero=yes],
 479        [tor_cv_null_is_zero=no],
 480        [tor_cv_null_is_zero=cross])])
 481
 482 if test "$tor_cv_null_is_zero" = cross ; then
 483   # Cross-compiling; let's hope that the target isn't raving mad.
 484   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 485 fi
 486
 487 if test "$tor_cv_null_is_zero" != no; then
 488   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 489             [Define to 1 iff memset(0) sets pointers to NULL])
 490 fi
 491
 492 # And what happens when we malloc zero?
 493 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 494 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 495 [[#include <stdlib.h>
 496 #include <string.h>
 497 #include <stdio.h>
 498 #ifdef HAVE_STDDEF_H
 499 #include <stddef.h>
 500 #endif
 501 int main () { return malloc(0)?0:1; }]])],
 502        [tor_cv_malloc_zero_works=yes],
 503        [tor_cv_malloc_zero_works=no],
 504        [tor_cv_malloc_zero_works=cross])])
 505
 506 if test "$tor_cv_malloc_zero_works" = cross; then
 507   # Cross-compiling; let's hope that the target isn't raving mad.
 508   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 509 fi
 510
 511 if test "$tor_cv_malloc_zero_works" = yes; then
 512   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 513             [Define to 1 iff malloc(0) returns a pointer])
 514 fi
 515
 516 # whether we seem to be in a 2s-complement world.
 517 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 518 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 519 [[int main () { int problem = ((-99) != (~99)+1);
 520 return problem ? 1 : 0; }]])],
 521        [tor_cv_twos_complement=yes],
 522        [tor_cv_twos_complement=no],
 523        [tor_cv_twos_complement=cross])])
 524
 525 if test "$tor_cv_twos_complement" = cross ; then
 526   # Cross-compiling; let's hope that the target isn't raving mad.
 527   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 528 fi
 529
 530 if test "$tor_cv_twos_complement" != no ; then
 531   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 532             [Define to 1 iff we represent negative integers with two's complement])
 533 fi
 534
 535 # Whether we should use the dmalloc memory allocation debugging library.
 536 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 537 AC_ARG_WITH(dmalloc,
 538 [  --with-dmalloc          Use debug memory allocation library. ],
 539 [if [[ "$withval" = "yes" ]]; then
 540   dmalloc=1
 541   AC_MSG_RESULT(yes)
 542 else
 543   dmalloc=1
 544   AC_MSG_RESULT(no)
 545 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 546 )
 547
 548 if [[ $dmalloc -eq 1 ]]; then
 549   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 550   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 551   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 552   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 553   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 554 fi
 555
 556 # Allow user to specify an alternate syslog facility
 557 AC_ARG_WITH(syslog-facility,
 558 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 559 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 560 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 561 AC_SUBST(LOGFACILITY)
 562
 563 # Check for gethostbyname_r in all its glorious incompatible versions.
 564 #   (This logic is based on that in Python's configure.in)
 565 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 566   [Define this if you have any gethostbyname_r()])
 567
 568 AC_CHECK_FUNC(gethostbyname_r, [
 569   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 570   OLD_CFLAGS=$CFLAGS
 571   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 572   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 573 #include <netdb.h>
 574   ], [[
 575     char *cp1, *cp2;
 576     struct hostent *h1, *h2;
 577     int i1, i2;
 578     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 579   ]]),[
 580     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 581     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 582      [Define this if gethostbyname_r takes 6 arguments])
 583     AC_MSG_RESULT(6)
 584   ], [
 585     AC_TRY_COMPILE([
 586 #include <netdb.h>
 587     ], [
 588       char *cp1, *cp2;
 589       struct hostent *h1;
 590       int i1, i2;
 591       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 592     ], [
 593       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 594       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 595         [Define this if gethostbyname_r takes 5 arguments])
 596       AC_MSG_RESULT(5)
 597    ], [
 598       AC_TRY_COMPILE([
 599 #include <netdb.h>
 600      ], [
 601        char *cp1;
 602        struct hostent *h1;
 603        struct hostent_data hd;
 604        (void) gethostbyname_r(cp1,h1,&hd);
 605      ], [
 606        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 607        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 608          [Define this if gethostbyname_r takes 3 arguments])
 609        AC_MSG_RESULT(3)
 610      ], [
 611        AC_MSG_RESULT(0)
 612      ])
 613   ])
 614  ])
 615  CFLAGS=$OLD_CFLAGS
 616 ])
 617
 618 AC_CACHE_CHECK([whether the C compiler supports __func__],
 619   tor_cv_have_func_macro,
 620   AC_COMPILE_IFELSE([
 621 #include <stdio.h>
 622 int main(int c, char **v) { puts(__func__); }],
 623   tor_cv_have_func_macro=yes,
 624   tor_cv_have_func_macro=no))
 625
 626 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 627   tor_cv_have_FUNC_macro,
 628   AC_COMPILE_IFELSE([
 629 #include <stdio.h>
 630 int main(int c, char **v) { puts(__FUNC__); }],
 631   tor_cv_have_FUNC_macro=yes,
 632   tor_cv_have_FUNC_macro=no))
 633
 634 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 635   tor_cv_have_FUNCTION_macro,
 636   AC_COMPILE_IFELSE([
 637 #include <stdio.h>
 638 int main(int c, char **v) { puts(__FUNCTION__); }],
 639   tor_cv_have_FUNCTION_macro=yes,
 640   tor_cv_have_FUNCTION_macro=no))
 641
 642 if test "$tor_cv_have_func_macro" = 'yes'; then
 643   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 644 fi
 645
 646 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 647   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 648 fi
 649
 650 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 651   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 652            [Defined if the compiler supports __FUNCTION__])
 653 fi
 654
 655 # $prefix stores the value of the --prefix command line option, or
 656 # NONE if the option wasn't set.  In the case that it wasn't set, make
 657 # it be the default, so that we can use it to expand directories now.
 658 if test "x$prefix" = "xNONE"; then
 659   prefix=$ac_default_prefix
 660 fi
 661
 662 # and similarly for $exec_prefix
 663 if test "x$exec_prefix" = "xNONE"; then
 664   exec_prefix=$prefix
 665 fi
 666
 667 if test "x$CONFDIR" = "x"; then
 668   CONFDIR=`eval echo $sysconfdir/tor`
 669 fi
 670 AC_SUBST(CONFDIR)
 671 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 672 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 673
 674 BINDIR=`eval echo $bindir`
 675 AC_SUBST(BINDIR)
 676 LOCALSTATEDIR=`eval echo $localstatedir`
 677 AC_SUBST(LOCALSTATEDIR)
 678
 679 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 680 # than autoconf's macros like.
 681 if test "$ac_cv_c_compiler_gnu" = yes; then
 682   CFLAGS="$CFLAGS -Wall -g -O2"
 683 else
 684   CFLAGS="$CFLAGS -g -O"
 685   enable_gcc_warnings=no
 686 fi
 687
 688 # Add some more warnings which we use in development but not in the
 689 # released versions.  (Some relevant gcc versions can't handle these.)
 690 if test x$enable_gcc_warnings = xyes; then
 691
 692   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 693 #if !defined(__GNUC__) || (__GNUC__ < 4)
 694 #error
 695 #endif]), have_gcc4=yes, have_gcc4=no)
 696
 697   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 698 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 699 #error
 700 #endif]), have_gcc42=yes, have_gcc42=no)
 701
 702   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 703   # Disabled, so we can use mallinfo(): -Waggregate-return
 704
 705   if test x$have_gcc4 = xyes ; then
 706     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 707     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 708   fi
 709
 710   if test x$have_gcc42 = xyes ; then
 711     # These warnings break gcc 4.0.2 and work on gcc 4.2
 712     # XXXX020 Use -fstack-protector.
 713     # XXXX020 See if any of these work with earlier versions.
 714     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 715   fi
 716
 717 ##This will break the world on some 64-bit architectures
 718 # CFLAGS="$CFLAGS -Winline"
 719
 720 fi
 721
 722 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 723
 724 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 725 AC_OUTPUT
 726
 727 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 728   ./contrib/updateVersions.pl
 729 fi
 730