configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.1.2-alpha-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45 AC_ARG_ENABLE(instrument-downloads,
  46    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  47
  48
  49 if test x$enable_cell_pool != xno; then
  50   AC_DEFINE(ENABLE_CELL_POOL, 1,
  51             [Defined if we try to use the pool allocator for queued cells])
  52 fi
  53 if test x$enable_buf_freelists != xno; then
  54   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  55             [Defined if we try to use freelists for buffer RAM chunks])
  56 fi
  57 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  58 if test x$enable_instrument_downloads == xyes; then
  59   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  60             [Defined if we want to keep track of how much of each kind of resource we download.])
  61 fi
  62
  63 AC_ARG_ENABLE(transparent,
  64      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  65      [case "${enableval}" in
  66         yes) transparent=true ;;
  67         no)  transparent=false ;;
  68         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  69       esac], [transparent=true])
  70
  71 AC_ARG_ENABLE(threads,
  72      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  73
  74 if test x$enable_threads = x; then
  75    case $host in
  76     *-*-solaris* )
  77      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  78      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  79 cpu workers lock up here, so I will disable threads.])
  80      enable_threads="no";;
  81     *)
  82      enable_threads="yes";;
  83    esac
  84 fi
  85
  86 if test "$enable_threads" = "yes"; then
  87   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  88 fi
  89
  90 case $host in
  91    *-*-solaris* )
  92      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  93      ;;
  94 esac
  95
  96 AC_ARG_ENABLE(geoip-stats,
  97      AS_HELP_STRING(--enable-geoip-stats, enable code for directories to collect per-country statistics))
  98
  99 if test "$enable_geoip_stats" = "yes"; then
 100   AC_DEFINE(ENABLE_GEOIP_STATS, 1, [Defined if we try to collect per-country statistics])
 101 fi
 102
 103 AC_ARG_ENABLE(gcc-warnings,
 104      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
 105
 106 AC_PROG_CC
 107 AC_PROG_CPP
 108 AC_PROG_MAKE_SET
 109 AC_PROG_RANLIB
 110
 111 TORUSER=_tor
 112 AC_ARG_WITH(tor-user,
 113         [  --with-tor-user=NAME    Specify username for tor daemon ],
 114         [
 115            TORUSER=$withval
 116         ]
 117 )
 118 AC_SUBST(TORUSER)
 119
 120 TORGROUP=_tor
 121 AC_ARG_WITH(tor-group,
 122         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 123         [
 124            TORGROUP=$withval
 125         ]
 126 )
 127 AC_SUBST(TORGROUP)
 128
 129
 130 dnl If WIN32 is defined and non-zero, we are building for win32
 131 AC_MSG_CHECKING([for win32])
 132 AC_RUN_IFELSE([
 133 int main(int c, char **v) {
 134 #ifdef WIN32
 135 #if WIN32
 136   return 0;
 137 #else
 138   return 1;
 139 #endif
 140 #else
 141   return 2;
 142 #endif
 143 }],
 144 bwin32=true; AC_MSG_RESULT([yes]),
 145 bwin32=false; AC_MSG_RESULT([no]),
 146 bwin32=cross; AC_MSG_RESULT([cross])
 147 )
 148
 149 if test "$bwin32" = cross; then
 150 AC_MSG_CHECKING([for win32 (cross)])
 151 AC_COMPILE_IFELSE([
 152 #ifdef WIN32
 153 int main(int c, char **v) {return 0;}
 154 #else
 155 #error
 156 int main(int c, char **v) {return x(y);}
 157 #endif
 158 ],
 159 bwin32=true; AC_MSG_RESULT([yes]),
 160 bwin32=false; AC_MSG_RESULT([no]))
 161 fi
 162
 163 if test "$bwin32" = true; then
 164 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 165 fi
 166 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 167
 168 dnl Enable C99 when compiling with MIPSpro
 169 AC_MSG_CHECKING([for MIPSpro compiler])
 170 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 171 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 172 #error
 173   return x(y);
 174 #endif
 175 ]),
 176 bmipspro=false; AC_MSG_RESULT(no),
 177 bmipspro=true; AC_MSG_RESULT(yes))
 178
 179 if test "$bmipspro" = true; then
 180   CFLAGS="$CFLAGS -c99"
 181 fi
 182
 183 AC_C_BIGENDIAN
 184
 185 AC_SEARCH_LIBS(socket, [socket])
 186 AC_SEARCH_LIBS(gethostbyname, [nsl])
 187 AC_SEARCH_LIBS(dlopen, [dl])
 188 AC_SEARCH_LIBS(inet_aton, [resolv])
 189
 190 if test "$enable_threads" = "yes"; then
 191   AC_SEARCH_LIBS(pthread_create, [pthread])
 192   AC_SEARCH_LIBS(pthread_detach, [pthread])
 193 fi
 194
 195 dnl -------------------------------------------------------------------
 196 dnl Check for functions before libevent, since libevent-1.2 apparently
 197 dnl exports strlcpy without defining it in a header.
 198
 199 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop writev readv)
 200
 201 using_custom_malloc=no
 202 if test x$enable_openbsd_malloc = xyes ; then
 203    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 204    using_custom_malloc=yes
 205 fi
 206 if test x$tcmalloc = xyes ; then
 207    using_custom_malloc=yes
 208 fi
 209 if test $using_custom_malloc = no ; then
 210    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 211 fi
 212
 213 if test "$enable_threads" = "yes"; then
 214   AC_CHECK_HEADERS(pthread.h)
 215   AC_CHECK_FUNCS(pthread_create)
 216 fi
 217
 218 dnl ------------------------------------------------------
 219 dnl Where do you live, libevent?  And how do we call you?
 220
 221 if test "$bwin32" = true; then
 222   TOR_LIB_WS32=-lws2_32
 223   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 224   # think it's actually necessary.
 225   TOR_LIB_GDI=-lgdi32
 226 else
 227   TOR_LIB_WS32=
 228   TOR_LIB_GDI=
 229 fi
 230 AC_SUBST(TOR_LIB_WS32)
 231 AC_SUBST(TOR_LIB_GDI)
 232
 233 dnl We need to do this before we try our disgusting hack below.
 234 AC_CHECK_HEADERS([sys/types.h])
 235
 236 dnl This is a disgusting hack so we safely include older libevent headers.
 237 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 238 AC_CHECK_TYPE(u_int32_t, unsigned long)
 239 AC_CHECK_TYPE(u_int16_t, unsigned short)
 240 AC_CHECK_TYPE(u_int8_t, unsigned char)
 241
 242 tor_libevent_pkg_redhat="libevent"
 243 tor_libevent_pkg_debian="libevent-dev"
 244 tor_libevent_devpkg_redhat="libevent-devel"
 245 tor_libevent_devpkg_debian="libevent-dev"
 246
 247 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 248 #ifdef WIN32
 249 #include <winsock2.h>
 250 #endif
 251 #include <stdlib.h>
 252 #include <sys/time.h>
 253 #include <sys/types.h>
 254 #include <event.h>], [
 255 #ifdef WIN32
 256 #include <winsock2.h>
 257 #endif
 258 void exit(int); void *event_init(void);],
 259     [
 260 #ifdef WIN32
 261 {WSADATA d; WSAStartup(0x101,&d); }
 262 #endif
 263 event_init(); exit(0);
 264 ], [--with-libevent-dir], [/opt/libevent])
 265
 266 dnl Now check for particular libevent functions.
 267 save_LIBS="$LIBS"
 268 save_LDFLAGS="$LDFLAGS"
 269 save_CPPFLAGS="$CPPFLAGS"
 270 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 271 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 272 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 273 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 274 LIBS="$save_LIBS"
 275 LDFLAGS="$save_LDFLAGS"
 276 CPPFLAGS="$save_CPPFLAGS"
 277
 278 dnl ------------------------------------------------------
 279 dnl Where do you live, openssl?  And how do we call you?
 280
 281 tor_openssl_pkg_redhat="openssl"
 282 tor_openssl_pkg_debian="libssl"
 283 tor_openssl_devpkg_redhat="openssl-devel"
 284 tor_openssl_devpkg_debian="libssl-dev"
 285
 286 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 287     [#include <openssl/rand.h>],
 288     [void RAND_add(const void *buf, int num, double entropy);],
 289     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 290     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 291
 292 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 293
 294 dnl ------------------------------------------------------
 295 dnl Where do you live, zlib?  And how do we call you?
 296
 297 tor_openssl_pkg_redhat="zlib"
 298 tor_openssl_pkg_debian="zlib1g"
 299 tor_openssl_devpkg_redhat="zlib-devel"
 300 tor_openssl_devpkg_debian="zlib1g-dev"
 301
 302 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 303     [#include <zlib.h>],
 304     [const char * zlibVersion(void);],
 305     [zlibVersion(); exit(0);], [--with-zlib-dir],
 306     [/opt/zlib])
 307
 308 dnl Make sure to enable support for large off_t if available.
 309
 310 AC_SYS_LARGEFILE
 311
 312 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 313
 314 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 315
 316 dnl These headers are not essential
 317
 318 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 319
 320 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 321 [#ifdef HAVE_MALLOC_H
 322 #include <malloc.h>
 323 #endif
 324 #ifdef HAVE_MALLOC_MALLOC_H
 325 #include <malloc/malloc.h>
 326 #endif])
 327
 328 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 329 [#ifdef HAVE_SYS_TYPES_H
 330 #include <sys/types.h>
 331 #endif
 332 #ifdef HAVE_SYS_SOCKET_H
 333 #include <sys/socket.h>
 334 #endif])
 335 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 336 [#ifdef HAVE_SYS_TYPES_H
 337 #include <sys/types.h>
 338 #endif
 339 #ifdef HAVE_SYS_SOCKET_H
 340 #include <sys/socket.h>
 341 #endif
 342 #ifdef HAVE_NET_IF_H
 343 #include <net/if.h>
 344 #endif])
 345 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 346         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 347 [#ifdef HAVE_SYS_TYPES_H
 348 #include <sys/types.h>
 349 #endif
 350 #ifdef HAVE_SYS_SOCKET_H
 351 #include <sys/socket.h>
 352 #endif
 353 #ifdef HAVE_NETINET_IN_H
 354 #include <netinet/in.h>
 355 #endif])
 356
 357 if test x$transparent = xtrue ; then
 358    transparent_ok=0
 359    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 360      transparent_ok=1
 361    fi
 362    if test x$linux_netfilter_ipv4 = x1 ; then
 363      transparent_ok=1
 364    fi
 365    if test x$transparent_ok = x1 ; then
 366      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 367      case $host in
 368        *-*-openbsd*)
 369          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 370      esac
 371    else
 372      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 373    fi
 374 fi
 375
 376 AC_FUNC_FSEEKO
 377
 378 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 379 [#ifdef HAVE_SYS_TYPES_H
 380 #include <sys/types.h>
 381 #endif
 382 #ifdef HAVE_SYS_TIME_H
 383 #include <sys/time.h>
 384 #endif])
 385
 386 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 387 dnl Watch out.
 388
 389 AC_CHECK_SIZEOF(int8_t)
 390 AC_CHECK_SIZEOF(int16_t)
 391 AC_CHECK_SIZEOF(int32_t)
 392 AC_CHECK_SIZEOF(int64_t)
 393 AC_CHECK_SIZEOF(uint8_t)
 394 AC_CHECK_SIZEOF(uint16_t)
 395 AC_CHECK_SIZEOF(uint32_t)
 396 AC_CHECK_SIZEOF(uint64_t)
 397 AC_CHECK_SIZEOF(intptr_t)
 398 AC_CHECK_SIZEOF(uintptr_t)
 399
 400 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 401
 402 AC_CHECK_SIZEOF(char)
 403 AC_CHECK_SIZEOF(short)
 404 AC_CHECK_SIZEOF(int)
 405 AC_CHECK_SIZEOF(long)
 406 AC_CHECK_SIZEOF(long long)
 407 AC_CHECK_SIZEOF(__int64)
 408 AC_CHECK_SIZEOF(void *)
 409 AC_CHECK_SIZEOF(time_t)
 410 AC_CHECK_SIZEOF(size_t)
 411
 412 AC_CHECK_TYPES([uint, u_char, ssize_t])
 413
 414 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 415 [#ifdef HAVE_SYS_TYPES_H
 416 #include <sys/types.h>
 417 #endif
 418 #ifdef HAVE_NETINET_IN_H
 419 #include <netinet/in.h>
 420 #endif
 421 #ifdef HAVE_NETINET_IN6_H
 422 #include <netinet/in6.h>
 423 #endif
 424 #ifdef HAVE_SYS_SOCKET_H
 425 #include <sys/socket.h>
 426 #endif
 427 #ifdef MS_WINDOWS
 428 #define WIN32_WINNT 0x400
 429 #define _WIN32_WINNT 0x400
 430 #define WIN32_LEAN_AND_MEAN
 431 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 432 #include <winsock.h>
 433 #else
 434 #include <winsock2.h>
 435 #include <ws2tcpip.h>
 436 #endif
 437 #endif
 438 ])
 439 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 440 [#ifdef HAVE_SYS_TYPES_H
 441 #include <sys/types.h>
 442 #endif
 443 #ifdef HAVE_NETINET_IN_H
 444 #include <netinet/in.h>
 445 #endif
 446 #ifdef HAVE_NETINET_IN6_H
 447 #include <netinet/in6.h>
 448 #endif
 449 #ifdef HAVE_SYS_SOCKET_H
 450 #include <sys/socket.h>
 451 #endif
 452 #ifdef MS_WINDOWS
 453 #define WIN32_WINNT 0x400
 454 #define _WIN32_WINNT 0x400
 455 #define WIN32_LEAN_AND_MEAN
 456 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 457 #include <winsock.h>
 458 #else
 459 #include <winsock2.h>
 460 #include <ws2tcpip.h>
 461 #endif
 462 #endif
 463 ])
 464
 465 AC_CHECK_TYPES([rlim_t], , ,
 466 [#ifdef HAVE_SYS_TYPES_H
 467 #include <sys/types.h>
 468 #endif
 469 #ifdef HAVE_SYS_TIME_H
 470 #include <sys/time.h>
 471 #endif
 472 #ifdef HAVE_SYS_RESOURCE_H
 473 #include <sys/resource.h>
 474 #endif
 475 ])
 476
 477 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 478 AC_RUN_IFELSE(AC_LANG_SOURCE([
 479 #ifdef HAVE_SYS_TYPES_H
 480 #include <sys/types.h>
 481 #endif
 482 #ifdef HAVE_SYS_TIME_H
 483 #include <sys/time.h>
 484 #endif
 485 #ifdef HAVE_TIME_H
 486 #include <time.h>
 487 #endif
 488 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 489   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 490 ])
 491
 492 if test "$tor_cv_time_t_signed" = cross; then
 493   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 494 fi
 495
 496 if test "$tor_cv_time_t_signed" != no; then
 497   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 498             [Define to 1 iff time_t is signed])
 499 fi
 500
 501 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 502 #ifdef HAVE_SYS_SOCKET_H
 503 #include <sys/socket.h>
 504 #endif
 505 ])
 506
 507 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 508
 509 AC_CHECK_SIZEOF(cell_t)
 510
 511 # Now make sure that NULL can be represented as zero bytes.
 512 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 513 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 514 [[#include <stdlib.h>
 515 #include <string.h>
 516 #include <stdio.h>
 517 #ifdef HAVE_STDDEF_H
 518 #include <stddef.h>
 519 #endif
 520 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 521 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 522        [tor_cv_null_is_zero=yes],
 523        [tor_cv_null_is_zero=no],
 524        [tor_cv_null_is_zero=cross])])
 525
 526 if test "$tor_cv_null_is_zero" = cross ; then
 527   # Cross-compiling; let's hope that the target isn't raving mad.
 528   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 529 fi
 530
 531 if test "$tor_cv_null_is_zero" != no; then
 532   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 533             [Define to 1 iff memset(0) sets pointers to NULL])
 534 fi
 535
 536 # And what happens when we malloc zero?
 537 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 538 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 539 [[#include <stdlib.h>
 540 #include <string.h>
 541 #include <stdio.h>
 542 #ifdef HAVE_STDDEF_H
 543 #include <stddef.h>
 544 #endif
 545 int main () { return malloc(0)?0:1; }]])],
 546        [tor_cv_malloc_zero_works=yes],
 547        [tor_cv_malloc_zero_works=no],
 548        [tor_cv_malloc_zero_works=cross])])
 549
 550 if test "$tor_cv_malloc_zero_works" = cross; then
 551   # Cross-compiling; let's hope that the target isn't raving mad.
 552   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 553 fi
 554
 555 if test "$tor_cv_malloc_zero_works" = yes; then
 556   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 557             [Define to 1 iff malloc(0) returns a pointer])
 558 fi
 559
 560 # whether we seem to be in a 2s-complement world.
 561 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 562 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 563 [[int main () { int problem = ((-99) != (~99)+1);
 564 return problem ? 1 : 0; }]])],
 565        [tor_cv_twos_complement=yes],
 566        [tor_cv_twos_complement=no],
 567        [tor_cv_twos_complement=cross])])
 568
 569 if test "$tor_cv_twos_complement" = cross ; then
 570   # Cross-compiling; let's hope that the target isn't raving mad.
 571   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 572 fi
 573
 574 if test "$tor_cv_twos_complement" != no ; then
 575   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 576             [Define to 1 iff we represent negative integers with two's complement])
 577 fi
 578
 579 # Whether we should use the dmalloc memory allocation debugging library.
 580 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 581 AC_ARG_WITH(dmalloc,
 582 [  --with-dmalloc          Use debug memory allocation library. ],
 583 [if [[ "$withval" = "yes" ]]; then
 584   dmalloc=1
 585   AC_MSG_RESULT(yes)
 586 else
 587   dmalloc=1
 588   AC_MSG_RESULT(no)
 589 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 590 )
 591
 592 if [[ $dmalloc -eq 1 ]]; then
 593   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 594   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 595   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 596   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 597   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 598 fi
 599
 600 AC_ARG_WITH(tcmalloc,
 601 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 602 [ tcmalloc=yes ], [ tcmalloc=no ])
 603
 604 if test x$tcmalloc = xyes ; then
 605    LDFLAGS="-ltcmalloc $LDFLAGS"
 606 fi
 607
 608 # Allow user to specify an alternate syslog facility
 609 AC_ARG_WITH(syslog-facility,
 610 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 611 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 612 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 613 AC_SUBST(LOGFACILITY)
 614
 615 # Check for gethostbyname_r in all its glorious incompatible versions.
 616 #   (This logic is based on that in Python's configure.in)
 617 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 618   [Define this if you have any gethostbyname_r()])
 619
 620 AC_CHECK_FUNC(gethostbyname_r, [
 621   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 622   OLD_CFLAGS=$CFLAGS
 623   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 624   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 625 #include <netdb.h>
 626   ], [[
 627     char *cp1, *cp2;
 628     struct hostent *h1, *h2;
 629     int i1, i2;
 630     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 631   ]]),[
 632     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 633     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 634      [Define this if gethostbyname_r takes 6 arguments])
 635     AC_MSG_RESULT(6)
 636   ], [
 637     AC_TRY_COMPILE([
 638 #include <netdb.h>
 639     ], [
 640       char *cp1, *cp2;
 641       struct hostent *h1;
 642       int i1, i2;
 643       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 644     ], [
 645       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 646       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 647         [Define this if gethostbyname_r takes 5 arguments])
 648       AC_MSG_RESULT(5)
 649    ], [
 650       AC_TRY_COMPILE([
 651 #include <netdb.h>
 652      ], [
 653        char *cp1;
 654        struct hostent *h1;
 655        struct hostent_data hd;
 656        (void) gethostbyname_r(cp1,h1,&hd);
 657      ], [
 658        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 659        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 660          [Define this if gethostbyname_r takes 3 arguments])
 661        AC_MSG_RESULT(3)
 662      ], [
 663        AC_MSG_RESULT(0)
 664      ])
 665   ])
 666  ])
 667  CFLAGS=$OLD_CFLAGS
 668 ])
 669
 670 AC_CACHE_CHECK([whether the C compiler supports __func__],
 671   tor_cv_have_func_macro,
 672   AC_COMPILE_IFELSE([
 673 #include <stdio.h>
 674 int main(int c, char **v) { puts(__func__); }],
 675   tor_cv_have_func_macro=yes,
 676   tor_cv_have_func_macro=no))
 677
 678 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 679   tor_cv_have_FUNC_macro,
 680   AC_COMPILE_IFELSE([
 681 #include <stdio.h>
 682 int main(int c, char **v) { puts(__FUNC__); }],
 683   tor_cv_have_FUNC_macro=yes,
 684   tor_cv_have_FUNC_macro=no))
 685
 686 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 687   tor_cv_have_FUNCTION_macro,
 688   AC_COMPILE_IFELSE([
 689 #include <stdio.h>
 690 int main(int c, char **v) { puts(__FUNCTION__); }],
 691   tor_cv_have_FUNCTION_macro=yes,
 692   tor_cv_have_FUNCTION_macro=no))
 693
 694 if test "$tor_cv_have_func_macro" = 'yes'; then
 695   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 696 fi
 697
 698 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 699   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 700 fi
 701
 702 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 703   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 704            [Defined if the compiler supports __FUNCTION__])
 705 fi
 706
 707 # $prefix stores the value of the --prefix command line option, or
 708 # NONE if the option wasn't set.  In the case that it wasn't set, make
 709 # it be the default, so that we can use it to expand directories now.
 710 if test "x$prefix" = "xNONE"; then
 711   prefix=$ac_default_prefix
 712 fi
 713
 714 # and similarly for $exec_prefix
 715 if test "x$exec_prefix" = "xNONE"; then
 716   exec_prefix=$prefix
 717 fi
 718
 719 if test "x$CONFDIR" = "x"; then
 720   CONFDIR=`eval echo $sysconfdir/tor`
 721 fi
 722 AC_SUBST(CONFDIR)
 723 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 724 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 725
 726 BINDIR=`eval echo $bindir`
 727 AC_SUBST(BINDIR)
 728 LOCALSTATEDIR=`eval echo $localstatedir`
 729 AC_SUBST(LOCALSTATEDIR)
 730
 731 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 732 # than autoconf's macros like.
 733 if test "$ac_cv_c_compiler_gnu" = yes; then
 734   CFLAGS="$CFLAGS -Wall -g -O2"
 735 else
 736   CFLAGS="$CFLAGS -g -O"
 737   enable_gcc_warnings=no
 738 fi
 739
 740 # Add some more warnings which we use in development but not in the
 741 # released versions.  (Some relevant gcc versions can't handle these.)
 742 if test x$enable_gcc_warnings = xyes; then
 743
 744   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 745 #if !defined(__GNUC__) || (__GNUC__ < 4)
 746 #error
 747 #endif]), have_gcc4=yes, have_gcc4=no)
 748
 749   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 750 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 751 #error
 752 #endif]), have_gcc42=yes, have_gcc42=no)
 753
 754   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 755 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 756 #error
 757 #endif]), have_gcc43=yes, have_gcc43=no)
 758
 759   save_CFLAGS="$CFLAGS"
 760   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 761   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 762                     have_shorten64_flag=no)
 763   CFLAGS="$save_CFLAGS"
 764
 765   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 766
 767   # Disabled, so we can use mallinfo(): -Waggregate-return
 768
 769   if test x$have_gcc4 = xyes ; then
 770     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 771     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 772   fi
 773
 774   if test x$have_gcc42 = xyes ; then
 775     # These warnings break gcc 4.0.2 and work on gcc 4.2
 776     # XXXX020 Use -fstack-protector.
 777     # XXXX020 See if any of these work with earlier versions.
 778     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 779     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 780   fi
 781
 782   if test x$have_gcc43 = xyes ; then
 783     # These warnings break gcc 4.2 and work on gcc 4.3
 784     # XXXX020 See if any of these work with earlier versions.
 785     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 786   fi
 787
 788   if test x$have_shorten64_flag = xyes ; then
 789     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 790   fi
 791
 792 ##This will break the world on some 64-bit architectures
 793 # CFLAGS="$CFLAGS -Winline"
 794 fi
 795
 796
 797
 798 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 799
 800 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 801 AC_OUTPUT
 802
 803 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 804   ./contrib/updateVersions.pl
 805 fi
 806