| blob | 6d721a2fc595c30e586289dddde5a06e7c24ab62 |
1 dnl Copyright (c) 2001-2004, Roger Dingledine
2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
3 dnl Copyright (c) 2007-2015, The Tor Project, Inc.
4 dnl See LICENSE for licensing information
6 AC_PREREQ([2.63])
7 AC_INIT([tor],[0.2.9.0-alpha-dev])
8 AC_CONFIG_SRCDIR([src/or/main.c])
9 AC_CONFIG_MACRO_DIR([m4])
11 # "foreign" means we don't follow GNU package layout standards
12 # "1.11" means we require automake version 1.11 or newer
13 # "subdir-objects" means put .o files in the same directory as the .c files
14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects])
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17 AC_CONFIG_HEADERS([orconfig.h])
19 AC_USE_SYSTEM_EXTENSIONS
20 AC_CANONICAL_HOST
22 PKG_PROG_PKG_CONFIG
24 if test -f "/etc/redhat-release"; then
25 if test -f "/usr/kerberos/include"; then
26 CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
27 fi
28 fi
30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
31 # the += operator on it in src/or/Makefile.am
32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
34 AC_ARG_ENABLE(openbsd-malloc,
35 AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD. Linux only]))
36 AC_ARG_ENABLE(static-openssl,
37 AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
38 AC_ARG_ENABLE(static-libevent,
39 AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
40 AC_ARG_ENABLE(static-zlib,
41 AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
42 AC_ARG_ENABLE(static-tor,
43 AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
44 AC_ARG_ENABLE(unittests,
45 AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
46 AC_ARG_ENABLE(coverage,
47 AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
48 AC_ARG_ENABLE(asserts-in-tests,
49 AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
50 AC_ARG_ENABLE(system-torrc,
51 AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
53 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
54 AC_MSG_ERROR([Can't disable assertions outside of coverage build])
55 fi
57 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
58 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
59 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
61 if test "$enable_static_tor" = "yes"; then
62 enable_static_libevent="yes";
63 enable_static_openssl="yes";
64 enable_static_zlib="yes";
65 CFLAGS="$CFLAGS -static"
66 fi
68 if test "$enable_system_torrc" = "no"; then
69 AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
70 [Defined if we're not going to look for a torrc in SYSCONF])
71 fi
73 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
75 AC_ARG_ENABLE(transparent,
76 AS_HELP_STRING(--disable-transparent, [disable transparent proxy support]),
77 [case "${enableval}" in
78 "yes") transparent=true ;;
79 "no") transparent=false ;;
80 *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
81 esac], [transparent=true])
83 AC_ARG_ENABLE(asciidoc,
84 AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
85 [case "${enableval}" in
86 "yes") asciidoc=true ;;
87 "no") asciidoc=false ;;
88 *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
89 esac], [asciidoc=true])
91 # systemd notify support
92 AC_ARG_ENABLE(systemd,
93 AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
94 [case "${enableval}" in
95 "yes") systemd=true ;;
96 "no") systemd=false ;;
97 * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
98 esac], [systemd=auto])
102 # systemd support
103 if test "x$enable_systemd" = "xno"; then
104 have_systemd=no;
105 else
106 PKG_CHECK_MODULES(SYSTEMD,
107 [libsystemd-daemon],
108 have_systemd=yes,
109 have_systemd=no)
110 if test "x$have_systemd" = "xno"; then
111 AC_MSG_NOTICE([Okay, checking for systemd a different way...])
112 PKG_CHECK_MODULES(SYSTEMD,
113 [libsystemd],
114 have_systemd=yes,
115 have_systemd=no)
116 fi
117 fi
119 if test "x$have_systemd" = "xyes"; then
120 AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
121 TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
122 TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
123 PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
124 [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
125 fi
126 AC_SUBST(TOR_SYSTEMD_CFLAGS)
127 AC_SUBST(TOR_SYSTEMD_LIBS)
129 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
130 AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
131 fi
133 case "$host" in
134 *-*-solaris* )
135 AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
136 ;;
137 esac
139 AC_ARG_ENABLE(gcc-warnings,
140 AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
141 AC_ARG_ENABLE(fatal-warnings,
142 AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
143 AC_ARG_ENABLE(gcc-warnings-advisory,
144 AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
146 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
147 AC_ARG_ENABLE(gcc-hardening,
148 AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
150 AC_ARG_ENABLE(expensive-hardening,
151 AS_HELP_STRING(--enable-expensive-hardening, [enable more expensive compiler hardening; makes Tor slower]))
153 dnl Linker hardening options
154 dnl Currently these options are ELF specific - you can't use this with MacOSX
155 AC_ARG_ENABLE(linker-hardening,
156 AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
158 AC_ARG_ENABLE(local-appdata,
159 AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
160 if test "$enable_local_appdata" = "yes"; then
161 AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
162 [Defined if we default to host local appdata paths on Windows])
163 fi
165 # Tor2web mode flag
166 AC_ARG_ENABLE(tor2web-mode,
167 AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
168 [if test "x$enableval" = "xyes"; then
169 CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
170 fi])
172 AC_ARG_ENABLE(bufferevents,
173 AS_HELP_STRING(--enable-bufferevents, [use Libevent's buffered IO]))
175 AC_ARG_ENABLE(tool-name-check,
176 AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
178 AC_ARG_ENABLE(seccomp,
179 AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
181 AC_ARG_ENABLE(libscrypt,
182 AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
184 dnl check for the correct "ar" when cross-compiling
185 AN_MAKEVAR([AR], [AC_PROG_AR])
186 AN_PROGRAM([ar], [AC_PROG_AR])
187 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
188 AC_PROG_AR
190 dnl Check whether the above macro has settled for a simply named tool even
191 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
192 dnl because that will find any cc on the system, not only the cross-compiler,
193 dnl and then verify that a binary built with this compiler runs on the
194 dnl build system. It will then come to the false conclusion that we're not
195 dnl cross-compiling.
196 if test "x$enable_tool_name_check" != "xno"; then
197 if test "x$ac_tool_warned" = "xyes"; then
198 AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
199 elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
200 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
201 fi
202 fi
204 AC_PROG_CC
205 AC_PROG_CPP
206 AC_PROG_MAKE_SET
207 AC_PROG_RANLIB
209 AC_PATH_PROG([PERL], [perl])
211 dnl autoconf 2.59 appears not to support AC_PROG_SED
212 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
214 dnl check for asciidoc and a2x
215 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
216 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
218 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
220 AM_CONDITIONAL(USE_FW_HELPER, test "x$natpmp" = "xtrue" || test "x$upnp" = "xtrue")
221 AM_CONDITIONAL(NAT_PMP, test "x$natpmp" = "xtrue")
222 AM_CONDITIONAL(MINIUPNPC, test "x$upnp" = "xtrue")
223 AM_PROG_CC_C_O
224 AC_PROG_CC_C99
226 AC_ARG_VAR([PYTHON], [path to Python binary])
227 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
228 if test "x$PYTHON" = "x"; then
229 AC_MSG_WARN([Python unavailable; some tests will not be run.])
230 fi
231 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
233 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
234 AC_C_FLEXIBLE_ARRAY_MEMBER
235 ], [
236 dnl Maybe we've got an old autoconf...
237 AC_CACHE_CHECK([for flexible array members],
238 tor_cv_c_flexarray,
239 [AC_COMPILE_IFELSE(
240 AC_LANG_PROGRAM([
241 struct abc { int a; char b[]; };
242 ], [
243 struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
244 def->b[0] = 33;
245 ]),
246 [tor_cv_c_flexarray=yes],
247 [tor_cv_c_flexarray=no])])
248 if test "$tor_cv_flexarray" = "yes"; then
249 AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
250 else
251 AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
252 fi
253 ])
255 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
256 tor_cv_c_c99_decl,
257 [AC_COMPILE_IFELSE(
258 [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
259 [tor_cv_c_c99_decl=yes],
260 [tor_cv_c_c99_decl=no] )])
261 if test "$tor_cv_c_c99_decl" != "yes"; then
262 AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
263 fi
265 AC_CACHE_CHECK([for working C99 designated initializers],
266 tor_cv_c_c99_designated_init,
267 [AC_COMPILE_IFELSE(
268 [AC_LANG_PROGRAM([struct s { int a; int b; };],
269 [[ struct s ss = { .b = 5, .a = 6 }; ]])],
270 [tor_cv_c_c99_designated_init=yes],
271 [tor_cv_c_c99_designated_init=no] )])
273 if test "$tor_cv_c_c99_designated_init" != "yes"; then
274 AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
275 fi
277 TORUSER=_tor
278 AC_ARG_WITH(tor-user,
279 AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
280 [
281 TORUSER=$withval
282 ]
283 )
284 AC_SUBST(TORUSER)
286 TORGROUP=_tor
287 AC_ARG_WITH(tor-group,
288 AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
289 [
290 TORGROUP=$withval
291 ]
292 )
293 AC_SUBST(TORGROUP)
296 dnl If _WIN32 is defined and non-zero, we are building for win32
297 AC_MSG_CHECKING([for win32])
298 AC_RUN_IFELSE([AC_LANG_SOURCE([
299 int main(int c, char **v) {
300 #ifdef _WIN32
301 #if _WIN32
302 return 0;
303 #else
304 return 1;
305 #endif
306 #else
307 return 2;
308 #endif
309 }])],
310 bwin32=true; AC_MSG_RESULT([yes]),
311 bwin32=false; AC_MSG_RESULT([no]),
312 bwin32=cross; AC_MSG_RESULT([cross])
313 )
315 if test "$bwin32" = "cross"; then
316 AC_MSG_CHECKING([for win32 (cross)])
317 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
318 #ifdef _WIN32
319 int main(int c, char **v) {return 0;}
320 #else
321 #error
322 int main(int c, char **v) {return x(y);}
323 #endif
324 ])],
325 bwin32=true; AC_MSG_RESULT([yes]),
326 bwin32=false; AC_MSG_RESULT([no]))
327 fi
329 AH_BOTTOM([
330 #ifdef _WIN32
331 /* Defined to access windows functions and definitions for >=WinXP */
332 # ifndef WINVER
333 # define WINVER 0x0501
334 # endif
336 /* Defined to access _other_ windows functions and definitions for >=WinXP */
337 # ifndef _WIN32_WINNT
338 # define _WIN32_WINNT 0x0501
339 # endif
341 /* Defined to avoid including some windows headers as part of Windows.h */
342 # ifndef WIN32_LEAN_AND_MEAN
343 # define WIN32_LEAN_AND_MEAN 1
344 # endif
345 #endif
346 ])
349 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
351 dnl Enable C99 when compiling with MIPSpro
352 AC_MSG_CHECKING([for MIPSpro compiler])
353 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
354 #if (defined(__sgi) && defined(_COMPILER_VERSION))
355 #error
356 return x(y);
357 #endif
358 ])],
359 bmipspro=false; AC_MSG_RESULT(no),
360 bmipspro=true; AC_MSG_RESULT(yes))
362 if test "$bmipspro" = "true"; then
363 CFLAGS="$CFLAGS -c99"
364 fi
366 AC_C_BIGENDIAN
368 AC_SEARCH_LIBS(socket, [socket network])
369 AC_SEARCH_LIBS(gethostbyname, [nsl])
370 AC_SEARCH_LIBS(dlopen, [dl])
371 AC_SEARCH_LIBS(inet_aton, [resolv])
372 AC_SEARCH_LIBS(backtrace, [execinfo])
373 saved_LIBS="$LIBS"
374 AC_SEARCH_LIBS([clock_gettime], [rt])
375 if test "$LIBS" != "$saved_LIBS"; then
376 # Looks like we need -lrt for clock_gettime().
377 have_rt=yes
378 fi
380 AC_SEARCH_LIBS(pthread_create, [pthread])
381 AC_SEARCH_LIBS(pthread_detach, [pthread])
383 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
384 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
386 AC_CHECK_FUNCS(
387 _NSGetEnviron \
388 RtlSecureZeroMemory \
389 SecureZeroMemory \
390 accept4 \
391 backtrace \
392 backtrace_symbols_fd \
393 clock_gettime \
394 eventfd \
395 explicit_bzero \
396 timingsafe_memcmp \
397 flock \
398 ftime \
399 getaddrinfo \
400 getentropy \
401 getifaddrs \
402 getpass \
403 getrlimit \
404 gettimeofday \
405 gmtime_r \
406 htonll \
407 inet_aton \
408 ioctl \
409 issetugid \
410 llround \
411 localtime_r \
412 lround \
413 memmem \
414 memset_s \
415 pipe \
416 pipe2 \
417 prctl \
418 readpassphrase \
419 rint \
420 sigaction \
421 socketpair \
422 statvfs \
423 strlcat \
424 strlcpy \
425 strnlen \
426 strptime \
427 strtok_r \
428 strtoull \
429 sysconf \
430 sysctl \
431 truncate \
432 uname \
433 usleep \
434 vasprintf \
435 _vscprintf
436 )
438 if test "$bwin32" != "true"; then
439 AC_CHECK_HEADERS(pthread.h)
440 AC_CHECK_FUNCS(pthread_create)
441 AC_CHECK_FUNCS(pthread_condattr_setclock)
442 fi
444 if test "$bwin32" = "true"; then
445 AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
446 #include <windows.h>
447 #include <conio.h>
448 #include <wchar.h>
449 ])
450 fi
452 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
453 test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
455 dnl ------------------------------------------------------
456 dnl Where do you live, libevent? And how do we call you?
458 if test "$bwin32" = "true"; then
459 TOR_LIB_WS32=-lws2_32
460 TOR_LIB_IPHLPAPI=-liphlpapi
461 # Some of the cargo-cults recommend -lwsock32 as well, but I don't
462 # think it's actually necessary.
463 TOR_LIB_GDI=-lgdi32
464 else
465 TOR_LIB_WS32=
466 TOR_LIB_GDI=
467 fi
468 AC_SUBST(TOR_LIB_WS32)
469 AC_SUBST(TOR_LIB_GDI)
470 AC_SUBST(TOR_LIB_IPHLPAPI)
472 tor_libevent_pkg_redhat="libevent"
473 tor_libevent_pkg_debian="libevent-dev"
474 tor_libevent_devpkg_redhat="libevent-devel"
475 tor_libevent_devpkg_debian="libevent-dev"
477 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
478 dnl linking for static builds.
479 STATIC_LIBEVENT_FLAGS=""
480 if test "$enable_static_libevent" = "yes"; then
481 if test "$have_rt" = "yes"; then
482 STATIC_LIBEVENT_FLAGS=" -lrt "
483 fi
484 fi
486 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
487 #ifdef _WIN32
488 #include <winsock2.h>
489 #endif
490 #include <sys/time.h>
491 #include <sys/types.h>
492 #include <event.h>], [
493 #ifdef _WIN32
494 #include <winsock2.h>
495 #endif
496 void *event_init(void);],
497 [
498 #ifdef _WIN32
499 {WSADATA d; WSAStartup(0x101,&d); }
500 #endif
501 event_init();
502 ], [--with-libevent-dir], [/opt/libevent])
504 dnl Now check for particular libevent functions.
505 save_LIBS="$LIBS"
506 save_LDFLAGS="$LDFLAGS"
507 save_CPPFLAGS="$CPPFLAGS"
508 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
509 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
510 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
511 AC_CHECK_FUNCS([event_get_version_number \
512 evutil_secure_rng_set_urandom_device_file \
513 evutil_secure_rng_init \
514 ])
515 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
516 [#include <event.h>
517 ])
519 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
521 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
523 AM_CONDITIONAL(USE_EXTERNAL_EVDNS,
524 test "x$ac_cv_header_event2_dns_h" = "xyes")
526 if test "$enable_static_libevent" = "yes"; then
527 if test "$tor_cv_library_libevent_dir" = "(system)"; then
528 AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
529 else
530 TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
531 fi
532 else
533 if test "x$ac_cv_header_event2_event_h" = "xyes"; then
534 AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
535 AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
537 if test "$ac_cv_search_event_new" != "none required"; then
538 TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
539 fi
540 if test "$ac_cv_search_evdns_base_new" != "none required"; then
541 TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
542 fi
543 else
544 TOR_LIBEVENT_LIBS="-levent"
545 fi
546 fi
548 LIBS="$save_LIBS"
549 LDFLAGS="$save_LDFLAGS"
550 CPPFLAGS="$save_CPPFLAGS"
552 dnl This isn't the best test for Libevent 2.0.3-alpha. Once it's released,
553 dnl we can do much better.
554 if test "$enable_bufferevents" = "yes"; then
555 if test "$ac_cv_header_event2_bufferevent_ssl_h" != "yes"; then
556 AC_MSG_ERROR([You've asked for bufferevent support, but you're using a version of Libevent without SSL support. This won't work. We need Libevent 2.0.8-rc or later, and you don't seem to even have Libevent 2.0.3-alpha.])
557 else
559 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
561 # Check for the right version. First see if version detection works.
562 AC_MSG_CHECKING([whether we can detect the Libevent version])
563 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
564 #include <event2/event.h>
565 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 10
566 #error
567 int x = y(zz);
568 #else
569 int x = 1;
570 #endif
571 ])], [event_version_number_works=yes; AC_MSG_RESULT([yes]) ],
572 [event_version_number_works=no; AC_MSG_RESULT([no])])
573 if test "$event_version_number_works" != "yes"; then
574 AC_MSG_WARN([Version detection on Libevent seems broken. Your Libevent installation is probably screwed up or very old.])
575 else
576 AC_MSG_CHECKING([whether Libevent is new enough for bufferevents])
577 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
578 #include <event2/event.h>
579 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000d00
580 #error
581 int x = y(zz);
582 #else
583 int x = 1;
584 #endif
585 ])], [ AC_MSG_RESULT([yes]) ],
586 [ AC_MSG_RESULT([no])
587 AC_MSG_ERROR([Libevent does not seem new enough to support bufferevents. We require 2.0.13-stable or later]) ] )
588 fi
589 fi
590 fi
592 LIBS="$save_LIBS"
593 LDFLAGS="$save_LDFLAGS"
594 CPPFLAGS="$save_CPPFLAGS"
596 AM_CONDITIONAL(USE_BUFFEREVENTS, test "$enable_bufferevents" = "yes")
597 if test "$enable_bufferevents" = "yes"; then
598 AC_DEFINE(USE_BUFFEREVENTS, 1, [Defined if we're going to use Libevent's buffered IO API])
599 if test "$enable_static_libevent" = "yes"; then
600 TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent_openssl.a $TOR_LIBEVENT_LIBS"
601 else
602 TOR_LIBEVENT_LIBS="-levent_openssl $TOR_LIBEVENT_LIBS"
603 fi
604 fi
605 AC_SUBST(TOR_LIBEVENT_LIBS)
607 dnl ------------------------------------------------------
608 dnl Where do you live, libm?
610 dnl On some platforms (Haiku/BeOS) the math library is
611 dnl part of libroot. In which case don't link against lm
612 TOR_LIB_MATH=""
613 save_LIBS="$LIBS"
614 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
615 if test "$ac_cv_search_pow" != "none required"; then
616 TOR_LIB_MATH="$ac_cv_search_pow"
617 fi
618 LIBS="$save_LIBS"
619 AC_SUBST(TOR_LIB_MATH)
621 dnl ------------------------------------------------------
622 dnl Where do you live, openssl? And how do we call you?
624 tor_openssl_pkg_redhat="openssl"
625 tor_openssl_pkg_debian="libssl-dev"
626 tor_openssl_devpkg_redhat="openssl-devel"
627 tor_openssl_devpkg_debian="libssl-dev"
629 ALT_openssl_WITHVAL=""
630 AC_ARG_WITH(ssl-dir,
631 AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
632 [
633 if test "x$withval" != "xno" && test "x$withval" != "x"; then
634 ALT_openssl_WITHVAL="$withval"
635 fi
636 ])
638 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
639 [#include <openssl/rand.h>],
640 [void RAND_add(const void *buf, int num, double entropy);],
641 [RAND_add((void*)0,0,0);], [],
642 [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
644 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
646 if test "$enable_static_openssl" = "yes"; then
647 if test "$tor_cv_library_openssl_dir" = "(system)"; then
648 AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
649 else
650 TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
651 fi
652 else
653 TOR_OPENSSL_LIBS="-lssl -lcrypto"
654 fi
655 AC_SUBST(TOR_OPENSSL_LIBS)
657 dnl Now check for particular openssl functions.
658 save_LIBS="$LIBS"
659 save_LDFLAGS="$LDFLAGS"
660 save_CPPFLAGS="$CPPFLAGS"
661 LIBS="$TOR_OPENSSL_LIBS $LIBS"
662 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
663 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
665 AC_TRY_COMPILE([
666 #include <openssl/opensslv.h>
667 #if OPENSSL_VERSION_NUMBER < 0x1000000fL
668 #error "too old"
669 #endif
670 ], [],
671 [ : ],
672 [ AC_ERROR([OpenSSL is too old. We require 1.0.0 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
674 AC_TRY_COMPILE([
675 #include <openssl/opensslv.h>
676 #include <openssl/evp.h>
677 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
678 #error "no ECC"
679 #endif
680 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
681 #error "curves unavailable"
682 #endif
683 ], [],
684 [ : ],
685 [ AC_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
687 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
688 [#include <openssl/ssl.h>
689 ])
691 AC_CHECK_FUNCS([ \
692 SSL_SESSION_get_master_key \
693 SSL_get_server_random \
694 SSL_get_client_ciphers \
695 SSL_get_client_random \
696 SSL_CIPHER_find \
697 TLS_method
698 ])
700 dnl Check if OpenSSL has scrypt implementation.
701 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
703 LIBS="$save_LIBS"
704 LDFLAGS="$save_LDFLAGS"
705 CPPFLAGS="$save_CPPFLAGS"
707 dnl ------------------------------------------------------
708 dnl Where do you live, zlib? And how do we call you?
710 tor_zlib_pkg_redhat="zlib"
711 tor_zlib_pkg_debian="zlib1g"
712 tor_zlib_devpkg_redhat="zlib-devel"
713 tor_zlib_devpkg_debian="zlib1g-dev"
715 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
716 [#include <zlib.h>],
717 [const char * zlibVersion(void);],
718 [zlibVersion();], [--with-zlib-dir],
719 [/opt/zlib])
721 if test "$enable_static_zlib" = "yes"; then
722 if test "$tor_cv_library_zlib_dir" = "(system)"; then
723 AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
724 using --enable-static-zlib")
725 else
726 TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
727 fi
728 else
729 TOR_ZLIB_LIBS="-lz"
730 fi
731 AC_SUBST(TOR_ZLIB_LIBS)
733 dnl ----------------------------------------------------------------------
734 dnl Check if libcap is available for capabilities.
736 tor_cap_pkg_debian="libcap2"
737 tor_cap_pkg_redhat="libcap"
738 tor_cap_devpkg_debian="libcap-dev"
739 tor_cap_devpkg_redhat="libcap-devel"
741 AC_CHECK_LIB([cap], [cap_init], [],
742 AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
743 )
744 AC_CHECK_FUNCS(cap_set_proc)
746 dnl ---------------------------------------------------------------------
747 dnl Now that we know about our major libraries, we can check for compiler
748 dnl and linker hardening options. We need to do this with the libraries known,
749 dnl since sometimes the linker will like an option but not be willing to
750 dnl use it with a build of a library.
752 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
753 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_CAP_LIBS"
755 CFLAGS_FTRAPV=
756 CFLAGS_FWRAPV=
757 CFLAGS_ASAN=
758 CFLAGS_UBSAN=
760 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
761 #if !defined(__clang__)
762 #error
763 #endif])], have_clang=yes, have_clang=no)
765 if test "x$enable_gcc_hardening" != "xno"; then
766 CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
767 if test "x$have_clang" = "xyes"; then
768 TOR_CHECK_CFLAGS(-Qunused-arguments)
769 fi
770 TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
771 AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
772 AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
773 m4_ifdef([AS_VAR_IF],[
774 AS_VAR_IF(can_compile, [yes],
775 AS_VAR_IF(can_link, [yes],
776 [],
777 AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
778 )])
779 AS_VAR_POPDEF([can_link])
780 AS_VAR_POPDEF([can_compile])
781 TOR_CHECK_CFLAGS(-Wstack-protector)
782 TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
783 if test "$bwin32" = "false"; then
784 TOR_CHECK_CFLAGS(-fPIE)
785 TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
786 fi
787 TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
788 TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
789 if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
790 AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
791 fi
792 fi
794 if test "x$enable_expensive_hardening" = "xyes"; then
795 if test "$tor_cv_cflags__ftrapv" != "yes"; then
796 AC_MSG_ERROR([You requested expensive hardening, but the compiler does not seem to support -ftrapv.])
797 fi
799 TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
800 if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
801 AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
802 fi
804 TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
805 if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
806 AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
807 fi
809 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
810 fi
812 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
813 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
815 mulodi_fixes_ftrapv=no
816 if test "$have_clang" = "yes"; then
817 saved_CFLAGS="$CFLAGS"
818 CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
819 AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
820 AC_LINK_IFELSE([
821 AC_LANG_SOURCE([[
822 #include <stdint.h>
823 #include <stdlib.h>
824 int main(int argc, char **argv)
825 {
826 int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
827 * (int64_t)atoi(argv[3]);
828 return x == 9;
829 } ]])],
830 [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
831 [ftrapv_can_link=no; AC_MSG_RESULT([no])])
832 if test "$ftrapv_can_link" = "no"; then
833 AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
834 AC_LINK_IFELSE([
835 AC_LANG_SOURCE([[
836 #include <stdint.h>
837 #include <stdlib.h>
838 int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
839 *overflow=0;
840 return a;
841 }
842 int main(int argc, char **argv)
843 {
844 int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
845 * (int64_t)atoi(argv[3]);
846 return x == 9;
847 } ]])],
848 [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
849 [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
850 fi
851 CFLAGS="$saved_CFLAGS"
852 fi
854 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
856 dnl These cflags add bunches of branches, and we haven't been able to
857 dnl persuade ourselves that they're suitable for code that needs to be
858 dnl constant time.
859 AC_SUBST(CFLAGS_BUGTRAP)
860 dnl These cflags are variant ones sutable for code that needs to be
861 dnl constant-time.
862 AC_SUBST(CFLAGS_CONSTTIME)
864 if test "x$enable_linker_hardening" != "xno"; then
865 TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
866 fi
868 # For backtrace support
869 TOR_CHECK_LDFLAGS(-rdynamic)
871 dnl ------------------------------------------------------
872 dnl Now see if we have a -fomit-frame-pointer compiler option.
874 saved_CFLAGS="$CFLAGS"
875 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
876 F_OMIT_FRAME_POINTER=''
877 if test "$saved_CFLAGS" != "$CFLAGS"; then
878 if test "x$enable_expensive_hardening" != "xyes"; then
879 F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
880 fi
881 fi
882 CFLAGS="$saved_CFLAGS"
883 AC_SUBST(F_OMIT_FRAME_POINTER)
885 dnl ------------------------------------------------------
886 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
887 dnl for us, as GCC 4.6 and later do at many optimization levels), then
888 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
889 dnl code will work.
890 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
892 dnl ============================================================
893 dnl Check for libseccomp
895 if test "x$enable_seccomp" != "xno"; then
896 AC_CHECK_HEADERS([seccomp.h])
897 AC_SEARCH_LIBS(seccomp_init, [seccomp])
898 fi
900 dnl ============================================================
901 dnl Check for libscrypt
903 if test "x$enable_libscrypt" != "xno"; then
904 AC_CHECK_HEADERS([libscrypt.h])
905 AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
906 AC_CHECK_FUNCS([libscrypt_scrypt])
907 fi
909 dnl ============================================================
910 dnl We need an implementation of curve25519.
912 dnl set these defaults.
913 build_curve25519_donna=no
914 build_curve25519_donna_c64=no
915 use_curve25519_donna=no
916 use_curve25519_nacl=no
917 CURVE25519_LIBS=
919 dnl The best choice is using curve25519-donna-c64, but that requires
920 dnl that we
921 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
922 tor_cv_can_use_curve25519_donna_c64,
923 [AC_RUN_IFELSE(
924 [AC_LANG_PROGRAM([dnl
925 #include <stdint.h>
926 typedef unsigned uint128_t __attribute__((mode(TI)));
927 int func(uint64_t a, uint64_t b) {
928 uint128_t c = ((uint128_t)a) * b;
929 int ok = ((uint64_t)(c>>96)) == 522859 &&
930 (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
931 (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
932 (((uint64_t)(c))&0xffffffffL) == 0;
933 return ok;
934 }
935 ], [dnl
936 int ok = func( ((uint64_t)2000000000) * 1000000000,
937 ((uint64_t)1234567890) << 24);
938 return !ok;
939 ])],
940 [tor_cv_can_use_curve25519_donna_c64=yes],
941 [tor_cv_can_use_curve25519_donna_c64=no],
942 [AC_LINK_IFELSE(
943 [AC_LANG_PROGRAM([dnl
944 #include <stdint.h>
945 typedef unsigned uint128_t __attribute__((mode(TI)));
946 int func(uint64_t a, uint64_t b) {
947 uint128_t c = ((uint128_t)a) * b;
948 int ok = ((uint64_t)(c>>96)) == 522859 &&
949 (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
950 (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
951 (((uint64_t)(c))&0xffffffffL) == 0;
952 return ok;
953 }
954 ], [dnl
955 int ok = func( ((uint64_t)2000000000) * 1000000000,
956 ((uint64_t)1234567890) << 24);
957 return !ok;
958 ])],
959 [tor_cv_can_use_curve25519_donna_c64=cross],
960 [tor_cv_can_use_curve25519_donna_c64=no])])])
962 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
963 nacl/crypto_scalarmult_curve25519.h])
965 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
966 tor_cv_can_use_curve25519_nacl,
967 [tor_saved_LIBS="$LIBS"
968 LIBS="$LIBS -lnacl"
969 AC_LINK_IFELSE(
970 [AC_LANG_PROGRAM([dnl
971 #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
972 #include <crypto_scalarmult_curve25519.h>
973 #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
974 #include <nacl/crypto_scalarmult_curve25519.h>
975 #endif
976 #ifdef crypto_scalarmult_curve25519_ref_BYTES
977 #error Hey, this is the reference implementation! That's not fast.
978 #endif
979 ], [
980 unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
981 ])], [tor_cv_can_use_curve25519_nacl=yes],
982 [tor_cv_can_use_curve25519_nacl=no])
983 LIBS="$tor_saved_LIBS" ])
985 dnl Okay, now we need to figure out which one to actually use. Fall back
986 dnl to curve25519-donna.c
988 if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
989 build_curve25519_donna_c64=yes
990 use_curve25519_donna=yes
991 elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
992 use_curve25519_nacl=yes
993 CURVE25519_LIBS=-lnacl
994 else
995 build_curve25519_donna=yes
996 use_curve25519_donna=yes
997 fi
999 if test "x$use_curve25519_donna" = "xyes"; then
1000 AC_DEFINE(USE_CURVE25519_DONNA, 1,
1001 [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1002 fi
1003 if test "x$use_curve25519_nacl" = "xyes"; then
1004 AC_DEFINE(USE_CURVE25519_NACL, 1,
1005 [Defined if we should use a curve25519 from nacl])
1006 fi
1007 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1008 test "x$build_curve25519_donna" = "xyes")
1009 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1010 test "x$build_curve25519_donna_c64" = "xyes")
1011 AC_SUBST(CURVE25519_LIBS)
1013 dnl Make sure to enable support for large off_t if available.
1014 AC_SYS_LARGEFILE
1016 AC_CHECK_HEADERS([assert.h \
1017 errno.h \
1018 fcntl.h \
1019 signal.h \
1020 string.h \
1021 sys/capability.h \
1022 sys/fcntl.h \
1023 sys/stat.h \
1024 sys/time.h \
1025 sys/types.h \
1026 time.h \
1027 unistd.h \
1028 arpa/inet.h \
1029 crt_externs.h \
1030 execinfo.h \
1031 grp.h \
1032 ifaddrs.h \
1033 inttypes.h \
1034 limits.h \
1035 linux/types.h \
1036 machine/limits.h \
1037 malloc.h \
1038 malloc/malloc.h \
1039 malloc_np.h \
1040 netdb.h \
1041 netinet/in.h \
1042 netinet/in6.h \
1043 pwd.h \
1044 readpassphrase.h \
1045 stdint.h \
1046 sys/eventfd.h \
1047 sys/file.h \
1048 sys/ioctl.h \
1049 sys/limits.h \
1050 sys/mman.h \
1051 sys/param.h \
1052 sys/prctl.h \
1053 sys/resource.h \
1054 sys/select.h \
1055 sys/socket.h \
1056 sys/statvfs.h \
1057 sys/syscall.h \
1058 sys/sysctl.h \
1059 sys/syslimits.h \
1060 sys/time.h \
1061 sys/types.h \
1062 sys/un.h \
1063 sys/utime.h \
1064 sys/wait.h \
1065 syslog.h \
1066 utime.h])
1068 AC_CHECK_HEADERS(sys/param.h)
1070 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1071 [#ifdef HAVE_SYS_TYPES_H
1072 #include <sys/types.h>
1073 #endif
1074 #ifdef HAVE_SYS_SOCKET_H
1075 #include <sys/socket.h>
1076 #endif])
1077 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1078 [#ifdef HAVE_SYS_TYPES_H
1079 #include <sys/types.h>
1080 #endif
1081 #ifdef HAVE_SYS_SOCKET_H
1082 #include <sys/socket.h>
1083 #endif
1084 #ifdef HAVE_NET_IF_H
1085 #include <net/if.h>
1086 #endif
1087 #ifdef HAVE_NETINET_IN_H
1088 #include <netinet/in.h>
1089 #endif])
1091 AC_CHECK_HEADERS(linux/if.h,[],[],
1092 [
1093 #ifdef HAVE_SYS_SOCKET_H
1094 #include <sys/socket.h>
1095 #endif
1096 ])
1098 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1099 linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1100 [#ifdef HAVE_SYS_TYPES_H
1101 #include <sys/types.h>
1102 #endif
1103 #ifdef HAVE_SYS_SOCKET_H
1104 #include <sys/socket.h>
1105 #endif
1106 #ifdef HAVE_LIMITS_H
1107 #include <limits.h>
1108 #endif
1109 #ifdef HAVE_LINUX_TYPES_H
1110 #include <linux/types.h>
1111 #endif
1112 #ifdef HAVE_NETINET_IN6_H
1113 #include <netinet/in6.h>
1114 #endif
1115 #ifdef HAVE_NETINET_IN_H
1116 #include <netinet/in.h>
1117 #endif])
1119 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1120 linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1121 [#ifdef HAVE_SYS_TYPES_H
1122 #include <sys/types.h>
1123 #endif
1124 #ifdef HAVE_SYS_SOCKET_H
1125 #include <sys/socket.h>
1126 #endif
1127 #ifdef HAVE_LIMITS_H
1128 #include <limits.h>
1129 #endif
1130 #ifdef HAVE_LINUX_TYPES_H
1131 #include <linux/types.h>
1132 #endif
1133 #ifdef HAVE_NETINET_IN6_H
1134 #include <netinet/in6.h>
1135 #endif
1136 #ifdef HAVE_NETINET_IN_H
1137 #include <netinet/in.h>
1138 #endif
1139 #ifdef HAVE_LINUX_IF_H
1140 #include <linux/if.h>
1141 #endif])
1143 if test "x$transparent" = "xtrue"; then
1144 transparent_ok=0
1145 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1146 transparent_ok=1
1147 fi
1148 if test "x$linux_netfilter_ipv4" = "x1"; then
1149 transparent_ok=1
1150 fi
1151 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1152 transparent_ok=1
1153 fi
1154 if test "x$transparent_ok" = "x1"; then
1155 AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1156 case "$host" in
1157 *-*-openbsd* | *-*-bitrig*)
1158 AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
1159 esac
1160 else
1161 AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1162 fi
1163 fi
1165 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1166 [#ifdef HAVE_SYS_TYPES_H
1167 #include <sys/types.h>
1168 #endif
1169 #ifdef HAVE_SYS_TIME_H
1170 #include <sys/time.h>
1171 #endif])
1173 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1174 dnl Watch out.
1176 AC_CHECK_SIZEOF(int8_t)
1177 AC_CHECK_SIZEOF(int16_t)
1178 AC_CHECK_SIZEOF(int32_t)
1179 AC_CHECK_SIZEOF(int64_t)
1180 AC_CHECK_SIZEOF(uint8_t)
1181 AC_CHECK_SIZEOF(uint16_t)
1182 AC_CHECK_SIZEOF(uint32_t)
1183 AC_CHECK_SIZEOF(uint64_t)
1184 AC_CHECK_SIZEOF(intptr_t)
1185 AC_CHECK_SIZEOF(uintptr_t)
1187 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1189 AC_CHECK_SIZEOF(char)
1190 AC_CHECK_SIZEOF(short)
1191 AC_CHECK_SIZEOF(int)
1192 AC_CHECK_SIZEOF(long)
1193 AC_CHECK_SIZEOF(long long)
1194 AC_CHECK_SIZEOF(__int64)
1195 AC_CHECK_SIZEOF(void *)
1196 AC_CHECK_SIZEOF(time_t)
1197 AC_CHECK_SIZEOF(size_t)
1198 AC_CHECK_SIZEOF(pid_t)
1200 AC_CHECK_TYPES([uint, u_char, ssize_t])
1202 AC_PC_FROM_UCONTEXT([:])
1204 dnl used to include sockaddr_storage, but everybody has that.
1205 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1206 [#ifdef HAVE_SYS_TYPES_H
1207 #include <sys/types.h>
1208 #endif
1209 #ifdef HAVE_NETINET_IN_H
1210 #include <netinet/in.h>
1211 #endif
1212 #ifdef HAVE_NETINET_IN6_H
1213 #include <netinet/in6.h>
1214 #endif
1215 #ifdef HAVE_SYS_SOCKET_H
1216 #include <sys/socket.h>
1217 #endif
1218 #ifdef _WIN32
1219 #define _WIN32_WINNT 0x0501
1220 #define WIN32_LEAN_AND_MEAN
1221 #include <winsock2.h>
1222 #include <ws2tcpip.h>
1223 #endif
1224 ])
1225 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1226 [#ifdef HAVE_SYS_TYPES_H
1227 #include <sys/types.h>
1228 #endif
1229 #ifdef HAVE_NETINET_IN_H
1230 #include <netinet/in.h>
1231 #endif
1232 #ifdef HAVE_NETINET_IN6_H
1233 #include <netinet/in6.h>
1234 #endif
1235 #ifdef HAVE_SYS_SOCKET_H
1236 #include <sys/socket.h>
1237 #endif
1238 #ifdef _WIN32
1239 #define _WIN32_WINNT 0x0501
1240 #define WIN32_LEAN_AND_MEAN
1241 #include <winsock2.h>
1242 #include <ws2tcpip.h>
1243 #endif
1244 ])
1246 AC_CHECK_TYPES([rlim_t], , ,
1247 [#ifdef HAVE_SYS_TYPES_H
1248 #include <sys/types.h>
1249 #endif
1250 #ifdef HAVE_SYS_TIME_H
1251 #include <sys/time.h>
1252 #endif
1253 #ifdef HAVE_SYS_RESOURCE_H
1254 #include <sys/resource.h>
1255 #endif
1256 ])
1258 AX_CHECK_SIGN([time_t],
1259 [ : ],
1260 [ : ], [
1261 #ifdef HAVE_SYS_TYPES_H
1262 #include <sys/types.h>
1263 #endif
1264 #ifdef HAVE_SYS_TIME_H
1265 #include <sys/time.h>
1266 #endif
1267 #ifdef HAVE_TIME_H
1268 #include <time.h>
1269 #endif
1270 ])
1272 if test "$ax_cv_decl_time_t_signed" = "no"; then
1273 AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1274 fi
1276 AX_CHECK_SIGN([size_t],
1277 [ tor_cv_size_t_signed=yes ],
1278 [ tor_cv_size_t_signed=no ], [
1279 #ifdef HAVE_SYS_TYPES_H
1280 #include <sys/types.h>
1281 #endif
1282 ])
1284 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1285 AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1286 fi
1288 AX_CHECK_SIGN([enum always],
1289 [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1290 [ : ], [
1291 enum always { AAA, BBB, CCC };
1292 ])
1294 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1295 #ifdef HAVE_SYS_SOCKET_H
1296 #include <sys/socket.h>
1297 #endif
1298 ])
1300 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1302 AC_CHECK_SIZEOF(cell_t)
1304 # Now make sure that NULL can be represented as zero bytes.
1305 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1306 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1307 [[#include <stdlib.h>
1308 #include <string.h>
1309 #include <stdio.h>
1310 #ifdef HAVE_STDDEF_H
1311 #include <stddef.h>
1312 #endif
1313 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1314 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1315 [tor_cv_null_is_zero=yes],
1316 [tor_cv_null_is_zero=no],
1317 [tor_cv_null_is_zero=cross])])
1319 if test "$tor_cv_null_is_zero" = "cross"; then
1320 # Cross-compiling; let's hope that the target isn't raving mad.
1321 AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1322 fi
1324 if test "$tor_cv_null_is_zero" != "no"; then
1325 AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1326 [Define to 1 iff memset(0) sets pointers to NULL])
1327 fi
1329 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1330 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1331 [[#include <stdlib.h>
1332 #include <string.h>
1333 #include <stdio.h>
1334 #ifdef HAVE_STDDEF_H
1335 #include <stddef.h>
1336 #endif
1337 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1338 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1339 [tor_cv_dbl0_is_zero=yes],
1340 [tor_cv_dbl0_is_zero=no],
1341 [tor_cv_dbl0_is_zero=cross])])
1343 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1344 # Cross-compiling; let's hope that the target isn't raving mad.
1345 AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1346 fi
1348 if test "$tor_cv_dbl0_is_zero" != "no"; then
1349 AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1350 [Define to 1 iff memset(0) sets doubles to 0.0])
1351 fi
1353 # And what happens when we malloc zero?
1354 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1355 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1356 [[#include <stdlib.h>
1357 #include <string.h>
1358 #include <stdio.h>
1359 #ifdef HAVE_STDDEF_H
1360 #include <stddef.h>
1361 #endif
1362 int main () { return malloc(0)?0:1; }]])],
1363 [tor_cv_malloc_zero_works=yes],
1364 [tor_cv_malloc_zero_works=no],
1365 [tor_cv_malloc_zero_works=cross])])
1367 if test "$tor_cv_malloc_zero_works" = "cross"; then
1368 # Cross-compiling; let's hope that the target isn't raving mad.
1369 AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1370 fi
1372 if test "$tor_cv_malloc_zero_works" = "yes"; then
1373 AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1374 [Define to 1 iff malloc(0) returns a pointer])
1375 fi
1377 # whether we seem to be in a 2s-complement world.
1378 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1379 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1380 [[int main () { int problem = ((-99) != (~99)+1);
1381 return problem ? 1 : 0; }]])],
1382 [tor_cv_twos_complement=yes],
1383 [tor_cv_twos_complement=no],
1384 [tor_cv_twos_complement=cross])])
1386 if test "$tor_cv_twos_complement" = "cross"; then
1387 # Cross-compiling; let's hope that the target isn't raving mad.
1388 AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1389 fi
1391 if test "$tor_cv_twos_complement" != "no"; then
1392 AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1393 [Define to 1 iff we represent negative integers with
1394 two's complement])
1395 fi
1397 # What does shifting a negative value do?
1398 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1399 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1400 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1401 [tor_cv_sign_extend=yes],
1402 [tor_cv_sign_extend=no],
1403 [tor_cv_sign_extend=cross])])
1405 if test "$tor_cv_sign_extend" = "cross"; then
1406 # Cross-compiling; let's hope that the target isn't raving mad.
1407 AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1408 fi
1410 if test "$tor_cv_sign_extend" != "no"; then
1411 AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1412 [Define to 1 iff right-shifting a negative value performs sign-extension])
1413 fi
1415 # Whether we should use the dmalloc memory allocation debugging library.
1416 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1417 AC_ARG_WITH(dmalloc,
1418 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1419 [if [[ "$withval" = "yes" ]]; then
1420 dmalloc=1
1421 AC_MSG_RESULT(yes)
1422 else
1423 dmalloc=1
1424 AC_MSG_RESULT(no)
1425 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1426 )
1428 if [[ $dmalloc -eq 1 ]]; then
1429 AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1430 AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1431 AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1432 AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1433 fi
1435 AC_ARG_WITH(tcmalloc,
1436 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1437 [ tcmalloc=yes ], [ tcmalloc=no ])
1439 if test "x$tcmalloc" = "xyes"; then
1440 LDFLAGS="-ltcmalloc $LDFLAGS"
1441 fi
1443 using_custom_malloc=no
1444 if test "x$enable_openbsd_malloc" = "xyes"; then
1445 using_custom_malloc=yes
1446 fi
1447 if test "x$tcmalloc" = "xyes"; then
1448 using_custom_malloc=yes
1449 fi
1450 if test "$using_custom_malloc" = "no"; then
1451 AC_CHECK_FUNCS(mallinfo)
1452 fi
1454 # By default, we're going to assume we don't have mlockall()
1455 # bionic and other platforms have various broken mlockall subsystems.
1456 # Some systems don't have a working mlockall, some aren't linkable,
1457 # and some have it but don't declare it.
1458 AC_CHECK_FUNCS(mlockall)
1459 AC_CHECK_DECLS([mlockall], , , [
1460 #ifdef HAVE_SYS_MMAN_H
1461 #include <sys/mman.h>
1462 #endif])
1464 # Allow user to specify an alternate syslog facility
1465 AC_ARG_WITH(syslog-facility,
1466 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1467 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1468 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1469 AC_SUBST(LOGFACILITY)
1471 # Check if we have getresuid and getresgid
1472 AC_CHECK_FUNCS(getresuid getresgid)
1474 # Check for gethostbyname_r in all its glorious incompatible versions.
1475 # (This logic is based on that in Python's configure.in)
1476 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1477 [Define this if you have any gethostbyname_r()])
1479 AC_CHECK_FUNC(gethostbyname_r, [
1480 AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1481 OLD_CFLAGS=$CFLAGS
1482 CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1483 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1484 #include <netdb.h>
1485 ], [[
1486 char *cp1, *cp2;
1487 struct hostent *h1, *h2;
1488 int i1, i2;
1489 (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1490 ]])],[
1491 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1492 AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1493 [Define this if gethostbyname_r takes 6 arguments])
1494 AC_MSG_RESULT(6)
1495 ], [
1496 AC_TRY_COMPILE([
1497 #include <netdb.h>
1498 ], [
1499 char *cp1, *cp2;
1500 struct hostent *h1;
1501 int i1, i2;
1502 (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1503 ], [
1504 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1505 AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1506 [Define this if gethostbyname_r takes 5 arguments])
1507 AC_MSG_RESULT(5)
1508 ], [
1509 AC_TRY_COMPILE([
1510 #include <netdb.h>
1511 ], [
1512 char *cp1;
1513 struct hostent *h1;
1514 struct hostent_data hd;
1515 (void) gethostbyname_r(cp1,h1,&hd);
1516 ], [
1517 AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1518 AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1519 [Define this if gethostbyname_r takes 3 arguments])
1520 AC_MSG_RESULT(3)
1521 ], [
1522 AC_MSG_RESULT(0)
1523 ])
1524 ])
1525 ])
1526 CFLAGS=$OLD_CFLAGS
1527 ])
1529 AC_CACHE_CHECK([whether the C compiler supports __func__],
1530 tor_cv_have_func_macro,
1531 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1532 #include <stdio.h>
1533 int main(int c, char **v) { puts(__func__); }])],
1534 tor_cv_have_func_macro=yes,
1535 tor_cv_have_func_macro=no))
1537 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1538 tor_cv_have_FUNC_macro,
1539 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1540 #include <stdio.h>
1541 int main(int c, char **v) { puts(__FUNC__); }])],
1542 tor_cv_have_FUNC_macro=yes,
1543 tor_cv_have_FUNC_macro=no))
1545 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1546 tor_cv_have_FUNCTION_macro,
1547 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1548 #include <stdio.h>
1549 int main(int c, char **v) { puts(__FUNCTION__); }])],
1550 tor_cv_have_FUNCTION_macro=yes,
1551 tor_cv_have_FUNCTION_macro=no))
1553 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1554 tor_cv_have_environ_declared,
1555 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1556 #ifdef HAVE_UNISTD_H
1557 #include <unistd.h>
1558 #endif
1559 #include <stdlib.h>
1560 int main(int c, char **v) { char **t = environ; }])],
1561 tor_cv_have_environ_declared=yes,
1562 tor_cv_have_environ_declared=no))
1564 if test "$tor_cv_have_func_macro" = "yes"; then
1565 AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1566 fi
1568 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1569 AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1570 fi
1572 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1573 AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1574 [Defined if the compiler supports __FUNCTION__])
1575 fi
1577 if test "$tor_cv_have_environ_declared" = "yes"; then
1578 AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1579 [Defined if we have extern char **environ already declared])
1580 fi
1582 # $prefix stores the value of the --prefix command line option, or
1583 # NONE if the option wasn't set. In the case that it wasn't set, make
1584 # it be the default, so that we can use it to expand directories now.
1585 if test "x$prefix" = "xNONE"; then
1586 prefix=$ac_default_prefix
1587 fi
1589 # and similarly for $exec_prefix
1590 if test "x$exec_prefix" = "xNONE"; then
1591 exec_prefix=$prefix
1592 fi
1594 if test "x$BUILDDIR" = "x"; then
1595 BUILDDIR=`pwd`
1596 fi
1597 AC_SUBST(BUILDDIR)
1598 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1599 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1601 if test "x$CONFDIR" = "x"; then
1602 CONFDIR=`eval echo $sysconfdir/tor`
1603 fi
1604 AC_SUBST(CONFDIR)
1605 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1606 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1608 BINDIR=`eval echo $bindir`
1609 AC_SUBST(BINDIR)
1610 LOCALSTATEDIR=`eval echo $localstatedir`
1611 AC_SUBST(LOCALSTATEDIR)
1613 if test "$bwin32" = "true"; then
1614 # Test if the linker supports the --nxcompat and --dynamicbase options
1615 # for Windows
1616 save_LDFLAGS="$LDFLAGS"
1617 LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1618 AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1619 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1620 [AC_MSG_RESULT([yes])]
1621 [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1622 [AC_MSG_RESULT([no])]
1623 )
1624 LDFLAGS="$save_LDFLAGS"
1625 fi
1627 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1628 # than autoconf's macros like.
1629 if test "$GCC" = "yes"; then
1630 # Disable GCC's strict aliasing checks. They are an hours-to-debug
1631 # accident waiting to happen.
1632 CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1633 else
1634 # Override optimization level for non-gcc compilers
1635 CFLAGS="$CFLAGS -O"
1636 enable_gcc_warnings=no
1637 enable_gcc_warnings_advisory=no
1638 fi
1640 # Warnings implies advisory-warnings and -Werror.
1641 if test "$enable_gcc_warnings" = "yes"; then
1642 enable_gcc_warnings_advisory=yes
1643 enable_fatal_warnings=yes
1644 fi
1646 # OS X Lion started deprecating the system openssl. Let's just disable
1647 # all deprecation warnings on OS X. Also, to potentially make the binary
1648 # a little smaller, let's enable dead_strip.
1649 case "$host_os" in
1651 darwin*)
1652 CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1653 LDFLAGS="$LDFLAGS -dead_strip" ;;
1654 esac
1656 # Add some more warnings which we use in development but not in the
1657 # released versions. (Some relevant gcc versions can't handle these.)
1658 #
1659 # Note that we have to do this near the end of the autoconf process, or
1660 # else we may run into problems when these warnings hit on the testing C
1661 # programs that autoconf wants to build.
1662 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1664 case "$host" in
1665 *-*-openbsd* | *-*-bitrig*)
1666 # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1667 # That's fine, except that the headers don't pass -Wredundant-decls.
1668 # Therefore, let's disable -Wsystem-headers when we're building
1669 # with maximal warnings on OpenBSD.
1670 CFLAGS="$CFLAGS -Wno-system-headers" ;;
1671 esac
1673 # GCC4.3 users once report trouble with -Wstrict-overflow=5. GCC5 users
1674 # have it work better.
1675 # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1677 # This warning was added in gcc 4.3, but it appears to generate
1678 # spurious warnings in gcc 4.4. I don't know if it works in 4.5.
1679 #CFLAGS="$CFLAGS -Wlogical-op"
1681 m4_foreach_w([warning_flag], [
1682 -Waddress
1683 -Waddress-of-array-temporary
1684 -Waddress-of-temporary
1685 -Wambiguous-macro
1686 -Wanonymous-pack-parens
1687 -Warc
1688 -Warc-abi
1689 -Warc-bridge-casts-disallowed-in-nonarc
1690 -Warc-maybe-repeated-use-of-weak
1691 -Warc-performSelector-leaks
1692 -Warc-repeated-use-of-weak
1693 -Warray-bounds
1694 -Warray-bounds-pointer-arithmetic
1695 -Wasm
1696 -Wasm-operand-widths
1697 -Watomic-properties
1698 -Watomic-property-with-user-defined-accessor
1699 -Wauto-import
1700 -Wauto-storage-class
1701 -Wauto-var-id
1702 -Wavailability
1703 -Wbackslash-newline-escape
1704 -Wbad-array-new-length
1705 -Wbind-to-temporary-copy
1706 -Wbitfield-constant-conversion
1707 -Wbool-conversion
1708 -Wbool-conversions
1709 -Wbuiltin-requires-header
1710 -Wchar-align
1711 -Wcompare-distinct-pointer-types
1712 -Wcomplex-component-init
1713 -Wconditional-type-mismatch
1714 -Wconfig-macros
1715 -Wconstant-conversion
1716 -Wconstant-logical-operand
1717 -Wconstexpr-not-const
1718 -Wcustom-atomic-properties
1719 -Wdangling-field
1720 -Wdangling-initializer-list
1721 -Wdate-time
1722 -Wdelegating-ctor-cycles
1723 -Wdeprecated-implementations
1724 -Wdeprecated-register
1725 -Wdirect-ivar-access
1726 -Wdiscard-qual
1727 -Wdistributed-object-modifiers
1728 -Wdivision-by-zero
1729 -Wdollar-in-identifier-extension
1730 -Wdouble-promotion
1731 -Wduplicate-decl-specifier
1732 -Wduplicate-enum
1733 -Wduplicate-method-arg
1734 -Wduplicate-method-match
1735 -Wduplicated-cond
1736 -Wdynamic-class-memaccess
1737 -Wembedded-directive
1738 -Wempty-translation-unit
1739 -Wenum-conversion
1740 -Wexit-time-destructors
1741 -Wexplicit-ownership-type
1742 -Wextern-initializer
1743 -Wextra
1744 -Wextra-semi
1745 -Wextra-tokens
1746 -Wflexible-array-extensions
1747 -Wfloat-conversion
1748 -Wformat-non-iso
1749 -Wfour-char-constants
1750 -Wgcc-compat
1751 -Wglobal-constructors
1752 -Wgnu-array-member-paren-init
1753 -Wgnu-designator
1754 -Wgnu-static-float-init
1755 -Wheader-guard
1756 -Wheader-hygiene
1757 -Widiomatic-parentheses
1758 -Wignored-attributes
1759 -Wimplicit-atomic-properties
1760 -Wimplicit-conversion-floating-point-to-bool
1761 -Wimplicit-exception-spec-mismatch
1762 -Wimplicit-fallthrough
1763 -Wimplicit-fallthrough-per-function
1764 -Wimplicit-retain-self
1765 -Wimport-preprocessor-directive-pedantic
1766 -Wincompatible-library-redeclaration
1767 -Wincompatible-pointer-types-discards-qualifiers
1768 -Wincomplete-implementation
1769 -Wincomplete-module
1770 -Wincomplete-umbrella
1771 -Winit-self
1772 -Wint-conversions
1773 -Wint-to-void-pointer-cast
1774 -Winteger-overflow
1775 -Winvalid-constexpr
1776 -Winvalid-iboutlet
1777 -Winvalid-noreturn
1778 -Winvalid-pp-token
1779 -Winvalid-source-encoding
1780 -Winvalid-token-paste
1781 -Wknr-promoted-parameter
1782 -Wlanguage-extension-token
1783 -Wlarge-by-value-copy
1784 -Wliteral-conversion
1785 -Wliteral-range
1786 -Wlocal-type-template-args
1787 -Wlogical-op
1788 -Wloop-analysis
1789 -Wmain-return-type
1790 -Wmalformed-warning-check
1791 -Wmethod-signatures
1792 -Wmicrosoft
1793 -Wmicrosoft-exists
1794 -Wmismatched-parameter-types
1795 -Wmismatched-return-types
1796 -Wmissing-field-initializers
1797 -Wmissing-format-attribute
1798 -Wmissing-noreturn
1799 -Wmissing-selector-name
1800 -Wmissing-sysroot
1801 -Wmissing-variable-declarations
1802 -Wmodule-conflict
1803 -Wnested-anon-types
1804 -Wnewline-eof
1805 -Wnon-literal-null-conversion
1806 -Wnon-pod-varargs
1807 -Wnonportable-cfstrings
1808 -Wnormalized=id
1809 -Wnull-arithmetic
1810 -Wnull-character
1811 -Wnull-conversion
1812 -Wnull-dereference
1813 -Wout-of-line-declaration
1814 -Wover-aligned
1815 -Woverlength-strings
1816 -Woverride-init
1817 -Woverriding-method-mismatch
1818 -Wpointer-type-mismatch
1819 -Wpredefined-identifier-outside-function
1820 -Wprotocol-property-synthesis-ambiguity
1821 -Wreadonly-iboutlet-property
1822 -Wreadonly-setter-attrs
1823 -Wreceiver-expr
1824 -Wreceiver-forward-class
1825 -Wreceiver-is-weak
1826 -Wreinterpret-base-class
1827 -Wrequires-super-attribute
1828 -Wreserved-user-defined-literal
1829 -Wreturn-stack-address
1830 -Wsection
1831 -Wselector-type-mismatch
1832 -Wsentinel
1833 -Wserialized-diagnostics
1834 -Wshift-count-negative
1835 -Wshift-count-overflow
1836 -Wshift-negative-value
1837 -Wshift-overflow=2
1838 -Wshift-sign-overflow
1839 -Wshorten-64-to-32
1840 -Wsizeof-array-argument
1841 -Wsource-uses-openmp
1842 -Wstatic-float-init
1843 -Wstatic-in-inline
1844 -Wstatic-local-in-inline
1845 -Wstrict-overflow=2
1846 -Wstring-compare
1847 -Wstring-conversion
1848 -Wstrlcpy-strlcat-size
1849 -Wstrncat-size
1850 -Wsuggest-attribute=format
1851 -Wsuggest-attribute=noreturn
1852 -Wsuper-class-method-mismatch
1853 -Wswitch-bool
1854 -Wsync-nand
1855 -Wtautological-constant-out-of-range-compare
1856 -Wtentative-definition-incomplete-type
1857 -Wthread-safety
1858 -Wthread-safety-analysis
1859 -Wthread-safety-attributes
1860 -Wthread-safety-beta
1861 -Wthread-safety-precise
1862 -Wtrampolines
1863 -Wtype-safety
1864 -Wtypedef-redefinition
1865 -Wtypename-missing
1866 -Wundefined-inline
1867 -Wundefined-internal
1868 -Wundefined-reinterpret-cast
1869 -Wunicode
1870 -Wunicode-whitespace
1871 -Wunknown-warning-option
1872 -Wunnamed-type-template-args
1873 -Wunneeded-member-function
1874 -Wunsequenced
1875 -Wunsupported-visibility
1876 -Wunused-but-set-parameter
1877 -Wunused-but-set-variable
1878 -Wunused-command-line-argument
1879 -Wunused-const-variable=2
1880 -Wunused-exception-parameter
1881 -Wunused-local-typedefs
1882 -Wunused-member-function
1883 -Wunused-sanitize-argument
1884 -Wunused-volatile-lvalue
1885 -Wuser-defined-literals
1886 -Wvariadic-macros
1887 -Wvector-conversion
1888 -Wvector-conversions
1889 -Wvexing-parse
1890 -Wvisibility
1891 -Wvla-extension
1892 -Wzero-length-array
1893 ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
1895 CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1896 CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1897 CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1898 CFLAGS="$CFLAGS -Wwrite-strings"
1899 CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1900 CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
1901 CFLAGS="$CFLAGS -Wunused-parameter "
1902 # These interfere with building main() { return 0; }, which autoconf
1903 # likes to use as its default program.
1904 CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
1906 if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
1907 AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
1908 fi
1909 if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
1910 AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
1911 fi
1913 if test "x$enable_fatal_warnings" = "xyes"; then
1914 # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
1915 # default autoconf programs are full of errors.
1916 CFLAGS="$CFLAGS -Werror"
1917 fi
1919 fi
1921 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
1922 case "$host_os" in
1923 darwin*)
1924 AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-profiling.])
1925 esac
1926 fi
1928 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1930 AC_CONFIG_FILES([
1931 Doxyfile
1932 Makefile
1933 contrib/dist/suse/tor.sh
1934 contrib/operator-tools/tor.logrotate
1935 contrib/dist/tor.sh
1936 contrib/dist/torctl
1937 contrib/dist/tor.service
1938 src/config/torrc.sample
1939 src/config/torrc.minimal
1940 scripts/maint/checkOptionDocs.pl
1941 scripts/maint/updateVersions.pl
1942 ])
1944 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
1945 regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
1946 for file in $regular_mans ; do
1947 if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
1948 echo "==================================";
1949 echo;
1950 echo "Building Tor has failed since manpages cannot be built.";
1951 echo;
1952 echo "You need asciidoc installed to be able to build the manpages.";
1953 echo "To build without manpages, use the --disable-asciidoc argument";
1954 echo "when calling configure.";
1955 echo;
1956 echo "==================================";
1957 exit 1;
1958 fi
1959 done
1960 fi
1962 AC_OUTPUT