configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2007, Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.0.9-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  17 # the += operator on it in src/or/Makefile.am
  18 CPPFLAGS="$CPPFLAGS -I../common"
  19
  20 AC_ARG_ENABLE(debug,
  21  AS_HELP_STRING(--enable-debug, compile with debugging info),
  22 [if test x$enableval = xyes; then
  23     CFLAGS="$CFLAGS -g"
  24 fi])
  25
  26 AC_ARG_ENABLE(cell-pool,
  27      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  28
  29 if test x$enable_cell_pool != xno; then
  30   AC_DEFINE(ENABLE_CELL_POOL, 1,
  31             [Defined if we try to use the pool allocator for queued cells])
  32 fi
  33
  34 AC_ARG_ENABLE(transparent,
  35      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  36      [case "${enableval}" in
  37         yes) transparent=true ;;
  38         no)  transparent=false ;;
  39         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  40       esac], [transparent=true])
  41
  42 AC_ARG_ENABLE(threads,
  43      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  44
  45 if test x$enable_threads = x; then
  46    case $host in
  47     *-*-solaris* )
  48      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  49      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  50 cpu workers lock up here, so I will disable threads.])
  51      enable_threads="no";;
  52     *)
  53      enable_threads="yes";;
  54    esac
  55 fi
  56
  57 if test $enable_threads = "yes"; then
  58   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  59 fi
  60
  61 case $host in
  62    *-*-solaris* )
  63      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  64      ;;
  65 esac
  66
  67 AC_ARG_ENABLE(gcc-warnings,
  68      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  69
  70 AC_PROG_CC
  71 AC_PROG_MAKE_SET
  72 AC_PROG_RANLIB
  73
  74 TORUSER=_tor
  75 AC_ARG_WITH(tor-user,
  76         [  --with-tor-user=NAME    Specify username for tor daemon ],
  77         [
  78            TORUSER=$withval
  79         ]
  80 )
  81 AC_SUBST(TORUSER)
  82
  83 TORGROUP=_tor
  84 AC_ARG_WITH(tor-group,
  85         [  --with-tor-group=NAME   Specify group name for tor daemon ],
  86         [
  87            TORGROUP=$withval
  88         ]
  89 )
  90 AC_SUBST(TORGROUP)
  91
  92
  93 dnl If WIN32 is defined and non-zero, we are building for win32
  94 AC_MSG_CHECKING([for win32])
  95 AC_RUN_IFELSE([
  96 int main(int c, char **v) {
  97 #ifdef WIN32
  98 #if WIN32
  99   return 0;
 100 #else
 101   return 1;
 102 #endif
 103 #else
 104   return 2;
 105 #endif
 106 }],
 107 bwin32=true; AC_MSG_RESULT([yes]),
 108 bwin32=false; AC_MSG_RESULT([no]),
 109 bwin32=cross; AC_MSG_RESULT([cross])
 110 )
 111
 112 if test $bwin32 = cross; then
 113 AC_MSG_CHECKING([for win32 (cross)])
 114 AC_COMPILE_IFELSE([
 115 #ifdef WIN32
 116 int main(int c, char **v) {return 0;}
 117 #else
 118 #error
 119 int main(int c, char **v) {return x(y);}
 120 #endif
 121 ],
 122 bwin32=true; AC_MSG_RESULT([yes]),
 123 bwin32=false; AC_MSG_RESULT([no]))
 124 fi
 125
 126 if test $bwin32 = true; then
 127 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 128 fi
 129 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 130
 131 dnl Enable C99 when compiling with MIPSpro
 132 AC_MSG_CHECKING([for MIPSpro compiler])
 133 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 134 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 135 #error
 136   return x(y);
 137 #endif
 138 ]),
 139 bmipspro=false; AC_MSG_RESULT(no),
 140 bmipspro=true; AC_MSG_RESULT(yes))
 141
 142 if test $bmipspro = true; then
 143   CFLAGS="$CFLAGS -c99"
 144 fi
 145
 146 AC_C_BIGENDIAN
 147
 148 AC_SEARCH_LIBS(socket, [socket])
 149 AC_SEARCH_LIBS(gethostbyname, [nsl])
 150 AC_SEARCH_LIBS(dlopen, [dl])
 151 AC_SEARCH_LIBS(inet_aton, [resolv])
 152
 153 if test $enable_threads = "yes"; then
 154   AC_SEARCH_LIBS(pthread_create, [pthread])
 155   AC_SEARCH_LIBS(pthread_detach, [pthread])
 156 fi
 157
 158 dnl -------------------------------------------------------------------
 159 dnl Check for functions before libevent, since libevent-1.2 apparently
 160 dnl exports strlcpy without defining it in a header.
 161
 162 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop mallinfo)
 163
 164 if test $enable_threads = "yes"; then
 165   AC_CHECK_HEADERS(pthread.h)
 166   AC_CHECK_FUNCS(pthread_create)
 167 fi
 168
 169 dnl ------------------------------------------------------
 170 dnl Where do you live, libevent?  And how do we call you?
 171
 172 if test $bwin32 = true; then
 173   TOR_LIB_WS32=-lws2_32
 174   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 175   # think it's actually necessary.
 176   TOR_LIB_GDI=-lgdi32
 177 else
 178   TOR_LIB_WS32=
 179   TOR_LIB_GDI=
 180 fi
 181 AC_SUBST(TOR_LIB_WS32)
 182 AC_SUBST(TOR_LIB_GDI)
 183
 184 dnl This is a disgusting hack so we safely include recent libevent headers.
 185 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 186 AC_CHECK_TYPE(u_int32_t, unsigned long)
 187 AC_CHECK_TYPE(u_int16_t, unsigned short)
 188 AC_CHECK_TYPE(u_int8_t, unsigned char)
 189
 190 tor_libevent_pkg_redhat="libevent"
 191 tor_libevent_pkg_debian="libevent-dev"
 192 tor_libevent_devpkg_redhat="libevent-devel"
 193 tor_libevent_devpkg_debian="libevent-dev"
 194
 195 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 196 #include <stdlib.h>
 197 #include <sys/time.h>
 198 #include <sys/types.h>
 199 #include <event.h>], [void exit(int); void *event_init(void);],
 200     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 201
 202 dnl Now check for particular libevent functions.
 203 save_LIBS="$LIBS"
 204 save_LDFLAGS="$LDFLAGS"
 205 save_CPPFLAGS="$CPPFLAGS"
 206 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 207 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 208 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 209 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 210 LIBS="$save_LIBS"
 211 LDFLAGS="$save_LDFLAGS"
 212 CPPFLAGS="$save_CPPFLAGS"
 213
 214 dnl ------------------------------------------------------
 215 dnl Where do you live, openssl?  And how do we call you?
 216
 217 tor_openssl_pkg_redhat="openssl"
 218 tor_openssl_pkg_debian="libssl"
 219 tor_openssl_devpkg_redhat="openssl-devel"
 220 tor_openssl_devpkg_debian="libssl-dev"
 221
 222 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 223     [#include <openssl/rand.h>],
 224     [void RAND_add(const void *buf, int num, double entropy);],
 225     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 226     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 227
 228 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 229
 230 dnl ------------------------------------------------------
 231 dnl Where do you live, zlib?  And how do we call you?
 232
 233 tor_openssl_pkg_redhat="zlib"
 234 tor_openssl_pkg_debian="zlib1g"
 235 tor_openssl_devpkg_redhat="zlib-devel"
 236 tor_openssl_devpkg_debian="zlib1g-dev"
 237
 238 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 239     [#include <zlib.h>],
 240     [const char * zlibVersion(void);],
 241     [zlibVersion(); exit(0);], [--with-zlib-dir],
 242     [/opt/zlib])
 243
 244 dnl Make sure to enable support for large off_t if avalable.
 245
 246 AC_SYS_LARGEFILE
 247
 248 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 249
 250 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 251
 252 dnl These headers are not essential
 253
 254 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h)
 255
 256 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 257 [#ifdef HAVE_SYS_TYPES_H
 258 #include <sys/types.h>
 259 #endif
 260 #ifdef HAVE_SYS_SOCKET_H
 261 #include <sys/socket.h>
 262 #endif])
 263 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 264 [#ifdef HAVE_SYS_TYPES_H
 265 #include <sys/types.h>
 266 #endif
 267 #ifdef HAVE_SYS_SOCKET_H
 268 #include <sys/socket.h>
 269 #endif
 270 #ifdef HAVE_NET_IF_H
 271 #include <net/if.h>
 272 #endif])
 273 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 274         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 275 [#ifdef HAVE_SYS_TYPES_H
 276 #include <sys/types.h>
 277 #endif
 278 #ifdef HAVE_SYS_SOCKET_H
 279 #include <sys/socket.h>
 280 #endif])
 281
 282 if test x$transparent = xtrue ; then
 283    transparent_ok=0
 284    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 285      transparent_ok=1
 286    fi
 287    if test x$linux_netfilter_ipv4 = x1 ; then
 288      transparent_ok=1
 289    fi
 290    if test x$transparent_ok = x1 ; then
 291      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 292      case $host in
 293        *-*-openbsd*)
 294          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 295      esac
 296    else
 297      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 298    fi
 299 fi
 300
 301 AC_FUNC_FSEEKO
 302
 303 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 304 [#ifdef HAVE_SYS_TYPES_H
 305 #include <sys/types.h>
 306 #endif
 307 #ifdef HAVE_SYS_TIME_H
 308 #include <sys/time.h>
 309 #endif])
 310
 311 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 312 dnl Watch out.
 313
 314 AC_CHECK_SIZEOF(int8_t)
 315 AC_CHECK_SIZEOF(int16_t)
 316 AC_CHECK_SIZEOF(int32_t)
 317 AC_CHECK_SIZEOF(int64_t)
 318 AC_CHECK_SIZEOF(uint8_t)
 319 AC_CHECK_SIZEOF(uint16_t)
 320 AC_CHECK_SIZEOF(uint32_t)
 321 AC_CHECK_SIZEOF(uint64_t)
 322 AC_CHECK_SIZEOF(intptr_t)
 323 AC_CHECK_SIZEOF(uintptr_t)
 324
 325 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 326
 327 AC_CHECK_SIZEOF(char)
 328 AC_CHECK_SIZEOF(short)
 329 AC_CHECK_SIZEOF(int)
 330 AC_CHECK_SIZEOF(long)
 331 AC_CHECK_SIZEOF(long long)
 332 AC_CHECK_SIZEOF(__int64)
 333 AC_CHECK_SIZEOF(void *)
 334 AC_CHECK_SIZEOF(time_t)
 335 AC_CHECK_SIZEOF(size_t)
 336
 337 AC_CHECK_TYPES([uint, u_char])
 338
 339 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 340 [#ifdef HAVE_SYS_TYPES_H
 341 #include <sys/types.h>
 342 #endif
 343 #ifdef HAVE_NETINET_IN_H
 344 #include <netinet/in.h>
 345 #endif
 346 #ifdef HAVE_NETINET_IN6_H
 347 #include <netinet/in6.h>
 348 #endif
 349 #ifdef HAVE_SYS_SOCKET_H
 350 #include <sys/socket.h>
 351 #endif
 352 #ifdef MS_WINDOWS
 353 #define WIN32_WINNT 0x400
 354 #define _WIN32_WINNT 0x400
 355 #define WIN32_LEAN_AND_MEAN
 356 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 357 #include <winsock.h>
 358 #else
 359 #include <winsock2.h>
 360 #include <ws2tcpip.h>
 361 #endif
 362 #endif
 363 ])
 364
 365 AC_CHECK_TYPES([rlim_t], , ,
 366 [#ifdef HAVE_SYS_RESOURCE_H
 367 #include <sys/resource.h>
 368 #endif
 369 ])
 370
 371 if test -z "$CROSS_COMPILE"; then
 372 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 373 AC_RUN_IFELSE(AC_LANG_SOURCE([
 374 #ifdef HAVE_SYS_TYPES_H
 375 #include <sys/types.h>
 376 #endif
 377 #ifdef HAVE_SYS_TIME_H
 378 #include <sys/time.h>
 379 #endif
 380 #ifdef HAVE_TIME_H
 381 #include <time.h>
 382 #endif
 383 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 384   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes)
 385 ])
 386 else
 387   # Cross-compiling; let's hope the target platform isn't loony.
 388   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 389   tor_cv_time_t_signed=yes
 390 fi
 391
 392 if test $tor_cv_time_t_signed = yes; then
 393   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 394             [Define to 1 iff time_t is signed])
 395 fi
 396
 397 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 398 #ifdef HAVE_SYS_SOCKET_H
 399 #include <sys/socket.h>
 400 #endif
 401 ])
 402
 403 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 404
 405 AC_CHECK_SIZEOF(cell_t)
 406
 407 # Now make sure that NULL can be represented as zero bytes.
 408 if test -z "$CROSS_COMPILE"; then
 409 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 410 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 411 [[#include <stdlib.h>
 412 #include <string.h>
 413 #include <stdio.h>
 414 #ifdef HAVE_STDDEF_H
 415 #include <stddef.h>
 416 #endif
 417 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 418 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 419        [tor_cv_null_is_zero=yes],
 420        [tor_cv_null_is_zero=no],
 421        [tor_cv_null_is_zero=cross])])
 422
 423 else
 424   # Cross-compiling; let's hope that the target isn't raving mad.
 425   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 426   tor_cv_null_is_zero=yes
 427 fi
 428
 429 if test $tor_cv_null_is_zero = yes; then
 430   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 431             [Define to 1 iff memset(0) sets pointers to NULL])
 432 fi
 433
 434 # And what happens when we malloc zero?
 435
 436 if test -z "$CROSS_COMPILE"; then
 437 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 438 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 439 [[#include <stdlib.h>
 440 #include <string.h>
 441 #include <stdio.h>
 442 #ifdef HAVE_STDDEF_H
 443 #include <stddef.h>
 444 #endif
 445 int main () { return malloc(0)?0:1; }]])],
 446        [tor_cv_malloc_zero_works=yes],
 447        [tor_cv_malloc_zero_works=no],
 448        [tor_cv_malloc_zero_works=cross])])
 449
 450 else
 451   # Cross-compiling; let's hope that the target isn't raving mad.
 452   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 453   tor_cv_malloc_zero_works=no
 454 fi
 455
 456 if test $tor_cv_malloc_zero_works = yes; then
 457   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 458             [Define to 1 iff malloc(0) returns a pointer])
 459 fi
 460
 461 # whether we seem to be in a 2s-complement world.
 462 if test -z "$CROSS_COMPILE"; then
 463 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 464 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 465 [[int main () { int problem = ((-99) != (~99)+1);
 466 return problem ? 1 : 0; }]])],
 467        [tor_cv_twos_complement=yes],
 468        [tor_cv_twos_complement=no],
 469        [tor_cv_twos_complement=cross])])
 470
 471 else
 472   # Cross-compiling; let's hope that the target isn't raving mad.
 473   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 474   tor_cv_twos_complement=yes
 475 fi
 476
 477 if test $tor_cv_twos_complement = yes; then
 478   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 479             [Define to 1 iff we represent negative integers with two's complement])
 480 fi
 481
 482 # Whether we should use the dmalloc memory allocation debugging library.
 483 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 484 AC_ARG_WITH(dmalloc,
 485 [  --with-dmalloc          Use debug memory allocation library. ],
 486 [if [[ "$withval" = "yes" ]]; then
 487   dmalloc=1
 488   AC_MSG_RESULT(yes)
 489 else
 490   dmalloc=1
 491   AC_MSG_RESULT(no)
 492 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 493 )
 494
 495 if [[ $dmalloc -eq 1 ]]; then
 496   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 497   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 498   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 499   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 500 fi
 501
 502 # Allow user to specify an alternate syslog facility
 503 AC_ARG_WITH(syslog-facility,
 504 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 505 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 506 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 507 AC_SUBST(LOGFACILITY)
 508
 509 # Check for gethostbyname_r in all its glorious incompatible versions.
 510 #   (This logic is based on that in Python's configure.in)
 511 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 512   [Define this if you have any gethostbyname_r()])
 513
 514 AC_CHECK_FUNC(gethostbyname_r, [
 515   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 516   OLD_CFLAGS=$CFLAGS
 517   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 518   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 519 #include <netdb.h>
 520   ], [[
 521     char *cp1, *cp2;
 522     struct hostent *h1, *h2;
 523     int i1, i2;
 524     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 525   ]]),[
 526     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 527     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 528      [Define this if gethostbyname_r takes 6 arguments])
 529     AC_MSG_RESULT(6)
 530   ], [
 531     AC_TRY_COMPILE([
 532 #include <netdb.h>
 533     ], [
 534       char *cp1, *cp2;
 535       struct hostent *h1;
 536       int i1, i2;
 537       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 538     ], [
 539       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 540       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 541         [Define this if gethostbyname_r takes 5 arguments])
 542       AC_MSG_RESULT(5)
 543    ], [
 544       AC_TRY_COMPILE([
 545 #include <netdb.h>
 546      ], [
 547        char *cp1;
 548        struct hostent *h1;
 549        struct hostent_data hd;
 550        (void) gethostbyname_r(cp1,h1,&hd);
 551      ], [
 552        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 553        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 554          [Define this if gethostbyname_r takes 3 arguments])
 555        AC_MSG_RESULT(3)
 556      ], [
 557        AC_MSG_RESULT(0)
 558      ])
 559   ])
 560  ])
 561  CFLAGS=$OLD_CFLAGS
 562 ])
 563
 564 AC_CACHE_CHECK([whether the C compiler supports __func__],
 565   tor_cv_have_func_macro,
 566   AC_COMPILE_IFELSE([
 567 #include <stdio.h>
 568 int main(int c, char **v) { puts(__func__); }],
 569   tor_cv_have_func_macro=yes,
 570   tor_cv_have_func_macro=no))
 571
 572 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 573   tor_cv_have_FUNC_macro,
 574   AC_COMPILE_IFELSE([
 575 #include <stdio.h>
 576 int main(int c, char **v) { puts(__FUNC__); }],
 577   tor_cv_have_FUNC_macro=yes,
 578   tor_cv_have_FUNC_macro=no))
 579
 580 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 581   tor_cv_have_FUNCTION_macro,
 582   AC_COMPILE_IFELSE([
 583 #include <stdio.h>
 584 int main(int c, char **v) { puts(__FUNCTION__); }],
 585   tor_cv_have_FUNCTION_macro=yes,
 586   tor_cv_have_FUNCTION_macro=no))
 587
 588 if test $tor_cv_have_func_macro = 'yes'; then
 589   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 590 fi
 591
 592 if test $tor_cv_have_FUNC_macro = 'yes'; then
 593   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 594 fi
 595
 596 if test $tor_cv_have_FUNCTION_macro = 'yes'; then
 597   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 598            [Defined if the compiler supports __FUNCTION__])
 599 fi
 600
 601 # $prefix stores the value of the --prefix command line option, or
 602 # NONE if the option wasn't set.  In the case that it wasn't set, make
 603 # it be the default, so that we can use it to expand directories now.
 604 if test "x$prefix" = "xNONE"; then
 605   prefix=$ac_default_prefix
 606 fi
 607
 608 # and similarly for $exec_prefix
 609 if test "x$exec_prefix" = "xNONE"; then
 610   exec_prefix=$prefix
 611 fi
 612
 613 if test "x$CONFDIR" = "x"; then
 614   CONFDIR=`eval echo $sysconfdir/tor`
 615 fi
 616 AC_SUBST(CONFDIR)
 617 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 618 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 619
 620 BINDIR=`eval echo $bindir`
 621 AC_SUBST(BINDIR)
 622
 623 LOCALSTATEDIR=`eval echo $localstatedir`
 624 AC_SUBST(LOCALSTATEDIR)
 625 AH_TEMPLATE([LOCALSTATEDIR], [Default location to store state files.])
 626 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 627
 628 dnl Note: this is not the same as Tor's "DataDir" config option.
 629 dnl   We'd call it 'DATADIR', except that's a symbol in MinGW's objidl.h.
 630 SHARE_DATADIR=`eval echo $datadir`
 631 AC_SUBST(SHARE_DATADIR)
 632 AH_TEMPLATE([SHARE_DATADIR], [Default location for platform-independent read-only data.])
 633 AC_DEFINE_UNQUOTED(SHARE_DATADIR,"$SHARE_DATADIR")
 634
 635 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 636 # than autoconf's macros like.
 637 if test $ac_cv_c_compiler_gnu = yes; then
 638   CFLAGS="$CFLAGS -Wall -g -O2"
 639 else
 640   CFLAGS="$CFLAGS -g -O"
 641   enable_gcc_warnings=no
 642 fi
 643
 644 # Add some more warnings which we use in development but not in the
 645 # released versions.  (Some relevant gcc versions can't handle these.)
 646 if test x$enable_gcc_warnings = xyes; then
 647
 648   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 649 #if !defined(__GNUC__) || (__GNUC__ < 4)
 650 #error
 651 #endif]), have_gcc4=yes, have_gcc4=no)
 652
 653   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 654 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 655 #error
 656 #endif]), have_gcc42=yes, have_gcc42=no)
 657
 658   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 659   # Disabled, so we can use mallinfo(): -Waggregate-return
 660
 661   if test x$have_gcc4 = xyes ; then
 662     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 663     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 664   fi
 665
 666   if test x$have_gcc42 = xyes ; then
 667     # These warnings break gcc 4.0.2 and work on gcc 4.2
 668     # XXXX020 Use -fstack-protector.
 669     # XXXX020 See if any of these work with earlier versions.
 670     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 671   fi
 672
 673 ##This will break the world on some 64-bit architectures
 674 # CFLAGS="$CFLAGS -Winline"
 675
 676 fi
 677
 678 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 679
 680 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 681 AC_OUTPUT
 682
 683 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 684   ./contrib/updateVersions.pl
 685 fi
 686