| blob | 8ee34070a356a89f9c73e35be8352c30a00a91de |
1 dnl Copyright (c) 2001-2004, Roger Dingledine
2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
3 dnl Copyright (c) 2007-2015, The Tor Project, Inc.
4 dnl See LICENSE for licensing information
6 AC_PREREQ([2.63])
7 AC_INIT([tor],[0.3.0.0-alpha-dev])
8 AC_CONFIG_SRCDIR([src/or/main.c])
9 AC_CONFIG_MACRO_DIR([m4])
11 # "foreign" means we don't follow GNU package layout standards
12 # "1.11" means we require automake version 1.11 or newer
13 # "subdir-objects" means put .o files in the same directory as the .c files
14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects])
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17 AC_CONFIG_HEADERS([orconfig.h])
19 AC_USE_SYSTEM_EXTENSIONS
20 AC_CANONICAL_HOST
22 PKG_PROG_PKG_CONFIG
24 if test -f "/etc/redhat-release"; then
25 if test -f "/usr/kerberos/include"; then
26 CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
27 fi
28 fi
30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
31 # the += operator on it in src/or/Makefile.am
32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
34 AC_ARG_ENABLE(openbsd-malloc,
35 AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD. Linux only]))
36 AC_ARG_ENABLE(static-openssl,
37 AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
38 AC_ARG_ENABLE(static-libevent,
39 AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
40 AC_ARG_ENABLE(static-zlib,
41 AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
42 AC_ARG_ENABLE(static-tor,
43 AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
44 AC_ARG_ENABLE(unittests,
45 AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
46 AC_ARG_ENABLE(coverage,
47 AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
48 AC_ARG_ENABLE(asserts-in-tests,
49 AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
50 AC_ARG_ENABLE(system-torrc,
51 AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
53 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
54 AC_MSG_ERROR([Can't disable assertions outside of coverage build])
55 fi
57 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
58 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
59 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
61 if test "$enable_static_tor" = "yes"; then
62 enable_static_libevent="yes";
63 enable_static_openssl="yes";
64 enable_static_zlib="yes";
65 CFLAGS="$CFLAGS -static"
66 fi
68 if test "$enable_system_torrc" = "no"; then
69 AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
70 [Defined if we're not going to look for a torrc in SYSCONF])
71 fi
73 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
75 AC_ARG_ENABLE(asciidoc,
76 AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
77 [case "${enableval}" in
78 "yes") asciidoc=true ;;
79 "no") asciidoc=false ;;
80 *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
81 esac], [asciidoc=true])
83 # systemd notify support
84 AC_ARG_ENABLE(systemd,
85 AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
86 [case "${enableval}" in
87 "yes") systemd=true ;;
88 "no") systemd=false ;;
89 * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
90 esac], [systemd=auto])
94 # systemd support
95 if test "x$enable_systemd" = "xno"; then
96 have_systemd=no;
97 else
98 PKG_CHECK_MODULES(SYSTEMD,
99 [libsystemd-daemon],
100 have_systemd=yes,
101 have_systemd=no)
102 if test "x$have_systemd" = "xno"; then
103 AC_MSG_NOTICE([Okay, checking for systemd a different way...])
104 PKG_CHECK_MODULES(SYSTEMD,
105 [libsystemd],
106 have_systemd=yes,
107 have_systemd=no)
108 fi
109 fi
111 if test "x$have_systemd" = "xyes"; then
112 AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
113 TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
114 TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
115 PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
116 [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
117 fi
118 AC_SUBST(TOR_SYSTEMD_CFLAGS)
119 AC_SUBST(TOR_SYSTEMD_LIBS)
121 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
122 AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
123 fi
125 case "$host" in
126 *-*-solaris* )
127 AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
128 ;;
129 esac
131 AC_ARG_ENABLE(gcc-warnings,
132 AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
133 AC_ARG_ENABLE(fatal-warnings,
134 AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
135 AC_ARG_ENABLE(gcc-warnings-advisory,
136 AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
138 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
139 AC_ARG_ENABLE(gcc-hardening,
140 AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
142 AC_ARG_ENABLE(expensive-hardening,
143 AS_HELP_STRING(--enable-expensive-hardening, [enable more expensive compiler hardening; makes Tor slower]))
145 dnl Linker hardening options
146 dnl Currently these options are ELF specific - you can't use this with MacOSX
147 AC_ARG_ENABLE(linker-hardening,
148 AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
150 AC_ARG_ENABLE(local-appdata,
151 AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
152 if test "$enable_local_appdata" = "yes"; then
153 AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
154 [Defined if we default to host local appdata paths on Windows])
155 fi
157 # Tor2web mode flag
158 AC_ARG_ENABLE(tor2web-mode,
159 AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
160 [if test "x$enableval" = "xyes"; then
161 CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
162 fi])
164 AC_ARG_ENABLE(tool-name-check,
165 AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
167 AC_ARG_ENABLE(seccomp,
168 AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
170 AC_ARG_ENABLE(libscrypt,
171 AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
173 dnl check for the correct "ar" when cross-compiling
174 AN_MAKEVAR([AR], [AC_PROG_AR])
175 AN_PROGRAM([ar], [AC_PROG_AR])
176 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
177 AC_PROG_AR
179 dnl Check whether the above macro has settled for a simply named tool even
180 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
181 dnl because that will find any cc on the system, not only the cross-compiler,
182 dnl and then verify that a binary built with this compiler runs on the
183 dnl build system. It will then come to the false conclusion that we're not
184 dnl cross-compiling.
185 if test "x$enable_tool_name_check" != "xno"; then
186 if test "x$ac_tool_warned" = "xyes"; then
187 AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
188 elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
189 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
190 fi
191 fi
193 AC_PROG_CC
194 AC_PROG_CPP
195 AC_PROG_MAKE_SET
196 AC_PROG_RANLIB
198 AC_PATH_PROG([PERL], [perl])
200 dnl autoconf 2.59 appears not to support AC_PROG_SED
201 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
203 dnl check for asciidoc and a2x
204 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
205 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
207 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
209 AM_CONDITIONAL(USE_FW_HELPER, test "x$natpmp" = "xtrue" || test "x$upnp" = "xtrue")
210 AM_CONDITIONAL(NAT_PMP, test "x$natpmp" = "xtrue")
211 AM_CONDITIONAL(MINIUPNPC, test "x$upnp" = "xtrue")
212 AM_PROG_CC_C_O
213 AC_PROG_CC_C99
215 AC_ARG_VAR([PYTHON], [path to Python binary])
216 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
217 if test "x$PYTHON" = "x"; then
218 AC_MSG_WARN([Python unavailable; some tests will not be run.])
219 fi
220 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
222 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
223 AC_C_FLEXIBLE_ARRAY_MEMBER
224 ], [
225 dnl Maybe we've got an old autoconf...
226 AC_CACHE_CHECK([for flexible array members],
227 tor_cv_c_flexarray,
228 [AC_COMPILE_IFELSE(
229 AC_LANG_PROGRAM([
230 struct abc { int a; char b[]; };
231 ], [
232 struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
233 def->b[0] = 33;
234 ]),
235 [tor_cv_c_flexarray=yes],
236 [tor_cv_c_flexarray=no])])
237 if test "$tor_cv_flexarray" = "yes"; then
238 AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
239 else
240 AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
241 fi
242 ])
244 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
245 tor_cv_c_c99_decl,
246 [AC_COMPILE_IFELSE(
247 [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
248 [tor_cv_c_c99_decl=yes],
249 [tor_cv_c_c99_decl=no] )])
250 if test "$tor_cv_c_c99_decl" != "yes"; then
251 AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
252 fi
254 AC_CACHE_CHECK([for working C99 designated initializers],
255 tor_cv_c_c99_designated_init,
256 [AC_COMPILE_IFELSE(
257 [AC_LANG_PROGRAM([struct s { int a; int b; };],
258 [[ struct s ss = { .b = 5, .a = 6 }; ]])],
259 [tor_cv_c_c99_designated_init=yes],
260 [tor_cv_c_c99_designated_init=no] )])
262 if test "$tor_cv_c_c99_designated_init" != "yes"; then
263 AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
264 fi
266 TORUSER=_tor
267 AC_ARG_WITH(tor-user,
268 AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
269 [
270 TORUSER=$withval
271 ]
272 )
273 AC_SUBST(TORUSER)
275 TORGROUP=_tor
276 AC_ARG_WITH(tor-group,
277 AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
278 [
279 TORGROUP=$withval
280 ]
281 )
282 AC_SUBST(TORGROUP)
285 dnl If _WIN32 is defined and non-zero, we are building for win32
286 AC_MSG_CHECKING([for win32])
287 AC_RUN_IFELSE([AC_LANG_SOURCE([
288 int main(int c, char **v) {
289 #ifdef _WIN32
290 #if _WIN32
291 return 0;
292 #else
293 return 1;
294 #endif
295 #else
296 return 2;
297 #endif
298 }])],
299 bwin32=true; AC_MSG_RESULT([yes]),
300 bwin32=false; AC_MSG_RESULT([no]),
301 bwin32=cross; AC_MSG_RESULT([cross])
302 )
304 if test "$bwin32" = "cross"; then
305 AC_MSG_CHECKING([for win32 (cross)])
306 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
307 #ifdef _WIN32
308 int main(int c, char **v) {return 0;}
309 #else
310 #error
311 int main(int c, char **v) {return x(y);}
312 #endif
313 ])],
314 bwin32=true; AC_MSG_RESULT([yes]),
315 bwin32=false; AC_MSG_RESULT([no]))
316 fi
318 AH_BOTTOM([
319 #ifdef _WIN32
320 /* Defined to access windows functions and definitions for >=WinXP */
321 # ifndef WINVER
322 # define WINVER 0x0501
323 # endif
325 /* Defined to access _other_ windows functions and definitions for >=WinXP */
326 # ifndef _WIN32_WINNT
327 # define _WIN32_WINNT 0x0501
328 # endif
330 /* Defined to avoid including some windows headers as part of Windows.h */
331 # ifndef WIN32_LEAN_AND_MEAN
332 # define WIN32_LEAN_AND_MEAN 1
333 # endif
334 #endif
335 ])
338 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
340 dnl Enable C99 when compiling with MIPSpro
341 AC_MSG_CHECKING([for MIPSpro compiler])
342 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
343 #if (defined(__sgi) && defined(_COMPILER_VERSION))
344 #error
345 return x(y);
346 #endif
347 ])],
348 bmipspro=false; AC_MSG_RESULT(no),
349 bmipspro=true; AC_MSG_RESULT(yes))
351 if test "$bmipspro" = "true"; then
352 CFLAGS="$CFLAGS -c99"
353 fi
355 AC_C_BIGENDIAN
357 AC_SEARCH_LIBS(socket, [socket network])
358 AC_SEARCH_LIBS(gethostbyname, [nsl])
359 AC_SEARCH_LIBS(dlopen, [dl])
360 AC_SEARCH_LIBS(inet_aton, [resolv])
361 AC_SEARCH_LIBS(backtrace, [execinfo])
362 saved_LIBS="$LIBS"
363 AC_SEARCH_LIBS([clock_gettime], [rt])
364 if test "$LIBS" != "$saved_LIBS"; then
365 # Looks like we need -lrt for clock_gettime().
366 have_rt=yes
367 fi
369 AC_SEARCH_LIBS(pthread_create, [pthread])
370 AC_SEARCH_LIBS(pthread_detach, [pthread])
372 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
373 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
375 AC_CHECK_FUNCS(
376 _NSGetEnviron \
377 RtlSecureZeroMemory \
378 SecureZeroMemory \
379 accept4 \
380 backtrace \
381 backtrace_symbols_fd \
382 clock_gettime \
383 eventfd \
384 explicit_bzero \
385 timingsafe_memcmp \
386 flock \
387 ftime \
388 getaddrinfo \
389 getentropy \
390 getifaddrs \
391 getpass \
392 getrlimit \
393 gettimeofday \
394 gmtime_r \
395 htonll \
396 inet_aton \
397 ioctl \
398 issetugid \
399 llround \
400 localtime_r \
401 lround \
402 memmem \
403 memset_s \
404 pipe \
405 pipe2 \
406 prctl \
407 readpassphrase \
408 rint \
409 sigaction \
410 socketpair \
411 statvfs \
412 strlcat \
413 strlcpy \
414 strnlen \
415 strptime \
416 strtok_r \
417 strtoull \
418 sysconf \
419 sysctl \
420 truncate \
421 uname \
422 usleep \
423 vasprintf \
424 _vscprintf
425 )
427 if test "$bwin32" != "true"; then
428 AC_CHECK_HEADERS(pthread.h)
429 AC_CHECK_FUNCS(pthread_create)
430 AC_CHECK_FUNCS(pthread_condattr_setclock)
431 fi
433 if test "$bwin32" = "true"; then
434 AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
435 #include <windows.h>
436 #include <conio.h>
437 #include <wchar.h>
438 ])
439 fi
441 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
442 test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
444 dnl ------------------------------------------------------
445 dnl Where do you live, libevent? And how do we call you?
447 if test "$bwin32" = "true"; then
448 TOR_LIB_WS32=-lws2_32
449 TOR_LIB_IPHLPAPI=-liphlpapi
450 # Some of the cargo-cults recommend -lwsock32 as well, but I don't
451 # think it's actually necessary.
452 TOR_LIB_GDI=-lgdi32
453 else
454 TOR_LIB_WS32=
455 TOR_LIB_GDI=
456 fi
457 AC_SUBST(TOR_LIB_WS32)
458 AC_SUBST(TOR_LIB_GDI)
459 AC_SUBST(TOR_LIB_IPHLPAPI)
461 tor_libevent_pkg_redhat="libevent"
462 tor_libevent_pkg_debian="libevent-dev"
463 tor_libevent_devpkg_redhat="libevent-devel"
464 tor_libevent_devpkg_debian="libevent-dev"
466 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
467 dnl linking for static builds.
468 STATIC_LIBEVENT_FLAGS=""
469 if test "$enable_static_libevent" = "yes"; then
470 if test "$have_rt" = "yes"; then
471 STATIC_LIBEVENT_FLAGS=" -lrt "
472 fi
473 fi
475 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
476 #ifdef _WIN32
477 #include <winsock2.h>
478 #endif
479 #include <sys/time.h>
480 #include <sys/types.h>
481 #include <event2/event.h>], [
482 #ifdef _WIN32
483 #include <winsock2.h>
484 #endif
485 void *event_init(void);],
486 [
487 #ifdef _WIN32
488 {WSADATA d; WSAStartup(0x101,&d); }
489 #endif
490 event_init();
491 ], [--with-libevent-dir], [/opt/libevent])
493 dnl Determine the incantation needed to link libevent.
494 save_LIBS="$LIBS"
495 save_LDFLAGS="$LDFLAGS"
496 save_CPPFLAGS="$CPPFLAGS"
498 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
499 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
500 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
502 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
504 if test "$enable_static_libevent" = "yes"; then
505 if test "$tor_cv_library_libevent_dir" = "(system)"; then
506 AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
507 else
508 TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
509 fi
510 else
511 if test "x$ac_cv_header_event2_event_h" = "xyes"; then
512 AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
513 AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
515 if test "$ac_cv_search_event_new" != "none required"; then
516 TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
517 fi
518 if test "$ac_cv_search_evdns_base_new" != "none required"; then
519 TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
520 fi
521 else
522 AC_MSG_ERROR("libevent2 is required but the headers could not be found")
523 fi
524 fi
526 dnl Now check for particular libevent functions.
527 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
528 evutil_secure_rng_add_bytes \
529 ])
531 LIBS="$save_LIBS"
532 LDFLAGS="$save_LDFLAGS"
533 CPPFLAGS="$save_CPPFLAGS"
535 dnl Check that libevent is at least at version 2.0.10, the first stable
536 dnl release of its series
537 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
538 AC_MSG_CHECKING([whether Libevent is new enough])
539 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
540 #include <event2/event.h>
541 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
542 #error
543 int x = y(zz);
544 #else
545 int x = 1;
546 #endif
547 ])], [ AC_MSG_RESULT([yes]) ],
548 [ AC_MSG_RESULT([no])
549 AC_MSG_ERROR([Libevent is not new enough. We require 2.0.10-stable or later]) ] )
551 LIBS="$save_LIBS"
552 LDFLAGS="$save_LDFLAGS"
553 CPPFLAGS="$save_CPPFLAGS"
555 AC_SUBST(TOR_LIBEVENT_LIBS)
557 dnl ------------------------------------------------------
558 dnl Where do you live, libm?
560 dnl On some platforms (Haiku/BeOS) the math library is
561 dnl part of libroot. In which case don't link against lm
562 TOR_LIB_MATH=""
563 save_LIBS="$LIBS"
564 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
565 if test "$ac_cv_search_pow" != "none required"; then
566 TOR_LIB_MATH="$ac_cv_search_pow"
567 fi
568 LIBS="$save_LIBS"
569 AC_SUBST(TOR_LIB_MATH)
571 dnl ------------------------------------------------------
572 dnl Where do you live, openssl? And how do we call you?
574 tor_openssl_pkg_redhat="openssl"
575 tor_openssl_pkg_debian="libssl-dev"
576 tor_openssl_devpkg_redhat="openssl-devel"
577 tor_openssl_devpkg_debian="libssl-dev"
579 ALT_openssl_WITHVAL=""
580 AC_ARG_WITH(ssl-dir,
581 AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
582 [
583 if test "x$withval" != "xno" && test "x$withval" != "x"; then
584 ALT_openssl_WITHVAL="$withval"
585 fi
586 ])
588 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
589 [#include <openssl/rand.h>],
590 [void RAND_add(const void *buf, int num, double entropy);],
591 [RAND_add((void*)0,0,0);], [],
592 [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
594 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
596 if test "$enable_static_openssl" = "yes"; then
597 if test "$tor_cv_library_openssl_dir" = "(system)"; then
598 AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
599 else
600 TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
601 fi
602 else
603 TOR_OPENSSL_LIBS="-lssl -lcrypto"
604 fi
605 AC_SUBST(TOR_OPENSSL_LIBS)
607 dnl Now check for particular openssl functions.
608 save_LIBS="$LIBS"
609 save_LDFLAGS="$LDFLAGS"
610 save_CPPFLAGS="$CPPFLAGS"
611 LIBS="$TOR_OPENSSL_LIBS $LIBS"
612 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
613 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
615 AC_TRY_COMPILE([
616 #include <openssl/opensslv.h>
617 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
618 #error "too old"
619 #endif
620 ], [],
621 [ : ],
622 [ AC_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
624 AC_TRY_COMPILE([
625 #include <openssl/opensslv.h>
626 #include <openssl/evp.h>
627 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
628 #error "no ECC"
629 #endif
630 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
631 #error "curves unavailable"
632 #endif
633 ], [],
634 [ : ],
635 [ AC_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
637 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
638 [#include <openssl/ssl.h>
639 ])
641 AC_CHECK_FUNCS([ \
642 SSL_SESSION_get_master_key \
643 SSL_get_server_random \
644 SSL_get_client_ciphers \
645 SSL_get_client_random \
646 SSL_CIPHER_find \
647 TLS_method
648 ])
650 dnl Check if OpenSSL has scrypt implementation.
651 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
653 LIBS="$save_LIBS"
654 LDFLAGS="$save_LDFLAGS"
655 CPPFLAGS="$save_CPPFLAGS"
657 dnl ------------------------------------------------------
658 dnl Where do you live, zlib? And how do we call you?
660 tor_zlib_pkg_redhat="zlib"
661 tor_zlib_pkg_debian="zlib1g"
662 tor_zlib_devpkg_redhat="zlib-devel"
663 tor_zlib_devpkg_debian="zlib1g-dev"
665 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
666 [#include <zlib.h>],
667 [const char * zlibVersion(void);],
668 [zlibVersion();], [--with-zlib-dir],
669 [/opt/zlib])
671 if test "$enable_static_zlib" = "yes"; then
672 if test "$tor_cv_library_zlib_dir" = "(system)"; then
673 AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
674 using --enable-static-zlib")
675 else
676 TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
677 fi
678 else
679 TOR_ZLIB_LIBS="-lz"
680 fi
681 AC_SUBST(TOR_ZLIB_LIBS)
683 dnl ----------------------------------------------------------------------
684 dnl Check if libcap is available for capabilities.
686 tor_cap_pkg_debian="libcap2"
687 tor_cap_pkg_redhat="libcap"
688 tor_cap_devpkg_debian="libcap-dev"
689 tor_cap_devpkg_redhat="libcap-devel"
691 AC_CHECK_LIB([cap], [cap_init], [],
692 AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
693 )
694 AC_CHECK_FUNCS(cap_set_proc)
696 dnl ---------------------------------------------------------------------
697 dnl Now that we know about our major libraries, we can check for compiler
698 dnl and linker hardening options. We need to do this with the libraries known,
699 dnl since sometimes the linker will like an option but not be willing to
700 dnl use it with a build of a library.
702 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
703 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_CAP_LIBS"
705 CFLAGS_FTRAPV=
706 CFLAGS_FWRAPV=
707 CFLAGS_ASAN=
708 CFLAGS_UBSAN=
710 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
711 #if !defined(__clang__)
712 #error
713 #endif])], have_clang=yes, have_clang=no)
715 if test "x$enable_gcc_hardening" != "xno"; then
716 CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
717 if test "x$have_clang" = "xyes"; then
718 TOR_CHECK_CFLAGS(-Qunused-arguments)
719 fi
720 TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
721 AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
722 AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
723 m4_ifdef([AS_VAR_IF],[
724 AS_VAR_IF(can_compile, [yes],
725 AS_VAR_IF(can_link, [yes],
726 [],
727 AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
728 )])
729 AS_VAR_POPDEF([can_link])
730 AS_VAR_POPDEF([can_compile])
731 TOR_CHECK_CFLAGS(-Wstack-protector)
732 TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
733 if test "$bwin32" = "false"; then
734 TOR_CHECK_CFLAGS(-fPIE)
735 TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
736 fi
737 TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
738 TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
739 if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
740 AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
741 fi
742 fi
744 if test "x$enable_expensive_hardening" = "xyes"; then
745 if test "$tor_cv_cflags__ftrapv" != "yes"; then
746 AC_MSG_ERROR([You requested expensive hardening, but the compiler does not seem to support -ftrapv.])
747 fi
749 TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
750 if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
751 AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
752 fi
754 TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
755 if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
756 AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
757 fi
759 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
760 fi
762 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
763 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
765 mulodi_fixes_ftrapv=no
766 if test "$have_clang" = "yes"; then
767 saved_CFLAGS="$CFLAGS"
768 CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
769 AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
770 AC_LINK_IFELSE([
771 AC_LANG_SOURCE([[
772 #include <stdint.h>
773 #include <stdlib.h>
774 int main(int argc, char **argv)
775 {
776 int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
777 * (int64_t)atoi(argv[3]);
778 return x == 9;
779 } ]])],
780 [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
781 [ftrapv_can_link=no; AC_MSG_RESULT([no])])
782 if test "$ftrapv_can_link" = "no"; then
783 AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
784 AC_LINK_IFELSE([
785 AC_LANG_SOURCE([[
786 #include <stdint.h>
787 #include <stdlib.h>
788 int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
789 *overflow=0;
790 return a;
791 }
792 int main(int argc, char **argv)
793 {
794 int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
795 * (int64_t)atoi(argv[3]);
796 return x == 9;
797 } ]])],
798 [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
799 [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
800 fi
801 CFLAGS="$saved_CFLAGS"
802 fi
804 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
806 dnl These cflags add bunches of branches, and we haven't been able to
807 dnl persuade ourselves that they're suitable for code that needs to be
808 dnl constant time.
809 AC_SUBST(CFLAGS_BUGTRAP)
810 dnl These cflags are variant ones sutable for code that needs to be
811 dnl constant-time.
812 AC_SUBST(CFLAGS_CONSTTIME)
814 if test "x$enable_linker_hardening" != "xno"; then
815 TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
816 fi
818 # For backtrace support
819 TOR_CHECK_LDFLAGS(-rdynamic)
821 dnl ------------------------------------------------------
822 dnl Now see if we have a -fomit-frame-pointer compiler option.
824 saved_CFLAGS="$CFLAGS"
825 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
826 F_OMIT_FRAME_POINTER=''
827 if test "$saved_CFLAGS" != "$CFLAGS"; then
828 if test "x$enable_expensive_hardening" != "xyes"; then
829 F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
830 fi
831 fi
832 CFLAGS="$saved_CFLAGS"
833 AC_SUBST(F_OMIT_FRAME_POINTER)
835 dnl ------------------------------------------------------
836 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
837 dnl for us, as GCC 4.6 and later do at many optimization levels), then
838 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
839 dnl code will work.
840 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
842 dnl ============================================================
843 dnl Check for libseccomp
845 if test "x$enable_seccomp" != "xno"; then
846 AC_CHECK_HEADERS([seccomp.h])
847 AC_SEARCH_LIBS(seccomp_init, [seccomp])
848 fi
850 dnl ============================================================
851 dnl Check for libscrypt
853 if test "x$enable_libscrypt" != "xno"; then
854 AC_CHECK_HEADERS([libscrypt.h])
855 AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
856 AC_CHECK_FUNCS([libscrypt_scrypt])
857 fi
859 dnl ============================================================
860 dnl We need an implementation of curve25519.
862 dnl set these defaults.
863 build_curve25519_donna=no
864 build_curve25519_donna_c64=no
865 use_curve25519_donna=no
866 use_curve25519_nacl=no
867 CURVE25519_LIBS=
869 dnl The best choice is using curve25519-donna-c64, but that requires
870 dnl that we
871 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
872 tor_cv_can_use_curve25519_donna_c64,
873 [AC_RUN_IFELSE(
874 [AC_LANG_PROGRAM([dnl
875 #include <stdint.h>
876 typedef unsigned uint128_t __attribute__((mode(TI)));
877 int func(uint64_t a, uint64_t b) {
878 uint128_t c = ((uint128_t)a) * b;
879 int ok = ((uint64_t)(c>>96)) == 522859 &&
880 (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
881 (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
882 (((uint64_t)(c))&0xffffffffL) == 0;
883 return ok;
884 }
885 ], [dnl
886 int ok = func( ((uint64_t)2000000000) * 1000000000,
887 ((uint64_t)1234567890) << 24);
888 return !ok;
889 ])],
890 [tor_cv_can_use_curve25519_donna_c64=yes],
891 [tor_cv_can_use_curve25519_donna_c64=no],
892 [AC_LINK_IFELSE(
893 [AC_LANG_PROGRAM([dnl
894 #include <stdint.h>
895 typedef unsigned uint128_t __attribute__((mode(TI)));
896 int func(uint64_t a, uint64_t b) {
897 uint128_t c = ((uint128_t)a) * b;
898 int ok = ((uint64_t)(c>>96)) == 522859 &&
899 (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
900 (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
901 (((uint64_t)(c))&0xffffffffL) == 0;
902 return ok;
903 }
904 ], [dnl
905 int ok = func( ((uint64_t)2000000000) * 1000000000,
906 ((uint64_t)1234567890) << 24);
907 return !ok;
908 ])],
909 [tor_cv_can_use_curve25519_donna_c64=cross],
910 [tor_cv_can_use_curve25519_donna_c64=no])])])
912 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
913 nacl/crypto_scalarmult_curve25519.h])
915 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
916 tor_cv_can_use_curve25519_nacl,
917 [tor_saved_LIBS="$LIBS"
918 LIBS="$LIBS -lnacl"
919 AC_LINK_IFELSE(
920 [AC_LANG_PROGRAM([dnl
921 #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
922 #include <crypto_scalarmult_curve25519.h>
923 #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
924 #include <nacl/crypto_scalarmult_curve25519.h>
925 #endif
926 #ifdef crypto_scalarmult_curve25519_ref_BYTES
927 #error Hey, this is the reference implementation! That's not fast.
928 #endif
929 ], [
930 unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
931 ])], [tor_cv_can_use_curve25519_nacl=yes],
932 [tor_cv_can_use_curve25519_nacl=no])
933 LIBS="$tor_saved_LIBS" ])
935 dnl Okay, now we need to figure out which one to actually use. Fall back
936 dnl to curve25519-donna.c
938 if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
939 build_curve25519_donna_c64=yes
940 use_curve25519_donna=yes
941 elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
942 use_curve25519_nacl=yes
943 CURVE25519_LIBS=-lnacl
944 else
945 build_curve25519_donna=yes
946 use_curve25519_donna=yes
947 fi
949 if test "x$use_curve25519_donna" = "xyes"; then
950 AC_DEFINE(USE_CURVE25519_DONNA, 1,
951 [Defined if we should use an internal curve25519_donna{,_c64} implementation])
952 fi
953 if test "x$use_curve25519_nacl" = "xyes"; then
954 AC_DEFINE(USE_CURVE25519_NACL, 1,
955 [Defined if we should use a curve25519 from nacl])
956 fi
957 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
958 test "x$build_curve25519_donna" = "xyes")
959 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
960 test "x$build_curve25519_donna_c64" = "xyes")
961 AC_SUBST(CURVE25519_LIBS)
963 dnl Make sure to enable support for large off_t if available.
964 AC_SYS_LARGEFILE
966 AC_CHECK_HEADERS([assert.h \
967 errno.h \
968 fcntl.h \
969 signal.h \
970 string.h \
971 sys/capability.h \
972 sys/fcntl.h \
973 sys/stat.h \
974 sys/time.h \
975 sys/types.h \
976 time.h \
977 unistd.h \
978 arpa/inet.h \
979 crt_externs.h \
980 execinfo.h \
981 grp.h \
982 ifaddrs.h \
983 inttypes.h \
984 limits.h \
985 linux/types.h \
986 machine/limits.h \
987 malloc.h \
988 malloc/malloc.h \
989 malloc_np.h \
990 netdb.h \
991 netinet/in.h \
992 netinet/in6.h \
993 pwd.h \
994 readpassphrase.h \
995 stdint.h \
996 sys/eventfd.h \
997 sys/file.h \
998 sys/ioctl.h \
999 sys/limits.h \
1000 sys/mman.h \
1001 sys/param.h \
1002 sys/prctl.h \
1003 sys/random.h \
1004 sys/resource.h \
1005 sys/select.h \
1006 sys/socket.h \
1007 sys/statvfs.h \
1008 sys/syscall.h \
1009 sys/sysctl.h \
1010 sys/syslimits.h \
1011 sys/time.h \
1012 sys/types.h \
1013 sys/un.h \
1014 sys/utime.h \
1015 sys/wait.h \
1016 syslog.h \
1017 utime.h])
1019 AC_CHECK_HEADERS(sys/param.h)
1021 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1022 [#ifdef HAVE_SYS_TYPES_H
1023 #include <sys/types.h>
1024 #endif
1025 #ifdef HAVE_SYS_SOCKET_H
1026 #include <sys/socket.h>
1027 #endif])
1028 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1029 [#ifdef HAVE_SYS_TYPES_H
1030 #include <sys/types.h>
1031 #endif
1032 #ifdef HAVE_SYS_SOCKET_H
1033 #include <sys/socket.h>
1034 #endif
1035 #ifdef HAVE_NET_IF_H
1036 #include <net/if.h>
1037 #endif
1038 #ifdef HAVE_NETINET_IN_H
1039 #include <netinet/in.h>
1040 #endif])
1042 AC_CHECK_HEADERS(linux/if.h,[],[],
1043 [
1044 #ifdef HAVE_SYS_SOCKET_H
1045 #include <sys/socket.h>
1046 #endif
1047 ])
1049 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1050 linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1051 [#ifdef HAVE_SYS_TYPES_H
1052 #include <sys/types.h>
1053 #endif
1054 #ifdef HAVE_SYS_SOCKET_H
1055 #include <sys/socket.h>
1056 #endif
1057 #ifdef HAVE_LIMITS_H
1058 #include <limits.h>
1059 #endif
1060 #ifdef HAVE_LINUX_TYPES_H
1061 #include <linux/types.h>
1062 #endif
1063 #ifdef HAVE_NETINET_IN6_H
1064 #include <netinet/in6.h>
1065 #endif
1066 #ifdef HAVE_NETINET_IN_H
1067 #include <netinet/in.h>
1068 #endif])
1070 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1071 linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1072 [#ifdef HAVE_SYS_TYPES_H
1073 #include <sys/types.h>
1074 #endif
1075 #ifdef HAVE_SYS_SOCKET_H
1076 #include <sys/socket.h>
1077 #endif
1078 #ifdef HAVE_LIMITS_H
1079 #include <limits.h>
1080 #endif
1081 #ifdef HAVE_LINUX_TYPES_H
1082 #include <linux/types.h>
1083 #endif
1084 #ifdef HAVE_NETINET_IN6_H
1085 #include <netinet/in6.h>
1086 #endif
1087 #ifdef HAVE_NETINET_IN_H
1088 #include <netinet/in.h>
1089 #endif
1090 #ifdef HAVE_LINUX_IF_H
1091 #include <linux/if.h>
1092 #endif])
1094 transparent_ok=0
1095 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1096 transparent_ok=1
1097 fi
1098 if test "x$linux_netfilter_ipv4" = "x1"; then
1099 transparent_ok=1
1100 fi
1101 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1102 transparent_ok=1
1103 fi
1104 if test "x$transparent_ok" = "x1"; then
1105 AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1106 case "$host" in
1107 *-*-openbsd* | *-*-bitrig*)
1108 AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
1109 esac
1110 else
1111 AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1112 fi
1114 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1115 [#ifdef HAVE_SYS_TYPES_H
1116 #include <sys/types.h>
1117 #endif
1118 #ifdef HAVE_SYS_TIME_H
1119 #include <sys/time.h>
1120 #endif])
1122 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1123 dnl Watch out.
1125 AC_CHECK_SIZEOF(int8_t)
1126 AC_CHECK_SIZEOF(int16_t)
1127 AC_CHECK_SIZEOF(int32_t)
1128 AC_CHECK_SIZEOF(int64_t)
1129 AC_CHECK_SIZEOF(uint8_t)
1130 AC_CHECK_SIZEOF(uint16_t)
1131 AC_CHECK_SIZEOF(uint32_t)
1132 AC_CHECK_SIZEOF(uint64_t)
1133 AC_CHECK_SIZEOF(intptr_t)
1134 AC_CHECK_SIZEOF(uintptr_t)
1136 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1138 AC_CHECK_SIZEOF(char)
1139 AC_CHECK_SIZEOF(short)
1140 AC_CHECK_SIZEOF(int)
1141 AC_CHECK_SIZEOF(long)
1142 AC_CHECK_SIZEOF(long long)
1143 AC_CHECK_SIZEOF(__int64)
1144 AC_CHECK_SIZEOF(void *)
1145 AC_CHECK_SIZEOF(time_t)
1146 AC_CHECK_SIZEOF(size_t)
1147 AC_CHECK_SIZEOF(pid_t)
1149 AC_CHECK_TYPES([uint, u_char, ssize_t])
1151 AC_PC_FROM_UCONTEXT([:])
1153 dnl used to include sockaddr_storage, but everybody has that.
1154 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1155 [#ifdef HAVE_SYS_TYPES_H
1156 #include <sys/types.h>
1157 #endif
1158 #ifdef HAVE_NETINET_IN_H
1159 #include <netinet/in.h>
1160 #endif
1161 #ifdef HAVE_NETINET_IN6_H
1162 #include <netinet/in6.h>
1163 #endif
1164 #ifdef HAVE_SYS_SOCKET_H
1165 #include <sys/socket.h>
1166 #endif
1167 #ifdef _WIN32
1168 #define _WIN32_WINNT 0x0501
1169 #define WIN32_LEAN_AND_MEAN
1170 #include <winsock2.h>
1171 #include <ws2tcpip.h>
1172 #endif
1173 ])
1174 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1175 [#ifdef HAVE_SYS_TYPES_H
1176 #include <sys/types.h>
1177 #endif
1178 #ifdef HAVE_NETINET_IN_H
1179 #include <netinet/in.h>
1180 #endif
1181 #ifdef HAVE_NETINET_IN6_H
1182 #include <netinet/in6.h>
1183 #endif
1184 #ifdef HAVE_SYS_SOCKET_H
1185 #include <sys/socket.h>
1186 #endif
1187 #ifdef _WIN32
1188 #define _WIN32_WINNT 0x0501
1189 #define WIN32_LEAN_AND_MEAN
1190 #include <winsock2.h>
1191 #include <ws2tcpip.h>
1192 #endif
1193 ])
1195 AC_CHECK_TYPES([rlim_t], , ,
1196 [#ifdef HAVE_SYS_TYPES_H
1197 #include <sys/types.h>
1198 #endif
1199 #ifdef HAVE_SYS_TIME_H
1200 #include <sys/time.h>
1201 #endif
1202 #ifdef HAVE_SYS_RESOURCE_H
1203 #include <sys/resource.h>
1204 #endif
1205 ])
1207 AX_CHECK_SIGN([time_t],
1208 [ : ],
1209 [ : ], [
1210 #ifdef HAVE_SYS_TYPES_H
1211 #include <sys/types.h>
1212 #endif
1213 #ifdef HAVE_SYS_TIME_H
1214 #include <sys/time.h>
1215 #endif
1216 #ifdef HAVE_TIME_H
1217 #include <time.h>
1218 #endif
1219 ])
1221 if test "$ax_cv_decl_time_t_signed" = "no"; then
1222 AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1223 fi
1225 AX_CHECK_SIGN([size_t],
1226 [ tor_cv_size_t_signed=yes ],
1227 [ tor_cv_size_t_signed=no ], [
1228 #ifdef HAVE_SYS_TYPES_H
1229 #include <sys/types.h>
1230 #endif
1231 ])
1233 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1234 AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1235 fi
1237 AX_CHECK_SIGN([enum always],
1238 [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1239 [ : ], [
1240 enum always { AAA, BBB, CCC };
1241 ])
1243 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1244 #ifdef HAVE_SYS_SOCKET_H
1245 #include <sys/socket.h>
1246 #endif
1247 ])
1249 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1251 AC_CHECK_SIZEOF(cell_t)
1253 # Now make sure that NULL can be represented as zero bytes.
1254 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1255 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1256 [[#include <stdlib.h>
1257 #include <string.h>
1258 #include <stdio.h>
1259 #ifdef HAVE_STDDEF_H
1260 #include <stddef.h>
1261 #endif
1262 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1263 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1264 [tor_cv_null_is_zero=yes],
1265 [tor_cv_null_is_zero=no],
1266 [tor_cv_null_is_zero=cross])])
1268 if test "$tor_cv_null_is_zero" = "cross"; then
1269 # Cross-compiling; let's hope that the target isn't raving mad.
1270 AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1271 fi
1273 if test "$tor_cv_null_is_zero" != "no"; then
1274 AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1275 [Define to 1 iff memset(0) sets pointers to NULL])
1276 fi
1278 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1279 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1280 [[#include <stdlib.h>
1281 #include <string.h>
1282 #include <stdio.h>
1283 #ifdef HAVE_STDDEF_H
1284 #include <stddef.h>
1285 #endif
1286 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1287 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1288 [tor_cv_dbl0_is_zero=yes],
1289 [tor_cv_dbl0_is_zero=no],
1290 [tor_cv_dbl0_is_zero=cross])])
1292 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1293 # Cross-compiling; let's hope that the target isn't raving mad.
1294 AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1295 fi
1297 if test "$tor_cv_dbl0_is_zero" != "no"; then
1298 AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1299 [Define to 1 iff memset(0) sets doubles to 0.0])
1300 fi
1302 # And what happens when we malloc zero?
1303 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1304 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1305 [[#include <stdlib.h>
1306 #include <string.h>
1307 #include <stdio.h>
1308 #ifdef HAVE_STDDEF_H
1309 #include <stddef.h>
1310 #endif
1311 int main () { return malloc(0)?0:1; }]])],
1312 [tor_cv_malloc_zero_works=yes],
1313 [tor_cv_malloc_zero_works=no],
1314 [tor_cv_malloc_zero_works=cross])])
1316 if test "$tor_cv_malloc_zero_works" = "cross"; then
1317 # Cross-compiling; let's hope that the target isn't raving mad.
1318 AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1319 fi
1321 if test "$tor_cv_malloc_zero_works" = "yes"; then
1322 AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1323 [Define to 1 iff malloc(0) returns a pointer])
1324 fi
1326 # whether we seem to be in a 2s-complement world.
1327 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1328 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1329 [[int main () { int problem = ((-99) != (~99)+1);
1330 return problem ? 1 : 0; }]])],
1331 [tor_cv_twos_complement=yes],
1332 [tor_cv_twos_complement=no],
1333 [tor_cv_twos_complement=cross])])
1335 if test "$tor_cv_twos_complement" = "cross"; then
1336 # Cross-compiling; let's hope that the target isn't raving mad.
1337 AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1338 fi
1340 if test "$tor_cv_twos_complement" != "no"; then
1341 AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1342 [Define to 1 iff we represent negative integers with
1343 two's complement])
1344 fi
1346 # What does shifting a negative value do?
1347 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1348 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1349 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1350 [tor_cv_sign_extend=yes],
1351 [tor_cv_sign_extend=no],
1352 [tor_cv_sign_extend=cross])])
1354 if test "$tor_cv_sign_extend" = "cross"; then
1355 # Cross-compiling; let's hope that the target isn't raving mad.
1356 AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1357 fi
1359 if test "$tor_cv_sign_extend" != "no"; then
1360 AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1361 [Define to 1 iff right-shifting a negative value performs sign-extension])
1362 fi
1364 # Whether we should use the dmalloc memory allocation debugging library.
1365 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1366 AC_ARG_WITH(dmalloc,
1367 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1368 [if [[ "$withval" = "yes" ]]; then
1369 dmalloc=1
1370 AC_MSG_RESULT(yes)
1371 else
1372 dmalloc=1
1373 AC_MSG_RESULT(no)
1374 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1375 )
1377 if [[ $dmalloc -eq 1 ]]; then
1378 AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1379 AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1380 AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1381 AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1382 fi
1384 AC_ARG_WITH(tcmalloc,
1385 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1386 [ tcmalloc=yes ], [ tcmalloc=no ])
1388 if test "x$tcmalloc" = "xyes"; then
1389 LDFLAGS="-ltcmalloc $LDFLAGS"
1390 fi
1392 using_custom_malloc=no
1393 if test "x$enable_openbsd_malloc" = "xyes"; then
1394 using_custom_malloc=yes
1395 fi
1396 if test "x$tcmalloc" = "xyes"; then
1397 using_custom_malloc=yes
1398 fi
1399 if test "$using_custom_malloc" = "no"; then
1400 AC_CHECK_FUNCS(mallinfo)
1401 fi
1403 # By default, we're going to assume we don't have mlockall()
1404 # bionic and other platforms have various broken mlockall subsystems.
1405 # Some systems don't have a working mlockall, some aren't linkable,
1406 # and some have it but don't declare it.
1407 AC_CHECK_FUNCS(mlockall)
1408 AC_CHECK_DECLS([mlockall], , , [
1409 #ifdef HAVE_SYS_MMAN_H
1410 #include <sys/mman.h>
1411 #endif])
1413 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1414 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1415 # using macros
1416 AC_CHECK_DECLS([getpagesize], , , [
1417 #ifdef HAVE_UNISTD_H
1418 #include <unistd.h>
1419 #endif])
1421 # Allow user to specify an alternate syslog facility
1422 AC_ARG_WITH(syslog-facility,
1423 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1424 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1425 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1426 AC_SUBST(LOGFACILITY)
1428 # Check if we have getresuid and getresgid
1429 AC_CHECK_FUNCS(getresuid getresgid)
1431 # Check for gethostbyname_r in all its glorious incompatible versions.
1432 # (This logic is based on that in Python's configure.in)
1433 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1434 [Define this if you have any gethostbyname_r()])
1436 AC_CHECK_FUNC(gethostbyname_r, [
1437 AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1438 OLD_CFLAGS=$CFLAGS
1439 CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1440 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1441 #include <netdb.h>
1442 ], [[
1443 char *cp1, *cp2;
1444 struct hostent *h1, *h2;
1445 int i1, i2;
1446 (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1447 ]])],[
1448 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1449 AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1450 [Define this if gethostbyname_r takes 6 arguments])
1451 AC_MSG_RESULT(6)
1452 ], [
1453 AC_TRY_COMPILE([
1454 #include <netdb.h>
1455 ], [
1456 char *cp1, *cp2;
1457 struct hostent *h1;
1458 int i1, i2;
1459 (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1460 ], [
1461 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1462 AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1463 [Define this if gethostbyname_r takes 5 arguments])
1464 AC_MSG_RESULT(5)
1465 ], [
1466 AC_TRY_COMPILE([
1467 #include <netdb.h>
1468 ], [
1469 char *cp1;
1470 struct hostent *h1;
1471 struct hostent_data hd;
1472 (void) gethostbyname_r(cp1,h1,&hd);
1473 ], [
1474 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1475 AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1476 [Define this if gethostbyname_r takes 3 arguments])
1477 AC_MSG_RESULT(3)
1478 ], [
1479 AC_MSG_RESULT(0)
1480 ])
1481 ])
1482 ])
1483 CFLAGS=$OLD_CFLAGS
1484 ])
1486 AC_CACHE_CHECK([whether the C compiler supports __func__],
1487 tor_cv_have_func_macro,
1488 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1489 #include <stdio.h>
1490 int main(int c, char **v) { puts(__func__); }])],
1491 tor_cv_have_func_macro=yes,
1492 tor_cv_have_func_macro=no))
1494 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1495 tor_cv_have_FUNC_macro,
1496 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1497 #include <stdio.h>
1498 int main(int c, char **v) { puts(__FUNC__); }])],
1499 tor_cv_have_FUNC_macro=yes,
1500 tor_cv_have_FUNC_macro=no))
1502 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1503 tor_cv_have_FUNCTION_macro,
1504 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1505 #include <stdio.h>
1506 int main(int c, char **v) { puts(__FUNCTION__); }])],
1507 tor_cv_have_FUNCTION_macro=yes,
1508 tor_cv_have_FUNCTION_macro=no))
1510 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1511 tor_cv_have_environ_declared,
1512 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1513 #ifdef HAVE_UNISTD_H
1514 #include <unistd.h>
1515 #endif
1516 #include <stdlib.h>
1517 int main(int c, char **v) { char **t = environ; }])],
1518 tor_cv_have_environ_declared=yes,
1519 tor_cv_have_environ_declared=no))
1521 if test "$tor_cv_have_func_macro" = "yes"; then
1522 AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1523 fi
1525 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1526 AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1527 fi
1529 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1530 AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1531 [Defined if the compiler supports __FUNCTION__])
1532 fi
1534 if test "$tor_cv_have_environ_declared" = "yes"; then
1535 AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1536 [Defined if we have extern char **environ already declared])
1537 fi
1539 # $prefix stores the value of the --prefix command line option, or
1540 # NONE if the option wasn't set. In the case that it wasn't set, make
1541 # it be the default, so that we can use it to expand directories now.
1542 if test "x$prefix" = "xNONE"; then
1543 prefix=$ac_default_prefix
1544 fi
1546 # and similarly for $exec_prefix
1547 if test "x$exec_prefix" = "xNONE"; then
1548 exec_prefix=$prefix
1549 fi
1551 if test "x$BUILDDIR" = "x"; then
1552 BUILDDIR=`pwd`
1553 fi
1554 AC_SUBST(BUILDDIR)
1555 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1556 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1558 if test "x$CONFDIR" = "x"; then
1559 CONFDIR=`eval echo $sysconfdir/tor`
1560 fi
1561 AC_SUBST(CONFDIR)
1562 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1563 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1565 BINDIR=`eval echo $bindir`
1566 AC_SUBST(BINDIR)
1567 LOCALSTATEDIR=`eval echo $localstatedir`
1568 AC_SUBST(LOCALSTATEDIR)
1570 if test "$bwin32" = "true"; then
1571 # Test if the linker supports the --nxcompat and --dynamicbase options
1572 # for Windows
1573 save_LDFLAGS="$LDFLAGS"
1574 LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1575 AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1576 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1577 [AC_MSG_RESULT([yes])]
1578 [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1579 [AC_MSG_RESULT([no])]
1580 )
1581 LDFLAGS="$save_LDFLAGS"
1582 fi
1584 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1585 # than autoconf's macros like.
1586 if test "$GCC" = "yes"; then
1587 # Disable GCC's strict aliasing checks. They are an hours-to-debug
1588 # accident waiting to happen.
1589 CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1590 else
1591 # Override optimization level for non-gcc compilers
1592 CFLAGS="$CFLAGS -O"
1593 enable_gcc_warnings=no
1594 enable_gcc_warnings_advisory=no
1595 fi
1597 # Warnings implies advisory-warnings and -Werror.
1598 if test "$enable_gcc_warnings" = "yes"; then
1599 enable_gcc_warnings_advisory=yes
1600 enable_fatal_warnings=yes
1601 fi
1603 # OS X Lion started deprecating the system openssl. Let's just disable
1604 # all deprecation warnings on OS X. Also, to potentially make the binary
1605 # a little smaller, let's enable dead_strip.
1606 case "$host_os" in
1608 darwin*)
1609 CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1610 LDFLAGS="$LDFLAGS -dead_strip" ;;
1611 esac
1613 # Add some more warnings which we use in development but not in the
1614 # released versions. (Some relevant gcc versions can't handle these.)
1615 #
1616 # Note that we have to do this near the end of the autoconf process, or
1617 # else we may run into problems when these warnings hit on the testing C
1618 # programs that autoconf wants to build.
1619 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1621 case "$host" in
1622 *-*-openbsd* | *-*-bitrig*)
1623 # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1624 # That's fine, except that the headers don't pass -Wredundant-decls.
1625 # Therefore, let's disable -Wsystem-headers when we're building
1626 # with maximal warnings on OpenBSD.
1627 CFLAGS="$CFLAGS -Wno-system-headers" ;;
1628 esac
1630 # GCC4.3 users once report trouble with -Wstrict-overflow=5. GCC5 users
1631 # have it work better.
1632 # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1634 # This warning was added in gcc 4.3, but it appears to generate
1635 # spurious warnings in gcc 4.4. I don't know if it works in 4.5.
1636 #CFLAGS="$CFLAGS -Wlogical-op"
1638 m4_foreach_w([warning_flag], [
1639 -Waddress
1640 -Waddress-of-array-temporary
1641 -Waddress-of-temporary
1642 -Wambiguous-macro
1643 -Wanonymous-pack-parens
1644 -Warc
1645 -Warc-abi
1646 -Warc-bridge-casts-disallowed-in-nonarc
1647 -Warc-maybe-repeated-use-of-weak
1648 -Warc-performSelector-leaks
1649 -Warc-repeated-use-of-weak
1650 -Warray-bounds
1651 -Warray-bounds-pointer-arithmetic
1652 -Wasm
1653 -Wasm-operand-widths
1654 -Watomic-properties
1655 -Watomic-property-with-user-defined-accessor
1656 -Wauto-import
1657 -Wauto-storage-class
1658 -Wauto-var-id
1659 -Wavailability
1660 -Wbackslash-newline-escape
1661 -Wbad-array-new-length
1662 -Wbind-to-temporary-copy
1663 -Wbitfield-constant-conversion
1664 -Wbool-conversion
1665 -Wbool-conversions
1666 -Wbuiltin-requires-header
1667 -Wchar-align
1668 -Wcompare-distinct-pointer-types
1669 -Wcomplex-component-init
1670 -Wconditional-type-mismatch
1671 -Wconfig-macros
1672 -Wconstant-conversion
1673 -Wconstant-logical-operand
1674 -Wconstexpr-not-const
1675 -Wcustom-atomic-properties
1676 -Wdangling-field
1677 -Wdangling-initializer-list
1678 -Wdate-time
1679 -Wdelegating-ctor-cycles
1680 -Wdeprecated-implementations
1681 -Wdeprecated-register
1682 -Wdirect-ivar-access
1683 -Wdiscard-qual
1684 -Wdistributed-object-modifiers
1685 -Wdivision-by-zero
1686 -Wdollar-in-identifier-extension
1687 -Wdouble-promotion
1688 -Wduplicate-decl-specifier
1689 -Wduplicate-enum
1690 -Wduplicate-method-arg
1691 -Wduplicate-method-match
1692 -Wduplicated-cond
1693 -Wdynamic-class-memaccess
1694 -Wembedded-directive
1695 -Wempty-translation-unit
1696 -Wenum-conversion
1697 -Wexit-time-destructors
1698 -Wexplicit-ownership-type
1699 -Wextern-initializer
1700 -Wextra
1701 -Wextra-semi
1702 -Wextra-tokens
1703 -Wflexible-array-extensions
1704 -Wfloat-conversion
1705 -Wformat-non-iso
1706 -Wfour-char-constants
1707 -Wgcc-compat
1708 -Wglobal-constructors
1709 -Wgnu-array-member-paren-init
1710 -Wgnu-designator
1711 -Wgnu-static-float-init
1712 -Wheader-guard
1713 -Wheader-hygiene
1714 -Widiomatic-parentheses
1715 -Wignored-attributes
1716 -Wimplicit-atomic-properties
1717 -Wimplicit-conversion-floating-point-to-bool
1718 -Wimplicit-exception-spec-mismatch
1719 -Wimplicit-fallthrough
1720 -Wimplicit-fallthrough-per-function
1721 -Wimplicit-retain-self
1722 -Wimport-preprocessor-directive-pedantic
1723 -Wincompatible-library-redeclaration
1724 -Wincompatible-pointer-types-discards-qualifiers
1725 -Wincomplete-implementation
1726 -Wincomplete-module
1727 -Wincomplete-umbrella
1728 -Winit-self
1729 -Wint-conversions
1730 -Wint-to-void-pointer-cast
1731 -Winteger-overflow
1732 -Winvalid-constexpr
1733 -Winvalid-iboutlet
1734 -Winvalid-noreturn
1735 -Winvalid-pp-token
1736 -Winvalid-source-encoding
1737 -Winvalid-token-paste
1738 -Wknr-promoted-parameter
1739 -Wlanguage-extension-token
1740 -Wlarge-by-value-copy
1741 -Wliteral-conversion
1742 -Wliteral-range
1743 -Wlocal-type-template-args
1744 -Wlogical-op
1745 -Wloop-analysis
1746 -Wmain-return-type
1747 -Wmalformed-warning-check
1748 -Wmethod-signatures
1749 -Wmicrosoft
1750 -Wmicrosoft-exists
1751 -Wmismatched-parameter-types
1752 -Wmismatched-return-types
1753 -Wmissing-field-initializers
1754 -Wmissing-format-attribute
1755 -Wmissing-noreturn
1756 -Wmissing-selector-name
1757 -Wmissing-sysroot
1758 -Wmissing-variable-declarations
1759 -Wmodule-conflict
1760 -Wnested-anon-types
1761 -Wnewline-eof
1762 -Wnon-literal-null-conversion
1763 -Wnon-pod-varargs
1764 -Wnonportable-cfstrings
1765 -Wnormalized=id
1766 -Wnull-arithmetic
1767 -Wnull-character
1768 -Wnull-conversion
1769 -Wnull-dereference
1770 -Wout-of-line-declaration
1771 -Wover-aligned
1772 -Woverlength-strings
1773 -Woverride-init
1774 -Woverriding-method-mismatch
1775 -Wpointer-type-mismatch
1776 -Wpredefined-identifier-outside-function
1777 -Wprotocol-property-synthesis-ambiguity
1778 -Wreadonly-iboutlet-property
1779 -Wreadonly-setter-attrs
1780 -Wreceiver-expr
1781 -Wreceiver-forward-class
1782 -Wreceiver-is-weak
1783 -Wreinterpret-base-class
1784 -Wrequires-super-attribute
1785 -Wreserved-user-defined-literal
1786 -Wreturn-stack-address
1787 -Wsection
1788 -Wselector-type-mismatch
1789 -Wsentinel
1790 -Wserialized-diagnostics
1791 -Wshadow
1792 -Wshift-count-negative
1793 -Wshift-count-overflow
1794 -Wshift-negative-value
1795 -Wshift-overflow=2
1796 -Wshift-sign-overflow
1797 -Wshorten-64-to-32
1798 -Wsizeof-array-argument
1799 -Wsource-uses-openmp
1800 -Wstatic-float-init
1801 -Wstatic-in-inline
1802 -Wstatic-local-in-inline
1803 -Wstrict-overflow=2
1804 -Wstring-compare
1805 -Wstring-conversion
1806 -Wstrlcpy-strlcat-size
1807 -Wstrncat-size
1808 -Wsuggest-attribute=format
1809 -Wsuggest-attribute=noreturn
1810 -Wsuper-class-method-mismatch
1811 -Wswitch-bool
1812 -Wsync-nand
1813 -Wtautological-constant-out-of-range-compare
1814 -Wtentative-definition-incomplete-type
1815 -Wtrampolines
1816 -Wtype-safety
1817 -Wtypedef-redefinition
1818 -Wtypename-missing
1819 -Wundefined-inline
1820 -Wundefined-internal
1821 -Wundefined-reinterpret-cast
1822 -Wunicode
1823 -Wunicode-whitespace
1824 -Wunknown-warning-option
1825 -Wunnamed-type-template-args
1826 -Wunneeded-member-function
1827 -Wunsequenced
1828 -Wunsupported-visibility
1829 -Wunused-but-set-parameter
1830 -Wunused-but-set-variable
1831 -Wunused-command-line-argument
1832 -Wunused-const-variable=2
1833 -Wunused-exception-parameter
1834 -Wunused-local-typedefs
1835 -Wunused-member-function
1836 -Wunused-sanitize-argument
1837 -Wunused-volatile-lvalue
1838 -Wuser-defined-literals
1839 -Wvariadic-macros
1840 -Wvector-conversion
1841 -Wvector-conversions
1842 -Wvexing-parse
1843 -Wvisibility
1844 -Wvla-extension
1845 -Wzero-length-array
1846 ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
1848 dnl These seem to require annotations that we don't currently use,
1849 dnl and they give false positives in our pthreads wrappers. (Clang 4)
1850 dnl -Wthread-safety
1851 dnl -Wthread-safety-analysis
1852 dnl -Wthread-safety-attributes
1853 dnl -Wthread-safety-beta
1854 dnl -Wthread-safety-precise
1856 CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1857 CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1858 CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1859 CFLAGS="$CFLAGS -Wwrite-strings"
1860 CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1861 CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
1862 CFLAGS="$CFLAGS -Wunused-parameter "
1863 # These interfere with building main() { return 0; }, which autoconf
1864 # likes to use as its default program.
1865 CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
1867 if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
1868 AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
1869 fi
1870 if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
1871 AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
1872 fi
1874 if test "x$enable_fatal_warnings" = "xyes"; then
1875 # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
1876 # default autoconf programs are full of errors.
1877 CFLAGS="$CFLAGS -Werror"
1878 fi
1880 fi
1882 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
1883 case "$host_os" in
1884 darwin*)
1885 AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
1886 esac
1887 fi
1889 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1891 AC_CONFIG_FILES([
1892 Doxyfile
1893 Makefile
1894 contrib/dist/suse/tor.sh
1895 contrib/operator-tools/tor.logrotate
1896 contrib/dist/tor.sh
1897 contrib/dist/torctl
1898 contrib/dist/tor.service
1899 src/config/torrc.sample
1900 src/config/torrc.minimal
1901 scripts/maint/checkOptionDocs.pl
1902 scripts/maint/updateVersions.pl
1903 ])
1905 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
1906 regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
1907 for file in $regular_mans ; do
1908 if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
1909 echo "==================================";
1910 echo;
1911 echo "Building Tor has failed since manpages cannot be built.";
1912 echo;
1913 echo "You need asciidoc installed to be able to build the manpages.";
1914 echo "To build without manpages, use the --disable-asciidoc argument";
1915 echo "when calling configure.";
1916 echo;
1917 echo "==================================";
1918 exit 1;
1919 fi
1920 done
1921 fi
1923 AC_OUTPUT