| blob | f6edb3a5139f2f5c975b5f74fa96d603f3bf0162 |
1 dnl Copyright (c) 2001-2004, Roger Dingledine
2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
3 dnl Copyright (c) 2007-2015, The Tor Project, Inc.
4 dnl See LICENSE for licensing information
6 AC_PREREQ([2.63])
7 AC_INIT([tor],[0.2.9.3-alpha-dev])
8 AC_CONFIG_SRCDIR([src/or/main.c])
9 AC_CONFIG_MACRO_DIR([m4])
11 # "foreign" means we don't follow GNU package layout standards
12 # "1.11" means we require automake version 1.11 or newer
13 # "subdir-objects" means put .o files in the same directory as the .c files
14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects])
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17 AC_CONFIG_HEADERS([orconfig.h])
19 AC_USE_SYSTEM_EXTENSIONS
20 AC_CANONICAL_HOST
22 PKG_PROG_PKG_CONFIG
24 if test -f "/etc/redhat-release"; then
25 if test -f "/usr/kerberos/include"; then
26 CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
27 fi
28 fi
30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
31 # the += operator on it in src/or/Makefile.am
32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
34 AC_ARG_ENABLE(openbsd-malloc,
35 AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD. Linux only]))
36 AC_ARG_ENABLE(static-openssl,
37 AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
38 AC_ARG_ENABLE(static-libevent,
39 AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
40 AC_ARG_ENABLE(static-zlib,
41 AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
42 AC_ARG_ENABLE(static-tor,
43 AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
44 AC_ARG_ENABLE(unittests,
45 AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
46 AC_ARG_ENABLE(coverage,
47 AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
48 AC_ARG_ENABLE(asserts-in-tests,
49 AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
50 AC_ARG_ENABLE(system-torrc,
51 AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
53 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
54 AC_MSG_ERROR([Can't disable assertions outside of coverage build])
55 fi
57 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
58 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
59 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
61 if test "$enable_static_tor" = "yes"; then
62 enable_static_libevent="yes";
63 enable_static_openssl="yes";
64 enable_static_zlib="yes";
65 CFLAGS="$CFLAGS -static"
66 fi
68 if test "$enable_system_torrc" = "no"; then
69 AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
70 [Defined if we're not going to look for a torrc in SYSCONF])
71 fi
73 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
75 AC_ARG_ENABLE(asciidoc,
76 AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
77 [case "${enableval}" in
78 "yes") asciidoc=true ;;
79 "no") asciidoc=false ;;
80 *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
81 esac], [asciidoc=true])
83 # systemd notify support
84 AC_ARG_ENABLE(systemd,
85 AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
86 [case "${enableval}" in
87 "yes") systemd=true ;;
88 "no") systemd=false ;;
89 * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
90 esac], [systemd=auto])
94 # systemd support
95 if test "x$enable_systemd" = "xno"; then
96 have_systemd=no;
97 else
98 PKG_CHECK_MODULES(SYSTEMD,
99 [libsystemd-daemon],
100 have_systemd=yes,
101 have_systemd=no)
102 if test "x$have_systemd" = "xno"; then
103 AC_MSG_NOTICE([Okay, checking for systemd a different way...])
104 PKG_CHECK_MODULES(SYSTEMD,
105 [libsystemd],
106 have_systemd=yes,
107 have_systemd=no)
108 fi
109 fi
111 if test "x$have_systemd" = "xyes"; then
112 AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
113 TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
114 TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
115 PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
116 [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
117 fi
118 AC_SUBST(TOR_SYSTEMD_CFLAGS)
119 AC_SUBST(TOR_SYSTEMD_LIBS)
121 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
122 AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
123 fi
125 case "$host" in
126 *-*-solaris* )
127 AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
128 ;;
129 esac
131 AC_ARG_ENABLE(gcc-warnings,
132 AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
133 AC_ARG_ENABLE(fatal-warnings,
134 AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
135 AC_ARG_ENABLE(gcc-warnings-advisory,
136 AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
138 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
139 AC_ARG_ENABLE(gcc-hardening,
140 AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
142 AC_ARG_ENABLE(expensive-hardening,
143 AS_HELP_STRING(--enable-expensive-hardening, [enable more expensive compiler hardening; makes Tor slower]))
145 dnl Linker hardening options
146 dnl Currently these options are ELF specific - you can't use this with MacOSX
147 AC_ARG_ENABLE(linker-hardening,
148 AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
150 AC_ARG_ENABLE(local-appdata,
151 AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
152 if test "$enable_local_appdata" = "yes"; then
153 AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
154 [Defined if we default to host local appdata paths on Windows])
155 fi
157 # Tor2web mode flag
158 AC_ARG_ENABLE(tor2web-mode,
159 AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
160 [if test "x$enableval" = "xyes"; then
161 CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
162 fi])
164 AC_ARG_ENABLE(tool-name-check,
165 AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
167 AC_ARG_ENABLE(seccomp,
168 AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
170 AC_ARG_ENABLE(libscrypt,
171 AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
173 dnl check for the correct "ar" when cross-compiling
174 AN_MAKEVAR([AR], [AC_PROG_AR])
175 AN_PROGRAM([ar], [AC_PROG_AR])
176 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
177 AC_PROG_AR
179 dnl Check whether the above macro has settled for a simply named tool even
180 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
181 dnl because that will find any cc on the system, not only the cross-compiler,
182 dnl and then verify that a binary built with this compiler runs on the
183 dnl build system. It will then come to the false conclusion that we're not
184 dnl cross-compiling.
185 if test "x$enable_tool_name_check" != "xno"; then
186 if test "x$ac_tool_warned" = "xyes"; then
187 AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
188 elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
189 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
190 fi
191 fi
193 AC_PROG_CC
194 AC_PROG_CPP
195 AC_PROG_MAKE_SET
196 AC_PROG_RANLIB
198 AC_PATH_PROG([PERL], [perl])
200 dnl autoconf 2.59 appears not to support AC_PROG_SED
201 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
203 dnl check for asciidoc and a2x
204 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
205 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
207 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
209 AM_CONDITIONAL(USE_FW_HELPER, test "x$natpmp" = "xtrue" || test "x$upnp" = "xtrue")
210 AM_CONDITIONAL(NAT_PMP, test "x$natpmp" = "xtrue")
211 AM_CONDITIONAL(MINIUPNPC, test "x$upnp" = "xtrue")
212 AM_PROG_CC_C_O
213 AC_PROG_CC_C99
215 AC_ARG_VAR([PYTHON], [path to Python binary])
216 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
217 if test "x$PYTHON" = "x"; then
218 AC_MSG_WARN([Python unavailable; some tests will not be run.])
219 fi
220 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
222 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
223 AC_C_FLEXIBLE_ARRAY_MEMBER
224 ], [
225 dnl Maybe we've got an old autoconf...
226 AC_CACHE_CHECK([for flexible array members],
227 tor_cv_c_flexarray,
228 [AC_COMPILE_IFELSE(
229 AC_LANG_PROGRAM([
230 struct abc { int a; char b[]; };
231 ], [
232 struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
233 def->b[0] = 33;
234 ]),
235 [tor_cv_c_flexarray=yes],
236 [tor_cv_c_flexarray=no])])
237 if test "$tor_cv_flexarray" = "yes"; then
238 AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
239 else
240 AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
241 fi
242 ])
244 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
245 tor_cv_c_c99_decl,
246 [AC_COMPILE_IFELSE(
247 [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
248 [tor_cv_c_c99_decl=yes],
249 [tor_cv_c_c99_decl=no] )])
250 if test "$tor_cv_c_c99_decl" != "yes"; then
251 AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
252 fi
254 AC_CACHE_CHECK([for working C99 designated initializers],
255 tor_cv_c_c99_designated_init,
256 [AC_COMPILE_IFELSE(
257 [AC_LANG_PROGRAM([struct s { int a; int b; };],
258 [[ struct s ss = { .b = 5, .a = 6 }; ]])],
259 [tor_cv_c_c99_designated_init=yes],
260 [tor_cv_c_c99_designated_init=no] )])
262 if test "$tor_cv_c_c99_designated_init" != "yes"; then
263 AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
264 fi
266 TORUSER=_tor
267 AC_ARG_WITH(tor-user,
268 AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
269 [
270 TORUSER=$withval
271 ]
272 )
273 AC_SUBST(TORUSER)
275 TORGROUP=_tor
276 AC_ARG_WITH(tor-group,
277 AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
278 [
279 TORGROUP=$withval
280 ]
281 )
282 AC_SUBST(TORGROUP)
285 dnl If _WIN32 is defined and non-zero, we are building for win32
286 AC_MSG_CHECKING([for win32])
287 AC_RUN_IFELSE([AC_LANG_SOURCE([
288 int main(int c, char **v) {
289 #ifdef _WIN32
290 #if _WIN32
291 return 0;
292 #else
293 return 1;
294 #endif
295 #else
296 return 2;
297 #endif
298 }])],
299 bwin32=true; AC_MSG_RESULT([yes]),
300 bwin32=false; AC_MSG_RESULT([no]),
301 bwin32=cross; AC_MSG_RESULT([cross])
302 )
304 if test "$bwin32" = "cross"; then
305 AC_MSG_CHECKING([for win32 (cross)])
306 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
307 #ifdef _WIN32
308 int main(int c, char **v) {return 0;}
309 #else
310 #error
311 int main(int c, char **v) {return x(y);}
312 #endif
313 ])],
314 bwin32=true; AC_MSG_RESULT([yes]),
315 bwin32=false; AC_MSG_RESULT([no]))
316 fi
318 AH_BOTTOM([
319 #ifdef _WIN32
320 /* Defined to access windows functions and definitions for >=WinXP */
321 # ifndef WINVER
322 # define WINVER 0x0501
323 # endif
325 /* Defined to access _other_ windows functions and definitions for >=WinXP */
326 # ifndef _WIN32_WINNT
327 # define _WIN32_WINNT 0x0501
328 # endif
330 /* Defined to avoid including some windows headers as part of Windows.h */
331 # ifndef WIN32_LEAN_AND_MEAN
332 # define WIN32_LEAN_AND_MEAN 1
333 # endif
334 #endif
335 ])
338 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
340 dnl Enable C99 when compiling with MIPSpro
341 AC_MSG_CHECKING([for MIPSpro compiler])
342 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
343 #if (defined(__sgi) && defined(_COMPILER_VERSION))
344 #error
345 return x(y);
346 #endif
347 ])],
348 bmipspro=false; AC_MSG_RESULT(no),
349 bmipspro=true; AC_MSG_RESULT(yes))
351 if test "$bmipspro" = "true"; then
352 CFLAGS="$CFLAGS -c99"
353 fi
355 AC_C_BIGENDIAN
357 AC_SEARCH_LIBS(socket, [socket network])
358 AC_SEARCH_LIBS(gethostbyname, [nsl])
359 AC_SEARCH_LIBS(dlopen, [dl])
360 AC_SEARCH_LIBS(inet_aton, [resolv])
361 AC_SEARCH_LIBS(backtrace, [execinfo])
362 saved_LIBS="$LIBS"
363 AC_SEARCH_LIBS([clock_gettime], [rt])
364 if test "$LIBS" != "$saved_LIBS"; then
365 # Looks like we need -lrt for clock_gettime().
366 have_rt=yes
367 fi
369 AC_SEARCH_LIBS(pthread_create, [pthread])
370 AC_SEARCH_LIBS(pthread_detach, [pthread])
372 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
373 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
375 AC_CHECK_FUNCS(
376 _NSGetEnviron \
377 RtlSecureZeroMemory \
378 SecureZeroMemory \
379 accept4 \
380 backtrace \
381 backtrace_symbols_fd \
382 clock_gettime \
383 eventfd \
384 explicit_bzero \
385 timingsafe_memcmp \
386 flock \
387 ftime \
388 getaddrinfo \
389 getentropy \
390 getifaddrs \
391 getpass \
392 getrlimit \
393 gettimeofday \
394 gmtime_r \
395 htonll \
396 inet_aton \
397 ioctl \
398 issetugid \
399 llround \
400 localtime_r \
401 lround \
402 memmem \
403 memset_s \
404 pipe \
405 pipe2 \
406 prctl \
407 readpassphrase \
408 rint \
409 sigaction \
410 socketpair \
411 statvfs \
412 strlcat \
413 strlcpy \
414 strnlen \
415 strptime \
416 strtok_r \
417 strtoull \
418 sysconf \
419 sysctl \
420 truncate \
421 uname \
422 usleep \
423 vasprintf \
424 _vscprintf
425 )
427 if test "$bwin32" != "true"; then
428 AC_CHECK_HEADERS(pthread.h)
429 AC_CHECK_FUNCS(pthread_create)
430 AC_CHECK_FUNCS(pthread_condattr_setclock)
431 fi
433 if test "$bwin32" = "true"; then
434 AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
435 #include <windows.h>
436 #include <conio.h>
437 #include <wchar.h>
438 ])
439 fi
441 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
442 test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
444 dnl ------------------------------------------------------
445 dnl Where do you live, libevent? And how do we call you?
447 if test "$bwin32" = "true"; then
448 TOR_LIB_WS32=-lws2_32
449 TOR_LIB_IPHLPAPI=-liphlpapi
450 # Some of the cargo-cults recommend -lwsock32 as well, but I don't
451 # think it's actually necessary.
452 TOR_LIB_GDI=-lgdi32
453 else
454 TOR_LIB_WS32=
455 TOR_LIB_GDI=
456 fi
457 AC_SUBST(TOR_LIB_WS32)
458 AC_SUBST(TOR_LIB_GDI)
459 AC_SUBST(TOR_LIB_IPHLPAPI)
461 tor_libevent_pkg_redhat="libevent"
462 tor_libevent_pkg_debian="libevent-dev"
463 tor_libevent_devpkg_redhat="libevent-devel"
464 tor_libevent_devpkg_debian="libevent-dev"
466 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
467 dnl linking for static builds.
468 STATIC_LIBEVENT_FLAGS=""
469 if test "$enable_static_libevent" = "yes"; then
470 if test "$have_rt" = "yes"; then
471 STATIC_LIBEVENT_FLAGS=" -lrt "
472 fi
473 fi
475 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
476 #ifdef _WIN32
477 #include <winsock2.h>
478 #endif
479 #include <sys/time.h>
480 #include <sys/types.h>
481 #include <event2/event.h>], [
482 #ifdef _WIN32
483 #include <winsock2.h>
484 #endif
485 void *event_init(void);],
486 [
487 #ifdef _WIN32
488 {WSADATA d; WSAStartup(0x101,&d); }
489 #endif
490 event_init();
491 ], [--with-libevent-dir], [/opt/libevent])
493 dnl Now check for particular libevent functions.
494 save_LIBS="$LIBS"
495 save_LDFLAGS="$LDFLAGS"
496 save_CPPFLAGS="$CPPFLAGS"
497 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
498 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
499 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
500 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
501 evutil_secure_rng_add_bytes \
502 ])
504 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
506 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
508 if test "$enable_static_libevent" = "yes"; then
509 if test "$tor_cv_library_libevent_dir" = "(system)"; then
510 AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
511 else
512 TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
513 fi
514 else
515 if test "x$ac_cv_header_event2_event_h" = "xyes"; then
516 AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
517 AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
519 if test "$ac_cv_search_event_new" != "none required"; then
520 TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
521 fi
522 if test "$ac_cv_search_evdns_base_new" != "none required"; then
523 TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
524 fi
525 else
526 AC_MSG_ERROR("libevent2 is required but the headers could not be found")
527 fi
528 fi
530 LIBS="$save_LIBS"
531 LDFLAGS="$save_LDFLAGS"
532 CPPFLAGS="$save_CPPFLAGS"
534 dnl Check that libevent is at least at version 2.0.10, the first stable
535 dnl release of its series
536 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
537 AC_MSG_CHECKING([whether Libevent is new enough])
538 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
539 #include <event2/event.h>
540 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
541 #error
542 int x = y(zz);
543 #else
544 int x = 1;
545 #endif
546 ])], [ AC_MSG_RESULT([yes]) ],
547 [ AC_MSG_RESULT([no])
548 AC_MSG_ERROR([Libevent is not new enough. We require 2.0.10-stable or later]) ] )
550 LIBS="$save_LIBS"
551 LDFLAGS="$save_LDFLAGS"
552 CPPFLAGS="$save_CPPFLAGS"
554 AC_SUBST(TOR_LIBEVENT_LIBS)
556 dnl ------------------------------------------------------
557 dnl Where do you live, libm?
559 dnl On some platforms (Haiku/BeOS) the math library is
560 dnl part of libroot. In which case don't link against lm
561 TOR_LIB_MATH=""
562 save_LIBS="$LIBS"
563 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
564 if test "$ac_cv_search_pow" != "none required"; then
565 TOR_LIB_MATH="$ac_cv_search_pow"
566 fi
567 LIBS="$save_LIBS"
568 AC_SUBST(TOR_LIB_MATH)
570 dnl ------------------------------------------------------
571 dnl Where do you live, openssl? And how do we call you?
573 tor_openssl_pkg_redhat="openssl"
574 tor_openssl_pkg_debian="libssl-dev"
575 tor_openssl_devpkg_redhat="openssl-devel"
576 tor_openssl_devpkg_debian="libssl-dev"
578 ALT_openssl_WITHVAL=""
579 AC_ARG_WITH(ssl-dir,
580 AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
581 [
582 if test "x$withval" != "xno" && test "x$withval" != "x"; then
583 ALT_openssl_WITHVAL="$withval"
584 fi
585 ])
587 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
588 [#include <openssl/rand.h>],
589 [void RAND_add(const void *buf, int num, double entropy);],
590 [RAND_add((void*)0,0,0);], [],
591 [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
593 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
595 if test "$enable_static_openssl" = "yes"; then
596 if test "$tor_cv_library_openssl_dir" = "(system)"; then
597 AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
598 else
599 TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
600 fi
601 else
602 TOR_OPENSSL_LIBS="-lssl -lcrypto"
603 fi
604 AC_SUBST(TOR_OPENSSL_LIBS)
606 dnl Now check for particular openssl functions.
607 save_LIBS="$LIBS"
608 save_LDFLAGS="$LDFLAGS"
609 save_CPPFLAGS="$CPPFLAGS"
610 LIBS="$TOR_OPENSSL_LIBS $LIBS"
611 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
612 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
614 AC_TRY_COMPILE([
615 #include <openssl/opensslv.h>
616 #if OPENSSL_VERSION_NUMBER < 0x1000000fL
617 #error "too old"
618 #endif
619 ], [],
620 [ : ],
621 [ AC_ERROR([OpenSSL is too old. We require 1.0.0 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
623 AC_TRY_COMPILE([
624 #include <openssl/opensslv.h>
625 #include <openssl/evp.h>
626 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
627 #error "no ECC"
628 #endif
629 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
630 #error "curves unavailable"
631 #endif
632 ], [],
633 [ : ],
634 [ AC_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
636 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
637 [#include <openssl/ssl.h>
638 ])
640 AC_CHECK_FUNCS([ \
641 SSL_SESSION_get_master_key \
642 SSL_get_server_random \
643 SSL_get_client_ciphers \
644 SSL_get_client_random \
645 SSL_CIPHER_find \
646 TLS_method
647 ])
649 dnl Check if OpenSSL has scrypt implementation.
650 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
652 LIBS="$save_LIBS"
653 LDFLAGS="$save_LDFLAGS"
654 CPPFLAGS="$save_CPPFLAGS"
656 dnl ------------------------------------------------------
657 dnl Where do you live, zlib? And how do we call you?
659 tor_zlib_pkg_redhat="zlib"
660 tor_zlib_pkg_debian="zlib1g"
661 tor_zlib_devpkg_redhat="zlib-devel"
662 tor_zlib_devpkg_debian="zlib1g-dev"
664 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
665 [#include <zlib.h>],
666 [const char * zlibVersion(void);],
667 [zlibVersion();], [--with-zlib-dir],
668 [/opt/zlib])
670 if test "$enable_static_zlib" = "yes"; then
671 if test "$tor_cv_library_zlib_dir" = "(system)"; then
672 AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
673 using --enable-static-zlib")
674 else
675 TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
676 fi
677 else
678 TOR_ZLIB_LIBS="-lz"
679 fi
680 AC_SUBST(TOR_ZLIB_LIBS)
682 dnl ----------------------------------------------------------------------
683 dnl Check if libcap is available for capabilities.
685 tor_cap_pkg_debian="libcap2"
686 tor_cap_pkg_redhat="libcap"
687 tor_cap_devpkg_debian="libcap-dev"
688 tor_cap_devpkg_redhat="libcap-devel"
690 AC_CHECK_LIB([cap], [cap_init], [],
691 AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
692 )
693 AC_CHECK_FUNCS(cap_set_proc)
695 dnl ---------------------------------------------------------------------
696 dnl Now that we know about our major libraries, we can check for compiler
697 dnl and linker hardening options. We need to do this with the libraries known,
698 dnl since sometimes the linker will like an option but not be willing to
699 dnl use it with a build of a library.
701 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
702 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_CAP_LIBS"
704 CFLAGS_FTRAPV=
705 CFLAGS_FWRAPV=
706 CFLAGS_ASAN=
707 CFLAGS_UBSAN=
709 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
710 #if !defined(__clang__)
711 #error
712 #endif])], have_clang=yes, have_clang=no)
714 if test "x$enable_gcc_hardening" != "xno"; then
715 CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
716 if test "x$have_clang" = "xyes"; then
717 TOR_CHECK_CFLAGS(-Qunused-arguments)
718 fi
719 TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
720 AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
721 AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
722 m4_ifdef([AS_VAR_IF],[
723 AS_VAR_IF(can_compile, [yes],
724 AS_VAR_IF(can_link, [yes],
725 [],
726 AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
727 )])
728 AS_VAR_POPDEF([can_link])
729 AS_VAR_POPDEF([can_compile])
730 TOR_CHECK_CFLAGS(-Wstack-protector)
731 TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
732 if test "$bwin32" = "false"; then
733 TOR_CHECK_CFLAGS(-fPIE)
734 TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
735 fi
736 TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
737 TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
738 if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
739 AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
740 fi
741 fi
743 if test "x$enable_expensive_hardening" = "xyes"; then
744 if test "$tor_cv_cflags__ftrapv" != "yes"; then
745 AC_MSG_ERROR([You requested expensive hardening, but the compiler does not seem to support -ftrapv.])
746 fi
748 TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
749 if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
750 AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
751 fi
753 TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
754 if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
755 AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
756 fi
758 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
759 fi
761 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
762 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
764 mulodi_fixes_ftrapv=no
765 if test "$have_clang" = "yes"; then
766 saved_CFLAGS="$CFLAGS"
767 CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
768 AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
769 AC_LINK_IFELSE([
770 AC_LANG_SOURCE([[
771 #include <stdint.h>
772 #include <stdlib.h>
773 int main(int argc, char **argv)
774 {
775 int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
776 * (int64_t)atoi(argv[3]);
777 return x == 9;
778 } ]])],
779 [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
780 [ftrapv_can_link=no; AC_MSG_RESULT([no])])
781 if test "$ftrapv_can_link" = "no"; then
782 AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
783 AC_LINK_IFELSE([
784 AC_LANG_SOURCE([[
785 #include <stdint.h>
786 #include <stdlib.h>
787 int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
788 *overflow=0;
789 return a;
790 }
791 int main(int argc, char **argv)
792 {
793 int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
794 * (int64_t)atoi(argv[3]);
795 return x == 9;
796 } ]])],
797 [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
798 [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
799 fi
800 CFLAGS="$saved_CFLAGS"
801 fi
803 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
805 dnl These cflags add bunches of branches, and we haven't been able to
806 dnl persuade ourselves that they're suitable for code that needs to be
807 dnl constant time.
808 AC_SUBST(CFLAGS_BUGTRAP)
809 dnl These cflags are variant ones sutable for code that needs to be
810 dnl constant-time.
811 AC_SUBST(CFLAGS_CONSTTIME)
813 if test "x$enable_linker_hardening" != "xno"; then
814 TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
815 fi
817 # For backtrace support
818 TOR_CHECK_LDFLAGS(-rdynamic)
820 dnl ------------------------------------------------------
821 dnl Now see if we have a -fomit-frame-pointer compiler option.
823 saved_CFLAGS="$CFLAGS"
824 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
825 F_OMIT_FRAME_POINTER=''
826 if test "$saved_CFLAGS" != "$CFLAGS"; then
827 if test "x$enable_expensive_hardening" != "xyes"; then
828 F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
829 fi
830 fi
831 CFLAGS="$saved_CFLAGS"
832 AC_SUBST(F_OMIT_FRAME_POINTER)
834 dnl ------------------------------------------------------
835 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
836 dnl for us, as GCC 4.6 and later do at many optimization levels), then
837 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
838 dnl code will work.
839 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
841 dnl ============================================================
842 dnl Check for libseccomp
844 if test "x$enable_seccomp" != "xno"; then
845 AC_CHECK_HEADERS([seccomp.h])
846 AC_SEARCH_LIBS(seccomp_init, [seccomp])
847 fi
849 dnl ============================================================
850 dnl Check for libscrypt
852 if test "x$enable_libscrypt" != "xno"; then
853 AC_CHECK_HEADERS([libscrypt.h])
854 AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
855 AC_CHECK_FUNCS([libscrypt_scrypt])
856 fi
858 dnl ============================================================
859 dnl We need an implementation of curve25519.
861 dnl set these defaults.
862 build_curve25519_donna=no
863 build_curve25519_donna_c64=no
864 use_curve25519_donna=no
865 use_curve25519_nacl=no
866 CURVE25519_LIBS=
868 dnl The best choice is using curve25519-donna-c64, but that requires
869 dnl that we
870 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
871 tor_cv_can_use_curve25519_donna_c64,
872 [AC_RUN_IFELSE(
873 [AC_LANG_PROGRAM([dnl
874 #include <stdint.h>
875 typedef unsigned uint128_t __attribute__((mode(TI)));
876 int func(uint64_t a, uint64_t b) {
877 uint128_t c = ((uint128_t)a) * b;
878 int ok = ((uint64_t)(c>>96)) == 522859 &&
879 (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
880 (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
881 (((uint64_t)(c))&0xffffffffL) == 0;
882 return ok;
883 }
884 ], [dnl
885 int ok = func( ((uint64_t)2000000000) * 1000000000,
886 ((uint64_t)1234567890) << 24);
887 return !ok;
888 ])],
889 [tor_cv_can_use_curve25519_donna_c64=yes],
890 [tor_cv_can_use_curve25519_donna_c64=no],
891 [AC_LINK_IFELSE(
892 [AC_LANG_PROGRAM([dnl
893 #include <stdint.h>
894 typedef unsigned uint128_t __attribute__((mode(TI)));
895 int func(uint64_t a, uint64_t b) {
896 uint128_t c = ((uint128_t)a) * b;
897 int ok = ((uint64_t)(c>>96)) == 522859 &&
898 (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
899 (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
900 (((uint64_t)(c))&0xffffffffL) == 0;
901 return ok;
902 }
903 ], [dnl
904 int ok = func( ((uint64_t)2000000000) * 1000000000,
905 ((uint64_t)1234567890) << 24);
906 return !ok;
907 ])],
908 [tor_cv_can_use_curve25519_donna_c64=cross],
909 [tor_cv_can_use_curve25519_donna_c64=no])])])
911 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
912 nacl/crypto_scalarmult_curve25519.h])
914 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
915 tor_cv_can_use_curve25519_nacl,
916 [tor_saved_LIBS="$LIBS"
917 LIBS="$LIBS -lnacl"
918 AC_LINK_IFELSE(
919 [AC_LANG_PROGRAM([dnl
920 #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
921 #include <crypto_scalarmult_curve25519.h>
922 #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
923 #include <nacl/crypto_scalarmult_curve25519.h>
924 #endif
925 #ifdef crypto_scalarmult_curve25519_ref_BYTES
926 #error Hey, this is the reference implementation! That's not fast.
927 #endif
928 ], [
929 unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
930 ])], [tor_cv_can_use_curve25519_nacl=yes],
931 [tor_cv_can_use_curve25519_nacl=no])
932 LIBS="$tor_saved_LIBS" ])
934 dnl Okay, now we need to figure out which one to actually use. Fall back
935 dnl to curve25519-donna.c
937 if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
938 build_curve25519_donna_c64=yes
939 use_curve25519_donna=yes
940 elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
941 use_curve25519_nacl=yes
942 CURVE25519_LIBS=-lnacl
943 else
944 build_curve25519_donna=yes
945 use_curve25519_donna=yes
946 fi
948 if test "x$use_curve25519_donna" = "xyes"; then
949 AC_DEFINE(USE_CURVE25519_DONNA, 1,
950 [Defined if we should use an internal curve25519_donna{,_c64} implementation])
951 fi
952 if test "x$use_curve25519_nacl" = "xyes"; then
953 AC_DEFINE(USE_CURVE25519_NACL, 1,
954 [Defined if we should use a curve25519 from nacl])
955 fi
956 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
957 test "x$build_curve25519_donna" = "xyes")
958 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
959 test "x$build_curve25519_donna_c64" = "xyes")
960 AC_SUBST(CURVE25519_LIBS)
962 dnl Make sure to enable support for large off_t if available.
963 AC_SYS_LARGEFILE
965 AC_CHECK_HEADERS([assert.h \
966 errno.h \
967 fcntl.h \
968 signal.h \
969 string.h \
970 sys/capability.h \
971 sys/fcntl.h \
972 sys/stat.h \
973 sys/time.h \
974 sys/types.h \
975 time.h \
976 unistd.h \
977 arpa/inet.h \
978 crt_externs.h \
979 execinfo.h \
980 grp.h \
981 ifaddrs.h \
982 inttypes.h \
983 limits.h \
984 linux/types.h \
985 machine/limits.h \
986 malloc.h \
987 malloc/malloc.h \
988 malloc_np.h \
989 netdb.h \
990 netinet/in.h \
991 netinet/in6.h \
992 pwd.h \
993 readpassphrase.h \
994 stdint.h \
995 sys/eventfd.h \
996 sys/file.h \
997 sys/ioctl.h \
998 sys/limits.h \
999 sys/mman.h \
1000 sys/param.h \
1001 sys/prctl.h \
1002 sys/random.h \
1003 sys/resource.h \
1004 sys/select.h \
1005 sys/socket.h \
1006 sys/statvfs.h \
1007 sys/syscall.h \
1008 sys/sysctl.h \
1009 sys/syslimits.h \
1010 sys/time.h \
1011 sys/types.h \
1012 sys/un.h \
1013 sys/utime.h \
1014 sys/wait.h \
1015 syslog.h \
1016 utime.h])
1018 AC_CHECK_HEADERS(sys/param.h)
1020 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1021 [#ifdef HAVE_SYS_TYPES_H
1022 #include <sys/types.h>
1023 #endif
1024 #ifdef HAVE_SYS_SOCKET_H
1025 #include <sys/socket.h>
1026 #endif])
1027 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1028 [#ifdef HAVE_SYS_TYPES_H
1029 #include <sys/types.h>
1030 #endif
1031 #ifdef HAVE_SYS_SOCKET_H
1032 #include <sys/socket.h>
1033 #endif
1034 #ifdef HAVE_NET_IF_H
1035 #include <net/if.h>
1036 #endif
1037 #ifdef HAVE_NETINET_IN_H
1038 #include <netinet/in.h>
1039 #endif])
1041 AC_CHECK_HEADERS(linux/if.h,[],[],
1042 [
1043 #ifdef HAVE_SYS_SOCKET_H
1044 #include <sys/socket.h>
1045 #endif
1046 ])
1048 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1049 linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1050 [#ifdef HAVE_SYS_TYPES_H
1051 #include <sys/types.h>
1052 #endif
1053 #ifdef HAVE_SYS_SOCKET_H
1054 #include <sys/socket.h>
1055 #endif
1056 #ifdef HAVE_LIMITS_H
1057 #include <limits.h>
1058 #endif
1059 #ifdef HAVE_LINUX_TYPES_H
1060 #include <linux/types.h>
1061 #endif
1062 #ifdef HAVE_NETINET_IN6_H
1063 #include <netinet/in6.h>
1064 #endif
1065 #ifdef HAVE_NETINET_IN_H
1066 #include <netinet/in.h>
1067 #endif])
1069 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1070 linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1071 [#ifdef HAVE_SYS_TYPES_H
1072 #include <sys/types.h>
1073 #endif
1074 #ifdef HAVE_SYS_SOCKET_H
1075 #include <sys/socket.h>
1076 #endif
1077 #ifdef HAVE_LIMITS_H
1078 #include <limits.h>
1079 #endif
1080 #ifdef HAVE_LINUX_TYPES_H
1081 #include <linux/types.h>
1082 #endif
1083 #ifdef HAVE_NETINET_IN6_H
1084 #include <netinet/in6.h>
1085 #endif
1086 #ifdef HAVE_NETINET_IN_H
1087 #include <netinet/in.h>
1088 #endif
1089 #ifdef HAVE_LINUX_IF_H
1090 #include <linux/if.h>
1091 #endif])
1093 transparent_ok=0
1094 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1095 transparent_ok=1
1096 fi
1097 if test "x$linux_netfilter_ipv4" = "x1"; then
1098 transparent_ok=1
1099 fi
1100 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1101 transparent_ok=1
1102 fi
1103 if test "x$transparent_ok" = "x1"; then
1104 AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1105 case "$host" in
1106 *-*-openbsd* | *-*-bitrig*)
1107 AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
1108 esac
1109 else
1110 AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1111 fi
1113 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1114 [#ifdef HAVE_SYS_TYPES_H
1115 #include <sys/types.h>
1116 #endif
1117 #ifdef HAVE_SYS_TIME_H
1118 #include <sys/time.h>
1119 #endif])
1121 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1122 dnl Watch out.
1124 AC_CHECK_SIZEOF(int8_t)
1125 AC_CHECK_SIZEOF(int16_t)
1126 AC_CHECK_SIZEOF(int32_t)
1127 AC_CHECK_SIZEOF(int64_t)
1128 AC_CHECK_SIZEOF(uint8_t)
1129 AC_CHECK_SIZEOF(uint16_t)
1130 AC_CHECK_SIZEOF(uint32_t)
1131 AC_CHECK_SIZEOF(uint64_t)
1132 AC_CHECK_SIZEOF(intptr_t)
1133 AC_CHECK_SIZEOF(uintptr_t)
1135 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1137 AC_CHECK_SIZEOF(char)
1138 AC_CHECK_SIZEOF(short)
1139 AC_CHECK_SIZEOF(int)
1140 AC_CHECK_SIZEOF(long)
1141 AC_CHECK_SIZEOF(long long)
1142 AC_CHECK_SIZEOF(__int64)
1143 AC_CHECK_SIZEOF(void *)
1144 AC_CHECK_SIZEOF(time_t)
1145 AC_CHECK_SIZEOF(size_t)
1146 AC_CHECK_SIZEOF(pid_t)
1148 AC_CHECK_TYPES([uint, u_char, ssize_t])
1150 AC_PC_FROM_UCONTEXT([:])
1152 dnl used to include sockaddr_storage, but everybody has that.
1153 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1154 [#ifdef HAVE_SYS_TYPES_H
1155 #include <sys/types.h>
1156 #endif
1157 #ifdef HAVE_NETINET_IN_H
1158 #include <netinet/in.h>
1159 #endif
1160 #ifdef HAVE_NETINET_IN6_H
1161 #include <netinet/in6.h>
1162 #endif
1163 #ifdef HAVE_SYS_SOCKET_H
1164 #include <sys/socket.h>
1165 #endif
1166 #ifdef _WIN32
1167 #define _WIN32_WINNT 0x0501
1168 #define WIN32_LEAN_AND_MEAN
1169 #include <winsock2.h>
1170 #include <ws2tcpip.h>
1171 #endif
1172 ])
1173 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1174 [#ifdef HAVE_SYS_TYPES_H
1175 #include <sys/types.h>
1176 #endif
1177 #ifdef HAVE_NETINET_IN_H
1178 #include <netinet/in.h>
1179 #endif
1180 #ifdef HAVE_NETINET_IN6_H
1181 #include <netinet/in6.h>
1182 #endif
1183 #ifdef HAVE_SYS_SOCKET_H
1184 #include <sys/socket.h>
1185 #endif
1186 #ifdef _WIN32
1187 #define _WIN32_WINNT 0x0501
1188 #define WIN32_LEAN_AND_MEAN
1189 #include <winsock2.h>
1190 #include <ws2tcpip.h>
1191 #endif
1192 ])
1194 AC_CHECK_TYPES([rlim_t], , ,
1195 [#ifdef HAVE_SYS_TYPES_H
1196 #include <sys/types.h>
1197 #endif
1198 #ifdef HAVE_SYS_TIME_H
1199 #include <sys/time.h>
1200 #endif
1201 #ifdef HAVE_SYS_RESOURCE_H
1202 #include <sys/resource.h>
1203 #endif
1204 ])
1206 AX_CHECK_SIGN([time_t],
1207 [ : ],
1208 [ : ], [
1209 #ifdef HAVE_SYS_TYPES_H
1210 #include <sys/types.h>
1211 #endif
1212 #ifdef HAVE_SYS_TIME_H
1213 #include <sys/time.h>
1214 #endif
1215 #ifdef HAVE_TIME_H
1216 #include <time.h>
1217 #endif
1218 ])
1220 if test "$ax_cv_decl_time_t_signed" = "no"; then
1221 AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1222 fi
1224 AX_CHECK_SIGN([size_t],
1225 [ tor_cv_size_t_signed=yes ],
1226 [ tor_cv_size_t_signed=no ], [
1227 #ifdef HAVE_SYS_TYPES_H
1228 #include <sys/types.h>
1229 #endif
1230 ])
1232 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1233 AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1234 fi
1236 AX_CHECK_SIGN([enum always],
1237 [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1238 [ : ], [
1239 enum always { AAA, BBB, CCC };
1240 ])
1242 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1243 #ifdef HAVE_SYS_SOCKET_H
1244 #include <sys/socket.h>
1245 #endif
1246 ])
1248 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1250 AC_CHECK_SIZEOF(cell_t)
1252 # Now make sure that NULL can be represented as zero bytes.
1253 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1254 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1255 [[#include <stdlib.h>
1256 #include <string.h>
1257 #include <stdio.h>
1258 #ifdef HAVE_STDDEF_H
1259 #include <stddef.h>
1260 #endif
1261 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1262 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1263 [tor_cv_null_is_zero=yes],
1264 [tor_cv_null_is_zero=no],
1265 [tor_cv_null_is_zero=cross])])
1267 if test "$tor_cv_null_is_zero" = "cross"; then
1268 # Cross-compiling; let's hope that the target isn't raving mad.
1269 AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1270 fi
1272 if test "$tor_cv_null_is_zero" != "no"; then
1273 AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1274 [Define to 1 iff memset(0) sets pointers to NULL])
1275 fi
1277 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1278 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1279 [[#include <stdlib.h>
1280 #include <string.h>
1281 #include <stdio.h>
1282 #ifdef HAVE_STDDEF_H
1283 #include <stddef.h>
1284 #endif
1285 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1286 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1287 [tor_cv_dbl0_is_zero=yes],
1288 [tor_cv_dbl0_is_zero=no],
1289 [tor_cv_dbl0_is_zero=cross])])
1291 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1292 # Cross-compiling; let's hope that the target isn't raving mad.
1293 AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1294 fi
1296 if test "$tor_cv_dbl0_is_zero" != "no"; then
1297 AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1298 [Define to 1 iff memset(0) sets doubles to 0.0])
1299 fi
1301 # And what happens when we malloc zero?
1302 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1303 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1304 [[#include <stdlib.h>
1305 #include <string.h>
1306 #include <stdio.h>
1307 #ifdef HAVE_STDDEF_H
1308 #include <stddef.h>
1309 #endif
1310 int main () { return malloc(0)?0:1; }]])],
1311 [tor_cv_malloc_zero_works=yes],
1312 [tor_cv_malloc_zero_works=no],
1313 [tor_cv_malloc_zero_works=cross])])
1315 if test "$tor_cv_malloc_zero_works" = "cross"; then
1316 # Cross-compiling; let's hope that the target isn't raving mad.
1317 AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1318 fi
1320 if test "$tor_cv_malloc_zero_works" = "yes"; then
1321 AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1322 [Define to 1 iff malloc(0) returns a pointer])
1323 fi
1325 # whether we seem to be in a 2s-complement world.
1326 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1327 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1328 [[int main () { int problem = ((-99) != (~99)+1);
1329 return problem ? 1 : 0; }]])],
1330 [tor_cv_twos_complement=yes],
1331 [tor_cv_twos_complement=no],
1332 [tor_cv_twos_complement=cross])])
1334 if test "$tor_cv_twos_complement" = "cross"; then
1335 # Cross-compiling; let's hope that the target isn't raving mad.
1336 AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1337 fi
1339 if test "$tor_cv_twos_complement" != "no"; then
1340 AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1341 [Define to 1 iff we represent negative integers with
1342 two's complement])
1343 fi
1345 # What does shifting a negative value do?
1346 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1347 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1348 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1349 [tor_cv_sign_extend=yes],
1350 [tor_cv_sign_extend=no],
1351 [tor_cv_sign_extend=cross])])
1353 if test "$tor_cv_sign_extend" = "cross"; then
1354 # Cross-compiling; let's hope that the target isn't raving mad.
1355 AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1356 fi
1358 if test "$tor_cv_sign_extend" != "no"; then
1359 AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1360 [Define to 1 iff right-shifting a negative value performs sign-extension])
1361 fi
1363 # Whether we should use the dmalloc memory allocation debugging library.
1364 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1365 AC_ARG_WITH(dmalloc,
1366 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1367 [if [[ "$withval" = "yes" ]]; then
1368 dmalloc=1
1369 AC_MSG_RESULT(yes)
1370 else
1371 dmalloc=1
1372 AC_MSG_RESULT(no)
1373 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1374 )
1376 if [[ $dmalloc -eq 1 ]]; then
1377 AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1378 AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1379 AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1380 AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1381 fi
1383 AC_ARG_WITH(tcmalloc,
1384 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1385 [ tcmalloc=yes ], [ tcmalloc=no ])
1387 if test "x$tcmalloc" = "xyes"; then
1388 LDFLAGS="-ltcmalloc $LDFLAGS"
1389 fi
1391 using_custom_malloc=no
1392 if test "x$enable_openbsd_malloc" = "xyes"; then
1393 using_custom_malloc=yes
1394 fi
1395 if test "x$tcmalloc" = "xyes"; then
1396 using_custom_malloc=yes
1397 fi
1398 if test "$using_custom_malloc" = "no"; then
1399 AC_CHECK_FUNCS(mallinfo)
1400 fi
1402 # By default, we're going to assume we don't have mlockall()
1403 # bionic and other platforms have various broken mlockall subsystems.
1404 # Some systems don't have a working mlockall, some aren't linkable,
1405 # and some have it but don't declare it.
1406 AC_CHECK_FUNCS(mlockall)
1407 AC_CHECK_DECLS([mlockall], , , [
1408 #ifdef HAVE_SYS_MMAN_H
1409 #include <sys/mman.h>
1410 #endif])
1412 # Allow user to specify an alternate syslog facility
1413 AC_ARG_WITH(syslog-facility,
1414 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1415 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1416 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1417 AC_SUBST(LOGFACILITY)
1419 # Check if we have getresuid and getresgid
1420 AC_CHECK_FUNCS(getresuid getresgid)
1422 # Check for gethostbyname_r in all its glorious incompatible versions.
1423 # (This logic is based on that in Python's configure.in)
1424 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1425 [Define this if you have any gethostbyname_r()])
1427 AC_CHECK_FUNC(gethostbyname_r, [
1428 AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1429 OLD_CFLAGS=$CFLAGS
1430 CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1431 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1432 #include <netdb.h>
1433 ], [[
1434 char *cp1, *cp2;
1435 struct hostent *h1, *h2;
1436 int i1, i2;
1437 (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1438 ]])],[
1439 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1440 AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1441 [Define this if gethostbyname_r takes 6 arguments])
1442 AC_MSG_RESULT(6)
1443 ], [
1444 AC_TRY_COMPILE([
1445 #include <netdb.h>
1446 ], [
1447 char *cp1, *cp2;
1448 struct hostent *h1;
1449 int i1, i2;
1450 (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1451 ], [
1452 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1453 AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1454 [Define this if gethostbyname_r takes 5 arguments])
1455 AC_MSG_RESULT(5)
1456 ], [
1457 AC_TRY_COMPILE([
1458 #include <netdb.h>
1459 ], [
1460 char *cp1;
1461 struct hostent *h1;
1462 struct hostent_data hd;
1463 (void) gethostbyname_r(cp1,h1,&hd);
1464 ], [
1465 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1466 AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1467 [Define this if gethostbyname_r takes 3 arguments])
1468 AC_MSG_RESULT(3)
1469 ], [
1470 AC_MSG_RESULT(0)
1471 ])
1472 ])
1473 ])
1474 CFLAGS=$OLD_CFLAGS
1475 ])
1477 AC_CACHE_CHECK([whether the C compiler supports __func__],
1478 tor_cv_have_func_macro,
1479 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1480 #include <stdio.h>
1481 int main(int c, char **v) { puts(__func__); }])],
1482 tor_cv_have_func_macro=yes,
1483 tor_cv_have_func_macro=no))
1485 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1486 tor_cv_have_FUNC_macro,
1487 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1488 #include <stdio.h>
1489 int main(int c, char **v) { puts(__FUNC__); }])],
1490 tor_cv_have_FUNC_macro=yes,
1491 tor_cv_have_FUNC_macro=no))
1493 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1494 tor_cv_have_FUNCTION_macro,
1495 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1496 #include <stdio.h>
1497 int main(int c, char **v) { puts(__FUNCTION__); }])],
1498 tor_cv_have_FUNCTION_macro=yes,
1499 tor_cv_have_FUNCTION_macro=no))
1501 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1502 tor_cv_have_environ_declared,
1503 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1504 #ifdef HAVE_UNISTD_H
1505 #include <unistd.h>
1506 #endif
1507 #include <stdlib.h>
1508 int main(int c, char **v) { char **t = environ; }])],
1509 tor_cv_have_environ_declared=yes,
1510 tor_cv_have_environ_declared=no))
1512 if test "$tor_cv_have_func_macro" = "yes"; then
1513 AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1514 fi
1516 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1517 AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1518 fi
1520 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1521 AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1522 [Defined if the compiler supports __FUNCTION__])
1523 fi
1525 if test "$tor_cv_have_environ_declared" = "yes"; then
1526 AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1527 [Defined if we have extern char **environ already declared])
1528 fi
1530 # $prefix stores the value of the --prefix command line option, or
1531 # NONE if the option wasn't set. In the case that it wasn't set, make
1532 # it be the default, so that we can use it to expand directories now.
1533 if test "x$prefix" = "xNONE"; then
1534 prefix=$ac_default_prefix
1535 fi
1537 # and similarly for $exec_prefix
1538 if test "x$exec_prefix" = "xNONE"; then
1539 exec_prefix=$prefix
1540 fi
1542 if test "x$BUILDDIR" = "x"; then
1543 BUILDDIR=`pwd`
1544 fi
1545 AC_SUBST(BUILDDIR)
1546 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1547 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1549 if test "x$CONFDIR" = "x"; then
1550 CONFDIR=`eval echo $sysconfdir/tor`
1551 fi
1552 AC_SUBST(CONFDIR)
1553 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1554 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1556 BINDIR=`eval echo $bindir`
1557 AC_SUBST(BINDIR)
1558 LOCALSTATEDIR=`eval echo $localstatedir`
1559 AC_SUBST(LOCALSTATEDIR)
1561 if test "$bwin32" = "true"; then
1562 # Test if the linker supports the --nxcompat and --dynamicbase options
1563 # for Windows
1564 save_LDFLAGS="$LDFLAGS"
1565 LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1566 AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1567 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1568 [AC_MSG_RESULT([yes])]
1569 [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1570 [AC_MSG_RESULT([no])]
1571 )
1572 LDFLAGS="$save_LDFLAGS"
1573 fi
1575 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1576 # than autoconf's macros like.
1577 if test "$GCC" = "yes"; then
1578 # Disable GCC's strict aliasing checks. They are an hours-to-debug
1579 # accident waiting to happen.
1580 CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1581 else
1582 # Override optimization level for non-gcc compilers
1583 CFLAGS="$CFLAGS -O"
1584 enable_gcc_warnings=no
1585 enable_gcc_warnings_advisory=no
1586 fi
1588 # Warnings implies advisory-warnings and -Werror.
1589 if test "$enable_gcc_warnings" = "yes"; then
1590 enable_gcc_warnings_advisory=yes
1591 enable_fatal_warnings=yes
1592 fi
1594 # OS X Lion started deprecating the system openssl. Let's just disable
1595 # all deprecation warnings on OS X. Also, to potentially make the binary
1596 # a little smaller, let's enable dead_strip.
1597 case "$host_os" in
1599 darwin*)
1600 CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1601 LDFLAGS="$LDFLAGS -dead_strip" ;;
1602 esac
1604 # Add some more warnings which we use in development but not in the
1605 # released versions. (Some relevant gcc versions can't handle these.)
1606 #
1607 # Note that we have to do this near the end of the autoconf process, or
1608 # else we may run into problems when these warnings hit on the testing C
1609 # programs that autoconf wants to build.
1610 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1612 case "$host" in
1613 *-*-openbsd* | *-*-bitrig*)
1614 # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1615 # That's fine, except that the headers don't pass -Wredundant-decls.
1616 # Therefore, let's disable -Wsystem-headers when we're building
1617 # with maximal warnings on OpenBSD.
1618 CFLAGS="$CFLAGS -Wno-system-headers" ;;
1619 esac
1621 # GCC4.3 users once report trouble with -Wstrict-overflow=5. GCC5 users
1622 # have it work better.
1623 # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1625 # This warning was added in gcc 4.3, but it appears to generate
1626 # spurious warnings in gcc 4.4. I don't know if it works in 4.5.
1627 #CFLAGS="$CFLAGS -Wlogical-op"
1629 m4_foreach_w([warning_flag], [
1630 -Waddress
1631 -Waddress-of-array-temporary
1632 -Waddress-of-temporary
1633 -Wambiguous-macro
1634 -Wanonymous-pack-parens
1635 -Warc
1636 -Warc-abi
1637 -Warc-bridge-casts-disallowed-in-nonarc
1638 -Warc-maybe-repeated-use-of-weak
1639 -Warc-performSelector-leaks
1640 -Warc-repeated-use-of-weak
1641 -Warray-bounds
1642 -Warray-bounds-pointer-arithmetic
1643 -Wasm
1644 -Wasm-operand-widths
1645 -Watomic-properties
1646 -Watomic-property-with-user-defined-accessor
1647 -Wauto-import
1648 -Wauto-storage-class
1649 -Wauto-var-id
1650 -Wavailability
1651 -Wbackslash-newline-escape
1652 -Wbad-array-new-length
1653 -Wbind-to-temporary-copy
1654 -Wbitfield-constant-conversion
1655 -Wbool-conversion
1656 -Wbool-conversions
1657 -Wbuiltin-requires-header
1658 -Wchar-align
1659 -Wcompare-distinct-pointer-types
1660 -Wcomplex-component-init
1661 -Wconditional-type-mismatch
1662 -Wconfig-macros
1663 -Wconstant-conversion
1664 -Wconstant-logical-operand
1665 -Wconstexpr-not-const
1666 -Wcustom-atomic-properties
1667 -Wdangling-field
1668 -Wdangling-initializer-list
1669 -Wdate-time
1670 -Wdelegating-ctor-cycles
1671 -Wdeprecated-implementations
1672 -Wdeprecated-register
1673 -Wdirect-ivar-access
1674 -Wdiscard-qual
1675 -Wdistributed-object-modifiers
1676 -Wdivision-by-zero
1677 -Wdollar-in-identifier-extension
1678 -Wdouble-promotion
1679 -Wduplicate-decl-specifier
1680 -Wduplicate-enum
1681 -Wduplicate-method-arg
1682 -Wduplicate-method-match
1683 -Wduplicated-cond
1684 -Wdynamic-class-memaccess
1685 -Wembedded-directive
1686 -Wempty-translation-unit
1687 -Wenum-conversion
1688 -Wexit-time-destructors
1689 -Wexplicit-ownership-type
1690 -Wextern-initializer
1691 -Wextra
1692 -Wextra-semi
1693 -Wextra-tokens
1694 -Wflexible-array-extensions
1695 -Wfloat-conversion
1696 -Wformat-non-iso
1697 -Wfour-char-constants
1698 -Wgcc-compat
1699 -Wglobal-constructors
1700 -Wgnu-array-member-paren-init
1701 -Wgnu-designator
1702 -Wgnu-static-float-init
1703 -Wheader-guard
1704 -Wheader-hygiene
1705 -Widiomatic-parentheses
1706 -Wignored-attributes
1707 -Wimplicit-atomic-properties
1708 -Wimplicit-conversion-floating-point-to-bool
1709 -Wimplicit-exception-spec-mismatch
1710 -Wimplicit-fallthrough
1711 -Wimplicit-fallthrough-per-function
1712 -Wimplicit-retain-self
1713 -Wimport-preprocessor-directive-pedantic
1714 -Wincompatible-library-redeclaration
1715 -Wincompatible-pointer-types-discards-qualifiers
1716 -Wincomplete-implementation
1717 -Wincomplete-module
1718 -Wincomplete-umbrella
1719 -Winit-self
1720 -Wint-conversions
1721 -Wint-to-void-pointer-cast
1722 -Winteger-overflow
1723 -Winvalid-constexpr
1724 -Winvalid-iboutlet
1725 -Winvalid-noreturn
1726 -Winvalid-pp-token
1727 -Winvalid-source-encoding
1728 -Winvalid-token-paste
1729 -Wknr-promoted-parameter
1730 -Wlanguage-extension-token
1731 -Wlarge-by-value-copy
1732 -Wliteral-conversion
1733 -Wliteral-range
1734 -Wlocal-type-template-args
1735 -Wlogical-op
1736 -Wloop-analysis
1737 -Wmain-return-type
1738 -Wmalformed-warning-check
1739 -Wmethod-signatures
1740 -Wmicrosoft
1741 -Wmicrosoft-exists
1742 -Wmismatched-parameter-types
1743 -Wmismatched-return-types
1744 -Wmissing-field-initializers
1745 -Wmissing-format-attribute
1746 -Wmissing-noreturn
1747 -Wmissing-selector-name
1748 -Wmissing-sysroot
1749 -Wmissing-variable-declarations
1750 -Wmodule-conflict
1751 -Wnested-anon-types
1752 -Wnewline-eof
1753 -Wnon-literal-null-conversion
1754 -Wnon-pod-varargs
1755 -Wnonportable-cfstrings
1756 -Wnormalized=id
1757 -Wnull-arithmetic
1758 -Wnull-character
1759 -Wnull-conversion
1760 -Wnull-dereference
1761 -Wout-of-line-declaration
1762 -Wover-aligned
1763 -Woverlength-strings
1764 -Woverride-init
1765 -Woverriding-method-mismatch
1766 -Wpointer-type-mismatch
1767 -Wpredefined-identifier-outside-function
1768 -Wprotocol-property-synthesis-ambiguity
1769 -Wreadonly-iboutlet-property
1770 -Wreadonly-setter-attrs
1771 -Wreceiver-expr
1772 -Wreceiver-forward-class
1773 -Wreceiver-is-weak
1774 -Wreinterpret-base-class
1775 -Wrequires-super-attribute
1776 -Wreserved-user-defined-literal
1777 -Wreturn-stack-address
1778 -Wsection
1779 -Wselector-type-mismatch
1780 -Wsentinel
1781 -Wserialized-diagnostics
1782 -Wshadow
1783 -Wshift-count-negative
1784 -Wshift-count-overflow
1785 -Wshift-negative-value
1786 -Wshift-overflow=2
1787 -Wshift-sign-overflow
1788 -Wshorten-64-to-32
1789 -Wsizeof-array-argument
1790 -Wsource-uses-openmp
1791 -Wstatic-float-init
1792 -Wstatic-in-inline
1793 -Wstatic-local-in-inline
1794 -Wstrict-overflow=2
1795 -Wstring-compare
1796 -Wstring-conversion
1797 -Wstrlcpy-strlcat-size
1798 -Wstrncat-size
1799 -Wsuggest-attribute=format
1800 -Wsuggest-attribute=noreturn
1801 -Wsuper-class-method-mismatch
1802 -Wswitch-bool
1803 -Wsync-nand
1804 -Wtautological-constant-out-of-range-compare
1805 -Wtentative-definition-incomplete-type
1806 -Wtrampolines
1807 -Wtype-safety
1808 -Wtypedef-redefinition
1809 -Wtypename-missing
1810 -Wundefined-inline
1811 -Wundefined-internal
1812 -Wundefined-reinterpret-cast
1813 -Wunicode
1814 -Wunicode-whitespace
1815 -Wunknown-warning-option
1816 -Wunnamed-type-template-args
1817 -Wunneeded-member-function
1818 -Wunsequenced
1819 -Wunsupported-visibility
1820 -Wunused-but-set-parameter
1821 -Wunused-but-set-variable
1822 -Wunused-command-line-argument
1823 -Wunused-const-variable=2
1824 -Wunused-exception-parameter
1825 -Wunused-local-typedefs
1826 -Wunused-member-function
1827 -Wunused-sanitize-argument
1828 -Wunused-volatile-lvalue
1829 -Wuser-defined-literals
1830 -Wvariadic-macros
1831 -Wvector-conversion
1832 -Wvector-conversions
1833 -Wvexing-parse
1834 -Wvisibility
1835 -Wvla-extension
1836 -Wzero-length-array
1837 ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
1839 dnl These seem to require annotations that we don't currently use,
1840 dnl and they give false positives in our pthreads wrappers. (Clang 4)
1841 dnl -Wthread-safety
1842 dnl -Wthread-safety-analysis
1843 dnl -Wthread-safety-attributes
1844 dnl -Wthread-safety-beta
1845 dnl -Wthread-safety-precise
1847 CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1848 CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1849 CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1850 CFLAGS="$CFLAGS -Wwrite-strings"
1851 CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1852 CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
1853 CFLAGS="$CFLAGS -Wunused-parameter "
1854 # These interfere with building main() { return 0; }, which autoconf
1855 # likes to use as its default program.
1856 CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
1858 if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
1859 AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
1860 fi
1861 if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
1862 AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
1863 fi
1865 if test "x$enable_fatal_warnings" = "xyes"; then
1866 # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
1867 # default autoconf programs are full of errors.
1868 CFLAGS="$CFLAGS -Werror"
1869 fi
1871 fi
1873 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
1874 case "$host_os" in
1875 darwin*)
1876 AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
1877 esac
1878 fi
1880 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1882 AC_CONFIG_FILES([
1883 Doxyfile
1884 Makefile
1885 contrib/dist/suse/tor.sh
1886 contrib/operator-tools/tor.logrotate
1887 contrib/dist/tor.sh
1888 contrib/dist/torctl
1889 contrib/dist/tor.service
1890 src/config/torrc.sample
1891 src/config/torrc.minimal
1892 scripts/maint/checkOptionDocs.pl
1893 scripts/maint/updateVersions.pl
1894 ])
1896 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
1897 regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
1898 for file in $regular_mans ; do
1899 if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
1900 echo "==================================";
1901 echo;
1902 echo "Building Tor has failed since manpages cannot be built.";
1903 echo;
1904 echo "You need asciidoc installed to be able to build the manpages.";
1905 echo "To build without manpages, use the --disable-asciidoc argument";
1906 echo "when calling configure.";
1907 echo;
1908 echo "==================================";
1909 exit 1;
1910 fi
1911 done
1912 fi
1914 AC_OUTPUT