configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2019, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.4.0.5-dev])
   8 AC_CONFIG_SRCDIR([src/app/main/tor_main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # DO NOT EDIT THIS DEFINITION BY HAND UNLESS YOU KNOW WHAT YOU'RE DOING.
  12 #
  13 # The update_versions.py script updates this definition when the
  14 # version number changes.  Tor uses it to make sure that it
  15 # only shuts down for missing "required protocols" when those protocols
  16 # are listed as required by a consensus after this date.
  17 AC_DEFINE(APPROX_RELEASE_DATE, ["2019-05-02"], # for 0.4.0.5-dev
  18           [Approximate date when this software was released. (Updated when the version changes.)])
  19
  20 # "foreign" means we don't follow GNU package layout standards
  21 # "1.11" means we require automake version 1.11 or newer
  22 # "subdir-objects" means put .o files in the same directory as the .c files
  23 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  24
  25 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  26 AC_CONFIG_HEADERS([orconfig.h])
  27
  28 AC_USE_SYSTEM_EXTENSIONS
  29 AC_CANONICAL_HOST
  30
  31 PKG_PROG_PKG_CONFIG
  32
  33 AC_ARG_ENABLE(openbsd-malloc,
  34    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only. Deprecated: see --with-malloc]))
  35 AC_ARG_ENABLE(static-openssl,
  36    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  37 AC_ARG_ENABLE(static-libevent,
  38    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  39 AC_ARG_ENABLE(static-zlib,
  40    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  41 AC_ARG_ENABLE(static-tor,
  42    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  43 AC_ARG_ENABLE(unittests,
  44    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  45 AC_ARG_ENABLE(coverage,
  46    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  47 AC_ARG_ENABLE(asserts-in-tests,
  48    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  49 AC_ARG_ENABLE(system-torrc,
  50    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  51 AC_ARG_ENABLE(libfuzzer,
  52    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  53 AC_ARG_ENABLE(oss-fuzz,
  54    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  55 AC_ARG_ENABLE(memory-sentinels,
  56    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  57 AC_ARG_ENABLE(rust,
  58    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  59 AC_ARG_ENABLE(cargo-online-mode,
  60    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  61 AC_ARG_ENABLE(restart-debugging,
  62    AS_HELP_STRING(--enable-restart-debugging, [Build Tor with support for debugging in-process restart. Developers only.]))
  63 AC_ARG_ENABLE(zstd-advanced-apis,
  64    AS_HELP_STRING(--disable-zstd-advanced-apis, [Build without support for zstd's "static-only" APIs.]))
  65 AC_ARG_ENABLE(nss,
  66    AS_HELP_STRING(--enable-nss, [Use Mozilla's NSS TLS library. (EXPERIMENTAL)]))
  67 AC_ARG_ENABLE(pic,
  68    AS_HELP_STRING(--enable-pic, [Build Tor's binaries as position-independent code, suitable to link as a library.]))
  69
  70 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  71     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  72 fi
  73
  74 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  75 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  76 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  77 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  78 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  79 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  80 AM_CONDITIONAL(USE_NSS, test "x$enable_nss" = "xyes")
  81 AM_CONDITIONAL(USE_OPENSSL, test "x$enable_nss" != "xyes")
  82
  83 if test "x$enable_nss" = "xyes"; then
  84   AC_DEFINE(ENABLE_NSS, 1,
  85             [Defined if we're building with NSS.])
  86 else
  87   AC_DEFINE(ENABLE_OPENSSL, 1,
  88             [Defined if we're building with OpenSSL or LibreSSL])
  89 fi
  90
  91 if test "$enable_static_tor" = "yes"; then
  92   enable_static_libevent="yes";
  93   enable_static_openssl="yes";
  94   enable_static_zlib="yes";
  95   CFLAGS="$CFLAGS -static"
  96 fi
  97
  98 if test "$enable_system_torrc" = "no"; then
  99   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
 100             [Defined if we're not going to look for a torrc in SYSCONF])
 101 fi
 102
 103 if test "$enable_memory_sentinels" = "no"; then
 104   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
 105            [Defined if we're turning off memory safety code to look for bugs])
 106 fi
 107
 108 AC_ARG_ENABLE(asciidoc,
 109      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
 110      [case "${enableval}" in
 111         "yes") asciidoc=true ;;
 112         "no")  asciidoc=false ;;
 113         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
 114       esac], [asciidoc=true])
 115
 116 # systemd notify support
 117 AC_ARG_ENABLE(systemd,
 118       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 119       [case "${enableval}" in
 120         "yes") systemd=true ;;
 121         "no")  systemd=false ;;
 122         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 123       esac], [systemd=auto])
 124
 125 if test "$enable_restart_debugging" = "yes"; then
 126   AC_DEFINE(ENABLE_RESTART_DEBUGGING, 1,
 127             [Defined if we're building with support for in-process restart debugging.])
 128 fi
 129
 130 if test "$enable_zstd_advanced_apis" != "no"; then
 131    AC_DEFINE(ENABLE_ZSTD_ADVANCED_APIS, 1,
 132              [Defined if we're going to try to use zstd's "static-only" APIs.])
 133 fi
 134
 135 # systemd support
 136 if test "x$enable_systemd" = "xno"; then
 137     have_systemd=no;
 138 else
 139     PKG_CHECK_MODULES(SYSTEMD,
 140         [libsystemd-daemon],
 141         have_systemd=yes,
 142         have_systemd=no)
 143     if test "x$have_systemd" = "xno"; then
 144         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 145         PKG_CHECK_MODULES(SYSTEMD,
 146             [libsystemd],
 147             have_systemd=yes,
 148             have_systemd=no)
 149     fi
 150 fi
 151
 152 if test "x$have_systemd" = "xyes"; then
 153     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 154     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 155     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 156     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 157          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 158 fi
 159 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 160 AC_SUBST(TOR_SYSTEMD_LIBS)
 161
 162 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 163     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 164 fi
 165
 166 case "$host" in
 167    *-*-solaris* )
 168      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 169      ;;
 170 esac
 171
 172 AC_ARG_ENABLE(gcc-warnings,
 173      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 174 AC_ARG_ENABLE(fatal-warnings,
 175      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 176 AC_ARG_ENABLE(gcc-warnings-advisory,
 177      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 178
 179 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 180 AC_ARG_ENABLE(gcc-hardening,
 181     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 182
 183 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 184 AC_ARG_ENABLE(expensive-hardening,
 185     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 186 AC_ARG_ENABLE(fragile-hardening,
 187     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 188 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 189   fragile_hardening="yes"
 190   AC_DEFINE(DEBUG_SMARTLIST, 1, [Enable smartlist debugging])
 191 fi
 192
 193 dnl Linker hardening options
 194 dnl Currently these options are ELF specific - you can't use this with MacOSX
 195 AC_ARG_ENABLE(linker-hardening,
 196     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 197
 198 AC_ARG_ENABLE(local-appdata,
 199    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 200 if test "$enable_local_appdata" = "yes"; then
 201   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 202             [Defined if we default to host local appdata paths on Windows])
 203 fi
 204
 205 AC_ARG_ENABLE(tool-name-check,
 206      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 207
 208 AC_ARG_ENABLE(seccomp,
 209      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 210
 211 AC_ARG_ENABLE(libscrypt,
 212      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 213
 214 dnl Enable event tracing which are transformed to debug log statement.
 215 AC_ARG_ENABLE(event-tracing-debug,
 216      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 217 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 218
 219 if test x$enable_event_tracing_debug = xyes; then
 220   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 221   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 222 fi
 223
 224 dnl Enable Android only features.
 225 AC_ARG_ENABLE(android,
 226      AS_HELP_STRING(--enable-android, [build with Android features enabled]))
 227 AM_CONDITIONAL([USE_ANDROID], [test "x$enable_android" = "xyes"])
 228
 229 if test "x$enable_android" = "xyes"; then
 230   AC_DEFINE([USE_ANDROID], [1], [Compile with Android specific features enabled])
 231
 232   dnl Check if the Android log library is available.
 233   AC_CHECK_HEADERS([android/log.h])
 234   AC_SEARCH_LIBS(__android_log_write, [log])
 235
 236 fi
 237
 238 dnl ---
 239 dnl Tor modules options. These options are namespaced with --disable-module-XXX
 240 dnl ---
 241
 242 dnl All our modules.
 243 m4_define(MODULES, dirauth)
 244
 245 dnl Directory Authority module.
 246 AC_ARG_ENABLE([module-dirauth],
 247               AS_HELP_STRING([--disable-module-dirauth],
 248                              [Do not build tor with the dirauth module]),
 249               [], dnl Action if-given
 250               AC_DEFINE([HAVE_MODULE_DIRAUTH], [1],
 251                         [Compile with Directory Authority feature support]))
 252 AM_CONDITIONAL(BUILD_MODULE_DIRAUTH, [test "x$enable_module_dirauth" != "xno"])
 253
 254 dnl Helper variables.
 255 TOR_MODULES_ALL_ENABLED=
 256 AC_DEFUN([ADD_MODULE], [
 257     MODULE=m4_toupper($1)
 258     TOR_MODULES_ALL_ENABLED="${TOR_MODULES_ALL_ENABLED} -DHAVE_MODULE_${MODULE}=1"
 259 ])
 260 m4_foreach_w([module], MODULES, [ADD_MODULE([module])])
 261 AC_SUBST(TOR_MODULES_ALL_ENABLED)
 262
 263 dnl check for the correct "ar" when cross-compiling.
 264 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 265 dnl    so kludge up a replacement for the case where it isn't there yet.)
 266 m4_ifdef([AM_PROG_AR],
 267          [AM_PROG_AR],
 268          [AN_MAKEVAR([AR], [AC_PROG_AR])
 269           AN_PROGRAM([ar], [AC_PROG_AR])
 270           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 271           AC_PROG_AR])
 272
 273 dnl Check whether the above macro has settled for a simply named tool even
 274 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 275 dnl because that will find any cc on the system, not only the cross-compiler,
 276 dnl and then verify that a binary built with this compiler runs on the
 277 dnl build system. It will then come to the false conclusion that we're not
 278 dnl cross-compiling.
 279 if test "x$enable_tool_name_check" != "xno"; then
 280     if test "x$ac_tool_warned" = "xyes"; then
 281         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 282         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 283                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 284         fi
 285 fi
 286
 287 AC_PROG_CC
 288 AC_PROG_CPP
 289 AC_PROG_MAKE_SET
 290 AC_PROG_RANLIB
 291 AC_PROG_SED
 292
 293 AC_ARG_VAR([PERL], [path to Perl binary])
 294 AC_CHECK_PROGS([PERL], [perl])
 295 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 296
 297 dnl check for asciidoc and a2x
 298 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 299 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 300
 301 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 302
 303 AM_PROG_CC_C_O
 304 AC_PROG_CC_C99
 305
 306 AC_ARG_VAR([PYTHON], [path to Python binary])
 307 AC_CHECK_PROGS(PYTHON, [ \
 308         python3 \
 309         python3.8 python3.7 python3.6 python3.5 python3.4 \
 310         python \
 311         python2 python2.7])
 312 if test "x$PYTHON" = "x"; then
 313   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 314 fi
 315 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 316
 317 dnl List all external rust crates we depend on here. Include the version
 318 rust_crates=" \
 319     digest-0.7.2 \
 320     libc-0.2.39 \
 321 "
 322 AC_SUBST(rust_crates)
 323
 324 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 325 AC_C_FLEXIBLE_ARRAY_MEMBER
 326 ], [
 327  dnl Maybe we've got an old autoconf...
 328  AC_CACHE_CHECK([for flexible array members],
 329      tor_cv_c_flexarray,
 330      [AC_COMPILE_IFELSE(
 331        AC_LANG_PROGRAM([
 332  struct abc { int a; char b[]; };
 333 ], [
 334  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 335  def->b[0] = 33;
 336 ]),
 337   [tor_cv_c_flexarray=yes],
 338   [tor_cv_c_flexarray=no])])
 339  if test "$tor_cv_flexarray" = "yes"; then
 340    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 341  else
 342    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 343  fi
 344 ])
 345
 346 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 347       tor_cv_c_c99_decl,
 348       [AC_COMPILE_IFELSE(
 349          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 350          [tor_cv_c_c99_decl=yes],
 351          [tor_cv_c_c99_decl=no] )])
 352 if test "$tor_cv_c_c99_decl" != "yes"; then
 353   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 354 fi
 355
 356 AC_CACHE_CHECK([for working C99 designated initializers],
 357       tor_cv_c_c99_designated_init,
 358       [AC_COMPILE_IFELSE(
 359          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 360                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 361          [tor_cv_c_c99_designated_init=yes],
 362          [tor_cv_c_c99_designated_init=no] )])
 363
 364 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 365   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 366 fi
 367
 368 TORUSER=_tor
 369 AC_ARG_WITH(tor-user,
 370         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 371         [
 372            TORUSER=$withval
 373         ]
 374 )
 375 AC_SUBST(TORUSER)
 376
 377 TORGROUP=_tor
 378 AC_ARG_WITH(tor-group,
 379         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 380         [
 381            TORGROUP=$withval
 382         ]
 383 )
 384 AC_SUBST(TORGROUP)
 385
 386
 387 dnl If _WIN32 is defined and non-zero, we are building for win32
 388 AC_MSG_CHECKING([for win32])
 389 AC_RUN_IFELSE([AC_LANG_SOURCE([
 390 int main(int c, char **v) {
 391 #ifdef _WIN32
 392 #if _WIN32
 393   return 0;
 394 #else
 395   return 1;
 396 #endif
 397 #else
 398   return 2;
 399 #endif
 400 }])],
 401 bwin32=true; AC_MSG_RESULT([yes]),
 402 bwin32=false; AC_MSG_RESULT([no]),
 403 bwin32=cross; AC_MSG_RESULT([cross])
 404 )
 405
 406 if test "$bwin32" = "cross"; then
 407 AC_MSG_CHECKING([for win32 (cross)])
 408 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 409 #ifdef _WIN32
 410 int main(int c, char **v) {return 0;}
 411 #else
 412 #error
 413 int main(int c, char **v) {return x(y);}
 414 #endif
 415 ])],
 416 bwin32=true; AC_MSG_RESULT([yes]),
 417 bwin32=false; AC_MSG_RESULT([no]))
 418 fi
 419
 420 AH_BOTTOM([
 421 #ifdef _WIN32
 422 /* Defined to access windows functions and definitions for >=WinXP */
 423 # ifndef WINVER
 424 #  define WINVER 0x0501
 425 # endif
 426
 427 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 428 # ifndef _WIN32_WINNT
 429 #  define _WIN32_WINNT 0x0501
 430 # endif
 431
 432 /* Defined to avoid including some windows headers as part of Windows.h */
 433 # ifndef WIN32_LEAN_AND_MEAN
 434 #  define WIN32_LEAN_AND_MEAN 1
 435 # endif
 436 #endif
 437 ])
 438
 439 AM_CONDITIONAL(WIN32, test "x$bwin32" = "xtrue")
 440 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 441 AM_CONDITIONAL(BUILD_LIBTORRUNNER, test "x$bwin32" != "xtrue")
 442
 443 dnl Enable C99 when compiling with MIPSpro
 444 AC_MSG_CHECKING([for MIPSpro compiler])
 445 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 446 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 447 #error
 448   return x(y);
 449 #endif
 450 ])],
 451 bmipspro=false; AC_MSG_RESULT(no),
 452 bmipspro=true; AC_MSG_RESULT(yes))
 453
 454 if test "$bmipspro" = "true"; then
 455   CFLAGS="$CFLAGS -c99"
 456 fi
 457
 458 AC_C_BIGENDIAN
 459
 460 AC_ARG_VAR([TOR_RUST_TARGET], [Rust target, must be specified when cross-compiling (HOST != BUILD). example: i686-pc-windows-gnu])
 461
 462 if test "x$enable_rust" = "xyes"; then
 463   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 464   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 465   if test "x$RUSTC" = "xno"; then
 466     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 467   fi
 468
 469   AC_ARG_VAR([CARGO], [path to the cargo binary])
 470   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 471   if test "x$CARGO" = "xno"; then
 472     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 473   fi
 474
 475   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 476   if test "x$enable_fatal_warnings" = "xyes"; then
 477     RUST_WARN=
 478   else
 479     RUST_WARN=#
 480   fi
 481   if test "x$enable_cargo_online_mode" = "xyes"; then
 482     CARGO_ONLINE=
 483     RUST_DL=#
 484   else
 485     CARGO_ONLINE=--frozen
 486     RUST_DL=
 487
 488     dnl When we're not allowed to touch the network, we need crate dependencies
 489     dnl locally available.
 490     AC_MSG_CHECKING([rust crate dependencies])
 491     AC_ARG_VAR([TOR_RUST_DEPENDENCIES], [path to directory with local crate mirror])
 492     if test "x$TOR_RUST_DEPENDENCIES" = "x"; then
 493       TOR_RUST_DEPENDENCIES="${srcdir}/src/ext/rust/crates"
 494     fi
 495     dnl Check whether the path exists before we try to cd into it.
 496     if test ! -d "$TOR_RUST_DEPENDENCIES"; then
 497       AC_MSG_ERROR([Rust dependency directory $TOR_RUST_DEPENDENCIES does not exist. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 498       ERRORED=1
 499     fi
 500     dnl Make the path absolute, since we'll be using it from within a
 501     dnl subdirectory.
 502     TOR_RUST_DEPENDENCIES=$(cd "$TOR_RUST_DEPENDENCIES" ; pwd)
 503
 504     for dep in $rust_crates; do
 505       if test ! -d "$TOR_RUST_DEPENDENCIES"/"$dep"; then
 506         AC_MSG_ERROR([Failure to find rust dependency $TOR_RUST_DEPENDENCIES/$dep. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 507         ERRORED=1
 508       fi
 509     done
 510     if test "x$ERRORED" = "x"; then
 511       AC_MSG_RESULT([yes])
 512     fi
 513   fi
 514
 515   dnl For now both MSVC and MinGW rust libraries will output static libs with
 516   dnl the MSVC naming convention.
 517   if test "$bwin32" = "true"; then
 518     tor_rust_static_name=tor_rust.lib
 519   else
 520     tor_rust_static_name=libtor_rust.a
 521   fi
 522
 523   AC_CANONICAL_BUILD
 524
 525   if test -n "$TOR_RUST_TARGET"; then
 526     if test "$host" = "$build"; then
 527       AC_MSG_ERROR([HOST = BUILD is invalid if TOR_RUST_TARGET is specified, see configure --help for more information.])
 528     fi
 529     RUST_TARGET_PROP="target = '$TOR_RUST_TARGET'"
 530     TOR_RUST_LIB_PATH="src/rust/target/$TOR_RUST_TARGET/release/$tor_rust_static_name"
 531   else
 532     if test "$host" != "$build"; then
 533       AC_MSG_ERROR([TOR_RUST_TARGET must be specified when cross-compiling with Rust enabled.])
 534     fi
 535     RUST_TARGET_PROP=
 536     TOR_RUST_LIB_PATH="src/rust/target/release/$tor_rust_static_name"
 537   fi
 538
 539   AC_SUBST(RUST_TARGET_PROP)
 540   AC_SUBST(TOR_RUST_LIB_PATH)
 541   AC_SUBST(CARGO_ONLINE)
 542   AC_SUBST(RUST_WARN)
 543   AC_SUBST(RUST_DL)
 544
 545   dnl Let's check the rustc version, too
 546   AC_MSG_CHECKING([rust version])
 547   RUSTC_VERSION=`$RUSTC --version`
 548   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 549   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 550   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 551     AC_MSG_ERROR([rustc version couldn't be identified])
 552   fi
 553   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 554     AC_MSG_ERROR([rustc must be at least version 1.14])
 555   fi
 556   AC_MSG_RESULT([$RUSTC_VERSION])
 557 fi
 558
 559 AC_SEARCH_LIBS(socket, [socket network])
 560 AC_SEARCH_LIBS(gethostbyname, [nsl])
 561 AC_SEARCH_LIBS(dlopen, [dl])
 562 AC_SEARCH_LIBS(inet_aton, [resolv])
 563 AC_SEARCH_LIBS(backtrace, [execinfo])
 564 saved_LIBS="$LIBS"
 565 AC_SEARCH_LIBS([clock_gettime], [rt])
 566 if test "$LIBS" != "$saved_LIBS"; then
 567    # Looks like we need -lrt for clock_gettime().
 568    have_rt=yes
 569 fi
 570
 571 if test "$bwin32" = "false"; then
 572   AC_SEARCH_LIBS(pthread_create, [pthread])
 573   AC_SEARCH_LIBS(pthread_detach, [pthread])
 574 fi
 575
 576 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 577 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 578
 579 AC_CHECK_FUNCS(
 580         _NSGetEnviron \
 581         RtlSecureZeroMemory \
 582         SecureZeroMemory \
 583         accept4 \
 584         backtrace \
 585         backtrace_symbols_fd \
 586         eventfd \
 587         explicit_bzero \
 588         timingsafe_memcmp \
 589         flock \
 590         ftime \
 591         get_current_dir_name \
 592         getaddrinfo \
 593         getdelim \
 594         getifaddrs \
 595         getline \
 596         getpass \
 597         getrlimit \
 598         gettimeofday \
 599         gmtime_r \
 600         gnu_get_libc_version \
 601         htonll \
 602         inet_aton \
 603         ioctl \
 604         issetugid \
 605         llround \
 606         localtime_r \
 607         lround \
 608         madvise \
 609         memmem \
 610         memset_s \
 611         minherit \
 612         mmap \
 613         pipe \
 614         pipe2 \
 615         prctl \
 616         readpassphrase \
 617         rint \
 618         sigaction \
 619         socketpair \
 620         statvfs \
 621         strncasecmp \
 622         strcasecmp \
 623         strlcat \
 624         strlcpy \
 625         strnlen \
 626         strptime \
 627         strtok_r \
 628         strtoull \
 629         sysconf \
 630         sysctl \
 631         truncate \
 632         uname \
 633         usleep \
 634         vasprintf \
 635         _vscprintf
 636 )
 637
 638 # Apple messed up when they added some functions: they
 639 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 640 # checks.
 641
 642 # We should only probe for these functions if we are sure that we
 643 # are not targeting OS X 10.9 or earlier.
 644 AC_MSG_CHECKING([for a pre-Yosemite OS X build target])
 645 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 646 #ifdef __APPLE__
 647 #  include <AvailabilityMacros.h>
 648 #  ifndef MAC_OS_X_VERSION_10_10
 649 #    define MAC_OS_X_VERSION_10_10 101000
 650 #  endif
 651 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 652 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_10
 653 #      error "Running on Mac OS X 10.9 or earlier"
 654 #    endif
 655 #  endif
 656 #endif
 657 ]], [[]])],
 658    [on_macos_pre_10_10=no ; AC_MSG_RESULT([no])],
 659    [on_macos_pre_10_10=yes; AC_MSG_RESULT([yes])])
 660
 661 if test "$on_macos_pre_10_10" = "no"; then
 662   AC_CHECK_FUNCS(
 663         mach_approximate_time \
 664   )
 665 fi
 666
 667 # We should only probe for these functions if we are sure that we
 668 # are not targeting OSX 10.11 or earlier.
 669 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 670 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 671 #ifdef __APPLE__
 672 #  include <AvailabilityMacros.h>
 673 #  ifndef MAC_OS_X_VERSION_10_12
 674 #    define MAC_OS_X_VERSION_10_12 101200
 675 #  endif
 676 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 677 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 678 #      error "Running on Mac OSX 10.11 or earlier"
 679 #    endif
 680 #  endif
 681 #endif
 682 ]], [[]])],
 683    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 684    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 685
 686 if test "$on_macos_pre_10_12" = "no"; then
 687   AC_CHECK_FUNCS(
 688         clock_gettime \
 689         getentropy \
 690   )
 691 fi
 692
 693 if test "$bwin32" != "true"; then
 694   AC_CHECK_HEADERS(pthread.h)
 695   AC_CHECK_FUNCS(pthread_create)
 696   AC_CHECK_FUNCS(pthread_condattr_setclock)
 697 fi
 698
 699 if test "$bwin32" = "true"; then
 700   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 701 #include <windows.h>
 702 #include <conio.h>
 703 #include <wchar.h>
 704                  ])
 705 fi
 706
 707 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 708   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 709
 710 AC_MSG_CHECKING([whether free(NULL) works])
 711 AC_RUN_IFELSE([AC_LANG_PROGRAM([
 712   #include <stdlib.h>
 713 ], [
 714 char *p = NULL;
 715 free(p);
 716 ])],
 717 [free_null_ok=true; AC_MSG_RESULT(yes)],
 718 [free_null_ok=false; AC_MSG_RESULT(no)],
 719 [free_null_ok=cross; AC_MSG_RESULT(cross)])
 720
 721 if test "$free_null_ok" = "false"; then
 722    AC_MSG_ERROR([Your libc implementation doesn't allow free(NULL), as required by C99.])
 723 fi
 724
 725 dnl ------------------------------------------------------
 726 dnl Where do you live, libevent?  And how do we call you?
 727
 728 if test "$bwin32" = "true"; then
 729   TOR_LIB_WS32=-lws2_32
 730   TOR_LIB_IPHLPAPI=-liphlpapi
 731   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 732   # think it's actually necessary.
 733   TOR_LIB_GDI=-lgdi32
 734   TOR_LIB_USERENV=-luserenv
 735 else
 736   TOR_LIB_WS32=
 737   TOR_LIB_GDI=
 738   TOR_LIB_USERENV=
 739 fi
 740 AC_SUBST(TOR_LIB_WS32)
 741 AC_SUBST(TOR_LIB_GDI)
 742 AC_SUBST(TOR_LIB_IPHLPAPI)
 743 AC_SUBST(TOR_LIB_USERENV)
 744
 745 tor_libevent_pkg_redhat="libevent"
 746 tor_libevent_pkg_debian="libevent-dev"
 747 tor_libevent_devpkg_redhat="libevent-devel"
 748 tor_libevent_devpkg_debian="libevent-dev"
 749
 750 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 751 dnl linking for static builds.
 752 STATIC_LIBEVENT_FLAGS=""
 753 if test "$enable_static_libevent" = "yes"; then
 754     if test "$have_rt" = "yes"; then
 755       STATIC_LIBEVENT_FLAGS=" -lrt "
 756     fi
 757 fi
 758
 759 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 760 #ifdef _WIN32
 761 #include <winsock2.h>
 762 #endif
 763 #include <sys/time.h>
 764 #include <sys/types.h>
 765 #include <event2/event.h>], [
 766 #ifdef _WIN32
 767 #include <winsock2.h>
 768 #endif
 769 struct event_base;
 770 struct event_base *event_base_new(void);
 771 void event_base_free(struct event_base *);],
 772     [
 773 #ifdef _WIN32
 774 {WSADATA d; WSAStartup(0x101,&d); }
 775 #endif
 776 event_base_free(event_base_new());
 777 ], [--with-libevent-dir], [/opt/libevent])
 778
 779 dnl Determine the incantation needed to link libevent.
 780 save_LIBS="$LIBS"
 781 save_LDFLAGS="$LDFLAGS"
 782 save_CPPFLAGS="$CPPFLAGS"
 783
 784 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 785 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 786 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 787
 788 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 789
 790 if test "$enable_static_libevent" = "yes"; then
 791    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 792      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 793    else
 794      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 795    fi
 796 else
 797      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 798        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 799        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 800
 801        if test "$ac_cv_search_event_new" != "none required"; then
 802          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 803        fi
 804        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 805          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 806        fi
 807      else
 808        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 809      fi
 810 fi
 811
 812 dnl Now check for particular libevent functions.
 813 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 814                 evutil_secure_rng_add_bytes \
 815                 evdns_base_get_nameserver_addr \
 816
 817 ])
 818
 819 LIBS="$save_LIBS"
 820 LDFLAGS="$save_LDFLAGS"
 821 CPPFLAGS="$save_CPPFLAGS"
 822
 823 dnl Check that libevent is at least at version 2.0.10, the first stable
 824 dnl release of its series
 825 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 826 AC_MSG_CHECKING([whether Libevent is new enough])
 827 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 828 #include <event2/event.h>
 829 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 830 #error
 831 int x = y(zz);
 832 #else
 833 int x = 1;
 834 #endif
 835 ])], [ AC_MSG_RESULT([yes]) ],
 836    [ AC_MSG_RESULT([no])
 837      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 838
 839 LIBS="$save_LIBS"
 840 LDFLAGS="$save_LDFLAGS"
 841 CPPFLAGS="$save_CPPFLAGS"
 842
 843 AC_SUBST(TOR_LIBEVENT_LIBS)
 844
 845 dnl ------------------------------------------------------
 846 dnl Where do you live, libm?
 847
 848 dnl On some platforms (Haiku/BeOS) the math library is
 849 dnl part of libroot. In which case don't link against lm
 850 TOR_LIB_MATH=""
 851 save_LIBS="$LIBS"
 852 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 853 if test "$ac_cv_search_pow" != "none required"; then
 854     TOR_LIB_MATH="$ac_cv_search_pow"
 855 fi
 856 LIBS="$save_LIBS"
 857 AC_SUBST(TOR_LIB_MATH)
 858
 859 dnl ------------------------------------------------------
 860 dnl Hello, NSS.  You're new around here.
 861 if test "x$enable_nss" = "xyes"; then
 862   PKG_CHECK_MODULES(NSS,
 863      [nss],
 864      [have_nss=yes],
 865      [have_nss=no; AC_MSG_ERROR([You asked for NSS but I can't find it.])])
 866   AC_SUBST(NSS_CFLAGS)
 867   AC_SUBST(NSS_LIBS)
 868 fi
 869
 870 dnl ------------------------------------------------------
 871 dnl Where do you live, openssl?  And how do we call you?
 872
 873 if test "x$enable_nss" != "xyes"; then
 874
 875 tor_openssl_pkg_redhat="openssl"
 876 tor_openssl_pkg_debian="libssl-dev"
 877 tor_openssl_devpkg_redhat="openssl-devel"
 878 tor_openssl_devpkg_debian="libssl-dev"
 879
 880 ALT_openssl_WITHVAL=""
 881 AC_ARG_WITH(ssl-dir,
 882   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 883   [
 884       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 885          ALT_openssl_WITHVAL="$withval"
 886       fi
 887   ])
 888
 889 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 890 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 891     [#include <openssl/ssl.h>
 892      char *getenv(const char *);],
 893     [struct ssl_cipher_st;
 894      unsigned SSL_CIPHER_get_id(const struct ssl_cipher_st *);
 895      char *getenv(const char *);],
 896     dnl This funny-looking test program calls getenv, so that the compiler
 897     dnl will neither make code that call SSL_CIPHER_get_id(NULL) [producing
 898     dnl a crash], nor optimize out the call to SSL_CIPHER_get_id().
 899     dnl We look for SSL_cipher_get_id() because it is present in
 900     dnl OpenSSL >=1.0.1, because it is not deprecated, and because Tor
 901     dnl depends on it.
 902     [if (getenv("THIS_SHOULDNT_BE_SET_X201803")) SSL_CIPHER_get_id((void *)0);], [],
 903     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /opt/openssl])
 904
 905 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 906
 907 if test "$enable_static_openssl" = "yes"; then
 908    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 909      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 910    else
 911      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 912    fi
 913 else
 914      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 915 fi
 916 AC_SUBST(TOR_OPENSSL_LIBS)
 917
 918 dnl Now check for particular openssl functions.
 919 save_LIBS="$LIBS"
 920 save_LDFLAGS="$LDFLAGS"
 921 save_CPPFLAGS="$CPPFLAGS"
 922 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 923 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 924 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 925
 926 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 927 #include <openssl/opensslv.h>
 928 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 929 #error "too old"
 930 #endif
 931    ]], [[]])],
 932    [ : ],
 933    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 934
 935 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 936 #include <openssl/opensslv.h>
 937 #include <openssl/evp.h>
 938 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 939 #error "no ECC"
 940 #endif
 941 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 942 #error "curves unavailable"
 943 #endif
 944    ]], [[]])],
 945    [ : ],
 946    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 947
 948 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 949 [#include <openssl/ssl.h>
 950 ])
 951
 952 AC_CHECK_FUNCS([ \
 953                 ERR_load_KDF_strings \
 954                 SSL_SESSION_get_master_key \
 955                 SSL_get_server_random \
 956                 SSL_get_client_ciphers \
 957                 SSL_get_client_random \
 958                 SSL_CTX_set1_groups_list \
 959                 SSL_CIPHER_find \
 960                 SSL_CTX_set_security_level \
 961                 TLS_method
 962                ])
 963
 964 dnl Check if OpenSSL has scrypt implementation.
 965 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 966
 967 dnl Check if OpenSSL structures are opaque
 968 AC_CHECK_MEMBERS([SSL.state], , ,
 969 [#include <openssl/ssl.h>
 970 ])
 971
 972 AC_CHECK_SIZEOF(SHA_CTX, , [AC_INCLUDES_DEFAULT()
 973 #include <openssl/sha.h>
 974 ])
 975
 976 fi # enable_nss
 977
 978 dnl ======================================================================
 979 dnl Can we use KIST?
 980
 981 dnl Define the set of checks for KIST scheduler support.
 982 AC_DEFUN([CHECK_KIST_SUPPORT],[
 983   dnl KIST needs struct tcp_info and for certain members to exist.
 984   AC_CHECK_MEMBERS(
 985     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
 986     , ,[[#include <netinet/tcp.h>]])
 987   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
 988   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 989                      #include <linux/sockios.h>
 990                      #ifndef SIOCOUTQNSD
 991                      #error
 992                      #endif
 993                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
 994   if test "x$have_siocoutqnsd" = "xyes"; then
 995     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
 996       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
 997         have_kist_support=yes
 998       fi
 999     fi
1000   fi
1001 ])
1002 dnl Now, trigger the check.
1003 CHECK_KIST_SUPPORT
1004 AS_IF([test "x$have_kist_support" = "xyes"],
1005       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
1006                                         on this system])],
1007       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
1008
1009 LIBS="$save_LIBS"
1010 LDFLAGS="$save_LDFLAGS"
1011 CPPFLAGS="$save_CPPFLAGS"
1012
1013 dnl ------------------------------------------------------
1014 dnl Where do you live, zlib?  And how do we call you?
1015
1016 tor_zlib_pkg_redhat="zlib"
1017 tor_zlib_pkg_debian="zlib1g"
1018 tor_zlib_devpkg_redhat="zlib-devel"
1019 tor_zlib_devpkg_debian="zlib1g-dev"
1020
1021 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
1022     [#include <zlib.h>],
1023     [const char * zlibVersion(void);],
1024     [zlibVersion();], [--with-zlib-dir],
1025     [/opt/zlib])
1026
1027 if test "$enable_static_zlib" = "yes"; then
1028    if test "$tor_cv_library_zlib_dir" = "(system)"; then
1029      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
1030  using --enable-static-zlib")
1031    else
1032      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
1033    fi
1034 else
1035      TOR_ZLIB_LIBS="-lz"
1036 fi
1037 AC_SUBST(TOR_ZLIB_LIBS)
1038
1039 dnl ------------------------------------------------------
1040 dnl Where we do we find lzma?
1041
1042 AC_ARG_ENABLE(lzma,
1043       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
1044       [case "${enableval}" in
1045         "yes") lzma=true ;;
1046         "no")  lzma=false ;;
1047         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
1048       esac], [lzma=auto])
1049
1050 if test "x$enable_lzma" = "xno"; then
1051     have_lzma=no;
1052 else
1053     PKG_CHECK_MODULES([LZMA],
1054                       [liblzma],
1055                       have_lzma=yes,
1056                       have_lzma=no)
1057
1058     if test "x$have_lzma" = "xno" ; then
1059         AC_MSG_WARN([Unable to find liblzma.])
1060     fi
1061 fi
1062
1063 if test "x$have_lzma" = "xyes"; then
1064     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
1065     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
1066     TOR_LZMA_LIBS="${LZMA_LIBS}"
1067 fi
1068 AC_SUBST(TOR_LZMA_CFLAGS)
1069 AC_SUBST(TOR_LZMA_LIBS)
1070
1071 dnl ------------------------------------------------------
1072 dnl Where we do we find zstd?
1073
1074 AC_ARG_ENABLE(zstd,
1075       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
1076       [case "${enableval}" in
1077         "yes") zstd=true ;;
1078         "no")  zstd=false ;;
1079         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
1080       esac], [zstd=auto])
1081
1082 if test "x$enable_zstd" = "xno"; then
1083     have_zstd=no;
1084 else
1085     PKG_CHECK_MODULES([ZSTD],
1086                       [libzstd >= 1.1],
1087                       have_zstd=yes,
1088                       have_zstd=no)
1089
1090     if test "x$have_zstd" = "xno" ; then
1091         AC_MSG_WARN([Unable to find libzstd.])
1092     fi
1093 fi
1094
1095 if test "x$have_zstd" = "xyes"; then
1096     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
1097     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
1098     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
1099
1100     dnl now check for zstd functions
1101     save_LIBS="$LIBS"
1102     save_CFLAGS="$CFLAGS"
1103     LIBS="$LIBS $ZSTD_LIBS"
1104     CFLAGS="$CFLAGS $ZSTD_CFLAGS"
1105     AC_CHECK_FUNCS(ZSTD_estimateCStreamSize \
1106                    ZSTD_estimateDCtxSize)
1107     LIBS="$save_LIBS"
1108     CFLAGS="$save_CFLAGS"
1109 fi
1110 AC_SUBST(TOR_ZSTD_CFLAGS)
1111 AC_SUBST(TOR_ZSTD_LIBS)
1112
1113 dnl ----------------------------------------------------------------------
1114 dnl Check if libcap is available for capabilities.
1115
1116 tor_cap_pkg_debian="libcap2"
1117 tor_cap_pkg_redhat="libcap"
1118 tor_cap_devpkg_debian="libcap-dev"
1119 tor_cap_devpkg_redhat="libcap-devel"
1120
1121 AC_CHECK_LIB([cap], [cap_init], [],
1122   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
1123 )
1124 AC_CHECK_FUNCS(cap_set_proc)
1125
1126 dnl ---------------------------------------------------------------------
1127 dnl Now that we know about our major libraries, we can check for compiler
1128 dnl and linker hardening options.  We need to do this with the libraries known,
1129 dnl since sometimes the linker will like an option but not be willing to
1130 dnl use it with a build of a library.
1131
1132 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
1133 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
1134
1135 CFLAGS_FTRAPV=
1136 CFLAGS_FWRAPV=
1137 CFLAGS_ASAN=
1138 CFLAGS_UBSAN=
1139
1140
1141 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1142 #if !defined(__clang__)
1143 #error
1144 #endif])], have_clang=yes, have_clang=no)
1145
1146 if test "x$enable_pic" = "xyes"; then
1147     TOR_CHECK_CFLAGS(-fPIC)
1148 fi
1149
1150 if test "x$enable_gcc_hardening" != "xno"; then
1151     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
1152     if test "x$have_clang" = "xyes"; then
1153         TOR_CHECK_CFLAGS(-Qunused-arguments)
1154     fi
1155     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
1156     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
1157     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
1158 m4_ifdef([AS_VAR_IF],[
1159     AS_VAR_IF(can_compile, [yes],
1160         AS_VAR_IF(can_link, [yes],
1161                   [],
1162                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
1163         )])
1164     AS_VAR_POPDEF([can_link])
1165     AS_VAR_POPDEF([can_compile])
1166     TOR_CHECK_CFLAGS(-Wstack-protector)
1167     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
1168     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
1169        if test "$enable_pic" != "yes"; then
1170            # If we have already enabled -fPIC, then we don't also need to
1171            # compile with -fPIE...
1172            TOR_CHECK_CFLAGS(-fPIE)
1173        fi
1174        # ... but we want to link our executables with -pie in any case, since
1175        # they're executables, not a library.
1176        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
1177     fi
1178     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
1179 fi
1180
1181 if test "$fragile_hardening" = "yes"; then
1182     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
1183    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
1184       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
1185    fi
1186
1187    if test "$tor_cv_cflags__ftrapv" != "yes"; then
1188      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
1189    fi
1190
1191    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
1192     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1193       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.*, and with Clang you need libclang_rt.ubsan*])
1194     fi
1195
1196    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1197     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1198       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1199     fi
1200
1201    TOR_TRY_COMPILE_WITH_CFLAGS([-fno-sanitize=float-divide-by-zero], also_link, CFLAGS_UBSAN="-fno-sanitize=float-divide-by-zero", true)
1202     if test "$tor_cv_cflags__fno_sanitize_float_divide_by_zero" = "yes" && test "$tor_can_link__fno_sanitize_float_divide_by_zero" != "yes"; then
1203       AC_MSG_ERROR([The compiler supports -fno-sanitize=float-divide-by-zero, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1204     fi
1205
1206 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1207 fi
1208
1209 dnl Find the correct libraries to add in order to use the sanitizers.
1210 dnl
1211 dnl When building Rust, Cargo will run the linker with the -nodefaultlibs
1212 dnl option, which will prevent the compiler from linking the sanitizer
1213 dnl libraries it needs.  We need to specify them manually.
1214 dnl
1215 dnl What's more, we need to specify them in a linker script rather than
1216 dnl from build.rs: these options aren't allowed in the cargo:rustc-flags
1217 dnl variable.
1218 RUST_LINKER_OPTIONS=""
1219 if test "x$have_clang" = "xyes"; then
1220         if test "x$CFLAGS_ASAN" != "x"; then
1221                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=$CFLAGS_ASAN -Cdefault-linker-libraries"
1222         fi
1223         if test "x$CFLAGS_UBSAN" != "x"; then
1224                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=$CFLAGS_UBSAN -Cdefault-linker-libraries"
1225         fi
1226 else
1227         if test "x$CFLAGS_ASAN" != "x"; then
1228                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=-fsanitize=address -Cdefault-linker-libraries"
1229         fi
1230         if test "x$CFLAGS_UBSAN" != "x"; then
1231                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=-fsanitize=undefined -Cdefault-linker-libraries"
1232         fi
1233 fi
1234 AC_SUBST(RUST_LINKER_OPTIONS)
1235
1236 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1237 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1238
1239 mulodi_fixes_ftrapv=no
1240 if test "$have_clang" = "yes"; then
1241   saved_CFLAGS="$CFLAGS"
1242   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1243   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1244   AC_LINK_IFELSE([
1245       AC_LANG_SOURCE([[
1246           #include <stdint.h>
1247           #include <stdlib.h>
1248           int main(int argc, char **argv)
1249           {
1250             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1251                         * (int64_t)atoi(argv[3]);
1252             return x == 9;
1253           } ]])],
1254           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1255           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1256   if test "$ftrapv_can_link" = "no"; then
1257     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1258     AC_LINK_IFELSE([
1259       AC_LANG_SOURCE([[
1260           #include <stdint.h>
1261           #include <stdlib.h>
1262           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1263              *overflow=0;
1264              return a;
1265           }
1266           int main(int argc, char **argv)
1267           {
1268             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1269                         * (int64_t)atoi(argv[3]);
1270             return x == 9;
1271           } ]])],
1272           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1273           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1274   fi
1275   CFLAGS="$saved_CFLAGS"
1276 fi
1277
1278 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1279
1280 dnl These cflags add bunches of branches, and we haven't been able to
1281 dnl persuade ourselves that they're suitable for code that needs to be
1282 dnl constant time.
1283 AC_SUBST(CFLAGS_BUGTRAP)
1284 dnl These cflags are variant ones sutable for code that needs to be
1285 dnl constant-time.
1286 AC_SUBST(CFLAGS_CONSTTIME)
1287
1288 if test "x$enable_linker_hardening" != "xno"; then
1289     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1290 fi
1291
1292 # For backtrace support
1293 TOR_CHECK_LDFLAGS(-rdynamic)
1294
1295 dnl ------------------------------------------------------
1296 dnl Now see if we have a -fomit-frame-pointer compiler option.
1297
1298 saved_CFLAGS="$CFLAGS"
1299 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1300 F_OMIT_FRAME_POINTER=''
1301 if test "$saved_CFLAGS" != "$CFLAGS"; then
1302   if test "$fragile_hardening" = "yes"; then
1303     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1304   fi
1305 fi
1306 CFLAGS="$saved_CFLAGS"
1307 AC_SUBST(F_OMIT_FRAME_POINTER)
1308
1309 dnl ------------------------------------------------------
1310 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1311 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1312 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1313 dnl code will work.
1314 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1315
1316 dnl ============================================================
1317 dnl Check for libseccomp
1318
1319 if test "x$enable_seccomp" != "xno"; then
1320   AC_CHECK_HEADERS([seccomp.h])
1321   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1322 fi
1323
1324 dnl ============================================================
1325 dnl Check for libscrypt
1326
1327 if test "x$enable_libscrypt" != "xno"; then
1328   AC_CHECK_HEADERS([libscrypt.h])
1329   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1330   AC_CHECK_FUNCS([libscrypt_scrypt])
1331 fi
1332
1333 dnl ============================================================
1334 dnl We need an implementation of curve25519.
1335
1336 dnl set these defaults.
1337 build_curve25519_donna=no
1338 build_curve25519_donna_c64=no
1339 use_curve25519_donna=no
1340 use_curve25519_nacl=no
1341 CURVE25519_LIBS=
1342
1343 dnl The best choice is using curve25519-donna-c64, but that requires
1344 dnl that we
1345 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1346   tor_cv_can_use_curve25519_donna_c64,
1347   [AC_RUN_IFELSE(
1348     [AC_LANG_PROGRAM([dnl
1349       #include <stdint.h>
1350       typedef unsigned uint128_t __attribute__((mode(TI)));
1351   int func(uint64_t a, uint64_t b) {
1352            uint128_t c = ((uint128_t)a) * b;
1353            int ok = ((uint64_t)(c>>96)) == 522859 &&
1354              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1355                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1356                  (((uint64_t)(c))&0xffffffffL) == 0;
1357            return ok;
1358       }
1359   ], [dnl
1360     int ok = func( ((uint64_t)2000000000) * 1000000000,
1361                    ((uint64_t)1234567890) << 24);
1362         return !ok;
1363       ])],
1364   [tor_cv_can_use_curve25519_donna_c64=yes],
1365       [tor_cv_can_use_curve25519_donna_c64=no],
1366   [AC_LINK_IFELSE(
1367         [AC_LANG_PROGRAM([dnl
1368       #include <stdint.h>
1369       typedef unsigned uint128_t __attribute__((mode(TI)));
1370   int func(uint64_t a, uint64_t b) {
1371            uint128_t c = ((uint128_t)a) * b;
1372            int ok = ((uint64_t)(c>>96)) == 522859 &&
1373              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1374                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1375                  (((uint64_t)(c))&0xffffffffL) == 0;
1376            return ok;
1377       }
1378   ], [dnl
1379     int ok = func( ((uint64_t)2000000000) * 1000000000,
1380                  ((uint64_t)1234567890) << 24);
1381         return !ok;
1382       ])],
1383           [tor_cv_can_use_curve25519_donna_c64=cross],
1384       [tor_cv_can_use_curve25519_donna_c64=no])])])
1385
1386 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1387                   nacl/crypto_scalarmult_curve25519.h])
1388
1389 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1390   tor_cv_can_use_curve25519_nacl,
1391   [tor_saved_LIBS="$LIBS"
1392    LIBS="$LIBS -lnacl"
1393    AC_LINK_IFELSE(
1394      [AC_LANG_PROGRAM([dnl
1395        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1396        #include <crypto_scalarmult_curve25519.h>
1397    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1398    #include <nacl/crypto_scalarmult_curve25519.h>
1399    #endif
1400        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1401    #error Hey, this is the reference implementation! That's not fast.
1402    #endif
1403      ], [
1404    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1405      ])], [tor_cv_can_use_curve25519_nacl=yes],
1406      [tor_cv_can_use_curve25519_nacl=no])
1407    LIBS="$tor_saved_LIBS" ])
1408
1409  dnl Okay, now we need to figure out which one to actually use. Fall back
1410  dnl to curve25519-donna.c
1411
1412  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1413    build_curve25519_donna_c64=yes
1414    use_curve25519_donna=yes
1415  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1416    use_curve25519_nacl=yes
1417    CURVE25519_LIBS=-lnacl
1418  else
1419    build_curve25519_donna=yes
1420    use_curve25519_donna=yes
1421  fi
1422
1423 if test "x$use_curve25519_donna" = "xyes"; then
1424   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1425             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1426 fi
1427 if test "x$use_curve25519_nacl" = "xyes"; then
1428   AC_DEFINE(USE_CURVE25519_NACL, 1,
1429             [Defined if we should use a curve25519 from nacl])
1430 fi
1431 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1432   test "x$build_curve25519_donna" = "xyes")
1433 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1434   test "x$build_curve25519_donna_c64" = "xyes")
1435 AC_SUBST(CURVE25519_LIBS)
1436
1437 dnl Make sure to enable support for large off_t if available.
1438 AC_SYS_LARGEFILE
1439
1440 AC_CHECK_HEADERS([errno.h \
1441                   fcntl.h \
1442                   signal.h \
1443                   string.h \
1444                   sys/capability.h \
1445                   sys/fcntl.h \
1446                   sys/stat.h \
1447                   sys/time.h \
1448                   sys/types.h \
1449                   time.h \
1450                   unistd.h \
1451                   arpa/inet.h \
1452                   crt_externs.h \
1453                   execinfo.h \
1454                   gnu/libc-version.h \
1455                   grp.h \
1456                   ifaddrs.h \
1457                   inttypes.h \
1458                   limits.h \
1459                   linux/types.h \
1460                   mach/vm_inherit.h \
1461                   machine/limits.h \
1462                   malloc.h \
1463                   malloc/malloc.h \
1464                   malloc_np.h \
1465                   netdb.h \
1466                   netinet/in.h \
1467                   netinet/in6.h \
1468                   pwd.h \
1469                   readpassphrase.h \
1470                   stdatomic.h \
1471                   sys/eventfd.h \
1472                   sys/file.h \
1473                   sys/ioctl.h \
1474                   sys/limits.h \
1475                   sys/mman.h \
1476                   sys/param.h \
1477                   sys/prctl.h \
1478                   sys/random.h \
1479                   sys/resource.h \
1480                   sys/select.h \
1481                   sys/socket.h \
1482                   sys/statvfs.h \
1483                   sys/syscall.h \
1484                   sys/sysctl.h \
1485                   sys/syslimits.h \
1486                   sys/time.h \
1487                   sys/types.h \
1488                   sys/un.h \
1489                   sys/utime.h \
1490                   sys/wait.h \
1491                   syslog.h \
1492                   utime.h])
1493
1494 AC_CHECK_HEADERS(sys/param.h)
1495
1496 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1497 [#ifdef HAVE_SYS_TYPES_H
1498 #include <sys/types.h>
1499 #endif
1500 #ifdef HAVE_SYS_SOCKET_H
1501 #include <sys/socket.h>
1502 #endif])
1503 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1504 [#ifdef HAVE_SYS_TYPES_H
1505 #include <sys/types.h>
1506 #endif
1507 #ifdef HAVE_SYS_SOCKET_H
1508 #include <sys/socket.h>
1509 #endif
1510 #ifdef HAVE_NET_IF_H
1511 #include <net/if.h>
1512 #endif
1513 #ifdef HAVE_NETINET_IN_H
1514 #include <netinet/in.h>
1515 #endif])
1516
1517 AC_CHECK_HEADERS(linux/if.h,[],[],
1518 [
1519 #ifdef HAVE_SYS_SOCKET_H
1520 #include <sys/socket.h>
1521 #endif
1522 ])
1523
1524 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1525         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1526 [#ifdef HAVE_SYS_TYPES_H
1527 #include <sys/types.h>
1528 #endif
1529 #ifdef HAVE_SYS_SOCKET_H
1530 #include <sys/socket.h>
1531 #endif
1532 #ifdef HAVE_LIMITS_H
1533 #include <limits.h>
1534 #endif
1535 #ifdef HAVE_LINUX_TYPES_H
1536 #include <linux/types.h>
1537 #endif
1538 #ifdef HAVE_NETINET_IN6_H
1539 #include <netinet/in6.h>
1540 #endif
1541 #ifdef HAVE_NETINET_IN_H
1542 #include <netinet/in.h>
1543 #endif])
1544
1545 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1546         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1547 [#ifdef HAVE_SYS_TYPES_H
1548 #include <sys/types.h>
1549 #endif
1550 #ifdef HAVE_SYS_SOCKET_H
1551 #include <sys/socket.h>
1552 #endif
1553 #ifdef HAVE_LIMITS_H
1554 #include <limits.h>
1555 #endif
1556 #ifdef HAVE_LINUX_TYPES_H
1557 #include <linux/types.h>
1558 #endif
1559 #ifdef HAVE_NETINET_IN6_H
1560 #include <netinet/in6.h>
1561 #endif
1562 #ifdef HAVE_NETINET_IN_H
1563 #include <netinet/in.h>
1564 #endif
1565 #ifdef HAVE_LINUX_IF_H
1566 #include <linux/if.h>
1567 #endif])
1568
1569 transparent_ok=0
1570 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1571   transparent_ok=1
1572 fi
1573 if test "x$linux_netfilter_ipv4" = "x1"; then
1574   transparent_ok=1
1575 fi
1576 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1577   transparent_ok=1
1578 fi
1579 if test "x$transparent_ok" = "x1"; then
1580   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1581 else
1582   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1583 fi
1584
1585 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1586 [#ifdef HAVE_SYS_TYPES_H
1587 #include <sys/types.h>
1588 #endif
1589 #ifdef HAVE_SYS_TIME_H
1590 #include <sys/time.h>
1591 #endif])
1592
1593 AC_CHECK_SIZEOF(char)
1594 AC_CHECK_SIZEOF(short)
1595 AC_CHECK_SIZEOF(int)
1596 AC_CHECK_SIZEOF(long)
1597 AC_CHECK_SIZEOF(long long)
1598 AC_CHECK_SIZEOF(__int64)
1599 AC_CHECK_SIZEOF(void *)
1600 AC_CHECK_SIZEOF(time_t)
1601 AC_CHECK_SIZEOF(size_t)
1602 AC_CHECK_SIZEOF(pid_t)
1603
1604 AC_CHECK_TYPES([uint, u_char, ssize_t])
1605
1606 AC_PC_FROM_UCONTEXT([:])
1607
1608 dnl used to include sockaddr_storage, but everybody has that.
1609 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1610 [#ifdef HAVE_SYS_TYPES_H
1611 #include <sys/types.h>
1612 #endif
1613 #ifdef HAVE_NETINET_IN_H
1614 #include <netinet/in.h>
1615 #endif
1616 #ifdef HAVE_NETINET_IN6_H
1617 #include <netinet/in6.h>
1618 #endif
1619 #ifdef HAVE_SYS_SOCKET_H
1620 #include <sys/socket.h>
1621 #endif
1622 #ifdef _WIN32
1623 #define _WIN32_WINNT 0x0501
1624 #define WIN32_LEAN_AND_MEAN
1625 #include <winsock2.h>
1626 #include <ws2tcpip.h>
1627 #endif
1628 ])
1629 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1630 [#ifdef HAVE_SYS_TYPES_H
1631 #include <sys/types.h>
1632 #endif
1633 #ifdef HAVE_NETINET_IN_H
1634 #include <netinet/in.h>
1635 #endif
1636 #ifdef HAVE_NETINET_IN6_H
1637 #include <netinet/in6.h>
1638 #endif
1639 #ifdef HAVE_SYS_SOCKET_H
1640 #include <sys/socket.h>
1641 #endif
1642 #ifdef _WIN32
1643 #define _WIN32_WINNT 0x0501
1644 #define WIN32_LEAN_AND_MEAN
1645 #include <winsock2.h>
1646 #include <ws2tcpip.h>
1647 #endif
1648 ])
1649
1650 AC_CHECK_TYPES([rlim_t], , ,
1651 [#ifdef HAVE_SYS_TYPES_H
1652 #include <sys/types.h>
1653 #endif
1654 #ifdef HAVE_SYS_TIME_H
1655 #include <sys/time.h>
1656 #endif
1657 #ifdef HAVE_SYS_RESOURCE_H
1658 #include <sys/resource.h>
1659 #endif
1660 ])
1661
1662 AX_CHECK_SIGN([time_t],
1663        [ : ],
1664        [ : ], [
1665 #ifdef HAVE_SYS_TYPES_H
1666 #include <sys/types.h>
1667 #endif
1668 #ifdef HAVE_SYS_TIME_H
1669 #include <sys/time.h>
1670 #endif
1671 #ifdef HAVE_TIME_H
1672 #include <time.h>
1673 #endif
1674 ])
1675
1676 if test "$ax_cv_decl_time_t_signed" = "no"; then
1677   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1678 fi
1679
1680 AX_CHECK_SIGN([size_t],
1681        [ tor_cv_size_t_signed=yes ],
1682        [ tor_cv_size_t_signed=no ], [
1683 #ifdef HAVE_SYS_TYPES_H
1684 #include <sys/types.h>
1685 #endif
1686 ])
1687
1688 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1689   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1690 fi
1691
1692 AX_CHECK_SIGN([enum always],
1693        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1694        [ : ], [
1695  enum always { AAA, BBB, CCC };
1696 ])
1697
1698 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1699 #ifdef HAVE_SYS_SOCKET_H
1700 #include <sys/socket.h>
1701 #endif
1702 ])
1703
1704 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1705
1706 AC_CHECK_SIZEOF(cell_t)
1707
1708 # Let's see if stdatomic works. (There are some debian clangs that screw it
1709 # up; see Tor bug #26779 and debian bug 903709.)
1710 AC_CACHE_CHECK([whether C11 stdatomic.h actually works],
1711                tor_cv_stdatomic_works,
1712 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1713 #include <stdatomic.h>
1714 struct x { atomic_size_t y; };
1715 void try_atomic_init(struct x *xx)
1716 {
1717   atomic_init(&xx->y, 99);
1718   atomic_fetch_add(&xx->y, 1);
1719 }
1720 ]])], [tor_cv_stdatomic_works=yes], [tor_cv_stdatomic_works=no])])
1721
1722 if test "$tor_cv_stdatomic_works" = "yes"; then
1723    AC_DEFINE(STDATOMIC_WORKS, 1, [Set to 1 if we can compile a simple stdatomic example.])
1724 elif test "$ac_cv_header_stdatomic_h" = "yes"; then
1725    AC_MSG_WARN([Your compiler provides the stdatomic.h header, but it doesn't seem to work.  I'll pretend it isn't there. If you are using Clang on Debian, maybe this is because of https://bugs.debian.org/903709 ])
1726 fi
1727
1728 # Now make sure that NULL can be represented as zero bytes.
1729 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1730 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1731 [[#include <stdlib.h>
1732 #include <string.h>
1733 #include <stdio.h>
1734 #ifdef HAVE_STDDEF_H
1735 #include <stddef.h>
1736 #endif
1737 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1738 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1739        [tor_cv_null_is_zero=yes],
1740        [tor_cv_null_is_zero=no],
1741        [tor_cv_null_is_zero=cross])])
1742
1743 if test "$tor_cv_null_is_zero" = "cross"; then
1744   # Cross-compiling; let's hope that the target isn't raving mad.
1745   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1746 fi
1747
1748 if test "$tor_cv_null_is_zero" != "no"; then
1749   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1750             [Define to 1 iff memset(0) sets pointers to NULL])
1751 fi
1752
1753 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1754 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1755 [[#include <stdlib.h>
1756 #include <string.h>
1757 #include <stdio.h>
1758 #ifdef HAVE_STDDEF_H
1759 #include <stddef.h>
1760 #endif
1761 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1762 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1763        [tor_cv_dbl0_is_zero=yes],
1764        [tor_cv_dbl0_is_zero=no],
1765        [tor_cv_dbl0_is_zero=cross])])
1766
1767 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1768   # Cross-compiling; let's hope that the target isn't raving mad.
1769   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1770 fi
1771
1772 if test "$tor_cv_dbl0_is_zero" != "no"; then
1773   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1774             [Define to 1 iff memset(0) sets doubles to 0.0])
1775 fi
1776
1777 # And what happens when we malloc zero?
1778 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1779 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1780 [[#include <stdlib.h>
1781 #include <string.h>
1782 #include <stdio.h>
1783 #ifdef HAVE_STDDEF_H
1784 #include <stddef.h>
1785 #endif
1786 int main () { return malloc(0)?0:1; }]])],
1787        [tor_cv_malloc_zero_works=yes],
1788        [tor_cv_malloc_zero_works=no],
1789        [tor_cv_malloc_zero_works=cross])])
1790
1791 if test "$tor_cv_malloc_zero_works" = "cross"; then
1792   # Cross-compiling; let's hope that the target isn't raving mad.
1793   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1794 fi
1795
1796 if test "$tor_cv_malloc_zero_works" = "yes"; then
1797   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1798             [Define to 1 iff malloc(0) returns a pointer])
1799 fi
1800
1801 # whether we seem to be in a 2s-complement world.
1802 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1803 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1804 [[int main () { int problem = ((-99) != (~99)+1);
1805 return problem ? 1 : 0; }]])],
1806        [tor_cv_twos_complement=yes],
1807        [tor_cv_twos_complement=no],
1808        [tor_cv_twos_complement=cross])])
1809
1810 if test "$tor_cv_twos_complement" = "cross"; then
1811   # Cross-compiling; let's hope that the target isn't raving mad.
1812   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1813 fi
1814
1815 if test "$tor_cv_twos_complement" != "no"; then
1816   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1817             [Define to 1 iff we represent negative integers with
1818              two's complement])
1819 fi
1820
1821 # What does shifting a negative value do?
1822 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1823 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1824 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1825        [tor_cv_sign_extend=yes],
1826        [tor_cv_sign_extend=no],
1827        [tor_cv_sign_extend=cross])])
1828
1829 if test "$tor_cv_sign_extend" = "cross"; then
1830   # Cross-compiling; let's hope that the target isn't raving mad.
1831   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1832 fi
1833
1834 if test "$tor_cv_sign_extend" != "no"; then
1835   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1836             [Define to 1 iff right-shifting a negative value performs sign-extension])
1837 fi
1838
1839 # Is uint8_t the same type as unsigned char?
1840 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1841 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1842 #include <stdint.h>
1843 extern uint8_t c;
1844 unsigned char c;]])],
1845        [tor_cv_uint8_uchar=yes],
1846        [tor_cv_uint8_uchar=no],
1847        [tor_cv_uint8_uchar=cross])])
1848
1849 if test "$tor_cv_uint8_uchar" = "cross"; then
1850   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1851 fi
1852
1853 if test "$tor_cv_uint8_uchar" = "no"; then
1854   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1855 fi
1856
1857 AC_ARG_WITH(tcmalloc,
1858 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library. Deprecated; see --with-malloc]),
1859 [ tcmalloc=yes ], [ tcmalloc=no ])
1860
1861 default_malloc=system
1862
1863 if test "x$enable_openbsd_malloc" = "xyes" ; then
1864   AC_MSG_NOTICE([The --enable-openbsd-malloc argument is deprecated; use --with-malloc=openbsd instead.])
1865   default_malloc=openbsd
1866 fi
1867
1868 if test "x$tcmalloc" = "xyes"; then
1869   AC_MSG_NOTICE([The --with-tcmalloc argument is deprecated; use --with-malloc=tcmalloc instead.])
1870   default_malloc=tcmalloc
1871 fi
1872
1873 AC_ARG_WITH(malloc,
1874    AS_HELP_STRING([--with-malloc=[system,jemalloc,tcmalloc,openbsd]],
1875                   [select special malloc implementation [system]]),
1876    [ malloc="$with_malloc" ], [ malloc="$default_malloc" ])
1877
1878 AS_CASE([$malloc],
1879   [tcmalloc], [
1880       PKG_CHECK_MODULES([TCMALLOC],
1881                         [libtcmalloc],
1882                         have_tcmalloc=yes,
1883                         have_tcmalloc=no)
1884
1885       if test "x$have_tcmalloc" = "xno" ; then
1886           AC_MSG_ERROR([Unable to find tcmalloc requested by --with-malloc.])
1887       fi
1888
1889       CFLAGS="$CFLAGS $TCMALLOC_CFLAGS"
1890       LIBS="$TCMALLOC_LIBS $LIBS"
1891   ],
1892
1893   [jemalloc], [
1894       PKG_CHECK_MODULES([JEMALLOC],
1895                         [jemalloc],
1896                         have_jemalloc=yes,
1897                         have_jemalloc=no)
1898
1899       if test "x$have_tcmalloc" = "xno" ; then
1900           AC_MSG_ERROR([Unable to find jemalloc requested by --with-malloc.])
1901       fi
1902
1903       CFLAGS="$CFLAGS $JEMALLOC_CFLAGS"
1904       LIBS="$JEMALLOC_LIBS $LIBS"
1905       using_custom_malloc=yes
1906   ],
1907
1908   [openbsd], [
1909     AC_MSG_WARN([The openbsd malloc port is deprecated in Tor 0.3.5 and will be removed in a future version.])
1910     enable_openbsd_malloc=yes
1911   ],
1912
1913   [system], [
1914      # handle this later, including the jemalloc fallback
1915     AC_CHECK_FUNCS(mallinfo)
1916   ],
1917
1918   [AC_MSG_ERROR([--with-malloc=`$with_malloc' not supported, see --help])
1919 ])
1920
1921 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
1922
1923 if test "$malloc" != "system"; then
1924   # Tell the C compiler not to use the system allocator functions.
1925   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
1926 fi
1927 if test "$using_custom_malloc" = "yes"; then
1928   # Tell the C compiler not to use the system allocator functions.
1929   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
1930 fi
1931
1932 # By default, we're going to assume we don't have mlockall()
1933 # bionic and other platforms have various broken mlockall subsystems.
1934 # Some systems don't have a working mlockall, some aren't linkable,
1935 # and some have it but don't declare it.
1936 AC_CHECK_FUNCS(mlockall)
1937 AC_CHECK_DECLS([mlockall], , , [
1938 #ifdef HAVE_SYS_MMAN_H
1939 #include <sys/mman.h>
1940 #endif])
1941
1942 # Allow user to specify an alternate syslog facility
1943 AC_ARG_WITH(syslog-facility,
1944 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1945 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1946 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1947 AC_SUBST(LOGFACILITY)
1948
1949 # Check if we have getresuid and getresgid
1950 AC_CHECK_FUNCS(getresuid getresgid)
1951
1952 # Check for gethostbyname_r in all its glorious incompatible versions.
1953 #   (This logic is based on that in Python's configure.in)
1954 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1955   [Define this if you have any gethostbyname_r()])
1956
1957 AC_CHECK_FUNC(gethostbyname_r, [
1958   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1959   OLD_CFLAGS=$CFLAGS
1960   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1961   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1962 #include <netdb.h>
1963   ]], [[
1964     char *cp1, *cp2;
1965     struct hostent *h1, *h2;
1966     int i1, i2;
1967     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1968   ]])],[
1969     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1970     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1971      [Define this if gethostbyname_r takes 6 arguments])
1972     AC_MSG_RESULT(6)
1973   ], [
1974     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1975 #include <netdb.h>
1976     ]], [[
1977       char *cp1, *cp2;
1978       struct hostent *h1;
1979       int i1, i2;
1980       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1981     ]])], [
1982       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1983       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1984         [Define this if gethostbyname_r takes 5 arguments])
1985       AC_MSG_RESULT(5)
1986    ], [
1987       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1988 #include <netdb.h>
1989      ]], [[
1990        char *cp1;
1991        struct hostent *h1;
1992        struct hostent_data hd;
1993        (void) gethostbyname_r(cp1,h1,&hd);
1994      ]])], [
1995        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1996        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1997          [Define this if gethostbyname_r takes 3 arguments])
1998        AC_MSG_RESULT(3)
1999      ], [
2000        AC_MSG_RESULT(0)
2001      ])
2002   ])
2003  ])
2004  CFLAGS=$OLD_CFLAGS
2005 ])
2006
2007 AC_CACHE_CHECK([whether the C compiler supports __func__],
2008   tor_cv_have_func_macro,
2009   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2010 #include <stdio.h>
2011 int main(int c, char **v) { puts(__func__); }])],
2012   tor_cv_have_func_macro=yes,
2013   tor_cv_have_func_macro=no))
2014
2015 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
2016   tor_cv_have_FUNC_macro,
2017   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2018 #include <stdio.h>
2019 int main(int c, char **v) { puts(__FUNC__); }])],
2020   tor_cv_have_FUNC_macro=yes,
2021   tor_cv_have_FUNC_macro=no))
2022
2023 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
2024   tor_cv_have_FUNCTION_macro,
2025   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2026 #include <stdio.h>
2027 int main(int c, char **v) { puts(__FUNCTION__); }])],
2028   tor_cv_have_FUNCTION_macro=yes,
2029   tor_cv_have_FUNCTION_macro=no))
2030
2031 AC_CACHE_CHECK([whether we have extern char **environ already declared],
2032   tor_cv_have_environ_declared,
2033   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2034 #ifdef HAVE_UNISTD_H
2035 #include <unistd.h>
2036 #endif
2037 #include <stdlib.h>
2038 int main(int c, char **v) { char **t = environ; }])],
2039   tor_cv_have_environ_declared=yes,
2040   tor_cv_have_environ_declared=no))
2041
2042 if test "$tor_cv_have_func_macro" = "yes"; then
2043   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
2044 fi
2045
2046 if test "$tor_cv_have_FUNC_macro" = "yes"; then
2047   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
2048 fi
2049
2050 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
2051   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
2052            [Defined if the compiler supports __FUNCTION__])
2053 fi
2054
2055 if test "$tor_cv_have_environ_declared" = "yes"; then
2056   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
2057            [Defined if we have extern char **environ already declared])
2058 fi
2059
2060 # $prefix stores the value of the --prefix command line option, or
2061 # NONE if the option wasn't set.  In the case that it wasn't set, make
2062 # it be the default, so that we can use it to expand directories now.
2063 if test "x$prefix" = "xNONE"; then
2064   prefix=$ac_default_prefix
2065 fi
2066
2067 # and similarly for $exec_prefix
2068 if test "x$exec_prefix" = "xNONE"; then
2069   exec_prefix=$prefix
2070 fi
2071
2072 if test "x$BUILDDIR" = "x"; then
2073   BUILDDIR=`pwd`
2074 fi
2075 AC_SUBST(BUILDDIR)
2076 AH_TEMPLATE([BUILDDIR],[tor's build directory])
2077 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
2078
2079 if test "x$SRCDIR" = "x"; then
2080   SRCDIR=$(cd "$srcdir"; pwd)
2081 fi
2082 AH_TEMPLATE([SRCDIR],[tor's sourcedir directory])
2083 AC_DEFINE_UNQUOTED(SRCDIR,"$SRCDIR")
2084
2085 if test "x$CONFDIR" = "x"; then
2086   CONFDIR=`eval echo $sysconfdir/tor`
2087 fi
2088 AC_SUBST(CONFDIR)
2089 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
2090 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
2091
2092 BINDIR=`eval echo $bindir`
2093 AC_SUBST(BINDIR)
2094 LOCALSTATEDIR=`eval echo $localstatedir`
2095 AC_SUBST(LOCALSTATEDIR)
2096
2097 if test "$bwin32" = "true"; then
2098   # Test if the linker supports the --nxcompat and --dynamicbase options
2099   # for Windows
2100   save_LDFLAGS="$LDFLAGS"
2101   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
2102   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
2103   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
2104     [AC_MSG_RESULT([yes])]
2105     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
2106     [AC_MSG_RESULT([no])]
2107   )
2108   LDFLAGS="$save_LDFLAGS"
2109 fi
2110
2111 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
2112 # than autoconf's macros like.
2113 if test "$GCC" = "yes"; then
2114   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
2115   # accident waiting to happen.
2116   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
2117 else
2118   # Override optimization level for non-gcc compilers
2119   CFLAGS="$CFLAGS -O"
2120   enable_gcc_warnings=no
2121   enable_gcc_warnings_advisory=no
2122 fi
2123
2124 # Warnings implies advisory-warnings and -Werror.
2125 if test "$enable_gcc_warnings" = "yes"; then
2126   enable_gcc_warnings_advisory=yes
2127   enable_fatal_warnings=yes
2128 fi
2129
2130 # OS X Lion started deprecating the system openssl. Let's just disable
2131 # all deprecation warnings on OS X. Also, to potentially make the binary
2132 # a little smaller, let's enable dead_strip.
2133 case "$host_os" in
2134
2135  darwin*)
2136     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
2137     LDFLAGS="$LDFLAGS -dead_strip" ;;
2138 esac
2139
2140 TOR_WARNING_FLAGS=""
2141
2142 # Add some more warnings which we use in development but not in the
2143 # released versions.  (Some relevant gcc versions can't handle these.)
2144 #
2145 # Note that we have to do this near the end  of the autoconf process, or
2146 # else we may run into problems when these warnings hit on the testing C
2147 # programs that autoconf wants to build.
2148 if test "x$enable_gcc_warnings_advisory" != "xno"; then
2149
2150   case "$host" in
2151     *-*-openbsd* | *-*-bitrig*)
2152       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
2153       # That's fine, except that the headers don't pass -Wredundant-decls.
2154       # Therefore, let's disable -Wsystem-headers when we're building
2155       # with maximal warnings on OpenBSD.
2156       CFLAGS="$CFLAGS -Wno-system-headers" ;;
2157   esac
2158
2159   CFLAGS_NOWARNINGS="$CFLAGS"
2160
2161   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
2162   # have it work better.
2163   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
2164
2165   # This warning was added in gcc 4.3, but it appears to generate
2166   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
2167   #CFLAGS="$CFLAGS -Wlogical-op"
2168
2169   m4_foreach_w([warning_flag], [
2170      -Waddress
2171      -Waddress-of-array-temporary
2172      -Waddress-of-temporary
2173      -Wambiguous-macro
2174      -Wanonymous-pack-parens
2175      -Warc
2176      -Warc-abi
2177      -Warc-bridge-casts-disallowed-in-nonarc
2178      -Warc-maybe-repeated-use-of-weak
2179      -Warc-performSelector-leaks
2180      -Warc-repeated-use-of-weak
2181      -Warray-bounds
2182      -Warray-bounds-pointer-arithmetic
2183      -Wasm
2184      -Wasm-operand-widths
2185      -Watomic-properties
2186      -Watomic-property-with-user-defined-accessor
2187      -Wauto-import
2188      -Wauto-storage-class
2189      -Wauto-var-id
2190      -Wavailability
2191      -Wbackslash-newline-escape
2192      -Wbad-array-new-length
2193      -Wbind-to-temporary-copy
2194      -Wbitfield-constant-conversion
2195      -Wbool-conversion
2196      -Wbool-conversions
2197      -Wbuiltin-requires-header
2198      -Wchar-align
2199      -Wcompare-distinct-pointer-types
2200      -Wcomplex-component-init
2201      -Wconditional-type-mismatch
2202      -Wconfig-macros
2203      -Wconstant-conversion
2204      -Wconstant-logical-operand
2205      -Wconstexpr-not-const
2206      -Wcustom-atomic-properties
2207      -Wdangling-field
2208      -Wdangling-initializer-list
2209      -Wdate-time
2210      -Wdelegating-ctor-cycles
2211      -Wdeprecated-implementations
2212      -Wdeprecated-register
2213      -Wdirect-ivar-access
2214      -Wdiscard-qual
2215      -Wdistributed-object-modifiers
2216      -Wdivision-by-zero
2217      -Wdollar-in-identifier-extension
2218      -Wdouble-promotion
2219      -Wduplicate-decl-specifier
2220      -Wduplicate-enum
2221      -Wduplicate-method-arg
2222      -Wduplicate-method-match
2223      -Wduplicated-cond
2224      -Wdynamic-class-memaccess
2225      -Wembedded-directive
2226      -Wempty-translation-unit
2227      -Wenum-conversion
2228      -Wexit-time-destructors
2229      -Wexplicit-ownership-type
2230      -Wextern-initializer
2231      -Wextra
2232      -Wextra-semi
2233      -Wextra-tokens
2234      -Wflexible-array-extensions
2235      -Wfloat-conversion
2236      -Wformat-non-iso
2237      -Wfour-char-constants
2238      -Wgcc-compat
2239      -Wglobal-constructors
2240      -Wgnu-array-member-paren-init
2241      -Wgnu-designator
2242      -Wgnu-static-float-init
2243      -Wheader-guard
2244      -Wheader-hygiene
2245      -Widiomatic-parentheses
2246      -Wignored-attributes
2247      -Wimplicit-atomic-properties
2248      -Wimplicit-conversion-floating-point-to-bool
2249      -Wimplicit-exception-spec-mismatch
2250      -Wimplicit-fallthrough
2251      -Wimplicit-fallthrough-per-function
2252      -Wimplicit-retain-self
2253      -Wimport-preprocessor-directive-pedantic
2254      -Wincompatible-library-redeclaration
2255      -Wincompatible-pointer-types-discards-qualifiers
2256      -Wincomplete-implementation
2257      -Wincomplete-module
2258      -Wincomplete-umbrella
2259      -Winit-self
2260      -Wint-conversions
2261      -Wint-to-void-pointer-cast
2262      -Winteger-overflow
2263      -Winvalid-constexpr
2264      -Winvalid-iboutlet
2265      -Winvalid-noreturn
2266      -Winvalid-pp-token
2267      -Winvalid-source-encoding
2268      -Winvalid-token-paste
2269      -Wknr-promoted-parameter
2270      -Wlarge-by-value-copy
2271      -Wliteral-conversion
2272      -Wliteral-range
2273      -Wlocal-type-template-args
2274      -Wlogical-op
2275      -Wloop-analysis
2276      -Wmain-return-type
2277      -Wmalformed-warning-check
2278      -Wmethod-signatures
2279      -Wmicrosoft
2280      -Wmicrosoft-exists
2281      -Wmismatched-parameter-types
2282      -Wmismatched-return-types
2283      -Wmissing-field-initializers
2284      -Wmissing-format-attribute
2285      -Wmissing-noreturn
2286      -Wmissing-selector-name
2287      -Wmissing-sysroot
2288      -Wmissing-variable-declarations
2289      -Wmodule-conflict
2290      -Wnested-anon-types
2291      -Wnewline-eof
2292      -Wnon-literal-null-conversion
2293      -Wnon-pod-varargs
2294      -Wnonportable-cfstrings
2295      -Wnormalized=nfkc
2296      -Wnull-arithmetic
2297      -Wnull-character
2298      -Wnull-conversion
2299      -Wnull-dereference
2300      -Wout-of-line-declaration
2301      -Wover-aligned
2302      -Woverlength-strings
2303      -Woverride-init
2304      -Woverriding-method-mismatch
2305      -Wpointer-type-mismatch
2306      -Wpredefined-identifier-outside-function
2307      -Wprotocol-property-synthesis-ambiguity
2308      -Wreadonly-iboutlet-property
2309      -Wreadonly-setter-attrs
2310      -Wreceiver-expr
2311      -Wreceiver-forward-class
2312      -Wreceiver-is-weak
2313      -Wreinterpret-base-class
2314      -Wrequires-super-attribute
2315      -Wreserved-user-defined-literal
2316      -Wreturn-stack-address
2317      -Wsection
2318      -Wselector-type-mismatch
2319      -Wsentinel
2320      -Wserialized-diagnostics
2321      -Wshadow
2322      -Wshift-count-negative
2323      -Wshift-count-overflow
2324      -Wshift-negative-value
2325      -Wshift-overflow=2
2326      -Wshift-sign-overflow
2327      -Wshorten-64-to-32
2328      -Wsizeof-array-argument
2329      -Wsource-uses-openmp
2330      -Wstatic-float-init
2331      -Wstatic-in-inline
2332      -Wstatic-local-in-inline
2333      -Wstrict-overflow=1
2334      -Wstring-compare
2335      -Wstring-conversion
2336      -Wstrlcpy-strlcat-size
2337      -Wstrncat-size
2338      -Wsuggest-attribute=format
2339      -Wsuggest-attribute=noreturn
2340      -Wsuper-class-method-mismatch
2341      -Wswitch-bool
2342      -Wsync-nand
2343      -Wtautological-constant-out-of-range-compare
2344      -Wtentative-definition-incomplete-type
2345      -Wtrampolines
2346      -Wtype-safety
2347      -Wtypedef-redefinition
2348      -Wtypename-missing
2349      -Wundefined-inline
2350      -Wundefined-internal
2351      -Wundefined-reinterpret-cast
2352      -Wunicode
2353      -Wunicode-whitespace
2354      -Wunknown-warning-option
2355      -Wunnamed-type-template-args
2356      -Wunneeded-member-function
2357      -Wunsequenced
2358      -Wunsupported-visibility
2359      -Wunused-but-set-parameter
2360      -Wunused-but-set-variable
2361      -Wunused-command-line-argument
2362      -Wunused-const-variable=2
2363      -Wunused-exception-parameter
2364      -Wunused-local-typedefs
2365      -Wunused-member-function
2366      -Wunused-sanitize-argument
2367      -Wunused-volatile-lvalue
2368      -Wuser-defined-literals
2369      -Wvariadic-macros
2370      -Wvector-conversion
2371      -Wvector-conversions
2372      -Wvexing-parse
2373      -Wvisibility
2374      -Wvla-extension
2375      -Wzero-length-array
2376   ], [ TOR_TRY_COMPILE_WITH_CFLAGS(warning_flag, [],
2377               [TOR_WARNING_FLAGS="$TOR_WARNING_FLAGS warning_flag" CFLAGS="$CFLAGS warning_flag"], true)
2378      ])
2379
2380 dnl    We should re-enable this in some later version.  Clang doesn't
2381 dnl    mind, but it causes trouble with GCC.
2382 dnl     -Wstrict-overflow=2
2383
2384 dnl    These seem to require annotations that we don't currently use,
2385 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2386 dnl     -Wthread-safety
2387 dnl     -Wthread-safety-analysis
2388 dnl     -Wthread-safety-attributes
2389 dnl     -Wthread-safety-beta
2390 dnl     -Wthread-safety-precise
2391
2392   W_FLAGS="$W_FLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2393   W_FLAGS="$W_FLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2394   W_FLAGS="$W_FLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2395   W_FLAGS="$W_FLAGS -Wwrite-strings"
2396   W_FLAGS="$W_FLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2397   W_FLAGS="$W_FLAGS -Waggregate-return -Wpacked -Wunused"
2398   W_FLAGS="$W_FLAGS -Wunused-parameter "
2399   # These interfere with building main() { return 0; }, which autoconf
2400   # likes to use as its default program.
2401   W_FLAGS="$W_FLAGS -Wold-style-definition -Wmissing-declarations"
2402
2403   TOR_WARNING_FLAGS="$TOR_WARNING_FLAGS $W_FLAGS"
2404   CFLAGS="$CFLAGS $W_FLAGS"
2405
2406   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2407     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2408   fi
2409   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2410     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2411   fi
2412   if test "$tor_cv_cflags__warn_unused_const_variable_2" = "yes"; then
2413     AC_DEFINE([HAVE_CFLAG_WUNUSED_CONST_VARIABLE], 1, [True if we have -Wunused-const-variable])
2414   fi
2415
2416   CFLAGS="$CFLAGS_NOWARNINGS"
2417
2418   if test "x$enable_fatal_warnings" = "xyes"; then
2419     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2420     # default autoconf programs are full of errors.
2421     CFLAGS="$CFLAGS -Werror"
2422   fi
2423
2424 fi
2425
2426 AC_SUBST(TOR_WARNING_FLAGS)
2427
2428 echo "$TOR_WARNING_FLAGS">warning_flags
2429
2430 TOR_TRY_COMPILE_WITH_CFLAGS([@warning_flags], [],
2431                             CFLAGS="$CFLAGS @warning_flags",
2432                             CFLAGS="$CFLAGS $TOR_WARNING_FLAGS")
2433
2434 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2435    case "$host_os" in
2436     darwin*)
2437       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2438    esac
2439 fi
2440
2441 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2442
2443 AC_CONFIG_FILES([
2444         Doxyfile
2445         Makefile
2446         config.rust
2447         contrib/dist/suse/tor.sh
2448         contrib/operator-tools/tor.logrotate
2449         contrib/dist/tor.sh
2450         contrib/dist/torctl
2451         contrib/dist/tor.service
2452         src/config/torrc.sample
2453         src/config/torrc.minimal
2454         src/rust/.cargo/config
2455         scripts/maint/checkOptionDocs.pl
2456         warning_flags
2457 ])
2458
2459 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2460   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2461   for file in $regular_mans ; do
2462     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2463       echo "==================================";
2464       echo;
2465       echo "Building Tor has failed since manpages cannot be built.";
2466       echo;
2467       echo "You need asciidoc installed to be able to build the manpages.";
2468       echo "To build without manpages, use the --disable-asciidoc argument";
2469       echo "when calling configure.";
2470       echo;
2471       echo "==================================";
2472       exit 1;
2473     fi
2474   done
2475 fi
2476
2477 if test "$fragile_hardening" = "yes"; then
2478   AC_MSG_WARN([
2479
2480 ============
2481 Warning!  Building Tor with --enable-fragile-hardening (also known as
2482 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2483 other kinds of attacks easier. A Tor instance build with this option will be
2484 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2485 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2486 denial of service attacks. For more information, see
2487 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2488 ============
2489   ])
2490 fi
2491
2492 AC_OUTPUT