configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2013, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT([tor],[0.2.4.23])
   7 AC_CONFIG_SRCDIR([src/or/main.c])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_INIT_AUTOMAKE
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AC_CONFIG_HEADERS([orconfig.h])
  12
  13 AC_CANONICAL_HOST
  14
  15 if test -f /etc/redhat-release ; then
  16   if test -f /usr/kerberos/include ; then
  17     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  18   fi
  19 fi
  20
  21 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  22 # the += operator on it in src/or/Makefile.am
  23 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  24
  25 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  26 AC_ARG_ENABLE(buf-freelists,
  27    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  28 AC_ARG_ENABLE(openbsd-malloc,
  29    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  30 AC_ARG_ENABLE(instrument-downloads,
  31    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  32 AC_ARG_ENABLE(static-openssl,
  33    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  34 AC_ARG_ENABLE(static-libevent,
  35    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  36 AC_ARG_ENABLE(static-zlib,
  37    AS_HELP_STRING(--enable-static-zlib, Link against a static zlib library. Requires --with-zlib-dir))
  38 AC_ARG_ENABLE(static-tor,
  39    AS_HELP_STRING(--enable-static-tor, Create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir))
  40 AC_ARG_ENABLE(curve25519,
  41    AS_HELP_STRING(--disable-curve25519, Build Tor with no curve25519 elliptic-curve crypto support))
  42
  43 if test "$enable_static_tor" = "yes"; then
  44   enable_static_libevent="yes";
  45   enable_static_openssl="yes";
  46   enable_static_zlib="yes";
  47   CFLAGS="$CFLAGS -static"
  48 fi
  49
  50 if test x$enable_buf_freelists != xno; then
  51   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  52             [Defined if we try to use freelists for buffer RAM chunks])
  53 fi
  54 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  55 if test x$enable_instrument_downloads = xyes; then
  56   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  57             [Defined if we want to keep track of how much of each kind of resource we download.])
  58 fi
  59
  60 AC_ARG_ENABLE(transparent,
  61      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  62      [case "${enableval}" in
  63         yes) transparent=true ;;
  64         no)  transparent=false ;;
  65         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  66       esac], [transparent=true])
  67
  68 AC_ARG_ENABLE(asciidoc,
  69      AS_HELP_STRING(--disable-asciidoc, don't use asciidoc (disables building of manpages)),
  70      [case "${enableval}" in
  71         yes) asciidoc=true ;;
  72         no)  asciidoc=false ;;
  73         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  74       esac], [asciidoc=true])
  75
  76 # By default, we're not ready to ship a NAT-PMP aware Tor
  77 AC_ARG_ENABLE(nat-pmp,
  78      AS_HELP_STRING(--enable-nat-pmp, enable NAT-PMP support),
  79      [case "${enableval}" in
  80         yes) natpmp=true ;;
  81         no)  natpmp=false ;;
  82         * ) AC_MSG_ERROR(bad value for --enable-nat-pmp) ;;
  83       esac], [natpmp=false])
  84
  85 # By default, we're not ready to ship a UPnP aware Tor
  86 AC_ARG_ENABLE(upnp,
  87      AS_HELP_STRING(--enable-upnp, enable UPnP support),
  88      [case "${enableval}" in
  89         yes) upnp=true ;;
  90         no)  upnp=false ;;
  91         * ) AC_MSG_ERROR(bad value for --enable-upnp) ;;
  92       esac], [upnp=false])
  93
  94
  95 AC_ARG_ENABLE(threads,
  96      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  97
  98 if test x$enable_threads = x; then
  99    case $host in
 100     *-*-solaris* )
 101      # Don't try multithreading on solaris -- cpuworkers seem to lock.
 102      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
 103 cpu workers lock up here, so I will disable threads.])
 104      enable_threads="no";;
 105     *)
 106      enable_threads="yes";;
 107    esac
 108 fi
 109
 110 if test "$enable_threads" = "yes"; then
 111   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
 112 fi
 113
 114 case $host in
 115    *-*-solaris* )
 116      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 117      ;;
 118 esac
 119
 120 AC_ARG_ENABLE(gcc-warnings,
 121      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
 122 AC_ARG_ENABLE(gcc-warnings-advisory,
 123      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
 124
 125 dnl Adam shostack suggests the following for Windows:
 126 dnl -D_FORTIFY_SOURCE=2 -fstack-protector-all
 127 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 128 dnl This requires that we use gcc and that we add -O2 to the CFLAGS.
 129 AC_ARG_ENABLE(gcc-hardening,
 130     AS_HELP_STRING(--disable-gcc-hardening, disable compiler security checks))
 131
 132 dnl Linker hardening options
 133 dnl Currently these options are ELF specific - you can't use this with MacOSX
 134 AC_ARG_ENABLE(linker-hardening,
 135     AS_HELP_STRING(--disable-linker-hardening, disable linker security fixups))
 136
 137 AC_ARG_ENABLE(local-appdata,
 138    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 139 if test "$enable_local_appdata" = "yes"; then
 140   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 141             [Defined if we default to host local appdata paths on Windows])
 142 fi
 143
 144 # Tor2web mode flag
 145 AC_ARG_ENABLE(tor2web-mode,
 146      AS_HELP_STRING(--enable-tor2web-mode, support tor2web non-anonymous mode),
 147 [if test x$enableval = xyes; then
 148     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 149 fi])
 150
 151 AC_ARG_ENABLE(bufferevents,
 152      AS_HELP_STRING(--enable-bufferevents, use Libevent's buffered IO.))
 153
 154 dnl check for the correct "ar" when cross-compiling
 155 AN_MAKEVAR([AR], [AC_PROG_AR])
 156 AN_PROGRAM([ar], [AC_PROG_AR])
 157 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
 158 AC_PROG_AR
 159
 160 AC_PROG_CC
 161 AC_PROG_CPP
 162 AC_PROG_MAKE_SET
 163 AC_PROG_RANLIB
 164
 165 dnl autoconf 2.59 appears not to support AC_PROG_SED
 166 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 167
 168 dnl check for asciidoc and a2x
 169 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 170 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 171
 172 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 173
 174 AM_CONDITIONAL(USE_FW_HELPER, test x$natpmp = xtrue || test x$upnp = xtrue)
 175 AM_CONDITIONAL(NAT_PMP, test x$natpmp = xtrue)
 176 AM_CONDITIONAL(MINIUPNPC, test x$upnp = xtrue)
 177 AM_PROG_CC_C_O
 178
 179 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 180 AC_C_FLEXIBLE_ARRAY_MEMBER
 181 ], [
 182  dnl Maybe we've got an old autoconf...
 183  AC_CACHE_CHECK([for flexible array members],
 184      tor_cv_c_flexarray,
 185      [AC_COMPILE_IFELSE(
 186        AC_LANG_PROGRAM([
 187  struct abc { int a; char b[]; };
 188 ], [
 189  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 190  def->b[0] = 33;
 191 ]),
 192   [tor_cv_c_flexarray=yes],
 193   [tor_cv_c_flexarray=no])])
 194  if test $tor_cv_flexarray = yes ; then
 195    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 196  else
 197    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 198  fi
 199 ])
 200
 201 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 202 AC_PATH_PROG([OPENSSL], [openssl], none)
 203
 204 TORUSER=_tor
 205 AC_ARG_WITH(tor-user,
 206         [  --with-tor-user=NAME    Specify username for tor daemon ],
 207         [
 208            TORUSER=$withval
 209         ]
 210 )
 211 AC_SUBST(TORUSER)
 212
 213 TORGROUP=_tor
 214 AC_ARG_WITH(tor-group,
 215         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 216         [
 217            TORGROUP=$withval
 218         ]
 219 )
 220 AC_SUBST(TORGROUP)
 221
 222
 223 dnl If _WIN32 is defined and non-zero, we are building for win32
 224 AC_MSG_CHECKING([for win32])
 225 AC_RUN_IFELSE([AC_LANG_SOURCE([
 226 int main(int c, char **v) {
 227 #ifdef _WIN32
 228 #if _WIN32
 229   return 0;
 230 #else
 231   return 1;
 232 #endif
 233 #else
 234   return 2;
 235 #endif
 236 }])],
 237 bwin32=true; AC_MSG_RESULT([yes]),
 238 bwin32=false; AC_MSG_RESULT([no]),
 239 bwin32=cross; AC_MSG_RESULT([cross])
 240 )
 241
 242 if test "$bwin32" = cross; then
 243 AC_MSG_CHECKING([for win32 (cross)])
 244 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 245 #ifdef _WIN32
 246 int main(int c, char **v) {return 0;}
 247 #else
 248 #error
 249 int main(int c, char **v) {return x(y);}
 250 #endif
 251 ])],
 252 bwin32=true; AC_MSG_RESULT([yes]),
 253 bwin32=false; AC_MSG_RESULT([no]))
 254 fi
 255
 256 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 257
 258 dnl Enable C99 when compiling with MIPSpro
 259 AC_MSG_CHECKING([for MIPSpro compiler])
 260 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 261 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 262 #error
 263   return x(y);
 264 #endif
 265 ])],
 266 bmipspro=false; AC_MSG_RESULT(no),
 267 bmipspro=true; AC_MSG_RESULT(yes))
 268
 269 if test "$bmipspro" = true; then
 270   CFLAGS="$CFLAGS -c99"
 271 fi
 272
 273 AC_C_BIGENDIAN
 274
 275 AC_SEARCH_LIBS(socket, [socket network])
 276 AC_SEARCH_LIBS(gethostbyname, [nsl])
 277 AC_SEARCH_LIBS(dlopen, [dl])
 278 AC_SEARCH_LIBS(inet_aton, [resolv])
 279 saved_LIBS="$LIBS"
 280 AC_SEARCH_LIBS([clock_gettime], [rt])
 281 if test "$LIBS" != "$saved_LIBS"; then
 282    # Looks like we need -lrt for clock_gettime().
 283    have_rt=yes
 284 fi
 285
 286 if test "$enable_threads" = "yes"; then
 287   AC_SEARCH_LIBS(pthread_create, [pthread])
 288   AC_SEARCH_LIBS(pthread_detach, [pthread])
 289 fi
 290
 291 dnl -------------------------------------------------------------------
 292 dnl Check for functions before libevent, since libevent-1.2 apparently
 293 dnl exports strlcpy without defining it in a header.
 294
 295 AC_CHECK_FUNCS(
 296         _NSGetEnviron \
 297         accept4 \
 298         clock_gettime \
 299         flock \
 300         ftime \
 301         getaddrinfo \
 302         getifaddrs \
 303         getrlimit \
 304         gettimeofday \
 305         gmtime_r \
 306         inet_aton \
 307         ioctl \
 308         issetugid \
 309         llround \
 310         localtime_r \
 311         lround \
 312         memmem \
 313         prctl \
 314         rint \
 315         socketpair \
 316         strlcat \
 317         strlcpy \
 318         strptime \
 319         strtok_r \
 320         strtoull \
 321         sysconf \
 322         uname \
 323         vasprintf \
 324         _vscprintf
 325 )
 326
 327 if test "$enable_threads" = "yes"; then
 328   AC_CHECK_HEADERS(pthread.h)
 329   AC_CHECK_FUNCS(pthread_create)
 330 fi
 331
 332 dnl ------------------------------------------------------
 333 dnl Where do you live, libevent?  And how do we call you?
 334
 335 if test "$bwin32" = true; then
 336   TOR_LIB_WS32=-lws2_32
 337   TOR_LIB_IPHLPAPI=-liphlpapi
 338   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 339   # think it's actually necessary.
 340   TOR_LIB_GDI=-lgdi32
 341 else
 342   TOR_LIB_WS32=
 343   TOR_LIB_GDI=
 344 fi
 345 AC_SUBST(TOR_LIB_WS32)
 346 AC_SUBST(TOR_LIB_GDI)
 347 AC_SUBST(TOR_LIB_IPHLPAPI)
 348
 349 dnl We need to do this before we try our disgusting hack below.
 350 AC_CHECK_HEADERS([sys/types.h])
 351
 352 dnl This is a disgusting hack so we safely include older libevent headers.
 353 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 354 AC_CHECK_TYPE(u_int32_t, unsigned long)
 355 AC_CHECK_TYPE(u_int16_t, unsigned short)
 356 AC_CHECK_TYPE(u_int8_t, unsigned char)
 357
 358 tor_libevent_pkg_redhat="libevent"
 359 tor_libevent_pkg_debian="libevent-dev"
 360 tor_libevent_devpkg_redhat="libevent-devel"
 361 tor_libevent_devpkg_debian="libevent-dev"
 362
 363 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 364 dnl linking for static builds.
 365 STATIC_LIBEVENT_FLAGS=""
 366 if test "$enable_static_libevent" = "yes"; then
 367     if test "$have_rt" = yes; then
 368       STATIC_LIBEVENT_FLAGS=" -lrt "
 369     fi
 370 fi
 371
 372 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 373 #ifdef _WIN32
 374 #include <winsock2.h>
 375 #endif
 376 #include <stdlib.h>
 377 #include <sys/time.h>
 378 #include <sys/types.h>
 379 #include <event.h>], [
 380 #ifdef _WIN32
 381 #include <winsock2.h>
 382 #endif
 383 void exit(int); void *event_init(void);],
 384     [
 385 #ifdef _WIN32
 386 {WSADATA d; WSAStartup(0x101,&d); }
 387 #endif
 388 event_init(); exit(0);
 389 ], [--with-libevent-dir], [/opt/libevent])
 390
 391 dnl Now check for particular libevent functions.
 392 save_LIBS="$LIBS"
 393 save_LDFLAGS="$LDFLAGS"
 394 save_CPPFLAGS="$CPPFLAGS"
 395 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
 396 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 397 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 398 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 399 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 400 [#include <event.h>
 401 ])
 402
 403 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 404
 405 LIBS="$save_LIBS"
 406 LDFLAGS="$save_LDFLAGS"
 407 CPPFLAGS="$save_CPPFLAGS"
 408
 409
 410 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 411
 412 if test "$enable_static_libevent" = "yes"; then
 413    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 414      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 415    else
 416      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 417    fi
 418 else
 419      TOR_LIBEVENT_LIBS="-levent"
 420 fi
 421
 422 dnl This isn't the best test for Libevent 2.0.3-alpha.  Once it's released,
 423 dnl we can do much better.
 424 if test "$enable_bufferevents" = "yes" ; then
 425   if test "$ac_cv_header_event2_bufferevent_ssl_h" != "yes" ; then
 426     AC_MSG_ERROR([You've asked for bufferevent support, but you're using a version of Libevent without SSL support.  This won't work.  We need Libevent 2.0.8-rc or later, and you don't seem to even have Libevent 2.0.3-alpha.])
 427   else
 428
 429     CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 430
 431     # Check for the right version.  First see if version detection works.
 432     AC_MSG_CHECKING([whether we can detect the Libevent version])
 433     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 434 #include <event2/event.h>
 435 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 10
 436 #error
 437 int x = y(zz);
 438 #else
 439 int x = 1;
 440 #endif
 441   ])], [event_version_number_works=yes; AC_MSG_RESULT([yes]) ],
 442      [event_version_number_works=no;  AC_MSG_RESULT([no])])
 443     if test "$event_version_number_works" != 'yes'; then
 444       AC_MSG_WARN([Version detection on Libevent seems broken.  Your Libevent installation is probably screwed up or very old.])
 445     else
 446       AC_MSG_CHECKING([whether Libevent is new enough for bufferevents])
 447       AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 448 #include <event2/event.h>
 449 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000d00
 450 #error
 451 int x = y(zz);
 452 #else
 453 int x = 1;
 454 #endif
 455    ])], [ AC_MSG_RESULT([yes]) ],
 456       [ AC_MSG_RESULT([no])
 457         AC_MSG_ERROR([Libevent does not seem new enough to support bufferevents.  We require 2.0.13-stable or later]) ] )
 458     fi
 459   fi
 460 fi
 461
 462 LIBS="$save_LIBS"
 463 LDFLAGS="$save_LDFLAGS"
 464 CPPFLAGS="$save_CPPFLAGS"
 465
 466 AM_CONDITIONAL(USE_BUFFEREVENTS, test "$enable_bufferevents" = "yes")
 467 if test "$enable_bufferevents" = "yes"; then
 468   AC_DEFINE(USE_BUFFEREVENTS, 1, [Defined if we're going to use Libevent's buffered IO API])
 469   if test "$enable_static_libevent" = "yes"; then
 470     TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent_openssl.a $TOR_LIBEVENT_LIBS"
 471   else
 472     TOR_LIBEVENT_LIBS="-levent_openssl $TOR_LIBEVENT_LIBS"
 473   fi
 474 fi
 475 AC_SUBST(TOR_LIBEVENT_LIBS)
 476
 477 dnl ------------------------------------------------------
 478 dnl Where do you live, libm?
 479
 480 dnl On some platforms (Haiku/BeOS) the math library is
 481 dnl part of libroot. In which case don't link against lm
 482 TOR_LIB_MATH=""
 483 save_LIBS="$LIBS"
 484 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 485 if test "$ac_cv_search_pow" != "none required"; then
 486     TOR_LIB_MATH="$ac_cv_search_pow"
 487 fi
 488 LIBS="$save_LIBS"
 489 AC_SUBST(TOR_LIB_MATH)
 490
 491 dnl ------------------------------------------------------
 492 dnl Where do you live, openssl?  And how do we call you?
 493
 494 tor_openssl_pkg_redhat="openssl"
 495 tor_openssl_pkg_debian="libssl"
 496 tor_openssl_devpkg_redhat="openssl-devel"
 497 tor_openssl_devpkg_debian="libssl-dev"
 498
 499 ALT_openssl_WITHVAL=""
 500 AC_ARG_WITH(ssl-dir,
 501   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 502   [
 503       if test "x$withval" != xno && test "x$withval" != "x" ; then
 504          ALT_openssl_WITHVAL="$withval"
 505       fi
 506   ])
 507
 508 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 509     [#include <openssl/rand.h>],
 510     [void RAND_add(const void *buf, int num, double entropy);],
 511     [RAND_add((void*)0,0,0); exit(0);], [],
 512     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 513
 514 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 515
 516 if test "$enable_static_openssl" = "yes"; then
 517    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 518      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 519    else
 520      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 521    fi
 522 else
 523      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 524 fi
 525 AC_SUBST(TOR_OPENSSL_LIBS)
 526
 527 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 528 [#include <openssl/ssl.h>
 529 ])
 530
 531 dnl ------------------------------------------------------
 532 dnl Where do you live, zlib?  And how do we call you?
 533
 534 tor_zlib_pkg_redhat="zlib"
 535 tor_zlib_pkg_debian="zlib1g"
 536 tor_zlib_devpkg_redhat="zlib-devel"
 537 tor_zlib_devpkg_debian="zlib1g-dev"
 538
 539 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 540     [#include <zlib.h>],
 541     [const char * zlibVersion(void);],
 542     [zlibVersion(); exit(0);], [--with-zlib-dir],
 543     [/opt/zlib])
 544
 545 if test "$enable_static_zlib" = "yes"; then
 546    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 547      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 548  using --enable-static-zlib")
 549    else
 550      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 551    fi
 552 else
 553      TOR_ZLIB_LIBS="-lz"
 554 fi
 555 AC_SUBST(TOR_ZLIB_LIBS)
 556
 557 dnl ---------------------------------------------------------------------
 558 dnl Now that we know about our major libraries, we can check for compiler
 559 dnl and linker hardening options.  We need to do this with the libraries known,
 560 dnl since sometimes the linker will like an option but not be willing to
 561 dnl use it with a build of a library.
 562
 563 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 564 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI"
 565
 566 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 567 #if !defined(__clang__)
 568 #error
 569 #endif])], have_clang=yes, have_clang=no)
 570
 571 if test x$enable_gcc_hardening != xno; then
 572     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2"
 573     if test x$have_clang = xyes; then
 574         TOR_CHECK_CFLAGS(-Qunused-arguments)
 575     fi
 576     TOR_CHECK_CFLAGS(-fstack-protector-all)
 577     TOR_CHECK_CFLAGS(-Wstack-protector)
 578     TOR_CHECK_CFLAGS(-fwrapv)
 579     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 580     if test "$bwin32" = "false"; then
 581        TOR_CHECK_CFLAGS(-fPIE)
 582        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 583     fi
 584 fi
 585
 586 if test x$enable_linker_hardening != xno; then
 587     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
 588 fi
 589
 590 dnl ------------------------------------------------------
 591 dnl Where do you live, libnatpmp?  And how do we call you?
 592 dnl There are no packages for Debian or Redhat as of this patch
 593
 594 if test "$natpmp" = "true"; then
 595     AC_DEFINE(NAT_PMP, 1, [Define to 1 if we are building with nat-pmp.])
 596     TOR_SEARCH_LIBRARY(libnatpmp, $trylibnatpmpdir, [-lnatpmp $TOR_LIB_WS32 $TOR_LIB_IPHLPAPI],
 597         [#include <natpmp.h>],
 598         [#ifdef _WIN32
 599          #define STATICLIB
 600          #endif
 601          #include <natpmp.h>],
 602         [   int r;
 603             natpmp_t natpmp;
 604             natpmpresp_t response;
 605             r = initnatpmp(&natpmp, 0, 0);],
 606             [printf("initnatpmp() returned %d (%s)\n", r, r?"FAILED":"SUCCESS");
 607             exit(0);],
 608         [--with-libnatpmp-dir],
 609         [/usr/lib/])
 610 fi
 611
 612
 613 dnl ------------------------------------------------------
 614 dnl Where do you live, libminiupnpc?  And how do we call you?
 615 dnl There are no packages for Debian or Redhat as of this patch
 616
 617 if test "$upnp" = "true"; then
 618     AC_DEFINE(MINIUPNPC, 1, [Define to 1 if we are building with UPnP.])
 619
 620     dnl Before we call TOR_SEARCH_LIBRARY we'll do a quick compile test
 621     dnl to see if we have miniupnpc-1.5 or -1.6
 622     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <miniupnpc/miniupnpc.h>],
 623         [upnpDiscover(1, 0, 0, 0);exit(0);])],[miniupnpc15="true"],[miniupnpc15="false"])
 624
 625     if test "$miniupnpc15" = "true" ; then
 626         AC_DEFINE([MINIUPNPC15],[1],[libminiupnpc version 1.5 found])
 627         TOR_SEARCH_LIBRARY(libminiupnpc, $trylibminiupnpcdir, [-lminiupnpc $TOR_LIB_WS32 $TOR_LIB_IPHLPAPI],
 628             [#include <miniupnpc/miniwget.h>
 629              #include <miniupnpc/miniupnpc.h>
 630              #include <miniupnpc/upnpcommands.h>],
 631             [void upnpDiscover(int delay, const char * multicastif,
 632              const char * minissdpdsock, int sameport);],
 633             [upnpDiscover(1, 0, 0, 0); exit(0);],
 634             [--with-libminiupnpc-dir],
 635             [/usr/lib/])
 636     else
 637         TOR_SEARCH_LIBRARY(libminiupnpc, $trylibminiupnpcdir, [-lminiupnpc $TOR_LIB_WS32 $TOR_LIB_IPHLPAPI],
 638             [#include <miniupnpc/miniwget.h>
 639              #include <miniupnpc/miniupnpc.h>
 640              #include <miniupnpc/upnpcommands.h>],
 641             [void upnpDiscover(int delay, const char * multicastif,
 642              const char * minissdpdsock, int sameport, int ipv6, int * error);],
 643             [upnpDiscover(1, 0, 0, 0, 0, 0); exit(0);],
 644             [--with-libminiupnpc-dir],
 645             [/usr/lib/])
 646     fi
 647 fi
 648
 649 dnl ============================================================
 650 dnl We need an implementation of curve25519.
 651
 652 dnl set these defaults.
 653 have_a_curve25519=no
 654 build_curve25519_donna=no
 655 build_curve25519_donna_c64=no
 656 use_curve25519_donna=no
 657 use_curve25519_nacl=no
 658 CURVE25519_LIBS=
 659
 660 if test x$enable_curve25519 != xno; then
 661
 662   dnl The best choice is using curve25519-donna-c64, but that requires
 663   dnl that we
 664   AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
 665     tor_cv_can_use_curve25519_donna_c64,
 666     [AC_RUN_IFELSE(
 667       [AC_LANG_PROGRAM([dnl
 668         #include <stdint.h>
 669         typedef unsigned uint128_t __attribute__((mode(TI)));
 670         int func(uint64_t a, uint64_t b) {
 671              uint128_t c = ((uint128_t)a) * b;
 672              int ok = ((uint64_t)(c>>96)) == 522859 &&
 673                    (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 674                    (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 675                    (((uint64_t)(c))&0xffffffffL) == 0;
 676              return ok;
 677         }
 678         ], [dnl
 679           int ok = func( ((uint64_t)2000000000) * 1000000000,
 680                          ((uint64_t)1234567890) << 24);
 681           return !ok;
 682         ])],
 683         [tor_cv_can_use_curve25519_donna_c64=yes],
 684         [tor_cv_can_use_curve25519_donna_c64=no],
 685         [AC_COMPILE_IFELSE(
 686           [AC_LANG_PROGRAM([dnl
 687         #include <stdint.h>
 688         typedef unsigned uint128_t __attribute__((mode(TI)));
 689         int func(uint64_t a, uint64_t b) {
 690              uint128_t c = ((uint128_t)a) * b;
 691              int ok = ((uint64_t)(c>>96)) == 522859 &&
 692                    (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 693                    (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 694                    (((uint64_t)(c))&0xffffffffL) == 0;
 695              return ok;
 696         }
 697         ], [dnl
 698           int ok = func( ((uint64_t)2000000000) * 1000000000,
 699                          ((uint64_t)1234567890) << 24);
 700           return !ok;
 701         ])],
 702             [tor_cv_can_use_curve25519_donna_c64=cross],
 703             [tor_cv_can_use_curve25519_donna_c64=no])])])
 704
 705   AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
 706                     nacl/crypto_scalarmult_curve25519.h])
 707
 708   AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
 709     tor_cv_can_use_curve25519_nacl,
 710     [tor_saved_LIBS="$LIBS"
 711      LIBS="$LIBS -lnacl"
 712      AC_LINK_IFELSE(
 713        [AC_LANG_PROGRAM([dnl
 714          #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
 715          #include <crypto_scalarmult_curve25519.h>
 716          #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
 717          #include <nacl/crypto_scalarmult_curve25519.h>
 718          #endif
 719          #ifdef crypto_scalarmult_curve25519_ref_BYTES
 720          #error Hey, this is the reference implementation! That's not fast.
 721          #endif
 722        ], [
 723          unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
 724        ])], [tor_cv_can_use_curve25519_nacl=yes],
 725        [tor_cv_can_use_curve25519_nacl=no])
 726      LIBS="$tor_saved_LIBS" ])
 727
 728    dnl Okay, now we need to figure out which one to actually use. Fall back
 729    dnl to curve25519-donna.c
 730
 731    if test x$tor_cv_can_use_curve25519_donna_c64 != xno; then
 732      build_curve25519_donna_c64=yes
 733      use_curve25519_donna=yes
 734    elif test x$tor_cv_can_use_curve25519_nacl = xyes; then
 735      use_curve25519_nacl=yes
 736      CURVE25519_LIBS=-lnacl
 737    else
 738      build_curve25519_donna=yes
 739      use_curve25519_donna=yes
 740    fi
 741    have_a_curve25519=yes
 742 fi
 743
 744 if test x$have_a_curve25519 = xyes; then
 745   AC_DEFINE(CURVE25519_ENABLED, 1,
 746             [Defined if we have a curve25519 implementation])
 747 fi
 748 if test x$use_curve25519_donna = xyes; then
 749   AC_DEFINE(USE_CURVE25519_DONNA, 1,
 750             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
 751 fi
 752 if test x$use_curve25519_nacl = xyes; then
 753   AC_DEFINE(USE_CURVE25519_NACL, 1,
 754             [Defined if we should use a curve25519 from nacl])
 755 fi
 756 AM_CONDITIONAL(BUILD_CURVE25519_DONNA, test x$build_curve25519_donna = xyes)
 757 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64, test x$build_curve25519_donna_c64 = xyes)
 758 AM_CONDITIONAL(CURVE25519_ENABLED, test x$have_a_curve25519 = xyes)
 759 AC_SUBST(CURVE25519_LIBS)
 760
 761 dnl Make sure to enable support for large off_t if available.
 762 AC_SYS_LARGEFILE
 763
 764 AC_CHECK_HEADERS(
 765         assert.h \
 766         errno.h \
 767         fcntl.h \
 768         signal.h \
 769         string.h \
 770         sys/fcntl.h \
 771         sys/stat.h \
 772         sys/time.h \
 773         sys/types.h \
 774         time.h \
 775         unistd.h
 776  , , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 777
 778 dnl These headers are not essential
 779
 780 AC_CHECK_HEADERS(
 781         arpa/inet.h \
 782         crt_externs.h \
 783         grp.h \
 784         ifaddrs.h \
 785         inttypes.h \
 786         limits.h \
 787         linux/types.h \
 788         machine/limits.h \
 789         malloc.h \
 790         malloc/malloc.h \
 791         malloc_np.h \
 792         netdb.h \
 793         netinet/in.h \
 794         netinet/in6.h \
 795         pwd.h \
 796         stdint.h \
 797         sys/file.h \
 798         sys/ioctl.h \
 799         sys/limits.h \
 800         sys/mman.h \
 801         sys/param.h \
 802         sys/prctl.h \
 803         sys/resource.h \
 804         sys/socket.h \
 805         sys/syslimits.h \
 806         sys/time.h \
 807         sys/types.h \
 808         sys/un.h \
 809         sys/utime.h \
 810         sys/wait.h \
 811         syslog.h \
 812         utime.h
 813 )
 814
 815 AC_CHECK_HEADERS(sys/param.h)
 816
 817 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 818 [#ifdef HAVE_SYS_TYPES_H
 819 #include <sys/types.h>
 820 #endif
 821 #ifdef HAVE_SYS_SOCKET_H
 822 #include <sys/socket.h>
 823 #endif])
 824 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 825 [#ifdef HAVE_SYS_TYPES_H
 826 #include <sys/types.h>
 827 #endif
 828 #ifdef HAVE_SYS_SOCKET_H
 829 #include <sys/socket.h>
 830 #endif
 831 #ifdef HAVE_NET_IF_H
 832 #include <net/if.h>
 833 #endif])
 834 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 835         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 836 [#ifdef HAVE_SYS_TYPES_H
 837 #include <sys/types.h>
 838 #endif
 839 #ifdef HAVE_SYS_SOCKET_H
 840 #include <sys/socket.h>
 841 #endif
 842 #ifdef HAVE_LIMITS_H
 843 #include <limits.h>
 844 #endif
 845 #ifdef HAVE_LINUX_TYPES_H
 846 #include <linux/types.h>
 847 #endif
 848 #ifdef HAVE_NETINET_IN6_H
 849 #include <netinet/in6.h>
 850 #endif
 851 #ifdef HAVE_NETINET_IN_H
 852 #include <netinet/in.h>
 853 #endif])
 854
 855 if test x$transparent = xtrue ; then
 856    transparent_ok=0
 857    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 858      transparent_ok=1
 859    fi
 860    if test x$linux_netfilter_ipv4 = x1 ; then
 861      transparent_ok=1
 862    fi
 863    if test x$transparent_ok = x1 ; then
 864      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 865      case $host in
 866        *-*-openbsd* | *-*-bitrig*)
 867          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 868      esac
 869    else
 870      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 871    fi
 872 fi
 873
 874 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 875 [#ifdef HAVE_SYS_TYPES_H
 876 #include <sys/types.h>
 877 #endif
 878 #ifdef HAVE_SYS_TIME_H
 879 #include <sys/time.h>
 880 #endif])
 881
 882 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 883 dnl Watch out.
 884
 885 AC_CHECK_SIZEOF(int8_t)
 886 AC_CHECK_SIZEOF(int16_t)
 887 AC_CHECK_SIZEOF(int32_t)
 888 AC_CHECK_SIZEOF(int64_t)
 889 AC_CHECK_SIZEOF(uint8_t)
 890 AC_CHECK_SIZEOF(uint16_t)
 891 AC_CHECK_SIZEOF(uint32_t)
 892 AC_CHECK_SIZEOF(uint64_t)
 893 AC_CHECK_SIZEOF(intptr_t)
 894 AC_CHECK_SIZEOF(uintptr_t)
 895
 896 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 897
 898 AC_CHECK_SIZEOF(char)
 899 AC_CHECK_SIZEOF(short)
 900 AC_CHECK_SIZEOF(int)
 901 AC_CHECK_SIZEOF(long)
 902 AC_CHECK_SIZEOF(long long)
 903 AC_CHECK_SIZEOF(__int64)
 904 AC_CHECK_SIZEOF(void *)
 905 AC_CHECK_SIZEOF(time_t)
 906 AC_CHECK_SIZEOF(size_t)
 907 AC_CHECK_SIZEOF(pid_t)
 908
 909 AC_CHECK_TYPES([uint, u_char, ssize_t])
 910
 911 dnl used to include sockaddr_storage, but everybody has that.
 912 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 913 [#ifdef HAVE_SYS_TYPES_H
 914 #include <sys/types.h>
 915 #endif
 916 #ifdef HAVE_NETINET_IN_H
 917 #include <netinet/in.h>
 918 #endif
 919 #ifdef HAVE_NETINET_IN6_H
 920 #include <netinet/in6.h>
 921 #endif
 922 #ifdef HAVE_SYS_SOCKET_H
 923 #include <sys/socket.h>
 924 #endif
 925 #ifdef _WIN32
 926 #define _WIN32_WINNT 0x0501
 927 #define WIN32_LEAN_AND_MEAN
 928 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 929 #include <winsock.h>
 930 #else
 931 #include <winsock2.h>
 932 #include <ws2tcpip.h>
 933 #endif
 934 #endif
 935 ])
 936 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 937 [#ifdef HAVE_SYS_TYPES_H
 938 #include <sys/types.h>
 939 #endif
 940 #ifdef HAVE_NETINET_IN_H
 941 #include <netinet/in.h>
 942 #endif
 943 #ifdef HAVE_NETINET_IN6_H
 944 #include <netinet/in6.h>
 945 #endif
 946 #ifdef HAVE_SYS_SOCKET_H
 947 #include <sys/socket.h>
 948 #endif
 949 #ifdef _WIN32
 950 #define _WIN32_WINNT 0x0501
 951 #define WIN32_LEAN_AND_MEAN
 952 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 953 #include <winsock.h>
 954 #else
 955 #include <winsock2.h>
 956 #include <ws2tcpip.h>
 957 #endif
 958 #endif
 959 ])
 960
 961 AC_CHECK_TYPES([rlim_t], , ,
 962 [#ifdef HAVE_SYS_TYPES_H
 963 #include <sys/types.h>
 964 #endif
 965 #ifdef HAVE_SYS_TIME_H
 966 #include <sys/time.h>
 967 #endif
 968 #ifdef HAVE_SYS_RESOURCE_H
 969 #include <sys/resource.h>
 970 #endif
 971 ])
 972
 973 AX_CHECK_SIGN([time_t],
 974        [ AC_DEFINE(TIME_T_IS_SIGNED, 1, [Define if time_t is signed]) ],
 975        [ : ], [
 976 #ifdef HAVE_SYS_TYPES_H
 977 #include <sys/types.h>
 978 #endif
 979 #ifdef HAVE_SYS_TIME_H
 980 #include <sys/time.h>
 981 #endif
 982 #ifdef HAVE_TIME_H
 983 #include <time.h>
 984 #endif
 985 ])
 986
 987 if test "$ax_cv_decl_time_t_signed" = no; then
 988   AC_MSG_WARN([You have an unsigned time_t; some things will probably break. Please tell the Tor developers about your interesting platform.])
 989 fi
 990
 991 AX_CHECK_SIGN([size_t],
 992        [ tor_cv_size_t_signed=yes ],
 993        [ tor_cv_size_t_signed=no ], [
 994 #ifdef HAVE_SYS_TYPES_H
 995 #include <sys/types.h>
 996 #endif
 997 ])
 998
 999 if test "$ax_cv_decl_size_t_signed" = yes; then
1000   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1001 fi
1002
1003 AX_CHECK_SIGN([enum always],
1004        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1005        [ : ], [
1006  enum always { AAA, BBB, CCC };
1007 ])
1008
1009 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1010 #ifdef HAVE_SYS_SOCKET_H
1011 #include <sys/socket.h>
1012 #endif
1013 ])
1014
1015 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1016
1017 AC_CHECK_SIZEOF(cell_t)
1018
1019 # Now make sure that NULL can be represented as zero bytes.
1020 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1021 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1022 [[#include <stdlib.h>
1023 #include <string.h>
1024 #include <stdio.h>
1025 #ifdef HAVE_STDDEF_H
1026 #include <stddef.h>
1027 #endif
1028 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1029 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1030        [tor_cv_null_is_zero=yes],
1031        [tor_cv_null_is_zero=no],
1032        [tor_cv_null_is_zero=cross])])
1033
1034 if test "$tor_cv_null_is_zero" = cross ; then
1035   # Cross-compiling; let's hope that the target isn't raving mad.
1036   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1037 fi
1038
1039 if test "$tor_cv_null_is_zero" != no; then
1040   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1041             [Define to 1 iff memset(0) sets pointers to NULL])
1042 fi
1043
1044 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1045 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1046 [[#include <stdlib.h>
1047 #include <string.h>
1048 #include <stdio.h>
1049 #ifdef HAVE_STDDEF_H
1050 #include <stddef.h>
1051 #endif
1052 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1053 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1054        [tor_cv_dbl0_is_zero=yes],
1055        [tor_cv_dbl0_is_zero=no],
1056        [tor_cv_dbl0_is_zero=cross])])
1057
1058 if test "$tor_cv_dbl0_is_zero" = cross ; then
1059   # Cross-compiling; let's hope that the target isn't raving mad.
1060   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1061 fi
1062
1063 if test "$tor_cv_dbl0_is_zero" != no; then
1064   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1065             [Define to 1 iff memset(0) sets doubles to 0.0])
1066 fi
1067
1068 # And what happens when we malloc zero?
1069 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1070 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1071 [[#include <stdlib.h>
1072 #include <string.h>
1073 #include <stdio.h>
1074 #ifdef HAVE_STDDEF_H
1075 #include <stddef.h>
1076 #endif
1077 int main () { return malloc(0)?0:1; }]])],
1078        [tor_cv_malloc_zero_works=yes],
1079        [tor_cv_malloc_zero_works=no],
1080        [tor_cv_malloc_zero_works=cross])])
1081
1082 if test "$tor_cv_malloc_zero_works" = cross; then
1083   # Cross-compiling; let's hope that the target isn't raving mad.
1084   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1085 fi
1086
1087 if test "$tor_cv_malloc_zero_works" = yes; then
1088   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1089             [Define to 1 iff malloc(0) returns a pointer])
1090 fi
1091
1092 # whether we seem to be in a 2s-complement world.
1093 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1094 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1095 [[int main () { int problem = ((-99) != (~99)+1);
1096 return problem ? 1 : 0; }]])],
1097        [tor_cv_twos_complement=yes],
1098        [tor_cv_twos_complement=no],
1099        [tor_cv_twos_complement=cross])])
1100
1101 if test "$tor_cv_twos_complement" = cross ; then
1102   # Cross-compiling; let's hope that the target isn't raving mad.
1103   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1104 fi
1105
1106 if test "$tor_cv_twos_complement" != no ; then
1107   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1108             [Define to 1 iff we represent negative integers with two's complement])
1109 fi
1110
1111 # What does shifting a negative value do?
1112 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1113 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1114 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1115        [tor_cv_sign_extend=yes],
1116        [tor_cv_sign_extend=no],
1117        [tor_cv_sign_extend=cross])])
1118
1119 if test "$tor_cv_sign_extend" = cross ; then
1120   # Cross-compiling; let's hope that the target isn't raving mad.
1121   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1122 fi
1123
1124 if test "$tor_cv_sign_extend" != no ; then
1125   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1126             [Define to 1 iff right-shifting a negative value performs sign-extension])
1127 fi
1128
1129 # Whether we should use the dmalloc memory allocation debugging library.
1130 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1131 AC_ARG_WITH(dmalloc,
1132 [  --with-dmalloc          Use debug memory allocation library. ],
1133 [if [[ "$withval" = "yes" ]]; then
1134   dmalloc=1
1135   AC_MSG_RESULT(yes)
1136 else
1137   dmalloc=1
1138   AC_MSG_RESULT(no)
1139 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1140 )
1141
1142 if [[ $dmalloc -eq 1 ]]; then
1143   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1144   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1145   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1146   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
1147   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1148 fi
1149
1150 AC_ARG_WITH(tcmalloc,
1151 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
1152 [ tcmalloc=yes ], [ tcmalloc=no ])
1153
1154 if test x$tcmalloc = xyes ; then
1155    LDFLAGS="-ltcmalloc $LDFLAGS"
1156 fi
1157
1158 using_custom_malloc=no
1159 if test x$enable_openbsd_malloc = xyes ; then
1160    using_custom_malloc=yes
1161 fi
1162 if test x$tcmalloc = xyes ; then
1163    using_custom_malloc=yes
1164 fi
1165 if test $using_custom_malloc = no ; then
1166    AC_CHECK_FUNCS(mallinfo)
1167 fi
1168
1169 # By default, we're going to assume we don't have mlockall()
1170 # bionic and other platforms have various broken mlockall subsystems.
1171 # Some systems don't have a working mlockall, some aren't linkable,
1172 # and some have it but don't declare it.
1173 AC_CHECK_FUNCS(mlockall)
1174 AC_CHECK_DECLS([mlockall], , , [
1175 #ifdef HAVE_SYS_MMAN_H
1176 #include <sys/mman.h>
1177 #endif])
1178
1179 # Allow user to specify an alternate syslog facility
1180 AC_ARG_WITH(syslog-facility,
1181 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
1182 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1183 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1184 AC_SUBST(LOGFACILITY)
1185
1186 # Check if we have getresuid and getresgid
1187 AC_CHECK_FUNCS(getresuid getresgid)
1188
1189 # Check for gethostbyname_r in all its glorious incompatible versions.
1190 #   (This logic is based on that in Python's configure.in)
1191 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1192   [Define this if you have any gethostbyname_r()])
1193
1194 AC_CHECK_FUNC(gethostbyname_r, [
1195   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1196   OLD_CFLAGS=$CFLAGS
1197   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1198   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1199 #include <netdb.h>
1200   ], [[
1201     char *cp1, *cp2;
1202     struct hostent *h1, *h2;
1203     int i1, i2;
1204     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1205   ]])],[
1206     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1207     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1208      [Define this if gethostbyname_r takes 6 arguments])
1209     AC_MSG_RESULT(6)
1210   ], [
1211     AC_TRY_COMPILE([
1212 #include <netdb.h>
1213     ], [
1214       char *cp1, *cp2;
1215       struct hostent *h1;
1216       int i1, i2;
1217       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1218     ], [
1219       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1220       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1221         [Define this if gethostbyname_r takes 5 arguments])
1222       AC_MSG_RESULT(5)
1223    ], [
1224       AC_TRY_COMPILE([
1225 #include <netdb.h>
1226      ], [
1227        char *cp1;
1228        struct hostent *h1;
1229        struct hostent_data hd;
1230        (void) gethostbyname_r(cp1,h1,&hd);
1231      ], [
1232        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1233        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1234          [Define this if gethostbyname_r takes 3 arguments])
1235        AC_MSG_RESULT(3)
1236      ], [
1237        AC_MSG_RESULT(0)
1238      ])
1239   ])
1240  ])
1241  CFLAGS=$OLD_CFLAGS
1242 ])
1243
1244 AC_CACHE_CHECK([whether the C compiler supports __func__],
1245   tor_cv_have_func_macro,
1246   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1247 #include <stdio.h>
1248 int main(int c, char **v) { puts(__func__); }])],
1249   tor_cv_have_func_macro=yes,
1250   tor_cv_have_func_macro=no))
1251
1252 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1253   tor_cv_have_FUNC_macro,
1254   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1255 #include <stdio.h>
1256 int main(int c, char **v) { puts(__FUNC__); }])],
1257   tor_cv_have_FUNC_macro=yes,
1258   tor_cv_have_FUNC_macro=no))
1259
1260 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1261   tor_cv_have_FUNCTION_macro,
1262   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1263 #include <stdio.h>
1264 int main(int c, char **v) { puts(__FUNCTION__); }])],
1265   tor_cv_have_FUNCTION_macro=yes,
1266   tor_cv_have_FUNCTION_macro=no))
1267
1268 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1269   tor_cv_have_environ_declared,
1270   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1271 /* We define _GNU_SOURCE here because it is also defined in compat.c.
1272  * Without it environ doesn't get declared. */
1273 #define _GNU_SOURCE
1274 #ifdef HAVE_UNISTD_H
1275 #include <unistd.h>
1276 #endif
1277 #include <stdlib.h>
1278 int main(int c, char **v) { char **t = environ; }])],
1279   tor_cv_have_environ_declared=yes,
1280   tor_cv_have_environ_declared=no))
1281
1282 if test "$tor_cv_have_func_macro" = 'yes'; then
1283   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1284 fi
1285
1286 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
1287   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1288 fi
1289
1290 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
1291   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1292            [Defined if the compiler supports __FUNCTION__])
1293 fi
1294
1295 if test "$tor_cv_have_environ_declared" = 'yes'; then
1296   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1297            [Defined if we have extern char **environ already declared])
1298 fi
1299
1300 # $prefix stores the value of the --prefix command line option, or
1301 # NONE if the option wasn't set.  In the case that it wasn't set, make
1302 # it be the default, so that we can use it to expand directories now.
1303 if test "x$prefix" = "xNONE"; then
1304   prefix=$ac_default_prefix
1305 fi
1306
1307 # and similarly for $exec_prefix
1308 if test "x$exec_prefix" = "xNONE"; then
1309   exec_prefix=$prefix
1310 fi
1311
1312 if test "x$BUILDDIR" = "x"; then
1313   BUILDDIR=`pwd`
1314 fi
1315 AC_SUBST(BUILDDIR)
1316 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1317 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1318
1319 if test "x$CONFDIR" = "x"; then
1320   CONFDIR=`eval echo $sysconfdir/tor`
1321 fi
1322 AC_SUBST(CONFDIR)
1323 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1324 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1325
1326 BINDIR=`eval echo $bindir`
1327 AC_SUBST(BINDIR)
1328 LOCALSTATEDIR=`eval echo $localstatedir`
1329 AC_SUBST(LOCALSTATEDIR)
1330
1331 if test "$bwin32" = true; then
1332   # Test if the linker supports the --nxcompat and --dynamicbase options
1333   # for Windows
1334   save_LDFLAGS="$LDFLAGS"
1335   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1336   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1337   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1338     [AC_MSG_RESULT([yes])]
1339     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1340     [AC_MSG_RESULT([no])]
1341   )
1342   LDFLAGS="$save_LDFLAGS"
1343 fi
1344
1345 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1346 # than autoconf's macros like.
1347 if test "$GCC" = yes; then
1348   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1349   # accident waiting to happen.
1350   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1351 else
1352   # Autoconf sets -g -O2 by default. Override optimization level
1353   # for non-gcc compilers
1354   CFLAGS="$CFLAGS -O"
1355   enable_gcc_warnings=no
1356   enable_gcc_warnings_advisory=no
1357 fi
1358
1359 # OS X Lion started deprecating the system openssl. Let's just disable
1360 # all deprecation warnings on OS X. Also, to potentially make the binary
1361 # a little smaller, let's enable dead_strip.
1362 case "$host_os" in
1363
1364  darwin*)
1365     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1366     LDFLAGS="$LDFLAGS -dead_strip" ;;
1367 esac
1368
1369 # Add some more warnings which we use in development but not in the
1370 # released versions.  (Some relevant gcc versions can't handle these.)
1371 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
1372
1373   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1374 #if !defined(__GNUC__) || (__GNUC__ < 4)
1375 #error
1376 #endif])], have_gcc4=yes, have_gcc4=no)
1377
1378   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1379 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
1380 #error
1381 #endif])], have_gcc42=yes, have_gcc42=no)
1382
1383   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1384 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
1385 #error
1386 #endif])], have_gcc43=yes, have_gcc43=no)
1387
1388   save_CFLAGS="$CFLAGS"
1389   CFLAGS="$CFLAGS -Wshorten-64-to-32"
1390   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
1391                     have_shorten64_flag=no)
1392   CFLAGS="$save_CFLAGS"
1393
1394   case $host in
1395     *-*-openbsd* | *-*-bitrig*)
1396       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1397       # That's fine, except that the headers don't pass -Wredundant-decls.
1398       # Therefore, let's disable -Wsystem-headers when we're building
1399       # with maximal warnings on OpenBSD.
1400       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1401   esac
1402
1403   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1404   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1405   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1406   CFLAGS="$CFLAGS -Wwrite-strings -Wmissing-declarations -Wredundant-decls"
1407   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1408
1409   if test x$enable_gcc_warnings = xyes; then
1410     CFLAGS="$CFLAGS -Werror"
1411   fi
1412
1413   # Disabled, so we can use mallinfo(): -Waggregate-return
1414
1415   if test x$have_gcc4 = xyes ; then
1416     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
1417     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
1418   fi
1419
1420   if test x$have_gcc42 = xyes ; then
1421     # These warnings break gcc 4.0.2 and work on gcc 4.2
1422     # XXXX020 See if any of these work with earlier versions.
1423     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wstrict-overflow=1"
1424
1425     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
1426   fi
1427
1428   if test x$have_gcc42 = xyes && test x$have_clang = xno; then
1429     # These warnings break gcc 4.0.2 and clang, but work on gcc 4.2
1430     CFLAGS="$CFLAGS -Wnormalized=id -Woverride-init"
1431   fi
1432
1433   if test x$have_gcc43 = xyes ; then
1434     # These warnings break gcc 4.2 and work on gcc 4.3
1435     # XXXX020 See if any of these work with earlier versions.
1436     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
1437   fi
1438
1439   if test x$have_shorten64_flag = xyes ; then
1440     CFLAGS="$CFLAGS -Wshorten-64-to-32"
1441   fi
1442
1443 ##This will break the world on some 64-bit architectures
1444 # CFLAGS="$CFLAGS -Winline"
1445 fi
1446
1447
1448
1449 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1450
1451 AC_CONFIG_FILES([
1452         Doxyfile
1453         Makefile
1454         contrib/suse/tor.sh
1455         contrib/tor.logrotate
1456         contrib/tor.sh
1457         contrib/torctl
1458         contrib/torify
1459         src/config/torrc.sample
1460 ])
1461
1462 AC_OUTPUT
1463
1464 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
1465   ./contrib/updateVersions.pl
1466 fi