configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.1.0-alpha-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45
  46
  47 if test x$enable_cell_pool != xno; then
  48   AC_DEFINE(ENABLE_CELL_POOL, 1,
  49             [Defined if we try to use the pool allocator for queued cells])
  50 fi
  51 if test x$enable_buf_freelists != xno; then
  52   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  53             [Defined if we try to use freelists for buffer RAM chunks])
  54 fi
  55 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  56
  57 AC_ARG_ENABLE(transparent,
  58      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  59      [case "${enableval}" in
  60         yes) transparent=true ;;
  61         no)  transparent=false ;;
  62         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  63       esac], [transparent=true])
  64
  65 AC_ARG_ENABLE(threads,
  66      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  67
  68 if test x$enable_threads = x; then
  69    case $host in
  70     *-*-solaris* )
  71      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  72      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  73 cpu workers lock up here, so I will disable threads.])
  74      enable_threads="no";;
  75     *)
  76      enable_threads="yes";;
  77    esac
  78 fi
  79
  80 if test "$enable_threads" = "yes"; then
  81   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  82 fi
  83
  84 case $host in
  85    *-*-solaris* )
  86      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  87      ;;
  88 esac
  89
  90 AC_ARG_ENABLE(geoip-stats,
  91      AS_HELP_STRING(--enable-geoip-stats, enable code for directories to collect per-country statistics))
  92
  93 if test "$enable_geoip_stats" = "yes"; then
  94   AC_DEFINE(ENABLE_GEOIP_STATS, 1, [Defined if we try to collect per-country statistics])
  95 fi
  96
  97 AC_ARG_ENABLE(gcc-warnings,
  98      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  99
 100 AC_PROG_CC
 101 AC_PROG_CPP
 102 AC_PROG_MAKE_SET
 103 AC_PROG_RANLIB
 104
 105 TORUSER=_tor
 106 AC_ARG_WITH(tor-user,
 107         [  --with-tor-user=NAME    Specify username for tor daemon ],
 108         [
 109            TORUSER=$withval
 110         ]
 111 )
 112 AC_SUBST(TORUSER)
 113
 114 TORGROUP=_tor
 115 AC_ARG_WITH(tor-group,
 116         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 117         [
 118            TORGROUP=$withval
 119         ]
 120 )
 121 AC_SUBST(TORGROUP)
 122
 123
 124 dnl If WIN32 is defined and non-zero, we are building for win32
 125 AC_MSG_CHECKING([for win32])
 126 AC_RUN_IFELSE([
 127 int main(int c, char **v) {
 128 #ifdef WIN32
 129 #if WIN32
 130   return 0;
 131 #else
 132   return 1;
 133 #endif
 134 #else
 135   return 2;
 136 #endif
 137 }],
 138 bwin32=true; AC_MSG_RESULT([yes]),
 139 bwin32=false; AC_MSG_RESULT([no]),
 140 bwin32=cross; AC_MSG_RESULT([cross])
 141 )
 142
 143 if test "$bwin32" = cross; then
 144 AC_MSG_CHECKING([for win32 (cross)])
 145 AC_COMPILE_IFELSE([
 146 #ifdef WIN32
 147 int main(int c, char **v) {return 0;}
 148 #else
 149 #error
 150 int main(int c, char **v) {return x(y);}
 151 #endif
 152 ],
 153 bwin32=true; AC_MSG_RESULT([yes]),
 154 bwin32=false; AC_MSG_RESULT([no]))
 155 fi
 156
 157 if test "$bwin32" = true; then
 158 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 159 fi
 160 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 161
 162 dnl Enable C99 when compiling with MIPSpro
 163 AC_MSG_CHECKING([for MIPSpro compiler])
 164 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 165 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 166 #error
 167   return x(y);
 168 #endif
 169 ]),
 170 bmipspro=false; AC_MSG_RESULT(no),
 171 bmipspro=true; AC_MSG_RESULT(yes))
 172
 173 if test "$bmipspro" = true; then
 174   CFLAGS="$CFLAGS -c99"
 175 fi
 176
 177 AC_C_BIGENDIAN
 178
 179 AC_SEARCH_LIBS(socket, [socket])
 180 AC_SEARCH_LIBS(gethostbyname, [nsl])
 181 AC_SEARCH_LIBS(dlopen, [dl])
 182 AC_SEARCH_LIBS(inet_aton, [resolv])
 183
 184 if test "$enable_threads" = "yes"; then
 185   AC_SEARCH_LIBS(pthread_create, [pthread])
 186   AC_SEARCH_LIBS(pthread_detach, [pthread])
 187 fi
 188
 189 dnl -------------------------------------------------------------------
 190 dnl Check for functions before libevent, since libevent-1.2 apparently
 191 dnl exports strlcpy without defining it in a header.
 192
 193 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop)
 194
 195 using_custom_malloc=no
 196 if test x$enable_openbsd_malloc = xyes ; then
 197    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 198    using_custom_malloc=yes
 199 fi
 200 if test x$tcmalloc = xyes ; then
 201    using_custom_malloc=yes
 202 fi
 203 if test $using_custom_malloc = no ; then
 204    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 205 fi
 206
 207 if test "$enable_threads" = "yes"; then
 208   AC_CHECK_HEADERS(pthread.h)
 209   AC_CHECK_FUNCS(pthread_create)
 210 fi
 211
 212 dnl ------------------------------------------------------
 213 dnl Where do you live, libevent?  And how do we call you?
 214
 215 if test "$bwin32" = true; then
 216   TOR_LIB_WS32=-lws2_32
 217   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 218   # think it's actually necessary.
 219   TOR_LIB_GDI=-lgdi32
 220 else
 221   TOR_LIB_WS32=
 222   TOR_LIB_GDI=
 223 fi
 224 AC_SUBST(TOR_LIB_WS32)
 225 AC_SUBST(TOR_LIB_GDI)
 226
 227 dnl We need to do this before we try our disgusting hack below.
 228 AC_CHECK_HEADERS([sys/types.h])
 229
 230 dnl This is a disgusting hack so we safely include older libevent headers.
 231 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 232 AC_CHECK_TYPE(u_int32_t, unsigned long)
 233 AC_CHECK_TYPE(u_int16_t, unsigned short)
 234 AC_CHECK_TYPE(u_int8_t, unsigned char)
 235
 236 tor_libevent_pkg_redhat="libevent"
 237 tor_libevent_pkg_debian="libevent-dev"
 238 tor_libevent_devpkg_redhat="libevent-devel"
 239 tor_libevent_devpkg_debian="libevent-dev"
 240
 241 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 242 #ifdef WIN32
 243 #include <winsock2.h>
 244 #endif
 245 #include <stdlib.h>
 246 #include <sys/time.h>
 247 #include <sys/types.h>
 248 #include <event.h>], [
 249 #ifdef WIN32
 250 #include <winsock2.h>
 251 #endif
 252 void exit(int); void *event_init(void);],
 253     [
 254 #ifdef WIN32
 255 {WSADATA d; WSAStartup(0x101,&d); }
 256 #endif
 257 event_init(); exit(0);
 258 ], [--with-libevent-dir], [/opt/libevent])
 259
 260 dnl Now check for particular libevent functions.
 261 save_LIBS="$LIBS"
 262 save_LDFLAGS="$LDFLAGS"
 263 save_CPPFLAGS="$CPPFLAGS"
 264 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 265 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 266 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 267 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 268 LIBS="$save_LIBS"
 269 LDFLAGS="$save_LDFLAGS"
 270 CPPFLAGS="$save_CPPFLAGS"
 271
 272 dnl ------------------------------------------------------
 273 dnl Where do you live, openssl?  And how do we call you?
 274
 275 tor_openssl_pkg_redhat="openssl"
 276 tor_openssl_pkg_debian="libssl"
 277 tor_openssl_devpkg_redhat="openssl-devel"
 278 tor_openssl_devpkg_debian="libssl-dev"
 279
 280 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 281     [#include <openssl/rand.h>],
 282     [void RAND_add(const void *buf, int num, double entropy);],
 283     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 284     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 285
 286 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 287
 288 dnl ------------------------------------------------------
 289 dnl Where do you live, zlib?  And how do we call you?
 290
 291 tor_openssl_pkg_redhat="zlib"
 292 tor_openssl_pkg_debian="zlib1g"
 293 tor_openssl_devpkg_redhat="zlib-devel"
 294 tor_openssl_devpkg_debian="zlib1g-dev"
 295
 296 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 297     [#include <zlib.h>],
 298     [const char * zlibVersion(void);],
 299     [zlibVersion(); exit(0);], [--with-zlib-dir],
 300     [/opt/zlib])
 301
 302 dnl Make sure to enable support for large off_t if available.
 303
 304 AC_SYS_LARGEFILE
 305
 306 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 307
 308 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 309
 310 dnl These headers are not essential
 311
 312 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 313
 314 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 315 [#ifdef HAVE_MALLOC_H
 316 #include <malloc.h>
 317 #endif
 318 #ifdef HAVE_MALLOC_MALLOC_H
 319 #include <malloc/malloc.h>
 320 #endif])
 321
 322 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 323 [#ifdef HAVE_SYS_TYPES_H
 324 #include <sys/types.h>
 325 #endif
 326 #ifdef HAVE_SYS_SOCKET_H
 327 #include <sys/socket.h>
 328 #endif])
 329 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 330 [#ifdef HAVE_SYS_TYPES_H
 331 #include <sys/types.h>
 332 #endif
 333 #ifdef HAVE_SYS_SOCKET_H
 334 #include <sys/socket.h>
 335 #endif
 336 #ifdef HAVE_NET_IF_H
 337 #include <net/if.h>
 338 #endif])
 339 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 340         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 341 [#ifdef HAVE_SYS_TYPES_H
 342 #include <sys/types.h>
 343 #endif
 344 #ifdef HAVE_SYS_SOCKET_H
 345 #include <sys/socket.h>
 346 #endif])
 347
 348 if test x$transparent = xtrue ; then
 349    transparent_ok=0
 350    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 351      transparent_ok=1
 352    fi
 353    if test x$linux_netfilter_ipv4 = x1 ; then
 354      transparent_ok=1
 355    fi
 356    if test x$transparent_ok = x1 ; then
 357      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 358      case $host in
 359        *-*-openbsd*)
 360          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 361      esac
 362    else
 363      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 364    fi
 365 fi
 366
 367 AC_FUNC_FSEEKO
 368
 369 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 370 [#ifdef HAVE_SYS_TYPES_H
 371 #include <sys/types.h>
 372 #endif
 373 #ifdef HAVE_SYS_TIME_H
 374 #include <sys/time.h>
 375 #endif])
 376
 377 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 378 dnl Watch out.
 379
 380 AC_CHECK_SIZEOF(int8_t)
 381 AC_CHECK_SIZEOF(int16_t)
 382 AC_CHECK_SIZEOF(int32_t)
 383 AC_CHECK_SIZEOF(int64_t)
 384 AC_CHECK_SIZEOF(uint8_t)
 385 AC_CHECK_SIZEOF(uint16_t)
 386 AC_CHECK_SIZEOF(uint32_t)
 387 AC_CHECK_SIZEOF(uint64_t)
 388 AC_CHECK_SIZEOF(intptr_t)
 389 AC_CHECK_SIZEOF(uintptr_t)
 390
 391 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 392
 393 AC_CHECK_SIZEOF(char)
 394 AC_CHECK_SIZEOF(short)
 395 AC_CHECK_SIZEOF(int)
 396 AC_CHECK_SIZEOF(long)
 397 AC_CHECK_SIZEOF(long long)
 398 AC_CHECK_SIZEOF(__int64)
 399 AC_CHECK_SIZEOF(void *)
 400 AC_CHECK_SIZEOF(time_t)
 401 AC_CHECK_SIZEOF(size_t)
 402
 403 AC_CHECK_TYPES([uint, u_char, ssize_t])
 404
 405 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 406 [#ifdef HAVE_SYS_TYPES_H
 407 #include <sys/types.h>
 408 #endif
 409 #ifdef HAVE_NETINET_IN_H
 410 #include <netinet/in.h>
 411 #endif
 412 #ifdef HAVE_NETINET_IN6_H
 413 #include <netinet/in6.h>
 414 #endif
 415 #ifdef HAVE_SYS_SOCKET_H
 416 #include <sys/socket.h>
 417 #endif
 418 #ifdef MS_WINDOWS
 419 #define WIN32_WINNT 0x400
 420 #define _WIN32_WINNT 0x400
 421 #define WIN32_LEAN_AND_MEAN
 422 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 423 #include <winsock.h>
 424 #else
 425 #include <winsock2.h>
 426 #include <ws2tcpip.h>
 427 #endif
 428 #endif
 429 ])
 430 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 431 [#ifdef HAVE_SYS_TYPES_H
 432 #include <sys/types.h>
 433 #endif
 434 #ifdef HAVE_NETINET_IN_H
 435 #include <netinet/in.h>
 436 #endif
 437 #ifdef HAVE_NETINET_IN6_H
 438 #include <netinet/in6.h>
 439 #endif
 440 #ifdef HAVE_SYS_SOCKET_H
 441 #include <sys/socket.h>
 442 #endif
 443 #ifdef MS_WINDOWS
 444 #define WIN32_WINNT 0x400
 445 #define _WIN32_WINNT 0x400
 446 #define WIN32_LEAN_AND_MEAN
 447 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 448 #include <winsock.h>
 449 #else
 450 #include <winsock2.h>
 451 #include <ws2tcpip.h>
 452 #endif
 453 #endif
 454 ])
 455
 456 AC_CHECK_TYPES([rlim_t], , ,
 457 [#ifdef HAVE_SYS_TYPES_H
 458 #include <sys/types.h>
 459 #endif
 460 #ifdef HAVE_SYS_TIME_H
 461 #include <sys/time.h>
 462 #endif
 463 #ifdef HAVE_SYS_RESOURCE_H
 464 #include <sys/resource.h>
 465 #endif
 466 ])
 467
 468 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 469 AC_RUN_IFELSE(AC_LANG_SOURCE([
 470 #ifdef HAVE_SYS_TYPES_H
 471 #include <sys/types.h>
 472 #endif
 473 #ifdef HAVE_SYS_TIME_H
 474 #include <sys/time.h>
 475 #endif
 476 #ifdef HAVE_TIME_H
 477 #include <time.h>
 478 #endif
 479 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 480   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 481 ])
 482
 483 if test "$tor_cv_time_t_signed" = cross; then
 484   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 485 fi
 486
 487 if test "$tor_cv_time_t_signed" != no; then
 488   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 489             [Define to 1 iff time_t is signed])
 490 fi
 491
 492 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 493 #ifdef HAVE_SYS_SOCKET_H
 494 #include <sys/socket.h>
 495 #endif
 496 ])
 497
 498 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 499
 500 AC_CHECK_SIZEOF(cell_t)
 501
 502 # Now make sure that NULL can be represented as zero bytes.
 503 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 504 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 505 [[#include <stdlib.h>
 506 #include <string.h>
 507 #include <stdio.h>
 508 #ifdef HAVE_STDDEF_H
 509 #include <stddef.h>
 510 #endif
 511 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 512 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 513        [tor_cv_null_is_zero=yes],
 514        [tor_cv_null_is_zero=no],
 515        [tor_cv_null_is_zero=cross])])
 516
 517 if test "$tor_cv_null_is_zero" = cross ; then
 518   # Cross-compiling; let's hope that the target isn't raving mad.
 519   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 520 fi
 521
 522 if test "$tor_cv_null_is_zero" != no; then
 523   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 524             [Define to 1 iff memset(0) sets pointers to NULL])
 525 fi
 526
 527 # And what happens when we malloc zero?
 528 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 529 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 530 [[#include <stdlib.h>
 531 #include <string.h>
 532 #include <stdio.h>
 533 #ifdef HAVE_STDDEF_H
 534 #include <stddef.h>
 535 #endif
 536 int main () { return malloc(0)?0:1; }]])],
 537        [tor_cv_malloc_zero_works=yes],
 538        [tor_cv_malloc_zero_works=no],
 539        [tor_cv_malloc_zero_works=cross])])
 540
 541 if test "$tor_cv_malloc_zero_works" = cross; then
 542   # Cross-compiling; let's hope that the target isn't raving mad.
 543   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 544 fi
 545
 546 if test "$tor_cv_malloc_zero_works" = yes; then
 547   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 548             [Define to 1 iff malloc(0) returns a pointer])
 549 fi
 550
 551 # whether we seem to be in a 2s-complement world.
 552 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 553 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 554 [[int main () { int problem = ((-99) != (~99)+1);
 555 return problem ? 1 : 0; }]])],
 556        [tor_cv_twos_complement=yes],
 557        [tor_cv_twos_complement=no],
 558        [tor_cv_twos_complement=cross])])
 559
 560 if test "$tor_cv_twos_complement" = cross ; then
 561   # Cross-compiling; let's hope that the target isn't raving mad.
 562   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 563 fi
 564
 565 if test "$tor_cv_twos_complement" != no ; then
 566   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 567             [Define to 1 iff we represent negative integers with two's complement])
 568 fi
 569
 570 # Whether we should use the dmalloc memory allocation debugging library.
 571 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 572 AC_ARG_WITH(dmalloc,
 573 [  --with-dmalloc          Use debug memory allocation library. ],
 574 [if [[ "$withval" = "yes" ]]; then
 575   dmalloc=1
 576   AC_MSG_RESULT(yes)
 577 else
 578   dmalloc=1
 579   AC_MSG_RESULT(no)
 580 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 581 )
 582
 583 if [[ $dmalloc -eq 1 ]]; then
 584   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 585   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 586   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 587   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 588   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 589 fi
 590
 591 AC_ARG_WITH(tcmalloc,
 592 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 593 [ tcmalloc=yes ], [ tcmalloc=no ])
 594
 595 if test x$tcmalloc = xyes ; then
 596    LDFLAGS="-ltcmalloc $LDFLAGS"
 597 fi
 598
 599 # Allow user to specify an alternate syslog facility
 600 AC_ARG_WITH(syslog-facility,
 601 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 602 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 603 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 604 AC_SUBST(LOGFACILITY)
 605
 606 # Check for gethostbyname_r in all its glorious incompatible versions.
 607 #   (This logic is based on that in Python's configure.in)
 608 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 609   [Define this if you have any gethostbyname_r()])
 610
 611 AC_CHECK_FUNC(gethostbyname_r, [
 612   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 613   OLD_CFLAGS=$CFLAGS
 614   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 615   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 616 #include <netdb.h>
 617   ], [[
 618     char *cp1, *cp2;
 619     struct hostent *h1, *h2;
 620     int i1, i2;
 621     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 622   ]]),[
 623     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 624     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 625      [Define this if gethostbyname_r takes 6 arguments])
 626     AC_MSG_RESULT(6)
 627   ], [
 628     AC_TRY_COMPILE([
 629 #include <netdb.h>
 630     ], [
 631       char *cp1, *cp2;
 632       struct hostent *h1;
 633       int i1, i2;
 634       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 635     ], [
 636       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 637       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 638         [Define this if gethostbyname_r takes 5 arguments])
 639       AC_MSG_RESULT(5)
 640    ], [
 641       AC_TRY_COMPILE([
 642 #include <netdb.h>
 643      ], [
 644        char *cp1;
 645        struct hostent *h1;
 646        struct hostent_data hd;
 647        (void) gethostbyname_r(cp1,h1,&hd);
 648      ], [
 649        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 650        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 651          [Define this if gethostbyname_r takes 3 arguments])
 652        AC_MSG_RESULT(3)
 653      ], [
 654        AC_MSG_RESULT(0)
 655      ])
 656   ])
 657  ])
 658  CFLAGS=$OLD_CFLAGS
 659 ])
 660
 661 AC_CACHE_CHECK([whether the C compiler supports __func__],
 662   tor_cv_have_func_macro,
 663   AC_COMPILE_IFELSE([
 664 #include <stdio.h>
 665 int main(int c, char **v) { puts(__func__); }],
 666   tor_cv_have_func_macro=yes,
 667   tor_cv_have_func_macro=no))
 668
 669 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 670   tor_cv_have_FUNC_macro,
 671   AC_COMPILE_IFELSE([
 672 #include <stdio.h>
 673 int main(int c, char **v) { puts(__FUNC__); }],
 674   tor_cv_have_FUNC_macro=yes,
 675   tor_cv_have_FUNC_macro=no))
 676
 677 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 678   tor_cv_have_FUNCTION_macro,
 679   AC_COMPILE_IFELSE([
 680 #include <stdio.h>
 681 int main(int c, char **v) { puts(__FUNCTION__); }],
 682   tor_cv_have_FUNCTION_macro=yes,
 683   tor_cv_have_FUNCTION_macro=no))
 684
 685 if test "$tor_cv_have_func_macro" = 'yes'; then
 686   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 687 fi
 688
 689 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 690   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 691 fi
 692
 693 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 694   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 695            [Defined if the compiler supports __FUNCTION__])
 696 fi
 697
 698 # $prefix stores the value of the --prefix command line option, or
 699 # NONE if the option wasn't set.  In the case that it wasn't set, make
 700 # it be the default, so that we can use it to expand directories now.
 701 if test "x$prefix" = "xNONE"; then
 702   prefix=$ac_default_prefix
 703 fi
 704
 705 # and similarly for $exec_prefix
 706 if test "x$exec_prefix" = "xNONE"; then
 707   exec_prefix=$prefix
 708 fi
 709
 710 if test "x$CONFDIR" = "x"; then
 711   CONFDIR=`eval echo $sysconfdir/tor`
 712 fi
 713 AC_SUBST(CONFDIR)
 714 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 715 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 716
 717 BINDIR=`eval echo $bindir`
 718 AC_SUBST(BINDIR)
 719 LOCALSTATEDIR=`eval echo $localstatedir`
 720 AC_SUBST(LOCALSTATEDIR)
 721
 722 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 723 # than autoconf's macros like.
 724 if test "$ac_cv_c_compiler_gnu" = yes; then
 725   CFLAGS="$CFLAGS -Wall -g -O2"
 726 else
 727   CFLAGS="$CFLAGS -g -O"
 728   enable_gcc_warnings=no
 729 fi
 730
 731 # Add some more warnings which we use in development but not in the
 732 # released versions.  (Some relevant gcc versions can't handle these.)
 733 if test x$enable_gcc_warnings = xyes; then
 734
 735   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 736 #if !defined(__GNUC__) || (__GNUC__ < 4)
 737 #error
 738 #endif]), have_gcc4=yes, have_gcc4=no)
 739
 740   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 741 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 742 #error
 743 #endif]), have_gcc42=yes, have_gcc42=no)
 744
 745   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 746 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 747 #error
 748 #endif]), have_gcc43=yes, have_gcc43=no)
 749
 750   save_CFLAGS="$CFLAGS"
 751   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 752   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 753                     have_shorten64_flag=no)
 754   CFLAGS="$save_CFLAGS"
 755
 756   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 757
 758   # Disabled, so we can use mallinfo(): -Waggregate-return
 759
 760   if test x$have_gcc4 = xyes ; then
 761     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 762     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 763   fi
 764
 765   if test x$have_gcc42 = xyes ; then
 766     # These warnings break gcc 4.0.2 and work on gcc 4.2
 767     # XXXX020 Use -fstack-protector.
 768     # XXXX020 See if any of these work with earlier versions.
 769     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 770     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 771   fi
 772
 773   if test x$have_gcc43 = xyes ; then
 774     # These warnings break gcc 4.2 and work on gcc 4.3
 775     # XXXX020 See if any of these work with earlier versions.
 776     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 777   fi
 778
 779   if test x$have_shorten64_flag = xyes ; then
 780     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 781   fi
 782
 783 ##This will break the world on some 64-bit architectures
 784 # CFLAGS="$CFLAGS -Winline"
 785 fi
 786
 787
 788
 789 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 790
 791 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 792 AC_OUTPUT
 793
 794 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 795   ./contrib/updateVersions.pl
 796 fi
 797