configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2017, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.2.1-alpha-dev])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56 AC_ARG_ENABLE(memory-sentinels,
  57    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  58 AC_ARG_ENABLE(rust,
  59    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  60 AC_ARG_ENABLE(cargo-online-mode,
  61    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  62
  63 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  64     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  65 fi
  66
  67 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  68 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  69 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  70 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  71 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  72 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  73
  74 if test "$enable_static_tor" = "yes"; then
  75   enable_static_libevent="yes";
  76   enable_static_openssl="yes";
  77   enable_static_zlib="yes";
  78   CFLAGS="$CFLAGS -static"
  79 fi
  80
  81 if test "$enable_system_torrc" = "no"; then
  82   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  83             [Defined if we're not going to look for a torrc in SYSCONF])
  84 fi
  85
  86 if test "$enable_memory_sentinels" = "no"; then
  87   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  88            [Defined if we're turning off memory safety code to look for bugs])
  89 fi
  90
  91 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  92
  93 AC_ARG_ENABLE(asciidoc,
  94      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  95      [case "${enableval}" in
  96         "yes") asciidoc=true ;;
  97         "no")  asciidoc=false ;;
  98         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  99       esac], [asciidoc=true])
 100
 101 # systemd notify support
 102 AC_ARG_ENABLE(systemd,
 103       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 104       [case "${enableval}" in
 105         "yes") systemd=true ;;
 106         "no")  systemd=false ;;
 107         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 108       esac], [systemd=auto])
 109
 110
 111
 112 # systemd support
 113 if test "x$enable_systemd" = "xno"; then
 114     have_systemd=no;
 115 else
 116     PKG_CHECK_MODULES(SYSTEMD,
 117         [libsystemd-daemon],
 118         have_systemd=yes,
 119         have_systemd=no)
 120     if test "x$have_systemd" = "xno"; then
 121         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 122         PKG_CHECK_MODULES(SYSTEMD,
 123             [libsystemd],
 124             have_systemd=yes,
 125             have_systemd=no)
 126     fi
 127 fi
 128
 129 if test "x$have_systemd" = "xyes"; then
 130     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 131     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 132     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 133     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 134          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 135 fi
 136 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 137 AC_SUBST(TOR_SYSTEMD_LIBS)
 138
 139 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 140     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 141 fi
 142
 143 case "$host" in
 144    *-*-solaris* )
 145      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 146      ;;
 147 esac
 148
 149 AC_ARG_ENABLE(gcc-warnings,
 150      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 151 AC_ARG_ENABLE(fatal-warnings,
 152      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 153 AC_ARG_ENABLE(gcc-warnings-advisory,
 154      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 155
 156 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 157 AC_ARG_ENABLE(gcc-hardening,
 158     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 159
 160 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 161 AC_ARG_ENABLE(expensive-hardening,
 162     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 163 AC_ARG_ENABLE(fragile-hardening,
 164     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 165 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 166   fragile_hardening="yes"
 167 fi
 168
 169 dnl Linker hardening options
 170 dnl Currently these options are ELF specific - you can't use this with MacOSX
 171 AC_ARG_ENABLE(linker-hardening,
 172     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 173
 174 AC_ARG_ENABLE(local-appdata,
 175    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 176 if test "$enable_local_appdata" = "yes"; then
 177   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 178             [Defined if we default to host local appdata paths on Windows])
 179 fi
 180
 181 # Tor2web mode flag
 182 AC_ARG_ENABLE(tor2web-mode,
 183      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 184 [if test "x$enableval" = "xyes"; then
 185     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 186 fi])
 187
 188 AC_ARG_ENABLE(tool-name-check,
 189      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 190
 191 AC_ARG_ENABLE(seccomp,
 192      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 193
 194 AC_ARG_ENABLE(libscrypt,
 195      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 196
 197 dnl Enable event tracing which are transformed to debug log statement.
 198 AC_ARG_ENABLE(event-tracing-debug,
 199      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 200 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 201
 202 if test x$enable_event_tracing_debug = xyes; then
 203   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 204   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 205 fi
 206
 207 dnl check for the correct "ar" when cross-compiling.
 208 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 209 dnl    so kludge up a replacement for the case where it isn't there yet.)
 210 m4_ifdef([AM_PROG_AR],
 211          [AM_PROG_AR],
 212          [AN_MAKEVAR([AR], [AC_PROG_AR])
 213           AN_PROGRAM([ar], [AC_PROG_AR])
 214           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 215           AC_PROG_AR])
 216
 217 dnl Check whether the above macro has settled for a simply named tool even
 218 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 219 dnl because that will find any cc on the system, not only the cross-compiler,
 220 dnl and then verify that a binary built with this compiler runs on the
 221 dnl build system. It will then come to the false conclusion that we're not
 222 dnl cross-compiling.
 223 if test "x$enable_tool_name_check" != "xno"; then
 224     if test "x$ac_tool_warned" = "xyes"; then
 225         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 226         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 227                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 228         fi
 229 fi
 230
 231 AC_PROG_CC
 232 AC_PROG_CPP
 233 AC_PROG_MAKE_SET
 234 AC_PROG_RANLIB
 235 AC_PROG_SED
 236
 237 AC_ARG_VAR([PERL], [path to Perl binary])
 238 AC_CHECK_PROGS([PERL], [perl])
 239 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 240
 241 dnl check for asciidoc and a2x
 242 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 243 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 244
 245 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 246
 247 AM_PROG_CC_C_O
 248 AC_PROG_CC_C99
 249
 250 AC_ARG_VAR([PYTHON], [path to Python binary])
 251 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 252 if test "x$PYTHON" = "x"; then
 253   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 254 fi
 255 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 256
 257 dnl List all external rust crates we depend on here. Include the version
 258 rust_crates="libc-0.2.22"
 259 AC_SUBST(rust_crates)
 260
 261 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 262 AC_C_FLEXIBLE_ARRAY_MEMBER
 263 ], [
 264  dnl Maybe we've got an old autoconf...
 265  AC_CACHE_CHECK([for flexible array members],
 266      tor_cv_c_flexarray,
 267      [AC_COMPILE_IFELSE(
 268        AC_LANG_PROGRAM([
 269  struct abc { int a; char b[]; };
 270 ], [
 271  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 272  def->b[0] = 33;
 273 ]),
 274   [tor_cv_c_flexarray=yes],
 275   [tor_cv_c_flexarray=no])])
 276  if test "$tor_cv_flexarray" = "yes"; then
 277    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 278  else
 279    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 280  fi
 281 ])
 282
 283 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 284       tor_cv_c_c99_decl,
 285       [AC_COMPILE_IFELSE(
 286          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 287          [tor_cv_c_c99_decl=yes],
 288          [tor_cv_c_c99_decl=no] )])
 289 if test "$tor_cv_c_c99_decl" != "yes"; then
 290   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 291 fi
 292
 293 AC_CACHE_CHECK([for working C99 designated initializers],
 294       tor_cv_c_c99_designated_init,
 295       [AC_COMPILE_IFELSE(
 296          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 297                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 298          [tor_cv_c_c99_designated_init=yes],
 299          [tor_cv_c_c99_designated_init=no] )])
 300
 301 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 302   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 303 fi
 304
 305 TORUSER=_tor
 306 AC_ARG_WITH(tor-user,
 307         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 308         [
 309            TORUSER=$withval
 310         ]
 311 )
 312 AC_SUBST(TORUSER)
 313
 314 TORGROUP=_tor
 315 AC_ARG_WITH(tor-group,
 316         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 317         [
 318            TORGROUP=$withval
 319         ]
 320 )
 321 AC_SUBST(TORGROUP)
 322
 323
 324 dnl If _WIN32 is defined and non-zero, we are building for win32
 325 AC_MSG_CHECKING([for win32])
 326 AC_RUN_IFELSE([AC_LANG_SOURCE([
 327 int main(int c, char **v) {
 328 #ifdef _WIN32
 329 #if _WIN32
 330   return 0;
 331 #else
 332   return 1;
 333 #endif
 334 #else
 335   return 2;
 336 #endif
 337 }])],
 338 bwin32=true; AC_MSG_RESULT([yes]),
 339 bwin32=false; AC_MSG_RESULT([no]),
 340 bwin32=cross; AC_MSG_RESULT([cross])
 341 )
 342
 343 if test "$bwin32" = "cross"; then
 344 AC_MSG_CHECKING([for win32 (cross)])
 345 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 346 #ifdef _WIN32
 347 int main(int c, char **v) {return 0;}
 348 #else
 349 #error
 350 int main(int c, char **v) {return x(y);}
 351 #endif
 352 ])],
 353 bwin32=true; AC_MSG_RESULT([yes]),
 354 bwin32=false; AC_MSG_RESULT([no]))
 355 fi
 356
 357 AH_BOTTOM([
 358 #ifdef _WIN32
 359 /* Defined to access windows functions and definitions for >=WinXP */
 360 # ifndef WINVER
 361 #  define WINVER 0x0501
 362 # endif
 363
 364 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 365 # ifndef _WIN32_WINNT
 366 #  define _WIN32_WINNT 0x0501
 367 # endif
 368
 369 /* Defined to avoid including some windows headers as part of Windows.h */
 370 # ifndef WIN32_LEAN_AND_MEAN
 371 #  define WIN32_LEAN_AND_MEAN 1
 372 # endif
 373 #endif
 374 ])
 375
 376
 377 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 378
 379 dnl Enable C99 when compiling with MIPSpro
 380 AC_MSG_CHECKING([for MIPSpro compiler])
 381 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 382 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 383 #error
 384   return x(y);
 385 #endif
 386 ])],
 387 bmipspro=false; AC_MSG_RESULT(no),
 388 bmipspro=true; AC_MSG_RESULT(yes))
 389
 390 if test "$bmipspro" = "true"; then
 391   CFLAGS="$CFLAGS -c99"
 392 fi
 393
 394 AC_C_BIGENDIAN
 395
 396 if test "x$enable_rust" = "xyes"; then
 397   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 398   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 399   if test "x$RUSTC" = "xno"; then
 400     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 401   fi
 402
 403   AC_ARG_VAR([CARGO], [path to the cargo binary])
 404   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 405   if test "x$CARGO" = "xno"; then
 406     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 407   fi
 408
 409   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 410   if test "x$enable_cargo_online_mode" = "xyes"; then
 411     CARGO_ONLINE=
 412     RUST_DL=#
 413   else
 414     CARGO_ONLINE=--frozen
 415     RUST_DL=
 416
 417     dnl When we're not allowed to touch the network, we need crate dependencies
 418     dnl locally available.
 419     AC_MSG_CHECKING([rust crate dependencies])
 420     AC_ARG_VAR([RUST_DEPENDENCIES], [path to directory with local crate mirror])
 421     if test "x$RUST_DEPENDENCIES" = "x"; then
 422       RUST_DEPENDENCIES="$srcdir/src/ext/rust/"
 423       NEED_MOD=1
 424     fi
 425     if test ! -d "$RUST_DEPENDENCIES"; then
 426       AC_MSG_ERROR([Rust dependency directory $RUST_DEPENDENCIES does not exist. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 427     fi
 428     for dep in $rust_crates; do
 429       if test ! -d "$RUST_DEPENDENCIES"/"$dep"; then
 430         AC_MSG_ERROR([Failure to find rust dependency $RUST_DEPENDENCIES/$dep. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 431       fi
 432     done
 433     if test "x$NEED_MOD" = "x1"; then
 434       dnl When looking for dependencies from cargo, pick right directory
 435       RUST_DEPENDENCIES="../../src/ext/rust"
 436     fi
 437   fi
 438
 439   dnl For now both MSVC and MinGW rust libraries will output static libs with
 440   dnl the MSVC naming convention.
 441   if test "$bwin32" = "true"; then
 442     TOR_RUST_UTIL_STATIC_NAME=tor_util.lib
 443   else
 444     TOR_RUST_UTIL_STATIC_NAME=libtor_util.a
 445   fi
 446
 447   AC_SUBST(TOR_RUST_UTIL_STATIC_NAME)
 448   AC_SUBST(CARGO_ONLINE)
 449   AC_SUBST(RUST_DL)
 450
 451   dnl Let's check the rustc version, too
 452   AC_MSG_CHECKING([rust version])
 453   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 454   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 455   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 456     AC_MSG_ERROR([rustc version couldn't be identified])
 457   fi
 458   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 459     AC_MSG_ERROR([rustc must be at least version 1.14])
 460   fi
 461 fi
 462
 463 AC_SEARCH_LIBS(socket, [socket network])
 464 AC_SEARCH_LIBS(gethostbyname, [nsl])
 465 AC_SEARCH_LIBS(dlopen, [dl])
 466 AC_SEARCH_LIBS(inet_aton, [resolv])
 467 AC_SEARCH_LIBS(backtrace, [execinfo])
 468 saved_LIBS="$LIBS"
 469 AC_SEARCH_LIBS([clock_gettime], [rt])
 470 if test "$LIBS" != "$saved_LIBS"; then
 471    # Looks like we need -lrt for clock_gettime().
 472    have_rt=yes
 473 fi
 474
 475 AC_SEARCH_LIBS(pthread_create, [pthread])
 476 AC_SEARCH_LIBS(pthread_detach, [pthread])
 477
 478 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 479 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 480
 481 AC_CHECK_FUNCS(
 482         _NSGetEnviron \
 483         RtlSecureZeroMemory \
 484         SecureZeroMemory \
 485         accept4 \
 486         backtrace \
 487         backtrace_symbols_fd \
 488         eventfd \
 489         explicit_bzero \
 490         timingsafe_memcmp \
 491         flock \
 492         ftime \
 493         get_current_dir_name \
 494         getaddrinfo \
 495         getifaddrs \
 496         getpass \
 497         getrlimit \
 498         gettimeofday \
 499         gmtime_r \
 500         htonll \
 501         inet_aton \
 502         ioctl \
 503         issetugid \
 504         llround \
 505         localtime_r \
 506         lround \
 507         memmem \
 508         memset_s \
 509         pipe \
 510         pipe2 \
 511         prctl \
 512         readpassphrase \
 513         rint \
 514         sigaction \
 515         socketpair \
 516         statvfs \
 517         strlcat \
 518         strlcpy \
 519         strnlen \
 520         strptime \
 521         strtok_r \
 522         strtoull \
 523         sysconf \
 524         sysctl \
 525         truncate \
 526         uname \
 527         usleep \
 528         vasprintf \
 529         _vscprintf
 530 )
 531
 532 # Apple messed up when they added two functions functions in Sierra: they
 533 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 534 # checks. So we should only probe for those functions if we are sure that we
 535 # are not targetting OSX 10.11 or earlier.
 536 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 537 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 538 #ifdef __APPLE__
 539 #  include <AvailabilityMacros.h>
 540 #  ifndef MAC_OS_X_VERSION_10_12
 541 #    define MAC_OS_X_VERSION_10_12 101200
 542 #  endif
 543 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 544 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 545 #      error "Running on Mac OSX 10.11 or earlier"
 546 #    endif
 547 #  endif
 548 #endif
 549 ]], [[]])],
 550    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 551    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 552
 553 if test "$on_macos_pre_10_12" = "no"; then
 554   AC_CHECK_FUNCS(
 555         clock_gettime \
 556         getentropy \
 557   )
 558 fi
 559
 560 if test "$bwin32" != "true"; then
 561   AC_CHECK_HEADERS(pthread.h)
 562   AC_CHECK_FUNCS(pthread_create)
 563   AC_CHECK_FUNCS(pthread_condattr_setclock)
 564 fi
 565
 566 if test "$bwin32" = "true"; then
 567   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 568 #include <windows.h>
 569 #include <conio.h>
 570 #include <wchar.h>
 571                  ])
 572 fi
 573
 574 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 575   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 576
 577 dnl ------------------------------------------------------
 578 dnl Where do you live, libevent?  And how do we call you?
 579
 580 if test "$bwin32" = "true"; then
 581   TOR_LIB_WS32=-lws2_32
 582   TOR_LIB_IPHLPAPI=-liphlpapi
 583   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 584   # think it's actually necessary.
 585   TOR_LIB_GDI=-lgdi32
 586   TOR_LIB_USERENV=-luserenv
 587 else
 588   TOR_LIB_WS32=
 589   TOR_LIB_GDI=
 590   TOR_LIB_USERENV=
 591 fi
 592 AC_SUBST(TOR_LIB_WS32)
 593 AC_SUBST(TOR_LIB_GDI)
 594 AC_SUBST(TOR_LIB_IPHLPAPI)
 595 AC_SUBST(TOR_LIB_USERENV)
 596
 597 tor_libevent_pkg_redhat="libevent"
 598 tor_libevent_pkg_debian="libevent-dev"
 599 tor_libevent_devpkg_redhat="libevent-devel"
 600 tor_libevent_devpkg_debian="libevent-dev"
 601
 602 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 603 dnl linking for static builds.
 604 STATIC_LIBEVENT_FLAGS=""
 605 if test "$enable_static_libevent" = "yes"; then
 606     if test "$have_rt" = "yes"; then
 607       STATIC_LIBEVENT_FLAGS=" -lrt "
 608     fi
 609 fi
 610
 611 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 612 #ifdef _WIN32
 613 #include <winsock2.h>
 614 #endif
 615 #include <sys/time.h>
 616 #include <sys/types.h>
 617 #include <event2/event.h>], [
 618 #ifdef _WIN32
 619 #include <winsock2.h>
 620 #endif
 621 struct event_base;
 622 struct event_base *event_base_new(void);],
 623     [
 624 #ifdef _WIN32
 625 {WSADATA d; WSAStartup(0x101,&d); }
 626 #endif
 627 event_base_new();
 628 ], [--with-libevent-dir], [/opt/libevent])
 629
 630 dnl Determine the incantation needed to link libevent.
 631 save_LIBS="$LIBS"
 632 save_LDFLAGS="$LDFLAGS"
 633 save_CPPFLAGS="$CPPFLAGS"
 634
 635 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 636 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 637 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 638
 639 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 640
 641 if test "$enable_static_libevent" = "yes"; then
 642    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 643      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 644    else
 645      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 646    fi
 647 else
 648      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 649        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 650        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 651
 652        if test "$ac_cv_search_event_new" != "none required"; then
 653          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 654        fi
 655        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 656          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 657        fi
 658      else
 659        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 660      fi
 661 fi
 662
 663 dnl Now check for particular libevent functions.
 664 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 665                 evutil_secure_rng_add_bytes \
 666 ])
 667
 668 LIBS="$save_LIBS"
 669 LDFLAGS="$save_LDFLAGS"
 670 CPPFLAGS="$save_CPPFLAGS"
 671
 672 dnl Check that libevent is at least at version 2.0.10, the first stable
 673 dnl release of its series
 674 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 675 AC_MSG_CHECKING([whether Libevent is new enough])
 676 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 677 #include <event2/event.h>
 678 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 679 #error
 680 int x = y(zz);
 681 #else
 682 int x = 1;
 683 #endif
 684 ])], [ AC_MSG_RESULT([yes]) ],
 685    [ AC_MSG_RESULT([no])
 686      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 687
 688 LIBS="$save_LIBS"
 689 LDFLAGS="$save_LDFLAGS"
 690 CPPFLAGS="$save_CPPFLAGS"
 691
 692 AC_SUBST(TOR_LIBEVENT_LIBS)
 693
 694 dnl ------------------------------------------------------
 695 dnl Where do you live, libm?
 696
 697 dnl On some platforms (Haiku/BeOS) the math library is
 698 dnl part of libroot. In which case don't link against lm
 699 TOR_LIB_MATH=""
 700 save_LIBS="$LIBS"
 701 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 702 if test "$ac_cv_search_pow" != "none required"; then
 703     TOR_LIB_MATH="$ac_cv_search_pow"
 704 fi
 705 LIBS="$save_LIBS"
 706 AC_SUBST(TOR_LIB_MATH)
 707
 708 dnl ------------------------------------------------------
 709 dnl Where do you live, openssl?  And how do we call you?
 710
 711 tor_openssl_pkg_redhat="openssl"
 712 tor_openssl_pkg_debian="libssl-dev"
 713 tor_openssl_devpkg_redhat="openssl-devel"
 714 tor_openssl_devpkg_debian="libssl-dev"
 715
 716 ALT_openssl_WITHVAL=""
 717 AC_ARG_WITH(ssl-dir,
 718   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 719   [
 720       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 721          ALT_openssl_WITHVAL="$withval"
 722       fi
 723   ])
 724
 725 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 726     [#include <openssl/rand.h>],
 727     [void RAND_add(const void *buf, int num, double entropy);],
 728     [RAND_add((void*)0,0,0);], [],
 729     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 730
 731 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 732
 733 if test "$enable_static_openssl" = "yes"; then
 734    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 735      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 736    else
 737      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 738    fi
 739 else
 740      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 741 fi
 742 AC_SUBST(TOR_OPENSSL_LIBS)
 743
 744 dnl Now check for particular openssl functions.
 745 save_LIBS="$LIBS"
 746 save_LDFLAGS="$LDFLAGS"
 747 save_CPPFLAGS="$CPPFLAGS"
 748 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 749 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 750 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 751
 752 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 753 #include <openssl/opensslv.h>
 754 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 755 #error "too old"
 756 #endif
 757    ]], [[]])],
 758    [ : ],
 759    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 760
 761 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 762 #include <openssl/opensslv.h>
 763 #include <openssl/evp.h>
 764 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 765 #error "no ECC"
 766 #endif
 767 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 768 #error "curves unavailable"
 769 #endif
 770    ]], [[]])],
 771    [ : ],
 772    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 773
 774 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 775 [#include <openssl/ssl.h>
 776 ])
 777
 778 AC_CHECK_FUNCS([ \
 779                 SSL_SESSION_get_master_key \
 780                 SSL_get_server_random \
 781                 SSL_get_client_ciphers \
 782                 SSL_get_client_random \
 783                 SSL_CIPHER_find \
 784                 TLS_method
 785                ])
 786
 787 dnl Check if OpenSSL has scrypt implementation.
 788 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 789
 790 dnl Check if OpenSSL structures are opaque
 791 AC_CHECK_MEMBERS([SSL.state], , ,
 792 [#include <openssl/ssl.h>
 793 ])
 794
 795 dnl Define the set of checks for KIST scheduler support.
 796 AC_DEFUN([CHECK_KIST_SUPPORT],[
 797   dnl KIST needs struct tcp_info and for certain members to exist.
 798   AC_CHECK_MEMBERS(
 799     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
 800     , ,[[#include <netinet/tcp.h>]])
 801   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
 802   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 803                      #include <linux/sockios.h>
 804                      #ifndef SIOCOUTQNSD
 805                      #error
 806                      #endif
 807                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
 808   if test "x$have_siocoutqnsd" = "xyes"; then
 809     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
 810       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
 811         have_kist_support=yes
 812       fi
 813     fi
 814   fi
 815 ])
 816 dnl Now, trigger the check.
 817 CHECK_KIST_SUPPORT
 818 AS_IF([test "x$have_kist_support" = "xyes"],
 819       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
 820                                         on this system])],
 821       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
 822
 823 LIBS="$save_LIBS"
 824 LDFLAGS="$save_LDFLAGS"
 825 CPPFLAGS="$save_CPPFLAGS"
 826
 827 dnl ------------------------------------------------------
 828 dnl Where do you live, zlib?  And how do we call you?
 829
 830 tor_zlib_pkg_redhat="zlib"
 831 tor_zlib_pkg_debian="zlib1g"
 832 tor_zlib_devpkg_redhat="zlib-devel"
 833 tor_zlib_devpkg_debian="zlib1g-dev"
 834
 835 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 836     [#include <zlib.h>],
 837     [const char * zlibVersion(void);],
 838     [zlibVersion();], [--with-zlib-dir],
 839     [/opt/zlib])
 840
 841 if test "$enable_static_zlib" = "yes"; then
 842    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 843      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 844  using --enable-static-zlib")
 845    else
 846      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 847    fi
 848 else
 849      TOR_ZLIB_LIBS="-lz"
 850 fi
 851 AC_SUBST(TOR_ZLIB_LIBS)
 852
 853 dnl ------------------------------------------------------
 854 dnl Where we do we find lzma?
 855
 856 AC_ARG_ENABLE(lzma,
 857       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
 858       [case "${enableval}" in
 859         "yes") lzma=true ;;
 860         "no")  lzma=false ;;
 861         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
 862       esac], [lzma=auto])
 863
 864 if test "x$enable_lzma" = "xno"; then
 865     have_lzma=no;
 866 else
 867     PKG_CHECK_MODULES([LZMA],
 868                       [liblzma],
 869                       have_lzma=yes,
 870                       have_lzma=no)
 871
 872     if test "x$have_lzma" = "xno" ; then
 873         AC_MSG_WARN([Unable to find liblzma.])
 874     fi
 875 fi
 876
 877 if test "x$have_lzma" = "xyes"; then
 878     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
 879     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
 880     TOR_LZMA_LIBS="${LZMA_LIBS}"
 881 fi
 882 AC_SUBST(TOR_LZMA_CFLAGS)
 883 AC_SUBST(TOR_LZMA_LIBS)
 884
 885 dnl ------------------------------------------------------
 886 dnl Where we do we find zstd?
 887
 888 AC_ARG_ENABLE(zstd,
 889       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
 890       [case "${enableval}" in
 891         "yes") zstd=true ;;
 892         "no")  zstd=false ;;
 893         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
 894       esac], [zstd=auto])
 895
 896 if test "x$enable_zstd" = "xno"; then
 897     have_zstd=no;
 898 else
 899     PKG_CHECK_MODULES([ZSTD],
 900                       [libzstd >= 1.1],
 901                       have_zstd=yes,
 902                       have_zstd=no)
 903
 904     if test "x$have_zstd" = "xno" ; then
 905         AC_MSG_WARN([Unable to find libzstd.])
 906     fi
 907 fi
 908
 909 if test "x$have_zstd" = "xyes"; then
 910     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
 911     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
 912     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
 913 fi
 914 AC_SUBST(TOR_ZSTD_CFLAGS)
 915 AC_SUBST(TOR_ZSTD_LIBS)
 916
 917 dnl ----------------------------------------------------------------------
 918 dnl Check if libcap is available for capabilities.
 919
 920 tor_cap_pkg_debian="libcap2"
 921 tor_cap_pkg_redhat="libcap"
 922 tor_cap_devpkg_debian="libcap-dev"
 923 tor_cap_devpkg_redhat="libcap-devel"
 924
 925 AC_CHECK_LIB([cap], [cap_init], [],
 926   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 927 )
 928 AC_CHECK_FUNCS(cap_set_proc)
 929
 930 dnl ---------------------------------------------------------------------
 931 dnl Now that we know about our major libraries, we can check for compiler
 932 dnl and linker hardening options.  We need to do this with the libraries known,
 933 dnl since sometimes the linker will like an option but not be willing to
 934 dnl use it with a build of a library.
 935
 936 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 937 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
 938
 939 CFLAGS_FTRAPV=
 940 CFLAGS_FWRAPV=
 941 CFLAGS_ASAN=
 942 CFLAGS_UBSAN=
 943
 944
 945 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 946 #if !defined(__clang__)
 947 #error
 948 #endif])], have_clang=yes, have_clang=no)
 949
 950 if test "x$enable_gcc_hardening" != "xno"; then
 951     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 952     if test "x$have_clang" = "xyes"; then
 953         TOR_CHECK_CFLAGS(-Qunused-arguments)
 954     fi
 955     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 956     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 957     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 958 m4_ifdef([AS_VAR_IF],[
 959     AS_VAR_IF(can_compile, [yes],
 960         AS_VAR_IF(can_link, [yes],
 961                   [],
 962                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 963         )])
 964     AS_VAR_POPDEF([can_link])
 965     AS_VAR_POPDEF([can_compile])
 966     TOR_CHECK_CFLAGS(-Wstack-protector)
 967     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 968     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
 969        TOR_CHECK_CFLAGS(-fPIE)
 970        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 971     fi
 972     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
 973 fi
 974
 975 if test "$fragile_hardening" = "yes"; then
 976     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
 977    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
 978       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
 979    fi
 980
 981    if test "$tor_cv_cflags__ftrapv" != "yes"; then
 982      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
 983    fi
 984
 985    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
 986     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 987       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
 988     fi
 989
 990    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
 991     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 992       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
 993     fi
 994
 995 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 996 fi
 997
 998 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
 999 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1000
1001 mulodi_fixes_ftrapv=no
1002 if test "$have_clang" = "yes"; then
1003   saved_CFLAGS="$CFLAGS"
1004   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1005   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1006   AC_LINK_IFELSE([
1007       AC_LANG_SOURCE([[
1008           #include <stdint.h>
1009           #include <stdlib.h>
1010           int main(int argc, char **argv)
1011           {
1012             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1013                         * (int64_t)atoi(argv[3]);
1014             return x == 9;
1015           } ]])],
1016           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1017           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1018   if test "$ftrapv_can_link" = "no"; then
1019     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1020     AC_LINK_IFELSE([
1021       AC_LANG_SOURCE([[
1022           #include <stdint.h>
1023           #include <stdlib.h>
1024           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1025              *overflow=0;
1026              return a;
1027           }
1028           int main(int argc, char **argv)
1029           {
1030             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1031                         * (int64_t)atoi(argv[3]);
1032             return x == 9;
1033           } ]])],
1034           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1035           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1036   fi
1037   CFLAGS="$saved_CFLAGS"
1038 fi
1039
1040 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1041
1042 dnl These cflags add bunches of branches, and we haven't been able to
1043 dnl persuade ourselves that they're suitable for code that needs to be
1044 dnl constant time.
1045 AC_SUBST(CFLAGS_BUGTRAP)
1046 dnl These cflags are variant ones sutable for code that needs to be
1047 dnl constant-time.
1048 AC_SUBST(CFLAGS_CONSTTIME)
1049
1050 if test "x$enable_linker_hardening" != "xno"; then
1051     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1052 fi
1053
1054 # For backtrace support
1055 TOR_CHECK_LDFLAGS(-rdynamic)
1056
1057 dnl ------------------------------------------------------
1058 dnl Now see if we have a -fomit-frame-pointer compiler option.
1059
1060 saved_CFLAGS="$CFLAGS"
1061 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1062 F_OMIT_FRAME_POINTER=''
1063 if test "$saved_CFLAGS" != "$CFLAGS"; then
1064   if test "$fragile_hardening" = "yes"; then
1065     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1066   fi
1067 fi
1068 CFLAGS="$saved_CFLAGS"
1069 AC_SUBST(F_OMIT_FRAME_POINTER)
1070
1071 dnl ------------------------------------------------------
1072 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1073 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1074 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1075 dnl code will work.
1076 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1077
1078 dnl ============================================================
1079 dnl Check for libseccomp
1080
1081 if test "x$enable_seccomp" != "xno"; then
1082   AC_CHECK_HEADERS([seccomp.h])
1083   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1084 fi
1085
1086 dnl ============================================================
1087 dnl Check for libscrypt
1088
1089 if test "x$enable_libscrypt" != "xno"; then
1090   AC_CHECK_HEADERS([libscrypt.h])
1091   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1092   AC_CHECK_FUNCS([libscrypt_scrypt])
1093 fi
1094
1095 dnl ============================================================
1096 dnl We need an implementation of curve25519.
1097
1098 dnl set these defaults.
1099 build_curve25519_donna=no
1100 build_curve25519_donna_c64=no
1101 use_curve25519_donna=no
1102 use_curve25519_nacl=no
1103 CURVE25519_LIBS=
1104
1105 dnl The best choice is using curve25519-donna-c64, but that requires
1106 dnl that we
1107 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1108   tor_cv_can_use_curve25519_donna_c64,
1109   [AC_RUN_IFELSE(
1110     [AC_LANG_PROGRAM([dnl
1111       #include <stdint.h>
1112       typedef unsigned uint128_t __attribute__((mode(TI)));
1113   int func(uint64_t a, uint64_t b) {
1114            uint128_t c = ((uint128_t)a) * b;
1115            int ok = ((uint64_t)(c>>96)) == 522859 &&
1116              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1117                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1118                  (((uint64_t)(c))&0xffffffffL) == 0;
1119            return ok;
1120       }
1121   ], [dnl
1122     int ok = func( ((uint64_t)2000000000) * 1000000000,
1123                    ((uint64_t)1234567890) << 24);
1124         return !ok;
1125       ])],
1126   [tor_cv_can_use_curve25519_donna_c64=yes],
1127       [tor_cv_can_use_curve25519_donna_c64=no],
1128   [AC_LINK_IFELSE(
1129         [AC_LANG_PROGRAM([dnl
1130       #include <stdint.h>
1131       typedef unsigned uint128_t __attribute__((mode(TI)));
1132   int func(uint64_t a, uint64_t b) {
1133            uint128_t c = ((uint128_t)a) * b;
1134            int ok = ((uint64_t)(c>>96)) == 522859 &&
1135              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1136                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1137                  (((uint64_t)(c))&0xffffffffL) == 0;
1138            return ok;
1139       }
1140   ], [dnl
1141     int ok = func( ((uint64_t)2000000000) * 1000000000,
1142                  ((uint64_t)1234567890) << 24);
1143         return !ok;
1144       ])],
1145           [tor_cv_can_use_curve25519_donna_c64=cross],
1146       [tor_cv_can_use_curve25519_donna_c64=no])])])
1147
1148 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1149                   nacl/crypto_scalarmult_curve25519.h])
1150
1151 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1152   tor_cv_can_use_curve25519_nacl,
1153   [tor_saved_LIBS="$LIBS"
1154    LIBS="$LIBS -lnacl"
1155    AC_LINK_IFELSE(
1156      [AC_LANG_PROGRAM([dnl
1157        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1158        #include <crypto_scalarmult_curve25519.h>
1159    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1160    #include <nacl/crypto_scalarmult_curve25519.h>
1161    #endif
1162        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1163    #error Hey, this is the reference implementation! That's not fast.
1164    #endif
1165      ], [
1166    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1167      ])], [tor_cv_can_use_curve25519_nacl=yes],
1168      [tor_cv_can_use_curve25519_nacl=no])
1169    LIBS="$tor_saved_LIBS" ])
1170
1171  dnl Okay, now we need to figure out which one to actually use. Fall back
1172  dnl to curve25519-donna.c
1173
1174  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1175    build_curve25519_donna_c64=yes
1176    use_curve25519_donna=yes
1177  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1178    use_curve25519_nacl=yes
1179    CURVE25519_LIBS=-lnacl
1180  else
1181    build_curve25519_donna=yes
1182    use_curve25519_donna=yes
1183  fi
1184
1185 if test "x$use_curve25519_donna" = "xyes"; then
1186   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1187             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1188 fi
1189 if test "x$use_curve25519_nacl" = "xyes"; then
1190   AC_DEFINE(USE_CURVE25519_NACL, 1,
1191             [Defined if we should use a curve25519 from nacl])
1192 fi
1193 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1194   test "x$build_curve25519_donna" = "xyes")
1195 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1196   test "x$build_curve25519_donna_c64" = "xyes")
1197 AC_SUBST(CURVE25519_LIBS)
1198
1199 dnl Make sure to enable support for large off_t if available.
1200 AC_SYS_LARGEFILE
1201
1202 AC_CHECK_HEADERS([assert.h \
1203                   errno.h \
1204                   fcntl.h \
1205                   signal.h \
1206                   string.h \
1207                   sys/capability.h \
1208                   sys/fcntl.h \
1209                   sys/stat.h \
1210                   sys/time.h \
1211                   sys/types.h \
1212                   time.h \
1213                   unistd.h \
1214                   arpa/inet.h \
1215                   crt_externs.h \
1216                   execinfo.h \
1217                   grp.h \
1218                   ifaddrs.h \
1219                   inttypes.h \
1220                   limits.h \
1221                   linux/types.h \
1222                   machine/limits.h \
1223                   malloc.h \
1224                   malloc/malloc.h \
1225                   malloc_np.h \
1226                   netdb.h \
1227                   netinet/in.h \
1228                   netinet/in6.h \
1229                   pwd.h \
1230                   readpassphrase.h \
1231                   stdint.h \
1232                   sys/eventfd.h \
1233                   sys/file.h \
1234                   sys/ioctl.h \
1235                   sys/limits.h \
1236                   sys/mman.h \
1237                   sys/param.h \
1238                   sys/prctl.h \
1239                   sys/random.h \
1240                   sys/resource.h \
1241                   sys/select.h \
1242                   sys/socket.h \
1243                   sys/statvfs.h \
1244                   sys/syscall.h \
1245                   sys/sysctl.h \
1246                   sys/syslimits.h \
1247                   sys/time.h \
1248                   sys/types.h \
1249                   sys/un.h \
1250                   sys/utime.h \
1251                   sys/wait.h \
1252                   syslog.h \
1253                   utime.h])
1254
1255 AC_CHECK_HEADERS(sys/param.h)
1256
1257 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1258 [#ifdef HAVE_SYS_TYPES_H
1259 #include <sys/types.h>
1260 #endif
1261 #ifdef HAVE_SYS_SOCKET_H
1262 #include <sys/socket.h>
1263 #endif])
1264 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1265 [#ifdef HAVE_SYS_TYPES_H
1266 #include <sys/types.h>
1267 #endif
1268 #ifdef HAVE_SYS_SOCKET_H
1269 #include <sys/socket.h>
1270 #endif
1271 #ifdef HAVE_NET_IF_H
1272 #include <net/if.h>
1273 #endif
1274 #ifdef HAVE_NETINET_IN_H
1275 #include <netinet/in.h>
1276 #endif])
1277
1278 AC_CHECK_HEADERS(linux/if.h,[],[],
1279 [
1280 #ifdef HAVE_SYS_SOCKET_H
1281 #include <sys/socket.h>
1282 #endif
1283 ])
1284
1285 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1286         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1287 [#ifdef HAVE_SYS_TYPES_H
1288 #include <sys/types.h>
1289 #endif
1290 #ifdef HAVE_SYS_SOCKET_H
1291 #include <sys/socket.h>
1292 #endif
1293 #ifdef HAVE_LIMITS_H
1294 #include <limits.h>
1295 #endif
1296 #ifdef HAVE_LINUX_TYPES_H
1297 #include <linux/types.h>
1298 #endif
1299 #ifdef HAVE_NETINET_IN6_H
1300 #include <netinet/in6.h>
1301 #endif
1302 #ifdef HAVE_NETINET_IN_H
1303 #include <netinet/in.h>
1304 #endif])
1305
1306 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1307         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1308 [#ifdef HAVE_SYS_TYPES_H
1309 #include <sys/types.h>
1310 #endif
1311 #ifdef HAVE_SYS_SOCKET_H
1312 #include <sys/socket.h>
1313 #endif
1314 #ifdef HAVE_LIMITS_H
1315 #include <limits.h>
1316 #endif
1317 #ifdef HAVE_LINUX_TYPES_H
1318 #include <linux/types.h>
1319 #endif
1320 #ifdef HAVE_NETINET_IN6_H
1321 #include <netinet/in6.h>
1322 #endif
1323 #ifdef HAVE_NETINET_IN_H
1324 #include <netinet/in.h>
1325 #endif
1326 #ifdef HAVE_LINUX_IF_H
1327 #include <linux/if.h>
1328 #endif])
1329
1330 transparent_ok=0
1331 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1332   transparent_ok=1
1333 fi
1334 if test "x$linux_netfilter_ipv4" = "x1"; then
1335   transparent_ok=1
1336 fi
1337 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1338   transparent_ok=1
1339 fi
1340 if test "x$transparent_ok" = "x1"; then
1341   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1342 else
1343   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1344 fi
1345
1346 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1347 [#ifdef HAVE_SYS_TYPES_H
1348 #include <sys/types.h>
1349 #endif
1350 #ifdef HAVE_SYS_TIME_H
1351 #include <sys/time.h>
1352 #endif])
1353
1354 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1355 dnl Watch out.
1356
1357 AC_CHECK_SIZEOF(int8_t)
1358 AC_CHECK_SIZEOF(int16_t)
1359 AC_CHECK_SIZEOF(int32_t)
1360 AC_CHECK_SIZEOF(int64_t)
1361 AC_CHECK_SIZEOF(uint8_t)
1362 AC_CHECK_SIZEOF(uint16_t)
1363 AC_CHECK_SIZEOF(uint32_t)
1364 AC_CHECK_SIZEOF(uint64_t)
1365 AC_CHECK_SIZEOF(intptr_t)
1366 AC_CHECK_SIZEOF(uintptr_t)
1367
1368 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1369
1370 AC_CHECK_SIZEOF(char)
1371 AC_CHECK_SIZEOF(short)
1372 AC_CHECK_SIZEOF(int)
1373 AC_CHECK_SIZEOF(long)
1374 AC_CHECK_SIZEOF(long long)
1375 AC_CHECK_SIZEOF(__int64)
1376 AC_CHECK_SIZEOF(void *)
1377 AC_CHECK_SIZEOF(time_t)
1378 AC_CHECK_SIZEOF(size_t)
1379 AC_CHECK_SIZEOF(pid_t)
1380
1381 AC_CHECK_TYPES([uint, u_char, ssize_t])
1382
1383 AC_PC_FROM_UCONTEXT([:])
1384
1385 dnl used to include sockaddr_storage, but everybody has that.
1386 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1387 [#ifdef HAVE_SYS_TYPES_H
1388 #include <sys/types.h>
1389 #endif
1390 #ifdef HAVE_NETINET_IN_H
1391 #include <netinet/in.h>
1392 #endif
1393 #ifdef HAVE_NETINET_IN6_H
1394 #include <netinet/in6.h>
1395 #endif
1396 #ifdef HAVE_SYS_SOCKET_H
1397 #include <sys/socket.h>
1398 #endif
1399 #ifdef _WIN32
1400 #define _WIN32_WINNT 0x0501
1401 #define WIN32_LEAN_AND_MEAN
1402 #include <winsock2.h>
1403 #include <ws2tcpip.h>
1404 #endif
1405 ])
1406 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1407 [#ifdef HAVE_SYS_TYPES_H
1408 #include <sys/types.h>
1409 #endif
1410 #ifdef HAVE_NETINET_IN_H
1411 #include <netinet/in.h>
1412 #endif
1413 #ifdef HAVE_NETINET_IN6_H
1414 #include <netinet/in6.h>
1415 #endif
1416 #ifdef HAVE_SYS_SOCKET_H
1417 #include <sys/socket.h>
1418 #endif
1419 #ifdef _WIN32
1420 #define _WIN32_WINNT 0x0501
1421 #define WIN32_LEAN_AND_MEAN
1422 #include <winsock2.h>
1423 #include <ws2tcpip.h>
1424 #endif
1425 ])
1426
1427 AC_CHECK_TYPES([rlim_t], , ,
1428 [#ifdef HAVE_SYS_TYPES_H
1429 #include <sys/types.h>
1430 #endif
1431 #ifdef HAVE_SYS_TIME_H
1432 #include <sys/time.h>
1433 #endif
1434 #ifdef HAVE_SYS_RESOURCE_H
1435 #include <sys/resource.h>
1436 #endif
1437 ])
1438
1439 AX_CHECK_SIGN([time_t],
1440        [ : ],
1441        [ : ], [
1442 #ifdef HAVE_SYS_TYPES_H
1443 #include <sys/types.h>
1444 #endif
1445 #ifdef HAVE_SYS_TIME_H
1446 #include <sys/time.h>
1447 #endif
1448 #ifdef HAVE_TIME_H
1449 #include <time.h>
1450 #endif
1451 ])
1452
1453 if test "$ax_cv_decl_time_t_signed" = "no"; then
1454   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1455 fi
1456
1457 AX_CHECK_SIGN([size_t],
1458        [ tor_cv_size_t_signed=yes ],
1459        [ tor_cv_size_t_signed=no ], [
1460 #ifdef HAVE_SYS_TYPES_H
1461 #include <sys/types.h>
1462 #endif
1463 ])
1464
1465 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1466   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1467 fi
1468
1469 AX_CHECK_SIGN([enum always],
1470        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1471        [ : ], [
1472  enum always { AAA, BBB, CCC };
1473 ])
1474
1475 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1476 #ifdef HAVE_SYS_SOCKET_H
1477 #include <sys/socket.h>
1478 #endif
1479 ])
1480
1481 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1482
1483 AC_CHECK_SIZEOF(cell_t)
1484
1485 # Now make sure that NULL can be represented as zero bytes.
1486 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1487 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1488 [[#include <stdlib.h>
1489 #include <string.h>
1490 #include <stdio.h>
1491 #ifdef HAVE_STDDEF_H
1492 #include <stddef.h>
1493 #endif
1494 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1495 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1496        [tor_cv_null_is_zero=yes],
1497        [tor_cv_null_is_zero=no],
1498        [tor_cv_null_is_zero=cross])])
1499
1500 if test "$tor_cv_null_is_zero" = "cross"; then
1501   # Cross-compiling; let's hope that the target isn't raving mad.
1502   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1503 fi
1504
1505 if test "$tor_cv_null_is_zero" != "no"; then
1506   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1507             [Define to 1 iff memset(0) sets pointers to NULL])
1508 fi
1509
1510 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1511 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1512 [[#include <stdlib.h>
1513 #include <string.h>
1514 #include <stdio.h>
1515 #ifdef HAVE_STDDEF_H
1516 #include <stddef.h>
1517 #endif
1518 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1519 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1520        [tor_cv_dbl0_is_zero=yes],
1521        [tor_cv_dbl0_is_zero=no],
1522        [tor_cv_dbl0_is_zero=cross])])
1523
1524 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1525   # Cross-compiling; let's hope that the target isn't raving mad.
1526   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1527 fi
1528
1529 if test "$tor_cv_dbl0_is_zero" != "no"; then
1530   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1531             [Define to 1 iff memset(0) sets doubles to 0.0])
1532 fi
1533
1534 # And what happens when we malloc zero?
1535 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1536 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1537 [[#include <stdlib.h>
1538 #include <string.h>
1539 #include <stdio.h>
1540 #ifdef HAVE_STDDEF_H
1541 #include <stddef.h>
1542 #endif
1543 int main () { return malloc(0)?0:1; }]])],
1544        [tor_cv_malloc_zero_works=yes],
1545        [tor_cv_malloc_zero_works=no],
1546        [tor_cv_malloc_zero_works=cross])])
1547
1548 if test "$tor_cv_malloc_zero_works" = "cross"; then
1549   # Cross-compiling; let's hope that the target isn't raving mad.
1550   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1551 fi
1552
1553 if test "$tor_cv_malloc_zero_works" = "yes"; then
1554   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1555             [Define to 1 iff malloc(0) returns a pointer])
1556 fi
1557
1558 # whether we seem to be in a 2s-complement world.
1559 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1560 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1561 [[int main () { int problem = ((-99) != (~99)+1);
1562 return problem ? 1 : 0; }]])],
1563        [tor_cv_twos_complement=yes],
1564        [tor_cv_twos_complement=no],
1565        [tor_cv_twos_complement=cross])])
1566
1567 if test "$tor_cv_twos_complement" = "cross"; then
1568   # Cross-compiling; let's hope that the target isn't raving mad.
1569   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1570 fi
1571
1572 if test "$tor_cv_twos_complement" != "no"; then
1573   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1574             [Define to 1 iff we represent negative integers with
1575              two's complement])
1576 fi
1577
1578 # What does shifting a negative value do?
1579 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1580 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1581 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1582        [tor_cv_sign_extend=yes],
1583        [tor_cv_sign_extend=no],
1584        [tor_cv_sign_extend=cross])])
1585
1586 if test "$tor_cv_sign_extend" = "cross"; then
1587   # Cross-compiling; let's hope that the target isn't raving mad.
1588   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1589 fi
1590
1591 if test "$tor_cv_sign_extend" != "no"; then
1592   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1593             [Define to 1 iff right-shifting a negative value performs sign-extension])
1594 fi
1595
1596 # Is uint8_t the same type as unsigned char?
1597 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1598 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1599 #include <stdint.h>
1600 extern uint8_t c;
1601 unsigned char c;]])],
1602        [tor_cv_uint8_uchar=yes],
1603        [tor_cv_uint8_uchar=no],
1604        [tor_cv_uint8_uchar=cross])])
1605
1606 if test "$tor_cv_uint8_uchar" = "cross"; then
1607   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1608 fi
1609
1610 if test "$tor_cv_uint8_uchar" = "no"; then
1611   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1612 fi
1613
1614 # Whether we should use the dmalloc memory allocation debugging library.
1615 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1616 AC_ARG_WITH(dmalloc,
1617 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1618 [if [[ "$withval" = "yes" ]]; then
1619   dmalloc=1
1620   AC_MSG_RESULT(yes)
1621 else
1622   dmalloc=1
1623   AC_MSG_RESULT(no)
1624 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1625 )
1626
1627 if [[ $dmalloc -eq 1 ]]; then
1628   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1629   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1630   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1631   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1632 fi
1633
1634 AC_ARG_WITH(tcmalloc,
1635 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1636 [ tcmalloc=yes ], [ tcmalloc=no ])
1637
1638 if test "x$tcmalloc" = "xyes"; then
1639    LDFLAGS="-ltcmalloc $LDFLAGS"
1640 fi
1641
1642 using_custom_malloc=no
1643 if test "x$enable_openbsd_malloc" = "xyes"; then
1644    using_custom_malloc=yes
1645 fi
1646 if test "x$tcmalloc" = "xyes"; then
1647    using_custom_malloc=yes
1648 fi
1649 if test "$using_custom_malloc" = "no"; then
1650    AC_CHECK_FUNCS(mallinfo)
1651 fi
1652
1653 # By default, we're going to assume we don't have mlockall()
1654 # bionic and other platforms have various broken mlockall subsystems.
1655 # Some systems don't have a working mlockall, some aren't linkable,
1656 # and some have it but don't declare it.
1657 AC_CHECK_FUNCS(mlockall)
1658 AC_CHECK_DECLS([mlockall], , , [
1659 #ifdef HAVE_SYS_MMAN_H
1660 #include <sys/mman.h>
1661 #endif])
1662
1663 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1664 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1665 # using macros
1666 AC_CHECK_DECLS([getpagesize], , , [
1667 #ifdef HAVE_UNISTD_H
1668 #include <unistd.h>
1669 #endif])
1670
1671 # Allow user to specify an alternate syslog facility
1672 AC_ARG_WITH(syslog-facility,
1673 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1674 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1675 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1676 AC_SUBST(LOGFACILITY)
1677
1678 # Check if we have getresuid and getresgid
1679 AC_CHECK_FUNCS(getresuid getresgid)
1680
1681 # Check for gethostbyname_r in all its glorious incompatible versions.
1682 #   (This logic is based on that in Python's configure.in)
1683 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1684   [Define this if you have any gethostbyname_r()])
1685
1686 AC_CHECK_FUNC(gethostbyname_r, [
1687   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1688   OLD_CFLAGS=$CFLAGS
1689   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1690   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1691 #include <netdb.h>
1692   ]], [[
1693     char *cp1, *cp2;
1694     struct hostent *h1, *h2;
1695     int i1, i2;
1696     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1697   ]])],[
1698     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1699     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1700      [Define this if gethostbyname_r takes 6 arguments])
1701     AC_MSG_RESULT(6)
1702   ], [
1703     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1704 #include <netdb.h>
1705     ]], [[
1706       char *cp1, *cp2;
1707       struct hostent *h1;
1708       int i1, i2;
1709       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1710     ]])], [
1711       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1712       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1713         [Define this if gethostbyname_r takes 5 arguments])
1714       AC_MSG_RESULT(5)
1715    ], [
1716       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1717 #include <netdb.h>
1718      ]], [[
1719        char *cp1;
1720        struct hostent *h1;
1721        struct hostent_data hd;
1722        (void) gethostbyname_r(cp1,h1,&hd);
1723      ]])], [
1724        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1725        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1726          [Define this if gethostbyname_r takes 3 arguments])
1727        AC_MSG_RESULT(3)
1728      ], [
1729        AC_MSG_RESULT(0)
1730      ])
1731   ])
1732  ])
1733  CFLAGS=$OLD_CFLAGS
1734 ])
1735
1736 AC_CACHE_CHECK([whether the C compiler supports __func__],
1737   tor_cv_have_func_macro,
1738   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1739 #include <stdio.h>
1740 int main(int c, char **v) { puts(__func__); }])],
1741   tor_cv_have_func_macro=yes,
1742   tor_cv_have_func_macro=no))
1743
1744 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1745   tor_cv_have_FUNC_macro,
1746   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1747 #include <stdio.h>
1748 int main(int c, char **v) { puts(__FUNC__); }])],
1749   tor_cv_have_FUNC_macro=yes,
1750   tor_cv_have_FUNC_macro=no))
1751
1752 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1753   tor_cv_have_FUNCTION_macro,
1754   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1755 #include <stdio.h>
1756 int main(int c, char **v) { puts(__FUNCTION__); }])],
1757   tor_cv_have_FUNCTION_macro=yes,
1758   tor_cv_have_FUNCTION_macro=no))
1759
1760 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1761   tor_cv_have_environ_declared,
1762   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1763 #ifdef HAVE_UNISTD_H
1764 #include <unistd.h>
1765 #endif
1766 #include <stdlib.h>
1767 int main(int c, char **v) { char **t = environ; }])],
1768   tor_cv_have_environ_declared=yes,
1769   tor_cv_have_environ_declared=no))
1770
1771 if test "$tor_cv_have_func_macro" = "yes"; then
1772   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1773 fi
1774
1775 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1776   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1777 fi
1778
1779 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1780   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1781            [Defined if the compiler supports __FUNCTION__])
1782 fi
1783
1784 if test "$tor_cv_have_environ_declared" = "yes"; then
1785   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1786            [Defined if we have extern char **environ already declared])
1787 fi
1788
1789 # $prefix stores the value of the --prefix command line option, or
1790 # NONE if the option wasn't set.  In the case that it wasn't set, make
1791 # it be the default, so that we can use it to expand directories now.
1792 if test "x$prefix" = "xNONE"; then
1793   prefix=$ac_default_prefix
1794 fi
1795
1796 # and similarly for $exec_prefix
1797 if test "x$exec_prefix" = "xNONE"; then
1798   exec_prefix=$prefix
1799 fi
1800
1801 if test "x$BUILDDIR" = "x"; then
1802   BUILDDIR=`pwd`
1803 fi
1804 AC_SUBST(BUILDDIR)
1805 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1806 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1807
1808 if test "x$CONFDIR" = "x"; then
1809   CONFDIR=`eval echo $sysconfdir/tor`
1810 fi
1811 AC_SUBST(CONFDIR)
1812 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1813 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1814
1815 BINDIR=`eval echo $bindir`
1816 AC_SUBST(BINDIR)
1817 LOCALSTATEDIR=`eval echo $localstatedir`
1818 AC_SUBST(LOCALSTATEDIR)
1819
1820 if test "$bwin32" = "true"; then
1821   # Test if the linker supports the --nxcompat and --dynamicbase options
1822   # for Windows
1823   save_LDFLAGS="$LDFLAGS"
1824   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1825   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1826   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1827     [AC_MSG_RESULT([yes])]
1828     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1829     [AC_MSG_RESULT([no])]
1830   )
1831   LDFLAGS="$save_LDFLAGS"
1832 fi
1833
1834 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1835 # than autoconf's macros like.
1836 if test "$GCC" = "yes"; then
1837   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1838   # accident waiting to happen.
1839   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1840 else
1841   # Override optimization level for non-gcc compilers
1842   CFLAGS="$CFLAGS -O"
1843   enable_gcc_warnings=no
1844   enable_gcc_warnings_advisory=no
1845 fi
1846
1847 # Warnings implies advisory-warnings and -Werror.
1848 if test "$enable_gcc_warnings" = "yes"; then
1849   enable_gcc_warnings_advisory=yes
1850   enable_fatal_warnings=yes
1851 fi
1852
1853 # OS X Lion started deprecating the system openssl. Let's just disable
1854 # all deprecation warnings on OS X. Also, to potentially make the binary
1855 # a little smaller, let's enable dead_strip.
1856 case "$host_os" in
1857
1858  darwin*)
1859     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1860     LDFLAGS="$LDFLAGS -dead_strip" ;;
1861 esac
1862
1863 # Add some more warnings which we use in development but not in the
1864 # released versions.  (Some relevant gcc versions can't handle these.)
1865 #
1866 # Note that we have to do this near the end  of the autoconf process, or
1867 # else we may run into problems when these warnings hit on the testing C
1868 # programs that autoconf wants to build.
1869 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1870
1871   case "$host" in
1872     *-*-openbsd* | *-*-bitrig*)
1873       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1874       # That's fine, except that the headers don't pass -Wredundant-decls.
1875       # Therefore, let's disable -Wsystem-headers when we're building
1876       # with maximal warnings on OpenBSD.
1877       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1878   esac
1879
1880   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1881   # have it work better.
1882   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1883
1884   # This warning was added in gcc 4.3, but it appears to generate
1885   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1886   #CFLAGS="$CFLAGS -Wlogical-op"
1887
1888   m4_foreach_w([warning_flag], [
1889      -Waddress
1890      -Waddress-of-array-temporary
1891      -Waddress-of-temporary
1892      -Wambiguous-macro
1893      -Wanonymous-pack-parens
1894      -Warc
1895      -Warc-abi
1896      -Warc-bridge-casts-disallowed-in-nonarc
1897      -Warc-maybe-repeated-use-of-weak
1898      -Warc-performSelector-leaks
1899      -Warc-repeated-use-of-weak
1900      -Warray-bounds
1901      -Warray-bounds-pointer-arithmetic
1902      -Wasm
1903      -Wasm-operand-widths
1904      -Watomic-properties
1905      -Watomic-property-with-user-defined-accessor
1906      -Wauto-import
1907      -Wauto-storage-class
1908      -Wauto-var-id
1909      -Wavailability
1910      -Wbackslash-newline-escape
1911      -Wbad-array-new-length
1912      -Wbind-to-temporary-copy
1913      -Wbitfield-constant-conversion
1914      -Wbool-conversion
1915      -Wbool-conversions
1916      -Wbuiltin-requires-header
1917      -Wchar-align
1918      -Wcompare-distinct-pointer-types
1919      -Wcomplex-component-init
1920      -Wconditional-type-mismatch
1921      -Wconfig-macros
1922      -Wconstant-conversion
1923      -Wconstant-logical-operand
1924      -Wconstexpr-not-const
1925      -Wcustom-atomic-properties
1926      -Wdangling-field
1927      -Wdangling-initializer-list
1928      -Wdate-time
1929      -Wdelegating-ctor-cycles
1930      -Wdeprecated-implementations
1931      -Wdeprecated-register
1932      -Wdirect-ivar-access
1933      -Wdiscard-qual
1934      -Wdistributed-object-modifiers
1935      -Wdivision-by-zero
1936      -Wdollar-in-identifier-extension
1937      -Wdouble-promotion
1938      -Wduplicate-decl-specifier
1939      -Wduplicate-enum
1940      -Wduplicate-method-arg
1941      -Wduplicate-method-match
1942      -Wduplicated-cond
1943      -Wdynamic-class-memaccess
1944      -Wembedded-directive
1945      -Wempty-translation-unit
1946      -Wenum-conversion
1947      -Wexit-time-destructors
1948      -Wexplicit-ownership-type
1949      -Wextern-initializer
1950      -Wextra
1951      -Wextra-semi
1952      -Wextra-tokens
1953      -Wflexible-array-extensions
1954      -Wfloat-conversion
1955      -Wformat-non-iso
1956      -Wfour-char-constants
1957      -Wgcc-compat
1958      -Wglobal-constructors
1959      -Wgnu-array-member-paren-init
1960      -Wgnu-designator
1961      -Wgnu-static-float-init
1962      -Wheader-guard
1963      -Wheader-hygiene
1964      -Widiomatic-parentheses
1965      -Wignored-attributes
1966      -Wimplicit-atomic-properties
1967      -Wimplicit-conversion-floating-point-to-bool
1968      -Wimplicit-exception-spec-mismatch
1969      -Wimplicit-fallthrough
1970      -Wimplicit-fallthrough-per-function
1971      -Wimplicit-retain-self
1972      -Wimport-preprocessor-directive-pedantic
1973      -Wincompatible-library-redeclaration
1974      -Wincompatible-pointer-types-discards-qualifiers
1975      -Wincomplete-implementation
1976      -Wincomplete-module
1977      -Wincomplete-umbrella
1978      -Winit-self
1979      -Wint-conversions
1980      -Wint-to-void-pointer-cast
1981      -Winteger-overflow
1982      -Winvalid-constexpr
1983      -Winvalid-iboutlet
1984      -Winvalid-noreturn
1985      -Winvalid-pp-token
1986      -Winvalid-source-encoding
1987      -Winvalid-token-paste
1988      -Wknr-promoted-parameter
1989      -Wlanguage-extension-token
1990      -Wlarge-by-value-copy
1991      -Wliteral-conversion
1992      -Wliteral-range
1993      -Wlocal-type-template-args
1994      -Wlogical-op
1995      -Wloop-analysis
1996      -Wmain-return-type
1997      -Wmalformed-warning-check
1998      -Wmethod-signatures
1999      -Wmicrosoft
2000      -Wmicrosoft-exists
2001      -Wmismatched-parameter-types
2002      -Wmismatched-return-types
2003      -Wmissing-field-initializers
2004      -Wmissing-format-attribute
2005      -Wmissing-noreturn
2006      -Wmissing-selector-name
2007      -Wmissing-sysroot
2008      -Wmissing-variable-declarations
2009      -Wmodule-conflict
2010      -Wnested-anon-types
2011      -Wnewline-eof
2012      -Wnon-literal-null-conversion
2013      -Wnon-pod-varargs
2014      -Wnonportable-cfstrings
2015      -Wnormalized=id
2016      -Wnull-arithmetic
2017      -Wnull-character
2018      -Wnull-conversion
2019      -Wnull-dereference
2020      -Wout-of-line-declaration
2021      -Wover-aligned
2022      -Woverlength-strings
2023      -Woverride-init
2024      -Woverriding-method-mismatch
2025      -Wpointer-type-mismatch
2026      -Wpredefined-identifier-outside-function
2027      -Wprotocol-property-synthesis-ambiguity
2028      -Wreadonly-iboutlet-property
2029      -Wreadonly-setter-attrs
2030      -Wreceiver-expr
2031      -Wreceiver-forward-class
2032      -Wreceiver-is-weak
2033      -Wreinterpret-base-class
2034      -Wrequires-super-attribute
2035      -Wreserved-user-defined-literal
2036      -Wreturn-stack-address
2037      -Wsection
2038      -Wselector-type-mismatch
2039      -Wsentinel
2040      -Wserialized-diagnostics
2041      -Wshadow
2042      -Wshift-count-negative
2043      -Wshift-count-overflow
2044      -Wshift-negative-value
2045      -Wshift-overflow=2
2046      -Wshift-sign-overflow
2047      -Wshorten-64-to-32
2048      -Wsizeof-array-argument
2049      -Wsource-uses-openmp
2050      -Wstatic-float-init
2051      -Wstatic-in-inline
2052      -Wstatic-local-in-inline
2053      -Wstrict-overflow=1
2054      -Wstring-compare
2055      -Wstring-conversion
2056      -Wstrlcpy-strlcat-size
2057      -Wstrncat-size
2058      -Wsuggest-attribute=format
2059      -Wsuggest-attribute=noreturn
2060      -Wsuper-class-method-mismatch
2061      -Wswitch-bool
2062      -Wsync-nand
2063      -Wtautological-constant-out-of-range-compare
2064      -Wtentative-definition-incomplete-type
2065      -Wtrampolines
2066      -Wtype-safety
2067      -Wtypedef-redefinition
2068      -Wtypename-missing
2069      -Wundefined-inline
2070      -Wundefined-internal
2071      -Wundefined-reinterpret-cast
2072      -Wunicode
2073      -Wunicode-whitespace
2074      -Wunknown-warning-option
2075      -Wunnamed-type-template-args
2076      -Wunneeded-member-function
2077      -Wunsequenced
2078      -Wunsupported-visibility
2079      -Wunused-but-set-parameter
2080      -Wunused-but-set-variable
2081      -Wunused-command-line-argument
2082      -Wunused-const-variable=2
2083      -Wunused-exception-parameter
2084      -Wunused-local-typedefs
2085      -Wunused-member-function
2086      -Wunused-sanitize-argument
2087      -Wunused-volatile-lvalue
2088      -Wuser-defined-literals
2089      -Wvariadic-macros
2090      -Wvector-conversion
2091      -Wvector-conversions
2092      -Wvexing-parse
2093      -Wvisibility
2094      -Wvla-extension
2095      -Wzero-length-array
2096   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
2097
2098 dnl    We should re-enable this in some later version.  Clang doesn't
2099 dnl    mind, but it causes trouble with GCC.
2100 dnl     -Wstrict-overflow=2
2101
2102 dnl    These seem to require annotations that we don't currently use,
2103 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2104 dnl     -Wthread-safety
2105 dnl     -Wthread-safety-analysis
2106 dnl     -Wthread-safety-attributes
2107 dnl     -Wthread-safety-beta
2108 dnl     -Wthread-safety-precise
2109
2110   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2111   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2112   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2113   CFLAGS="$CFLAGS -Wwrite-strings"
2114   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2115   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
2116   CFLAGS="$CFLAGS -Wunused-parameter "
2117   # These interfere with building main() { return 0; }, which autoconf
2118   # likes to use as its default program.
2119   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
2120
2121   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2122     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2123   fi
2124   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2125     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2126   fi
2127
2128   if test "x$enable_fatal_warnings" = "xyes"; then
2129     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2130     # default autoconf programs are full of errors.
2131     CFLAGS="$CFLAGS -Werror"
2132   fi
2133
2134 fi
2135
2136 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2137    case "$host_os" in
2138     darwin*)
2139       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2140    esac
2141 fi
2142
2143 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2144
2145 AC_CONFIG_FILES([
2146         Doxyfile
2147         Makefile
2148         contrib/dist/suse/tor.sh
2149         contrib/operator-tools/tor.logrotate
2150         contrib/dist/tor.sh
2151         contrib/dist/torctl
2152         contrib/dist/tor.service
2153         src/config/torrc.sample
2154         src/config/torrc.minimal
2155         src/rust/.cargo/config
2156         scripts/maint/checkOptionDocs.pl
2157         scripts/maint/updateVersions.pl
2158 ])
2159
2160 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2161   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2162   for file in $regular_mans ; do
2163     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2164       echo "==================================";
2165       echo;
2166       echo "Building Tor has failed since manpages cannot be built.";
2167       echo;
2168       echo "You need asciidoc installed to be able to build the manpages.";
2169       echo "To build without manpages, use the --disable-asciidoc argument";
2170       echo "when calling configure.";
2171       echo;
2172       echo "==================================";
2173       exit 1;
2174     fi
2175   done
2176 fi
2177
2178 if test "$fragile_hardening" = "yes"; then
2179   AC_MSG_WARN([
2180
2181 ============
2182 Warning!  Building Tor with --enable-fragile-hardening (also known as
2183 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2184 other kinds of attacks easier. A Tor instance build with this option will be
2185 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2186 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2187 denial of service attacks. For more information, see
2188 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2189 ============
2190   ])
2191 fi
2192
2193 AC_OUTPUT