configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2018, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.5.0-alpha-dev])
   8 AC_CONFIG_SRCDIR([src/app/main/tor_main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 AC_ARG_ENABLE(openbsd-malloc,
  25    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only. Deprecated: see --with-malloc]))
  26 AC_ARG_ENABLE(static-openssl,
  27    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  28 AC_ARG_ENABLE(static-libevent,
  29    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  30 AC_ARG_ENABLE(static-zlib,
  31    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  32 AC_ARG_ENABLE(static-tor,
  33    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  34 AC_ARG_ENABLE(unittests,
  35    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  36 AC_ARG_ENABLE(coverage,
  37    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  38 AC_ARG_ENABLE(asserts-in-tests,
  39    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  40 AC_ARG_ENABLE(system-torrc,
  41    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  42 AC_ARG_ENABLE(libfuzzer,
  43    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  44 AC_ARG_ENABLE(oss-fuzz,
  45    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  46 AC_ARG_ENABLE(memory-sentinels,
  47    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  48 AC_ARG_ENABLE(rust,
  49    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  50 AC_ARG_ENABLE(cargo-online-mode,
  51    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  52 AC_ARG_ENABLE(restart-debugging,
  53    AS_HELP_STRING(--enable-restart-debugging, [Build Tor with support for debugging in-process restart. Developers only.]))
  54 AC_ARG_ENABLE(zstd-advanced-apis,
  55    AS_HELP_STRING(--disable-zstd-advanced-apis, [Build without support for zstd's "static-only" APIs.]))
  56
  57 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  58     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  59 fi
  60
  61 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  62 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  63 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  64 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  65 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  66 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  67
  68 if test "$enable_static_tor" = "yes"; then
  69   enable_static_libevent="yes";
  70   enable_static_openssl="yes";
  71   enable_static_zlib="yes";
  72   CFLAGS="$CFLAGS -static"
  73 fi
  74
  75 if test "$enable_system_torrc" = "no"; then
  76   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  77             [Defined if we're not going to look for a torrc in SYSCONF])
  78 fi
  79
  80 if test "$enable_memory_sentinels" = "no"; then
  81   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  82            [Defined if we're turning off memory safety code to look for bugs])
  83 fi
  84
  85 AC_ARG_ENABLE(asciidoc,
  86      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  87      [case "${enableval}" in
  88         "yes") asciidoc=true ;;
  89         "no")  asciidoc=false ;;
  90         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  91       esac], [asciidoc=true])
  92
  93 # systemd notify support
  94 AC_ARG_ENABLE(systemd,
  95       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  96       [case "${enableval}" in
  97         "yes") systemd=true ;;
  98         "no")  systemd=false ;;
  99         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 100       esac], [systemd=auto])
 101
 102 if test "$enable_restart_debugging" = "yes"; then
 103   AC_DEFINE(ENABLE_RESTART_DEBUGGING, 1,
 104             [Defined if we're building with support for in-process restart debugging.])
 105 fi
 106
 107 if test "$enable_zstd_advanced_apis" != "no"; then
 108    AC_DEFINE(ENABLE_ZSTD_ADVANCED_APIS, 1,
 109              [Defined if we're going to try to use zstd's "static-only" APIs.])
 110 fi
 111
 112 # systemd support
 113 if test "x$enable_systemd" = "xno"; then
 114     have_systemd=no;
 115 else
 116     PKG_CHECK_MODULES(SYSTEMD,
 117         [libsystemd-daemon],
 118         have_systemd=yes,
 119         have_systemd=no)
 120     if test "x$have_systemd" = "xno"; then
 121         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 122         PKG_CHECK_MODULES(SYSTEMD,
 123             [libsystemd],
 124             have_systemd=yes,
 125             have_systemd=no)
 126     fi
 127 fi
 128
 129 if test "x$have_systemd" = "xyes"; then
 130     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 131     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 132     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 133     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 134          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 135 fi
 136 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 137 AC_SUBST(TOR_SYSTEMD_LIBS)
 138
 139 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 140     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 141 fi
 142
 143 case "$host" in
 144    *-*-solaris* )
 145      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 146      ;;
 147 esac
 148
 149 AC_ARG_ENABLE(gcc-warnings,
 150      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 151 AC_ARG_ENABLE(fatal-warnings,
 152      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 153 AC_ARG_ENABLE(gcc-warnings-advisory,
 154      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 155
 156 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 157 AC_ARG_ENABLE(gcc-hardening,
 158     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 159
 160 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 161 AC_ARG_ENABLE(expensive-hardening,
 162     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 163 AC_ARG_ENABLE(fragile-hardening,
 164     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 165 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 166   fragile_hardening="yes"
 167   AC_DEFINE(DEBUG_SMARTLIST, 1, [Enable smartlist debugging])
 168 fi
 169
 170 dnl Linker hardening options
 171 dnl Currently these options are ELF specific - you can't use this with MacOSX
 172 AC_ARG_ENABLE(linker-hardening,
 173     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 174
 175 AC_ARG_ENABLE(local-appdata,
 176    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 177 if test "$enable_local_appdata" = "yes"; then
 178   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 179             [Defined if we default to host local appdata paths on Windows])
 180 fi
 181
 182 # Tor2web mode flag
 183 AC_ARG_ENABLE(tor2web-mode,
 184      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 185 [if test "x$enableval" = "xyes"; then
 186     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 187 fi])
 188
 189 AC_ARG_ENABLE(tool-name-check,
 190      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 191
 192 AC_ARG_ENABLE(seccomp,
 193      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 194
 195 AC_ARG_ENABLE(libscrypt,
 196      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 197
 198 dnl Enable event tracing which are transformed to debug log statement.
 199 AC_ARG_ENABLE(event-tracing-debug,
 200      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 201 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 202
 203 if test x$enable_event_tracing_debug = xyes; then
 204   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 205   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 206 fi
 207
 208 dnl Enable Android only features.
 209 AC_ARG_ENABLE(android,
 210      AS_HELP_STRING(--enable-android, [build with Android features enabled]))
 211 AM_CONDITIONAL([USE_ANDROID], [test "x$enable_android" = "xyes"])
 212
 213 if test "x$enable_android" = "xyes"; then
 214   AC_DEFINE([USE_ANDROID], [1], [Compile with Android specific features enabled])
 215
 216   dnl Check if the Android log library is available.
 217   AC_CHECK_HEADERS([android/log.h])
 218   AC_SEARCH_LIBS(__android_log_write, [log])
 219
 220 fi
 221
 222 dnl ---
 223 dnl Tor modules options. These options are namespaced with --disable-module-XXX
 224 dnl ---
 225
 226 dnl All our modules.
 227 m4_define(MODULES, dirauth)
 228
 229 dnl Directory Authority module.
 230 AC_ARG_ENABLE([module-dirauth],
 231               AS_HELP_STRING([--disable-module-dirauth],
 232                              [Do not build tor with the dirauth module]),
 233               [], dnl Action if-given
 234               AC_DEFINE([HAVE_MODULE_DIRAUTH], [1],
 235                         [Compile with Directory Authority feature support]))
 236 AM_CONDITIONAL(BUILD_MODULE_DIRAUTH, [test "x$enable_module_dirauth" != "xno"])
 237
 238 dnl Helper variables.
 239 TOR_MODULES_ALL_ENABLED=
 240 AC_DEFUN([ADD_MODULE], [
 241     MODULE=m4_toupper($1)
 242     TOR_MODULES_ALL_ENABLED="${TOR_MODULES_ALL_ENABLED} -DHAVE_MODULE_${MODULE}=1"
 243 ])
 244 m4_foreach_w([module], MODULES, [ADD_MODULE([module])])
 245 AC_SUBST(TOR_MODULES_ALL_ENABLED)
 246
 247 dnl check for the correct "ar" when cross-compiling.
 248 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 249 dnl    so kludge up a replacement for the case where it isn't there yet.)
 250 m4_ifdef([AM_PROG_AR],
 251          [AM_PROG_AR],
 252          [AN_MAKEVAR([AR], [AC_PROG_AR])
 253           AN_PROGRAM([ar], [AC_PROG_AR])
 254           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 255           AC_PROG_AR])
 256
 257 dnl Check whether the above macro has settled for a simply named tool even
 258 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 259 dnl because that will find any cc on the system, not only the cross-compiler,
 260 dnl and then verify that a binary built with this compiler runs on the
 261 dnl build system. It will then come to the false conclusion that we're not
 262 dnl cross-compiling.
 263 if test "x$enable_tool_name_check" != "xno"; then
 264     if test "x$ac_tool_warned" = "xyes"; then
 265         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 266         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 267                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 268         fi
 269 fi
 270
 271 AC_PROG_CC
 272 AC_PROG_CPP
 273 AC_PROG_MAKE_SET
 274 AC_PROG_RANLIB
 275 AC_PROG_SED
 276
 277 AC_ARG_VAR([PERL], [path to Perl binary])
 278 AC_CHECK_PROGS([PERL], [perl])
 279 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 280
 281 dnl check for asciidoc and a2x
 282 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 283 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 284
 285 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 286
 287 AM_PROG_CC_C_O
 288 AC_PROG_CC_C99
 289
 290 AC_ARG_VAR([PYTHON], [path to Python binary])
 291 AC_CHECK_PROGS(PYTHON, [ \
 292         python3 \
 293         python3.8 python3.7 python3.6 python3.5 python3.4 \
 294         python \
 295         python2 python2.7])
 296 if test "x$PYTHON" = "x"; then
 297   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 298 fi
 299 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 300
 301 dnl List all external rust crates we depend on here. Include the version
 302 rust_crates=" \
 303     digest-0.7.2 \
 304     libc-0.2.39 \
 305 "
 306 AC_SUBST(rust_crates)
 307
 308 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 309 AC_C_FLEXIBLE_ARRAY_MEMBER
 310 ], [
 311  dnl Maybe we've got an old autoconf...
 312  AC_CACHE_CHECK([for flexible array members],
 313      tor_cv_c_flexarray,
 314      [AC_COMPILE_IFELSE(
 315        AC_LANG_PROGRAM([
 316  struct abc { int a; char b[]; };
 317 ], [
 318  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 319  def->b[0] = 33;
 320 ]),
 321   [tor_cv_c_flexarray=yes],
 322   [tor_cv_c_flexarray=no])])
 323  if test "$tor_cv_flexarray" = "yes"; then
 324    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 325  else
 326    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 327  fi
 328 ])
 329
 330 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 331       tor_cv_c_c99_decl,
 332       [AC_COMPILE_IFELSE(
 333          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 334          [tor_cv_c_c99_decl=yes],
 335          [tor_cv_c_c99_decl=no] )])
 336 if test "$tor_cv_c_c99_decl" != "yes"; then
 337   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 338 fi
 339
 340 AC_CACHE_CHECK([for working C99 designated initializers],
 341       tor_cv_c_c99_designated_init,
 342       [AC_COMPILE_IFELSE(
 343          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 344                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 345          [tor_cv_c_c99_designated_init=yes],
 346          [tor_cv_c_c99_designated_init=no] )])
 347
 348 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 349   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 350 fi
 351
 352 TORUSER=_tor
 353 AC_ARG_WITH(tor-user,
 354         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 355         [
 356            TORUSER=$withval
 357         ]
 358 )
 359 AC_SUBST(TORUSER)
 360
 361 TORGROUP=_tor
 362 AC_ARG_WITH(tor-group,
 363         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 364         [
 365            TORGROUP=$withval
 366         ]
 367 )
 368 AC_SUBST(TORGROUP)
 369
 370
 371 dnl If _WIN32 is defined and non-zero, we are building for win32
 372 AC_MSG_CHECKING([for win32])
 373 AC_RUN_IFELSE([AC_LANG_SOURCE([
 374 int main(int c, char **v) {
 375 #ifdef _WIN32
 376 #if _WIN32
 377   return 0;
 378 #else
 379   return 1;
 380 #endif
 381 #else
 382   return 2;
 383 #endif
 384 }])],
 385 bwin32=true; AC_MSG_RESULT([yes]),
 386 bwin32=false; AC_MSG_RESULT([no]),
 387 bwin32=cross; AC_MSG_RESULT([cross])
 388 )
 389
 390 if test "$bwin32" = "cross"; then
 391 AC_MSG_CHECKING([for win32 (cross)])
 392 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 393 #ifdef _WIN32
 394 int main(int c, char **v) {return 0;}
 395 #else
 396 #error
 397 int main(int c, char **v) {return x(y);}
 398 #endif
 399 ])],
 400 bwin32=true; AC_MSG_RESULT([yes]),
 401 bwin32=false; AC_MSG_RESULT([no]))
 402 fi
 403
 404 AH_BOTTOM([
 405 #ifdef _WIN32
 406 /* Defined to access windows functions and definitions for >=WinXP */
 407 # ifndef WINVER
 408 #  define WINVER 0x0501
 409 # endif
 410
 411 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 412 # ifndef _WIN32_WINNT
 413 #  define _WIN32_WINNT 0x0501
 414 # endif
 415
 416 /* Defined to avoid including some windows headers as part of Windows.h */
 417 # ifndef WIN32_LEAN_AND_MEAN
 418 #  define WIN32_LEAN_AND_MEAN 1
 419 # endif
 420 #endif
 421 ])
 422
 423 AM_CONDITIONAL(WIN32, test "x$bwin32" = "xtrue")
 424 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 425 AM_CONDITIONAL(BUILD_LIBTORRUNNER, test "x$bwin32" != "xtrue")
 426
 427 dnl Enable C99 when compiling with MIPSpro
 428 AC_MSG_CHECKING([for MIPSpro compiler])
 429 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 430 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 431 #error
 432   return x(y);
 433 #endif
 434 ])],
 435 bmipspro=false; AC_MSG_RESULT(no),
 436 bmipspro=true; AC_MSG_RESULT(yes))
 437
 438 if test "$bmipspro" = "true"; then
 439   CFLAGS="$CFLAGS -c99"
 440 fi
 441
 442 AC_C_BIGENDIAN
 443
 444 AC_ARG_VAR([TOR_RUST_TARGET], [Rust target, must be specified when cross-compiling (HOST != BUILD). example: i686-pc-windows-gnu])
 445
 446 if test "x$enable_rust" = "xyes"; then
 447   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 448   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 449   if test "x$RUSTC" = "xno"; then
 450     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 451   fi
 452
 453   AC_ARG_VAR([CARGO], [path to the cargo binary])
 454   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 455   if test "x$CARGO" = "xno"; then
 456     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 457   fi
 458
 459   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 460   if test "x$enable_fatal_warnings" = "xyes"; then
 461     RUST_WARN=
 462   else
 463     RUST_WARN=#
 464   fi
 465   if test "x$enable_cargo_online_mode" = "xyes"; then
 466     CARGO_ONLINE=
 467     RUST_DL=#
 468   else
 469     CARGO_ONLINE=--frozen
 470     RUST_DL=
 471
 472     dnl When we're not allowed to touch the network, we need crate dependencies
 473     dnl locally available.
 474     AC_MSG_CHECKING([rust crate dependencies])
 475     AC_ARG_VAR([TOR_RUST_DEPENDENCIES], [path to directory with local crate mirror])
 476     if test "x$TOR_RUST_DEPENDENCIES" = "x"; then
 477       TOR_RUST_DEPENDENCIES="${srcdir}/src/ext/rust/crates"
 478     fi
 479     dnl Check whether the path exists before we try to cd into it.
 480     if test ! -d "$TOR_RUST_DEPENDENCIES"; then
 481       AC_MSG_ERROR([Rust dependency directory $TOR_RUST_DEPENDENCIES does not exist. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 482       ERRORED=1
 483     fi
 484     dnl Make the path absolute, since we'll be using it from within a
 485     dnl subdirectory.
 486     TOR_RUST_DEPENDENCIES=$(cd "$TOR_RUST_DEPENDENCIES" ; pwd)
 487
 488     for dep in $rust_crates; do
 489       if test ! -d "$TOR_RUST_DEPENDENCIES"/"$dep"; then
 490         AC_MSG_ERROR([Failure to find rust dependency $TOR_RUST_DEPENDENCIES/$dep. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 491         ERRORED=1
 492       fi
 493     done
 494     if test "x$ERRORED" = "x"; then
 495       AC_MSG_RESULT([yes])
 496     fi
 497   fi
 498
 499   dnl This is a workaround for #46797
 500   dnl (a.k.a https://github.com/rust-lang/rust/issues/46797 ).  Once the
 501   dnl upstream bug is fixed, we can remove this workaround.
 502   case "$host_os" in
 503       darwin*)
 504         TOR_RUST_EXTRA_LIBS="-lresolv"
 505         ;;
 506   esac
 507
 508   dnl For now both MSVC and MinGW rust libraries will output static libs with
 509   dnl the MSVC naming convention.
 510   if test "$bwin32" = "true"; then
 511     tor_rust_static_name=tor_rust.lib
 512   else
 513     tor_rust_static_name=libtor_rust.a
 514   fi
 515
 516   AC_CANONICAL_BUILD
 517
 518   if test -n "$TOR_RUST_TARGET"; then
 519     if test "$host" = "$build"; then
 520       AC_MSG_ERROR([HOST = BUILD is invalid if TOR_RUST_TARGET is specified, see configure --help for more information.])
 521     fi
 522     RUST_TARGET_PROP="target = '$TOR_RUST_TARGET'"
 523     TOR_RUST_LIB_PATH="src/rust/target/$TOR_RUST_TARGET/release/$tor_rust_static_name"
 524   else
 525     if test "$host" != "$build"; then
 526       AC_MSG_ERROR([TOR_RUST_TARGET must be specified when cross-compiling with Rust enabled.])
 527     fi
 528     RUST_TARGET_PROP=
 529     TOR_RUST_LIB_PATH="src/rust/target/release/$tor_rust_static_name"
 530   fi
 531
 532   AC_SUBST(RUST_TARGET_PROP)
 533   AC_SUBST(TOR_RUST_LIB_PATH)
 534   AC_SUBST(CARGO_ONLINE)
 535   AC_SUBST(RUST_WARN)
 536   AC_SUBST(RUST_DL)
 537
 538   dnl Let's check the rustc version, too
 539   AC_MSG_CHECKING([rust version])
 540   RUSTC_VERSION=`$RUSTC --version`
 541   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 542   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 543   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 544     AC_MSG_ERROR([rustc version couldn't be identified])
 545   fi
 546   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 547     AC_MSG_ERROR([rustc must be at least version 1.14])
 548   fi
 549   AC_MSG_RESULT([$RUSTC_VERSION])
 550 fi
 551
 552 AC_SUBST(TOR_RUST_EXTRA_LIBS)
 553
 554 AC_SEARCH_LIBS(socket, [socket network])
 555 AC_SEARCH_LIBS(gethostbyname, [nsl])
 556 AC_SEARCH_LIBS(dlopen, [dl])
 557 AC_SEARCH_LIBS(inet_aton, [resolv])
 558 AC_SEARCH_LIBS(backtrace, [execinfo])
 559 saved_LIBS="$LIBS"
 560 AC_SEARCH_LIBS([clock_gettime], [rt])
 561 if test "$LIBS" != "$saved_LIBS"; then
 562    # Looks like we need -lrt for clock_gettime().
 563    have_rt=yes
 564 fi
 565
 566 AC_SEARCH_LIBS(pthread_create, [pthread])
 567 AC_SEARCH_LIBS(pthread_detach, [pthread])
 568
 569 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 570 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 571
 572 AC_CHECK_FUNCS(
 573         _NSGetEnviron \
 574         RtlSecureZeroMemory \
 575         SecureZeroMemory \
 576         accept4 \
 577         backtrace \
 578         backtrace_symbols_fd \
 579         eventfd \
 580         explicit_bzero \
 581         timingsafe_memcmp \
 582         flock \
 583         ftime \
 584         get_current_dir_name \
 585         getaddrinfo \
 586         getdelim \
 587         getifaddrs \
 588         getline \
 589         getpass \
 590         getrlimit \
 591         gettimeofday \
 592         gmtime_r \
 593         gnu_get_libc_version \
 594         htonll \
 595         inet_aton \
 596         ioctl \
 597         issetugid \
 598         llround \
 599         localtime_r \
 600         lround \
 601         memmem \
 602         memset_s \
 603         mmap \
 604         pipe \
 605         pipe2 \
 606         prctl \
 607         readpassphrase \
 608         rint \
 609         sigaction \
 610         socketpair \
 611         statvfs \
 612         strncasecmp \
 613         strcasecmp \
 614         strlcat \
 615         strlcpy \
 616         strnlen \
 617         strptime \
 618         strtok_r \
 619         strtoull \
 620         sysconf \
 621         sysctl \
 622         truncate \
 623         uname \
 624         usleep \
 625         vasprintf \
 626         _vscprintf
 627 )
 628
 629 # Apple messed up when they added some functions: they
 630 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 631 # checks.
 632
 633 # We should only probe for these functions if we are sure that we
 634 # are not targeting OS X 10.9 or earlier.
 635 AC_MSG_CHECKING([for a pre-Yosemite OS X build target])
 636 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 637 #ifdef __APPLE__
 638 #  include <AvailabilityMacros.h>
 639 #  ifndef MAC_OS_X_VERSION_10_10
 640 #    define MAC_OS_X_VERSION_10_10 101000
 641 #  endif
 642 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 643 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_10
 644 #      error "Running on Mac OS X 10.9 or earlier"
 645 #    endif
 646 #  endif
 647 #endif
 648 ]], [[]])],
 649    [on_macos_pre_10_10=no ; AC_MSG_RESULT([no])],
 650    [on_macos_pre_10_10=yes; AC_MSG_RESULT([yes])])
 651
 652 if test "$on_macos_pre_10_10" = "no"; then
 653   AC_CHECK_FUNCS(
 654         mach_approximate_time \
 655   )
 656 fi
 657
 658 # We should only probe for these functions if we are sure that we
 659 # are not targeting OSX 10.11 or earlier.
 660 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 661 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 662 #ifdef __APPLE__
 663 #  include <AvailabilityMacros.h>
 664 #  ifndef MAC_OS_X_VERSION_10_12
 665 #    define MAC_OS_X_VERSION_10_12 101200
 666 #  endif
 667 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 668 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 669 #      error "Running on Mac OSX 10.11 or earlier"
 670 #    endif
 671 #  endif
 672 #endif
 673 ]], [[]])],
 674    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 675    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 676
 677 if test "$on_macos_pre_10_12" = "no"; then
 678   AC_CHECK_FUNCS(
 679         clock_gettime \
 680         getentropy \
 681   )
 682 fi
 683
 684 if test "$bwin32" != "true"; then
 685   AC_CHECK_HEADERS(pthread.h)
 686   AC_CHECK_FUNCS(pthread_create)
 687   AC_CHECK_FUNCS(pthread_condattr_setclock)
 688 fi
 689
 690 if test "$bwin32" = "true"; then
 691   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 692 #include <windows.h>
 693 #include <conio.h>
 694 #include <wchar.h>
 695                  ])
 696 fi
 697
 698 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 699   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 700
 701 AC_MSG_CHECKING([whether free(NULL) works])
 702 AC_RUN_IFELSE([AC_LANG_PROGRAM([
 703   #include <stdlib.h>
 704 ], [
 705 char *p = NULL;
 706 free(p);
 707 ])],
 708 [free_null_ok=true; AC_MSG_RESULT(yes)],
 709 [free_null_ok=false; AC_MSG_RESULT(no)],
 710 [free_null_ok=cross; AC_MSG_RESULT(cross)])
 711
 712 if test "$free_null_ok" = "false"; then
 713    AC_MSG_ERROR([Your libc implementation doesn't allow free(NULL), as required by C99.])
 714 fi
 715
 716 dnl ------------------------------------------------------
 717 dnl Where do you live, libevent?  And how do we call you?
 718
 719 if test "$bwin32" = "true"; then
 720   TOR_LIB_WS32=-lws2_32
 721   TOR_LIB_IPHLPAPI=-liphlpapi
 722   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 723   # think it's actually necessary.
 724   TOR_LIB_GDI=-lgdi32
 725   TOR_LIB_USERENV=-luserenv
 726 else
 727   TOR_LIB_WS32=
 728   TOR_LIB_GDI=
 729   TOR_LIB_USERENV=
 730 fi
 731 AC_SUBST(TOR_LIB_WS32)
 732 AC_SUBST(TOR_LIB_GDI)
 733 AC_SUBST(TOR_LIB_IPHLPAPI)
 734 AC_SUBST(TOR_LIB_USERENV)
 735
 736 tor_libevent_pkg_redhat="libevent"
 737 tor_libevent_pkg_debian="libevent-dev"
 738 tor_libevent_devpkg_redhat="libevent-devel"
 739 tor_libevent_devpkg_debian="libevent-dev"
 740
 741 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 742 dnl linking for static builds.
 743 STATIC_LIBEVENT_FLAGS=""
 744 if test "$enable_static_libevent" = "yes"; then
 745     if test "$have_rt" = "yes"; then
 746       STATIC_LIBEVENT_FLAGS=" -lrt "
 747     fi
 748 fi
 749
 750 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 751 #ifdef _WIN32
 752 #include <winsock2.h>
 753 #endif
 754 #include <sys/time.h>
 755 #include <sys/types.h>
 756 #include <event2/event.h>], [
 757 #ifdef _WIN32
 758 #include <winsock2.h>
 759 #endif
 760 struct event_base;
 761 struct event_base *event_base_new(void);
 762 void event_base_free(struct event_base *);],
 763     [
 764 #ifdef _WIN32
 765 {WSADATA d; WSAStartup(0x101,&d); }
 766 #endif
 767 event_base_free(event_base_new());
 768 ], [--with-libevent-dir], [/opt/libevent])
 769
 770 dnl Determine the incantation needed to link libevent.
 771 save_LIBS="$LIBS"
 772 save_LDFLAGS="$LDFLAGS"
 773 save_CPPFLAGS="$CPPFLAGS"
 774
 775 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 776 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 777 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 778
 779 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 780
 781 if test "$enable_static_libevent" = "yes"; then
 782    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 783      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 784    else
 785      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 786    fi
 787 else
 788      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 789        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 790        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 791
 792        if test "$ac_cv_search_event_new" != "none required"; then
 793          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 794        fi
 795        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 796          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 797        fi
 798      else
 799        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 800      fi
 801 fi
 802
 803 dnl Now check for particular libevent functions.
 804 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 805                 evutil_secure_rng_add_bytes \
 806 ])
 807
 808 LIBS="$save_LIBS"
 809 LDFLAGS="$save_LDFLAGS"
 810 CPPFLAGS="$save_CPPFLAGS"
 811
 812 dnl Check that libevent is at least at version 2.0.10, the first stable
 813 dnl release of its series
 814 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 815 AC_MSG_CHECKING([whether Libevent is new enough])
 816 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 817 #include <event2/event.h>
 818 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 819 #error
 820 int x = y(zz);
 821 #else
 822 int x = 1;
 823 #endif
 824 ])], [ AC_MSG_RESULT([yes]) ],
 825    [ AC_MSG_RESULT([no])
 826      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 827
 828 LIBS="$save_LIBS"
 829 LDFLAGS="$save_LDFLAGS"
 830 CPPFLAGS="$save_CPPFLAGS"
 831
 832 AC_SUBST(TOR_LIBEVENT_LIBS)
 833
 834 dnl ------------------------------------------------------
 835 dnl Where do you live, libm?
 836
 837 dnl On some platforms (Haiku/BeOS) the math library is
 838 dnl part of libroot. In which case don't link against lm
 839 TOR_LIB_MATH=""
 840 save_LIBS="$LIBS"
 841 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 842 if test "$ac_cv_search_pow" != "none required"; then
 843     TOR_LIB_MATH="$ac_cv_search_pow"
 844 fi
 845 LIBS="$save_LIBS"
 846 AC_SUBST(TOR_LIB_MATH)
 847
 848 dnl ------------------------------------------------------
 849 dnl Where do you live, openssl?  And how do we call you?
 850
 851 tor_openssl_pkg_redhat="openssl"
 852 tor_openssl_pkg_debian="libssl-dev"
 853 tor_openssl_devpkg_redhat="openssl-devel"
 854 tor_openssl_devpkg_debian="libssl-dev"
 855
 856 ALT_openssl_WITHVAL=""
 857 AC_ARG_WITH(ssl-dir,
 858   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 859   [
 860       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 861          ALT_openssl_WITHVAL="$withval"
 862       fi
 863   ])
 864
 865 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 866 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 867     [#include <openssl/ssl.h>
 868      char *getenv(const char *);],
 869     [struct ssl_cipher_st;
 870      unsigned SSL_CIPHER_get_id(const struct ssl_cipher_st *);
 871      char *getenv(const char *);],
 872     dnl This funny-looking test program calls getenv, so that the compiler
 873     dnl will neither make code that call SSL_CIPHER_get_id(NULL) [producing
 874     dnl a crash], nor optimize out the call to SSL_CIPHER_get_id().
 875     dnl We look for SSL_cipher_get_id() because it is present in
 876     dnl OpenSSL >=1.0.1, because it is not deprecated, and because Tor
 877     dnl depends on it.
 878     [if (getenv("THIS_SHOULDNT_BE_SET_X201803")) SSL_CIPHER_get_id((void *)0);], [],
 879     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /opt/openssl])
 880
 881 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 882
 883 if test "$enable_static_openssl" = "yes"; then
 884    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 885      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 886    else
 887      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 888    fi
 889 else
 890      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 891 fi
 892 AC_SUBST(TOR_OPENSSL_LIBS)
 893
 894 dnl Now check for particular openssl functions.
 895 save_LIBS="$LIBS"
 896 save_LDFLAGS="$LDFLAGS"
 897 save_CPPFLAGS="$CPPFLAGS"
 898 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 899 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 900 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 901
 902 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 903 #include <openssl/opensslv.h>
 904 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 905 #error "too old"
 906 #endif
 907    ]], [[]])],
 908    [ : ],
 909    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 910
 911 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 912 #include <openssl/opensslv.h>
 913 #include <openssl/evp.h>
 914 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 915 #error "no ECC"
 916 #endif
 917 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 918 #error "curves unavailable"
 919 #endif
 920    ]], [[]])],
 921    [ : ],
 922    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 923
 924 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 925 [#include <openssl/ssl.h>
 926 ])
 927
 928 AC_CHECK_FUNCS([ \
 929                 ERR_load_KDF_strings \
 930                 SSL_SESSION_get_master_key \
 931                 SSL_get_server_random \
 932                 SSL_get_client_ciphers \
 933                 SSL_get_client_random \
 934                 SSL_CIPHER_find \
 935                 TLS_method
 936                ])
 937
 938 dnl Check if OpenSSL has scrypt implementation.
 939 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 940
 941 dnl Check if OpenSSL structures are opaque
 942 AC_CHECK_MEMBERS([SSL.state], , ,
 943 [#include <openssl/ssl.h>
 944 ])
 945
 946 AC_CHECK_SIZEOF(SHA_CTX, , [AC_INCLUDES_DEFAULT()
 947 #include <openssl/sha.h>
 948 ])
 949
 950 dnl Define the set of checks for KIST scheduler support.
 951 AC_DEFUN([CHECK_KIST_SUPPORT],[
 952   dnl KIST needs struct tcp_info and for certain members to exist.
 953   AC_CHECK_MEMBERS(
 954     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
 955     , ,[[#include <netinet/tcp.h>]])
 956   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
 957   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 958                      #include <linux/sockios.h>
 959                      #ifndef SIOCOUTQNSD
 960                      #error
 961                      #endif
 962                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
 963   if test "x$have_siocoutqnsd" = "xyes"; then
 964     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
 965       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
 966         have_kist_support=yes
 967       fi
 968     fi
 969   fi
 970 ])
 971 dnl Now, trigger the check.
 972 CHECK_KIST_SUPPORT
 973 AS_IF([test "x$have_kist_support" = "xyes"],
 974       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
 975                                         on this system])],
 976       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
 977
 978 LIBS="$save_LIBS"
 979 LDFLAGS="$save_LDFLAGS"
 980 CPPFLAGS="$save_CPPFLAGS"
 981
 982 dnl ------------------------------------------------------
 983 dnl Where do you live, zlib?  And how do we call you?
 984
 985 tor_zlib_pkg_redhat="zlib"
 986 tor_zlib_pkg_debian="zlib1g"
 987 tor_zlib_devpkg_redhat="zlib-devel"
 988 tor_zlib_devpkg_debian="zlib1g-dev"
 989
 990 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 991     [#include <zlib.h>],
 992     [const char * zlibVersion(void);],
 993     [zlibVersion();], [--with-zlib-dir],
 994     [/opt/zlib])
 995
 996 if test "$enable_static_zlib" = "yes"; then
 997    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 998      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 999  using --enable-static-zlib")
1000    else
1001      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
1002    fi
1003 else
1004      TOR_ZLIB_LIBS="-lz"
1005 fi
1006 AC_SUBST(TOR_ZLIB_LIBS)
1007
1008 dnl ------------------------------------------------------
1009 dnl Where we do we find lzma?
1010
1011 AC_ARG_ENABLE(lzma,
1012       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
1013       [case "${enableval}" in
1014         "yes") lzma=true ;;
1015         "no")  lzma=false ;;
1016         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
1017       esac], [lzma=auto])
1018
1019 if test "x$enable_lzma" = "xno"; then
1020     have_lzma=no;
1021 else
1022     PKG_CHECK_MODULES([LZMA],
1023                       [liblzma],
1024                       have_lzma=yes,
1025                       have_lzma=no)
1026
1027     if test "x$have_lzma" = "xno" ; then
1028         AC_MSG_WARN([Unable to find liblzma.])
1029     fi
1030 fi
1031
1032 if test "x$have_lzma" = "xyes"; then
1033     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
1034     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
1035     TOR_LZMA_LIBS="${LZMA_LIBS}"
1036 fi
1037 AC_SUBST(TOR_LZMA_CFLAGS)
1038 AC_SUBST(TOR_LZMA_LIBS)
1039
1040 dnl ------------------------------------------------------
1041 dnl Where we do we find zstd?
1042
1043 AC_ARG_ENABLE(zstd,
1044       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
1045       [case "${enableval}" in
1046         "yes") zstd=true ;;
1047         "no")  zstd=false ;;
1048         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
1049       esac], [zstd=auto])
1050
1051 if test "x$enable_zstd" = "xno"; then
1052     have_zstd=no;
1053 else
1054     PKG_CHECK_MODULES([ZSTD],
1055                       [libzstd >= 1.1],
1056                       have_zstd=yes,
1057                       have_zstd=no)
1058
1059     if test "x$have_zstd" = "xno" ; then
1060         AC_MSG_WARN([Unable to find libzstd.])
1061     fi
1062 fi
1063
1064 if test "x$have_zstd" = "xyes"; then
1065     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
1066     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
1067     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
1068
1069     dnl now check for zstd functions
1070     save_LIBS="$LIBS"
1071     save_CFLAGS="$CFLAGS"
1072     LIBS="$LIBS $ZSTD_LIBS"
1073     CFLAGS="$CFLAGS $ZSTD_CFLAGS"
1074     AC_CHECK_FUNCS(ZSTD_estimateCStreamSize \
1075                    ZSTD_estimateDCtxSize)
1076     LIBS="$save_LIBS"
1077     CFLAGS="$save_CFLAGS"
1078 fi
1079 AC_SUBST(TOR_ZSTD_CFLAGS)
1080 AC_SUBST(TOR_ZSTD_LIBS)
1081
1082 dnl ----------------------------------------------------------------------
1083 dnl Check if libcap is available for capabilities.
1084
1085 tor_cap_pkg_debian="libcap2"
1086 tor_cap_pkg_redhat="libcap"
1087 tor_cap_devpkg_debian="libcap-dev"
1088 tor_cap_devpkg_redhat="libcap-devel"
1089
1090 AC_CHECK_LIB([cap], [cap_init], [],
1091   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
1092 )
1093 AC_CHECK_FUNCS(cap_set_proc)
1094
1095 dnl ---------------------------------------------------------------------
1096 dnl Now that we know about our major libraries, we can check for compiler
1097 dnl and linker hardening options.  We need to do this with the libraries known,
1098 dnl since sometimes the linker will like an option but not be willing to
1099 dnl use it with a build of a library.
1100
1101 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
1102 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
1103
1104 CFLAGS_FTRAPV=
1105 CFLAGS_FWRAPV=
1106 CFLAGS_ASAN=
1107 CFLAGS_UBSAN=
1108
1109
1110 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1111 #if !defined(__clang__)
1112 #error
1113 #endif])], have_clang=yes, have_clang=no)
1114
1115 if test "x$enable_gcc_hardening" != "xno"; then
1116     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
1117     if test "x$have_clang" = "xyes"; then
1118         TOR_CHECK_CFLAGS(-Qunused-arguments)
1119     fi
1120     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
1121     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
1122     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
1123 m4_ifdef([AS_VAR_IF],[
1124     AS_VAR_IF(can_compile, [yes],
1125         AS_VAR_IF(can_link, [yes],
1126                   [],
1127                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
1128         )])
1129     AS_VAR_POPDEF([can_link])
1130     AS_VAR_POPDEF([can_compile])
1131     TOR_CHECK_CFLAGS(-Wstack-protector)
1132     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
1133     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
1134        TOR_CHECK_CFLAGS(-fPIE)
1135        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
1136     fi
1137     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
1138 fi
1139
1140 if test "$fragile_hardening" = "yes"; then
1141     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
1142    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
1143       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
1144    fi
1145
1146    if test "$tor_cv_cflags__ftrapv" != "yes"; then
1147      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
1148    fi
1149
1150    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
1151     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1152       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.*, and with Clang you need libclang_rt.ubsan*])
1153     fi
1154
1155    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1156     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1157       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1158     fi
1159
1160 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1161 fi
1162
1163 dnl Find the correct libraries to add in order to use the sanitizers.
1164 dnl
1165 dnl When building Rust, Cargo will run the linker with the -nodefaultlibs
1166 dnl option, which will prevent the compiler from linking the sanitizer
1167 dnl libraries it needs.  We need to specify them manually.
1168 dnl
1169 dnl What's more, we need to specify them in a linker script rather than
1170 dnl from build.rs: these options aren't allowed in the cargo:rustc-flags
1171 dnl variable.
1172 RUST_LINKER_OPTIONS=""
1173 if test "x$have_clang" = "xyes"; then
1174         if test "x$CFLAGS_ASAN" != "x"; then
1175                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS $CFLAGS_ASAN"
1176         fi
1177         if test "x$CFLAGS_UBSAN" != "x"; then
1178                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS $CFLAGS_UBSAN"
1179         fi
1180 else
1181         if test "x$CFLAGS_ASAN" != "x"; then
1182                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -lasan"
1183         fi
1184         if test "x$CFLAGS_UBSAN" != "x"; then
1185                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -lubsan"
1186         fi
1187 fi
1188 AC_SUBST(RUST_LINKER_OPTIONS)
1189
1190 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1191 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1192
1193 mulodi_fixes_ftrapv=no
1194 if test "$have_clang" = "yes"; then
1195   saved_CFLAGS="$CFLAGS"
1196   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1197   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1198   AC_LINK_IFELSE([
1199       AC_LANG_SOURCE([[
1200           #include <stdint.h>
1201           #include <stdlib.h>
1202           int main(int argc, char **argv)
1203           {
1204             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1205                         * (int64_t)atoi(argv[3]);
1206             return x == 9;
1207           } ]])],
1208           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1209           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1210   if test "$ftrapv_can_link" = "no"; then
1211     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1212     AC_LINK_IFELSE([
1213       AC_LANG_SOURCE([[
1214           #include <stdint.h>
1215           #include <stdlib.h>
1216           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1217              *overflow=0;
1218              return a;
1219           }
1220           int main(int argc, char **argv)
1221           {
1222             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1223                         * (int64_t)atoi(argv[3]);
1224             return x == 9;
1225           } ]])],
1226           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1227           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1228   fi
1229   CFLAGS="$saved_CFLAGS"
1230 fi
1231
1232 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1233
1234 dnl These cflags add bunches of branches, and we haven't been able to
1235 dnl persuade ourselves that they're suitable for code that needs to be
1236 dnl constant time.
1237 AC_SUBST(CFLAGS_BUGTRAP)
1238 dnl These cflags are variant ones sutable for code that needs to be
1239 dnl constant-time.
1240 AC_SUBST(CFLAGS_CONSTTIME)
1241
1242 if test "x$enable_linker_hardening" != "xno"; then
1243     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1244 fi
1245
1246 # For backtrace support
1247 TOR_CHECK_LDFLAGS(-rdynamic)
1248
1249 dnl ------------------------------------------------------
1250 dnl Now see if we have a -fomit-frame-pointer compiler option.
1251
1252 saved_CFLAGS="$CFLAGS"
1253 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1254 F_OMIT_FRAME_POINTER=''
1255 if test "$saved_CFLAGS" != "$CFLAGS"; then
1256   if test "$fragile_hardening" = "yes"; then
1257     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1258   fi
1259 fi
1260 CFLAGS="$saved_CFLAGS"
1261 AC_SUBST(F_OMIT_FRAME_POINTER)
1262
1263 dnl ------------------------------------------------------
1264 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1265 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1266 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1267 dnl code will work.
1268 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1269
1270 dnl ============================================================
1271 dnl Check for libseccomp
1272
1273 if test "x$enable_seccomp" != "xno"; then
1274   AC_CHECK_HEADERS([seccomp.h])
1275   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1276 fi
1277
1278 dnl ============================================================
1279 dnl Check for libscrypt
1280
1281 if test "x$enable_libscrypt" != "xno"; then
1282   AC_CHECK_HEADERS([libscrypt.h])
1283   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1284   AC_CHECK_FUNCS([libscrypt_scrypt])
1285 fi
1286
1287 dnl ============================================================
1288 dnl We need an implementation of curve25519.
1289
1290 dnl set these defaults.
1291 build_curve25519_donna=no
1292 build_curve25519_donna_c64=no
1293 use_curve25519_donna=no
1294 use_curve25519_nacl=no
1295 CURVE25519_LIBS=
1296
1297 dnl The best choice is using curve25519-donna-c64, but that requires
1298 dnl that we
1299 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1300   tor_cv_can_use_curve25519_donna_c64,
1301   [AC_RUN_IFELSE(
1302     [AC_LANG_PROGRAM([dnl
1303       #include <stdint.h>
1304       typedef unsigned uint128_t __attribute__((mode(TI)));
1305   int func(uint64_t a, uint64_t b) {
1306            uint128_t c = ((uint128_t)a) * b;
1307            int ok = ((uint64_t)(c>>96)) == 522859 &&
1308              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1309                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1310                  (((uint64_t)(c))&0xffffffffL) == 0;
1311            return ok;
1312       }
1313   ], [dnl
1314     int ok = func( ((uint64_t)2000000000) * 1000000000,
1315                    ((uint64_t)1234567890) << 24);
1316         return !ok;
1317       ])],
1318   [tor_cv_can_use_curve25519_donna_c64=yes],
1319       [tor_cv_can_use_curve25519_donna_c64=no],
1320   [AC_LINK_IFELSE(
1321         [AC_LANG_PROGRAM([dnl
1322       #include <stdint.h>
1323       typedef unsigned uint128_t __attribute__((mode(TI)));
1324   int func(uint64_t a, uint64_t b) {
1325            uint128_t c = ((uint128_t)a) * b;
1326            int ok = ((uint64_t)(c>>96)) == 522859 &&
1327              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1328                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1329                  (((uint64_t)(c))&0xffffffffL) == 0;
1330            return ok;
1331       }
1332   ], [dnl
1333     int ok = func( ((uint64_t)2000000000) * 1000000000,
1334                  ((uint64_t)1234567890) << 24);
1335         return !ok;
1336       ])],
1337           [tor_cv_can_use_curve25519_donna_c64=cross],
1338       [tor_cv_can_use_curve25519_donna_c64=no])])])
1339
1340 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1341                   nacl/crypto_scalarmult_curve25519.h])
1342
1343 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1344   tor_cv_can_use_curve25519_nacl,
1345   [tor_saved_LIBS="$LIBS"
1346    LIBS="$LIBS -lnacl"
1347    AC_LINK_IFELSE(
1348      [AC_LANG_PROGRAM([dnl
1349        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1350        #include <crypto_scalarmult_curve25519.h>
1351    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1352    #include <nacl/crypto_scalarmult_curve25519.h>
1353    #endif
1354        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1355    #error Hey, this is the reference implementation! That's not fast.
1356    #endif
1357      ], [
1358    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1359      ])], [tor_cv_can_use_curve25519_nacl=yes],
1360      [tor_cv_can_use_curve25519_nacl=no])
1361    LIBS="$tor_saved_LIBS" ])
1362
1363  dnl Okay, now we need to figure out which one to actually use. Fall back
1364  dnl to curve25519-donna.c
1365
1366  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1367    build_curve25519_donna_c64=yes
1368    use_curve25519_donna=yes
1369  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1370    use_curve25519_nacl=yes
1371    CURVE25519_LIBS=-lnacl
1372  else
1373    build_curve25519_donna=yes
1374    use_curve25519_donna=yes
1375  fi
1376
1377 if test "x$use_curve25519_donna" = "xyes"; then
1378   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1379             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1380 fi
1381 if test "x$use_curve25519_nacl" = "xyes"; then
1382   AC_DEFINE(USE_CURVE25519_NACL, 1,
1383             [Defined if we should use a curve25519 from nacl])
1384 fi
1385 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1386   test "x$build_curve25519_donna" = "xyes")
1387 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1388   test "x$build_curve25519_donna_c64" = "xyes")
1389 AC_SUBST(CURVE25519_LIBS)
1390
1391 dnl Make sure to enable support for large off_t if available.
1392 AC_SYS_LARGEFILE
1393
1394 AC_CHECK_HEADERS([errno.h \
1395                   fcntl.h \
1396                   signal.h \
1397                   string.h \
1398                   sys/capability.h \
1399                   sys/fcntl.h \
1400                   sys/stat.h \
1401                   sys/time.h \
1402                   sys/types.h \
1403                   time.h \
1404                   unistd.h \
1405                   arpa/inet.h \
1406                   crt_externs.h \
1407                   execinfo.h \
1408                   gnu/libc-version.h \
1409                   grp.h \
1410                   ifaddrs.h \
1411                   inttypes.h \
1412                   limits.h \
1413                   linux/types.h \
1414                   machine/limits.h \
1415                   malloc.h \
1416                   malloc/malloc.h \
1417                   malloc_np.h \
1418                   netdb.h \
1419                   netinet/in.h \
1420                   netinet/in6.h \
1421                   pwd.h \
1422                   readpassphrase.h \
1423                   stdatomic.h \
1424                   sys/eventfd.h \
1425                   sys/file.h \
1426                   sys/ioctl.h \
1427                   sys/limits.h \
1428                   sys/mman.h \
1429                   sys/param.h \
1430                   sys/prctl.h \
1431                   sys/random.h \
1432                   sys/resource.h \
1433                   sys/select.h \
1434                   sys/socket.h \
1435                   sys/statvfs.h \
1436                   sys/syscall.h \
1437                   sys/sysctl.h \
1438                   sys/syslimits.h \
1439                   sys/time.h \
1440                   sys/types.h \
1441                   sys/un.h \
1442                   sys/utime.h \
1443                   sys/wait.h \
1444                   syslog.h \
1445                   utime.h])
1446
1447 AC_CHECK_HEADERS(sys/param.h)
1448
1449 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1450 [#ifdef HAVE_SYS_TYPES_H
1451 #include <sys/types.h>
1452 #endif
1453 #ifdef HAVE_SYS_SOCKET_H
1454 #include <sys/socket.h>
1455 #endif])
1456 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1457 [#ifdef HAVE_SYS_TYPES_H
1458 #include <sys/types.h>
1459 #endif
1460 #ifdef HAVE_SYS_SOCKET_H
1461 #include <sys/socket.h>
1462 #endif
1463 #ifdef HAVE_NET_IF_H
1464 #include <net/if.h>
1465 #endif
1466 #ifdef HAVE_NETINET_IN_H
1467 #include <netinet/in.h>
1468 #endif])
1469
1470 AC_CHECK_HEADERS(linux/if.h,[],[],
1471 [
1472 #ifdef HAVE_SYS_SOCKET_H
1473 #include <sys/socket.h>
1474 #endif
1475 ])
1476
1477 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1478         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1479 [#ifdef HAVE_SYS_TYPES_H
1480 #include <sys/types.h>
1481 #endif
1482 #ifdef HAVE_SYS_SOCKET_H
1483 #include <sys/socket.h>
1484 #endif
1485 #ifdef HAVE_LIMITS_H
1486 #include <limits.h>
1487 #endif
1488 #ifdef HAVE_LINUX_TYPES_H
1489 #include <linux/types.h>
1490 #endif
1491 #ifdef HAVE_NETINET_IN6_H
1492 #include <netinet/in6.h>
1493 #endif
1494 #ifdef HAVE_NETINET_IN_H
1495 #include <netinet/in.h>
1496 #endif])
1497
1498 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1499         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1500 [#ifdef HAVE_SYS_TYPES_H
1501 #include <sys/types.h>
1502 #endif
1503 #ifdef HAVE_SYS_SOCKET_H
1504 #include <sys/socket.h>
1505 #endif
1506 #ifdef HAVE_LIMITS_H
1507 #include <limits.h>
1508 #endif
1509 #ifdef HAVE_LINUX_TYPES_H
1510 #include <linux/types.h>
1511 #endif
1512 #ifdef HAVE_NETINET_IN6_H
1513 #include <netinet/in6.h>
1514 #endif
1515 #ifdef HAVE_NETINET_IN_H
1516 #include <netinet/in.h>
1517 #endif
1518 #ifdef HAVE_LINUX_IF_H
1519 #include <linux/if.h>
1520 #endif])
1521
1522 transparent_ok=0
1523 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1524   transparent_ok=1
1525 fi
1526 if test "x$linux_netfilter_ipv4" = "x1"; then
1527   transparent_ok=1
1528 fi
1529 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1530   transparent_ok=1
1531 fi
1532 if test "x$transparent_ok" = "x1"; then
1533   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1534 else
1535   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1536 fi
1537
1538 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1539 [#ifdef HAVE_SYS_TYPES_H
1540 #include <sys/types.h>
1541 #endif
1542 #ifdef HAVE_SYS_TIME_H
1543 #include <sys/time.h>
1544 #endif])
1545
1546 AC_CHECK_SIZEOF(char)
1547 AC_CHECK_SIZEOF(short)
1548 AC_CHECK_SIZEOF(int)
1549 AC_CHECK_SIZEOF(long)
1550 AC_CHECK_SIZEOF(long long)
1551 AC_CHECK_SIZEOF(__int64)
1552 AC_CHECK_SIZEOF(void *)
1553 AC_CHECK_SIZEOF(time_t)
1554 AC_CHECK_SIZEOF(size_t)
1555 AC_CHECK_SIZEOF(pid_t)
1556
1557 AC_CHECK_TYPES([uint, u_char, ssize_t])
1558
1559 AC_PC_FROM_UCONTEXT([:])
1560
1561 dnl used to include sockaddr_storage, but everybody has that.
1562 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1563 [#ifdef HAVE_SYS_TYPES_H
1564 #include <sys/types.h>
1565 #endif
1566 #ifdef HAVE_NETINET_IN_H
1567 #include <netinet/in.h>
1568 #endif
1569 #ifdef HAVE_NETINET_IN6_H
1570 #include <netinet/in6.h>
1571 #endif
1572 #ifdef HAVE_SYS_SOCKET_H
1573 #include <sys/socket.h>
1574 #endif
1575 #ifdef _WIN32
1576 #define _WIN32_WINNT 0x0501
1577 #define WIN32_LEAN_AND_MEAN
1578 #include <winsock2.h>
1579 #include <ws2tcpip.h>
1580 #endif
1581 ])
1582 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1583 [#ifdef HAVE_SYS_TYPES_H
1584 #include <sys/types.h>
1585 #endif
1586 #ifdef HAVE_NETINET_IN_H
1587 #include <netinet/in.h>
1588 #endif
1589 #ifdef HAVE_NETINET_IN6_H
1590 #include <netinet/in6.h>
1591 #endif
1592 #ifdef HAVE_SYS_SOCKET_H
1593 #include <sys/socket.h>
1594 #endif
1595 #ifdef _WIN32
1596 #define _WIN32_WINNT 0x0501
1597 #define WIN32_LEAN_AND_MEAN
1598 #include <winsock2.h>
1599 #include <ws2tcpip.h>
1600 #endif
1601 ])
1602
1603 AC_CHECK_TYPES([rlim_t], , ,
1604 [#ifdef HAVE_SYS_TYPES_H
1605 #include <sys/types.h>
1606 #endif
1607 #ifdef HAVE_SYS_TIME_H
1608 #include <sys/time.h>
1609 #endif
1610 #ifdef HAVE_SYS_RESOURCE_H
1611 #include <sys/resource.h>
1612 #endif
1613 ])
1614
1615 AX_CHECK_SIGN([time_t],
1616        [ : ],
1617        [ : ], [
1618 #ifdef HAVE_SYS_TYPES_H
1619 #include <sys/types.h>
1620 #endif
1621 #ifdef HAVE_SYS_TIME_H
1622 #include <sys/time.h>
1623 #endif
1624 #ifdef HAVE_TIME_H
1625 #include <time.h>
1626 #endif
1627 ])
1628
1629 if test "$ax_cv_decl_time_t_signed" = "no"; then
1630   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1631 fi
1632
1633 AX_CHECK_SIGN([size_t],
1634        [ tor_cv_size_t_signed=yes ],
1635        [ tor_cv_size_t_signed=no ], [
1636 #ifdef HAVE_SYS_TYPES_H
1637 #include <sys/types.h>
1638 #endif
1639 ])
1640
1641 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1642   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1643 fi
1644
1645 AX_CHECK_SIGN([enum always],
1646        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1647        [ : ], [
1648  enum always { AAA, BBB, CCC };
1649 ])
1650
1651 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1652 #ifdef HAVE_SYS_SOCKET_H
1653 #include <sys/socket.h>
1654 #endif
1655 ])
1656
1657 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1658
1659 AC_CHECK_SIZEOF(cell_t)
1660
1661 # Now make sure that NULL can be represented as zero bytes.
1662 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1663 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1664 [[#include <stdlib.h>
1665 #include <string.h>
1666 #include <stdio.h>
1667 #ifdef HAVE_STDDEF_H
1668 #include <stddef.h>
1669 #endif
1670 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1671 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1672        [tor_cv_null_is_zero=yes],
1673        [tor_cv_null_is_zero=no],
1674        [tor_cv_null_is_zero=cross])])
1675
1676 if test "$tor_cv_null_is_zero" = "cross"; then
1677   # Cross-compiling; let's hope that the target isn't raving mad.
1678   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1679 fi
1680
1681 if test "$tor_cv_null_is_zero" != "no"; then
1682   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1683             [Define to 1 iff memset(0) sets pointers to NULL])
1684 fi
1685
1686 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1687 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1688 [[#include <stdlib.h>
1689 #include <string.h>
1690 #include <stdio.h>
1691 #ifdef HAVE_STDDEF_H
1692 #include <stddef.h>
1693 #endif
1694 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1695 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1696        [tor_cv_dbl0_is_zero=yes],
1697        [tor_cv_dbl0_is_zero=no],
1698        [tor_cv_dbl0_is_zero=cross])])
1699
1700 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1701   # Cross-compiling; let's hope that the target isn't raving mad.
1702   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1703 fi
1704
1705 if test "$tor_cv_dbl0_is_zero" != "no"; then
1706   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1707             [Define to 1 iff memset(0) sets doubles to 0.0])
1708 fi
1709
1710 # And what happens when we malloc zero?
1711 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1712 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1713 [[#include <stdlib.h>
1714 #include <string.h>
1715 #include <stdio.h>
1716 #ifdef HAVE_STDDEF_H
1717 #include <stddef.h>
1718 #endif
1719 int main () { return malloc(0)?0:1; }]])],
1720        [tor_cv_malloc_zero_works=yes],
1721        [tor_cv_malloc_zero_works=no],
1722        [tor_cv_malloc_zero_works=cross])])
1723
1724 if test "$tor_cv_malloc_zero_works" = "cross"; then
1725   # Cross-compiling; let's hope that the target isn't raving mad.
1726   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1727 fi
1728
1729 if test "$tor_cv_malloc_zero_works" = "yes"; then
1730   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1731             [Define to 1 iff malloc(0) returns a pointer])
1732 fi
1733
1734 # whether we seem to be in a 2s-complement world.
1735 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1736 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1737 [[int main () { int problem = ((-99) != (~99)+1);
1738 return problem ? 1 : 0; }]])],
1739        [tor_cv_twos_complement=yes],
1740        [tor_cv_twos_complement=no],
1741        [tor_cv_twos_complement=cross])])
1742
1743 if test "$tor_cv_twos_complement" = "cross"; then
1744   # Cross-compiling; let's hope that the target isn't raving mad.
1745   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1746 fi
1747
1748 if test "$tor_cv_twos_complement" != "no"; then
1749   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1750             [Define to 1 iff we represent negative integers with
1751              two's complement])
1752 fi
1753
1754 # What does shifting a negative value do?
1755 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1756 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1757 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1758        [tor_cv_sign_extend=yes],
1759        [tor_cv_sign_extend=no],
1760        [tor_cv_sign_extend=cross])])
1761
1762 if test "$tor_cv_sign_extend" = "cross"; then
1763   # Cross-compiling; let's hope that the target isn't raving mad.
1764   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1765 fi
1766
1767 if test "$tor_cv_sign_extend" != "no"; then
1768   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1769             [Define to 1 iff right-shifting a negative value performs sign-extension])
1770 fi
1771
1772 # Is uint8_t the same type as unsigned char?
1773 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1774 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1775 #include <stdint.h>
1776 extern uint8_t c;
1777 unsigned char c;]])],
1778        [tor_cv_uint8_uchar=yes],
1779        [tor_cv_uint8_uchar=no],
1780        [tor_cv_uint8_uchar=cross])])
1781
1782 if test "$tor_cv_uint8_uchar" = "cross"; then
1783   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1784 fi
1785
1786 if test "$tor_cv_uint8_uchar" = "no"; then
1787   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1788 fi
1789
1790 AC_ARG_WITH(tcmalloc,
1791 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library. Deprecated; see --with-malloc]),
1792 [ tcmalloc=yes ], [ tcmalloc=no ])
1793
1794 default_malloc=system
1795
1796 if test "x$enable_openbsd_malloc" = "xyes" ; then
1797   AC_MSG_NOTICE([The --enable-openbsd-malloc argument is deprecated; use --with-malloc=openbsd instead.])
1798   default_malloc=openbsd
1799 fi
1800
1801 if test "x$tcmalloc" = "xyes"; then
1802   AC_MSG_NOTICE([The --with-tcmalloc argument is deprecated; use --with-malloc=tcmalloc instead.])
1803   default_malloc=tcmalloc
1804 fi
1805
1806 AC_ARG_WITH(malloc,
1807    AS_HELP_STRING([--with-malloc=[system,jemalloc,tcmalloc,openbsd]],
1808                   [select special malloc implementation [system]]),
1809    [ malloc="$with_malloc" ], [ malloc="$default_malloc" ])
1810
1811 AS_CASE([$malloc],
1812   [tcmalloc], [
1813       PKG_CHECK_MODULES([TCMALLOC],
1814                         [libtcmalloc],
1815                         have_tcmalloc=yes,
1816                         have_tcmalloc=no)
1817
1818       if test "x$have_tcmalloc" = "xno" ; then
1819           AC_MSG_ERROR([Unable to find tcmalloc requested by --with-malloc.])
1820       fi
1821
1822       CFLAGS="$CFLAGS $TCMALLOC_CFLAGS"
1823       LIBS="$TCMALLOC_LIBS $LIBS"
1824   ],
1825
1826   [jemalloc], [
1827       PKG_CHECK_MODULES([JEMALLOC],
1828                         [jemalloc],
1829                         have_jemalloc=yes,
1830                         have_jemalloc=no)
1831
1832       if test "x$have_tcmalloc" = "xno" ; then
1833           AC_MSG_ERROR([Unable to find jemalloc requested by --with-malloc.])
1834       fi
1835
1836       CFLAGS="$CFLAGS $JEMALLOC_CFLAGS"
1837       LIBS="$JEMALLOC_LIBS $LIBS"
1838       using_custom_malloc=yes
1839   ],
1840
1841   [openbsd], [
1842     AC_MSG_WARN([The openbsd malloc port is deprecated in Tor 0.3.5 and will be removed in a future version.])
1843     enable_openbsd_malloc=yes
1844   ],
1845
1846   [system], [
1847      # handle this later, including the jemalloc fallback
1848     AC_CHECK_FUNCS(mallinfo)
1849   ],
1850
1851   [AC_MSG_ERROR([--with-malloc=`$with_malloc' not supported, see --help])
1852 ])
1853
1854 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
1855
1856 if test "$malloc" != "system"; then
1857   # Tell the C compiler not to use the system allocator functions.
1858   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
1859 fi
1860 if test "$using_custom_malloc" = "yes"; then
1861   # Tell the C compiler not to use the system allocator functions.
1862   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
1863 fi
1864
1865 # By default, we're going to assume we don't have mlockall()
1866 # bionic and other platforms have various broken mlockall subsystems.
1867 # Some systems don't have a working mlockall, some aren't linkable,
1868 # and some have it but don't declare it.
1869 AC_CHECK_FUNCS(mlockall)
1870 AC_CHECK_DECLS([mlockall], , , [
1871 #ifdef HAVE_SYS_MMAN_H
1872 #include <sys/mman.h>
1873 #endif])
1874
1875 # Allow user to specify an alternate syslog facility
1876 AC_ARG_WITH(syslog-facility,
1877 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1878 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1879 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1880 AC_SUBST(LOGFACILITY)
1881
1882 # Check if we have getresuid and getresgid
1883 AC_CHECK_FUNCS(getresuid getresgid)
1884
1885 # Check for gethostbyname_r in all its glorious incompatible versions.
1886 #   (This logic is based on that in Python's configure.in)
1887 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1888   [Define this if you have any gethostbyname_r()])
1889
1890 AC_CHECK_FUNC(gethostbyname_r, [
1891   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1892   OLD_CFLAGS=$CFLAGS
1893   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1894   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1895 #include <netdb.h>
1896   ]], [[
1897     char *cp1, *cp2;
1898     struct hostent *h1, *h2;
1899     int i1, i2;
1900     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1901   ]])],[
1902     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1903     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1904      [Define this if gethostbyname_r takes 6 arguments])
1905     AC_MSG_RESULT(6)
1906   ], [
1907     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1908 #include <netdb.h>
1909     ]], [[
1910       char *cp1, *cp2;
1911       struct hostent *h1;
1912       int i1, i2;
1913       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1914     ]])], [
1915       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1916       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1917         [Define this if gethostbyname_r takes 5 arguments])
1918       AC_MSG_RESULT(5)
1919    ], [
1920       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1921 #include <netdb.h>
1922      ]], [[
1923        char *cp1;
1924        struct hostent *h1;
1925        struct hostent_data hd;
1926        (void) gethostbyname_r(cp1,h1,&hd);
1927      ]])], [
1928        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1929        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1930          [Define this if gethostbyname_r takes 3 arguments])
1931        AC_MSG_RESULT(3)
1932      ], [
1933        AC_MSG_RESULT(0)
1934      ])
1935   ])
1936  ])
1937  CFLAGS=$OLD_CFLAGS
1938 ])
1939
1940 AC_CACHE_CHECK([whether the C compiler supports __func__],
1941   tor_cv_have_func_macro,
1942   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1943 #include <stdio.h>
1944 int main(int c, char **v) { puts(__func__); }])],
1945   tor_cv_have_func_macro=yes,
1946   tor_cv_have_func_macro=no))
1947
1948 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1949   tor_cv_have_FUNC_macro,
1950   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1951 #include <stdio.h>
1952 int main(int c, char **v) { puts(__FUNC__); }])],
1953   tor_cv_have_FUNC_macro=yes,
1954   tor_cv_have_FUNC_macro=no))
1955
1956 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1957   tor_cv_have_FUNCTION_macro,
1958   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1959 #include <stdio.h>
1960 int main(int c, char **v) { puts(__FUNCTION__); }])],
1961   tor_cv_have_FUNCTION_macro=yes,
1962   tor_cv_have_FUNCTION_macro=no))
1963
1964 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1965   tor_cv_have_environ_declared,
1966   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1967 #ifdef HAVE_UNISTD_H
1968 #include <unistd.h>
1969 #endif
1970 #include <stdlib.h>
1971 int main(int c, char **v) { char **t = environ; }])],
1972   tor_cv_have_environ_declared=yes,
1973   tor_cv_have_environ_declared=no))
1974
1975 if test "$tor_cv_have_func_macro" = "yes"; then
1976   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1977 fi
1978
1979 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1980   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1981 fi
1982
1983 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1984   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1985            [Defined if the compiler supports __FUNCTION__])
1986 fi
1987
1988 if test "$tor_cv_have_environ_declared" = "yes"; then
1989   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1990            [Defined if we have extern char **environ already declared])
1991 fi
1992
1993 # $prefix stores the value of the --prefix command line option, or
1994 # NONE if the option wasn't set.  In the case that it wasn't set, make
1995 # it be the default, so that we can use it to expand directories now.
1996 if test "x$prefix" = "xNONE"; then
1997   prefix=$ac_default_prefix
1998 fi
1999
2000 # and similarly for $exec_prefix
2001 if test "x$exec_prefix" = "xNONE"; then
2002   exec_prefix=$prefix
2003 fi
2004
2005 if test "x$BUILDDIR" = "x"; then
2006   BUILDDIR=`pwd`
2007 fi
2008 AC_SUBST(BUILDDIR)
2009 AH_TEMPLATE([BUILDDIR],[tor's build directory])
2010 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
2011
2012 if test "x$SRCDIR" = "x"; then
2013   SRCDIR=$(cd "$srcdir"; pwd)
2014 fi
2015 AH_TEMPLATE([SRCDIR],[tor's sourcedir directory])
2016 AC_DEFINE_UNQUOTED(SRCDIR,"$SRCDIR")
2017
2018 if test "x$CONFDIR" = "x"; then
2019   CONFDIR=`eval echo $sysconfdir/tor`
2020 fi
2021 AC_SUBST(CONFDIR)
2022 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
2023 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
2024
2025 BINDIR=`eval echo $bindir`
2026 AC_SUBST(BINDIR)
2027 LOCALSTATEDIR=`eval echo $localstatedir`
2028 AC_SUBST(LOCALSTATEDIR)
2029
2030 if test "$bwin32" = "true"; then
2031   # Test if the linker supports the --nxcompat and --dynamicbase options
2032   # for Windows
2033   save_LDFLAGS="$LDFLAGS"
2034   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
2035   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
2036   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
2037     [AC_MSG_RESULT([yes])]
2038     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
2039     [AC_MSG_RESULT([no])]
2040   )
2041   LDFLAGS="$save_LDFLAGS"
2042 fi
2043
2044 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
2045 # than autoconf's macros like.
2046 if test "$GCC" = "yes"; then
2047   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
2048   # accident waiting to happen.
2049   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
2050 else
2051   # Override optimization level for non-gcc compilers
2052   CFLAGS="$CFLAGS -O"
2053   enable_gcc_warnings=no
2054   enable_gcc_warnings_advisory=no
2055 fi
2056
2057 # Warnings implies advisory-warnings and -Werror.
2058 if test "$enable_gcc_warnings" = "yes"; then
2059   enable_gcc_warnings_advisory=yes
2060   enable_fatal_warnings=yes
2061 fi
2062
2063 # OS X Lion started deprecating the system openssl. Let's just disable
2064 # all deprecation warnings on OS X. Also, to potentially make the binary
2065 # a little smaller, let's enable dead_strip.
2066 case "$host_os" in
2067
2068  darwin*)
2069     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
2070     LDFLAGS="$LDFLAGS -dead_strip" ;;
2071 esac
2072
2073 # Add some more warnings which we use in development but not in the
2074 # released versions.  (Some relevant gcc versions can't handle these.)
2075 #
2076 # Note that we have to do this near the end  of the autoconf process, or
2077 # else we may run into problems when these warnings hit on the testing C
2078 # programs that autoconf wants to build.
2079 if test "x$enable_gcc_warnings_advisory" != "xno"; then
2080
2081   case "$host" in
2082     *-*-openbsd* | *-*-bitrig*)
2083       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
2084       # That's fine, except that the headers don't pass -Wredundant-decls.
2085       # Therefore, let's disable -Wsystem-headers when we're building
2086       # with maximal warnings on OpenBSD.
2087       CFLAGS="$CFLAGS -Wno-system-headers" ;;
2088   esac
2089
2090   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
2091   # have it work better.
2092   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
2093
2094   # This warning was added in gcc 4.3, but it appears to generate
2095   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
2096   #CFLAGS="$CFLAGS -Wlogical-op"
2097
2098   m4_foreach_w([warning_flag], [
2099      -Waddress
2100      -Waddress-of-array-temporary
2101      -Waddress-of-temporary
2102      -Wambiguous-macro
2103      -Wanonymous-pack-parens
2104      -Warc
2105      -Warc-abi
2106      -Warc-bridge-casts-disallowed-in-nonarc
2107      -Warc-maybe-repeated-use-of-weak
2108      -Warc-performSelector-leaks
2109      -Warc-repeated-use-of-weak
2110      -Warray-bounds
2111      -Warray-bounds-pointer-arithmetic
2112      -Wasm
2113      -Wasm-operand-widths
2114      -Watomic-properties
2115      -Watomic-property-with-user-defined-accessor
2116      -Wauto-import
2117      -Wauto-storage-class
2118      -Wauto-var-id
2119      -Wavailability
2120      -Wbackslash-newline-escape
2121      -Wbad-array-new-length
2122      -Wbind-to-temporary-copy
2123      -Wbitfield-constant-conversion
2124      -Wbool-conversion
2125      -Wbool-conversions
2126      -Wbuiltin-requires-header
2127      -Wchar-align
2128      -Wcompare-distinct-pointer-types
2129      -Wcomplex-component-init
2130      -Wconditional-type-mismatch
2131      -Wconfig-macros
2132      -Wconstant-conversion
2133      -Wconstant-logical-operand
2134      -Wconstexpr-not-const
2135      -Wcustom-atomic-properties
2136      -Wdangling-field
2137      -Wdangling-initializer-list
2138      -Wdate-time
2139      -Wdelegating-ctor-cycles
2140      -Wdeprecated-implementations
2141      -Wdeprecated-register
2142      -Wdirect-ivar-access
2143      -Wdiscard-qual
2144      -Wdistributed-object-modifiers
2145      -Wdivision-by-zero
2146      -Wdollar-in-identifier-extension
2147      -Wdouble-promotion
2148      -Wduplicate-decl-specifier
2149      -Wduplicate-enum
2150      -Wduplicate-method-arg
2151      -Wduplicate-method-match
2152      -Wduplicated-cond
2153      -Wdynamic-class-memaccess
2154      -Wembedded-directive
2155      -Wempty-translation-unit
2156      -Wenum-conversion
2157      -Wexit-time-destructors
2158      -Wexplicit-ownership-type
2159      -Wextern-initializer
2160      -Wextra
2161      -Wextra-semi
2162      -Wextra-tokens
2163      -Wflexible-array-extensions
2164      -Wfloat-conversion
2165      -Wformat-non-iso
2166      -Wfour-char-constants
2167      -Wgcc-compat
2168      -Wglobal-constructors
2169      -Wgnu-array-member-paren-init
2170      -Wgnu-designator
2171      -Wgnu-static-float-init
2172      -Wheader-guard
2173      -Wheader-hygiene
2174      -Widiomatic-parentheses
2175      -Wignored-attributes
2176      -Wimplicit-atomic-properties
2177      -Wimplicit-conversion-floating-point-to-bool
2178      -Wimplicit-exception-spec-mismatch
2179      -Wimplicit-fallthrough
2180      -Wimplicit-fallthrough-per-function
2181      -Wimplicit-retain-self
2182      -Wimport-preprocessor-directive-pedantic
2183      -Wincompatible-library-redeclaration
2184      -Wincompatible-pointer-types-discards-qualifiers
2185      -Wincomplete-implementation
2186      -Wincomplete-module
2187      -Wincomplete-umbrella
2188      -Winit-self
2189      -Wint-conversions
2190      -Wint-to-void-pointer-cast
2191      -Winteger-overflow
2192      -Winvalid-constexpr
2193      -Winvalid-iboutlet
2194      -Winvalid-noreturn
2195      -Winvalid-pp-token
2196      -Winvalid-source-encoding
2197      -Winvalid-token-paste
2198      -Wknr-promoted-parameter
2199      -Wlarge-by-value-copy
2200      -Wliteral-conversion
2201      -Wliteral-range
2202      -Wlocal-type-template-args
2203      -Wlogical-op
2204      -Wloop-analysis
2205      -Wmain-return-type
2206      -Wmalformed-warning-check
2207      -Wmethod-signatures
2208      -Wmicrosoft
2209      -Wmicrosoft-exists
2210      -Wmismatched-parameter-types
2211      -Wmismatched-return-types
2212      -Wmissing-field-initializers
2213      -Wmissing-format-attribute
2214      -Wmissing-noreturn
2215      -Wmissing-selector-name
2216      -Wmissing-sysroot
2217      -Wmissing-variable-declarations
2218      -Wmodule-conflict
2219      -Wnested-anon-types
2220      -Wnewline-eof
2221      -Wnon-literal-null-conversion
2222      -Wnon-pod-varargs
2223      -Wnonportable-cfstrings
2224      -Wnormalized=nfkc
2225      -Wnull-arithmetic
2226      -Wnull-character
2227      -Wnull-conversion
2228      -Wnull-dereference
2229      -Wout-of-line-declaration
2230      -Wover-aligned
2231      -Woverlength-strings
2232      -Woverride-init
2233      -Woverriding-method-mismatch
2234      -Wpointer-type-mismatch
2235      -Wpredefined-identifier-outside-function
2236      -Wprotocol-property-synthesis-ambiguity
2237      -Wreadonly-iboutlet-property
2238      -Wreadonly-setter-attrs
2239      -Wreceiver-expr
2240      -Wreceiver-forward-class
2241      -Wreceiver-is-weak
2242      -Wreinterpret-base-class
2243      -Wrequires-super-attribute
2244      -Wreserved-user-defined-literal
2245      -Wreturn-stack-address
2246      -Wsection
2247      -Wselector-type-mismatch
2248      -Wsentinel
2249      -Wserialized-diagnostics
2250      -Wshadow
2251      -Wshift-count-negative
2252      -Wshift-count-overflow
2253      -Wshift-negative-value
2254      -Wshift-overflow=2
2255      -Wshift-sign-overflow
2256      -Wshorten-64-to-32
2257      -Wsizeof-array-argument
2258      -Wsource-uses-openmp
2259      -Wstatic-float-init
2260      -Wstatic-in-inline
2261      -Wstatic-local-in-inline
2262      -Wstrict-overflow=1
2263      -Wstring-compare
2264      -Wstring-conversion
2265      -Wstrlcpy-strlcat-size
2266      -Wstrncat-size
2267      -Wsuggest-attribute=format
2268      -Wsuggest-attribute=noreturn
2269      -Wsuper-class-method-mismatch
2270      -Wswitch-bool
2271      -Wsync-nand
2272      -Wtautological-constant-out-of-range-compare
2273      -Wtentative-definition-incomplete-type
2274      -Wtrampolines
2275      -Wtype-safety
2276      -Wtypedef-redefinition
2277      -Wtypename-missing
2278      -Wundefined-inline
2279      -Wundefined-internal
2280      -Wundefined-reinterpret-cast
2281      -Wunicode
2282      -Wunicode-whitespace
2283      -Wunknown-warning-option
2284      -Wunnamed-type-template-args
2285      -Wunneeded-member-function
2286      -Wunsequenced
2287      -Wunsupported-visibility
2288      -Wunused-but-set-parameter
2289      -Wunused-but-set-variable
2290      -Wunused-command-line-argument
2291      -Wunused-const-variable=2
2292      -Wunused-exception-parameter
2293      -Wunused-local-typedefs
2294      -Wunused-member-function
2295      -Wunused-sanitize-argument
2296      -Wunused-volatile-lvalue
2297      -Wuser-defined-literals
2298      -Wvariadic-macros
2299      -Wvector-conversion
2300      -Wvector-conversions
2301      -Wvexing-parse
2302      -Wvisibility
2303      -Wvla-extension
2304      -Wzero-length-array
2305   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
2306
2307 dnl    We should re-enable this in some later version.  Clang doesn't
2308 dnl    mind, but it causes trouble with GCC.
2309 dnl     -Wstrict-overflow=2
2310
2311 dnl    These seem to require annotations that we don't currently use,
2312 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2313 dnl     -Wthread-safety
2314 dnl     -Wthread-safety-analysis
2315 dnl     -Wthread-safety-attributes
2316 dnl     -Wthread-safety-beta
2317 dnl     -Wthread-safety-precise
2318
2319   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2320   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2321   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2322   CFLAGS="$CFLAGS -Wwrite-strings"
2323   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2324   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
2325   CFLAGS="$CFLAGS -Wunused-parameter "
2326   # These interfere with building main() { return 0; }, which autoconf
2327   # likes to use as its default program.
2328   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
2329
2330   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2331     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2332   fi
2333   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2334     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2335   fi
2336   if test "$tor_cv_cflags__warn_unused_const_variable_2" = "yes"; then
2337     AC_DEFINE([HAVE_CFLAG_WUNUSED_CONST_VARIABLE], 1, [True if we have -Wunused-const-variable])
2338   fi
2339
2340   if test "x$enable_fatal_warnings" = "xyes"; then
2341     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2342     # default autoconf programs are full of errors.
2343     CFLAGS="$CFLAGS -Werror"
2344   fi
2345
2346 fi
2347
2348 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2349    case "$host_os" in
2350     darwin*)
2351       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2352    esac
2353 fi
2354
2355 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2356
2357 AC_CONFIG_FILES([
2358         Doxyfile
2359         Makefile
2360         config.rust
2361         link_rust.sh
2362         contrib/dist/suse/tor.sh
2363         contrib/operator-tools/tor.logrotate
2364         contrib/dist/tor.sh
2365         contrib/dist/torctl
2366         contrib/dist/tor.service
2367         src/config/torrc.sample
2368         src/config/torrc.minimal
2369         src/rust/.cargo/config
2370         scripts/maint/checkOptionDocs.pl
2371         scripts/maint/updateVersions.pl
2372 ])
2373
2374 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2375   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2376   for file in $regular_mans ; do
2377     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2378       echo "==================================";
2379       echo;
2380       echo "Building Tor has failed since manpages cannot be built.";
2381       echo;
2382       echo "You need asciidoc installed to be able to build the manpages.";
2383       echo "To build without manpages, use the --disable-asciidoc argument";
2384       echo "when calling configure.";
2385       echo;
2386       echo "==================================";
2387       exit 1;
2388     fi
2389   done
2390 fi
2391
2392 if test "$fragile_hardening" = "yes"; then
2393   AC_MSG_WARN([
2394
2395 ============
2396 Warning!  Building Tor with --enable-fragile-hardening (also known as
2397 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2398 other kinds of attacks easier. A Tor instance build with this option will be
2399 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2400 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2401 denial of service attacks. For more information, see
2402 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2403 ============
2404   ])
2405 fi
2406
2407 AC_OUTPUT