configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.0.27-rc-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45
  46
  47 if test x$enable_cell_pool != xno; then
  48   AC_DEFINE(ENABLE_CELL_POOL, 1,
  49             [Defined if we try to use the pool allocator for queued cells])
  50 fi
  51 if test x$enable_buf_freelists != xno; then
  52   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  53             [Defined if we try to use freelists for buffer RAM chunks])
  54 fi
  55 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  56
  57 AC_ARG_ENABLE(transparent,
  58      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  59      [case "${enableval}" in
  60         yes) transparent=true ;;
  61         no)  transparent=false ;;
  62         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  63       esac], [transparent=true])
  64
  65 AC_ARG_ENABLE(threads,
  66      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  67
  68 if test x$enable_threads = x; then
  69    case $host in
  70     *-*-solaris* )
  71      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  72      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  73 cpu workers lock up here, so I will disable threads.])
  74      enable_threads="no";;
  75     *)
  76      enable_threads="yes";;
  77    esac
  78 fi
  79
  80 if test "$enable_threads" = "yes"; then
  81   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  82 fi
  83
  84 case $host in
  85    *-*-solaris* )
  86      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  87      ;;
  88 esac
  89
  90 AC_ARG_ENABLE(gcc-warnings,
  91      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  92
  93 AC_PROG_CC
  94 AC_PROG_CPP
  95 AC_PROG_MAKE_SET
  96 AC_PROG_RANLIB
  97
  98 TORUSER=_tor
  99 AC_ARG_WITH(tor-user,
 100         [  --with-tor-user=NAME    Specify username for tor daemon ],
 101         [
 102            TORUSER=$withval
 103         ]
 104 )
 105 AC_SUBST(TORUSER)
 106
 107 TORGROUP=_tor
 108 AC_ARG_WITH(tor-group,
 109         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 110         [
 111            TORGROUP=$withval
 112         ]
 113 )
 114 AC_SUBST(TORGROUP)
 115
 116
 117 dnl If WIN32 is defined and non-zero, we are building for win32
 118 AC_MSG_CHECKING([for win32])
 119 AC_RUN_IFELSE([
 120 int main(int c, char **v) {
 121 #ifdef WIN32
 122 #if WIN32
 123   return 0;
 124 #else
 125   return 1;
 126 #endif
 127 #else
 128   return 2;
 129 #endif
 130 }],
 131 bwin32=true; AC_MSG_RESULT([yes]),
 132 bwin32=false; AC_MSG_RESULT([no]),
 133 bwin32=cross; AC_MSG_RESULT([cross])
 134 )
 135
 136 if test "$bwin32" = cross; then
 137 AC_MSG_CHECKING([for win32 (cross)])
 138 AC_COMPILE_IFELSE([
 139 #ifdef WIN32
 140 int main(int c, char **v) {return 0;}
 141 #else
 142 #error
 143 int main(int c, char **v) {return x(y);}
 144 #endif
 145 ],
 146 bwin32=true; AC_MSG_RESULT([yes]),
 147 bwin32=false; AC_MSG_RESULT([no]))
 148 fi
 149
 150 if test "$bwin32" = true; then
 151 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 152 fi
 153 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 154
 155 dnl Enable C99 when compiling with MIPSpro
 156 AC_MSG_CHECKING([for MIPSpro compiler])
 157 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 158 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 159 #error
 160   return x(y);
 161 #endif
 162 ]),
 163 bmipspro=false; AC_MSG_RESULT(no),
 164 bmipspro=true; AC_MSG_RESULT(yes))
 165
 166 if test "$bmipspro" = true; then
 167   CFLAGS="$CFLAGS -c99"
 168 fi
 169
 170 AC_C_BIGENDIAN
 171
 172 AC_SEARCH_LIBS(socket, [socket])
 173 AC_SEARCH_LIBS(gethostbyname, [nsl])
 174 AC_SEARCH_LIBS(dlopen, [dl])
 175 AC_SEARCH_LIBS(inet_aton, [resolv])
 176
 177 if test "$enable_threads" = "yes"; then
 178   AC_SEARCH_LIBS(pthread_create, [pthread])
 179   AC_SEARCH_LIBS(pthread_detach, [pthread])
 180 fi
 181
 182 dnl -------------------------------------------------------------------
 183 dnl Check for functions before libevent, since libevent-1.2 apparently
 184 dnl exports strlcpy without defining it in a header.
 185
 186 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop)
 187
 188 using_custom_malloc=no
 189 if test x$enable_openbsd_malloc = xyes ; then
 190    using_custom_malloc=yes
 191 fi
 192 if test x$tcmalloc = xyes ; then
 193    using_custom_malloc=yes
 194 fi
 195 if test $using_custom_malloc = no ; then
 196    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 197 fi
 198
 199 if test "$enable_threads" = "yes"; then
 200   AC_CHECK_HEADERS(pthread.h)
 201   AC_CHECK_FUNCS(pthread_create)
 202 fi
 203
 204 dnl ------------------------------------------------------
 205 dnl Where do you live, libevent?  And how do we call you?
 206
 207 if test "$bwin32" = true; then
 208   TOR_LIB_WS32=-lws2_32
 209   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 210   # think it's actually necessary.
 211   TOR_LIB_GDI=-lgdi32
 212 else
 213   TOR_LIB_WS32=
 214   TOR_LIB_GDI=
 215 fi
 216 AC_SUBST(TOR_LIB_WS32)
 217 AC_SUBST(TOR_LIB_GDI)
 218
 219 dnl We need to do this before we try our disgusting hack below.
 220 AC_CHECK_HEADERS([sys/types.h])
 221
 222 dnl This is a disgusting hack so we safely include older libevent headers.
 223 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 224 AC_CHECK_TYPE(u_int32_t, unsigned long)
 225 AC_CHECK_TYPE(u_int16_t, unsigned short)
 226 AC_CHECK_TYPE(u_int8_t, unsigned char)
 227
 228 tor_libevent_pkg_redhat="libevent"
 229 tor_libevent_pkg_debian="libevent-dev"
 230 tor_libevent_devpkg_redhat="libevent-devel"
 231 tor_libevent_devpkg_debian="libevent-dev"
 232
 233 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 234 #ifdef WIN32
 235 #include <winsock2.h>
 236 #endif
 237 #include <stdlib.h>
 238 #include <sys/time.h>
 239 #include <sys/types.h>
 240 #include <event.h>], [
 241 #ifdef WIN32
 242 #include <winsock2.h>
 243 #endif
 244 void exit(int); void *event_init(void);],
 245     [
 246 #ifdef WIN32
 247 {WSADATA d; WSAStartup(0x101,&d); }
 248 #endif
 249 event_init(); exit(0);
 250 ], [--with-libevent-dir], [/opt/libevent])
 251
 252 dnl Now check for particular libevent functions.
 253 save_LIBS="$LIBS"
 254 save_LDFLAGS="$LDFLAGS"
 255 save_CPPFLAGS="$CPPFLAGS"
 256 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 257 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 258 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 259 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 260 LIBS="$save_LIBS"
 261 LDFLAGS="$save_LDFLAGS"
 262 CPPFLAGS="$save_CPPFLAGS"
 263
 264 dnl ------------------------------------------------------
 265 dnl Where do you live, openssl?  And how do we call you?
 266
 267 tor_openssl_pkg_redhat="openssl"
 268 tor_openssl_pkg_debian="libssl"
 269 tor_openssl_devpkg_redhat="openssl-devel"
 270 tor_openssl_devpkg_debian="libssl-dev"
 271
 272 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 273     [#include <openssl/rand.h>],
 274     [void RAND_add(const void *buf, int num, double entropy);],
 275     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 276     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 277
 278 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 279
 280 dnl ------------------------------------------------------
 281 dnl Where do you live, zlib?  And how do we call you?
 282
 283 tor_openssl_pkg_redhat="zlib"
 284 tor_openssl_pkg_debian="zlib1g"
 285 tor_openssl_devpkg_redhat="zlib-devel"
 286 tor_openssl_devpkg_debian="zlib1g-dev"
 287
 288 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 289     [#include <zlib.h>],
 290     [const char * zlibVersion(void);],
 291     [zlibVersion(); exit(0);], [--with-zlib-dir],
 292     [/opt/zlib])
 293
 294 dnl Make sure to enable support for large off_t if available.
 295
 296 AC_SYS_LARGEFILE
 297
 298 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 299
 300 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 301
 302 dnl These headers are not essential
 303
 304 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 305
 306 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 307 [#ifdef HAVE_MALLOC_H
 308 #include <malloc.h>
 309 #endif
 310 #ifdef HAVE_MALLOC_MALLOC_H
 311 #include <malloc/malloc.h>
 312 #endif])
 313
 314 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 315 [#ifdef HAVE_SYS_TYPES_H
 316 #include <sys/types.h>
 317 #endif
 318 #ifdef HAVE_SYS_SOCKET_H
 319 #include <sys/socket.h>
 320 #endif])
 321 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 322 [#ifdef HAVE_SYS_TYPES_H
 323 #include <sys/types.h>
 324 #endif
 325 #ifdef HAVE_SYS_SOCKET_H
 326 #include <sys/socket.h>
 327 #endif
 328 #ifdef HAVE_NET_IF_H
 329 #include <net/if.h>
 330 #endif])
 331 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 332         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 333 [#ifdef HAVE_SYS_TYPES_H
 334 #include <sys/types.h>
 335 #endif
 336 #ifdef HAVE_SYS_SOCKET_H
 337 #include <sys/socket.h>
 338 #endif])
 339
 340 if test x$transparent = xtrue ; then
 341    transparent_ok=0
 342    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 343      transparent_ok=1
 344    fi
 345    if test x$linux_netfilter_ipv4 = x1 ; then
 346      transparent_ok=1
 347    fi
 348    if test x$transparent_ok = x1 ; then
 349      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 350      case $host in
 351        *-*-openbsd*)
 352          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 353      esac
 354    else
 355      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 356    fi
 357 fi
 358
 359 AC_FUNC_FSEEKO
 360
 361 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 362 [#ifdef HAVE_SYS_TYPES_H
 363 #include <sys/types.h>
 364 #endif
 365 #ifdef HAVE_SYS_TIME_H
 366 #include <sys/time.h>
 367 #endif])
 368
 369 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 370 dnl Watch out.
 371
 372 AC_CHECK_SIZEOF(int8_t)
 373 AC_CHECK_SIZEOF(int16_t)
 374 AC_CHECK_SIZEOF(int32_t)
 375 AC_CHECK_SIZEOF(int64_t)
 376 AC_CHECK_SIZEOF(uint8_t)
 377 AC_CHECK_SIZEOF(uint16_t)
 378 AC_CHECK_SIZEOF(uint32_t)
 379 AC_CHECK_SIZEOF(uint64_t)
 380 AC_CHECK_SIZEOF(intptr_t)
 381 AC_CHECK_SIZEOF(uintptr_t)
 382
 383 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 384
 385 AC_CHECK_SIZEOF(char)
 386 AC_CHECK_SIZEOF(short)
 387 AC_CHECK_SIZEOF(int)
 388 AC_CHECK_SIZEOF(long)
 389 AC_CHECK_SIZEOF(long long)
 390 AC_CHECK_SIZEOF(__int64)
 391 AC_CHECK_SIZEOF(void *)
 392 AC_CHECK_SIZEOF(time_t)
 393 AC_CHECK_SIZEOF(size_t)
 394
 395 AC_CHECK_TYPES([uint, u_char, ssize_t])
 396
 397 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 398 [#ifdef HAVE_SYS_TYPES_H
 399 #include <sys/types.h>
 400 #endif
 401 #ifdef HAVE_NETINET_IN_H
 402 #include <netinet/in.h>
 403 #endif
 404 #ifdef HAVE_NETINET_IN6_H
 405 #include <netinet/in6.h>
 406 #endif
 407 #ifdef HAVE_SYS_SOCKET_H
 408 #include <sys/socket.h>
 409 #endif
 410 #ifdef MS_WINDOWS
 411 #define WIN32_WINNT 0x400
 412 #define _WIN32_WINNT 0x400
 413 #define WIN32_LEAN_AND_MEAN
 414 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 415 #include <winsock.h>
 416 #else
 417 #include <winsock2.h>
 418 #include <ws2tcpip.h>
 419 #endif
 420 #endif
 421 ])
 422 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 423 [#ifdef HAVE_SYS_TYPES_H
 424 #include <sys/types.h>
 425 #endif
 426 #ifdef HAVE_NETINET_IN_H
 427 #include <netinet/in.h>
 428 #endif
 429 #ifdef HAVE_NETINET_IN6_H
 430 #include <netinet/in6.h>
 431 #endif
 432 #ifdef HAVE_SYS_SOCKET_H
 433 #include <sys/socket.h>
 434 #endif
 435 #ifdef MS_WINDOWS
 436 #define WIN32_WINNT 0x400
 437 #define _WIN32_WINNT 0x400
 438 #define WIN32_LEAN_AND_MEAN
 439 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 440 #include <winsock.h>
 441 #else
 442 #include <winsock2.h>
 443 #include <ws2tcpip.h>
 444 #endif
 445 #endif
 446 ])
 447
 448 AC_CHECK_TYPES([rlim_t], , ,
 449 [#ifdef HAVE_SYS_TYPES_H
 450 #include <sys/types.h>
 451 #endif
 452 #ifdef HAVE_SYS_TIME_H
 453 #include <sys/time.h>
 454 #endif
 455 #ifdef HAVE_SYS_RESOURCE_H
 456 #include <sys/resource.h>
 457 #endif
 458 ])
 459
 460 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 461 AC_RUN_IFELSE(AC_LANG_SOURCE([
 462 #ifdef HAVE_SYS_TYPES_H
 463 #include <sys/types.h>
 464 #endif
 465 #ifdef HAVE_SYS_TIME_H
 466 #include <sys/time.h>
 467 #endif
 468 #ifdef HAVE_TIME_H
 469 #include <time.h>
 470 #endif
 471 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 472   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 473 ])
 474
 475 if test "$tor_cv_time_t_signed" = cross; then
 476   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 477 fi
 478
 479 if test "$tor_cv_time_t_signed" != no; then
 480   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 481             [Define to 1 iff time_t is signed])
 482 fi
 483
 484 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 485 #ifdef HAVE_SYS_SOCKET_H
 486 #include <sys/socket.h>
 487 #endif
 488 ])
 489
 490 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 491
 492 AC_CHECK_SIZEOF(cell_t)
 493
 494 # Now make sure that NULL can be represented as zero bytes.
 495 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 496 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 497 [[#include <stdlib.h>
 498 #include <string.h>
 499 #include <stdio.h>
 500 #ifdef HAVE_STDDEF_H
 501 #include <stddef.h>
 502 #endif
 503 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 504 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 505        [tor_cv_null_is_zero=yes],
 506        [tor_cv_null_is_zero=no],
 507        [tor_cv_null_is_zero=cross])])
 508
 509 if test "$tor_cv_null_is_zero" = cross ; then
 510   # Cross-compiling; let's hope that the target isn't raving mad.
 511   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 512 fi
 513
 514 if test "$tor_cv_null_is_zero" != no; then
 515   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 516             [Define to 1 iff memset(0) sets pointers to NULL])
 517 fi
 518
 519 # And what happens when we malloc zero?
 520 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 521 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 522 [[#include <stdlib.h>
 523 #include <string.h>
 524 #include <stdio.h>
 525 #ifdef HAVE_STDDEF_H
 526 #include <stddef.h>
 527 #endif
 528 int main () { return malloc(0)?0:1; }]])],
 529        [tor_cv_malloc_zero_works=yes],
 530        [tor_cv_malloc_zero_works=no],
 531        [tor_cv_malloc_zero_works=cross])])
 532
 533 if test "$tor_cv_malloc_zero_works" = cross; then
 534   # Cross-compiling; let's hope that the target isn't raving mad.
 535   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 536 fi
 537
 538 if test "$tor_cv_malloc_zero_works" = yes; then
 539   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 540             [Define to 1 iff malloc(0) returns a pointer])
 541 fi
 542
 543 # whether we seem to be in a 2s-complement world.
 544 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 545 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 546 [[int main () { int problem = ((-99) != (~99)+1);
 547 return problem ? 1 : 0; }]])],
 548        [tor_cv_twos_complement=yes],
 549        [tor_cv_twos_complement=no],
 550        [tor_cv_twos_complement=cross])])
 551
 552 if test "$tor_cv_twos_complement" = cross ; then
 553   # Cross-compiling; let's hope that the target isn't raving mad.
 554   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 555 fi
 556
 557 if test "$tor_cv_twos_complement" != no ; then
 558   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 559             [Define to 1 iff we represent negative integers with two's complement])
 560 fi
 561
 562 # Whether we should use the dmalloc memory allocation debugging library.
 563 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 564 AC_ARG_WITH(dmalloc,
 565 [  --with-dmalloc          Use debug memory allocation library. ],
 566 [if [[ "$withval" = "yes" ]]; then
 567   dmalloc=1
 568   AC_MSG_RESULT(yes)
 569 else
 570   dmalloc=1
 571   AC_MSG_RESULT(no)
 572 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 573 )
 574
 575 if [[ $dmalloc -eq 1 ]]; then
 576   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 577   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 578   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 579   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 580   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 581 fi
 582
 583 AC_ARG_WITH(tcmalloc,
 584 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 585 [ tcmalloc=yes ], [ tcmalloc=no ])
 586
 587 if test x$tcmalloc = xyes ; then
 588    LDFLAGS="-ltcmalloc $LDFLAGS"
 589 fi
 590
 591 # Allow user to specify an alternate syslog facility
 592 AC_ARG_WITH(syslog-facility,
 593 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 594 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 595 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 596 AC_SUBST(LOGFACILITY)
 597
 598 # Check for gethostbyname_r in all its glorious incompatible versions.
 599 #   (This logic is based on that in Python's configure.in)
 600 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 601   [Define this if you have any gethostbyname_r()])
 602
 603 AC_CHECK_FUNC(gethostbyname_r, [
 604   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 605   OLD_CFLAGS=$CFLAGS
 606   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 607   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 608 #include <netdb.h>
 609   ], [[
 610     char *cp1, *cp2;
 611     struct hostent *h1, *h2;
 612     int i1, i2;
 613     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 614   ]]),[
 615     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 616     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 617      [Define this if gethostbyname_r takes 6 arguments])
 618     AC_MSG_RESULT(6)
 619   ], [
 620     AC_TRY_COMPILE([
 621 #include <netdb.h>
 622     ], [
 623       char *cp1, *cp2;
 624       struct hostent *h1;
 625       int i1, i2;
 626       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 627     ], [
 628       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 629       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 630         [Define this if gethostbyname_r takes 5 arguments])
 631       AC_MSG_RESULT(5)
 632    ], [
 633       AC_TRY_COMPILE([
 634 #include <netdb.h>
 635      ], [
 636        char *cp1;
 637        struct hostent *h1;
 638        struct hostent_data hd;
 639        (void) gethostbyname_r(cp1,h1,&hd);
 640      ], [
 641        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 642        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 643          [Define this if gethostbyname_r takes 3 arguments])
 644        AC_MSG_RESULT(3)
 645      ], [
 646        AC_MSG_RESULT(0)
 647      ])
 648   ])
 649  ])
 650  CFLAGS=$OLD_CFLAGS
 651 ])
 652
 653 AC_CACHE_CHECK([whether the C compiler supports __func__],
 654   tor_cv_have_func_macro,
 655   AC_COMPILE_IFELSE([
 656 #include <stdio.h>
 657 int main(int c, char **v) { puts(__func__); }],
 658   tor_cv_have_func_macro=yes,
 659   tor_cv_have_func_macro=no))
 660
 661 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 662   tor_cv_have_FUNC_macro,
 663   AC_COMPILE_IFELSE([
 664 #include <stdio.h>
 665 int main(int c, char **v) { puts(__FUNC__); }],
 666   tor_cv_have_FUNC_macro=yes,
 667   tor_cv_have_FUNC_macro=no))
 668
 669 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 670   tor_cv_have_FUNCTION_macro,
 671   AC_COMPILE_IFELSE([
 672 #include <stdio.h>
 673 int main(int c, char **v) { puts(__FUNCTION__); }],
 674   tor_cv_have_FUNCTION_macro=yes,
 675   tor_cv_have_FUNCTION_macro=no))
 676
 677 if test "$tor_cv_have_func_macro" = 'yes'; then
 678   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 679 fi
 680
 681 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 682   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 683 fi
 684
 685 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 686   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 687            [Defined if the compiler supports __FUNCTION__])
 688 fi
 689
 690 # $prefix stores the value of the --prefix command line option, or
 691 # NONE if the option wasn't set.  In the case that it wasn't set, make
 692 # it be the default, so that we can use it to expand directories now.
 693 if test "x$prefix" = "xNONE"; then
 694   prefix=$ac_default_prefix
 695 fi
 696
 697 # and similarly for $exec_prefix
 698 if test "x$exec_prefix" = "xNONE"; then
 699   exec_prefix=$prefix
 700 fi
 701
 702 if test "x$CONFDIR" = "x"; then
 703   CONFDIR=`eval echo $sysconfdir/tor`
 704 fi
 705 AC_SUBST(CONFDIR)
 706 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 707 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 708
 709 BINDIR=`eval echo $bindir`
 710 AC_SUBST(BINDIR)
 711 LOCALSTATEDIR=`eval echo $localstatedir`
 712 AC_SUBST(LOCALSTATEDIR)
 713
 714 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 715 # than autoconf's macros like.
 716 if test "$ac_cv_c_compiler_gnu" = yes; then
 717   CFLAGS="$CFLAGS -Wall -g -O2"
 718 else
 719   CFLAGS="$CFLAGS -g -O"
 720   enable_gcc_warnings=no
 721 fi
 722
 723 # Add some more warnings which we use in development but not in the
 724 # released versions.  (Some relevant gcc versions can't handle these.)
 725 if test x$enable_gcc_warnings = xyes; then
 726
 727   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 728 #if !defined(__GNUC__) || (__GNUC__ < 4)
 729 #error
 730 #endif]), have_gcc4=yes, have_gcc4=no)
 731
 732   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 733 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 734 #error
 735 #endif]), have_gcc42=yes, have_gcc42=no)
 736
 737   save_CFLAGS="$CFLAGS"
 738   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 739   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 740                     have_shorten64_flag=no)
 741   CFLAGS="$save_CFLAGS"
 742
 743   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 744   # Disabled, so we can use mallinfo(): -Waggregate-return
 745
 746   if test x$have_gcc4 = xyes ; then
 747     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 748     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 749   fi
 750
 751   if test x$have_gcc42 = xyes ; then
 752     # These warnings break gcc 4.0.2 and work on gcc 4.2
 753     # XXXX020 Use -fstack-protector.
 754     # XXXX020 See if any of these work with earlier versions.
 755     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 756     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 757   fi
 758
 759   if test x$have_shorten64_flag = xyes ; then
 760     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 761   fi
 762
 763 ##This will break the world on some 64-bit architectures
 764 # CFLAGS="$CFLAGS -Winline"
 765 fi
 766
 767
 768
 769 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 770
 771 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 772 AC_OUTPUT
 773
 774 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 775   ./contrib/updateVersions.pl
 776 fi
 777