configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2007, Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.0.0-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13     CFLAGS="$CFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 AC_ARG_ENABLE(debug,
  17  AS_HELP_STRING(--enable-debug, compile with debugging info),
  18 [if test x$enableval = xyes; then
  19     CFLAGS="$CFLAGS -g"
  20 fi])
  21
  22 AC_ARG_ENABLE(cell-pool,
  23      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  24
  25 if test x$enable_cell_pool != xno; then
  26   AC_DEFINE(ENABLE_CELL_POOL, 1,
  27             [Defined if we try to use the pool allocator for queued cells])
  28 fi
  29
  30 AC_ARG_ENABLE(transparent,
  31      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  32      [case "${enableval}" in
  33         yes) transparent=true ;;
  34         no)  transparent=false ;;
  35         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  36       esac], [transparent=true])
  37
  38 AC_ARG_ENABLE(threads,
  39      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  40
  41 if test x$enable_threads = x; then
  42    case $host in
  43     *-*-solaris* )
  44      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  45      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  46 cpu workers lock up here, so I will disable threads.])
  47      enable_threads="no";;
  48     *)
  49      enable_threads="yes";;
  50    esac
  51 fi
  52
  53 if test $enable_threads = "yes"; then
  54   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  55 fi
  56
  57 case $host in
  58    *-*-solaris* )
  59      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  60      ;;
  61 esac
  62
  63 AC_ARG_ENABLE(gcc-warnings,
  64      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  65
  66 AC_PROG_CC
  67 AC_PROG_MAKE_SET
  68 AC_PROG_RANLIB
  69
  70 TORUSER=_tor
  71 AC_ARG_WITH(tor-user,
  72         [  --with-tor-user=NAME    Specify username for tor daemon ],
  73         [
  74            TORUSER=$withval
  75         ]
  76 )
  77 AC_SUBST(TORUSER)
  78
  79 TORGROUP=_tor
  80 AC_ARG_WITH(tor-group,
  81         [  --with-tor-group=NAME   Specify group name for tor daemon ],
  82         [
  83            TORGROUP=$withval
  84         ]
  85 )
  86 AC_SUBST(TORGROUP)
  87
  88
  89 dnl If WIN32 is defined and non-zero, we are building for win32
  90 AC_MSG_CHECKING([for win32])
  91 AC_RUN_IFELSE([
  92 int main(int c, char **v) {
  93 #ifdef WIN32
  94 #if WIN32
  95   return 0;
  96 #else
  97   return 1;
  98 #endif
  99 #else
 100   return 2;
 101 #endif
 102 }],
 103 bwin32=true; AC_MSG_RESULT([yes]),
 104 bwin32=false; AC_MSG_RESULT([no]),
 105 bwin32=cross; AC_MSG_RESULT([cross])
 106 )
 107
 108 if test $bwin32 = cross; then
 109 AC_MSG_CHECKING([for win32 (cross)])
 110 AC_COMPILE_IFELSE([
 111 #ifdef WIN32
 112 int main(int c, char **v) {return 0;}
 113 #else
 114 #error
 115 int main(int c, char **v) {return x(y);}
 116 #endif
 117 ],
 118 bwin32=true; AC_MSG_RESULT([yes]),
 119 bwin32=false; AC_MSG_RESULT([no]))
 120 fi
 121
 122 if test $bwin32 = true; then
 123 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 124 fi
 125
 126 dnl Enable C99 when compiling with MIPSpro
 127 AC_MSG_CHECKING([for MIPSpro compiler])
 128 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 129 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 130 #error
 131   return x(y);
 132 #endif
 133 ]),
 134 bmipspro=false; AC_MSG_RESULT(no),
 135 bmipspro=true; AC_MSG_RESULT(yes))
 136
 137 if test $bmipspro = true; then
 138   CFLAGS="$CFLAGS -c99"
 139 fi
 140
 141 AC_SEARCH_LIBS(socket, [socket])
 142 AC_SEARCH_LIBS(gethostbyname, [nsl])
 143 AC_SEARCH_LIBS(dlopen, [dl])
 144 AC_SEARCH_LIBS(inet_aton, [resolv])
 145
 146 if test $enable_threads = "yes"; then
 147   AC_SEARCH_LIBS(pthread_create, [pthread])
 148   AC_SEARCH_LIBS(pthread_detach, [pthread])
 149 fi
 150
 151 dnl -------------------------------------------------------------------
 152 dnl Check for functions before libevent, since libevent-1.2 apparently
 153 dnl exports strlcpy without defining it in a header.
 154
 155 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop)
 156
 157 if test $enable_threads = "yes"; then
 158   AC_CHECK_HEADERS(pthread.h)
 159   AC_CHECK_FUNCS(pthread_create)
 160 fi
 161
 162 dnl ------------------------------------------------------
 163 dnl Where do you live, libevent?  And how do we call you?
 164
 165 if test $bwin32 = true; then
 166   TOR_LIB_WS32=-lws2_32
 167   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 168   # think it's actually necessary.
 169   TOR_LIB_GDI=-lgdi32
 170 else
 171   TOR_LIB_WS32=
 172   TOR_LIB_GDI=
 173 fi
 174 AC_SUBST(TOR_LIB_WS32)
 175 AC_SUBST(TOR_LIB_GDI)
 176
 177 dnl This is a disgusting hack so we safely include recent libevent headers.
 178 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 179 AC_CHECK_TYPE(u_int32_t, unsigned long)
 180 AC_CHECK_TYPE(u_int16_t, unsigned short)
 181 AC_CHECK_TYPE(u_int8_t, unsigned char)
 182
 183 tor_libevent_pkg_redhat="libevent"
 184 tor_libevent_pkg_debian="libevent"
 185 tor_libevent_devpkg_redhat="libevent-devel"
 186 tor_libevent_devpkg_debian="libevent-dev"
 187
 188 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 189 #include <stdlib.h>
 190 #include <sys/time.h>
 191 #include <sys/types.h>
 192 #include <event.h>], [void exit(int); void *event_init(void);],
 193     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 194
 195 dnl Now check for particular libevent functions.
 196 save_LIBS="$LIBS"
 197 save_LDFLAGS="$LDFLAGS"
 198 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 199 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 200 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 201 LIBS="$save_LIBS"
 202 LDFLAGS="$save_LDFLAGS"
 203
 204 dnl ------------------------------------------------------
 205 dnl Where do you live, openssl?  And how do we call you?
 206
 207 tor_openssl_pkg_redhat="openssl"
 208 tor_openssl_pkg_debian="libssl"
 209 tor_openssl_devpkg_redhat="openssl-devel"
 210 tor_openssl_devpkg_debian="libssl-dev"
 211
 212 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 213     [#include <openssl/rand.h>],
 214     [void RAND_add(const void *buf, int num, double entropy);],
 215     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 216     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 217
 218 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 219
 220 dnl ------------------------------------------------------
 221 dnl Where do you live, zlib?  And how do we call you?
 222
 223 tor_openssl_pkg_redhat="zlib"
 224 tor_openssl_pkg_debian="zlib1g"
 225 tor_openssl_devpkg_redhat="zlib-devel"
 226 tor_openssl_devpkg_debian="zlib1g-dev"
 227
 228 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 229     [#include <zlib.h>],
 230     [const char * zlibVersion(void);],
 231     [zlibVersion(); exit(0);], [--with-zlib-dir],
 232     [/opt/zlib])
 233
 234 dnl Make sure to enable support for large off_t if avalable.
 235
 236 AC_SYS_LARGEFILE
 237
 238 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 239
 240 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h)
 241
 242 dnl These headers are not essential
 243
 244 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h)
 245
 246 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 247 [#ifdef HAVE_SYS_TYPES_H
 248 #include <sys/types.h>
 249 #endif
 250 #ifdef HAVE_SYS_SOCKET_H
 251 #include <sys/socket.h>
 252 #endif])
 253 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 254 [#ifdef HAVE_SYS_TYPES_H
 255 #include <sys/types.h>
 256 #endif
 257 #ifdef HAVE_SYS_SOCKET_H
 258 #include <sys/socket.h>
 259 #endif
 260 #ifdef HAVE_NET_IF_H
 261 #include <net/if.h>
 262 #endif])
 263 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 264         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 265 [#ifdef HAVE_SYS_TYPES_H
 266 #include <sys/types.h>
 267 #endif
 268 #ifdef HAVE_SYS_SOCKET_H
 269 #include <sys/socket.h>
 270 #endif])
 271
 272 if test x$transparent = xtrue ; then
 273    transparent_ok=0
 274    if test x$net_if_found = x1 -a x$net_pfvar_found = x1 ; then
 275      transparent_ok=1
 276    fi
 277    if test x$linux_netfilter_ipv4 = x1 ; then
 278      transparent_ok=1
 279    fi
 280    if test x$transparent_ok = x1 ; then
 281      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 282      case $host in
 283        *-*-openbsd*)
 284          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 285      esac
 286    else
 287      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 288    fi
 289 fi
 290
 291 AC_FUNC_FSEEKO
 292
 293 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 294 [#ifdef HAVE_SYS_TYPES_H
 295 #include <sys/types.h>
 296 #endif
 297 #ifdef HAVE_SYS_TIME_H
 298 #include <sys/time.h>
 299 #endif])
 300
 301 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 302 dnl Watch out.
 303
 304 AC_CHECK_SIZEOF(int8_t)
 305 AC_CHECK_SIZEOF(int16_t)
 306 AC_CHECK_SIZEOF(int32_t)
 307 AC_CHECK_SIZEOF(int64_t)
 308 AC_CHECK_SIZEOF(uint8_t)
 309 AC_CHECK_SIZEOF(uint16_t)
 310 AC_CHECK_SIZEOF(uint32_t)
 311 AC_CHECK_SIZEOF(uint64_t)
 312 AC_CHECK_SIZEOF(intptr_t)
 313 AC_CHECK_SIZEOF(uintptr_t)
 314
 315 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 316
 317 AC_CHECK_SIZEOF(char)
 318 AC_CHECK_SIZEOF(short)
 319 AC_CHECK_SIZEOF(int)
 320 AC_CHECK_SIZEOF(long)
 321 AC_CHECK_SIZEOF(long long)
 322 AC_CHECK_SIZEOF(__int64)
 323 AC_CHECK_SIZEOF(void *)
 324 AC_CHECK_SIZEOF(time_t)
 325 AC_CHECK_SIZEOF(size_t)
 326
 327 AC_CHECK_TYPES([uint, u_char])
 328
 329 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_storage], , ,
 330 [#ifdef HAVE_SYS_TYPES_H
 331 #include <sys/types.h>
 332 #endif
 333 #ifdef HAVE_NETINET_IN_H
 334 #include <netinet/in.h>
 335 #endif
 336 #ifdef HAVE_NETINET_IN6_H
 337 #include <netinet/in6.h>
 338 #endif
 339 #ifdef HAVE_SYS_SOCKET_H
 340 #include <sys/socket.h>
 341 #endif])
 342
 343 if test -z "$CROSS_COMPILE"; then
 344 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 345 AC_RUN_IFELSE(AC_LANG_SOURCE([
 346 #ifdef HAVE_SYS_TYPES_H
 347 #include <sys/types.h>
 348 #endif
 349 #ifdef HAVE_SYS_TIME_H
 350 #include <sys/time.h>
 351 #endif
 352 #ifdef HAVE_TIME_H
 353 #include <time.h>
 354 #endif
 355 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 356   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes)
 357 ])
 358 else
 359   # Cross-compiling; let's hope the target platform isn't loony.
 360   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 361   tor_cv_time_t_signed=yes
 362 fi
 363
 364 if test $tor_cv_time_t_signed = yes; then
 365   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 366             [Define to 1 iff time_t is signed])
 367 fi
 368
 369 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 370 #ifdef HAVE_SYS_SOCKET_H
 371 #include <sys/socket.h>
 372 #endif
 373 ])
 374
 375 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 376
 377 AC_CHECK_SIZEOF(cell_t)
 378
 379 # Now make sure that NULL can be represented as zero bytes.
 380 if test -z "$CROSS_COMPILE"; then
 381 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 382 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 383 [[#include <stdlib.h>
 384 #include <string.h>
 385 #include <stdio.h>
 386 #ifdef HAVE_STDDEF_H
 387 #include <stddef.h>
 388 #endif
 389 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 390 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 391        [tor_cv_null_is_zero=yes],
 392        [tor_cv_null_is_zero=no],
 393        [tor_cv_null_is_zero=cross])])
 394
 395 else
 396   # Cross-compiling; let's hope that the target isn't raving mad.
 397   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 398   tor_cv_null_is_zero=yes
 399 fi
 400
 401 if test $tor_cv_null_is_zero = yes; then
 402   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 403             [Define to 1 iff memset(0) sets pointers to NULL])
 404 fi
 405
 406 # And what happens when we malloc zero?
 407
 408 if test -z "$CROSS_COMPILE"; then
 409 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 410 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 411 [[#include <stdlib.h>
 412 #include <string.h>
 413 #include <stdio.h>
 414 #ifdef HAVE_STDDEF_H
 415 #include <stddef.h>
 416 #endif
 417 int main () { return malloc(0)?0:1; }]])],
 418        [tor_cv_malloc_zero_works=yes],
 419        [tor_cv_malloc_zero_works=no],
 420        [tor_cv_malloc_zero_works=cross])])
 421
 422 else
 423   # Cross-compiling; let's hope that the target isn't raving mad.
 424   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 425   tor_cv_malloc_zero_works=no
 426 fi
 427
 428 if test $tor_cv_malloc_zero_works = yes; then
 429   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 430             [Define to 1 iff malloc(0) returns a pointer])
 431 fi
 432
 433 # whether we seem to be in a 2s-complement world.
 434 if test -z "$CROSS_COMPILE"; then
 435 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 436 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 437 [[int main () { int problem = ((-99) != (~99)+1);
 438 return problem ? 1 : 0; }]])],
 439        [tor_cv_twos_complement=yes],
 440        [tor_cv_twos_complement=no],
 441        [tor_cv_twos_complement=cross])])
 442
 443 else
 444   # Cross-compiling; let's hope that the target isn't raving mad.
 445   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 446   tor_cv_twos_complement=yes
 447 fi
 448
 449 if test $tor_cv_twos_complement = yes; then
 450   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 451             [Define to 1 iff we represent negative integers with two's complement])
 452 fi
 453
 454 # Whether we should use the dmalloc memory allocation debugging library.
 455 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 456 AC_ARG_WITH(dmalloc,
 457 [  --with-dmalloc          Use debug memory allocation library. ],
 458 [if [[ "$withval" = "yes" ]]; then
 459   dmalloc=1
 460   AC_MSG_RESULT(yes)
 461 else
 462   dmalloc=1
 463   AC_MSG_RESULT(no)
 464 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 465 )
 466
 467 if [[ $dmalloc -eq 1 ]]; then
 468   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 469   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 470   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 471   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 472 fi
 473
 474 # Allow user to specify an alternate syslog facility
 475 AC_ARG_WITH(syslog-facility,
 476 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 477 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 478 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 479 AC_SUBST(LOGFACILITY)
 480
 481 # Check for gethostbyname_r in all its glorious incompatible versions.
 482 #   (This logic is based on that in Python's configure.in)
 483 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 484   [Define this if you have any gethostbyname_r()])
 485
 486 AC_CHECK_FUNC(gethostbyname_r, [
 487   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 488   OLD_CFLAGS=$CFLAGS
 489   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 490   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 491 #include <netdb.h>
 492   ], [[
 493     char *cp1, *cp2;
 494     struct hostent *h1, *h2;
 495     int i1, i2;
 496     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 497   ]]),[
 498     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 499     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 500      [Define this if gethostbyname_r takes 6 arguments])
 501     AC_MSG_RESULT(6)
 502   ], [
 503     AC_TRY_COMPILE([
 504 #include <netdb.h>
 505     ], [
 506       char *cp1, *cp2;
 507       struct hostent *h1;
 508       int i1, i2;
 509       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 510     ], [
 511       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 512       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 513         [Define this if gethostbyname_r takes 5 arguments])
 514       AC_MSG_RESULT(5)
 515    ], [
 516       AC_TRY_COMPILE([
 517 #include <netdb.h>
 518      ], [
 519        char *cp1;
 520        struct hostent *h1;
 521        struct hostent_data hd;
 522        (void) gethostbyname_r(cp1,h1,&hd);
 523      ], [
 524        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 525        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 526          [Define this if gethostbyname_r takes 3 arguments])
 527        AC_MSG_RESULT(3)
 528      ], [
 529        AC_MSG_RESULT(0)
 530      ])
 531   ])
 532  ])
 533  CFLAGS=$OLD_CFLAGS
 534 ])
 535
 536 AC_CACHE_CHECK([whether the C compiler supports __func__],
 537   tor_cv_have_func_macro,
 538   AC_COMPILE_IFELSE([
 539 #include <stdio.h>
 540 int main(int c, char **v) { puts(__func__); }],
 541   tor_cv_have_func_macro=yes,
 542   tor_cv_have_func_macro=no))
 543
 544 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 545   tor_cv_have_FUNC_macro,
 546   AC_COMPILE_IFELSE([
 547 #include <stdio.h>
 548 int main(int c, char **v) { puts(__FUNC__); }],
 549   tor_cv_have_FUNC_macro=yes,
 550   tor_cv_have_FUNC_macro=no))
 551
 552 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 553   tor_cv_have_FUNCTION_macro,
 554   AC_COMPILE_IFELSE([
 555 #include <stdio.h>
 556 int main(int c, char **v) { puts(__FUNCTION__); }],
 557   tor_cv_have_FUNCTION_macro=yes,
 558   tor_cv_have_FUNCTION_macro=no))
 559
 560 if test $tor_cv_have_func_macro = 'yes'; then
 561   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 562 fi
 563
 564 if test $tor_cv_have_FUNC_macro = 'yes'; then
 565   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 566 fi
 567
 568 if test $tor_cv_have_FUNCTION_macro = 'yes'; then
 569   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 570            [Defined if the compiler supports __FUNCTION__])
 571 fi
 572
 573 # $prefix stores the value of the --prefix command line option, or
 574 # NONE if the option wasn't set.  In the case that it wasn't set, make
 575 # it be the default, so that we can use it to expand directories now.
 576 if test "x$prefix" = "xNONE"; then
 577   prefix=$ac_default_prefix
 578 fi
 579
 580 # and similarly for $exec_prefix
 581 if test "x$exec_prefix" = "xNONE"; then
 582   exec_prefix=$prefix
 583 fi
 584
 585 if test "x$CONFDIR" = "x"; then
 586   CONFDIR=`eval echo $sysconfdir/tor`
 587 fi
 588 AC_SUBST(CONFDIR)
 589 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 590 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 591
 592 BINDIR=`eval echo $bindir`
 593 AC_SUBST(BINDIR)
 594
 595 LOCALSTATEDIR=`eval echo $localstatedir`
 596 AC_SUBST(LOCALSTATEDIR)
 597 AH_TEMPLATE([LOCALSTATEDIR], [Default location to store state files.])
 598 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 599
 600 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 601 # than autoconf's macros like.
 602 if test $ac_cv_c_compiler_gnu = yes; then
 603   CFLAGS="$CFLAGS -Wall -g -O2"
 604 else
 605   CFLAGS="$CFLAGS -g -O"
 606   enable_gcc_warnings=no
 607 fi
 608
 609 # Add some more warnings which we use in the cvs version but not in the
 610 # released versions.  (Some relevant gcc versions can't handle these.)
 611 if test x$enable_gcc_warnings = xyes; then
 612
 613   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 614 #if !defined(__GNUC__) || (__GNUC__ < 4)
 615 #error
 616 #endif]), have_gcc4=yes, have_gcc4=no)
 617
 618   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 619 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 620 #error
 621 #endif]), have_gcc42=yes, have_gcc42=no)
 622
 623   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Waggregate-return -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 624
 625   if test x$have_gcc4 = xyes ; then
 626     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 627     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 628   fi
 629
 630   if test x$have_gcc42 = xyes ; then
 631     # These warnings break gcc 4.0.2 and work on gcc 4.2
 632     # XXXX020 Use -fstack-protector.
 633     # XXXX020 See if any of these work with earlier versions.
 634     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 635   fi
 636
 637 ##This will break the world on some 64-bit architectures
 638 # CFLAGS="$CFLAGS -Winline"
 639
 640 fi
 641
 642 AC_CONFIG_FILES([Makefile tor.spec contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 643 AC_OUTPUT
 644
 645 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 646   ./contrib/updateVersions.pl
 647 fi
 648