configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2007, Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.0.12-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  17 # the += operator on it in src/or/Makefile.am
  18 CPPFLAGS="$CPPFLAGS -I../common"
  19
  20 AC_ARG_ENABLE(debug,
  21  AS_HELP_STRING(--enable-debug, compile with debugging info),
  22 [if test x$enableval = xyes; then
  23     CFLAGS="$CFLAGS -g"
  24 fi])
  25
  26 AC_ARG_ENABLE(cell-pool,
  27      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  28
  29 if test x$enable_cell_pool != xno; then
  30   AC_DEFINE(ENABLE_CELL_POOL, 1,
  31             [Defined if we try to use the pool allocator for queued cells])
  32 fi
  33
  34 AC_ARG_ENABLE(transparent,
  35      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  36      [case "${enableval}" in
  37         yes) transparent=true ;;
  38         no)  transparent=false ;;
  39         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  40       esac], [transparent=true])
  41
  42 AC_ARG_ENABLE(threads,
  43      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  44
  45 if test x$enable_threads = x; then
  46    case $host in
  47     *-*-solaris* )
  48      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  49      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  50 cpu workers lock up here, so I will disable threads.])
  51      enable_threads="no";;
  52     *)
  53      enable_threads="yes";;
  54    esac
  55 fi
  56
  57 if test $enable_threads = "yes"; then
  58   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  59 fi
  60
  61 case $host in
  62    *-*-solaris* )
  63      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  64      ;;
  65 esac
  66
  67 AC_ARG_ENABLE(gcc-warnings,
  68      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  69
  70 AC_PROG_CC
  71 AC_PROG_MAKE_SET
  72 AC_PROG_RANLIB
  73
  74 TORUSER=_tor
  75 AC_ARG_WITH(tor-user,
  76         [  --with-tor-user=NAME    Specify username for tor daemon ],
  77         [
  78            TORUSER=$withval
  79         ]
  80 )
  81 AC_SUBST(TORUSER)
  82
  83 TORGROUP=_tor
  84 AC_ARG_WITH(tor-group,
  85         [  --with-tor-group=NAME   Specify group name for tor daemon ],
  86         [
  87            TORGROUP=$withval
  88         ]
  89 )
  90 AC_SUBST(TORGROUP)
  91
  92
  93 dnl If WIN32 is defined and non-zero, we are building for win32
  94 AC_MSG_CHECKING([for win32])
  95 AC_RUN_IFELSE([
  96 int main(int c, char **v) {
  97 #ifdef WIN32
  98 #if WIN32
  99   return 0;
 100 #else
 101   return 1;
 102 #endif
 103 #else
 104   return 2;
 105 #endif
 106 }],
 107 bwin32=true; AC_MSG_RESULT([yes]),
 108 bwin32=false; AC_MSG_RESULT([no]),
 109 bwin32=cross; AC_MSG_RESULT([cross])
 110 )
 111
 112 if test $bwin32 = cross; then
 113 AC_MSG_CHECKING([for win32 (cross)])
 114 AC_COMPILE_IFELSE([
 115 #ifdef WIN32
 116 int main(int c, char **v) {return 0;}
 117 #else
 118 #error
 119 int main(int c, char **v) {return x(y);}
 120 #endif
 121 ],
 122 bwin32=true; AC_MSG_RESULT([yes]),
 123 bwin32=false; AC_MSG_RESULT([no]))
 124 fi
 125
 126 if test $bwin32 = true; then
 127 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 128 fi
 129 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 130
 131 dnl Enable C99 when compiling with MIPSpro
 132 AC_MSG_CHECKING([for MIPSpro compiler])
 133 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 134 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 135 #error
 136   return x(y);
 137 #endif
 138 ]),
 139 bmipspro=false; AC_MSG_RESULT(no),
 140 bmipspro=true; AC_MSG_RESULT(yes))
 141
 142 if test $bmipspro = true; then
 143   CFLAGS="$CFLAGS -c99"
 144 fi
 145
 146 AC_C_BIGENDIAN
 147
 148 AC_SEARCH_LIBS(socket, [socket])
 149 AC_SEARCH_LIBS(gethostbyname, [nsl])
 150 AC_SEARCH_LIBS(dlopen, [dl])
 151 AC_SEARCH_LIBS(inet_aton, [resolv])
 152
 153 if test $enable_threads = "yes"; then
 154   AC_SEARCH_LIBS(pthread_create, [pthread])
 155   AC_SEARCH_LIBS(pthread_detach, [pthread])
 156 fi
 157
 158 dnl -------------------------------------------------------------------
 159 dnl Check for functions before libevent, since libevent-1.2 apparently
 160 dnl exports strlcpy without defining it in a header.
 161
 162 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop mallinfo)
 163
 164 if test $enable_threads = "yes"; then
 165   AC_CHECK_HEADERS(pthread.h)
 166   AC_CHECK_FUNCS(pthread_create)
 167 fi
 168
 169 dnl ------------------------------------------------------
 170 dnl Where do you live, libevent?  And how do we call you?
 171
 172 if test $bwin32 = true; then
 173   TOR_LIB_WS32=-lws2_32
 174   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 175   # think it's actually necessary.
 176   TOR_LIB_GDI=-lgdi32
 177 else
 178   TOR_LIB_WS32=
 179   TOR_LIB_GDI=
 180 fi
 181 AC_SUBST(TOR_LIB_WS32)
 182 AC_SUBST(TOR_LIB_GDI)
 183
 184 dnl This is a disgusting hack so we safely include recent libevent headers.
 185 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 186 AC_CHECK_TYPE(u_int32_t, unsigned long)
 187 AC_CHECK_TYPE(u_int16_t, unsigned short)
 188 AC_CHECK_TYPE(u_int8_t, unsigned char)
 189
 190 tor_libevent_pkg_redhat="libevent"
 191 tor_libevent_pkg_debian="libevent-dev"
 192 tor_libevent_devpkg_redhat="libevent-devel"
 193 tor_libevent_devpkg_debian="libevent-dev"
 194
 195 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 196 #include <stdlib.h>
 197 #include <sys/time.h>
 198 #include <sys/types.h>
 199 #include <event.h>], [void exit(int); void *event_init(void);],
 200     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 201
 202 dnl Now check for particular libevent functions.
 203 save_LIBS="$LIBS"
 204 save_LDFLAGS="$LDFLAGS"
 205 save_CPPFLAGS="$CPPFLAGS"
 206 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 207 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 208 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 209 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 210 LIBS="$save_LIBS"
 211 LDFLAGS="$save_LDFLAGS"
 212 CPPFLAGS="$save_CPPFLAGS"
 213
 214 dnl ------------------------------------------------------
 215 dnl Where do you live, openssl?  And how do we call you?
 216
 217 tor_openssl_pkg_redhat="openssl"
 218 tor_openssl_pkg_debian="libssl"
 219 tor_openssl_devpkg_redhat="openssl-devel"
 220 tor_openssl_devpkg_debian="libssl-dev"
 221
 222 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 223     [#include <openssl/rand.h>],
 224     [void RAND_add(const void *buf, int num, double entropy);],
 225     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 226     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 227
 228 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 229
 230 dnl ------------------------------------------------------
 231 dnl Where do you live, zlib?  And how do we call you?
 232
 233 tor_openssl_pkg_redhat="zlib"
 234 tor_openssl_pkg_debian="zlib1g"
 235 tor_openssl_devpkg_redhat="zlib-devel"
 236 tor_openssl_devpkg_debian="zlib1g-dev"
 237
 238 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 239     [#include <zlib.h>],
 240     [const char * zlibVersion(void);],
 241     [zlibVersion(); exit(0);], [--with-zlib-dir],
 242     [/opt/zlib])
 243
 244 dnl Make sure to enable support for large off_t if avalable.
 245
 246 AC_SYS_LARGEFILE
 247
 248 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 249
 250 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 251
 252 dnl These headers are not essential
 253
 254 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h)
 255
 256 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 257 [#ifdef HAVE_SYS_TYPES_H
 258 #include <sys/types.h>
 259 #endif
 260 #ifdef HAVE_SYS_SOCKET_H
 261 #include <sys/socket.h>
 262 #endif])
 263 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 264 [#ifdef HAVE_SYS_TYPES_H
 265 #include <sys/types.h>
 266 #endif
 267 #ifdef HAVE_SYS_SOCKET_H
 268 #include <sys/socket.h>
 269 #endif
 270 #ifdef HAVE_NET_IF_H
 271 #include <net/if.h>
 272 #endif])
 273 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 274         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 275 [#ifdef HAVE_SYS_TYPES_H
 276 #include <sys/types.h>
 277 #endif
 278 #ifdef HAVE_SYS_SOCKET_H
 279 #include <sys/socket.h>
 280 #endif])
 281
 282 if test x$transparent = xtrue ; then
 283    transparent_ok=0
 284    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 285      transparent_ok=1
 286    fi
 287    if test x$linux_netfilter_ipv4 = x1 ; then
 288      transparent_ok=1
 289    fi
 290    if test x$transparent_ok = x1 ; then
 291      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 292      case $host in
 293        *-*-openbsd*)
 294          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 295      esac
 296    else
 297      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 298    fi
 299 fi
 300
 301 AC_FUNC_FSEEKO
 302
 303 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 304 [#ifdef HAVE_SYS_TYPES_H
 305 #include <sys/types.h>
 306 #endif
 307 #ifdef HAVE_SYS_TIME_H
 308 #include <sys/time.h>
 309 #endif])
 310
 311 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 312 dnl Watch out.
 313
 314 AC_CHECK_SIZEOF(int8_t)
 315 AC_CHECK_SIZEOF(int16_t)
 316 AC_CHECK_SIZEOF(int32_t)
 317 AC_CHECK_SIZEOF(int64_t)
 318 AC_CHECK_SIZEOF(uint8_t)
 319 AC_CHECK_SIZEOF(uint16_t)
 320 AC_CHECK_SIZEOF(uint32_t)
 321 AC_CHECK_SIZEOF(uint64_t)
 322 AC_CHECK_SIZEOF(intptr_t)
 323 AC_CHECK_SIZEOF(uintptr_t)
 324
 325 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 326
 327 AC_CHECK_SIZEOF(char)
 328 AC_CHECK_SIZEOF(short)
 329 AC_CHECK_SIZEOF(int)
 330 AC_CHECK_SIZEOF(long)
 331 AC_CHECK_SIZEOF(long long)
 332 AC_CHECK_SIZEOF(__int64)
 333 AC_CHECK_SIZEOF(void *)
 334 AC_CHECK_SIZEOF(time_t)
 335 AC_CHECK_SIZEOF(size_t)
 336
 337 AC_CHECK_TYPES([uint, u_char])
 338
 339 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 340 [#ifdef HAVE_SYS_TYPES_H
 341 #include <sys/types.h>
 342 #endif
 343 #ifdef HAVE_NETINET_IN_H
 344 #include <netinet/in.h>
 345 #endif
 346 #ifdef HAVE_NETINET_IN6_H
 347 #include <netinet/in6.h>
 348 #endif
 349 #ifdef HAVE_SYS_SOCKET_H
 350 #include <sys/socket.h>
 351 #endif
 352 #ifdef MS_WINDOWS
 353 #define WIN32_WINNT 0x400
 354 #define _WIN32_WINNT 0x400
 355 #define WIN32_LEAN_AND_MEAN
 356 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 357 #include <winsock.h>
 358 #else
 359 #include <winsock2.h>
 360 #include <ws2tcpip.h>
 361 #endif
 362 #endif
 363 ])
 364 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 365 [#ifdef HAVE_SYS_TYPES_H
 366 #include <sys/types.h>
 367 #endif
 368 #ifdef HAVE_NETINET_IN_H
 369 #include <netinet/in.h>
 370 #endif
 371 #ifdef HAVE_NETINET_IN6_H
 372 #include <netinet/in6.h>
 373 #endif
 374 #ifdef HAVE_SYS_SOCKET_H
 375 #include <sys/socket.h>
 376 #endif
 377 #ifdef MS_WINDOWS
 378 #define WIN32_WINNT 0x400
 379 #define _WIN32_WINNT 0x400
 380 #define WIN32_LEAN_AND_MEAN
 381 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 382 #include <winsock.h>
 383 #else
 384 #include <winsock2.h>
 385 #include <ws2tcpip.h>
 386 #endif
 387 #endif
 388 ])
 389
 390 AC_CHECK_TYPES([rlim_t], , ,
 391 [#ifdef HAVE_SYS_TYPES_H
 392 #include <sys/types.h>
 393 #endif
 394 #ifdef HAVE_SYS_RESOURCE_H
 395 #include <sys/resource.h>
 396 #endif
 397 ])
 398
 399 if test -z "$CROSS_COMPILE"; then
 400 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 401 AC_RUN_IFELSE(AC_LANG_SOURCE([
 402 #ifdef HAVE_SYS_TYPES_H
 403 #include <sys/types.h>
 404 #endif
 405 #ifdef HAVE_SYS_TIME_H
 406 #include <sys/time.h>
 407 #endif
 408 #ifdef HAVE_TIME_H
 409 #include <time.h>
 410 #endif
 411 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 412   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes)
 413 ])
 414 else
 415   # Cross-compiling; let's hope the target platform isn't loony.
 416   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 417   tor_cv_time_t_signed=yes
 418 fi
 419
 420 if test $tor_cv_time_t_signed = yes; then
 421   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 422             [Define to 1 iff time_t is signed])
 423 fi
 424
 425 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 426 #ifdef HAVE_SYS_SOCKET_H
 427 #include <sys/socket.h>
 428 #endif
 429 ])
 430
 431 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 432
 433 AC_CHECK_SIZEOF(cell_t)
 434
 435 # Now make sure that NULL can be represented as zero bytes.
 436 if test -z "$CROSS_COMPILE"; then
 437 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 438 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 439 [[#include <stdlib.h>
 440 #include <string.h>
 441 #include <stdio.h>
 442 #ifdef HAVE_STDDEF_H
 443 #include <stddef.h>
 444 #endif
 445 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 446 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 447        [tor_cv_null_is_zero=yes],
 448        [tor_cv_null_is_zero=no],
 449        [tor_cv_null_is_zero=cross])])
 450
 451 else
 452   # Cross-compiling; let's hope that the target isn't raving mad.
 453   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 454   tor_cv_null_is_zero=yes
 455 fi
 456
 457 if test $tor_cv_null_is_zero = yes; then
 458   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 459             [Define to 1 iff memset(0) sets pointers to NULL])
 460 fi
 461
 462 # And what happens when we malloc zero?
 463
 464 if test -z "$CROSS_COMPILE"; then
 465 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 466 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 467 [[#include <stdlib.h>
 468 #include <string.h>
 469 #include <stdio.h>
 470 #ifdef HAVE_STDDEF_H
 471 #include <stddef.h>
 472 #endif
 473 int main () { return malloc(0)?0:1; }]])],
 474        [tor_cv_malloc_zero_works=yes],
 475        [tor_cv_malloc_zero_works=no],
 476        [tor_cv_malloc_zero_works=cross])])
 477
 478 else
 479   # Cross-compiling; let's hope that the target isn't raving mad.
 480   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 481   tor_cv_malloc_zero_works=no
 482 fi
 483
 484 if test $tor_cv_malloc_zero_works = yes; then
 485   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 486             [Define to 1 iff malloc(0) returns a pointer])
 487 fi
 488
 489 # whether we seem to be in a 2s-complement world.
 490 if test -z "$CROSS_COMPILE"; then
 491 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 492 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 493 [[int main () { int problem = ((-99) != (~99)+1);
 494 return problem ? 1 : 0; }]])],
 495        [tor_cv_twos_complement=yes],
 496        [tor_cv_twos_complement=no],
 497        [tor_cv_twos_complement=cross])])
 498
 499 else
 500   # Cross-compiling; let's hope that the target isn't raving mad.
 501   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 502   tor_cv_twos_complement=yes
 503 fi
 504
 505 if test $tor_cv_twos_complement = yes; then
 506   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 507             [Define to 1 iff we represent negative integers with two's complement])
 508 fi
 509
 510 # Whether we should use the dmalloc memory allocation debugging library.
 511 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 512 AC_ARG_WITH(dmalloc,
 513 [  --with-dmalloc          Use debug memory allocation library. ],
 514 [if [[ "$withval" = "yes" ]]; then
 515   dmalloc=1
 516   AC_MSG_RESULT(yes)
 517 else
 518   dmalloc=1
 519   AC_MSG_RESULT(no)
 520 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 521 )
 522
 523 if [[ $dmalloc -eq 1 ]]; then
 524   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 525   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 526   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 527   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 528   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 529 fi
 530
 531 # Allow user to specify an alternate syslog facility
 532 AC_ARG_WITH(syslog-facility,
 533 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 534 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 535 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 536 AC_SUBST(LOGFACILITY)
 537
 538 # Check for gethostbyname_r in all its glorious incompatible versions.
 539 #   (This logic is based on that in Python's configure.in)
 540 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 541   [Define this if you have any gethostbyname_r()])
 542
 543 AC_CHECK_FUNC(gethostbyname_r, [
 544   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 545   OLD_CFLAGS=$CFLAGS
 546   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 547   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 548 #include <netdb.h>
 549   ], [[
 550     char *cp1, *cp2;
 551     struct hostent *h1, *h2;
 552     int i1, i2;
 553     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 554   ]]),[
 555     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 556     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 557      [Define this if gethostbyname_r takes 6 arguments])
 558     AC_MSG_RESULT(6)
 559   ], [
 560     AC_TRY_COMPILE([
 561 #include <netdb.h>
 562     ], [
 563       char *cp1, *cp2;
 564       struct hostent *h1;
 565       int i1, i2;
 566       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 567     ], [
 568       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 569       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 570         [Define this if gethostbyname_r takes 5 arguments])
 571       AC_MSG_RESULT(5)
 572    ], [
 573       AC_TRY_COMPILE([
 574 #include <netdb.h>
 575      ], [
 576        char *cp1;
 577        struct hostent *h1;
 578        struct hostent_data hd;
 579        (void) gethostbyname_r(cp1,h1,&hd);
 580      ], [
 581        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 582        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 583          [Define this if gethostbyname_r takes 3 arguments])
 584        AC_MSG_RESULT(3)
 585      ], [
 586        AC_MSG_RESULT(0)
 587      ])
 588   ])
 589  ])
 590  CFLAGS=$OLD_CFLAGS
 591 ])
 592
 593 AC_CACHE_CHECK([whether the C compiler supports __func__],
 594   tor_cv_have_func_macro,
 595   AC_COMPILE_IFELSE([
 596 #include <stdio.h>
 597 int main(int c, char **v) { puts(__func__); }],
 598   tor_cv_have_func_macro=yes,
 599   tor_cv_have_func_macro=no))
 600
 601 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 602   tor_cv_have_FUNC_macro,
 603   AC_COMPILE_IFELSE([
 604 #include <stdio.h>
 605 int main(int c, char **v) { puts(__FUNC__); }],
 606   tor_cv_have_FUNC_macro=yes,
 607   tor_cv_have_FUNC_macro=no))
 608
 609 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 610   tor_cv_have_FUNCTION_macro,
 611   AC_COMPILE_IFELSE([
 612 #include <stdio.h>
 613 int main(int c, char **v) { puts(__FUNCTION__); }],
 614   tor_cv_have_FUNCTION_macro=yes,
 615   tor_cv_have_FUNCTION_macro=no))
 616
 617 if test $tor_cv_have_func_macro = 'yes'; then
 618   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 619 fi
 620
 621 if test $tor_cv_have_FUNC_macro = 'yes'; then
 622   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 623 fi
 624
 625 if test $tor_cv_have_FUNCTION_macro = 'yes'; then
 626   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 627            [Defined if the compiler supports __FUNCTION__])
 628 fi
 629
 630 # $prefix stores the value of the --prefix command line option, or
 631 # NONE if the option wasn't set.  In the case that it wasn't set, make
 632 # it be the default, so that we can use it to expand directories now.
 633 if test "x$prefix" = "xNONE"; then
 634   prefix=$ac_default_prefix
 635 fi
 636
 637 # and similarly for $exec_prefix
 638 if test "x$exec_prefix" = "xNONE"; then
 639   exec_prefix=$prefix
 640 fi
 641
 642 if test "x$CONFDIR" = "x"; then
 643   CONFDIR=`eval echo $sysconfdir/tor`
 644 fi
 645 AC_SUBST(CONFDIR)
 646 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 647 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 648
 649 BINDIR=`eval echo $bindir`
 650 AC_SUBST(BINDIR)
 651 LOCALSTATEDIR=`eval echo $localstatedir`
 652 AC_SUBST(LOCALSTATEDIR)
 653
 654 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 655 # than autoconf's macros like.
 656 if test $ac_cv_c_compiler_gnu = yes; then
 657   CFLAGS="$CFLAGS -Wall -g -O2"
 658 else
 659   CFLAGS="$CFLAGS -g -O"
 660   enable_gcc_warnings=no
 661 fi
 662
 663 # Add some more warnings which we use in development but not in the
 664 # released versions.  (Some relevant gcc versions can't handle these.)
 665 if test x$enable_gcc_warnings = xyes; then
 666
 667   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 668 #if !defined(__GNUC__) || (__GNUC__ < 4)
 669 #error
 670 #endif]), have_gcc4=yes, have_gcc4=no)
 671
 672   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 673 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 674 #error
 675 #endif]), have_gcc42=yes, have_gcc42=no)
 676
 677   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 678   # Disabled, so we can use mallinfo(): -Waggregate-return
 679
 680   if test x$have_gcc4 = xyes ; then
 681     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 682     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 683   fi
 684
 685   if test x$have_gcc42 = xyes ; then
 686     # These warnings break gcc 4.0.2 and work on gcc 4.2
 687     # XXXX020 Use -fstack-protector.
 688     # XXXX020 See if any of these work with earlier versions.
 689     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 690   fi
 691
 692 ##This will break the world on some 64-bit architectures
 693 # CFLAGS="$CFLAGS -Winline"
 694
 695 fi
 696
 697 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 698
 699 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 700 AC_OUTPUT
 701
 702 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 703   ./contrib/updateVersions.pl
 704 fi
 705