configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2013, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT([tor],[0.2.6.0-alpha-dev])
   7 AC_CONFIG_SRCDIR([src/or/main.c])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_INIT_AUTOMAKE
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AC_CONFIG_HEADERS([orconfig.h])
  12
  13 AC_CANONICAL_HOST
  14
  15 if test -f /etc/redhat-release ; then
  16   if test -f /usr/kerberos/include ; then
  17     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  18   fi
  19 fi
  20
  21 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  22 # the += operator on it in src/or/Makefile.am
  23 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  24
  25 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  26 AC_ARG_ENABLE(buf-freelists,
  27    AS_HELP_STRING(--enable-buf-freelists, enable freelists for buffer RAM))
  28 AC_ARG_ENABLE(mempools,
  29    AS_HELP_STRING(--enable-mempools, enable mempools for relay cells))
  30 AC_ARG_ENABLE(openbsd-malloc,
  31    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  32 AC_ARG_ENABLE(instrument-downloads,
  33    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  34 AC_ARG_ENABLE(static-openssl,
  35    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  36 AC_ARG_ENABLE(static-libevent,
  37    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  38 AC_ARG_ENABLE(static-zlib,
  39    AS_HELP_STRING(--enable-static-zlib, Link against a static zlib library. Requires --with-zlib-dir))
  40 AC_ARG_ENABLE(static-tor,
  41    AS_HELP_STRING(--enable-static-tor, Create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir))
  42 AC_ARG_ENABLE(curve25519,
  43    AS_HELP_STRING(--disable-curve25519, Build Tor with no curve25519 elliptic-curve crypto support))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [Don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [Enable coverage support in the unit-test build]))
  48
  49 AM_CONDITIONAL(UNITTESTS_ENABLED, test x$enable_unittests != xno)
  50 AM_CONDITIONAL(COVERAGE_ENABLED, test x$enable_coverage = xyes)
  51
  52 if test "$enable_static_tor" = "yes"; then
  53   enable_static_libevent="yes";
  54   enable_static_openssl="yes";
  55   enable_static_zlib="yes";
  56   CFLAGS="$CFLAGS -static"
  57 fi
  58
  59 if test x$enable_buf_freelists = xyes; then
  60   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  61             [Defined if we try to use freelists for buffer RAM chunks])
  62 fi
  63
  64 AM_CONDITIONAL(USE_MEMPOOLS, test x$enable_mempools = xyes)
  65 if test x$enable_mempools = xyes; then
  66   AC_DEFINE(ENABLE_MEMPOOLS, 1,
  67             [Defined if we try to use mempools for cells being relayed])
  68 fi
  69
  70 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  71 if test x$enable_instrument_downloads = xyes; then
  72   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  73             [Defined if we want to keep track of how much of each kind of resource we download.])
  74 fi
  75
  76 AC_ARG_ENABLE(transparent,
  77      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  78      [case "${enableval}" in
  79         yes) transparent=true ;;
  80         no)  transparent=false ;;
  81         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  82       esac], [transparent=true])
  83
  84 AC_ARG_ENABLE(asciidoc,
  85      AS_HELP_STRING(--disable-asciidoc, don't use asciidoc (disables building of manpages)),
  86      [case "${enableval}" in
  87         yes) asciidoc=true ;;
  88         no)  asciidoc=false ;;
  89         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  90       esac], [asciidoc=true])
  91
  92 # By default, we're not ready to ship a NAT-PMP aware Tor
  93 AC_ARG_ENABLE(nat-pmp,
  94      AS_HELP_STRING(--enable-nat-pmp, enable NAT-PMP support),
  95      [case "${enableval}" in
  96         yes) natpmp=true ;;
  97         no)  natpmp=false ;;
  98         * ) AC_MSG_ERROR(bad value for --enable-nat-pmp) ;;
  99       esac], [natpmp=false])
 100
 101 # By default, we're not ready to ship a UPnP aware Tor
 102 AC_ARG_ENABLE(upnp,
 103      AS_HELP_STRING(--enable-upnp, enable UPnP support),
 104      [case "${enableval}" in
 105         yes) upnp=true ;;
 106         no)  upnp=false ;;
 107         * ) AC_MSG_ERROR(bad value for --enable-upnp) ;;
 108       esac], [upnp=false])
 109
 110 case $host in
 111    *-*-solaris* )
 112      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 113      ;;
 114 esac
 115
 116 AC_ARG_ENABLE(gcc-warnings,
 117      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
 118 AC_ARG_ENABLE(gcc-warnings-advisory,
 119      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
 120
 121 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 122 AC_ARG_ENABLE(gcc-hardening,
 123     AS_HELP_STRING(--disable-gcc-hardening, disable compiler security checks))
 124
 125 AC_ARG_ENABLE(expensive-hardening,
 126     AS_HELP_STRING(--enable-expensive-hardening, enable more expensive compiler hardening; makes Tor slower))
 127
 128 dnl Linker hardening options
 129 dnl Currently these options are ELF specific - you can't use this with MacOSX
 130 AC_ARG_ENABLE(linker-hardening,
 131     AS_HELP_STRING(--disable-linker-hardening, disable linker security fixups))
 132
 133 AC_ARG_ENABLE(local-appdata,
 134    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 135 if test "$enable_local_appdata" = "yes"; then
 136   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 137             [Defined if we default to host local appdata paths on Windows])
 138 fi
 139
 140 # Tor2web mode flag
 141 AC_ARG_ENABLE(tor2web-mode,
 142      AS_HELP_STRING(--enable-tor2web-mode, support tor2web non-anonymous mode),
 143 [if test x$enableval = xyes; then
 144     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 145 fi])
 146
 147 AC_ARG_ENABLE(bufferevents,
 148      AS_HELP_STRING(--enable-bufferevents, use Libevent's buffered IO.))
 149
 150 AC_ARG_ENABLE(tool-name-check,
 151      AS_HELP_STRING(--disable-tool-name-check, check for sanely named toolchain when cross-compiling))
 152
 153 AC_ARG_ENABLE(seccomp,
 154      AS_HELP_STRING(--disable-seccomp, do not attempt to use libseccomp))
 155
 156 AC_ARG_ENABLE(libscrypt,
 157      AS_HELP_STRING(--disable-libscrypt, do not attempt to use libscrypt))
 158
 159 dnl check for the correct "ar" when cross-compiling
 160 AN_MAKEVAR([AR], [AC_PROG_AR])
 161 AN_PROGRAM([ar], [AC_PROG_AR])
 162 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
 163 AC_PROG_AR
 164
 165 dnl Check whether the above macro has settled for a simply named tool even
 166 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 167 dnl because that will find any cc on the system, not only the cross-compiler,
 168 dnl and then verify that a binary built with this compiler runs on the
 169 dnl build system. It will then come to the false conclusion that we're not
 170 dnl cross-compiling.
 171 if test x$enable_tool_name_check != xno; then
 172     if test x$ac_tool_warned = xyes; then
 173         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 174         elif test "x$ac_ct_AR" != x -a x$cross_compiling = xmaybe; then
 175                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 176         fi
 177 fi
 178
 179 AC_PROG_CC
 180 AC_PROG_CPP
 181 AC_PROG_MAKE_SET
 182 AC_PROG_RANLIB
 183
 184 dnl autoconf 2.59 appears not to support AC_PROG_SED
 185 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 186
 187 dnl check for asciidoc and a2x
 188 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 189 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 190
 191 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 192
 193 AM_CONDITIONAL(USE_FW_HELPER, test x$natpmp = xtrue || test x$upnp = xtrue)
 194 AM_CONDITIONAL(NAT_PMP, test x$natpmp = xtrue)
 195 AM_CONDITIONAL(MINIUPNPC, test x$upnp = xtrue)
 196 AM_PROG_CC_C_O
 197 AC_PROG_CC_C99
 198
 199 AC_ARG_VAR(PYTHON)
 200 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 201 if test "x$PYTHON" = "x"; then
 202   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 203 fi
 204 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 205
 206 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 207 AC_C_FLEXIBLE_ARRAY_MEMBER
 208 ], [
 209  dnl Maybe we've got an old autoconf...
 210  AC_CACHE_CHECK([for flexible array members],
 211      tor_cv_c_flexarray,
 212      [AC_COMPILE_IFELSE(
 213        AC_LANG_PROGRAM([
 214  struct abc { int a; char b[]; };
 215 ], [
 216  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 217  def->b[0] = 33;
 218 ]),
 219   [tor_cv_c_flexarray=yes],
 220   [tor_cv_c_flexarray=no])])
 221  if test $tor_cv_flexarray = yes ; then
 222    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 223  else
 224    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 225  fi
 226 ])
 227
 228 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 229       tor_cv_c_c99_decl,
 230       [AC_COMPILE_IFELSE(
 231          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 232          [tor_cv_c_c99_decl=yes],
 233          [tor_cv_c_c99_decl=no] )])
 234 if test "$tor_cv_c_c99_decl" != "yes"; then
 235   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 236 fi
 237
 238 AC_CACHE_CHECK([for working C99 designated initializers],
 239       tor_cv_c_c99_designated_init,
 240       [AC_COMPILE_IFELSE(
 241          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 242                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 243          [tor_cv_c_c99_designated_init=yes],
 244          [tor_cv_c_c99_designated_init=no] )])
 245
 246 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 247   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 248 fi
 249
 250 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 251 AC_PATH_PROG([OPENSSL], [openssl], none)
 252
 253 TORUSER=_tor
 254 AC_ARG_WITH(tor-user,
 255         [  --with-tor-user=NAME    Specify username for tor daemon ],
 256         [
 257            TORUSER=$withval
 258         ]
 259 )
 260 AC_SUBST(TORUSER)
 261
 262 TORGROUP=_tor
 263 AC_ARG_WITH(tor-group,
 264         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 265         [
 266            TORGROUP=$withval
 267         ]
 268 )
 269 AC_SUBST(TORGROUP)
 270
 271
 272 dnl If _WIN32 is defined and non-zero, we are building for win32
 273 AC_MSG_CHECKING([for win32])
 274 AC_RUN_IFELSE([AC_LANG_SOURCE([
 275 int main(int c, char **v) {
 276 #ifdef _WIN32
 277 #if _WIN32
 278   return 0;
 279 #else
 280   return 1;
 281 #endif
 282 #else
 283   return 2;
 284 #endif
 285 }])],
 286 bwin32=true; AC_MSG_RESULT([yes]),
 287 bwin32=false; AC_MSG_RESULT([no]),
 288 bwin32=cross; AC_MSG_RESULT([cross])
 289 )
 290
 291 if test "$bwin32" = cross; then
 292 AC_MSG_CHECKING([for win32 (cross)])
 293 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 294 #ifdef _WIN32
 295 int main(int c, char **v) {return 0;}
 296 #else
 297 #error
 298 int main(int c, char **v) {return x(y);}
 299 #endif
 300 ])],
 301 bwin32=true; AC_MSG_RESULT([yes]),
 302 bwin32=false; AC_MSG_RESULT([no]))
 303 fi
 304
 305 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 306
 307 dnl Enable C99 when compiling with MIPSpro
 308 AC_MSG_CHECKING([for MIPSpro compiler])
 309 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 310 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 311 #error
 312   return x(y);
 313 #endif
 314 ])],
 315 bmipspro=false; AC_MSG_RESULT(no),
 316 bmipspro=true; AC_MSG_RESULT(yes))
 317
 318 if test "$bmipspro" = true; then
 319   CFLAGS="$CFLAGS -c99"
 320 fi
 321
 322 AC_C_BIGENDIAN
 323
 324 AC_SEARCH_LIBS(socket, [socket network])
 325 AC_SEARCH_LIBS(gethostbyname, [nsl])
 326 AC_SEARCH_LIBS(dlopen, [dl])
 327 AC_SEARCH_LIBS(inet_aton, [resolv])
 328 saved_LIBS="$LIBS"
 329 AC_SEARCH_LIBS([clock_gettime], [rt])
 330 if test "$LIBS" != "$saved_LIBS"; then
 331    # Looks like we need -lrt for clock_gettime().
 332    have_rt=yes
 333 fi
 334
 335 AC_SEARCH_LIBS(pthread_create, [pthread])
 336 AC_SEARCH_LIBS(pthread_detach, [pthread])
 337
 338 dnl -------------------------------------------------------------------
 339 dnl Check for functions before libevent, since libevent-1.2 apparently
 340 dnl exports strlcpy without defining it in a header.
 341
 342 AC_CHECK_FUNCS(
 343         _NSGetEnviron \
 344         accept4 \
 345         backtrace \
 346         backtrace_symbols_fd \
 347         clock_gettime \
 348         flock \
 349         ftime \
 350         getaddrinfo \
 351         getifaddrs \
 352         getrlimit \
 353         gettimeofday \
 354         gmtime_r \
 355         inet_aton \
 356         ioctl \
 357         issetugid \
 358         llround \
 359         localtime_r \
 360         lround \
 361         memmem \
 362         prctl \
 363         rint \
 364         sigaction \
 365         socketpair \
 366         strlcat \
 367         strlcpy \
 368         strnlen \
 369         strptime \
 370         strtok_r \
 371         strtoull \
 372         sysconf \
 373         sysctl \
 374         uname \
 375         usleep \
 376         vasprintf \
 377         _vscprintf
 378 )
 379
 380 if test "$bwin32" != true; then
 381   AC_CHECK_HEADERS(pthread.h)
 382   AC_CHECK_FUNCS(pthread_create)
 383 fi
 384
 385 dnl ------------------------------------------------------
 386 dnl Where do you live, libevent?  And how do we call you?
 387
 388 if test "$bwin32" = true; then
 389   TOR_LIB_WS32=-lws2_32
 390   TOR_LIB_IPHLPAPI=-liphlpapi
 391   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 392   # think it's actually necessary.
 393   TOR_LIB_GDI=-lgdi32
 394 else
 395   TOR_LIB_WS32=
 396   TOR_LIB_GDI=
 397 fi
 398 AC_SUBST(TOR_LIB_WS32)
 399 AC_SUBST(TOR_LIB_GDI)
 400 AC_SUBST(TOR_LIB_IPHLPAPI)
 401
 402 dnl We need to do this before we try our disgusting hack below.
 403 AC_CHECK_HEADERS([sys/types.h])
 404
 405 dnl This is a disgusting hack so we safely include older libevent headers.
 406 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 407 AC_CHECK_TYPE(u_int32_t, unsigned long)
 408 AC_CHECK_TYPE(u_int16_t, unsigned short)
 409 AC_CHECK_TYPE(u_int8_t, unsigned char)
 410
 411 tor_libevent_pkg_redhat="libevent"
 412 tor_libevent_pkg_debian="libevent-dev"
 413 tor_libevent_devpkg_redhat="libevent-devel"
 414 tor_libevent_devpkg_debian="libevent-dev"
 415
 416 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 417 dnl linking for static builds.
 418 STATIC_LIBEVENT_FLAGS=""
 419 if test "$enable_static_libevent" = "yes"; then
 420     if test "$have_rt" = yes; then
 421       STATIC_LIBEVENT_FLAGS=" -lrt "
 422     fi
 423 fi
 424
 425 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 426 #ifdef _WIN32
 427 #include <winsock2.h>
 428 #endif
 429 #include <stdlib.h>
 430 #include <sys/time.h>
 431 #include <sys/types.h>
 432 #include <event.h>], [
 433 #ifdef _WIN32
 434 #include <winsock2.h>
 435 #endif
 436 void exit(int); void *event_init(void);],
 437     [
 438 #ifdef _WIN32
 439 {WSADATA d; WSAStartup(0x101,&d); }
 440 #endif
 441 event_init(); exit(0);
 442 ], [--with-libevent-dir], [/opt/libevent])
 443
 444 dnl Now check for particular libevent functions.
 445 save_LIBS="$LIBS"
 446 save_LDFLAGS="$LDFLAGS"
 447 save_CPPFLAGS="$CPPFLAGS"
 448 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
 449 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 450 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 451 AC_CHECK_FUNCS([event_get_version \
 452                 event_get_version_number \
 453                 event_get_method \
 454                 event_set_log_callback \
 455                 evutil_secure_rng_set_urandom_device_file \
 456                 evutil_secure_rng_init \
 457                 event_base_loopexit])
 458 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 459 [#include <event.h>
 460 ])
 461
 462 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 463
 464 LIBS="$save_LIBS"
 465 LDFLAGS="$save_LDFLAGS"
 466 CPPFLAGS="$save_CPPFLAGS"
 467
 468
 469 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 470
 471 if test "$enable_static_libevent" = "yes"; then
 472    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 473      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 474    else
 475      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 476    fi
 477 else
 478      TOR_LIBEVENT_LIBS="-levent"
 479 fi
 480
 481 dnl This isn't the best test for Libevent 2.0.3-alpha.  Once it's released,
 482 dnl we can do much better.
 483 if test "$enable_bufferevents" = "yes" ; then
 484   if test "$ac_cv_header_event2_bufferevent_ssl_h" != "yes" ; then
 485     AC_MSG_ERROR([You've asked for bufferevent support, but you're using a version of Libevent without SSL support.  This won't work.  We need Libevent 2.0.8-rc or later, and you don't seem to even have Libevent 2.0.3-alpha.])
 486   else
 487
 488     CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 489
 490     # Check for the right version.  First see if version detection works.
 491     AC_MSG_CHECKING([whether we can detect the Libevent version])
 492     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 493 #include <event2/event.h>
 494 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 10
 495 #error
 496 int x = y(zz);
 497 #else
 498 int x = 1;
 499 #endif
 500   ])], [event_version_number_works=yes; AC_MSG_RESULT([yes]) ],
 501      [event_version_number_works=no;  AC_MSG_RESULT([no])])
 502     if test "$event_version_number_works" != 'yes'; then
 503       AC_MSG_WARN([Version detection on Libevent seems broken.  Your Libevent installation is probably screwed up or very old.])
 504     else
 505       AC_MSG_CHECKING([whether Libevent is new enough for bufferevents])
 506       AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 507 #include <event2/event.h>
 508 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000d00
 509 #error
 510 int x = y(zz);
 511 #else
 512 int x = 1;
 513 #endif
 514    ])], [ AC_MSG_RESULT([yes]) ],
 515       [ AC_MSG_RESULT([no])
 516         AC_MSG_ERROR([Libevent does not seem new enough to support bufferevents.  We require 2.0.13-stable or later]) ] )
 517     fi
 518   fi
 519 fi
 520
 521 LIBS="$save_LIBS"
 522 LDFLAGS="$save_LDFLAGS"
 523 CPPFLAGS="$save_CPPFLAGS"
 524
 525 AM_CONDITIONAL(USE_BUFFEREVENTS, test "$enable_bufferevents" = "yes")
 526 if test "$enable_bufferevents" = "yes"; then
 527   AC_DEFINE(USE_BUFFEREVENTS, 1, [Defined if we're going to use Libevent's buffered IO API])
 528   if test "$enable_static_libevent" = "yes"; then
 529     TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent_openssl.a $TOR_LIBEVENT_LIBS"
 530   else
 531     TOR_LIBEVENT_LIBS="-levent_openssl $TOR_LIBEVENT_LIBS"
 532   fi
 533 fi
 534 AC_SUBST(TOR_LIBEVENT_LIBS)
 535
 536 dnl ------------------------------------------------------
 537 dnl Where do you live, libm?
 538
 539 dnl On some platforms (Haiku/BeOS) the math library is
 540 dnl part of libroot. In which case don't link against lm
 541 TOR_LIB_MATH=""
 542 save_LIBS="$LIBS"
 543 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 544 if test "$ac_cv_search_pow" != "none required"; then
 545     TOR_LIB_MATH="$ac_cv_search_pow"
 546 fi
 547 LIBS="$save_LIBS"
 548 AC_SUBST(TOR_LIB_MATH)
 549
 550 dnl ------------------------------------------------------
 551 dnl Where do you live, openssl?  And how do we call you?
 552
 553 tor_openssl_pkg_redhat="openssl"
 554 tor_openssl_pkg_debian="libssl-dev"
 555 tor_openssl_devpkg_redhat="openssl-devel"
 556 tor_openssl_devpkg_debian="libssl-dev"
 557
 558 ALT_openssl_WITHVAL=""
 559 AC_ARG_WITH(ssl-dir,
 560   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 561   [
 562       if test "x$withval" != xno && test "x$withval" != "x" ; then
 563          ALT_openssl_WITHVAL="$withval"
 564       fi
 565   ])
 566
 567 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 568     [#include <openssl/rand.h>],
 569     [void RAND_add(const void *buf, int num, double entropy);],
 570     [RAND_add((void*)0,0,0); exit(0);], [],
 571     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 572
 573 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 574
 575 if test "$enable_static_openssl" = "yes"; then
 576    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 577      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 578    else
 579      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 580    fi
 581 else
 582      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 583 fi
 584 AC_SUBST(TOR_OPENSSL_LIBS)
 585
 586 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 587 [#include <openssl/ssl.h>
 588 ])
 589
 590 dnl ------------------------------------------------------
 591 dnl Where do you live, zlib?  And how do we call you?
 592
 593 tor_zlib_pkg_redhat="zlib"
 594 tor_zlib_pkg_debian="zlib1g"
 595 tor_zlib_devpkg_redhat="zlib-devel"
 596 tor_zlib_devpkg_debian="zlib1g-dev"
 597
 598 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 599     [#include <zlib.h>],
 600     [const char * zlibVersion(void);],
 601     [zlibVersion(); exit(0);], [--with-zlib-dir],
 602     [/opt/zlib])
 603
 604 if test "$enable_static_zlib" = "yes"; then
 605    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 606      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 607  using --enable-static-zlib")
 608    else
 609      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 610    fi
 611 else
 612      TOR_ZLIB_LIBS="-lz"
 613 fi
 614 AC_SUBST(TOR_ZLIB_LIBS)
 615
 616 dnl ---------------------------------------------------------------------
 617 dnl Now that we know about our major libraries, we can check for compiler
 618 dnl and linker hardening options.  We need to do this with the libraries known,
 619 dnl since sometimes the linker will like an option but not be willing to
 620 dnl use it with a build of a library.
 621
 622 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 623 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI"
 624
 625 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 626 #if !defined(__clang__)
 627 #error
 628 #endif])], have_clang=yes, have_clang=no)
 629
 630 if test x$enable_gcc_hardening != xno; then
 631     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2"
 632     if test x$have_clang = xyes; then
 633         TOR_CHECK_CFLAGS(-Qunused-arguments)
 634     fi
 635     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 636     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 637     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 638 m4_ifdef([AS_VAR_IF],[
 639     AS_VAR_IF(can_compile, [yes],
 640         AS_VAR_IF(can_link, [yes],
 641                   [],
 642                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 643         )])
 644     AS_VAR_POPDEF([can_link])
 645     AS_VAR_POPDEF([can_compile])
 646     TOR_CHECK_CFLAGS(-Wstack-protector)
 647     TOR_CHECK_CFLAGS(-fwrapv)
 648     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 649     if test "$bwin32" = "false"; then
 650        TOR_CHECK_CFLAGS(-fPIE)
 651        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 652     fi
 653 fi
 654
 655 if test x$enable_expensive_hardening = xyes ; then
 656    TOR_CHECK_CFLAGS([-fsanitize=address])
 657    TOR_CHECK_CFLAGS([-fsanitize=undefined])
 658    TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 659 fi
 660
 661 if test x$enable_linker_hardening != xno; then
 662     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
 663 fi
 664
 665 # For backtrace support
 666 TOR_CHECK_LDFLAGS(-rdynamic)
 667
 668 dnl ------------------------------------------------------
 669 dnl Now see if we have a -fomit-frame-pointer compiler option.
 670
 671 saved_CFLAGS="$CFLAGS"
 672 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
 673 F_OMIT_FRAME_POINTER=''
 674 if test "$saved_CFLAGS" != "$CFLAGS"; then
 675   if test x$enable_expensive_hardening != xyes ; then
 676     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
 677   fi
 678 fi
 679 CFLAGS="$saved_CFLAGS"
 680 AC_SUBST(F_OMIT_FRAME_POINTER)
 681
 682 dnl ------------------------------------------------------
 683 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
 684 dnl for us, as GCC 4.6 and later do at many optimization levels), then
 685 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
 686 dnl code will work.
 687 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
 688
 689 dnl ------------------------------------------------------
 690 dnl Where do you live, libnatpmp?  And how do we call you?
 691 dnl There are no packages for Debian or Redhat as of this patch
 692
 693 if test "$natpmp" = "true"; then
 694     AC_DEFINE(NAT_PMP, 1, [Define to 1 if we are building with nat-pmp.])
 695     TOR_SEARCH_LIBRARY(libnatpmp, $trylibnatpmpdir, [-lnatpmp $TOR_LIB_WS32 $TOR_LIB_IPHLPAPI],
 696         [#include <natpmp.h>],
 697         [#ifdef _WIN32
 698          #define STATICLIB
 699          #endif
 700          #include <natpmp.h>],
 701         [   int r;
 702             natpmp_t natpmp;
 703             natpmpresp_t response;
 704             r = initnatpmp(&natpmp, 0, 0);],
 705             [printf("initnatpmp() returned %d (%s)\n", r, r?"FAILED":"SUCCESS");
 706             exit(0);],
 707         [--with-libnatpmp-dir],
 708         [/usr/lib/])
 709 fi
 710
 711
 712 dnl ------------------------------------------------------
 713 dnl Where do you live, libminiupnpc?  And how do we call you?
 714 dnl There are no packages for Debian or Redhat as of this patch
 715
 716 if test "$upnp" = "true"; then
 717     AC_DEFINE(MINIUPNPC, 1, [Define to 1 if we are building with UPnP.])
 718
 719     dnl Before we call TOR_SEARCH_LIBRARY we'll do a quick compile test
 720     dnl to see if we have miniupnpc-1.5 or -1.6
 721     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <miniupnpc/miniupnpc.h>],
 722         [upnpDiscover(1, 0, 0, 0);exit(0);])],[miniupnpc15="true"],[miniupnpc15="false"])
 723
 724     if test "$miniupnpc15" = "true" ; then
 725         AC_DEFINE([MINIUPNPC15],[1],[libminiupnpc version 1.5 found])
 726         TOR_SEARCH_LIBRARY(libminiupnpc, $trylibminiupnpcdir, [-lminiupnpc $TOR_LIB_WS32 $TOR_LIB_IPHLPAPI],
 727             [#include <miniupnpc/miniwget.h>
 728              #include <miniupnpc/miniupnpc.h>
 729              #include <miniupnpc/upnpcommands.h>],
 730             [void upnpDiscover(int delay, const char * multicastif,
 731              const char * minissdpdsock, int sameport);],
 732             [upnpDiscover(1, 0, 0, 0); exit(0);],
 733             [--with-libminiupnpc-dir],
 734             [/usr/lib/])
 735     else
 736         TOR_SEARCH_LIBRARY(libminiupnpc, $trylibminiupnpcdir, [-lminiupnpc $TOR_LIB_WS32 $TOR_LIB_IPHLPAPI],
 737             [#include <miniupnpc/miniwget.h>
 738              #include <miniupnpc/miniupnpc.h>
 739              #include <miniupnpc/upnpcommands.h>],
 740             [void upnpDiscover(int delay, const char * multicastif,
 741              const char * minissdpdsock, int sameport, int ipv6, int * error);],
 742             [upnpDiscover(1, 0, 0, 0, 0, 0); exit(0);],
 743             [--with-libminiupnpc-dir],
 744             [/usr/lib/])
 745     fi
 746 fi
 747
 748 dnl ============================================================
 749 dnl Check for libseccomp
 750
 751 if test "x$enable_seccomp" != "xno"; then
 752   AC_CHECK_HEADERS([seccomp.h])
 753   AC_SEARCH_LIBS(seccomp_init, [seccomp])
 754 fi
 755
 756 dnl ============================================================
 757 dnl Check for libscrypt
 758
 759 if test "x$enable_libscrypt" != "xno"; then
 760   AC_CHECK_HEADERS([libscrypt.h])
 761   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
 762 fi
 763
 764 dnl ============================================================
 765 dnl We need an implementation of curve25519.
 766
 767 dnl set these defaults.
 768 have_a_curve25519=no
 769 build_curve25519_donna=no
 770 build_curve25519_donna_c64=no
 771 use_curve25519_donna=no
 772 use_curve25519_nacl=no
 773 CURVE25519_LIBS=
 774
 775 if test x$enable_curve25519 != xno; then
 776
 777   dnl The best choice is using curve25519-donna-c64, but that requires
 778   dnl that we
 779   AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
 780     tor_cv_can_use_curve25519_donna_c64,
 781     [AC_RUN_IFELSE(
 782       [AC_LANG_PROGRAM([dnl
 783         #include <stdint.h>
 784         typedef unsigned uint128_t __attribute__((mode(TI)));
 785         int func(uint64_t a, uint64_t b) {
 786              uint128_t c = ((uint128_t)a) * b;
 787              int ok = ((uint64_t)(c>>96)) == 522859 &&
 788                    (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 789                    (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 790                    (((uint64_t)(c))&0xffffffffL) == 0;
 791              return ok;
 792         }
 793         ], [dnl
 794           int ok = func( ((uint64_t)2000000000) * 1000000000,
 795                          ((uint64_t)1234567890) << 24);
 796           return !ok;
 797         ])],
 798         [tor_cv_can_use_curve25519_donna_c64=yes],
 799         [tor_cv_can_use_curve25519_donna_c64=no],
 800         [AC_LINK_IFELSE(
 801           [AC_LANG_PROGRAM([dnl
 802         #include <stdint.h>
 803         typedef unsigned uint128_t __attribute__((mode(TI)));
 804         int func(uint64_t a, uint64_t b) {
 805              uint128_t c = ((uint128_t)a) * b;
 806              int ok = ((uint64_t)(c>>96)) == 522859 &&
 807                    (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 808                    (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 809                    (((uint64_t)(c))&0xffffffffL) == 0;
 810              return ok;
 811         }
 812         ], [dnl
 813           int ok = func( ((uint64_t)2000000000) * 1000000000,
 814                          ((uint64_t)1234567890) << 24);
 815           return !ok;
 816         ])],
 817             [tor_cv_can_use_curve25519_donna_c64=cross],
 818             [tor_cv_can_use_curve25519_donna_c64=no])])])
 819
 820   AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
 821                     nacl/crypto_scalarmult_curve25519.h])
 822
 823   AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
 824     tor_cv_can_use_curve25519_nacl,
 825     [tor_saved_LIBS="$LIBS"
 826      LIBS="$LIBS -lnacl"
 827      AC_LINK_IFELSE(
 828        [AC_LANG_PROGRAM([dnl
 829          #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
 830          #include <crypto_scalarmult_curve25519.h>
 831          #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
 832          #include <nacl/crypto_scalarmult_curve25519.h>
 833          #endif
 834          #ifdef crypto_scalarmult_curve25519_ref_BYTES
 835          #error Hey, this is the reference implementation! That's not fast.
 836          #endif
 837        ], [
 838          unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
 839        ])], [tor_cv_can_use_curve25519_nacl=yes],
 840        [tor_cv_can_use_curve25519_nacl=no])
 841      LIBS="$tor_saved_LIBS" ])
 842
 843    dnl Okay, now we need to figure out which one to actually use. Fall back
 844    dnl to curve25519-donna.c
 845
 846    if test x$tor_cv_can_use_curve25519_donna_c64 != xno; then
 847      build_curve25519_donna_c64=yes
 848      use_curve25519_donna=yes
 849    elif test x$tor_cv_can_use_curve25519_nacl = xyes; then
 850      use_curve25519_nacl=yes
 851      CURVE25519_LIBS=-lnacl
 852    else
 853      build_curve25519_donna=yes
 854      use_curve25519_donna=yes
 855    fi
 856    have_a_curve25519=yes
 857 fi
 858
 859 if test x$have_a_curve25519 = xyes; then
 860   AC_DEFINE(CURVE25519_ENABLED, 1,
 861             [Defined if we have a curve25519 implementation])
 862 fi
 863 if test x$use_curve25519_donna = xyes; then
 864   AC_DEFINE(USE_CURVE25519_DONNA, 1,
 865             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
 866 fi
 867 if test x$use_curve25519_nacl = xyes; then
 868   AC_DEFINE(USE_CURVE25519_NACL, 1,
 869             [Defined if we should use a curve25519 from nacl])
 870 fi
 871 AM_CONDITIONAL(BUILD_CURVE25519_DONNA, test x$build_curve25519_donna = xyes)
 872 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64, test x$build_curve25519_donna_c64 = xyes)
 873 AM_CONDITIONAL(CURVE25519_ENABLED, test x$have_a_curve25519 = xyes)
 874 AC_SUBST(CURVE25519_LIBS)
 875
 876 dnl Make sure to enable support for large off_t if available.
 877 AC_SYS_LARGEFILE
 878
 879 AC_CHECK_HEADERS(
 880         assert.h \
 881         errno.h \
 882         fcntl.h \
 883         signal.h \
 884         string.h \
 885         sys/fcntl.h \
 886         sys/stat.h \
 887         sys/time.h \
 888         sys/types.h \
 889         time.h \
 890         unistd.h
 891  , , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 892
 893 dnl These headers are not essential
 894
 895 AC_CHECK_HEADERS(
 896         arpa/inet.h \
 897         crt_externs.h \
 898         execinfo.h \
 899         grp.h \
 900         ifaddrs.h \
 901         inttypes.h \
 902         limits.h \
 903         linux/types.h \
 904         machine/limits.h \
 905         malloc.h \
 906         malloc/malloc.h \
 907         malloc_np.h \
 908         netdb.h \
 909         netinet/in.h \
 910         netinet/in6.h \
 911         pwd.h \
 912         stdint.h \
 913         sys/file.h \
 914         sys/ioctl.h \
 915         sys/limits.h \
 916         sys/mman.h \
 917         sys/param.h \
 918         sys/prctl.h \
 919         sys/resource.h \
 920         sys/select.h \
 921         sys/socket.h \
 922         sys/sysctl.h \
 923         sys/syslimits.h \
 924         sys/time.h \
 925         sys/types.h \
 926         sys/un.h \
 927         sys/utime.h \
 928         sys/wait.h \
 929         syslog.h \
 930         utime.h
 931 )
 932
 933 AC_CHECK_HEADERS(sys/param.h)
 934
 935 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 936 [#ifdef HAVE_SYS_TYPES_H
 937 #include <sys/types.h>
 938 #endif
 939 #ifdef HAVE_SYS_SOCKET_H
 940 #include <sys/socket.h>
 941 #endif])
 942 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 943 [#ifdef HAVE_SYS_TYPES_H
 944 #include <sys/types.h>
 945 #endif
 946 #ifdef HAVE_SYS_SOCKET_H
 947 #include <sys/socket.h>
 948 #endif
 949 #ifdef HAVE_NET_IF_H
 950 #include <net/if.h>
 951 #endif])
 952 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 953         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 954 [#ifdef HAVE_SYS_TYPES_H
 955 #include <sys/types.h>
 956 #endif
 957 #ifdef HAVE_SYS_SOCKET_H
 958 #include <sys/socket.h>
 959 #endif
 960 #ifdef HAVE_LIMITS_H
 961 #include <limits.h>
 962 #endif
 963 #ifdef HAVE_LINUX_TYPES_H
 964 #include <linux/types.h>
 965 #endif
 966 #ifdef HAVE_NETINET_IN6_H
 967 #include <netinet/in6.h>
 968 #endif
 969 #ifdef HAVE_NETINET_IN_H
 970 #include <netinet/in.h>
 971 #endif])
 972
 973 if test x$transparent = xtrue ; then
 974    transparent_ok=0
 975    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 976      transparent_ok=1
 977    fi
 978    if test x$linux_netfilter_ipv4 = x1 ; then
 979      transparent_ok=1
 980    fi
 981    if test x$transparent_ok = x1 ; then
 982      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 983      case $host in
 984        *-*-openbsd* | *-*-bitrig*)
 985          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 986      esac
 987    else
 988      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 989    fi
 990 fi
 991
 992 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 993 [#ifdef HAVE_SYS_TYPES_H
 994 #include <sys/types.h>
 995 #endif
 996 #ifdef HAVE_SYS_TIME_H
 997 #include <sys/time.h>
 998 #endif])
 999
1000 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1001 dnl Watch out.
1002
1003 AC_CHECK_SIZEOF(int8_t)
1004 AC_CHECK_SIZEOF(int16_t)
1005 AC_CHECK_SIZEOF(int32_t)
1006 AC_CHECK_SIZEOF(int64_t)
1007 AC_CHECK_SIZEOF(uint8_t)
1008 AC_CHECK_SIZEOF(uint16_t)
1009 AC_CHECK_SIZEOF(uint32_t)
1010 AC_CHECK_SIZEOF(uint64_t)
1011 AC_CHECK_SIZEOF(intptr_t)
1012 AC_CHECK_SIZEOF(uintptr_t)
1013
1014 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1015
1016 AC_CHECK_SIZEOF(char)
1017 AC_CHECK_SIZEOF(short)
1018 AC_CHECK_SIZEOF(int)
1019 AC_CHECK_SIZEOF(long)
1020 AC_CHECK_SIZEOF(long long)
1021 AC_CHECK_SIZEOF(__int64)
1022 AC_CHECK_SIZEOF(void *)
1023 AC_CHECK_SIZEOF(time_t)
1024 AC_CHECK_SIZEOF(size_t)
1025 AC_CHECK_SIZEOF(pid_t)
1026
1027 AC_CHECK_TYPES([uint, u_char, ssize_t])
1028
1029 AC_PC_FROM_UCONTEXT([/bin/true])
1030
1031 dnl used to include sockaddr_storage, but everybody has that.
1032 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1033 [#ifdef HAVE_SYS_TYPES_H
1034 #include <sys/types.h>
1035 #endif
1036 #ifdef HAVE_NETINET_IN_H
1037 #include <netinet/in.h>
1038 #endif
1039 #ifdef HAVE_NETINET_IN6_H
1040 #include <netinet/in6.h>
1041 #endif
1042 #ifdef HAVE_SYS_SOCKET_H
1043 #include <sys/socket.h>
1044 #endif
1045 #ifdef _WIN32
1046 #define _WIN32_WINNT 0x0501
1047 #define WIN32_LEAN_AND_MEAN
1048 #if defined(_MSC_VER) && (_MSC_VER < 1300)
1049 #include <winsock.h>
1050 #else
1051 #include <winsock2.h>
1052 #include <ws2tcpip.h>
1053 #endif
1054 #endif
1055 ])
1056 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1057 [#ifdef HAVE_SYS_TYPES_H
1058 #include <sys/types.h>
1059 #endif
1060 #ifdef HAVE_NETINET_IN_H
1061 #include <netinet/in.h>
1062 #endif
1063 #ifdef HAVE_NETINET_IN6_H
1064 #include <netinet/in6.h>
1065 #endif
1066 #ifdef HAVE_SYS_SOCKET_H
1067 #include <sys/socket.h>
1068 #endif
1069 #ifdef _WIN32
1070 #define _WIN32_WINNT 0x0501
1071 #define WIN32_LEAN_AND_MEAN
1072 #if defined(_MSC_VER) && (_MSC_VER < 1300)
1073 #include <winsock.h>
1074 #else
1075 #include <winsock2.h>
1076 #include <ws2tcpip.h>
1077 #endif
1078 #endif
1079 ])
1080
1081 AC_CHECK_TYPES([rlim_t], , ,
1082 [#ifdef HAVE_SYS_TYPES_H
1083 #include <sys/types.h>
1084 #endif
1085 #ifdef HAVE_SYS_TIME_H
1086 #include <sys/time.h>
1087 #endif
1088 #ifdef HAVE_SYS_RESOURCE_H
1089 #include <sys/resource.h>
1090 #endif
1091 ])
1092
1093 AX_CHECK_SIGN([time_t],
1094        [ AC_DEFINE(TIME_T_IS_SIGNED, 1, [Define if time_t is signed]) ],
1095        [ : ], [
1096 #ifdef HAVE_SYS_TYPES_H
1097 #include <sys/types.h>
1098 #endif
1099 #ifdef HAVE_SYS_TIME_H
1100 #include <sys/time.h>
1101 #endif
1102 #ifdef HAVE_TIME_H
1103 #include <time.h>
1104 #endif
1105 ])
1106
1107 if test "$ax_cv_decl_time_t_signed" = no; then
1108   AC_MSG_WARN([You have an unsigned time_t; some things will probably break. Please tell the Tor developers about your interesting platform.])
1109 fi
1110
1111 AX_CHECK_SIGN([size_t],
1112        [ tor_cv_size_t_signed=yes ],
1113        [ tor_cv_size_t_signed=no ], [
1114 #ifdef HAVE_SYS_TYPES_H
1115 #include <sys/types.h>
1116 #endif
1117 ])
1118
1119 if test "$ax_cv_decl_size_t_signed" = yes; then
1120   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1121 fi
1122
1123 AX_CHECK_SIGN([enum always],
1124        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1125        [ : ], [
1126  enum always { AAA, BBB, CCC };
1127 ])
1128
1129 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1130 #ifdef HAVE_SYS_SOCKET_H
1131 #include <sys/socket.h>
1132 #endif
1133 ])
1134
1135 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1136
1137 AC_CHECK_SIZEOF(cell_t)
1138
1139 # Now make sure that NULL can be represented as zero bytes.
1140 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1141 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1142 [[#include <stdlib.h>
1143 #include <string.h>
1144 #include <stdio.h>
1145 #ifdef HAVE_STDDEF_H
1146 #include <stddef.h>
1147 #endif
1148 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1149 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1150        [tor_cv_null_is_zero=yes],
1151        [tor_cv_null_is_zero=no],
1152        [tor_cv_null_is_zero=cross])])
1153
1154 if test "$tor_cv_null_is_zero" = cross ; then
1155   # Cross-compiling; let's hope that the target isn't raving mad.
1156   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1157 fi
1158
1159 if test "$tor_cv_null_is_zero" != no; then
1160   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1161             [Define to 1 iff memset(0) sets pointers to NULL])
1162 fi
1163
1164 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1165 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1166 [[#include <stdlib.h>
1167 #include <string.h>
1168 #include <stdio.h>
1169 #ifdef HAVE_STDDEF_H
1170 #include <stddef.h>
1171 #endif
1172 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1173 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1174        [tor_cv_dbl0_is_zero=yes],
1175        [tor_cv_dbl0_is_zero=no],
1176        [tor_cv_dbl0_is_zero=cross])])
1177
1178 if test "$tor_cv_dbl0_is_zero" = cross ; then
1179   # Cross-compiling; let's hope that the target isn't raving mad.
1180   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1181 fi
1182
1183 if test "$tor_cv_dbl0_is_zero" != no; then
1184   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1185             [Define to 1 iff memset(0) sets doubles to 0.0])
1186 fi
1187
1188 # And what happens when we malloc zero?
1189 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1190 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1191 [[#include <stdlib.h>
1192 #include <string.h>
1193 #include <stdio.h>
1194 #ifdef HAVE_STDDEF_H
1195 #include <stddef.h>
1196 #endif
1197 int main () { return malloc(0)?0:1; }]])],
1198        [tor_cv_malloc_zero_works=yes],
1199        [tor_cv_malloc_zero_works=no],
1200        [tor_cv_malloc_zero_works=cross])])
1201
1202 if test "$tor_cv_malloc_zero_works" = cross; then
1203   # Cross-compiling; let's hope that the target isn't raving mad.
1204   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1205 fi
1206
1207 if test "$tor_cv_malloc_zero_works" = yes; then
1208   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1209             [Define to 1 iff malloc(0) returns a pointer])
1210 fi
1211
1212 # whether we seem to be in a 2s-complement world.
1213 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1214 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1215 [[int main () { int problem = ((-99) != (~99)+1);
1216 return problem ? 1 : 0; }]])],
1217        [tor_cv_twos_complement=yes],
1218        [tor_cv_twos_complement=no],
1219        [tor_cv_twos_complement=cross])])
1220
1221 if test "$tor_cv_twos_complement" = cross ; then
1222   # Cross-compiling; let's hope that the target isn't raving mad.
1223   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1224 fi
1225
1226 if test "$tor_cv_twos_complement" != no ; then
1227   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1228             [Define to 1 iff we represent negative integers with two's complement])
1229 fi
1230
1231 # What does shifting a negative value do?
1232 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1233 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1234 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1235        [tor_cv_sign_extend=yes],
1236        [tor_cv_sign_extend=no],
1237        [tor_cv_sign_extend=cross])])
1238
1239 if test "$tor_cv_sign_extend" = cross ; then
1240   # Cross-compiling; let's hope that the target isn't raving mad.
1241   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1242 fi
1243
1244 if test "$tor_cv_sign_extend" != no ; then
1245   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1246             [Define to 1 iff right-shifting a negative value performs sign-extension])
1247 fi
1248
1249 # Whether we should use the dmalloc memory allocation debugging library.
1250 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1251 AC_ARG_WITH(dmalloc,
1252 [  --with-dmalloc          Use debug memory allocation library. ],
1253 [if [[ "$withval" = "yes" ]]; then
1254   dmalloc=1
1255   AC_MSG_RESULT(yes)
1256 else
1257   dmalloc=1
1258   AC_MSG_RESULT(no)
1259 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1260 )
1261
1262 if [[ $dmalloc -eq 1 ]]; then
1263   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1264   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1265   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1266   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1267 fi
1268
1269 AC_ARG_WITH(tcmalloc,
1270 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
1271 [ tcmalloc=yes ], [ tcmalloc=no ])
1272
1273 if test x$tcmalloc = xyes ; then
1274    LDFLAGS="-ltcmalloc $LDFLAGS"
1275 fi
1276
1277 using_custom_malloc=no
1278 if test x$enable_openbsd_malloc = xyes ; then
1279    using_custom_malloc=yes
1280 fi
1281 if test x$tcmalloc = xyes ; then
1282    using_custom_malloc=yes
1283 fi
1284 if test $using_custom_malloc = no ; then
1285    AC_CHECK_FUNCS(mallinfo)
1286 fi
1287
1288 # By default, we're going to assume we don't have mlockall()
1289 # bionic and other platforms have various broken mlockall subsystems.
1290 # Some systems don't have a working mlockall, some aren't linkable,
1291 # and some have it but don't declare it.
1292 AC_CHECK_FUNCS(mlockall)
1293 AC_CHECK_DECLS([mlockall], , , [
1294 #ifdef HAVE_SYS_MMAN_H
1295 #include <sys/mman.h>
1296 #endif])
1297
1298 # Allow user to specify an alternate syslog facility
1299 AC_ARG_WITH(syslog-facility,
1300 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
1301 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1302 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1303 AC_SUBST(LOGFACILITY)
1304
1305 # Check if we have getresuid and getresgid
1306 AC_CHECK_FUNCS(getresuid getresgid)
1307
1308 # Check for gethostbyname_r in all its glorious incompatible versions.
1309 #   (This logic is based on that in Python's configure.in)
1310 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1311   [Define this if you have any gethostbyname_r()])
1312
1313 AC_CHECK_FUNC(gethostbyname_r, [
1314   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1315   OLD_CFLAGS=$CFLAGS
1316   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1317   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1318 #include <netdb.h>
1319   ], [[
1320     char *cp1, *cp2;
1321     struct hostent *h1, *h2;
1322     int i1, i2;
1323     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1324   ]])],[
1325     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1326     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1327      [Define this if gethostbyname_r takes 6 arguments])
1328     AC_MSG_RESULT(6)
1329   ], [
1330     AC_TRY_COMPILE([
1331 #include <netdb.h>
1332     ], [
1333       char *cp1, *cp2;
1334       struct hostent *h1;
1335       int i1, i2;
1336       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1337     ], [
1338       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1339       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1340         [Define this if gethostbyname_r takes 5 arguments])
1341       AC_MSG_RESULT(5)
1342    ], [
1343       AC_TRY_COMPILE([
1344 #include <netdb.h>
1345      ], [
1346        char *cp1;
1347        struct hostent *h1;
1348        struct hostent_data hd;
1349        (void) gethostbyname_r(cp1,h1,&hd);
1350      ], [
1351        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1352        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1353          [Define this if gethostbyname_r takes 3 arguments])
1354        AC_MSG_RESULT(3)
1355      ], [
1356        AC_MSG_RESULT(0)
1357      ])
1358   ])
1359  ])
1360  CFLAGS=$OLD_CFLAGS
1361 ])
1362
1363 AC_CACHE_CHECK([whether the C compiler supports __func__],
1364   tor_cv_have_func_macro,
1365   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1366 #include <stdio.h>
1367 int main(int c, char **v) { puts(__func__); }])],
1368   tor_cv_have_func_macro=yes,
1369   tor_cv_have_func_macro=no))
1370
1371 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1372   tor_cv_have_FUNC_macro,
1373   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1374 #include <stdio.h>
1375 int main(int c, char **v) { puts(__FUNC__); }])],
1376   tor_cv_have_FUNC_macro=yes,
1377   tor_cv_have_FUNC_macro=no))
1378
1379 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1380   tor_cv_have_FUNCTION_macro,
1381   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1382 #include <stdio.h>
1383 int main(int c, char **v) { puts(__FUNCTION__); }])],
1384   tor_cv_have_FUNCTION_macro=yes,
1385   tor_cv_have_FUNCTION_macro=no))
1386
1387 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1388   tor_cv_have_environ_declared,
1389   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1390 /* We define _GNU_SOURCE here because it is also defined in compat.c.
1391  * Without it environ doesn't get declared. */
1392 #define _GNU_SOURCE
1393 #ifdef HAVE_UNISTD_H
1394 #include <unistd.h>
1395 #endif
1396 #include <stdlib.h>
1397 int main(int c, char **v) { char **t = environ; }])],
1398   tor_cv_have_environ_declared=yes,
1399   tor_cv_have_environ_declared=no))
1400
1401 if test "$tor_cv_have_func_macro" = 'yes'; then
1402   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1403 fi
1404
1405 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
1406   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1407 fi
1408
1409 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
1410   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1411            [Defined if the compiler supports __FUNCTION__])
1412 fi
1413
1414 if test "$tor_cv_have_environ_declared" = 'yes'; then
1415   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1416            [Defined if we have extern char **environ already declared])
1417 fi
1418
1419 # $prefix stores the value of the --prefix command line option, or
1420 # NONE if the option wasn't set.  In the case that it wasn't set, make
1421 # it be the default, so that we can use it to expand directories now.
1422 if test "x$prefix" = "xNONE"; then
1423   prefix=$ac_default_prefix
1424 fi
1425
1426 # and similarly for $exec_prefix
1427 if test "x$exec_prefix" = "xNONE"; then
1428   exec_prefix=$prefix
1429 fi
1430
1431 if test "x$BUILDDIR" = "x"; then
1432   BUILDDIR=`pwd`
1433 fi
1434 AC_SUBST(BUILDDIR)
1435 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1436 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1437
1438 if test "x$CONFDIR" = "x"; then
1439   CONFDIR=`eval echo $sysconfdir/tor`
1440 fi
1441 AC_SUBST(CONFDIR)
1442 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1443 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1444
1445 BINDIR=`eval echo $bindir`
1446 AC_SUBST(BINDIR)
1447 LOCALSTATEDIR=`eval echo $localstatedir`
1448 AC_SUBST(LOCALSTATEDIR)
1449
1450 if test "$bwin32" = true; then
1451   # Test if the linker supports the --nxcompat and --dynamicbase options
1452   # for Windows
1453   save_LDFLAGS="$LDFLAGS"
1454   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1455   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1456   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1457     [AC_MSG_RESULT([yes])]
1458     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1459     [AC_MSG_RESULT([no])]
1460   )
1461   LDFLAGS="$save_LDFLAGS"
1462 fi
1463
1464 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1465 # than autoconf's macros like.
1466 if test "$GCC" = yes; then
1467   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1468   # accident waiting to happen.
1469   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1470 else
1471   # Autoconf sets -g -O2 by default. Override optimization level
1472   # for non-gcc compilers
1473   CFLAGS="$CFLAGS -O"
1474   enable_gcc_warnings=no
1475   enable_gcc_warnings_advisory=no
1476 fi
1477
1478 # OS X Lion started deprecating the system openssl. Let's just disable
1479 # all deprecation warnings on OS X. Also, to potentially make the binary
1480 # a little smaller, let's enable dead_strip.
1481 case "$host_os" in
1482
1483  darwin*)
1484     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1485     LDFLAGS="$LDFLAGS -dead_strip" ;;
1486 esac
1487
1488 # Add some more warnings which we use in development but not in the
1489 # released versions.  (Some relevant gcc versions can't handle these.)
1490 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
1491
1492   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1493 #if !defined(__GNUC__) || (__GNUC__ < 4)
1494 #error
1495 #endif])], have_gcc4=yes, have_gcc4=no)
1496
1497   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1498 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
1499 #error
1500 #endif])], have_gcc42=yes, have_gcc42=no)
1501
1502   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1503 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
1504 #error
1505 #endif])], have_gcc43=yes, have_gcc43=no)
1506
1507   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1508 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 6)
1509 #error
1510 #endif])], have_gcc46=yes, have_gcc46=no)
1511
1512
1513   save_CFLAGS="$CFLAGS"
1514   CFLAGS="$CFLAGS -Wshorten-64-to-32"
1515   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
1516                     have_shorten64_flag=no)
1517   CFLAGS="$save_CFLAGS"
1518
1519   case $host in
1520     *-*-openbsd* | *-*-bitrig*)
1521       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1522       # That's fine, except that the headers don't pass -Wredundant-decls.
1523       # Therefore, let's disable -Wsystem-headers when we're building
1524       # with maximal warnings on OpenBSD.
1525       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1526   esac
1527
1528   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1529   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1530   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1531   CFLAGS="$CFLAGS -Wwrite-strings -Wmissing-declarations -Wredundant-decls"
1532   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1533
1534   if test x$enable_gcc_warnings = xyes; then
1535     CFLAGS="$CFLAGS -Werror"
1536   fi
1537
1538   # Disabled, so we can use mallinfo(): -Waggregate-return
1539
1540   if test x$have_gcc4 = xyes ; then
1541     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
1542     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wold-style-definition"
1543   fi
1544
1545   if test x$have_gcc42 = xyes ; then
1546     # These warnings break gcc 4.0.2 and work on gcc 4.2
1547     # XXXX020 See if any of these work with earlier versions.
1548     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wstrict-overflow=1"
1549
1550     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
1551   fi
1552
1553   if test x$have_gcc42 = xyes && test x$have_clang = xno; then
1554     # These warnings break gcc 4.0.2 and clang, but work on gcc 4.2
1555     CFLAGS="$CFLAGS -Wnormalized=id -Woverride-init"
1556   fi
1557
1558   if test x$have_gcc43 = xyes ; then
1559     # These warnings break gcc 4.2 and work on gcc 4.3
1560     # XXXX020 See if any of these work with earlier versions.
1561     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
1562   fi
1563
1564   if test x$have_gcc46 = xyes ; then
1565     # This warning was added in gcc 4.3, but it appears to generate
1566     # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1567     CFLAGS="$CFLAGS -Wlogical-op"
1568   fi
1569
1570   if test x$have_shorten64_flag = xyes ; then
1571     CFLAGS="$CFLAGS -Wshorten-64-to-32"
1572   fi
1573
1574
1575
1576 ##This will break the world on some 64-bit architectures
1577 # CFLAGS="$CFLAGS -Winline"
1578 fi
1579
1580 if test "$enable_coverage" = yes && test "$have_clang" = "no"; then
1581    case "$host_os" in
1582     darwin*)
1583       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-profiling.])
1584    esac
1585 fi
1586
1587 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1588
1589 AC_CONFIG_FILES([
1590         Doxyfile
1591         Makefile
1592         contrib/dist/suse/tor.sh
1593         contrib/operator-tools/tor.logrotate
1594         contrib/dist/tor.sh
1595         contrib/dist/torctl
1596         contrib/dist/tor.service
1597         src/config/torrc.sample
1598         src/config/torrc.minimal
1599 ])
1600
1601 if test x$asciidoc = xtrue && test "$ASCIIDOC" = "none" ; then
1602   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
1603   for file in $regular_mans ; do
1604     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
1605       echo "==================================";
1606       echo;
1607       echo "Building Tor has failed since manpages cannot be built.";
1608       echo;
1609       echo "You need asciidoc installed to be able to build the manpages.";
1610       echo "To build without manpages, use the --disable-asciidoc argument";
1611       echo "when calling configure.";
1612       echo;
1613       echo "==================================";
1614       exit 1;
1615     fi
1616   done
1617 fi
1618
1619 AC_OUTPUT
1620
1621 if test -x /usr/bin/perl && test -x ./scripts/maint/updateVersions.pl ; then
1622   ./scripts/maint/updateVersions.pl
1623 fi