configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.19-alpha)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  23 AC_ARG_ENABLE(buf-freelists,
  24    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  25 AC_ARG_ENABLE(openbsd-malloc,
  26    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  27 AC_ARG_ENABLE(instrument-downloads,
  28    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  29 AC_ARG_ENABLE(static-openssl,
  30    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  31 AC_ARG_ENABLE(static-libevent,
  32    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  33 AC_ARG_ENABLE(static-zlib,
  34    AS_HELP_STRING(--enable-static-zlib, Link against a static zlib library. Requires --with-zlib-dir))
  35
  36 if test x$enable_buf_freelists != xno; then
  37   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  38             [Defined if we try to use freelists for buffer RAM chunks])
  39 fi
  40 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  41 if test x$enable_instrument_downloads = xyes; then
  42   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  43             [Defined if we want to keep track of how much of each kind of resource we download.])
  44 fi
  45
  46 AC_ARG_ENABLE(transparent,
  47      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  48      [case "${enableval}" in
  49         yes) transparent=true ;;
  50         no)  transparent=false ;;
  51         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  52       esac], [transparent=true])
  53
  54 AC_ARG_ENABLE(asciidoc,
  55      AS_HELP_STRING(--disable-asciidoc, don't use asciidoc (disables building of manpages)),
  56      [case "${enableval}" in
  57         yes) asciidoc=true ;;
  58         no)  asciidoc=false ;;
  59         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  60       esac], [asciidoc=true])
  61
  62
  63 AC_ARG_ENABLE(threads,
  64      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  65
  66 if test x$enable_threads = x; then
  67    case $host in
  68     *-*-solaris* )
  69      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  70      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  71 cpu workers lock up here, so I will disable threads.])
  72      enable_threads="no";;
  73     *)
  74      enable_threads="yes";;
  75    esac
  76 fi
  77
  78 if test "$enable_threads" = "yes"; then
  79   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  80 fi
  81
  82 case $host in
  83    *-*-solaris* )
  84      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  85      ;;
  86 esac
  87
  88 AC_ARG_ENABLE(gcc-warnings,
  89      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  90 AC_ARG_ENABLE(gcc-warnings-advisory,
  91      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
  92
  93 dnl Adam shostack suggests the following for Windows:
  94 dnl -D_FORTIFY_SOURCE=2 -fstack-protector-all
  95 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
  96 dnl This requires that we use gcc and that we add -O2 to the CFLAGS.
  97 AC_ARG_ENABLE(gcc-hardening,
  98      AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
  99 [if test x$enableval = xyes; then
 100     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 101     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 102     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 103     LDFLAGS="$LDFLAGS -pie"
 104 fi])
 105
 106 dnl Linker hardening options
 107 dnl Currently these options are ELF specific - you can't use this with MacOSX
 108 AC_ARG_ENABLE(linker-hardening,
 109         AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 110 [if test x$enableval = xyes; then
 111     LDFLAGS="$LDFLAGS -z relro -z now"
 112 fi])
 113
 114 AC_ARG_ENABLE(local-appdata,
 115    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 116 if test "$enable_local_appdata" = "yes"; then
 117   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 118             [Defined if we default to host local appdata paths on Windows])
 119 fi
 120
 121 AC_PROG_CC
 122 AC_PROG_CPP
 123 AC_PROG_MAKE_SET
 124 AC_PROG_RANLIB
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 128
 129 dnl check for asciidoc and a2x
 130 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 131 AC_PATH_PROG([A2X], [a2x], none)
 132
 133 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 134
 135 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 136 AC_PATH_PROG([OPENSSL], [openssl], none)
 137
 138 TORUSER=_tor
 139 AC_ARG_WITH(tor-user,
 140         [  --with-tor-user=NAME    Specify username for tor daemon ],
 141         [
 142            TORUSER=$withval
 143         ]
 144 )
 145 AC_SUBST(TORUSER)
 146
 147 TORGROUP=_tor
 148 AC_ARG_WITH(tor-group,
 149         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 150         [
 151            TORGROUP=$withval
 152         ]
 153 )
 154 AC_SUBST(TORGROUP)
 155
 156
 157 dnl If WIN32 is defined and non-zero, we are building for win32
 158 AC_MSG_CHECKING([for win32])
 159 AC_RUN_IFELSE([AC_LANG_SOURCE([
 160 int main(int c, char **v) {
 161 #ifdef WIN32
 162 #if WIN32
 163   return 0;
 164 #else
 165   return 1;
 166 #endif
 167 #else
 168   return 2;
 169 #endif
 170 }])],
 171 bwin32=true; AC_MSG_RESULT([yes]),
 172 bwin32=false; AC_MSG_RESULT([no]),
 173 bwin32=cross; AC_MSG_RESULT([cross])
 174 )
 175
 176 if test "$bwin32" = cross; then
 177 AC_MSG_CHECKING([for win32 (cross)])
 178 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 179 #ifdef WIN32
 180 int main(int c, char **v) {return 0;}
 181 #else
 182 #error
 183 int main(int c, char **v) {return x(y);}
 184 #endif
 185 ])],
 186 bwin32=true; AC_MSG_RESULT([yes]),
 187 bwin32=false; AC_MSG_RESULT([no]))
 188 fi
 189
 190 if test "$bwin32" = true; then
 191 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 192 fi
 193 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 194
 195 dnl Enable C99 when compiling with MIPSpro
 196 AC_MSG_CHECKING([for MIPSpro compiler])
 197 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 198 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 199 #error
 200   return x(y);
 201 #endif
 202 ])],
 203 bmipspro=false; AC_MSG_RESULT(no),
 204 bmipspro=true; AC_MSG_RESULT(yes))
 205
 206 if test "$bmipspro" = true; then
 207   CFLAGS="$CFLAGS -c99"
 208 fi
 209
 210 AC_C_BIGENDIAN
 211
 212 AC_SEARCH_LIBS(socket, [socket])
 213 AC_SEARCH_LIBS(gethostbyname, [nsl])
 214 AC_SEARCH_LIBS(dlopen, [dl])
 215 AC_SEARCH_LIBS(inet_aton, [resolv])
 216
 217 if test "$enable_threads" = "yes"; then
 218   AC_SEARCH_LIBS(pthread_create, [pthread])
 219   AC_SEARCH_LIBS(pthread_detach, [pthread])
 220 fi
 221
 222 dnl -------------------------------------------------------------------
 223 dnl Check for functions before libevent, since libevent-1.2 apparently
 224 dnl exports strlcpy without defining it in a header.
 225
 226 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl vasprintf)
 227
 228 using_custom_malloc=no
 229 if test x$enable_openbsd_malloc = xyes ; then
 230    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 231    using_custom_malloc=yes
 232 fi
 233 if test x$tcmalloc = xyes ; then
 234    using_custom_malloc=yes
 235 fi
 236 if test $using_custom_malloc = no ; then
 237    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 238 fi
 239
 240 if test "$enable_threads" = "yes"; then
 241   AC_CHECK_HEADERS(pthread.h)
 242   AC_CHECK_FUNCS(pthread_create)
 243 fi
 244
 245 dnl ------------------------------------------------------
 246 dnl Where do you live, libevent?  And how do we call you?
 247
 248 if test "$bwin32" = true; then
 249   TOR_LIB_WS32=-lws2_32
 250   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 251   # think it's actually necessary.
 252   TOR_LIB_GDI=-lgdi32
 253 else
 254   TOR_LIB_WS32=
 255   TOR_LIB_GDI=
 256 fi
 257 AC_SUBST(TOR_LIB_WS32)
 258 AC_SUBST(TOR_LIB_GDI)
 259
 260 dnl We need to do this before we try our disgusting hack below.
 261 AC_CHECK_HEADERS([sys/types.h])
 262
 263 dnl This is a disgusting hack so we safely include older libevent headers.
 264 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 265 AC_CHECK_TYPE(u_int32_t, unsigned long)
 266 AC_CHECK_TYPE(u_int16_t, unsigned short)
 267 AC_CHECK_TYPE(u_int8_t, unsigned char)
 268
 269 tor_libevent_pkg_redhat="libevent"
 270 tor_libevent_pkg_debian="libevent-dev"
 271 tor_libevent_devpkg_redhat="libevent-devel"
 272 tor_libevent_devpkg_debian="libevent-dev"
 273
 274 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 275 dnl linking for static builds.
 276 STATIC_LIBEVENT_FLAGS=""
 277 if test "$enable_static_libevent" = "yes"; then
 278     dnl Determine if we have clock_gettime in librt
 279     AC_SEARCH_LIBS([clock_gettime], [rt],
 280         [have_rt=yes])
 281     if test "$have_rt" = yes; then
 282       STATIC_LIBEVENT_FLAGS=" -lrt "
 283     fi
 284 fi
 285
 286 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 287 #ifdef WIN32
 288 #include <winsock2.h>
 289 #endif
 290 #include <stdlib.h>
 291 #include <sys/time.h>
 292 #include <sys/types.h>
 293 #include <event.h>], [
 294 #ifdef WIN32
 295 #include <winsock2.h>
 296 #endif
 297 void exit(int); void *event_init(void);],
 298     [
 299 #ifdef WIN32
 300 {WSADATA d; WSAStartup(0x101,&d); }
 301 #endif
 302 event_init(); exit(0);
 303 ], [--with-libevent-dir], [/opt/libevent])
 304
 305 dnl Now check for particular libevent functions.
 306 save_LIBS="$LIBS"
 307 save_LDFLAGS="$LDFLAGS"
 308 save_CPPFLAGS="$CPPFLAGS"
 309 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
 310 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 311 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 312 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 313 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 314 [#include <event.h>
 315 ])
 316
 317 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 318
 319 LIBS="$save_LIBS"
 320 LDFLAGS="$save_LDFLAGS"
 321 CPPFLAGS="$save_CPPFLAGS"
 322
 323
 324 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 325
 326 if test "$enable_static_libevent" = "yes"; then
 327    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 328      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 329    else
 330      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 331    fi
 332 else
 333      TOR_LIBEVENT_LIBS="-levent"
 334 fi
 335 AC_SUBST(TOR_LIBEVENT_LIBS)
 336
 337
 338 dnl ------------------------------------------------------
 339 dnl Where do you live, openssl?  And how do we call you?
 340
 341 tor_openssl_pkg_redhat="openssl"
 342 tor_openssl_pkg_debian="libssl"
 343 tor_openssl_devpkg_redhat="openssl-devel"
 344 tor_openssl_devpkg_debian="libssl-dev"
 345
 346 ALT_openssl_WITHVAL=""
 347 AC_ARG_WITH(ssl-dir,
 348   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 349   [
 350       if test "x$withval" != xno && test "x$withval" != "x" ; then
 351          ALT_openssl_WITHVAL="$withval"
 352       fi
 353   ])
 354
 355 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 356     [#include <openssl/rand.h>],
 357     [void RAND_add(const void *buf, int num, double entropy);],
 358     [RAND_add((void*)0,0,0); exit(0);], [],
 359     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 360
 361 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 362
 363 echo "tor_cv_library_openssl_dir is $tor_cv_library_openssl_dir"
 364 if test "$enable_static_openssl" = "yes"; then
 365    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 366      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 367    else
 368      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 369    fi
 370 else
 371      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 372 fi
 373 AC_SUBST(TOR_OPENSSL_LIBS)
 374
 375 dnl ------------------------------------------------------
 376 dnl Where do you live, zlib?  And how do we call you?
 377
 378 tor_zlib_pkg_redhat="zlib"
 379 tor_zlib_pkg_debian="zlib1g"
 380 tor_zlib_devpkg_redhat="zlib-devel"
 381 tor_zlib_devpkg_debian="zlib1g-dev"
 382
 383 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 384     [#include <zlib.h>],
 385     [const char * zlibVersion(void);],
 386     [zlibVersion(); exit(0);], [--with-zlib-dir],
 387     [/opt/zlib])
 388
 389 if test "$enable_static_zlib" = "yes"; then
 390    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 391      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 392  using --enable-static-zlib")
 393    else
 394      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 395      echo "$TOR_LIBDIR_zlib/libz.a"
 396    fi
 397 else
 398      TOR_ZLIB_LIBS="-lz"
 399 fi
 400 AC_SUBST(TOR_ZLIB_LIBS)
 401
 402 dnl Make sure to enable support for large off_t if available.
 403
 404 AC_SYS_LARGEFILE
 405
 406 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 407
 408 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 409
 410 dnl These headers are not essential
 411
 412 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 413
 414 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 415 [#ifdef HAVE_MALLOC_H
 416 #include <malloc.h>
 417 #endif
 418 #ifdef HAVE_MALLOC_MALLOC_H
 419 #include <malloc/malloc.h>
 420 #endif])
 421
 422 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 423 [#ifdef HAVE_SYS_TYPES_H
 424 #include <sys/types.h>
 425 #endif
 426 #ifdef HAVE_SYS_SOCKET_H
 427 #include <sys/socket.h>
 428 #endif])
 429 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 430 [#ifdef HAVE_SYS_TYPES_H
 431 #include <sys/types.h>
 432 #endif
 433 #ifdef HAVE_SYS_SOCKET_H
 434 #include <sys/socket.h>
 435 #endif
 436 #ifdef HAVE_NET_IF_H
 437 #include <net/if.h>
 438 #endif])
 439 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 440         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 441 [#ifdef HAVE_SYS_TYPES_H
 442 #include <sys/types.h>
 443 #endif
 444 #ifdef HAVE_SYS_SOCKET_H
 445 #include <sys/socket.h>
 446 #endif
 447 #ifdef HAVE_LIMITS_H
 448 #include <limits.h>
 449 #endif
 450 #ifdef HAVE_LINUX_TYPES_H
 451 #include <linux/types.h>
 452 #endif
 453 #ifdef HAVE_NETINET_IN6_H
 454 #include <netinet/in6.h>
 455 #endif
 456 #ifdef HAVE_NETINET_IN_H
 457 #include <netinet/in.h>
 458 #endif])
 459
 460 if test x$transparent = xtrue ; then
 461    transparent_ok=0
 462    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 463      transparent_ok=1
 464    fi
 465    if test x$linux_netfilter_ipv4 = x1 ; then
 466      transparent_ok=1
 467    fi
 468    if test x$transparent_ok = x1 ; then
 469      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 470      case $host in
 471        *-*-openbsd*)
 472          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 473      esac
 474    else
 475      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 476    fi
 477 fi
 478
 479 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 480 [#ifdef HAVE_SYS_TYPES_H
 481 #include <sys/types.h>
 482 #endif
 483 #ifdef HAVE_SYS_TIME_H
 484 #include <sys/time.h>
 485 #endif])
 486
 487 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 488 dnl Watch out.
 489
 490 AC_CHECK_SIZEOF(int8_t)
 491 AC_CHECK_SIZEOF(int16_t)
 492 AC_CHECK_SIZEOF(int32_t)
 493 AC_CHECK_SIZEOF(int64_t)
 494 AC_CHECK_SIZEOF(uint8_t)
 495 AC_CHECK_SIZEOF(uint16_t)
 496 AC_CHECK_SIZEOF(uint32_t)
 497 AC_CHECK_SIZEOF(uint64_t)
 498 AC_CHECK_SIZEOF(intptr_t)
 499 AC_CHECK_SIZEOF(uintptr_t)
 500
 501 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 502
 503 AC_CHECK_SIZEOF(char)
 504 AC_CHECK_SIZEOF(short)
 505 AC_CHECK_SIZEOF(int)
 506 AC_CHECK_SIZEOF(long)
 507 AC_CHECK_SIZEOF(long long)
 508 AC_CHECK_SIZEOF(__int64)
 509 AC_CHECK_SIZEOF(void *)
 510 AC_CHECK_SIZEOF(time_t)
 511 AC_CHECK_SIZEOF(size_t)
 512
 513 AC_CHECK_TYPES([uint, u_char, ssize_t])
 514
 515 dnl used to include sockaddr_storage, but everybody has that.
 516 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 517 [#ifdef HAVE_SYS_TYPES_H
 518 #include <sys/types.h>
 519 #endif
 520 #ifdef HAVE_NETINET_IN_H
 521 #include <netinet/in.h>
 522 #endif
 523 #ifdef HAVE_NETINET_IN6_H
 524 #include <netinet/in6.h>
 525 #endif
 526 #ifdef HAVE_SYS_SOCKET_H
 527 #include <sys/socket.h>
 528 #endif
 529 #ifdef MS_WINDOWS
 530 #define WIN32_WINNT 0x400
 531 #define _WIN32_WINNT 0x400
 532 #define WIN32_LEAN_AND_MEAN
 533 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 534 #include <winsock.h>
 535 #else
 536 #include <winsock2.h>
 537 #include <ws2tcpip.h>
 538 #endif
 539 #endif
 540 ])
 541 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 542 [#ifdef HAVE_SYS_TYPES_H
 543 #include <sys/types.h>
 544 #endif
 545 #ifdef HAVE_NETINET_IN_H
 546 #include <netinet/in.h>
 547 #endif
 548 #ifdef HAVE_NETINET_IN6_H
 549 #include <netinet/in6.h>
 550 #endif
 551 #ifdef HAVE_SYS_SOCKET_H
 552 #include <sys/socket.h>
 553 #endif
 554 #ifdef MS_WINDOWS
 555 #define WIN32_WINNT 0x400
 556 #define _WIN32_WINNT 0x400
 557 #define WIN32_LEAN_AND_MEAN
 558 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 559 #include <winsock.h>
 560 #else
 561 #include <winsock2.h>
 562 #include <ws2tcpip.h>
 563 #endif
 564 #endif
 565 ])
 566
 567 AC_CHECK_TYPES([rlim_t], , ,
 568 [#ifdef HAVE_SYS_TYPES_H
 569 #include <sys/types.h>
 570 #endif
 571 #ifdef HAVE_SYS_TIME_H
 572 #include <sys/time.h>
 573 #endif
 574 #ifdef HAVE_SYS_RESOURCE_H
 575 #include <sys/resource.h>
 576 #endif
 577 ])
 578
 579 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 580 AC_RUN_IFELSE([AC_LANG_SOURCE([
 581 #ifdef HAVE_SYS_TYPES_H
 582 #include <sys/types.h>
 583 #endif
 584 #ifdef HAVE_SYS_TIME_H
 585 #include <sys/time.h>
 586 #endif
 587 #ifdef HAVE_TIME_H
 588 #include <time.h>
 589 #endif
 590 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }])],
 591   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 592 ])
 593
 594 if test "$tor_cv_time_t_signed" = cross; then
 595   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 596 fi
 597
 598 if test "$tor_cv_time_t_signed" != no; then
 599   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 600             [Define to 1 iff time_t is signed])
 601 fi
 602
 603 AC_CACHE_CHECK([whether size_t is signed], tor_cv_size_t_signed, [
 604 AC_RUN_IFELSE([AC_LANG_SOURCE([
 605 #ifdef HAVE_SYS_TYPES_H
 606 #include <sys/types.h>
 607 #endif
 608 int main(int c, char**v) { if (((size_t)-1)<0) return 1; else return 0; }])],
 609   tor_cv_size_t_signed=no, tor_cv_size_t_signed=yes, tor_cv_size_t_signed=cross)
 610 ])
 611
 612 if test "$tor_cv_size_t_signed" = cross; then
 613   AC_MSG_NOTICE([Cross compiling: assuming that size_t is not signed.])
 614 fi
 615
 616 if test "$tor_cv_size_t_signed" = yes; then
 617   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
 618 fi
 619
 620 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 621 #ifdef HAVE_SYS_SOCKET_H
 622 #include <sys/socket.h>
 623 #endif
 624 ])
 625
 626 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 627
 628 AC_CHECK_SIZEOF(cell_t)
 629
 630 # Now make sure that NULL can be represented as zero bytes.
 631 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 632 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 633 [[#include <stdlib.h>
 634 #include <string.h>
 635 #include <stdio.h>
 636 #ifdef HAVE_STDDEF_H
 637 #include <stddef.h>
 638 #endif
 639 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 640 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 641        [tor_cv_null_is_zero=yes],
 642        [tor_cv_null_is_zero=no],
 643        [tor_cv_null_is_zero=cross])])
 644
 645 if test "$tor_cv_null_is_zero" = cross ; then
 646   # Cross-compiling; let's hope that the target isn't raving mad.
 647   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 648 fi
 649
 650 if test "$tor_cv_null_is_zero" != no; then
 651   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 652             [Define to 1 iff memset(0) sets pointers to NULL])
 653 fi
 654
 655 # And what happens when we malloc zero?
 656 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 657 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 658 [[#include <stdlib.h>
 659 #include <string.h>
 660 #include <stdio.h>
 661 #ifdef HAVE_STDDEF_H
 662 #include <stddef.h>
 663 #endif
 664 int main () { return malloc(0)?0:1; }]])],
 665        [tor_cv_malloc_zero_works=yes],
 666        [tor_cv_malloc_zero_works=no],
 667        [tor_cv_malloc_zero_works=cross])])
 668
 669 if test "$tor_cv_malloc_zero_works" = cross; then
 670   # Cross-compiling; let's hope that the target isn't raving mad.
 671   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 672 fi
 673
 674 if test "$tor_cv_malloc_zero_works" = yes; then
 675   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 676             [Define to 1 iff malloc(0) returns a pointer])
 677 fi
 678
 679 # whether we seem to be in a 2s-complement world.
 680 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 681 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 682 [[int main () { int problem = ((-99) != (~99)+1);
 683 return problem ? 1 : 0; }]])],
 684        [tor_cv_twos_complement=yes],
 685        [tor_cv_twos_complement=no],
 686        [tor_cv_twos_complement=cross])])
 687
 688 if test "$tor_cv_twos_complement" = cross ; then
 689   # Cross-compiling; let's hope that the target isn't raving mad.
 690   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 691 fi
 692
 693 if test "$tor_cv_twos_complement" != no ; then
 694   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 695             [Define to 1 iff we represent negative integers with two's complement])
 696 fi
 697
 698 # What does shifting a negative value do?
 699 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
 700 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 701 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
 702        [tor_cv_sign_extend=yes],
 703        [tor_cv_sign_extend=no],
 704        [tor_cv_sign_extend=cross])])
 705
 706 if test "$tor_cv_sign_extend" = cross ; then
 707   # Cross-compiling; let's hope that the target isn't raving mad.
 708   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
 709 fi
 710
 711 if test "$tor_cv_sign_extend" != no ; then
 712   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
 713             [Define to 1 iff right-shifting a negative value performs sign-extension])
 714 fi
 715
 716 # Whether we should use the dmalloc memory allocation debugging library.
 717 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 718 AC_ARG_WITH(dmalloc,
 719 [  --with-dmalloc          Use debug memory allocation library. ],
 720 [if [[ "$withval" = "yes" ]]; then
 721   dmalloc=1
 722   AC_MSG_RESULT(yes)
 723 else
 724   dmalloc=1
 725   AC_MSG_RESULT(no)
 726 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 727 )
 728
 729 if [[ $dmalloc -eq 1 ]]; then
 730   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 731   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 732   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 733   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 734   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 735 fi
 736
 737 AC_ARG_WITH(tcmalloc,
 738 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 739 [ tcmalloc=yes ], [ tcmalloc=no ])
 740
 741 if test x$tcmalloc = xyes ; then
 742    LDFLAGS="-ltcmalloc $LDFLAGS"
 743 fi
 744
 745 # By default, we're going to assume we don't have mlockall()
 746 # bionic and other platforms have various broken mlockall subsystems.
 747 # Some systems don't have a working mlockall, some aren't linkable,
 748 # and some have it but don't declare it.
 749 AC_CHECK_FUNCS(mlockall)
 750 AC_CHECK_DECLS([mlockall], , , [
 751 #ifdef HAVE_SYS_MMAN_H
 752 #include <sys/mman.h>
 753 #endif])
 754
 755 # Allow user to specify an alternate syslog facility
 756 AC_ARG_WITH(syslog-facility,
 757 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 758 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 759 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 760 AC_SUBST(LOGFACILITY)
 761
 762 # Check if we have getresuid and getresgid
 763 AC_CHECK_FUNCS(getresuid getresgid)
 764
 765 # Check for gethostbyname_r in all its glorious incompatible versions.
 766 #   (This logic is based on that in Python's configure.in)
 767 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 768   [Define this if you have any gethostbyname_r()])
 769
 770 AC_CHECK_FUNC(gethostbyname_r, [
 771   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 772   OLD_CFLAGS=$CFLAGS
 773   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 774   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 775 #include <netdb.h>
 776   ], [[
 777     char *cp1, *cp2;
 778     struct hostent *h1, *h2;
 779     int i1, i2;
 780     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 781   ]])],[
 782     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 783     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 784      [Define this if gethostbyname_r takes 6 arguments])
 785     AC_MSG_RESULT(6)
 786   ], [
 787     AC_TRY_COMPILE([
 788 #include <netdb.h>
 789     ], [
 790       char *cp1, *cp2;
 791       struct hostent *h1;
 792       int i1, i2;
 793       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 794     ], [
 795       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 796       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 797         [Define this if gethostbyname_r takes 5 arguments])
 798       AC_MSG_RESULT(5)
 799    ], [
 800       AC_TRY_COMPILE([
 801 #include <netdb.h>
 802      ], [
 803        char *cp1;
 804        struct hostent *h1;
 805        struct hostent_data hd;
 806        (void) gethostbyname_r(cp1,h1,&hd);
 807      ], [
 808        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 809        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 810          [Define this if gethostbyname_r takes 3 arguments])
 811        AC_MSG_RESULT(3)
 812      ], [
 813        AC_MSG_RESULT(0)
 814      ])
 815   ])
 816  ])
 817  CFLAGS=$OLD_CFLAGS
 818 ])
 819
 820 AC_CACHE_CHECK([whether the C compiler supports __func__],
 821   tor_cv_have_func_macro,
 822   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 823 #include <stdio.h>
 824 int main(int c, char **v) { puts(__func__); }])],
 825   tor_cv_have_func_macro=yes,
 826   tor_cv_have_func_macro=no))
 827
 828 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 829   tor_cv_have_FUNC_macro,
 830   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 831 #include <stdio.h>
 832 int main(int c, char **v) { puts(__FUNC__); }])],
 833   tor_cv_have_FUNC_macro=yes,
 834   tor_cv_have_FUNC_macro=no))
 835
 836 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 837   tor_cv_have_FUNCTION_macro,
 838   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 839 #include <stdio.h>
 840 int main(int c, char **v) { puts(__FUNCTION__); }])],
 841   tor_cv_have_FUNCTION_macro=yes,
 842   tor_cv_have_FUNCTION_macro=no))
 843
 844 if test "$tor_cv_have_func_macro" = 'yes'; then
 845   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 846 fi
 847
 848 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 849   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 850 fi
 851
 852 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 853   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 854            [Defined if the compiler supports __FUNCTION__])
 855 fi
 856
 857 # $prefix stores the value of the --prefix command line option, or
 858 # NONE if the option wasn't set.  In the case that it wasn't set, make
 859 # it be the default, so that we can use it to expand directories now.
 860 if test "x$prefix" = "xNONE"; then
 861   prefix=$ac_default_prefix
 862 fi
 863
 864 # and similarly for $exec_prefix
 865 if test "x$exec_prefix" = "xNONE"; then
 866   exec_prefix=$prefix
 867 fi
 868
 869 if test "x$CONFDIR" = "x"; then
 870   CONFDIR=`eval echo $sysconfdir/tor`
 871 fi
 872 AC_SUBST(CONFDIR)
 873 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 874 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 875
 876 BINDIR=`eval echo $bindir`
 877 AC_SUBST(BINDIR)
 878 LOCALSTATEDIR=`eval echo $localstatedir`
 879 AC_SUBST(LOCALSTATEDIR)
 880
 881 if test "$bwin32" = true; then
 882   # Test if the linker supports the --nxcompat and --dynamicbase options
 883   # for Windows
 884   save_LDFLAGS="$LDFLAGS"
 885   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
 886   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
 887   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 888     [AC_MSG_RESULT([yes])]
 889     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
 890     [AC_MSG_RESULT([no])]
 891   )
 892   LDFLAGS="$save_LDFLAGS"
 893 fi
 894
 895 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 896 # than autoconf's macros like.
 897 if test "$GCC" = yes; then
 898   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 899   # accident waiting to happen.
 900   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
 901 else
 902   # Autoconf sets -g -O2 by default. Override optimization level
 903   # for non-gcc compilers
 904   CFLAGS="$CFLAGS -O"
 905   enable_gcc_warnings=no
 906   enable_gcc_warnings_advisory=no
 907 fi
 908
 909 # Add some more warnings which we use in development but not in the
 910 # released versions.  (Some relevant gcc versions can't handle these.)
 911 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
 912
 913   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 914 #if !defined(__GNUC__) || (__GNUC__ < 4)
 915 #error
 916 #endif])], have_gcc4=yes, have_gcc4=no)
 917
 918   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 919 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 920 #error
 921 #endif])], have_gcc42=yes, have_gcc42=no)
 922
 923   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 924 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 925 #error
 926 #endif])], have_gcc43=yes, have_gcc43=no)
 927
 928   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 929 #if !defined(__clang__) || (__clang_major__ > 2) || (__clang_major__ == 2 && __clang_minor__ > 9)
 930 #error
 931 #endif])], have_clang29orlower=yes, have_clang29orlower=no)
 932
 933   save_CFLAGS="$CFLAGS"
 934   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 935   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
 936                     have_shorten64_flag=no)
 937   CFLAGS="$save_CFLAGS"
 938
 939   case $host in
 940     *-*-openbsd*)
 941       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
 942       # That's fine, except that the headers don't pass -Wredundant-decls.
 943       # Therefore, let's disable -Wsystem-headers when we're building
 944       # with maximal warnings on OpenBSD.
 945       CFLAGS="$CFLAGS -Wno-system-headers" ;;
 946   esac
 947
 948   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum"
 949   if test x$enable_gcc_warnings = xyes; then
 950     CFLAGS="$CFLAGS -Werror"
 951   fi
 952
 953   # Disabled, so we can use mallinfo(): -Waggregate-return
 954
 955   if test x$have_gcc4 = xyes ; then
 956     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 957     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 958   fi
 959
 960   if test x$have_gcc42 = xyes ; then
 961     # These warnings break gcc 4.0.2 and work on gcc 4.2
 962     # XXXX020 See if any of these work with earlier versions.
 963     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wstrict-overflow=1"
 964
 965     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 966   fi
 967
 968   if test x$have_gcc42 = xyes && test x$have_clang29orlower = xno; then
 969     # These warnings break gcc 4.0.2 and clang, but work on gcc 4.2
 970     # We only disable these for clang 2.9 and lower, in case they are
 971     # supported in later versions.
 972     CFLAGS="$CFLAGS -Wnormalized=id -Woverride-init"
 973   fi
 974
 975   if test x$have_gcc43 = xyes ; then
 976     # These warnings break gcc 4.2 and work on gcc 4.3
 977     # XXXX020 See if any of these work with earlier versions.
 978     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 979   fi
 980
 981   if test x$have_shorten64_flag = xyes ; then
 982     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 983   fi
 984
 985 ##This will break the world on some 64-bit architectures
 986 # CFLAGS="$CFLAGS -Winline"
 987 fi
 988
 989
 990
 991 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 992
 993 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile src/config/torrc.sample src/Makefile doc/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/test/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 994 AC_OUTPUT
 995
 996 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 997   ./contrib/updateVersions.pl
 998 fi
 999