configure.in

   1 dnl $Id$
   2 dnl Copyright 2001-2004 Roger Dingledine
   3 dnl Copyright 2004-2005 Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.1.0.5-rc-cvs)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release; then
  13     CFLAGS="$CFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 AC_ARG_ENABLE(debug,
  17  AC_HELP_STRING(--enable-debug, compile with debugging info),
  18 [if test x$enableval = xyes; then
  19     CFLAGS="$CFLAGS -g"
  20 fi])
  21
  22 AC_ARG_ENABLE(threads,
  23      AC_HELP_STRING(--disable-threads, disable multi-threading support))
  24
  25 if test x$enable_threads = x; then
  26    case $ac_sys_system in
  27     NetBSD*)
  28      enable_threads="no";;
  29     *)
  30      enable_threads="yes";;
  31    esac
  32 fi
  33
  34 if test $enable_threads = "yes"; then
  35   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  36 fi
  37
  38 AC_PROG_CC
  39 AC_PROG_MAKE_SET
  40 AC_PROG_RANLIB
  41
  42 # The big search for OpenSSL
  43 # copied from openssh's configure.ac
  44 AC_ARG_WITH(ssl-dir,
  45         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
  46         [
  47                 if test "x$withval" != "xno" ; then
  48                         tryssldir=$withval
  49                 fi
  50         ]
  51 )
  52
  53 AC_SEARCH_LIBS(socket, [socket])
  54 AC_SEARCH_LIBS(gethostbyname, [nsl])
  55 AC_SEARCH_LIBS(pthread_create, [pthread])
  56 AC_SEARCH_LIBS(pthread_detach, [pthread])
  57 AC_SEARCH_LIBS(event_loop, [event], , AC_MSG_ERROR(Libevent library not found. Tor requires libevent to build.  You can get the latest version of libevent at http://www.monkey.org/~provos/libevent/ ))
  58
  59 saved_LIBS="$LIBS"
  60 saved_LDFLAGS="$LDFLAGS"
  61 saved_CPPFLAGS="$CPPFLAGS"
  62 if test "x$prefix" != "xNONE" ; then
  63         tryssldir="$tryssldir $prefix"
  64 fi
  65 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
  66         for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /usr/pkg /opt /opt/openssl ; do
  67                 CPPFLAGS="$saved_CPPFLAGS"
  68                 LDFLAGS="$saved_LDFLAGS"
  69                 LIBS="$saved_LIBS -lssl -lcrypto"
  70
  71                 # Skip directories if they don't exist
  72                 if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
  73                         continue;
  74                 fi
  75                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
  76                         # Try to use $ssldir/lib if it exists, otherwise
  77                         # $ssldir
  78                         if test -d "$ssldir/lib" ; then
  79                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
  80                                 if test ! -z "$need_dash_r" ; then
  81                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
  82                                 fi
  83                         else
  84                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
  85                                 if test ! -z "$need_dash_r" ; then
  86                                         LDFLAGS="-R$ssldir $LDFLAGS"
  87                                 fi
  88                         fi
  89                         # Try to use $ssldir/include if it exists, otherwise
  90                         # $ssldir
  91                         if test -d "$ssldir/include" ; then
  92                                 CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
  93                         else
  94                                 CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
  95                         fi
  96                 fi
  97
  98                 # Basic test to check for compatible version and correct linking
  99                 # *does not* test for RSA - that comes later.
 100                 AC_TRY_RUN(
 101                         [
 102 #include <string.h>
 103 #include <openssl/rand.h>
 104 int main(void)
 105 {
 106         char a[2048];
 107         memset(a, 0, sizeof(a));
 108         RAND_add(a, sizeof(a), sizeof(a));
 109         return(RAND_status() <= 0);
 110 }
 111                         ],
 112                         [
 113                                 found_crypto=1
 114                                 break;
 115                         ], []
 116                 )
 117
 118                 if test ! -z "$found_crypto" ; then
 119                         break;
 120                 fi
 121         done
 122
 123         if test -z "$found_crypto" ; then
 124                 AC_MSG_ERROR([Could not find working OpenSSL library, please install or check config.log])
 125         fi
 126         if test -z "$ssldir" ; then
 127                 ssldir="(system)"
 128         fi
 129
 130         ac_cv_openssldir=$ssldir
 131 ])
 132 if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ;
 133  then
 134         dnl Need to recover ssldir - test above runs in subshell
 135         ssldir=$ac_cv_openssldir
 136         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 137                 # Try to use $ssldir/lib if it exists, otherwise
 138                 # $ssldir
 139                 if test -d "$ssldir/lib" ; then
 140                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 141                         if test ! -z "$need_dash_r" ; then
 142                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 143                         fi
 144                 else
 145                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 146                         if test ! -z "$need_dash_r" ; then
 147                                 LDFLAGS="-R$ssldir $LDFLAGS"
 148                         fi
 149                 fi
 150                 # Try to use $ssldir/include if it exists, otherwise
 151                 # $ssldir
 152                 if test -d "$ssldir/include" ; then
 153                         CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 154                 else
 155                         CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 156                 fi
 157         fi
 158 fi
 159 LIBS="$saved_LIBS"
 160
 161 AC_SYS_LARGEFILE
 162
 163 dnl The warning message here is no longer strictly accurate.
 164
 165 AC_CHECK_HEADERS(unistd.h string.h signal.h netdb.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/ioctl.h sys/socket.h sys/time.h netinet/in.h arpa/inet.h errno.h assert.h time.h pwd.h grp.h, , AC_MSG_WARN(some headers were not found, compilation may fail))
 166
 167 AC_CHECK_HEADERS(event.h, , AC_MSG_ERROR(Libevent header (event.h) not found. Tor requires libevent to build.))
 168
 169 AC_CHECK_HEADERS(zlib.h, , AC_MSG_ERROR(Zlib header (zlib.h) not found. Tor requires zlib to build. You may need to install a zlib development package.))
 170
 171 dnl These headers are not essential
 172
 173 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h pthread.h stddef.h inttypes.h)
 174
 175 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit setrlimit strlcat strlcpy strtoull getpwnam ftello pthread_create getaddrinfo localtime_r gmtime_r event_get_version event_get_method event_set_log_callback)
 176 AC_FUNC_FSEEKO
 177
 178 AC_CHECK_MEMBERS([struct timeval.tv_sec])
 179
 180
 181 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 182 dnl Watch out.
 183
 184 AC_CHECK_SIZEOF(int8_t)
 185 AC_CHECK_SIZEOF(int16_t)
 186 AC_CHECK_SIZEOF(int32_t)
 187 AC_CHECK_SIZEOF(int64_t)
 188 AC_CHECK_SIZEOF(uint8_t)
 189 AC_CHECK_SIZEOF(uint16_t)
 190 AC_CHECK_SIZEOF(uint32_t)
 191 AC_CHECK_SIZEOF(uint64_t)
 192 AC_CHECK_SIZEOF(intptr_t)
 193 AC_CHECK_SIZEOF(uintptr_t)
 194
 195 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 196
 197 AC_CHECK_SIZEOF(char)
 198 AC_CHECK_SIZEOF(short)
 199 AC_CHECK_SIZEOF(int)
 200 AC_CHECK_SIZEOF(long)
 201 AC_CHECK_SIZEOF(long long)
 202 AC_CHECK_SIZEOF(__int64)
 203 AC_CHECK_SIZEOF(void *)
 204 AC_CHECK_SIZEOF(time_t)
 205 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 206 #ifdef HAVE_SYS_SOCKET_H
 207 #include <sys/socket.h>
 208 #endif
 209 ])
 210
 211 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 212
 213 AC_CHECK_SIZEOF(cell_t)
 214
 215 # Now, let's see about alignment requirements.  On some platforms, we override
 216 # the default.
 217 case $host in
 218  ia64-*-* | arm-*-* )
 219     tor_cv_unaligned_ok=no
 220     ;;
 221  *)
 222 AC_CACHE_CHECK([whether unaligned int access is allowed], tor_cv_unaligned_ok,
 223 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 224 [[int main () { char s[] = "A\x00\x00\x00\x00\x00\x00\x00";
 225 return *(int*)(&s[1]); }]])],
 226        [tor_cv_unaligned_ok=yes],
 227        [tor_cv_unaligned_ok=no],
 228        [tor_cv_unaligned_ok=cross])])
 229 esac
 230
 231 if test $tor_cv_unaligned_ok = yes; then
 232   AC_DEFINE([UNALIGNED_INT_ACCESS_OK], 1,
 233             [Define to 1 iff unaligned int access is allowed])
 234 fi
 235
 236 # Now make sure that NULL can be represented as zero bytes.
 237 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 238 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 239 [[#include <stdlib.h>
 240 #include <string.h>
 241 #include <stdio.h>
 242 #ifdef HAVE_STDDEF_H
 243 #include <stddef.h>
 244 #endif
 245 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 246 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 247        [tor_cv_null_is_zero=yes],
 248        [tor_cv_null_is_zero=no],
 249        [tor_cv_null_is_zero=cross])])
 250
 251 if test $tor_cv_null_is_zero = yes; then
 252   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 253             [Define to 1 iff memset(0) sets pointers to NULL])
 254 fi
 255
 256 # Whether we should use the dmalloc memory allocation debugging library.
 257 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 258 AC_ARG_WITH(dmalloc,
 259 [  --with-dmalloc          Use debug memory allocation library. ],
 260 [if [[ "$withval" = "yes" ]]; then
 261   dmalloc=1
 262   AC_MSG_RESULT(yes)
 263 else
 264   dmalloc=1
 265   AC_MSG_RESULT(no)
 266 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 267 )
 268
 269 if [[ $dmalloc -eq 1 ]]; then
 270   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 271   AC_SEARCH_LIBS(dmalloc_malloc, [dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 272   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 273   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 274 fi
 275
 276 # Check for gethostbyname_r in all its glorious incompatible versions.
 277 #   (This logic is based on that in Python's configure.in)
 278 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 279   [Define this if you have any gethostbyname_r()])
 280
 281 AC_CHECK_FUNC(gethostbyname_r, [
 282   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 283   OLD_CFLAGS=$CFLAGS
 284   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 285   AC_TRY_COMPILE([
 286 #include <netdb.h>
 287   ], [
 288     char *cp1, *cp2;
 289     struct hostent *h1, *h2;
 290     int i1, i2;
 291     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 292   ], [
 293     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 294     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 295      [Define this if gethostbyname_r takes 6 arguments])
 296     AC_MSG_RESULT(6)
 297   ], [
 298     AC_TRY_COMPILE([
 299 #include <netdb.h>
 300     ], [
 301       char *cp1, *cp2;
 302       struct hostent *h1;
 303       int i1, i2;
 304       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 305     ], [
 306       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 307       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 308         [Define this if gethostbyname_r takes 5 arguments])
 309       AC_MSG_RESULT(5)
 310    ], [
 311       AC_TRY_COMPILE([
 312 #include <netdb.h>
 313      ], [
 314        char *cp1;
 315        struct hostent *h1;
 316        struct hostent_data hd;
 317        (void) gethostbyname_r(cp1,h1,&hd);
 318      ], [
 319        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 320        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 321          [Define this if gethostbyname_r takes 3 arguments])
 322        AC_MSG_RESULT(3)
 323      ], [
 324        AC_MSG_RESULT(0)
 325      ])
 326   ])
 327  ])
 328  CFLAGS=$OLD_CFLAGS
 329 ])
 330
 331 # $prefix stores the value of the --prefix command line option, or
 332 # NONE if the option wasn't set.  In the case that it wasn't set, make
 333 # it be the default, so that we can use it to expand directories now.
 334 if test "x$prefix" = "xNONE"; then
 335   prefix=$ac_default_prefix
 336 fi
 337
 338 # and similarly for $exec_prefix
 339 if test "x$exec_prefix" = "xNONE"; then
 340   exec_prefix=$prefix
 341 fi
 342
 343 CONFDIR=`eval echo $sysconfdir/tor`
 344 AC_SUBST(CONFDIR)
 345 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 346 AC_DEFINE([CONFDIR], [], [tor's configuration directory])
 347
 348 BINDIR=`eval echo $bindir`
 349 AC_SUBST(BINDIR)
 350
 351 LOCALSTATEDIR=`eval echo $localstatedir`
 352 AC_SUBST(LOCALSTATEDIR)
 353 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 354 AC_DEFINE([LOCALSTATEDIR], [], [Default location to store state files.])
 355
 356 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 357 # than autoconf's macros like.
 358 CFLAGS="$CFLAGS -Wall -g -O2"
 359 # Add some more warnings which we use in the cvs version but not in the
 360 # released versions.  (Some relevant gcc versions can't handle these.)
 361 #CFLAGS="$CFLAGS -W -Wno-unused-parameter -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls"
 362 # Add these in when you feel like fun.
 363 #CFLAGS="$CFLAGS -Wbad-function-cast -Werror -Wdeclaration-after-statement"
 364
 365 echo "confdir: $CONFDIR"
 366
 367 AC_OUTPUT(Makefile tor.spec contrib/tor.sh contrib/torctl contrib/torify contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile)
 368
 369 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 370   ./contrib/updateVersions.pl
 371 fi
 372