configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2019, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.5.11-dev])
   8 AC_CONFIG_SRCDIR([src/app/main/tor_main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 AC_ARG_ENABLE(openbsd-malloc,
  25    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only. Deprecated: see --with-malloc]))
  26 AC_ARG_ENABLE(static-openssl,
  27    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  28 AC_ARG_ENABLE(static-libevent,
  29    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  30 AC_ARG_ENABLE(static-zlib,
  31    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  32 AC_ARG_ENABLE(static-tor,
  33    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  34 AC_ARG_ENABLE(unittests,
  35    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  36 AC_ARG_ENABLE(coverage,
  37    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  38 AC_ARG_ENABLE(asserts-in-tests,
  39    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  40 AC_ARG_ENABLE(system-torrc,
  41    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  42 AC_ARG_ENABLE(libfuzzer,
  43    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  44 AC_ARG_ENABLE(oss-fuzz,
  45    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  46 AC_ARG_ENABLE(memory-sentinels,
  47    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  48 AC_ARG_ENABLE(rust,
  49    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  50 AC_ARG_ENABLE(cargo-online-mode,
  51    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  52 AC_ARG_ENABLE(restart-debugging,
  53    AS_HELP_STRING(--enable-restart-debugging, [Build Tor with support for debugging in-process restart. Developers only.]))
  54 AC_ARG_ENABLE(zstd-advanced-apis,
  55    AS_HELP_STRING(--disable-zstd-advanced-apis, [Build without support for zstd's "static-only" APIs.]))
  56 AC_ARG_ENABLE(nss,
  57    AS_HELP_STRING(--enable-nss, [Use Mozilla's NSS TLS library. (EXPERIMENTAL)]))
  58 AC_ARG_ENABLE(pic,
  59    AS_HELP_STRING(--enable-pic, [Build Tor's binaries as position-independent code, suitable to link as a library.]))
  60
  61 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  62     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  63 fi
  64
  65 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  66 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  67 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  68 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  69 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  70 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  71 AM_CONDITIONAL(USE_NSS, test "x$enable_nss" = "xyes")
  72 AM_CONDITIONAL(USE_OPENSSL, test "x$enable_nss" != "xyes")
  73
  74 if test "x$enable_nss" = "xyes"; then
  75   AC_DEFINE(ENABLE_NSS, 1,
  76             [Defined if we're building with NSS.])
  77 else
  78   AC_DEFINE(ENABLE_OPENSSL, 1,
  79             [Defined if we're building with OpenSSL or LibreSSL])
  80 fi
  81
  82 if test "$enable_static_tor" = "yes"; then
  83   enable_static_libevent="yes";
  84   enable_static_openssl="yes";
  85   enable_static_zlib="yes";
  86   CFLAGS="$CFLAGS -static"
  87 fi
  88
  89 if test "$enable_system_torrc" = "no"; then
  90   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  91             [Defined if we're not going to look for a torrc in SYSCONF])
  92 fi
  93
  94 if test "$enable_memory_sentinels" = "no"; then
  95   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  96            [Defined if we're turning off memory safety code to look for bugs])
  97 fi
  98
  99 AC_ARG_ENABLE(asciidoc,
 100      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
 101      [case "${enableval}" in
 102         "yes") asciidoc=true ;;
 103         "no")  asciidoc=false ;;
 104         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
 105       esac], [asciidoc=true])
 106
 107 # systemd notify support
 108 AC_ARG_ENABLE(systemd,
 109       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 110       [case "${enableval}" in
 111         "yes") systemd=true ;;
 112         "no")  systemd=false ;;
 113         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 114       esac], [systemd=auto])
 115
 116 if test "$enable_restart_debugging" = "yes"; then
 117   AC_DEFINE(ENABLE_RESTART_DEBUGGING, 1,
 118             [Defined if we're building with support for in-process restart debugging.])
 119 fi
 120
 121 if test "$enable_zstd_advanced_apis" != "no"; then
 122    AC_DEFINE(ENABLE_ZSTD_ADVANCED_APIS, 1,
 123              [Defined if we're going to try to use zstd's "static-only" APIs.])
 124 fi
 125
 126 # systemd support
 127 if test "x$enable_systemd" = "xno"; then
 128     have_systemd=no;
 129 else
 130     PKG_CHECK_MODULES(SYSTEMD,
 131         [libsystemd-daemon],
 132         have_systemd=yes,
 133         have_systemd=no)
 134     if test "x$have_systemd" = "xno"; then
 135         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 136         PKG_CHECK_MODULES(SYSTEMD,
 137             [libsystemd],
 138             have_systemd=yes,
 139             have_systemd=no)
 140     fi
 141 fi
 142
 143 if test "x$have_systemd" = "xyes"; then
 144     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 145     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 146     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 147     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 148          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 149 fi
 150 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 151 AC_SUBST(TOR_SYSTEMD_LIBS)
 152
 153 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 154     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 155 fi
 156
 157 case "$host" in
 158    *-*-solaris* )
 159      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 160      ;;
 161 esac
 162
 163 AC_ARG_ENABLE(gcc-warnings,
 164      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 165 AC_ARG_ENABLE(fatal-warnings,
 166      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 167 AC_ARG_ENABLE(gcc-warnings-advisory,
 168      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 169
 170 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 171 AC_ARG_ENABLE(gcc-hardening,
 172     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 173
 174 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 175 AC_ARG_ENABLE(expensive-hardening,
 176     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 177 AC_ARG_ENABLE(fragile-hardening,
 178     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 179 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 180   fragile_hardening="yes"
 181   AC_DEFINE(DEBUG_SMARTLIST, 1, [Enable smartlist debugging])
 182 fi
 183
 184 dnl Linker hardening options
 185 dnl Currently these options are ELF specific - you can't use this with MacOSX
 186 AC_ARG_ENABLE(linker-hardening,
 187     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 188
 189 AC_ARG_ENABLE(local-appdata,
 190    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 191 if test "$enable_local_appdata" = "yes"; then
 192   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 193             [Defined if we default to host local appdata paths on Windows])
 194 fi
 195
 196 AC_ARG_ENABLE(tool-name-check,
 197      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 198
 199 AC_ARG_ENABLE(seccomp,
 200      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 201
 202 AC_ARG_ENABLE(libscrypt,
 203      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 204
 205 dnl Enable event tracing which are transformed to debug log statement.
 206 AC_ARG_ENABLE(event-tracing-debug,
 207      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 208 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 209
 210 if test x$enable_event_tracing_debug = xyes; then
 211   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 212   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 213 fi
 214
 215 dnl Enable Android only features.
 216 AC_ARG_ENABLE(android,
 217      AS_HELP_STRING(--enable-android, [build with Android features enabled]))
 218 AM_CONDITIONAL([USE_ANDROID], [test "x$enable_android" = "xyes"])
 219
 220 if test "x$enable_android" = "xyes"; then
 221   AC_DEFINE([USE_ANDROID], [1], [Compile with Android specific features enabled])
 222
 223   dnl Check if the Android log library is available.
 224   AC_CHECK_HEADERS([android/log.h])
 225   AC_SEARCH_LIBS(__android_log_write, [log])
 226
 227 fi
 228
 229 dnl ---
 230 dnl Tor modules options. These options are namespaced with --disable-module-XXX
 231 dnl ---
 232
 233 dnl All our modules.
 234 m4_define(MODULES, dirauth)
 235
 236 dnl Directory Authority module.
 237 AC_ARG_ENABLE([module-dirauth],
 238               AS_HELP_STRING([--disable-module-dirauth],
 239                              [Do not build tor with the dirauth module]),
 240               [], dnl Action if-given
 241               AC_DEFINE([HAVE_MODULE_DIRAUTH], [1],
 242                         [Compile with Directory Authority feature support]))
 243 AM_CONDITIONAL(BUILD_MODULE_DIRAUTH, [test "x$enable_module_dirauth" != "xno"])
 244
 245 dnl Helper variables.
 246 TOR_MODULES_ALL_ENABLED=
 247 AC_DEFUN([ADD_MODULE], [
 248     MODULE=m4_toupper($1)
 249     TOR_MODULES_ALL_ENABLED="${TOR_MODULES_ALL_ENABLED} -DHAVE_MODULE_${MODULE}=1"
 250 ])
 251 m4_foreach_w([module], MODULES, [ADD_MODULE([module])])
 252 AC_SUBST(TOR_MODULES_ALL_ENABLED)
 253
 254 dnl check for the correct "ar" when cross-compiling.
 255 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 256 dnl    so kludge up a replacement for the case where it isn't there yet.)
 257 m4_ifdef([AM_PROG_AR],
 258          [AM_PROG_AR],
 259          [AN_MAKEVAR([AR], [AC_PROG_AR])
 260           AN_PROGRAM([ar], [AC_PROG_AR])
 261           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 262           AC_PROG_AR])
 263
 264 dnl Check whether the above macro has settled for a simply named tool even
 265 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 266 dnl because that will find any cc on the system, not only the cross-compiler,
 267 dnl and then verify that a binary built with this compiler runs on the
 268 dnl build system. It will then come to the false conclusion that we're not
 269 dnl cross-compiling.
 270 if test "x$enable_tool_name_check" != "xno"; then
 271     if test "x$ac_tool_warned" = "xyes"; then
 272         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 273         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 274                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 275         fi
 276 fi
 277
 278 AC_PROG_CC
 279 AC_PROG_CPP
 280 AC_PROG_MAKE_SET
 281 AC_PROG_RANLIB
 282 AC_PROG_SED
 283
 284 AC_ARG_VAR([PERL], [path to Perl binary])
 285 AC_CHECK_PROGS([PERL], [perl])
 286 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 287
 288 dnl check for asciidoc and a2x
 289 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 290 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 291
 292 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 293
 294 AM_PROG_CC_C_O
 295 AC_PROG_CC_C99
 296
 297 AC_ARG_VAR([PYTHON], [path to Python binary])
 298 AC_CHECK_PROGS(PYTHON, [ \
 299         python3 \
 300         python3.8 python3.7 python3.6 python3.5 python3.4 \
 301         python \
 302         python2 python2.7])
 303 if test "x$PYTHON" = "x"; then
 304   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 305 fi
 306 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 307
 308 dnl List all external rust crates we depend on here. Include the version
 309 rust_crates=" \
 310     digest-0.7.2 \
 311     libc-0.2.39 \
 312 "
 313 AC_SUBST(rust_crates)
 314
 315 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 316 AC_C_FLEXIBLE_ARRAY_MEMBER
 317 ], [
 318  dnl Maybe we've got an old autoconf...
 319  AC_CACHE_CHECK([for flexible array members],
 320      tor_cv_c_flexarray,
 321      [AC_COMPILE_IFELSE(
 322        AC_LANG_PROGRAM([
 323  struct abc { int a; char b[]; };
 324 ], [
 325  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 326  def->b[0] = 33;
 327 ]),
 328   [tor_cv_c_flexarray=yes],
 329   [tor_cv_c_flexarray=no])])
 330  if test "$tor_cv_flexarray" = "yes"; then
 331    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 332  else
 333    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 334  fi
 335 ])
 336
 337 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 338       tor_cv_c_c99_decl,
 339       [AC_COMPILE_IFELSE(
 340          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 341          [tor_cv_c_c99_decl=yes],
 342          [tor_cv_c_c99_decl=no] )])
 343 if test "$tor_cv_c_c99_decl" != "yes"; then
 344   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 345 fi
 346
 347 AC_CACHE_CHECK([for working C99 designated initializers],
 348       tor_cv_c_c99_designated_init,
 349       [AC_COMPILE_IFELSE(
 350          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 351                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 352          [tor_cv_c_c99_designated_init=yes],
 353          [tor_cv_c_c99_designated_init=no] )])
 354
 355 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 356   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 357 fi
 358
 359 saved_CFLAGS="$CFLAGS"
 360 CFLAGS="$CFLAGS -Werror"
 361 AC_CACHE_CHECK([for __attribute__((fallthrough))],
 362       tor_cv_c_attr_fallthrough,
 363       [AC_COMPILE_IFELSE(
 364          [AC_LANG_PROGRAM([extern int x; void fn(void) ;],
 365                [[ switch (x) { case 1: fn(); __attribute__((fallthrough));
 366                                case 2: fn(); break; } ]])],
 367          [tor_cv_c_attr_fallthrough=yes],
 368          [tor_cv_c_attr_fallthrough=no] )])
 369 CFLAGS="$saved_CFLAGS"
 370
 371 if test "$tor_cv_c_attr_fallthrough" = "yes"; then
 372   AC_DEFINE(HAVE_ATTR_FALLTHROUGH, [1], [defined if we have the fallthrough attribute.])
 373 fi
 374
 375 TORUSER=_tor
 376 AC_ARG_WITH(tor-user,
 377         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 378         [
 379            TORUSER=$withval
 380         ]
 381 )
 382 AC_SUBST(TORUSER)
 383
 384 TORGROUP=_tor
 385 AC_ARG_WITH(tor-group,
 386         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 387         [
 388            TORGROUP=$withval
 389         ]
 390 )
 391 AC_SUBST(TORGROUP)
 392
 393
 394 dnl If _WIN32 is defined and non-zero, we are building for win32
 395 AC_MSG_CHECKING([for win32])
 396 AC_RUN_IFELSE([AC_LANG_SOURCE([
 397 int main(int c, char **v) {
 398 #ifdef _WIN32
 399 #if _WIN32
 400   return 0;
 401 #else
 402   return 1;
 403 #endif
 404 #else
 405   return 2;
 406 #endif
 407 }])],
 408 bwin32=true; AC_MSG_RESULT([yes]),
 409 bwin32=false; AC_MSG_RESULT([no]),
 410 bwin32=cross; AC_MSG_RESULT([cross])
 411 )
 412
 413 if test "$bwin32" = "cross"; then
 414 AC_MSG_CHECKING([for win32 (cross)])
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 416 #ifdef _WIN32
 417 int main(int c, char **v) {return 0;}
 418 #else
 419 #error
 420 int main(int c, char **v) {return x(y);}
 421 #endif
 422 ])],
 423 bwin32=true; AC_MSG_RESULT([yes]),
 424 bwin32=false; AC_MSG_RESULT([no]))
 425 fi
 426
 427 AH_BOTTOM([
 428 #ifdef _WIN32
 429 /* Defined to access windows functions and definitions for >=WinXP */
 430 # ifndef WINVER
 431 #  define WINVER 0x0501
 432 # endif
 433
 434 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 435 # ifndef _WIN32_WINNT
 436 #  define _WIN32_WINNT 0x0501
 437 # endif
 438
 439 /* Defined to avoid including some windows headers as part of Windows.h */
 440 # ifndef WIN32_LEAN_AND_MEAN
 441 #  define WIN32_LEAN_AND_MEAN 1
 442 # endif
 443 #endif
 444 ])
 445
 446 AM_CONDITIONAL(WIN32, test "x$bwin32" = "xtrue")
 447 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 448 AM_CONDITIONAL(BUILD_LIBTORRUNNER, test "x$bwin32" != "xtrue")
 449
 450 dnl Enable C99 when compiling with MIPSpro
 451 AC_MSG_CHECKING([for MIPSpro compiler])
 452 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 453 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 454 #error
 455   return x(y);
 456 #endif
 457 ])],
 458 bmipspro=false; AC_MSG_RESULT(no),
 459 bmipspro=true; AC_MSG_RESULT(yes))
 460
 461 if test "$bmipspro" = "true"; then
 462   CFLAGS="$CFLAGS -c99"
 463 fi
 464
 465 AC_C_BIGENDIAN
 466
 467 AC_ARG_VAR([TOR_RUST_TARGET], [Rust target, must be specified when cross-compiling (HOST != BUILD). example: i686-pc-windows-gnu])
 468
 469 if test "x$enable_rust" = "xyes"; then
 470   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 471   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 472   if test "x$RUSTC" = "xno"; then
 473     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 474   fi
 475
 476   AC_ARG_VAR([CARGO], [path to the cargo binary])
 477   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 478   if test "x$CARGO" = "xno"; then
 479     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 480   fi
 481
 482   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 483   if test "x$enable_fatal_warnings" = "xyes"; then
 484     RUST_WARN=
 485   else
 486     RUST_WARN=#
 487   fi
 488   if test "x$enable_cargo_online_mode" = "xyes"; then
 489     CARGO_ONLINE=
 490     RUST_DL=#
 491   else
 492     CARGO_ONLINE=--frozen
 493     RUST_DL=
 494
 495     dnl When we're not allowed to touch the network, we need crate dependencies
 496     dnl locally available.
 497     AC_MSG_CHECKING([rust crate dependencies])
 498     AC_ARG_VAR([TOR_RUST_DEPENDENCIES], [path to directory with local crate mirror])
 499     if test "x$TOR_RUST_DEPENDENCIES" = "x"; then
 500       TOR_RUST_DEPENDENCIES="${srcdir}/src/ext/rust/crates"
 501     fi
 502     dnl Check whether the path exists before we try to cd into it.
 503     if test ! -d "$TOR_RUST_DEPENDENCIES"; then
 504       AC_MSG_ERROR([Rust dependency directory $TOR_RUST_DEPENDENCIES does not exist. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 505       ERRORED=1
 506     fi
 507     dnl Make the path absolute, since we'll be using it from within a
 508     dnl subdirectory.
 509     TOR_RUST_DEPENDENCIES=$(cd "$TOR_RUST_DEPENDENCIES" ; pwd)
 510
 511     for dep in $rust_crates; do
 512       if test ! -d "$TOR_RUST_DEPENDENCIES"/"$dep"; then
 513         AC_MSG_ERROR([Failure to find rust dependency $TOR_RUST_DEPENDENCIES/$dep. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 514         ERRORED=1
 515       fi
 516     done
 517     if test "x$ERRORED" = "x"; then
 518       AC_MSG_RESULT([yes])
 519     fi
 520   fi
 521
 522   dnl This is a workaround for #46797
 523   dnl (a.k.a https://github.com/rust-lang/rust/issues/46797 ).  Once the
 524   dnl upstream bug is fixed, we can remove this workaround.
 525   case "$host_os" in
 526       darwin*)
 527         TOR_RUST_EXTRA_LIBS="-lresolv"
 528         ;;
 529   esac
 530
 531   dnl For now both MSVC and MinGW rust libraries will output static libs with
 532   dnl the MSVC naming convention.
 533   if test "$bwin32" = "true"; then
 534     tor_rust_static_name=tor_rust.lib
 535   else
 536     tor_rust_static_name=libtor_rust.a
 537   fi
 538
 539   AC_CANONICAL_BUILD
 540
 541   if test -n "$TOR_RUST_TARGET"; then
 542     if test "$host" = "$build"; then
 543       AC_MSG_ERROR([HOST = BUILD is invalid if TOR_RUST_TARGET is specified, see configure --help for more information.])
 544     fi
 545     RUST_TARGET_PROP="target = '$TOR_RUST_TARGET'"
 546     TOR_RUST_LIB_PATH="src/rust/target/$TOR_RUST_TARGET/release/$tor_rust_static_name"
 547   else
 548     if test "$host" != "$build"; then
 549       AC_MSG_ERROR([TOR_RUST_TARGET must be specified when cross-compiling with Rust enabled.])
 550     fi
 551     RUST_TARGET_PROP=
 552     TOR_RUST_LIB_PATH="src/rust/target/release/$tor_rust_static_name"
 553   fi
 554
 555   AC_SUBST(RUST_TARGET_PROP)
 556   AC_SUBST(TOR_RUST_LIB_PATH)
 557   AC_SUBST(CARGO_ONLINE)
 558   AC_SUBST(RUST_WARN)
 559   AC_SUBST(RUST_DL)
 560
 561   dnl Let's check the rustc version, too
 562   AC_MSG_CHECKING([rust version])
 563   RUSTC_VERSION=`$RUSTC --version`
 564   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 565   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 566   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 567     AC_MSG_ERROR([rustc version couldn't be identified])
 568   fi
 569   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 570     AC_MSG_ERROR([rustc must be at least version 1.14])
 571   fi
 572   AC_MSG_RESULT([$RUSTC_VERSION])
 573 fi
 574
 575 AC_SUBST(TOR_RUST_EXTRA_LIBS)
 576
 577 AC_SEARCH_LIBS(socket, [socket network])
 578 AC_SEARCH_LIBS(gethostbyname, [nsl])
 579 AC_SEARCH_LIBS(dlopen, [dl])
 580 AC_SEARCH_LIBS(inet_aton, [resolv])
 581 AC_SEARCH_LIBS(backtrace, [execinfo])
 582 saved_LIBS="$LIBS"
 583 AC_SEARCH_LIBS([clock_gettime], [rt])
 584 if test "$LIBS" != "$saved_LIBS"; then
 585    # Looks like we need -lrt for clock_gettime().
 586    have_rt=yes
 587 fi
 588
 589 if test "$bwin32" = "false"; then
 590   AC_SEARCH_LIBS(pthread_create, [pthread])
 591   AC_SEARCH_LIBS(pthread_detach, [pthread])
 592 fi
 593
 594 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 595 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 596
 597 AC_CHECK_FUNCS(
 598         _NSGetEnviron \
 599         RtlSecureZeroMemory \
 600         SecureZeroMemory \
 601         accept4 \
 602         backtrace \
 603         backtrace_symbols_fd \
 604         eventfd \
 605         explicit_bzero \
 606         timingsafe_memcmp \
 607         flock \
 608         ftime \
 609         get_current_dir_name \
 610         getaddrinfo \
 611         getdelim \
 612         getifaddrs \
 613         getline \
 614         getpass \
 615         getrlimit \
 616         gettimeofday \
 617         gmtime_r \
 618         gnu_get_libc_version \
 619         htonll \
 620         inet_aton \
 621         ioctl \
 622         issetugid \
 623         llround \
 624         localtime_r \
 625         lround \
 626         memmem \
 627         memset_s \
 628         mmap \
 629         pipe \
 630         pipe2 \
 631         prctl \
 632         readpassphrase \
 633         rint \
 634         sigaction \
 635         socketpair \
 636         statvfs \
 637         strncasecmp \
 638         strcasecmp \
 639         strlcat \
 640         strlcpy \
 641         strnlen \
 642         strptime \
 643         strtok_r \
 644         strtoull \
 645         sysconf \
 646         sysctl \
 647         truncate \
 648         uname \
 649         usleep \
 650         vasprintf \
 651         _vscprintf
 652 )
 653
 654 # Apple messed up when they added some functions: they
 655 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 656 # checks.
 657
 658 # We should only probe for these functions if we are sure that we
 659 # are not targeting OS X 10.9 or earlier.
 660 AC_MSG_CHECKING([for a pre-Yosemite OS X build target])
 661 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 662 #ifdef __APPLE__
 663 #  include <AvailabilityMacros.h>
 664 #  ifndef MAC_OS_X_VERSION_10_10
 665 #    define MAC_OS_X_VERSION_10_10 101000
 666 #  endif
 667 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 668 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_10
 669 #      error "Running on Mac OS X 10.9 or earlier"
 670 #    endif
 671 #  endif
 672 #endif
 673 ]], [[]])],
 674    [on_macos_pre_10_10=no ; AC_MSG_RESULT([no])],
 675    [on_macos_pre_10_10=yes; AC_MSG_RESULT([yes])])
 676
 677 if test "$on_macos_pre_10_10" = "no"; then
 678   AC_CHECK_FUNCS(
 679         mach_approximate_time \
 680   )
 681 fi
 682
 683 # We should only probe for these functions if we are sure that we
 684 # are not targeting OSX 10.11 or earlier.
 685 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 686 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 687 #ifdef __APPLE__
 688 #  include <AvailabilityMacros.h>
 689 #  ifndef MAC_OS_X_VERSION_10_12
 690 #    define MAC_OS_X_VERSION_10_12 101200
 691 #  endif
 692 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 693 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 694 #      error "Running on Mac OSX 10.11 or earlier"
 695 #    endif
 696 #  endif
 697 #endif
 698 ]], [[]])],
 699    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 700    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 701
 702 if test "$on_macos_pre_10_12" = "no"; then
 703   AC_CHECK_FUNCS(
 704         clock_gettime \
 705         getentropy \
 706   )
 707 fi
 708
 709 if test "$bwin32" != "true"; then
 710   AC_CHECK_HEADERS(pthread.h)
 711   AC_CHECK_FUNCS(pthread_create)
 712   AC_CHECK_FUNCS(pthread_condattr_setclock)
 713 fi
 714
 715 if test "$bwin32" = "true"; then
 716   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 717 #include <windows.h>
 718 #include <conio.h>
 719 #include <wchar.h>
 720                  ])
 721 fi
 722
 723 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 724   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 725
 726 AC_MSG_CHECKING([whether free(NULL) works])
 727 AC_RUN_IFELSE([AC_LANG_PROGRAM([
 728   #include <stdlib.h>
 729 ], [
 730 char *p = NULL;
 731 free(p);
 732 ])],
 733 [free_null_ok=true; AC_MSG_RESULT(yes)],
 734 [free_null_ok=false; AC_MSG_RESULT(no)],
 735 [free_null_ok=cross; AC_MSG_RESULT(cross)])
 736
 737 if test "$free_null_ok" = "false"; then
 738    AC_MSG_ERROR([Your libc implementation doesn't allow free(NULL), as required by C99.])
 739 fi
 740
 741 dnl ------------------------------------------------------
 742 dnl Where do you live, libevent?  And how do we call you?
 743
 744 if test "$bwin32" = "true"; then
 745   TOR_LIB_WS32=-lws2_32
 746   TOR_LIB_IPHLPAPI=-liphlpapi
 747   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 748   # think it's actually necessary.
 749   TOR_LIB_GDI=-lgdi32
 750   TOR_LIB_USERENV=-luserenv
 751 else
 752   TOR_LIB_WS32=
 753   TOR_LIB_GDI=
 754   TOR_LIB_USERENV=
 755 fi
 756 AC_SUBST(TOR_LIB_WS32)
 757 AC_SUBST(TOR_LIB_GDI)
 758 AC_SUBST(TOR_LIB_IPHLPAPI)
 759 AC_SUBST(TOR_LIB_USERENV)
 760
 761 tor_libevent_pkg_redhat="libevent"
 762 tor_libevent_pkg_debian="libevent-dev"
 763 tor_libevent_devpkg_redhat="libevent-devel"
 764 tor_libevent_devpkg_debian="libevent-dev"
 765
 766 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 767 dnl linking for static builds.
 768 STATIC_LIBEVENT_FLAGS=""
 769 if test "$enable_static_libevent" = "yes"; then
 770     if test "$have_rt" = "yes"; then
 771       STATIC_LIBEVENT_FLAGS=" -lrt "
 772     fi
 773 fi
 774
 775 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 776 #ifdef _WIN32
 777 #include <winsock2.h>
 778 #endif
 779 #include <sys/time.h>
 780 #include <sys/types.h>
 781 #include <event2/event.h>], [
 782 #ifdef _WIN32
 783 #include <winsock2.h>
 784 #endif
 785 struct event_base;
 786 struct event_base *event_base_new(void);
 787 void event_base_free(struct event_base *);],
 788     [
 789 #ifdef _WIN32
 790 {WSADATA d; WSAStartup(0x101,&d); }
 791 #endif
 792 event_base_free(event_base_new());
 793 ], [--with-libevent-dir], [/opt/libevent])
 794
 795 dnl Determine the incantation needed to link libevent.
 796 save_LIBS="$LIBS"
 797 save_LDFLAGS="$LDFLAGS"
 798 save_CPPFLAGS="$CPPFLAGS"
 799
 800 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 801 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 802 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 803
 804 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 805
 806 if test "$enable_static_libevent" = "yes"; then
 807    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 808      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 809    else
 810      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 811    fi
 812 else
 813      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 814        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 815        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 816
 817        if test "$ac_cv_search_event_new" != "none required"; then
 818          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 819        fi
 820        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 821          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 822        fi
 823      else
 824        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 825      fi
 826 fi
 827
 828 dnl Now check for particular libevent functions.
 829 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 830                 evutil_secure_rng_add_bytes \
 831 ])
 832
 833 LIBS="$save_LIBS"
 834 LDFLAGS="$save_LDFLAGS"
 835 CPPFLAGS="$save_CPPFLAGS"
 836
 837 dnl Check that libevent is at least at version 2.0.10, the first stable
 838 dnl release of its series
 839 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 840 AC_MSG_CHECKING([whether Libevent is new enough])
 841 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 842 #include <event2/event.h>
 843 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 844 #error
 845 int x = y(zz);
 846 #else
 847 int x = 1;
 848 #endif
 849 ])], [ AC_MSG_RESULT([yes]) ],
 850    [ AC_MSG_RESULT([no])
 851      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 852
 853 LIBS="$save_LIBS"
 854 LDFLAGS="$save_LDFLAGS"
 855 CPPFLAGS="$save_CPPFLAGS"
 856
 857 AC_SUBST(TOR_LIBEVENT_LIBS)
 858
 859 dnl ------------------------------------------------------
 860 dnl Where do you live, libm?
 861
 862 dnl On some platforms (Haiku/BeOS) the math library is
 863 dnl part of libroot. In which case don't link against lm
 864 TOR_LIB_MATH=""
 865 save_LIBS="$LIBS"
 866 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 867 if test "$ac_cv_search_pow" != "none required"; then
 868     TOR_LIB_MATH="$ac_cv_search_pow"
 869 fi
 870 LIBS="$save_LIBS"
 871 AC_SUBST(TOR_LIB_MATH)
 872
 873 dnl ------------------------------------------------------
 874 dnl Hello, NSS.  You're new around here.
 875 if test "x$enable_nss" = "xyes"; then
 876   PKG_CHECK_MODULES(NSS,
 877      [nss],
 878      [have_nss=yes],
 879      [have_nss=no; AC_MSG_ERROR([You asked for NSS but I can't find it.])])
 880   AC_SUBST(NSS_CFLAGS)
 881   AC_SUBST(NSS_LIBS)
 882 fi
 883
 884 dnl ------------------------------------------------------
 885 dnl Where do you live, openssl?  And how do we call you?
 886
 887 if test "x$enable_nss" != "xyes"; then
 888
 889 tor_openssl_pkg_redhat="openssl"
 890 tor_openssl_pkg_debian="libssl-dev"
 891 tor_openssl_devpkg_redhat="openssl-devel"
 892 tor_openssl_devpkg_debian="libssl-dev"
 893
 894 ALT_openssl_WITHVAL=""
 895 AC_ARG_WITH(ssl-dir,
 896   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 897   [
 898       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 899          ALT_openssl_WITHVAL="$withval"
 900       fi
 901   ])
 902
 903 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 904 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 905     [#include <openssl/ssl.h>
 906      char *getenv(const char *);],
 907     [struct ssl_cipher_st;
 908      unsigned SSL_CIPHER_get_id(const struct ssl_cipher_st *);
 909      char *getenv(const char *);],
 910     dnl This funny-looking test program calls getenv, so that the compiler
 911     dnl will neither make code that call SSL_CIPHER_get_id(NULL) [producing
 912     dnl a crash], nor optimize out the call to SSL_CIPHER_get_id().
 913     dnl We look for SSL_cipher_get_id() because it is present in
 914     dnl OpenSSL >=1.0.1, because it is not deprecated, and because Tor
 915     dnl depends on it.
 916     [if (getenv("THIS_SHOULDNT_BE_SET_X201803")) SSL_CIPHER_get_id((void *)0);], [],
 917     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /opt/openssl])
 918
 919 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 920
 921 if test "$enable_static_openssl" = "yes"; then
 922    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 923      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 924    else
 925      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 926    fi
 927 else
 928      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 929 fi
 930 AC_SUBST(TOR_OPENSSL_LIBS)
 931
 932 dnl Now check for particular openssl functions.
 933 save_LIBS="$LIBS"
 934 save_LDFLAGS="$LDFLAGS"
 935 save_CPPFLAGS="$CPPFLAGS"
 936 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 937 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 938 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 939
 940 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 941 #include <openssl/opensslv.h>
 942 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 943 #error "too old"
 944 #endif
 945    ]], [[]])],
 946    [ : ],
 947    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 948
 949 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 950 #include <openssl/opensslv.h>
 951 #include <openssl/evp.h>
 952 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 953 #error "no ECC"
 954 #endif
 955 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 956 #error "curves unavailable"
 957 #endif
 958    ]], [[]])],
 959    [ : ],
 960    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 961
 962 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 963 [#include <openssl/ssl.h>
 964 ])
 965
 966 AC_CHECK_FUNCS([ \
 967                 ERR_load_KDF_strings \
 968                 SSL_SESSION_get_master_key \
 969                 SSL_get_server_random \
 970                 SSL_get_client_ciphers \
 971                 SSL_get_client_random \
 972                 SSL_CTX_set1_groups_list \
 973                 SSL_CIPHER_find \
 974                 SSL_CTX_set_security_level \
 975                 TLS_method
 976                ])
 977
 978 dnl Check if OpenSSL has scrypt implementation.
 979 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 980
 981 dnl Check if OpenSSL structures are opaque
 982 AC_CHECK_MEMBERS([SSL.state], , ,
 983 [#include <openssl/ssl.h>
 984 ])
 985
 986 AC_CHECK_SIZEOF(SHA_CTX, , [AC_INCLUDES_DEFAULT()
 987 #include <openssl/sha.h>
 988 ])
 989
 990 fi # enable_nss
 991
 992 dnl ======================================================================
 993 dnl Can we use KIST?
 994
 995 dnl Define the set of checks for KIST scheduler support.
 996 AC_DEFUN([CHECK_KIST_SUPPORT],[
 997   dnl KIST needs struct tcp_info and for certain members to exist.
 998   AC_CHECK_MEMBERS(
 999     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
1000     , ,[[#include <netinet/tcp.h>]])
1001   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
1002   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1003                      #include <linux/sockios.h>
1004                      #ifndef SIOCOUTQNSD
1005                      #error
1006                      #endif
1007                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
1008   if test "x$have_siocoutqnsd" = "xyes"; then
1009     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
1010       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
1011         have_kist_support=yes
1012       fi
1013     fi
1014   fi
1015 ])
1016 dnl Now, trigger the check.
1017 CHECK_KIST_SUPPORT
1018 AS_IF([test "x$have_kist_support" = "xyes"],
1019       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
1020                                         on this system])],
1021       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
1022
1023 LIBS="$save_LIBS"
1024 LDFLAGS="$save_LDFLAGS"
1025 CPPFLAGS="$save_CPPFLAGS"
1026
1027 dnl ------------------------------------------------------
1028 dnl Where do you live, zlib?  And how do we call you?
1029
1030 tor_zlib_pkg_redhat="zlib"
1031 tor_zlib_pkg_debian="zlib1g"
1032 tor_zlib_devpkg_redhat="zlib-devel"
1033 tor_zlib_devpkg_debian="zlib1g-dev"
1034
1035 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
1036     [#include <zlib.h>],
1037     [const char * zlibVersion(void);],
1038     [zlibVersion();], [--with-zlib-dir],
1039     [/opt/zlib])
1040
1041 if test "$enable_static_zlib" = "yes"; then
1042    if test "$tor_cv_library_zlib_dir" = "(system)"; then
1043      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
1044  using --enable-static-zlib")
1045    else
1046      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
1047    fi
1048 else
1049      TOR_ZLIB_LIBS="-lz"
1050 fi
1051 AC_SUBST(TOR_ZLIB_LIBS)
1052
1053 dnl ------------------------------------------------------
1054 dnl Where we do we find lzma?
1055
1056 AC_ARG_ENABLE(lzma,
1057       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
1058       [case "${enableval}" in
1059         "yes") lzma=true ;;
1060         "no")  lzma=false ;;
1061         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
1062       esac], [lzma=auto])
1063
1064 if test "x$enable_lzma" = "xno"; then
1065     have_lzma=no;
1066 else
1067     PKG_CHECK_MODULES([LZMA],
1068                       [liblzma],
1069                       have_lzma=yes,
1070                       have_lzma=no)
1071
1072     if test "x$have_lzma" = "xno" ; then
1073         AC_MSG_WARN([Unable to find liblzma.])
1074     fi
1075 fi
1076
1077 if test "x$have_lzma" = "xyes"; then
1078     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
1079     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
1080     TOR_LZMA_LIBS="${LZMA_LIBS}"
1081 fi
1082 AC_SUBST(TOR_LZMA_CFLAGS)
1083 AC_SUBST(TOR_LZMA_LIBS)
1084
1085 dnl ------------------------------------------------------
1086 dnl Where we do we find zstd?
1087
1088 AC_ARG_ENABLE(zstd,
1089       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
1090       [case "${enableval}" in
1091         "yes") zstd=true ;;
1092         "no")  zstd=false ;;
1093         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
1094       esac], [zstd=auto])
1095
1096 if test "x$enable_zstd" = "xno"; then
1097     have_zstd=no;
1098 else
1099     PKG_CHECK_MODULES([ZSTD],
1100                       [libzstd >= 1.1],
1101                       have_zstd=yes,
1102                       have_zstd=no)
1103
1104     if test "x$have_zstd" = "xno" ; then
1105         AC_MSG_WARN([Unable to find libzstd.])
1106     fi
1107 fi
1108
1109 if test "x$have_zstd" = "xyes"; then
1110     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
1111     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
1112     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
1113
1114     dnl now check for zstd functions
1115     save_LIBS="$LIBS"
1116     save_CFLAGS="$CFLAGS"
1117     LIBS="$LIBS $ZSTD_LIBS"
1118     CFLAGS="$CFLAGS $ZSTD_CFLAGS"
1119     AC_CHECK_FUNCS(ZSTD_estimateCStreamSize \
1120                    ZSTD_estimateDCtxSize)
1121     LIBS="$save_LIBS"
1122     CFLAGS="$save_CFLAGS"
1123 fi
1124 AC_SUBST(TOR_ZSTD_CFLAGS)
1125 AC_SUBST(TOR_ZSTD_LIBS)
1126
1127 dnl ----------------------------------------------------------------------
1128 dnl Check if libcap is available for capabilities.
1129
1130 tor_cap_pkg_debian="libcap2"
1131 tor_cap_pkg_redhat="libcap"
1132 tor_cap_devpkg_debian="libcap-dev"
1133 tor_cap_devpkg_redhat="libcap-devel"
1134
1135 AC_CHECK_LIB([cap], [cap_init], [],
1136   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
1137 )
1138 AC_CHECK_FUNCS(cap_set_proc)
1139
1140 dnl ---------------------------------------------------------------------
1141 dnl Now that we know about our major libraries, we can check for compiler
1142 dnl and linker hardening options.  We need to do this with the libraries known,
1143 dnl since sometimes the linker will like an option but not be willing to
1144 dnl use it with a build of a library.
1145
1146 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
1147 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
1148
1149 CFLAGS_FTRAPV=
1150 CFLAGS_FWRAPV=
1151 CFLAGS_ASAN=
1152 CFLAGS_UBSAN=
1153
1154
1155 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1156 #if !defined(__clang__)
1157 #error
1158 #endif])], have_clang=yes, have_clang=no)
1159
1160 if test "x$enable_pic" = "xyes"; then
1161     TOR_CHECK_CFLAGS(-fPIC)
1162 fi
1163
1164 if test "x$enable_gcc_hardening" != "xno"; then
1165     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
1166     if test "x$have_clang" = "xyes"; then
1167         TOR_CHECK_CFLAGS(-Qunused-arguments)
1168     fi
1169     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
1170     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
1171     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
1172 m4_ifdef([AS_VAR_IF],[
1173     AS_VAR_IF(can_compile, [yes],
1174         AS_VAR_IF(can_link, [yes],
1175                   [],
1176                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
1177         )])
1178     AS_VAR_POPDEF([can_link])
1179     AS_VAR_POPDEF([can_compile])
1180     TOR_CHECK_CFLAGS(-Wstack-protector)
1181     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
1182     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
1183        if test "$enable_pic" != "yes"; then
1184            # If we have already enabled -fPIC, then we don't also need to
1185            # compile with -fPIE...
1186            TOR_CHECK_CFLAGS(-fPIE)
1187        fi
1188        # ... but we want to link our executables with -pie in any case, since
1189        # they're executables, not a library.
1190        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
1191     fi
1192     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
1193 fi
1194
1195 if test "$fragile_hardening" = "yes"; then
1196     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
1197    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
1198       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
1199    fi
1200
1201    if test "$tor_cv_cflags__ftrapv" != "yes"; then
1202      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
1203    fi
1204
1205    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
1206     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1207       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.*, and with Clang you need libclang_rt.ubsan*])
1208     fi
1209
1210    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1211     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1212       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1213     fi
1214
1215 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1216 fi
1217
1218 dnl Find the correct libraries to add in order to use the sanitizers.
1219 dnl
1220 dnl When building Rust, Cargo will run the linker with the -nodefaultlibs
1221 dnl option, which will prevent the compiler from linking the sanitizer
1222 dnl libraries it needs.  We need to specify them manually.
1223 dnl
1224 dnl What's more, we need to specify them in a linker script rather than
1225 dnl from build.rs: these options aren't allowed in the cargo:rustc-flags
1226 dnl variable.
1227 RUST_LINKER_OPTIONS=""
1228 if test "x$have_clang" = "xyes"; then
1229         if test "x$CFLAGS_ASAN" != "x"; then
1230                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=$CFLAGS_ASAN -Cdefault-linker-libraries"
1231         fi
1232         if test "x$CFLAGS_UBSAN" != "x"; then
1233                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=$CFLAGS_UBSAN -Cdefault-linker-libraries"
1234         fi
1235 else
1236         if test "x$CFLAGS_ASAN" != "x"; then
1237                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=-fsanitize=address -Cdefault-linker-libraries"
1238         fi
1239         if test "x$CFLAGS_UBSAN" != "x"; then
1240                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=-fsanitize=undefined -Cdefault-linker-libraries"
1241         fi
1242 fi
1243 AC_SUBST(RUST_LINKER_OPTIONS)
1244
1245 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1246 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1247
1248 mulodi_fixes_ftrapv=no
1249 if test "$have_clang" = "yes"; then
1250   saved_CFLAGS="$CFLAGS"
1251   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1252   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1253   AC_LINK_IFELSE([
1254       AC_LANG_SOURCE([[
1255           #include <stdint.h>
1256           #include <stdlib.h>
1257           int main(int argc, char **argv)
1258           {
1259             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1260                         * (int64_t)atoi(argv[3]);
1261             return x == 9;
1262           } ]])],
1263           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1264           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1265   if test "$ftrapv_can_link" = "no"; then
1266     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1267     AC_LINK_IFELSE([
1268       AC_LANG_SOURCE([[
1269           #include <stdint.h>
1270           #include <stdlib.h>
1271           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1272              *overflow=0;
1273              return a;
1274           }
1275           int main(int argc, char **argv)
1276           {
1277             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1278                         * (int64_t)atoi(argv[3]);
1279             return x == 9;
1280           } ]])],
1281           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1282           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1283   fi
1284   CFLAGS="$saved_CFLAGS"
1285 fi
1286
1287 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1288
1289 dnl These cflags add bunches of branches, and we haven't been able to
1290 dnl persuade ourselves that they're suitable for code that needs to be
1291 dnl constant time.
1292 AC_SUBST(CFLAGS_BUGTRAP)
1293 dnl These cflags are variant ones sutable for code that needs to be
1294 dnl constant-time.
1295 AC_SUBST(CFLAGS_CONSTTIME)
1296
1297 if test "x$enable_linker_hardening" != "xno"; then
1298     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1299 fi
1300
1301 # For backtrace support
1302 TOR_CHECK_LDFLAGS(-rdynamic)
1303
1304 dnl ------------------------------------------------------
1305 dnl Now see if we have a -fomit-frame-pointer compiler option.
1306
1307 saved_CFLAGS="$CFLAGS"
1308 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1309 F_OMIT_FRAME_POINTER=''
1310 if test "$saved_CFLAGS" != "$CFLAGS"; then
1311   if test "$fragile_hardening" = "yes"; then
1312     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1313   fi
1314 fi
1315 CFLAGS="$saved_CFLAGS"
1316 AC_SUBST(F_OMIT_FRAME_POINTER)
1317
1318 dnl ------------------------------------------------------
1319 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1320 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1321 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1322 dnl code will work.
1323 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1324
1325 dnl ============================================================
1326 dnl Check for libseccomp
1327
1328 if test "x$enable_seccomp" != "xno"; then
1329   AC_CHECK_HEADERS([seccomp.h])
1330   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1331 fi
1332
1333 dnl ============================================================
1334 dnl Check for libscrypt
1335
1336 if test "x$enable_libscrypt" != "xno"; then
1337   AC_CHECK_HEADERS([libscrypt.h])
1338   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1339   AC_CHECK_FUNCS([libscrypt_scrypt])
1340 fi
1341
1342 dnl ============================================================
1343 dnl We need an implementation of curve25519.
1344
1345 dnl set these defaults.
1346 build_curve25519_donna=no
1347 build_curve25519_donna_c64=no
1348 use_curve25519_donna=no
1349 use_curve25519_nacl=no
1350 CURVE25519_LIBS=
1351
1352 dnl The best choice is using curve25519-donna-c64, but that requires
1353 dnl that we
1354 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1355   tor_cv_can_use_curve25519_donna_c64,
1356   [AC_RUN_IFELSE(
1357     [AC_LANG_PROGRAM([dnl
1358       #include <stdint.h>
1359       typedef unsigned uint128_t __attribute__((mode(TI)));
1360   int func(uint64_t a, uint64_t b) {
1361            uint128_t c = ((uint128_t)a) * b;
1362            int ok = ((uint64_t)(c>>96)) == 522859 &&
1363              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1364                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1365                  (((uint64_t)(c))&0xffffffffL) == 0;
1366            return ok;
1367       }
1368   ], [dnl
1369     int ok = func( ((uint64_t)2000000000) * 1000000000,
1370                    ((uint64_t)1234567890) << 24);
1371         return !ok;
1372       ])],
1373   [tor_cv_can_use_curve25519_donna_c64=yes],
1374       [tor_cv_can_use_curve25519_donna_c64=no],
1375   [AC_LINK_IFELSE(
1376         [AC_LANG_PROGRAM([dnl
1377       #include <stdint.h>
1378       typedef unsigned uint128_t __attribute__((mode(TI)));
1379   int func(uint64_t a, uint64_t b) {
1380            uint128_t c = ((uint128_t)a) * b;
1381            int ok = ((uint64_t)(c>>96)) == 522859 &&
1382              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1383                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1384                  (((uint64_t)(c))&0xffffffffL) == 0;
1385            return ok;
1386       }
1387   ], [dnl
1388     int ok = func( ((uint64_t)2000000000) * 1000000000,
1389                  ((uint64_t)1234567890) << 24);
1390         return !ok;
1391       ])],
1392           [tor_cv_can_use_curve25519_donna_c64=cross],
1393       [tor_cv_can_use_curve25519_donna_c64=no])])])
1394
1395 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1396                   nacl/crypto_scalarmult_curve25519.h])
1397
1398 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1399   tor_cv_can_use_curve25519_nacl,
1400   [tor_saved_LIBS="$LIBS"
1401    LIBS="$LIBS -lnacl"
1402    AC_LINK_IFELSE(
1403      [AC_LANG_PROGRAM([dnl
1404        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1405        #include <crypto_scalarmult_curve25519.h>
1406    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1407    #include <nacl/crypto_scalarmult_curve25519.h>
1408    #endif
1409        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1410    #error Hey, this is the reference implementation! That's not fast.
1411    #endif
1412      ], [
1413    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1414      ])], [tor_cv_can_use_curve25519_nacl=yes],
1415      [tor_cv_can_use_curve25519_nacl=no])
1416    LIBS="$tor_saved_LIBS" ])
1417
1418  dnl Okay, now we need to figure out which one to actually use. Fall back
1419  dnl to curve25519-donna.c
1420
1421  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1422    build_curve25519_donna_c64=yes
1423    use_curve25519_donna=yes
1424  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1425    use_curve25519_nacl=yes
1426    CURVE25519_LIBS=-lnacl
1427  else
1428    build_curve25519_donna=yes
1429    use_curve25519_donna=yes
1430  fi
1431
1432 if test "x$use_curve25519_donna" = "xyes"; then
1433   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1434             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1435 fi
1436 if test "x$use_curve25519_nacl" = "xyes"; then
1437   AC_DEFINE(USE_CURVE25519_NACL, 1,
1438             [Defined if we should use a curve25519 from nacl])
1439 fi
1440 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1441   test "x$build_curve25519_donna" = "xyes")
1442 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1443   test "x$build_curve25519_donna_c64" = "xyes")
1444 AC_SUBST(CURVE25519_LIBS)
1445
1446 dnl Make sure to enable support for large off_t if available.
1447 AC_SYS_LARGEFILE
1448
1449 AC_CHECK_HEADERS([errno.h \
1450                   fcntl.h \
1451                   signal.h \
1452                   string.h \
1453                   sys/capability.h \
1454                   sys/fcntl.h \
1455                   sys/stat.h \
1456                   sys/time.h \
1457                   sys/types.h \
1458                   time.h \
1459                   unistd.h \
1460                   arpa/inet.h \
1461                   crt_externs.h \
1462                   execinfo.h \
1463                   gnu/libc-version.h \
1464                   grp.h \
1465                   ifaddrs.h \
1466                   inttypes.h \
1467                   limits.h \
1468                   linux/types.h \
1469                   machine/limits.h \
1470                   malloc.h \
1471                   malloc/malloc.h \
1472                   malloc_np.h \
1473                   netdb.h \
1474                   netinet/in.h \
1475                   netinet/in6.h \
1476                   pwd.h \
1477                   readpassphrase.h \
1478                   stdatomic.h \
1479                   sys/eventfd.h \
1480                   sys/file.h \
1481                   sys/ioctl.h \
1482                   sys/limits.h \
1483                   sys/mman.h \
1484                   sys/param.h \
1485                   sys/prctl.h \
1486                   sys/random.h \
1487                   sys/resource.h \
1488                   sys/select.h \
1489                   sys/socket.h \
1490                   sys/statvfs.h \
1491                   sys/syscall.h \
1492                   sys/sysctl.h \
1493                   sys/syslimits.h \
1494                   sys/time.h \
1495                   sys/types.h \
1496                   sys/un.h \
1497                   sys/utime.h \
1498                   sys/wait.h \
1499                   syslog.h \
1500                   utime.h])
1501
1502 AC_CHECK_HEADERS(sys/param.h)
1503
1504 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1505 [#ifdef HAVE_SYS_TYPES_H
1506 #include <sys/types.h>
1507 #endif
1508 #ifdef HAVE_SYS_SOCKET_H
1509 #include <sys/socket.h>
1510 #endif])
1511 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1512 [#ifdef HAVE_SYS_TYPES_H
1513 #include <sys/types.h>
1514 #endif
1515 #ifdef HAVE_SYS_SOCKET_H
1516 #include <sys/socket.h>
1517 #endif
1518 #ifdef HAVE_NET_IF_H
1519 #include <net/if.h>
1520 #endif
1521 #ifdef HAVE_NETINET_IN_H
1522 #include <netinet/in.h>
1523 #endif])
1524
1525 AC_CHECK_HEADERS(linux/if.h,[],[],
1526 [
1527 #ifdef HAVE_SYS_SOCKET_H
1528 #include <sys/socket.h>
1529 #endif
1530 ])
1531
1532 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1533         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1534 [#ifdef HAVE_SYS_TYPES_H
1535 #include <sys/types.h>
1536 #endif
1537 #ifdef HAVE_SYS_SOCKET_H
1538 #include <sys/socket.h>
1539 #endif
1540 #ifdef HAVE_LIMITS_H
1541 #include <limits.h>
1542 #endif
1543 #ifdef HAVE_LINUX_TYPES_H
1544 #include <linux/types.h>
1545 #endif
1546 #ifdef HAVE_NETINET_IN6_H
1547 #include <netinet/in6.h>
1548 #endif
1549 #ifdef HAVE_NETINET_IN_H
1550 #include <netinet/in.h>
1551 #endif])
1552
1553 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1554         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1555 [#ifdef HAVE_SYS_TYPES_H
1556 #include <sys/types.h>
1557 #endif
1558 #ifdef HAVE_SYS_SOCKET_H
1559 #include <sys/socket.h>
1560 #endif
1561 #ifdef HAVE_LIMITS_H
1562 #include <limits.h>
1563 #endif
1564 #ifdef HAVE_LINUX_TYPES_H
1565 #include <linux/types.h>
1566 #endif
1567 #ifdef HAVE_NETINET_IN6_H
1568 #include <netinet/in6.h>
1569 #endif
1570 #ifdef HAVE_NETINET_IN_H
1571 #include <netinet/in.h>
1572 #endif
1573 #ifdef HAVE_LINUX_IF_H
1574 #include <linux/if.h>
1575 #endif])
1576
1577 transparent_ok=0
1578 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1579   transparent_ok=1
1580 fi
1581 if test "x$linux_netfilter_ipv4" = "x1"; then
1582   transparent_ok=1
1583 fi
1584 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1585   transparent_ok=1
1586 fi
1587 if test "x$transparent_ok" = "x1"; then
1588   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1589 else
1590   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1591 fi
1592
1593 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1594 [#ifdef HAVE_SYS_TYPES_H
1595 #include <sys/types.h>
1596 #endif
1597 #ifdef HAVE_SYS_TIME_H
1598 #include <sys/time.h>
1599 #endif])
1600
1601 AC_CHECK_SIZEOF(char)
1602 AC_CHECK_SIZEOF(short)
1603 AC_CHECK_SIZEOF(int)
1604 AC_CHECK_SIZEOF(long)
1605 AC_CHECK_SIZEOF(long long)
1606 AC_CHECK_SIZEOF(__int64)
1607 AC_CHECK_SIZEOF(void *)
1608 AC_CHECK_SIZEOF(time_t)
1609 AC_CHECK_SIZEOF(size_t)
1610 AC_CHECK_SIZEOF(pid_t)
1611
1612 AC_CHECK_TYPES([uint, u_char, ssize_t])
1613
1614 AC_PC_FROM_UCONTEXT([:])
1615
1616 dnl used to include sockaddr_storage, but everybody has that.
1617 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1618 [#ifdef HAVE_SYS_TYPES_H
1619 #include <sys/types.h>
1620 #endif
1621 #ifdef HAVE_NETINET_IN_H
1622 #include <netinet/in.h>
1623 #endif
1624 #ifdef HAVE_NETINET_IN6_H
1625 #include <netinet/in6.h>
1626 #endif
1627 #ifdef HAVE_SYS_SOCKET_H
1628 #include <sys/socket.h>
1629 #endif
1630 #ifdef _WIN32
1631 #define _WIN32_WINNT 0x0501
1632 #define WIN32_LEAN_AND_MEAN
1633 #include <winsock2.h>
1634 #include <ws2tcpip.h>
1635 #endif
1636 ])
1637 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1638 [#ifdef HAVE_SYS_TYPES_H
1639 #include <sys/types.h>
1640 #endif
1641 #ifdef HAVE_NETINET_IN_H
1642 #include <netinet/in.h>
1643 #endif
1644 #ifdef HAVE_NETINET_IN6_H
1645 #include <netinet/in6.h>
1646 #endif
1647 #ifdef HAVE_SYS_SOCKET_H
1648 #include <sys/socket.h>
1649 #endif
1650 #ifdef _WIN32
1651 #define _WIN32_WINNT 0x0501
1652 #define WIN32_LEAN_AND_MEAN
1653 #include <winsock2.h>
1654 #include <ws2tcpip.h>
1655 #endif
1656 ])
1657
1658 AC_CHECK_TYPES([rlim_t], , ,
1659 [#ifdef HAVE_SYS_TYPES_H
1660 #include <sys/types.h>
1661 #endif
1662 #ifdef HAVE_SYS_TIME_H
1663 #include <sys/time.h>
1664 #endif
1665 #ifdef HAVE_SYS_RESOURCE_H
1666 #include <sys/resource.h>
1667 #endif
1668 ])
1669
1670 AX_CHECK_SIGN([time_t],
1671        [ : ],
1672        [ : ], [
1673 #ifdef HAVE_SYS_TYPES_H
1674 #include <sys/types.h>
1675 #endif
1676 #ifdef HAVE_SYS_TIME_H
1677 #include <sys/time.h>
1678 #endif
1679 #ifdef HAVE_TIME_H
1680 #include <time.h>
1681 #endif
1682 ])
1683
1684 if test "$ax_cv_decl_time_t_signed" = "no"; then
1685   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1686 fi
1687
1688 AX_CHECK_SIGN([size_t],
1689        [ tor_cv_size_t_signed=yes ],
1690        [ tor_cv_size_t_signed=no ], [
1691 #ifdef HAVE_SYS_TYPES_H
1692 #include <sys/types.h>
1693 #endif
1694 ])
1695
1696 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1697   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1698 fi
1699
1700 AX_CHECK_SIGN([enum always],
1701        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1702        [ : ], [
1703  enum always { AAA, BBB, CCC };
1704 ])
1705
1706 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1707 #ifdef HAVE_SYS_SOCKET_H
1708 #include <sys/socket.h>
1709 #endif
1710 ])
1711
1712 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1713
1714 AC_CHECK_SIZEOF(cell_t)
1715
1716 # Let's see if stdatomic works. (There are some debian clangs that screw it
1717 # up; see Tor bug #26779 and debian bug 903709.)
1718 AC_CACHE_CHECK([whether C11 stdatomic.h actually works],
1719                tor_cv_stdatomic_works,
1720 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1721 #include <stdatomic.h>
1722 struct x { atomic_size_t y; };
1723 void try_atomic_init(struct x *xx)
1724 {
1725   atomic_init(&xx->y, 99);
1726   atomic_fetch_add(&xx->y, 1);
1727 }
1728 ]])], [tor_cv_stdatomic_works=yes], [tor_cv_stdatomic_works=no])])
1729
1730 if test "$tor_cv_stdatomic_works" = "yes"; then
1731    AC_DEFINE(STDATOMIC_WORKS, 1, [Set to 1 if we can compile a simple stdatomic example.])
1732 elif test "$ac_cv_header_stdatomic_h" = "yes"; then
1733    AC_MSG_WARN([Your compiler provides the stdatomic.h header, but it doesn't seem to work.  I'll pretend it isn't there. If you are using Clang on Debian, maybe this is because of https://bugs.debian.org/903709 ])
1734 fi
1735
1736 # Now make sure that NULL can be represented as zero bytes.
1737 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1738 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1739 [[#include <stdlib.h>
1740 #include <string.h>
1741 #include <stdio.h>
1742 #ifdef HAVE_STDDEF_H
1743 #include <stddef.h>
1744 #endif
1745 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1746 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1747        [tor_cv_null_is_zero=yes],
1748        [tor_cv_null_is_zero=no],
1749        [tor_cv_null_is_zero=cross])])
1750
1751 if test "$tor_cv_null_is_zero" = "cross"; then
1752   # Cross-compiling; let's hope that the target isn't raving mad.
1753   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1754 fi
1755
1756 if test "$tor_cv_null_is_zero" != "no"; then
1757   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1758             [Define to 1 iff memset(0) sets pointers to NULL])
1759 fi
1760
1761 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1762 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1763 [[#include <stdlib.h>
1764 #include <string.h>
1765 #include <stdio.h>
1766 #ifdef HAVE_STDDEF_H
1767 #include <stddef.h>
1768 #endif
1769 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1770 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1771        [tor_cv_dbl0_is_zero=yes],
1772        [tor_cv_dbl0_is_zero=no],
1773        [tor_cv_dbl0_is_zero=cross])])
1774
1775 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1776   # Cross-compiling; let's hope that the target isn't raving mad.
1777   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1778 fi
1779
1780 if test "$tor_cv_dbl0_is_zero" != "no"; then
1781   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1782             [Define to 1 iff memset(0) sets doubles to 0.0])
1783 fi
1784
1785 # And what happens when we malloc zero?
1786 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1787 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1788 [[#include <stdlib.h>
1789 #include <string.h>
1790 #include <stdio.h>
1791 #ifdef HAVE_STDDEF_H
1792 #include <stddef.h>
1793 #endif
1794 int main () { return malloc(0)?0:1; }]])],
1795        [tor_cv_malloc_zero_works=yes],
1796        [tor_cv_malloc_zero_works=no],
1797        [tor_cv_malloc_zero_works=cross])])
1798
1799 if test "$tor_cv_malloc_zero_works" = "cross"; then
1800   # Cross-compiling; let's hope that the target isn't raving mad.
1801   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1802 fi
1803
1804 if test "$tor_cv_malloc_zero_works" = "yes"; then
1805   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1806             [Define to 1 iff malloc(0) returns a pointer])
1807 fi
1808
1809 # whether we seem to be in a 2s-complement world.
1810 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1811 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1812 [[int main () { int problem = ((-99) != (~99)+1);
1813 return problem ? 1 : 0; }]])],
1814        [tor_cv_twos_complement=yes],
1815        [tor_cv_twos_complement=no],
1816        [tor_cv_twos_complement=cross])])
1817
1818 if test "$tor_cv_twos_complement" = "cross"; then
1819   # Cross-compiling; let's hope that the target isn't raving mad.
1820   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1821 fi
1822
1823 if test "$tor_cv_twos_complement" != "no"; then
1824   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1825             [Define to 1 iff we represent negative integers with
1826              two's complement])
1827 fi
1828
1829 # What does shifting a negative value do?
1830 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1831 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1832 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1833        [tor_cv_sign_extend=yes],
1834        [tor_cv_sign_extend=no],
1835        [tor_cv_sign_extend=cross])])
1836
1837 if test "$tor_cv_sign_extend" = "cross"; then
1838   # Cross-compiling; let's hope that the target isn't raving mad.
1839   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1840 fi
1841
1842 if test "$tor_cv_sign_extend" != "no"; then
1843   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1844             [Define to 1 iff right-shifting a negative value performs sign-extension])
1845 fi
1846
1847 # Is uint8_t the same type as unsigned char?
1848 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1849 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1850 #include <stdint.h>
1851 extern uint8_t c;
1852 unsigned char c;]])],
1853        [tor_cv_uint8_uchar=yes],
1854        [tor_cv_uint8_uchar=no],
1855        [tor_cv_uint8_uchar=cross])])
1856
1857 if test "$tor_cv_uint8_uchar" = "cross"; then
1858   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1859 fi
1860
1861 if test "$tor_cv_uint8_uchar" = "no"; then
1862   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1863 fi
1864
1865 AC_ARG_WITH(tcmalloc,
1866 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library. Deprecated; see --with-malloc]),
1867 [ tcmalloc=yes ], [ tcmalloc=no ])
1868
1869 default_malloc=system
1870
1871 if test "x$enable_openbsd_malloc" = "xyes" ; then
1872   AC_MSG_NOTICE([The --enable-openbsd-malloc argument is deprecated; use --with-malloc=openbsd instead.])
1873   default_malloc=openbsd
1874 fi
1875
1876 if test "x$tcmalloc" = "xyes"; then
1877   AC_MSG_NOTICE([The --with-tcmalloc argument is deprecated; use --with-malloc=tcmalloc instead.])
1878   default_malloc=tcmalloc
1879 fi
1880
1881 AC_ARG_WITH(malloc,
1882    AS_HELP_STRING([--with-malloc=[system,jemalloc,tcmalloc,openbsd]],
1883                   [select special malloc implementation [system]]),
1884    [ malloc="$with_malloc" ], [ malloc="$default_malloc" ])
1885
1886 AS_CASE([$malloc],
1887   [tcmalloc], [
1888       PKG_CHECK_MODULES([TCMALLOC],
1889                         [libtcmalloc],
1890                         have_tcmalloc=yes,
1891                         have_tcmalloc=no)
1892
1893       if test "x$have_tcmalloc" = "xno" ; then
1894           AC_MSG_ERROR([Unable to find tcmalloc requested by --with-malloc.])
1895       fi
1896
1897       CFLAGS="$CFLAGS $TCMALLOC_CFLAGS"
1898       LIBS="$TCMALLOC_LIBS $LIBS"
1899   ],
1900
1901   [jemalloc], [
1902       PKG_CHECK_MODULES([JEMALLOC],
1903                         [jemalloc],
1904                         have_jemalloc=yes,
1905                         have_jemalloc=no)
1906
1907       if test "x$have_tcmalloc" = "xno" ; then
1908           AC_MSG_ERROR([Unable to find jemalloc requested by --with-malloc.])
1909       fi
1910
1911       CFLAGS="$CFLAGS $JEMALLOC_CFLAGS"
1912       LIBS="$JEMALLOC_LIBS $LIBS"
1913       using_custom_malloc=yes
1914   ],
1915
1916   [openbsd], [
1917     AC_MSG_WARN([The openbsd malloc port is deprecated in Tor 0.3.5 and will be removed in a future version.])
1918     enable_openbsd_malloc=yes
1919   ],
1920
1921   [system], [
1922      # handle this later, including the jemalloc fallback
1923     AC_CHECK_FUNCS(mallinfo)
1924   ],
1925
1926   [AC_MSG_ERROR([--with-malloc=`$with_malloc' not supported, see --help])
1927 ])
1928
1929 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
1930
1931 if test "$malloc" != "system"; then
1932   # Tell the C compiler not to use the system allocator functions.
1933   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
1934 fi
1935 if test "$using_custom_malloc" = "yes"; then
1936   # Tell the C compiler not to use the system allocator functions.
1937   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
1938 fi
1939
1940 # By default, we're going to assume we don't have mlockall()
1941 # bionic and other platforms have various broken mlockall subsystems.
1942 # Some systems don't have a working mlockall, some aren't linkable,
1943 # and some have it but don't declare it.
1944 AC_CHECK_FUNCS(mlockall)
1945 AC_CHECK_DECLS([mlockall], , , [
1946 #ifdef HAVE_SYS_MMAN_H
1947 #include <sys/mman.h>
1948 #endif])
1949
1950 # Allow user to specify an alternate syslog facility
1951 AC_ARG_WITH(syslog-facility,
1952 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1953 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1954 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1955 AC_SUBST(LOGFACILITY)
1956
1957 # Check if we have getresuid and getresgid
1958 AC_CHECK_FUNCS(getresuid getresgid)
1959
1960 # Check for gethostbyname_r in all its glorious incompatible versions.
1961 #   (This logic is based on that in Python's configure.in)
1962 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1963   [Define this if you have any gethostbyname_r()])
1964
1965 AC_CHECK_FUNC(gethostbyname_r, [
1966   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1967   OLD_CFLAGS=$CFLAGS
1968   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1969   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1970 #include <netdb.h>
1971   ]], [[
1972     char *cp1, *cp2;
1973     struct hostent *h1, *h2;
1974     int i1, i2;
1975     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1976   ]])],[
1977     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1978     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1979      [Define this if gethostbyname_r takes 6 arguments])
1980     AC_MSG_RESULT(6)
1981   ], [
1982     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1983 #include <netdb.h>
1984     ]], [[
1985       char *cp1, *cp2;
1986       struct hostent *h1;
1987       int i1, i2;
1988       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1989     ]])], [
1990       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1991       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1992         [Define this if gethostbyname_r takes 5 arguments])
1993       AC_MSG_RESULT(5)
1994    ], [
1995       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1996 #include <netdb.h>
1997      ]], [[
1998        char *cp1;
1999        struct hostent *h1;
2000        struct hostent_data hd;
2001        (void) gethostbyname_r(cp1,h1,&hd);
2002      ]])], [
2003        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
2004        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
2005          [Define this if gethostbyname_r takes 3 arguments])
2006        AC_MSG_RESULT(3)
2007      ], [
2008        AC_MSG_RESULT(0)
2009      ])
2010   ])
2011  ])
2012  CFLAGS=$OLD_CFLAGS
2013 ])
2014
2015 AC_CACHE_CHECK([whether the C compiler supports __func__],
2016   tor_cv_have_func_macro,
2017   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2018 #include <stdio.h>
2019 int main(int c, char **v) { puts(__func__); }])],
2020   tor_cv_have_func_macro=yes,
2021   tor_cv_have_func_macro=no))
2022
2023 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
2024   tor_cv_have_FUNC_macro,
2025   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2026 #include <stdio.h>
2027 int main(int c, char **v) { puts(__FUNC__); }])],
2028   tor_cv_have_FUNC_macro=yes,
2029   tor_cv_have_FUNC_macro=no))
2030
2031 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
2032   tor_cv_have_FUNCTION_macro,
2033   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2034 #include <stdio.h>
2035 int main(int c, char **v) { puts(__FUNCTION__); }])],
2036   tor_cv_have_FUNCTION_macro=yes,
2037   tor_cv_have_FUNCTION_macro=no))
2038
2039 AC_CACHE_CHECK([whether we have extern char **environ already declared],
2040   tor_cv_have_environ_declared,
2041   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2042 #ifdef HAVE_UNISTD_H
2043 #include <unistd.h>
2044 #endif
2045 #include <stdlib.h>
2046 int main(int c, char **v) { char **t = environ; }])],
2047   tor_cv_have_environ_declared=yes,
2048   tor_cv_have_environ_declared=no))
2049
2050 if test "$tor_cv_have_func_macro" = "yes"; then
2051   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
2052 fi
2053
2054 if test "$tor_cv_have_FUNC_macro" = "yes"; then
2055   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
2056 fi
2057
2058 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
2059   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
2060            [Defined if the compiler supports __FUNCTION__])
2061 fi
2062
2063 if test "$tor_cv_have_environ_declared" = "yes"; then
2064   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
2065            [Defined if we have extern char **environ already declared])
2066 fi
2067
2068 # $prefix stores the value of the --prefix command line option, or
2069 # NONE if the option wasn't set.  In the case that it wasn't set, make
2070 # it be the default, so that we can use it to expand directories now.
2071 if test "x$prefix" = "xNONE"; then
2072   prefix=$ac_default_prefix
2073 fi
2074
2075 # and similarly for $exec_prefix
2076 if test "x$exec_prefix" = "xNONE"; then
2077   exec_prefix=$prefix
2078 fi
2079
2080 if test "x$BUILDDIR" = "x"; then
2081   BUILDDIR=`pwd`
2082 fi
2083 AC_SUBST(BUILDDIR)
2084 AH_TEMPLATE([BUILDDIR],[tor's build directory])
2085 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
2086
2087 if test "x$SRCDIR" = "x"; then
2088   SRCDIR=$(cd "$srcdir"; pwd)
2089 fi
2090 AH_TEMPLATE([SRCDIR],[tor's sourcedir directory])
2091 AC_DEFINE_UNQUOTED(SRCDIR,"$SRCDIR")
2092
2093 if test "x$CONFDIR" = "x"; then
2094   CONFDIR=`eval echo $sysconfdir/tor`
2095 fi
2096 AC_SUBST(CONFDIR)
2097 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
2098 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
2099
2100 BINDIR=`eval echo $bindir`
2101 AC_SUBST(BINDIR)
2102 LOCALSTATEDIR=`eval echo $localstatedir`
2103 AC_SUBST(LOCALSTATEDIR)
2104
2105 if test "$bwin32" = "true"; then
2106   # Test if the linker supports the --nxcompat and --dynamicbase options
2107   # for Windows
2108   save_LDFLAGS="$LDFLAGS"
2109   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
2110   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
2111   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
2112     [AC_MSG_RESULT([yes])]
2113     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
2114     [AC_MSG_RESULT([no])]
2115   )
2116   LDFLAGS="$save_LDFLAGS"
2117 fi
2118
2119 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
2120 # than autoconf's macros like.
2121 if test "$GCC" = "yes"; then
2122   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
2123   # accident waiting to happen.
2124   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
2125 else
2126   # Override optimization level for non-gcc compilers
2127   CFLAGS="$CFLAGS -O"
2128   enable_gcc_warnings=no
2129   enable_gcc_warnings_advisory=no
2130 fi
2131
2132 # Warnings implies advisory-warnings and -Werror.
2133 if test "$enable_gcc_warnings" = "yes"; then
2134   enable_gcc_warnings_advisory=yes
2135   enable_fatal_warnings=yes
2136 fi
2137
2138 # OS X Lion started deprecating the system openssl. Let's just disable
2139 # all deprecation warnings on OS X. Also, to potentially make the binary
2140 # a little smaller, let's enable dead_strip.
2141 case "$host_os" in
2142
2143  darwin*)
2144     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
2145     LDFLAGS="$LDFLAGS -dead_strip" ;;
2146 esac
2147
2148 TOR_WARNING_FLAGS=""
2149
2150 # Add some more warnings which we use in development but not in the
2151 # released versions.  (Some relevant gcc versions can't handle these.)
2152 #
2153 # Note that we have to do this near the end  of the autoconf process, or
2154 # else we may run into problems when these warnings hit on the testing C
2155 # programs that autoconf wants to build.
2156 if test "x$enable_gcc_warnings_advisory" != "xno"; then
2157
2158   case "$host" in
2159     *-*-openbsd* | *-*-bitrig*)
2160       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
2161       # That's fine, except that the headers don't pass -Wredundant-decls.
2162       # Therefore, let's disable -Wsystem-headers when we're building
2163       # with maximal warnings on OpenBSD.
2164       CFLAGS="$CFLAGS -Wno-system-headers" ;;
2165   esac
2166
2167   CFLAGS_NOWARNINGS="$CFLAGS"
2168
2169   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
2170   # have it work better.
2171   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
2172
2173   # This warning was added in gcc 4.3, but it appears to generate
2174   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
2175   #CFLAGS="$CFLAGS -Wlogical-op"
2176
2177   m4_foreach_w([warning_flag], [
2178      -Waddress
2179      -Waddress-of-array-temporary
2180      -Waddress-of-temporary
2181      -Wambiguous-macro
2182      -Wanonymous-pack-parens
2183      -Warc
2184      -Warc-abi
2185      -Warc-bridge-casts-disallowed-in-nonarc
2186      -Warc-maybe-repeated-use-of-weak
2187      -Warc-performSelector-leaks
2188      -Warc-repeated-use-of-weak
2189      -Warray-bounds
2190      -Warray-bounds-pointer-arithmetic
2191      -Wasm
2192      -Wasm-operand-widths
2193      -Watomic-properties
2194      -Watomic-property-with-user-defined-accessor
2195      -Wauto-import
2196      -Wauto-storage-class
2197      -Wauto-var-id
2198      -Wavailability
2199      -Wbackslash-newline-escape
2200      -Wbad-array-new-length
2201      -Wbind-to-temporary-copy
2202      -Wbitfield-constant-conversion
2203      -Wbool-conversion
2204      -Wbool-conversions
2205      -Wbuiltin-requires-header
2206      -Wchar-align
2207      -Wcompare-distinct-pointer-types
2208      -Wcomplex-component-init
2209      -Wconditional-type-mismatch
2210      -Wconfig-macros
2211      -Wconstant-conversion
2212      -Wconstant-logical-operand
2213      -Wconstexpr-not-const
2214      -Wcustom-atomic-properties
2215      -Wdangling-field
2216      -Wdangling-initializer-list
2217      -Wdate-time
2218      -Wdelegating-ctor-cycles
2219      -Wdeprecated-implementations
2220      -Wdeprecated-register
2221      -Wdirect-ivar-access
2222      -Wdiscard-qual
2223      -Wdistributed-object-modifiers
2224      -Wdivision-by-zero
2225      -Wdollar-in-identifier-extension
2226      -Wdouble-promotion
2227      -Wduplicate-decl-specifier
2228      -Wduplicate-enum
2229      -Wduplicate-method-arg
2230      -Wduplicate-method-match
2231      -Wduplicated-cond
2232      -Wdynamic-class-memaccess
2233      -Wembedded-directive
2234      -Wempty-translation-unit
2235      -Wenum-conversion
2236      -Wexit-time-destructors
2237      -Wexplicit-ownership-type
2238      -Wextern-initializer
2239      -Wextra
2240      -Wextra-semi
2241      -Wextra-tokens
2242      -Wflexible-array-extensions
2243      -Wfloat-conversion
2244      -Wformat-non-iso
2245      -Wfour-char-constants
2246      -Wgcc-compat
2247      -Wglobal-constructors
2248      -Wgnu-array-member-paren-init
2249      -Wgnu-designator
2250      -Wgnu-static-float-init
2251      -Wheader-guard
2252      -Wheader-hygiene
2253      -Widiomatic-parentheses
2254      -Wignored-attributes
2255      -Wimplicit-atomic-properties
2256      -Wimplicit-conversion-floating-point-to-bool
2257      -Wimplicit-exception-spec-mismatch
2258      -Wimplicit-fallthrough
2259      -Wimplicit-fallthrough-per-function
2260      -Wimplicit-retain-self
2261      -Wimport-preprocessor-directive-pedantic
2262      -Wincompatible-library-redeclaration
2263      -Wincompatible-pointer-types-discards-qualifiers
2264      -Wincomplete-implementation
2265      -Wincomplete-module
2266      -Wincomplete-umbrella
2267      -Winit-self
2268      -Wint-conversions
2269      -Wint-to-void-pointer-cast
2270      -Winteger-overflow
2271      -Winvalid-constexpr
2272      -Winvalid-iboutlet
2273      -Winvalid-noreturn
2274      -Winvalid-pp-token
2275      -Winvalid-source-encoding
2276      -Winvalid-token-paste
2277      -Wknr-promoted-parameter
2278      -Wlarge-by-value-copy
2279      -Wliteral-conversion
2280      -Wliteral-range
2281      -Wlocal-type-template-args
2282      -Wlogical-op
2283      -Wloop-analysis
2284      -Wmain-return-type
2285      -Wmalformed-warning-check
2286      -Wmethod-signatures
2287      -Wmicrosoft
2288      -Wmicrosoft-exists
2289      -Wmismatched-parameter-types
2290      -Wmismatched-return-types
2291      -Wmissing-field-initializers
2292      -Wmissing-format-attribute
2293      -Wmissing-noreturn
2294      -Wmissing-selector-name
2295      -Wmissing-sysroot
2296      -Wmissing-variable-declarations
2297      -Wmodule-conflict
2298      -Wnested-anon-types
2299      -Wnewline-eof
2300      -Wnon-literal-null-conversion
2301      -Wnon-pod-varargs
2302      -Wnonportable-cfstrings
2303      -Wnormalized=nfkc
2304      -Wnull-arithmetic
2305      -Wnull-character
2306      -Wnull-conversion
2307      -Wnull-dereference
2308      -Wout-of-line-declaration
2309      -Wover-aligned
2310      -Woverlength-strings
2311      -Woverride-init
2312      -Woverriding-method-mismatch
2313      -Wpointer-type-mismatch
2314      -Wpredefined-identifier-outside-function
2315      -Wprotocol-property-synthesis-ambiguity
2316      -Wreadonly-iboutlet-property
2317      -Wreadonly-setter-attrs
2318      -Wreceiver-expr
2319      -Wreceiver-forward-class
2320      -Wreceiver-is-weak
2321      -Wreinterpret-base-class
2322      -Wrequires-super-attribute
2323      -Wreserved-user-defined-literal
2324      -Wreturn-stack-address
2325      -Wsection
2326      -Wselector-type-mismatch
2327      -Wsentinel
2328      -Wserialized-diagnostics
2329      -Wshadow
2330      -Wshift-count-negative
2331      -Wshift-count-overflow
2332      -Wshift-negative-value
2333      -Wshift-overflow=2
2334      -Wshift-sign-overflow
2335      -Wshorten-64-to-32
2336      -Wsizeof-array-argument
2337      -Wsource-uses-openmp
2338      -Wstatic-float-init
2339      -Wstatic-in-inline
2340      -Wstatic-local-in-inline
2341      -Wstrict-overflow=1
2342      -Wstring-compare
2343      -Wstring-conversion
2344      -Wstrlcpy-strlcat-size
2345      -Wstrncat-size
2346      -Wsuggest-attribute=format
2347      -Wsuggest-attribute=noreturn
2348      -Wsuper-class-method-mismatch
2349      -Wswitch-bool
2350      -Wsync-nand
2351      -Wtautological-constant-out-of-range-compare
2352      -Wtentative-definition-incomplete-type
2353      -Wtrampolines
2354      -Wtype-safety
2355      -Wtypedef-redefinition
2356      -Wtypename-missing
2357      -Wundefined-inline
2358      -Wundefined-internal
2359      -Wundefined-reinterpret-cast
2360      -Wunicode
2361      -Wunicode-whitespace
2362      -Wunknown-warning-option
2363      -Wunnamed-type-template-args
2364      -Wunneeded-member-function
2365      -Wunsequenced
2366      -Wunsupported-visibility
2367      -Wunused-but-set-parameter
2368      -Wunused-but-set-variable
2369      -Wunused-command-line-argument
2370      -Wunused-const-variable=2
2371      -Wunused-exception-parameter
2372      -Wunused-local-typedefs
2373      -Wunused-member-function
2374      -Wunused-sanitize-argument
2375      -Wunused-volatile-lvalue
2376      -Wuser-defined-literals
2377      -Wvariadic-macros
2378      -Wvector-conversion
2379      -Wvector-conversions
2380      -Wvexing-parse
2381      -Wvisibility
2382      -Wvla-extension
2383      -Wzero-length-array
2384   ], [ TOR_TRY_COMPILE_WITH_CFLAGS(warning_flag, [],
2385               [TOR_WARNING_FLAGS="$TOR_WARNING_FLAGS warning_flag" CFLAGS="$CFLAGS warning_flag"], true)
2386      ])
2387
2388 dnl    We should re-enable this in some later version.  Clang doesn't
2389 dnl    mind, but it causes trouble with GCC.
2390 dnl     -Wstrict-overflow=2
2391
2392 dnl    These seem to require annotations that we don't currently use,
2393 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2394 dnl     -Wthread-safety
2395 dnl     -Wthread-safety-analysis
2396 dnl     -Wthread-safety-attributes
2397 dnl     -Wthread-safety-beta
2398 dnl     -Wthread-safety-precise
2399
2400   W_FLAGS="$W_FLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2401   W_FLAGS="$W_FLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2402   W_FLAGS="$W_FLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2403   W_FLAGS="$W_FLAGS -Wwrite-strings"
2404   W_FLAGS="$W_FLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2405   W_FLAGS="$W_FLAGS -Waggregate-return -Wpacked -Wunused"
2406   W_FLAGS="$W_FLAGS -Wunused-parameter "
2407   # These interfere with building main() { return 0; }, which autoconf
2408   # likes to use as its default program.
2409   W_FLAGS="$W_FLAGS -Wold-style-definition -Wmissing-declarations"
2410
2411   TOR_WARNING_FLAGS="$TOR_WARNING_FLAGS $W_FLAGS"
2412   CFLAGS="$CFLAGS $W_FLAGS"
2413
2414   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2415     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2416   fi
2417   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2418     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2419   fi
2420   if test "$tor_cv_cflags__warn_unused_const_variable_2" = "yes"; then
2421     AC_DEFINE([HAVE_CFLAG_WUNUSED_CONST_VARIABLE], 1, [True if we have -Wunused-const-variable])
2422   fi
2423
2424   CFLAGS="$CFLAGS_NOWARNINGS"
2425
2426   if test "x$enable_fatal_warnings" = "xyes"; then
2427     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2428     # default autoconf programs are full of errors.
2429     CFLAGS="$CFLAGS -Werror"
2430   fi
2431
2432 fi
2433
2434 AC_SUBST(TOR_WARNING_FLAGS)
2435
2436 echo "$TOR_WARNING_FLAGS">warning_flags
2437
2438 TOR_TRY_COMPILE_WITH_CFLAGS([@warning_flags], [],
2439                             CFLAGS="$CFLAGS @warning_flags",
2440                             CFLAGS="$CFLAGS $TOR_WARNING_FLAGS")
2441
2442 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2443    case "$host_os" in
2444     darwin*)
2445       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2446    esac
2447 fi
2448
2449 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2450
2451 AC_CONFIG_FILES([
2452         Doxyfile
2453         Makefile
2454         config.rust
2455         contrib/dist/suse/tor.sh
2456         contrib/operator-tools/tor.logrotate
2457         contrib/dist/tor.sh
2458         contrib/dist/torctl
2459         contrib/dist/tor.service
2460         src/config/torrc.sample
2461         src/config/torrc.minimal
2462         src/rust/.cargo/config
2463         scripts/maint/checkOptionDocs.pl
2464         scripts/maint/updateVersions.pl
2465         warning_flags
2466 ])
2467
2468 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2469   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2470   for file in $regular_mans ; do
2471     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2472       echo "==================================";
2473       echo;
2474       echo "Building Tor has failed since manpages cannot be built.";
2475       echo;
2476       echo "You need asciidoc installed to be able to build the manpages.";
2477       echo "To build without manpages, use the --disable-asciidoc argument";
2478       echo "when calling configure.";
2479       echo;
2480       echo "==================================";
2481       exit 1;
2482     fi
2483   done
2484 fi
2485
2486 if test "$fragile_hardening" = "yes"; then
2487   AC_MSG_WARN([
2488
2489 ============
2490 Warning!  Building Tor with --enable-fragile-hardening (also known as
2491 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2492 other kinds of attacks easier. A Tor instance build with this option will be
2493 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2494 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2495 denial of service attacks. For more information, see
2496 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2497 ============
2498   ])
2499 fi
2500
2501 AC_OUTPUT