configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.10-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  23 AC_ARG_ENABLE(buf-freelists,
  24    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  25 AC_ARG_ENABLE(openbsd-malloc,
  26    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  27 AC_ARG_ENABLE(instrument-downloads,
  28    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  29 AC_ARG_ENABLE(static-openssl,
  30    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  31 AC_ARG_ENABLE(static-libevent,
  32    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  33
  34 if test x$enable_buf_freelists != xno; then
  35   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  36             [Defined if we try to use freelists for buffer RAM chunks])
  37 fi
  38 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  39 if test x$enable_instrument_downloads = xyes; then
  40   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  41             [Defined if we want to keep track of how much of each kind of resource we download.])
  42 fi
  43
  44 AC_ARG_ENABLE(transparent,
  45      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  46      [case "${enableval}" in
  47         yes) transparent=true ;;
  48         no)  transparent=false ;;
  49         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  50       esac], [transparent=true])
  51
  52 AC_ARG_ENABLE(asciidoc,
  53      AS_HELP_STRING(--disable-asciidoc, don't use asciidoc (disables building of manpages)),
  54      [case "${enableval}" in
  55         yes) asciidoc=true ;;
  56         no)  asciidoc=false ;;
  57         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  58       esac], [asciidoc=true])
  59
  60
  61 AC_ARG_ENABLE(threads,
  62      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  63
  64 if test x$enable_threads = x; then
  65    case $host in
  66     *-*-solaris* )
  67      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  68      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  69 cpu workers lock up here, so I will disable threads.])
  70      enable_threads="no";;
  71     *)
  72      enable_threads="yes";;
  73    esac
  74 fi
  75
  76 if test "$enable_threads" = "yes"; then
  77   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  78 fi
  79
  80 case $host in
  81    *-*-solaris* )
  82      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  83      ;;
  84 esac
  85
  86 AC_ARG_ENABLE(gcc-warnings,
  87      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  88 AC_ARG_ENABLE(gcc-warnings-advisory,
  89      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
  90
  91 AC_ARG_ENABLE(local-appdata,
  92    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
  93 if test "$enable_local_appdata" = "yes"; then
  94   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
  95             [Defined if we default to host local appdata paths on Windows])
  96 fi
  97
  98 AC_PROG_CC
  99 AC_PROG_CPP
 100 AC_PROG_MAKE_SET
 101 AC_PROG_RANLIB
 102
 103 dnl autoconf 2.59 appears not to support AC_PROG_SED
 104 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 105
 106 dnl check for asciidoc and a2x
 107 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 108 AC_PATH_PROG([A2X], [a2x], none)
 109
 110 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 111
 112 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 113 AC_PATH_PROG([OPENSSL], [openssl], none)
 114
 115 TORUSER=_tor
 116 AC_ARG_WITH(tor-user,
 117         [  --with-tor-user=NAME    Specify username for tor daemon ],
 118         [
 119            TORUSER=$withval
 120         ]
 121 )
 122 AC_SUBST(TORUSER)
 123
 124 TORGROUP=_tor
 125 AC_ARG_WITH(tor-group,
 126         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 127         [
 128            TORGROUP=$withval
 129         ]
 130 )
 131 AC_SUBST(TORGROUP)
 132
 133
 134 dnl If WIN32 is defined and non-zero, we are building for win32
 135 AC_MSG_CHECKING([for win32])
 136 AC_RUN_IFELSE([
 137 int main(int c, char **v) {
 138 #ifdef WIN32
 139 #if WIN32
 140   return 0;
 141 #else
 142   return 1;
 143 #endif
 144 #else
 145   return 2;
 146 #endif
 147 }],
 148 bwin32=true; AC_MSG_RESULT([yes]),
 149 bwin32=false; AC_MSG_RESULT([no]),
 150 bwin32=cross; AC_MSG_RESULT([cross])
 151 )
 152
 153 if test "$bwin32" = cross; then
 154 AC_MSG_CHECKING([for win32 (cross)])
 155 AC_COMPILE_IFELSE([
 156 #ifdef WIN32
 157 int main(int c, char **v) {return 0;}
 158 #else
 159 #error
 160 int main(int c, char **v) {return x(y);}
 161 #endif
 162 ],
 163 bwin32=true; AC_MSG_RESULT([yes]),
 164 bwin32=false; AC_MSG_RESULT([no]))
 165 fi
 166
 167 if test "$bwin32" = true; then
 168 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 169 fi
 170 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 171
 172 dnl Enable C99 when compiling with MIPSpro
 173 AC_MSG_CHECKING([for MIPSpro compiler])
 174 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 175 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 176 #error
 177   return x(y);
 178 #endif
 179 ]),
 180 bmipspro=false; AC_MSG_RESULT(no),
 181 bmipspro=true; AC_MSG_RESULT(yes))
 182
 183 if test "$bmipspro" = true; then
 184   CFLAGS="$CFLAGS -c99"
 185 fi
 186
 187 AC_C_BIGENDIAN
 188
 189 AC_SEARCH_LIBS(socket, [socket])
 190 AC_SEARCH_LIBS(gethostbyname, [nsl])
 191 AC_SEARCH_LIBS(dlopen, [dl])
 192 AC_SEARCH_LIBS(inet_aton, [resolv])
 193
 194 if test "$enable_threads" = "yes"; then
 195   AC_SEARCH_LIBS(pthread_create, [pthread])
 196   AC_SEARCH_LIBS(pthread_detach, [pthread])
 197 fi
 198
 199 dnl -------------------------------------------------------------------
 200 dnl Check for functions before libevent, since libevent-1.2 apparently
 201 dnl exports strlcpy without defining it in a header.
 202
 203 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl vasprintf)
 204
 205 using_custom_malloc=no
 206 if test x$enable_openbsd_malloc = xyes ; then
 207    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 208    using_custom_malloc=yes
 209 fi
 210 if test x$tcmalloc = xyes ; then
 211    using_custom_malloc=yes
 212 fi
 213 if test $using_custom_malloc = no ; then
 214    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 215 fi
 216
 217 if test "$enable_threads" = "yes"; then
 218   AC_CHECK_HEADERS(pthread.h)
 219   AC_CHECK_FUNCS(pthread_create)
 220 fi
 221
 222 dnl ------------------------------------------------------
 223 dnl Where do you live, libevent?  And how do we call you?
 224
 225 if test "$bwin32" = true; then
 226   TOR_LIB_WS32=-lws2_32
 227   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 228   # think it's actually necessary.
 229   TOR_LIB_GDI=-lgdi32
 230 else
 231   TOR_LIB_WS32=
 232   TOR_LIB_GDI=
 233 fi
 234 AC_SUBST(TOR_LIB_WS32)
 235 AC_SUBST(TOR_LIB_GDI)
 236
 237 dnl We need to do this before we try our disgusting hack below.
 238 AC_CHECK_HEADERS([sys/types.h])
 239
 240 dnl This is a disgusting hack so we safely include older libevent headers.
 241 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 242 AC_CHECK_TYPE(u_int32_t, unsigned long)
 243 AC_CHECK_TYPE(u_int16_t, unsigned short)
 244 AC_CHECK_TYPE(u_int8_t, unsigned char)
 245
 246 tor_libevent_pkg_redhat="libevent"
 247 tor_libevent_pkg_debian="libevent-dev"
 248 tor_libevent_devpkg_redhat="libevent-devel"
 249 tor_libevent_devpkg_debian="libevent-dev"
 250
 251 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 252 #ifdef WIN32
 253 #include <winsock2.h>
 254 #endif
 255 #include <stdlib.h>
 256 #include <sys/time.h>
 257 #include <sys/types.h>
 258 #include <event.h>], [
 259 #ifdef WIN32
 260 #include <winsock2.h>
 261 #endif
 262 void exit(int); void *event_init(void);],
 263     [
 264 #ifdef WIN32
 265 {WSADATA d; WSAStartup(0x101,&d); }
 266 #endif
 267 event_init(); exit(0);
 268 ], [--with-libevent-dir], [/opt/libevent])
 269
 270 dnl Now check for particular libevent functions.
 271 save_LIBS="$LIBS"
 272 save_LDFLAGS="$LDFLAGS"
 273 save_CPPFLAGS="$CPPFLAGS"
 274 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 275 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 276 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 277 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 278 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 279 [#include <event.h>
 280 ])
 281
 282 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 283
 284 LIBS="$save_LIBS"
 285 LDFLAGS="$save_LDFLAGS"
 286 CPPFLAGS="$save_CPPFLAGS"
 287
 288
 289 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 290
 291 if test "$enable_static_libevent" = "yes"; then
 292    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 293      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 294    else
 295      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a"
 296    fi
 297 else
 298      TOR_LIBEVENT_LIBS="-levent"
 299 fi
 300 AC_SUBST(TOR_LIBEVENT_LIBS)
 301
 302
 303 dnl ------------------------------------------------------
 304 dnl Where do you live, openssl?  And how do we call you?
 305
 306 tor_openssl_pkg_redhat="openssl"
 307 tor_openssl_pkg_debian="libssl"
 308 tor_openssl_devpkg_redhat="openssl-devel"
 309 tor_openssl_devpkg_debian="libssl-dev"
 310
 311 ALT_openssl_WITHVAL=""
 312 AC_ARG_WITH(ssl-dir,
 313   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 314   [
 315       if test "x$withval" != xno && test "x$withval" != "x" ; then
 316          ALT_openssl_WITHVAL="$withval"
 317       fi
 318   ])
 319
 320 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 321     [#include <openssl/rand.h>],
 322     [void RAND_add(const void *buf, int num, double entropy);],
 323     [RAND_add((void*)0,0,0); exit(0);], [],
 324     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 325
 326 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 327
 328 echo "tor_cv_library_openssl_dir is $tor_cv_library_openssl_dir"
 329 if test "$enable_static_openssl" = "yes"; then
 330    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 331      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 332    else
 333      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 334    fi
 335 else
 336      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 337 fi
 338 AC_SUBST(TOR_OPENSSL_LIBS)
 339
 340 dnl ------------------------------------------------------
 341 dnl Where do you live, zlib?  And how do we call you?
 342
 343 tor_openssl_pkg_redhat="zlib"
 344 tor_openssl_pkg_debian="zlib1g"
 345 tor_openssl_devpkg_redhat="zlib-devel"
 346 tor_openssl_devpkg_debian="zlib1g-dev"
 347
 348 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 349     [#include <zlib.h>],
 350     [const char * zlibVersion(void);],
 351     [zlibVersion(); exit(0);], [--with-zlib-dir],
 352     [/opt/zlib])
 353
 354 dnl Make sure to enable support for large off_t if available.
 355
 356 AC_SYS_LARGEFILE
 357
 358 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 359
 360 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 361
 362 dnl These headers are not essential
 363
 364 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 365
 366 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 367 [#ifdef HAVE_MALLOC_H
 368 #include <malloc.h>
 369 #endif
 370 #ifdef HAVE_MALLOC_MALLOC_H
 371 #include <malloc/malloc.h>
 372 #endif])
 373
 374 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 375 [#ifdef HAVE_SYS_TYPES_H
 376 #include <sys/types.h>
 377 #endif
 378 #ifdef HAVE_SYS_SOCKET_H
 379 #include <sys/socket.h>
 380 #endif])
 381 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 382 [#ifdef HAVE_SYS_TYPES_H
 383 #include <sys/types.h>
 384 #endif
 385 #ifdef HAVE_SYS_SOCKET_H
 386 #include <sys/socket.h>
 387 #endif
 388 #ifdef HAVE_NET_IF_H
 389 #include <net/if.h>
 390 #endif])
 391 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 392         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 393 [#ifdef HAVE_SYS_TYPES_H
 394 #include <sys/types.h>
 395 #endif
 396 #ifdef HAVE_SYS_SOCKET_H
 397 #include <sys/socket.h>
 398 #endif
 399 #ifdef HAVE_LIMITS_H
 400 #include <limits.h>
 401 #endif
 402 #ifdef HAVE_LINUX_TYPES_H
 403 #include <linux/types.h>
 404 #endif
 405 #ifdef HAVE_NETINET_IN6_H
 406 #include <netinet/in6.h>
 407 #endif
 408 #ifdef HAVE_NETINET_IN_H
 409 #include <netinet/in.h>
 410 #endif])
 411
 412 if test x$transparent = xtrue ; then
 413    transparent_ok=0
 414    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 415      transparent_ok=1
 416    fi
 417    if test x$linux_netfilter_ipv4 = x1 ; then
 418      transparent_ok=1
 419    fi
 420    if test x$transparent_ok = x1 ; then
 421      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 422      case $host in
 423        *-*-openbsd*)
 424          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 425      esac
 426    else
 427      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 428    fi
 429 fi
 430
 431 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 432 [#ifdef HAVE_SYS_TYPES_H
 433 #include <sys/types.h>
 434 #endif
 435 #ifdef HAVE_SYS_TIME_H
 436 #include <sys/time.h>
 437 #endif])
 438
 439 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 440 dnl Watch out.
 441
 442 AC_CHECK_SIZEOF(int8_t)
 443 AC_CHECK_SIZEOF(int16_t)
 444 AC_CHECK_SIZEOF(int32_t)
 445 AC_CHECK_SIZEOF(int64_t)
 446 AC_CHECK_SIZEOF(uint8_t)
 447 AC_CHECK_SIZEOF(uint16_t)
 448 AC_CHECK_SIZEOF(uint32_t)
 449 AC_CHECK_SIZEOF(uint64_t)
 450 AC_CHECK_SIZEOF(intptr_t)
 451 AC_CHECK_SIZEOF(uintptr_t)
 452
 453 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 454
 455 AC_CHECK_SIZEOF(char)
 456 AC_CHECK_SIZEOF(short)
 457 AC_CHECK_SIZEOF(int)
 458 AC_CHECK_SIZEOF(long)
 459 AC_CHECK_SIZEOF(long long)
 460 AC_CHECK_SIZEOF(__int64)
 461 AC_CHECK_SIZEOF(void *)
 462 AC_CHECK_SIZEOF(time_t)
 463 AC_CHECK_SIZEOF(size_t)
 464
 465 AC_CHECK_TYPES([uint, u_char, ssize_t])
 466
 467 dnl used to include sockaddr_storage, but everybody has that.
 468 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 469 [#ifdef HAVE_SYS_TYPES_H
 470 #include <sys/types.h>
 471 #endif
 472 #ifdef HAVE_NETINET_IN_H
 473 #include <netinet/in.h>
 474 #endif
 475 #ifdef HAVE_NETINET_IN6_H
 476 #include <netinet/in6.h>
 477 #endif
 478 #ifdef HAVE_SYS_SOCKET_H
 479 #include <sys/socket.h>
 480 #endif
 481 #ifdef MS_WINDOWS
 482 #define WIN32_WINNT 0x400
 483 #define _WIN32_WINNT 0x400
 484 #define WIN32_LEAN_AND_MEAN
 485 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 486 #include <winsock.h>
 487 #else
 488 #include <winsock2.h>
 489 #include <ws2tcpip.h>
 490 #endif
 491 #endif
 492 ])
 493 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 494 [#ifdef HAVE_SYS_TYPES_H
 495 #include <sys/types.h>
 496 #endif
 497 #ifdef HAVE_NETINET_IN_H
 498 #include <netinet/in.h>
 499 #endif
 500 #ifdef HAVE_NETINET_IN6_H
 501 #include <netinet/in6.h>
 502 #endif
 503 #ifdef HAVE_SYS_SOCKET_H
 504 #include <sys/socket.h>
 505 #endif
 506 #ifdef MS_WINDOWS
 507 #define WIN32_WINNT 0x400
 508 #define _WIN32_WINNT 0x400
 509 #define WIN32_LEAN_AND_MEAN
 510 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 511 #include <winsock.h>
 512 #else
 513 #include <winsock2.h>
 514 #include <ws2tcpip.h>
 515 #endif
 516 #endif
 517 ])
 518
 519 AC_CHECK_TYPES([rlim_t], , ,
 520 [#ifdef HAVE_SYS_TYPES_H
 521 #include <sys/types.h>
 522 #endif
 523 #ifdef HAVE_SYS_TIME_H
 524 #include <sys/time.h>
 525 #endif
 526 #ifdef HAVE_SYS_RESOURCE_H
 527 #include <sys/resource.h>
 528 #endif
 529 ])
 530
 531 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 532 AC_RUN_IFELSE(AC_LANG_SOURCE([
 533 #ifdef HAVE_SYS_TYPES_H
 534 #include <sys/types.h>
 535 #endif
 536 #ifdef HAVE_SYS_TIME_H
 537 #include <sys/time.h>
 538 #endif
 539 #ifdef HAVE_TIME_H
 540 #include <time.h>
 541 #endif
 542 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 543   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 544 ])
 545
 546 if test "$tor_cv_time_t_signed" = cross; then
 547   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 548 fi
 549
 550 if test "$tor_cv_time_t_signed" != no; then
 551   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 552             [Define to 1 iff time_t is signed])
 553 fi
 554
 555 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 556 #ifdef HAVE_SYS_SOCKET_H
 557 #include <sys/socket.h>
 558 #endif
 559 ])
 560
 561 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 562
 563 AC_CHECK_SIZEOF(cell_t)
 564
 565 # Now make sure that NULL can be represented as zero bytes.
 566 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 567 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 568 [[#include <stdlib.h>
 569 #include <string.h>
 570 #include <stdio.h>
 571 #ifdef HAVE_STDDEF_H
 572 #include <stddef.h>
 573 #endif
 574 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 575 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 576        [tor_cv_null_is_zero=yes],
 577        [tor_cv_null_is_zero=no],
 578        [tor_cv_null_is_zero=cross])])
 579
 580 if test "$tor_cv_null_is_zero" = cross ; then
 581   # Cross-compiling; let's hope that the target isn't raving mad.
 582   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 583 fi
 584
 585 if test "$tor_cv_null_is_zero" != no; then
 586   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 587             [Define to 1 iff memset(0) sets pointers to NULL])
 588 fi
 589
 590 # And what happens when we malloc zero?
 591 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 592 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 593 [[#include <stdlib.h>
 594 #include <string.h>
 595 #include <stdio.h>
 596 #ifdef HAVE_STDDEF_H
 597 #include <stddef.h>
 598 #endif
 599 int main () { return malloc(0)?0:1; }]])],
 600        [tor_cv_malloc_zero_works=yes],
 601        [tor_cv_malloc_zero_works=no],
 602        [tor_cv_malloc_zero_works=cross])])
 603
 604 if test "$tor_cv_malloc_zero_works" = cross; then
 605   # Cross-compiling; let's hope that the target isn't raving mad.
 606   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 607 fi
 608
 609 if test "$tor_cv_malloc_zero_works" = yes; then
 610   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 611             [Define to 1 iff malloc(0) returns a pointer])
 612 fi
 613
 614 # whether we seem to be in a 2s-complement world.
 615 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 616 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 617 [[int main () { int problem = ((-99) != (~99)+1);
 618 return problem ? 1 : 0; }]])],
 619        [tor_cv_twos_complement=yes],
 620        [tor_cv_twos_complement=no],
 621        [tor_cv_twos_complement=cross])])
 622
 623 if test "$tor_cv_twos_complement" = cross ; then
 624   # Cross-compiling; let's hope that the target isn't raving mad.
 625   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 626 fi
 627
 628 if test "$tor_cv_twos_complement" != no ; then
 629   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 630             [Define to 1 iff we represent negative integers with two's complement])
 631 fi
 632
 633 # Whether we should use the dmalloc memory allocation debugging library.
 634 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 635 AC_ARG_WITH(dmalloc,
 636 [  --with-dmalloc          Use debug memory allocation library. ],
 637 [if [[ "$withval" = "yes" ]]; then
 638   dmalloc=1
 639   AC_MSG_RESULT(yes)
 640 else
 641   dmalloc=1
 642   AC_MSG_RESULT(no)
 643 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 644 )
 645
 646 if [[ $dmalloc -eq 1 ]]; then
 647   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 648   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 649   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 650   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 651   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 652 fi
 653
 654 AC_ARG_WITH(tcmalloc,
 655 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 656 [ tcmalloc=yes ], [ tcmalloc=no ])
 657
 658 if test x$tcmalloc = xyes ; then
 659    LDFLAGS="-ltcmalloc $LDFLAGS"
 660 fi
 661
 662 # By default, we're going to assume we don't have mlockall()
 663 # bionic and other platforms have various broken mlockall subsystems.
 664 # Some systems don't have a working mlockall, some aren't linkable,
 665 # and some have it but don't declare it.
 666 AC_CHECK_FUNCS(mlockall)
 667 AC_CHECK_DECLS([mlockall], , , [
 668 #ifdef HAVE_SYS_MMAN_H
 669 #include <sys/mman.h>
 670 #endif])
 671
 672 # Allow user to specify an alternate syslog facility
 673 AC_ARG_WITH(syslog-facility,
 674 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 675 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 676 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 677 AC_SUBST(LOGFACILITY)
 678
 679 # Check if we have getresuid and getresgid
 680 AC_CHECK_FUNCS(getresuid getresgid)
 681
 682 # Check for gethostbyname_r in all its glorious incompatible versions.
 683 #   (This logic is based on that in Python's configure.in)
 684 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 685   [Define this if you have any gethostbyname_r()])
 686
 687 AC_CHECK_FUNC(gethostbyname_r, [
 688   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 689   OLD_CFLAGS=$CFLAGS
 690   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 691   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 692 #include <netdb.h>
 693   ], [[
 694     char *cp1, *cp2;
 695     struct hostent *h1, *h2;
 696     int i1, i2;
 697     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 698   ]]),[
 699     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 700     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 701      [Define this if gethostbyname_r takes 6 arguments])
 702     AC_MSG_RESULT(6)
 703   ], [
 704     AC_TRY_COMPILE([
 705 #include <netdb.h>
 706     ], [
 707       char *cp1, *cp2;
 708       struct hostent *h1;
 709       int i1, i2;
 710       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 711     ], [
 712       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 713       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 714         [Define this if gethostbyname_r takes 5 arguments])
 715       AC_MSG_RESULT(5)
 716    ], [
 717       AC_TRY_COMPILE([
 718 #include <netdb.h>
 719      ], [
 720        char *cp1;
 721        struct hostent *h1;
 722        struct hostent_data hd;
 723        (void) gethostbyname_r(cp1,h1,&hd);
 724      ], [
 725        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 726        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 727          [Define this if gethostbyname_r takes 3 arguments])
 728        AC_MSG_RESULT(3)
 729      ], [
 730        AC_MSG_RESULT(0)
 731      ])
 732   ])
 733  ])
 734  CFLAGS=$OLD_CFLAGS
 735 ])
 736
 737 AC_CACHE_CHECK([whether the C compiler supports __func__],
 738   tor_cv_have_func_macro,
 739   AC_COMPILE_IFELSE([
 740 #include <stdio.h>
 741 int main(int c, char **v) { puts(__func__); }],
 742   tor_cv_have_func_macro=yes,
 743   tor_cv_have_func_macro=no))
 744
 745 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 746   tor_cv_have_FUNC_macro,
 747   AC_COMPILE_IFELSE([
 748 #include <stdio.h>
 749 int main(int c, char **v) { puts(__FUNC__); }],
 750   tor_cv_have_FUNC_macro=yes,
 751   tor_cv_have_FUNC_macro=no))
 752
 753 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 754   tor_cv_have_FUNCTION_macro,
 755   AC_COMPILE_IFELSE([
 756 #include <stdio.h>
 757 int main(int c, char **v) { puts(__FUNCTION__); }],
 758   tor_cv_have_FUNCTION_macro=yes,
 759   tor_cv_have_FUNCTION_macro=no))
 760
 761 if test "$tor_cv_have_func_macro" = 'yes'; then
 762   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 763 fi
 764
 765 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 766   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 767 fi
 768
 769 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 770   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 771            [Defined if the compiler supports __FUNCTION__])
 772 fi
 773
 774 # $prefix stores the value of the --prefix command line option, or
 775 # NONE if the option wasn't set.  In the case that it wasn't set, make
 776 # it be the default, so that we can use it to expand directories now.
 777 if test "x$prefix" = "xNONE"; then
 778   prefix=$ac_default_prefix
 779 fi
 780
 781 # and similarly for $exec_prefix
 782 if test "x$exec_prefix" = "xNONE"; then
 783   exec_prefix=$prefix
 784 fi
 785
 786 if test "x$CONFDIR" = "x"; then
 787   CONFDIR=`eval echo $sysconfdir/tor`
 788 fi
 789 AC_SUBST(CONFDIR)
 790 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 791 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 792
 793 BINDIR=`eval echo $bindir`
 794 AC_SUBST(BINDIR)
 795 LOCALSTATEDIR=`eval echo $localstatedir`
 796 AC_SUBST(LOCALSTATEDIR)
 797
 798 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 799 # than autoconf's macros like.
 800 if test "$GCC" = yes; then
 801   CFLAGS="$CFLAGS -Wall -g -O2"
 802   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 803   # accident waiting to happen.
 804   CFLAGS="$CFLAGS -fno-strict-aliasing"
 805 else
 806   CFLAGS="$CFLAGS -g -O"
 807   enable_gcc_warnings=no
 808   enable_gcc_warnings_advisory=no
 809 fi
 810
 811 # Add some more warnings which we use in development but not in the
 812 # released versions.  (Some relevant gcc versions can't handle these.)
 813 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
 814
 815   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 816 #if !defined(__GNUC__) || (__GNUC__ < 4)
 817 #error
 818 #endif]), have_gcc4=yes, have_gcc4=no)
 819
 820   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 821 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 822 #error
 823 #endif]), have_gcc42=yes, have_gcc42=no)
 824
 825   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 826 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 827 #error
 828 #endif]), have_gcc43=yes, have_gcc43=no)
 829
 830   save_CFLAGS="$CFLAGS"
 831   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 832   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 833                     have_shorten64_flag=no)
 834   CFLAGS="$save_CFLAGS"
 835
 836   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum"
 837   if test x$enable_gcc_warnings = xyes; then
 838     CFLAGS="$CFLAGS -Werror"
 839   fi
 840
 841   # Disabled, so we can use mallinfo(): -Waggregate-return
 842
 843   if test x$have_gcc4 = xyes ; then
 844     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 845     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 846   fi
 847
 848   if test x$have_gcc42 = xyes ; then
 849     # These warnings break gcc 4.0.2 and work on gcc 4.2
 850     # XXXX020 Use -fstack-protector.
 851     # XXXX020 See if any of these work with earlier versions.
 852     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 853     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 854   fi
 855
 856   if test x$have_gcc43 = xyes ; then
 857     # These warnings break gcc 4.2 and work on gcc 4.3
 858     # XXXX020 See if any of these work with earlier versions.
 859     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 860   fi
 861
 862   if test x$have_shorten64_flag = xyes ; then
 863     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 864   fi
 865
 866 ##This will break the world on some 64-bit architectures
 867 # CFLAGS="$CFLAGS -Winline"
 868 fi
 869
 870
 871
 872 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 873
 874 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample src/Makefile doc/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/test/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 875 AC_OUTPUT
 876
 877 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 878   ./contrib/updateVersions.pl
 879 fi
 880