configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2015, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.0.11])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56
  57 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  58     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  59 fi
  60
  61 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  62 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  63 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  64 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  65 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  66
  67 if test "$enable_static_tor" = "yes"; then
  68   enable_static_libevent="yes";
  69   enable_static_openssl="yes";
  70   enable_static_zlib="yes";
  71   CFLAGS="$CFLAGS -static"
  72 fi
  73
  74 if test "$enable_system_torrc" = "no"; then
  75   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  76             [Defined if we're not going to look for a torrc in SYSCONF])
  77 fi
  78
  79 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  80
  81 AC_ARG_ENABLE(asciidoc,
  82      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  83      [case "${enableval}" in
  84         "yes") asciidoc=true ;;
  85         "no")  asciidoc=false ;;
  86         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  87       esac], [asciidoc=true])
  88
  89 # systemd notify support
  90 AC_ARG_ENABLE(systemd,
  91       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  92       [case "${enableval}" in
  93         "yes") systemd=true ;;
  94         "no")  systemd=false ;;
  95         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
  96       esac], [systemd=auto])
  97
  98
  99
 100 # systemd support
 101 if test "x$enable_systemd" = "xno"; then
 102     have_systemd=no;
 103 else
 104     PKG_CHECK_MODULES(SYSTEMD,
 105         [libsystemd-daemon],
 106         have_systemd=yes,
 107         have_systemd=no)
 108     if test "x$have_systemd" = "xno"; then
 109         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 110         PKG_CHECK_MODULES(SYSTEMD,
 111             [libsystemd],
 112             have_systemd=yes,
 113             have_systemd=no)
 114     fi
 115 fi
 116
 117 if test "x$have_systemd" = "xyes"; then
 118     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 119     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 120     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 121     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 122          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 123 fi
 124 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 125 AC_SUBST(TOR_SYSTEMD_LIBS)
 126
 127 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 128     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 129 fi
 130
 131 case "$host" in
 132    *-*-solaris* )
 133      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 134      ;;
 135 esac
 136
 137 AC_ARG_ENABLE(gcc-warnings,
 138      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 139 AC_ARG_ENABLE(fatal-warnings,
 140      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 141 AC_ARG_ENABLE(gcc-warnings-advisory,
 142      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 143
 144 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 145 AC_ARG_ENABLE(gcc-hardening,
 146     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 147
 148 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 149 AC_ARG_ENABLE(expensive-hardening,
 150     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 151 AC_ARG_ENABLE(fragile-hardening,
 152     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 153 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 154   fragile_hardening="yes"
 155 fi
 156
 157 dnl Linker hardening options
 158 dnl Currently these options are ELF specific - you can't use this with MacOSX
 159 AC_ARG_ENABLE(linker-hardening,
 160     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 161
 162 AC_ARG_ENABLE(local-appdata,
 163    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 164 if test "$enable_local_appdata" = "yes"; then
 165   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 166             [Defined if we default to host local appdata paths on Windows])
 167 fi
 168
 169 # Tor2web mode flag
 170 AC_ARG_ENABLE(tor2web-mode,
 171      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 172 [if test "x$enableval" = "xyes"; then
 173     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 174 fi])
 175
 176 AC_ARG_ENABLE(tool-name-check,
 177      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 178
 179 AC_ARG_ENABLE(seccomp,
 180      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 181
 182 AC_ARG_ENABLE(libscrypt,
 183      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 184
 185 dnl check for the correct "ar" when cross-compiling.
 186 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 187 dnl    so kludge up a replacement for the case where it isn't there yet.)
 188 m4_ifdef([AM_PROG_AR],
 189          [AM_PROG_AR],
 190          [AN_MAKEVAR([AR], [AC_PROG_AR])
 191           AN_PROGRAM([ar], [AC_PROG_AR])
 192           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 193           AC_PROG_AR])
 194
 195 dnl Check whether the above macro has settled for a simply named tool even
 196 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 197 dnl because that will find any cc on the system, not only the cross-compiler,
 198 dnl and then verify that a binary built with this compiler runs on the
 199 dnl build system. It will then come to the false conclusion that we're not
 200 dnl cross-compiling.
 201 if test "x$enable_tool_name_check" != "xno"; then
 202     if test "x$ac_tool_warned" = "xyes"; then
 203         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 204         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 205                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 206         fi
 207 fi
 208
 209 AC_PROG_CC
 210 AC_PROG_CPP
 211 AC_PROG_MAKE_SET
 212 AC_PROG_RANLIB
 213 AC_PROG_SED
 214
 215 AC_ARG_VAR([PERL], [path to Perl binary])
 216 AC_CHECK_PROGS([PERL], [perl])
 217 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 218
 219 dnl check for asciidoc and a2x
 220 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 221 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 222
 223 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 224
 225 AM_PROG_CC_C_O
 226 AC_PROG_CC_C99
 227
 228 AC_ARG_VAR([PYTHON], [path to Python binary])
 229 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 230 if test "x$PYTHON" = "x"; then
 231   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 232 fi
 233 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 234
 235 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 236 AC_C_FLEXIBLE_ARRAY_MEMBER
 237 ], [
 238  dnl Maybe we've got an old autoconf...
 239  AC_CACHE_CHECK([for flexible array members],
 240      tor_cv_c_flexarray,
 241      [AC_COMPILE_IFELSE(
 242        AC_LANG_PROGRAM([
 243  struct abc { int a; char b[]; };
 244 ], [
 245  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 246  def->b[0] = 33;
 247 ]),
 248   [tor_cv_c_flexarray=yes],
 249   [tor_cv_c_flexarray=no])])
 250  if test "$tor_cv_flexarray" = "yes"; then
 251    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 252  else
 253    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 254  fi
 255 ])
 256
 257 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 258       tor_cv_c_c99_decl,
 259       [AC_COMPILE_IFELSE(
 260          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 261          [tor_cv_c_c99_decl=yes],
 262          [tor_cv_c_c99_decl=no] )])
 263 if test "$tor_cv_c_c99_decl" != "yes"; then
 264   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 265 fi
 266
 267 AC_CACHE_CHECK([for working C99 designated initializers],
 268       tor_cv_c_c99_designated_init,
 269       [AC_COMPILE_IFELSE(
 270          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 271                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 272          [tor_cv_c_c99_designated_init=yes],
 273          [tor_cv_c_c99_designated_init=no] )])
 274
 275 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 276   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 277 fi
 278
 279 TORUSER=_tor
 280 AC_ARG_WITH(tor-user,
 281         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 282         [
 283            TORUSER=$withval
 284         ]
 285 )
 286 AC_SUBST(TORUSER)
 287
 288 TORGROUP=_tor
 289 AC_ARG_WITH(tor-group,
 290         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 291         [
 292            TORGROUP=$withval
 293         ]
 294 )
 295 AC_SUBST(TORGROUP)
 296
 297
 298 dnl If _WIN32 is defined and non-zero, we are building for win32
 299 AC_MSG_CHECKING([for win32])
 300 AC_RUN_IFELSE([AC_LANG_SOURCE([
 301 int main(int c, char **v) {
 302 #ifdef _WIN32
 303 #if _WIN32
 304   return 0;
 305 #else
 306   return 1;
 307 #endif
 308 #else
 309   return 2;
 310 #endif
 311 }])],
 312 bwin32=true; AC_MSG_RESULT([yes]),
 313 bwin32=false; AC_MSG_RESULT([no]),
 314 bwin32=cross; AC_MSG_RESULT([cross])
 315 )
 316
 317 if test "$bwin32" = "cross"; then
 318 AC_MSG_CHECKING([for win32 (cross)])
 319 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 320 #ifdef _WIN32
 321 int main(int c, char **v) {return 0;}
 322 #else
 323 #error
 324 int main(int c, char **v) {return x(y);}
 325 #endif
 326 ])],
 327 bwin32=true; AC_MSG_RESULT([yes]),
 328 bwin32=false; AC_MSG_RESULT([no]))
 329 fi
 330
 331 AH_BOTTOM([
 332 #ifdef _WIN32
 333 /* Defined to access windows functions and definitions for >=WinXP */
 334 # ifndef WINVER
 335 #  define WINVER 0x0501
 336 # endif
 337
 338 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 339 # ifndef _WIN32_WINNT
 340 #  define _WIN32_WINNT 0x0501
 341 # endif
 342
 343 /* Defined to avoid including some windows headers as part of Windows.h */
 344 # ifndef WIN32_LEAN_AND_MEAN
 345 #  define WIN32_LEAN_AND_MEAN 1
 346 # endif
 347 #endif
 348 ])
 349
 350
 351 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 352
 353 dnl Enable C99 when compiling with MIPSpro
 354 AC_MSG_CHECKING([for MIPSpro compiler])
 355 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 356 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 357 #error
 358   return x(y);
 359 #endif
 360 ])],
 361 bmipspro=false; AC_MSG_RESULT(no),
 362 bmipspro=true; AC_MSG_RESULT(yes))
 363
 364 if test "$bmipspro" = "true"; then
 365   CFLAGS="$CFLAGS -c99"
 366 fi
 367
 368 AC_C_BIGENDIAN
 369
 370 AC_SEARCH_LIBS(socket, [socket network])
 371 AC_SEARCH_LIBS(gethostbyname, [nsl])
 372 AC_SEARCH_LIBS(dlopen, [dl])
 373 AC_SEARCH_LIBS(inet_aton, [resolv])
 374 AC_SEARCH_LIBS(backtrace, [execinfo])
 375 saved_LIBS="$LIBS"
 376 AC_SEARCH_LIBS([clock_gettime], [rt])
 377 if test "$LIBS" != "$saved_LIBS"; then
 378    # Looks like we need -lrt for clock_gettime().
 379    have_rt=yes
 380 fi
 381
 382 AC_SEARCH_LIBS(pthread_create, [pthread])
 383 AC_SEARCH_LIBS(pthread_detach, [pthread])
 384
 385 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 386 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 387
 388 AC_CHECK_FUNCS(
 389         _NSGetEnviron \
 390         RtlSecureZeroMemory \
 391         SecureZeroMemory \
 392         accept4 \
 393         backtrace \
 394         backtrace_symbols_fd \
 395         eventfd \
 396         explicit_bzero \
 397         timingsafe_memcmp \
 398         flock \
 399         ftime \
 400         getaddrinfo \
 401         getifaddrs \
 402         getpass \
 403         getrlimit \
 404         gettimeofday \
 405         gmtime_r \
 406         htonll \
 407         inet_aton \
 408         ioctl \
 409         issetugid \
 410         llround \
 411         localtime_r \
 412         lround \
 413         memmem \
 414         memset_s \
 415         pipe \
 416         pipe2 \
 417         prctl \
 418         readpassphrase \
 419         rint \
 420         sigaction \
 421         socketpair \
 422         statvfs \
 423         strlcat \
 424         strlcpy \
 425         strnlen \
 426         strptime \
 427         strtok_r \
 428         strtoull \
 429         sysconf \
 430         sysctl \
 431         truncate \
 432         uname \
 433         usleep \
 434         vasprintf \
 435         _vscprintf
 436 )
 437
 438 # Apple messed up when they added two functions functions in Sierra: they
 439 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 440 # checks. So we should only probe for those functions if we are sure that we
 441 # are not targetting OSX 10.11 or earlier.
 442 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 443 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 444 #ifdef __APPLE__
 445 #  include <AvailabilityMacros.h>
 446 #  ifndef MAC_OS_X_VERSION_10_12
 447 #    define MAC_OS_X_VERSION_10_12 101200
 448 #  endif
 449 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 450 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 451 #      error "Running on Mac OSX 10.11 or earlier"
 452 #    endif
 453 #  endif
 454 #endif
 455 ]], [[]])],
 456    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 457    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 458
 459 if test "$on_macos_pre_10_12" = "no"; then
 460   AC_CHECK_FUNCS(
 461         clock_gettime \
 462         getentropy \
 463   )
 464 fi
 465
 466 if test "$bwin32" != "true"; then
 467   AC_CHECK_HEADERS(pthread.h)
 468   AC_CHECK_FUNCS(pthread_create)
 469   AC_CHECK_FUNCS(pthread_condattr_setclock)
 470 fi
 471
 472 if test "$bwin32" = "true"; then
 473   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 474 #include <windows.h>
 475 #include <conio.h>
 476 #include <wchar.h>
 477                  ])
 478 fi
 479
 480 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 481   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 482
 483 dnl ------------------------------------------------------
 484 dnl Where do you live, libevent?  And how do we call you?
 485
 486 if test "$bwin32" = "true"; then
 487   TOR_LIB_WS32=-lws2_32
 488   TOR_LIB_IPHLPAPI=-liphlpapi
 489   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 490   # think it's actually necessary.
 491   TOR_LIB_GDI=-lgdi32
 492 else
 493   TOR_LIB_WS32=
 494   TOR_LIB_GDI=
 495 fi
 496 AC_SUBST(TOR_LIB_WS32)
 497 AC_SUBST(TOR_LIB_GDI)
 498 AC_SUBST(TOR_LIB_IPHLPAPI)
 499
 500 tor_libevent_pkg_redhat="libevent"
 501 tor_libevent_pkg_debian="libevent-dev"
 502 tor_libevent_devpkg_redhat="libevent-devel"
 503 tor_libevent_devpkg_debian="libevent-dev"
 504
 505 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 506 dnl linking for static builds.
 507 STATIC_LIBEVENT_FLAGS=""
 508 if test "$enable_static_libevent" = "yes"; then
 509     if test "$have_rt" = "yes"; then
 510       STATIC_LIBEVENT_FLAGS=" -lrt "
 511     fi
 512 fi
 513
 514 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 515 #ifdef _WIN32
 516 #include <winsock2.h>
 517 #endif
 518 #include <sys/time.h>
 519 #include <sys/types.h>
 520 #include <event2/event.h>], [
 521 #ifdef _WIN32
 522 #include <winsock2.h>
 523 #endif
 524 struct event_base;
 525 struct event_base *event_base_new(void);],
 526     [
 527 #ifdef _WIN32
 528 {WSADATA d; WSAStartup(0x101,&d); }
 529 #endif
 530 event_base_new();
 531 ], [--with-libevent-dir], [/opt/libevent])
 532
 533 dnl Determine the incantation needed to link libevent.
 534 save_LIBS="$LIBS"
 535 save_LDFLAGS="$LDFLAGS"
 536 save_CPPFLAGS="$CPPFLAGS"
 537
 538 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 539 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 540 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 541
 542 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 543
 544 if test "$enable_static_libevent" = "yes"; then
 545    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 546      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 547    else
 548      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 549    fi
 550 else
 551      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 552        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 553        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 554
 555        if test "$ac_cv_search_event_new" != "none required"; then
 556          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 557        fi
 558        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 559          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 560        fi
 561      else
 562        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 563      fi
 564 fi
 565
 566 dnl Now check for particular libevent functions.
 567 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 568                 evutil_secure_rng_add_bytes \
 569 ])
 570
 571 LIBS="$save_LIBS"
 572 LDFLAGS="$save_LDFLAGS"
 573 CPPFLAGS="$save_CPPFLAGS"
 574
 575 dnl Check that libevent is at least at version 2.0.10, the first stable
 576 dnl release of its series
 577 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 578 AC_MSG_CHECKING([whether Libevent is new enough])
 579 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 580 #include <event2/event.h>
 581 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 582 #error
 583 int x = y(zz);
 584 #else
 585 int x = 1;
 586 #endif
 587 ])], [ AC_MSG_RESULT([yes]) ],
 588    [ AC_MSG_RESULT([no])
 589      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 590
 591 LIBS="$save_LIBS"
 592 LDFLAGS="$save_LDFLAGS"
 593 CPPFLAGS="$save_CPPFLAGS"
 594
 595 AC_SUBST(TOR_LIBEVENT_LIBS)
 596
 597 dnl ------------------------------------------------------
 598 dnl Where do you live, libm?
 599
 600 dnl On some platforms (Haiku/BeOS) the math library is
 601 dnl part of libroot. In which case don't link against lm
 602 TOR_LIB_MATH=""
 603 save_LIBS="$LIBS"
 604 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 605 if test "$ac_cv_search_pow" != "none required"; then
 606     TOR_LIB_MATH="$ac_cv_search_pow"
 607 fi
 608 LIBS="$save_LIBS"
 609 AC_SUBST(TOR_LIB_MATH)
 610
 611 dnl ------------------------------------------------------
 612 dnl Where do you live, openssl?  And how do we call you?
 613
 614 tor_openssl_pkg_redhat="openssl"
 615 tor_openssl_pkg_debian="libssl-dev"
 616 tor_openssl_devpkg_redhat="openssl-devel"
 617 tor_openssl_devpkg_debian="libssl-dev"
 618
 619 ALT_openssl_WITHVAL=""
 620 AC_ARG_WITH(ssl-dir,
 621   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 622   [
 623       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 624          ALT_openssl_WITHVAL="$withval"
 625       fi
 626   ])
 627
 628 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 629     [#include <openssl/rand.h>],
 630     [void RAND_add(const void *buf, int num, double entropy);],
 631     [RAND_add((void*)0,0,0);], [],
 632     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 633
 634 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 635
 636 if test "$enable_static_openssl" = "yes"; then
 637    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 638      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 639    else
 640      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 641    fi
 642 else
 643      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 644 fi
 645 AC_SUBST(TOR_OPENSSL_LIBS)
 646
 647 dnl Now check for particular openssl functions.
 648 save_LIBS="$LIBS"
 649 save_LDFLAGS="$LDFLAGS"
 650 save_CPPFLAGS="$CPPFLAGS"
 651 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 652 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 653 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 654
 655 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 656 #include <openssl/opensslv.h>
 657 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 658 #error "too old"
 659 #endif
 660    ]], [[]])],
 661    [ : ],
 662    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 663
 664 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 665 #include <openssl/opensslv.h>
 666 #include <openssl/evp.h>
 667 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 668 #error "no ECC"
 669 #endif
 670 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 671 #error "curves unavailable"
 672 #endif
 673    ]], [[]])],
 674    [ : ],
 675    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 676
 677 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 678 [#include <openssl/ssl.h>
 679 ])
 680
 681 AC_CHECK_FUNCS([ \
 682                 SSL_SESSION_get_master_key \
 683                 SSL_get_server_random \
 684                 SSL_get_client_ciphers \
 685                 SSL_get_client_random \
 686                 SSL_CIPHER_find \
 687                 TLS_method
 688                ])
 689
 690 dnl Check if OpenSSL has scrypt implementation.
 691 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 692
 693 dnl Check if OpenSSL structures are opaque
 694 AC_CHECK_MEMBERS([SSL.state], , ,
 695 [#include <openssl/ssl.h>
 696 ])
 697
 698 LIBS="$save_LIBS"
 699 LDFLAGS="$save_LDFLAGS"
 700 CPPFLAGS="$save_CPPFLAGS"
 701
 702 dnl ------------------------------------------------------
 703 dnl Where do you live, zlib?  And how do we call you?
 704
 705 tor_zlib_pkg_redhat="zlib"
 706 tor_zlib_pkg_debian="zlib1g"
 707 tor_zlib_devpkg_redhat="zlib-devel"
 708 tor_zlib_devpkg_debian="zlib1g-dev"
 709
 710 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 711     [#include <zlib.h>],
 712     [const char * zlibVersion(void);],
 713     [zlibVersion();], [--with-zlib-dir],
 714     [/opt/zlib])
 715
 716 if test "$enable_static_zlib" = "yes"; then
 717    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 718      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 719  using --enable-static-zlib")
 720    else
 721      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 722    fi
 723 else
 724      TOR_ZLIB_LIBS="-lz"
 725 fi
 726 AC_SUBST(TOR_ZLIB_LIBS)
 727
 728 dnl ----------------------------------------------------------------------
 729 dnl Check if libcap is available for capabilities.
 730
 731 tor_cap_pkg_debian="libcap2"
 732 tor_cap_pkg_redhat="libcap"
 733 tor_cap_devpkg_debian="libcap-dev"
 734 tor_cap_devpkg_redhat="libcap-devel"
 735
 736 AC_CHECK_LIB([cap], [cap_init], [],
 737   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 738 )
 739 AC_CHECK_FUNCS(cap_set_proc)
 740
 741 dnl ---------------------------------------------------------------------
 742 dnl Now that we know about our major libraries, we can check for compiler
 743 dnl and linker hardening options.  We need to do this with the libraries known,
 744 dnl since sometimes the linker will like an option but not be willing to
 745 dnl use it with a build of a library.
 746
 747 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 748 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_CAP_LIBS"
 749
 750 CFLAGS_FTRAPV=
 751 CFLAGS_FWRAPV=
 752 CFLAGS_ASAN=
 753 CFLAGS_UBSAN=
 754
 755
 756 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 757 #if !defined(__clang__)
 758 #error
 759 #endif])], have_clang=yes, have_clang=no)
 760
 761 if test "x$enable_gcc_hardening" != "xno"; then
 762     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 763     if test "x$have_clang" = "xyes"; then
 764         TOR_CHECK_CFLAGS(-Qunused-arguments)
 765     fi
 766     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 767     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 768     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 769 m4_ifdef([AS_VAR_IF],[
 770     AS_VAR_IF(can_compile, [yes],
 771         AS_VAR_IF(can_link, [yes],
 772                   [],
 773                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 774         )])
 775     AS_VAR_POPDEF([can_link])
 776     AS_VAR_POPDEF([can_compile])
 777     TOR_CHECK_CFLAGS(-Wstack-protector)
 778     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 779     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
 780        TOR_CHECK_CFLAGS(-fPIE)
 781        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 782     fi
 783     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
 784 fi
 785
 786 if test "$fragile_hardening" = "yes"; then
 787     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
 788    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
 789       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
 790    fi
 791
 792    if test "$tor_cv_cflags__ftrapv" != "yes"; then
 793      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
 794    fi
 795
 796    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
 797     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 798       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
 799     fi
 800
 801    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
 802     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
 803       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
 804     fi
 805
 806 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 807 fi
 808
 809 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
 810 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
 811
 812 mulodi_fixes_ftrapv=no
 813 if test "$have_clang" = "yes"; then
 814   saved_CFLAGS="$CFLAGS"
 815   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
 816   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
 817   AC_LINK_IFELSE([
 818       AC_LANG_SOURCE([[
 819           #include <stdint.h>
 820           #include <stdlib.h>
 821           int main(int argc, char **argv)
 822           {
 823             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
 824                         * (int64_t)atoi(argv[3]);
 825             return x == 9;
 826           } ]])],
 827           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
 828           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
 829   if test "$ftrapv_can_link" = "no"; then
 830     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
 831     AC_LINK_IFELSE([
 832       AC_LANG_SOURCE([[
 833           #include <stdint.h>
 834           #include <stdlib.h>
 835           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
 836              *overflow=0;
 837              return a;
 838           }
 839           int main(int argc, char **argv)
 840           {
 841             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
 842                         * (int64_t)atoi(argv[3]);
 843             return x == 9;
 844           } ]])],
 845           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
 846           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
 847   fi
 848   CFLAGS="$saved_CFLAGS"
 849 fi
 850
 851 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
 852
 853 dnl These cflags add bunches of branches, and we haven't been able to
 854 dnl persuade ourselves that they're suitable for code that needs to be
 855 dnl constant time.
 856 AC_SUBST(CFLAGS_BUGTRAP)
 857 dnl These cflags are variant ones sutable for code that needs to be
 858 dnl constant-time.
 859 AC_SUBST(CFLAGS_CONSTTIME)
 860
 861 if test "x$enable_linker_hardening" != "xno"; then
 862     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
 863 fi
 864
 865 # For backtrace support
 866 TOR_CHECK_LDFLAGS(-rdynamic)
 867
 868 dnl ------------------------------------------------------
 869 dnl Now see if we have a -fomit-frame-pointer compiler option.
 870
 871 saved_CFLAGS="$CFLAGS"
 872 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
 873 F_OMIT_FRAME_POINTER=''
 874 if test "$saved_CFLAGS" != "$CFLAGS"; then
 875   if test "$fragile_hardening" = "yes"; then
 876     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
 877   fi
 878 fi
 879 CFLAGS="$saved_CFLAGS"
 880 AC_SUBST(F_OMIT_FRAME_POINTER)
 881
 882 dnl ------------------------------------------------------
 883 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
 884 dnl for us, as GCC 4.6 and later do at many optimization levels), then
 885 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
 886 dnl code will work.
 887 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
 888
 889 dnl ============================================================
 890 dnl Check for libseccomp
 891
 892 if test "x$enable_seccomp" != "xno"; then
 893   AC_CHECK_HEADERS([seccomp.h])
 894   AC_SEARCH_LIBS(seccomp_init, [seccomp])
 895 fi
 896
 897 dnl ============================================================
 898 dnl Check for libscrypt
 899
 900 if test "x$enable_libscrypt" != "xno"; then
 901   AC_CHECK_HEADERS([libscrypt.h])
 902   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
 903   AC_CHECK_FUNCS([libscrypt_scrypt])
 904 fi
 905
 906 dnl ============================================================
 907 dnl We need an implementation of curve25519.
 908
 909 dnl set these defaults.
 910 build_curve25519_donna=no
 911 build_curve25519_donna_c64=no
 912 use_curve25519_donna=no
 913 use_curve25519_nacl=no
 914 CURVE25519_LIBS=
 915
 916 dnl The best choice is using curve25519-donna-c64, but that requires
 917 dnl that we
 918 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
 919   tor_cv_can_use_curve25519_donna_c64,
 920   [AC_RUN_IFELSE(
 921     [AC_LANG_PROGRAM([dnl
 922       #include <stdint.h>
 923       typedef unsigned uint128_t __attribute__((mode(TI)));
 924   int func(uint64_t a, uint64_t b) {
 925            uint128_t c = ((uint128_t)a) * b;
 926            int ok = ((uint64_t)(c>>96)) == 522859 &&
 927              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 928                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 929                  (((uint64_t)(c))&0xffffffffL) == 0;
 930            return ok;
 931       }
 932   ], [dnl
 933     int ok = func( ((uint64_t)2000000000) * 1000000000,
 934                    ((uint64_t)1234567890) << 24);
 935         return !ok;
 936       ])],
 937   [tor_cv_can_use_curve25519_donna_c64=yes],
 938       [tor_cv_can_use_curve25519_donna_c64=no],
 939   [AC_LINK_IFELSE(
 940         [AC_LANG_PROGRAM([dnl
 941       #include <stdint.h>
 942       typedef unsigned uint128_t __attribute__((mode(TI)));
 943   int func(uint64_t a, uint64_t b) {
 944            uint128_t c = ((uint128_t)a) * b;
 945            int ok = ((uint64_t)(c>>96)) == 522859 &&
 946              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 947                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 948                  (((uint64_t)(c))&0xffffffffL) == 0;
 949            return ok;
 950       }
 951   ], [dnl
 952     int ok = func( ((uint64_t)2000000000) * 1000000000,
 953                  ((uint64_t)1234567890) << 24);
 954         return !ok;
 955       ])],
 956           [tor_cv_can_use_curve25519_donna_c64=cross],
 957       [tor_cv_can_use_curve25519_donna_c64=no])])])
 958
 959 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
 960                   nacl/crypto_scalarmult_curve25519.h])
 961
 962 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
 963   tor_cv_can_use_curve25519_nacl,
 964   [tor_saved_LIBS="$LIBS"
 965    LIBS="$LIBS -lnacl"
 966    AC_LINK_IFELSE(
 967      [AC_LANG_PROGRAM([dnl
 968        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
 969        #include <crypto_scalarmult_curve25519.h>
 970    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
 971    #include <nacl/crypto_scalarmult_curve25519.h>
 972    #endif
 973        #ifdef crypto_scalarmult_curve25519_ref_BYTES
 974    #error Hey, this is the reference implementation! That's not fast.
 975    #endif
 976      ], [
 977    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
 978      ])], [tor_cv_can_use_curve25519_nacl=yes],
 979      [tor_cv_can_use_curve25519_nacl=no])
 980    LIBS="$tor_saved_LIBS" ])
 981
 982  dnl Okay, now we need to figure out which one to actually use. Fall back
 983  dnl to curve25519-donna.c
 984
 985  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
 986    build_curve25519_donna_c64=yes
 987    use_curve25519_donna=yes
 988  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
 989    use_curve25519_nacl=yes
 990    CURVE25519_LIBS=-lnacl
 991  else
 992    build_curve25519_donna=yes
 993    use_curve25519_donna=yes
 994  fi
 995
 996 if test "x$use_curve25519_donna" = "xyes"; then
 997   AC_DEFINE(USE_CURVE25519_DONNA, 1,
 998             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
 999 fi
1000 if test "x$use_curve25519_nacl" = "xyes"; then
1001   AC_DEFINE(USE_CURVE25519_NACL, 1,
1002             [Defined if we should use a curve25519 from nacl])
1003 fi
1004 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1005   test "x$build_curve25519_donna" = "xyes")
1006 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1007   test "x$build_curve25519_donna_c64" = "xyes")
1008 AC_SUBST(CURVE25519_LIBS)
1009
1010 dnl Make sure to enable support for large off_t if available.
1011 AC_SYS_LARGEFILE
1012
1013 AC_CHECK_HEADERS([assert.h \
1014                   errno.h \
1015                   fcntl.h \
1016                   signal.h \
1017                   string.h \
1018                   sys/capability.h \
1019                   sys/fcntl.h \
1020                   sys/stat.h \
1021                   sys/time.h \
1022                   sys/types.h \
1023                   time.h \
1024                   unistd.h \
1025                   arpa/inet.h \
1026                   crt_externs.h \
1027                   execinfo.h \
1028                   grp.h \
1029                   ifaddrs.h \
1030                   inttypes.h \
1031                   limits.h \
1032                   linux/types.h \
1033                   machine/limits.h \
1034                   malloc.h \
1035                   malloc/malloc.h \
1036                   malloc_np.h \
1037                   netdb.h \
1038                   netinet/in.h \
1039                   netinet/in6.h \
1040                   pwd.h \
1041                   readpassphrase.h \
1042                   stdint.h \
1043                   sys/eventfd.h \
1044                   sys/file.h \
1045                   sys/ioctl.h \
1046                   sys/limits.h \
1047                   sys/mman.h \
1048                   sys/param.h \
1049                   sys/prctl.h \
1050                   sys/random.h \
1051                   sys/resource.h \
1052                   sys/select.h \
1053                   sys/socket.h \
1054                   sys/statvfs.h \
1055                   sys/syscall.h \
1056                   sys/sysctl.h \
1057                   sys/syslimits.h \
1058                   sys/time.h \
1059                   sys/types.h \
1060                   sys/un.h \
1061                   sys/utime.h \
1062                   sys/wait.h \
1063                   syslog.h \
1064                   utime.h])
1065
1066 AC_CHECK_HEADERS(sys/param.h)
1067
1068 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1069 [#ifdef HAVE_SYS_TYPES_H
1070 #include <sys/types.h>
1071 #endif
1072 #ifdef HAVE_SYS_SOCKET_H
1073 #include <sys/socket.h>
1074 #endif])
1075 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1076 [#ifdef HAVE_SYS_TYPES_H
1077 #include <sys/types.h>
1078 #endif
1079 #ifdef HAVE_SYS_SOCKET_H
1080 #include <sys/socket.h>
1081 #endif
1082 #ifdef HAVE_NET_IF_H
1083 #include <net/if.h>
1084 #endif
1085 #ifdef HAVE_NETINET_IN_H
1086 #include <netinet/in.h>
1087 #endif])
1088
1089 AC_CHECK_HEADERS(linux/if.h,[],[],
1090 [
1091 #ifdef HAVE_SYS_SOCKET_H
1092 #include <sys/socket.h>
1093 #endif
1094 ])
1095
1096 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1097         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1098 [#ifdef HAVE_SYS_TYPES_H
1099 #include <sys/types.h>
1100 #endif
1101 #ifdef HAVE_SYS_SOCKET_H
1102 #include <sys/socket.h>
1103 #endif
1104 #ifdef HAVE_LIMITS_H
1105 #include <limits.h>
1106 #endif
1107 #ifdef HAVE_LINUX_TYPES_H
1108 #include <linux/types.h>
1109 #endif
1110 #ifdef HAVE_NETINET_IN6_H
1111 #include <netinet/in6.h>
1112 #endif
1113 #ifdef HAVE_NETINET_IN_H
1114 #include <netinet/in.h>
1115 #endif])
1116
1117 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1118         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1119 [#ifdef HAVE_SYS_TYPES_H
1120 #include <sys/types.h>
1121 #endif
1122 #ifdef HAVE_SYS_SOCKET_H
1123 #include <sys/socket.h>
1124 #endif
1125 #ifdef HAVE_LIMITS_H
1126 #include <limits.h>
1127 #endif
1128 #ifdef HAVE_LINUX_TYPES_H
1129 #include <linux/types.h>
1130 #endif
1131 #ifdef HAVE_NETINET_IN6_H
1132 #include <netinet/in6.h>
1133 #endif
1134 #ifdef HAVE_NETINET_IN_H
1135 #include <netinet/in.h>
1136 #endif
1137 #ifdef HAVE_LINUX_IF_H
1138 #include <linux/if.h>
1139 #endif])
1140
1141 transparent_ok=0
1142 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1143   transparent_ok=1
1144 fi
1145 if test "x$linux_netfilter_ipv4" = "x1"; then
1146   transparent_ok=1
1147 fi
1148 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1149   transparent_ok=1
1150 fi
1151 if test "x$transparent_ok" = "x1"; then
1152   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1153 else
1154   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1155 fi
1156
1157 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1158 [#ifdef HAVE_SYS_TYPES_H
1159 #include <sys/types.h>
1160 #endif
1161 #ifdef HAVE_SYS_TIME_H
1162 #include <sys/time.h>
1163 #endif])
1164
1165 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1166 dnl Watch out.
1167
1168 AC_CHECK_SIZEOF(int8_t)
1169 AC_CHECK_SIZEOF(int16_t)
1170 AC_CHECK_SIZEOF(int32_t)
1171 AC_CHECK_SIZEOF(int64_t)
1172 AC_CHECK_SIZEOF(uint8_t)
1173 AC_CHECK_SIZEOF(uint16_t)
1174 AC_CHECK_SIZEOF(uint32_t)
1175 AC_CHECK_SIZEOF(uint64_t)
1176 AC_CHECK_SIZEOF(intptr_t)
1177 AC_CHECK_SIZEOF(uintptr_t)
1178
1179 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1180
1181 AC_CHECK_SIZEOF(char)
1182 AC_CHECK_SIZEOF(short)
1183 AC_CHECK_SIZEOF(int)
1184 AC_CHECK_SIZEOF(long)
1185 AC_CHECK_SIZEOF(long long)
1186 AC_CHECK_SIZEOF(__int64)
1187 AC_CHECK_SIZEOF(void *)
1188 AC_CHECK_SIZEOF(time_t)
1189 AC_CHECK_SIZEOF(size_t)
1190 AC_CHECK_SIZEOF(pid_t)
1191
1192 AC_CHECK_TYPES([uint, u_char, ssize_t])
1193
1194 AC_PC_FROM_UCONTEXT([:])
1195
1196 dnl used to include sockaddr_storage, but everybody has that.
1197 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1198 [#ifdef HAVE_SYS_TYPES_H
1199 #include <sys/types.h>
1200 #endif
1201 #ifdef HAVE_NETINET_IN_H
1202 #include <netinet/in.h>
1203 #endif
1204 #ifdef HAVE_NETINET_IN6_H
1205 #include <netinet/in6.h>
1206 #endif
1207 #ifdef HAVE_SYS_SOCKET_H
1208 #include <sys/socket.h>
1209 #endif
1210 #ifdef _WIN32
1211 #define _WIN32_WINNT 0x0501
1212 #define WIN32_LEAN_AND_MEAN
1213 #include <winsock2.h>
1214 #include <ws2tcpip.h>
1215 #endif
1216 ])
1217 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1218 [#ifdef HAVE_SYS_TYPES_H
1219 #include <sys/types.h>
1220 #endif
1221 #ifdef HAVE_NETINET_IN_H
1222 #include <netinet/in.h>
1223 #endif
1224 #ifdef HAVE_NETINET_IN6_H
1225 #include <netinet/in6.h>
1226 #endif
1227 #ifdef HAVE_SYS_SOCKET_H
1228 #include <sys/socket.h>
1229 #endif
1230 #ifdef _WIN32
1231 #define _WIN32_WINNT 0x0501
1232 #define WIN32_LEAN_AND_MEAN
1233 #include <winsock2.h>
1234 #include <ws2tcpip.h>
1235 #endif
1236 ])
1237
1238 AC_CHECK_TYPES([rlim_t], , ,
1239 [#ifdef HAVE_SYS_TYPES_H
1240 #include <sys/types.h>
1241 #endif
1242 #ifdef HAVE_SYS_TIME_H
1243 #include <sys/time.h>
1244 #endif
1245 #ifdef HAVE_SYS_RESOURCE_H
1246 #include <sys/resource.h>
1247 #endif
1248 ])
1249
1250 AX_CHECK_SIGN([time_t],
1251        [ : ],
1252        [ : ], [
1253 #ifdef HAVE_SYS_TYPES_H
1254 #include <sys/types.h>
1255 #endif
1256 #ifdef HAVE_SYS_TIME_H
1257 #include <sys/time.h>
1258 #endif
1259 #ifdef HAVE_TIME_H
1260 #include <time.h>
1261 #endif
1262 ])
1263
1264 if test "$ax_cv_decl_time_t_signed" = "no"; then
1265   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1266 fi
1267
1268 AX_CHECK_SIGN([size_t],
1269        [ tor_cv_size_t_signed=yes ],
1270        [ tor_cv_size_t_signed=no ], [
1271 #ifdef HAVE_SYS_TYPES_H
1272 #include <sys/types.h>
1273 #endif
1274 ])
1275
1276 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1277   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1278 fi
1279
1280 AX_CHECK_SIGN([enum always],
1281        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1282        [ : ], [
1283  enum always { AAA, BBB, CCC };
1284 ])
1285
1286 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1287 #ifdef HAVE_SYS_SOCKET_H
1288 #include <sys/socket.h>
1289 #endif
1290 ])
1291
1292 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1293
1294 AC_CHECK_SIZEOF(cell_t)
1295
1296 # Now make sure that NULL can be represented as zero bytes.
1297 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1298 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1299 [[#include <stdlib.h>
1300 #include <string.h>
1301 #include <stdio.h>
1302 #ifdef HAVE_STDDEF_H
1303 #include <stddef.h>
1304 #endif
1305 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1306 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1307        [tor_cv_null_is_zero=yes],
1308        [tor_cv_null_is_zero=no],
1309        [tor_cv_null_is_zero=cross])])
1310
1311 if test "$tor_cv_null_is_zero" = "cross"; then
1312   # Cross-compiling; let's hope that the target isn't raving mad.
1313   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1314 fi
1315
1316 if test "$tor_cv_null_is_zero" != "no"; then
1317   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1318             [Define to 1 iff memset(0) sets pointers to NULL])
1319 fi
1320
1321 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1322 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1323 [[#include <stdlib.h>
1324 #include <string.h>
1325 #include <stdio.h>
1326 #ifdef HAVE_STDDEF_H
1327 #include <stddef.h>
1328 #endif
1329 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1330 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1331        [tor_cv_dbl0_is_zero=yes],
1332        [tor_cv_dbl0_is_zero=no],
1333        [tor_cv_dbl0_is_zero=cross])])
1334
1335 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1336   # Cross-compiling; let's hope that the target isn't raving mad.
1337   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1338 fi
1339
1340 if test "$tor_cv_dbl0_is_zero" != "no"; then
1341   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1342             [Define to 1 iff memset(0) sets doubles to 0.0])
1343 fi
1344
1345 # And what happens when we malloc zero?
1346 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1347 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1348 [[#include <stdlib.h>
1349 #include <string.h>
1350 #include <stdio.h>
1351 #ifdef HAVE_STDDEF_H
1352 #include <stddef.h>
1353 #endif
1354 int main () { return malloc(0)?0:1; }]])],
1355        [tor_cv_malloc_zero_works=yes],
1356        [tor_cv_malloc_zero_works=no],
1357        [tor_cv_malloc_zero_works=cross])])
1358
1359 if test "$tor_cv_malloc_zero_works" = "cross"; then
1360   # Cross-compiling; let's hope that the target isn't raving mad.
1361   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1362 fi
1363
1364 if test "$tor_cv_malloc_zero_works" = "yes"; then
1365   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1366             [Define to 1 iff malloc(0) returns a pointer])
1367 fi
1368
1369 # whether we seem to be in a 2s-complement world.
1370 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1371 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1372 [[int main () { int problem = ((-99) != (~99)+1);
1373 return problem ? 1 : 0; }]])],
1374        [tor_cv_twos_complement=yes],
1375        [tor_cv_twos_complement=no],
1376        [tor_cv_twos_complement=cross])])
1377
1378 if test "$tor_cv_twos_complement" = "cross"; then
1379   # Cross-compiling; let's hope that the target isn't raving mad.
1380   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1381 fi
1382
1383 if test "$tor_cv_twos_complement" != "no"; then
1384   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1385             [Define to 1 iff we represent negative integers with
1386              two's complement])
1387 fi
1388
1389 # What does shifting a negative value do?
1390 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1391 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1392 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1393        [tor_cv_sign_extend=yes],
1394        [tor_cv_sign_extend=no],
1395        [tor_cv_sign_extend=cross])])
1396
1397 if test "$tor_cv_sign_extend" = "cross"; then
1398   # Cross-compiling; let's hope that the target isn't raving mad.
1399   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1400 fi
1401
1402 if test "$tor_cv_sign_extend" != "no"; then
1403   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1404             [Define to 1 iff right-shifting a negative value performs sign-extension])
1405 fi
1406
1407 # Whether we should use the dmalloc memory allocation debugging library.
1408 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1409 AC_ARG_WITH(dmalloc,
1410 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1411 [if [[ "$withval" = "yes" ]]; then
1412   dmalloc=1
1413   AC_MSG_RESULT(yes)
1414 else
1415   dmalloc=1
1416   AC_MSG_RESULT(no)
1417 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1418 )
1419
1420 if [[ $dmalloc -eq 1 ]]; then
1421   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1422   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1423   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1424   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1425 fi
1426
1427 AC_ARG_WITH(tcmalloc,
1428 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1429 [ tcmalloc=yes ], [ tcmalloc=no ])
1430
1431 if test "x$tcmalloc" = "xyes"; then
1432    LDFLAGS="-ltcmalloc $LDFLAGS"
1433 fi
1434
1435 using_custom_malloc=no
1436 if test "x$enable_openbsd_malloc" = "xyes"; then
1437    using_custom_malloc=yes
1438 fi
1439 if test "x$tcmalloc" = "xyes"; then
1440    using_custom_malloc=yes
1441 fi
1442 if test "$using_custom_malloc" = "no"; then
1443    AC_CHECK_FUNCS(mallinfo)
1444 fi
1445
1446 # By default, we're going to assume we don't have mlockall()
1447 # bionic and other platforms have various broken mlockall subsystems.
1448 # Some systems don't have a working mlockall, some aren't linkable,
1449 # and some have it but don't declare it.
1450 AC_CHECK_FUNCS(mlockall)
1451 AC_CHECK_DECLS([mlockall], , , [
1452 #ifdef HAVE_SYS_MMAN_H
1453 #include <sys/mman.h>
1454 #endif])
1455
1456 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1457 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1458 # using macros
1459 AC_CHECK_DECLS([getpagesize], , , [
1460 #ifdef HAVE_UNISTD_H
1461 #include <unistd.h>
1462 #endif])
1463
1464 # Allow user to specify an alternate syslog facility
1465 AC_ARG_WITH(syslog-facility,
1466 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1467 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1468 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1469 AC_SUBST(LOGFACILITY)
1470
1471 # Check if we have getresuid and getresgid
1472 AC_CHECK_FUNCS(getresuid getresgid)
1473
1474 # Check for gethostbyname_r in all its glorious incompatible versions.
1475 #   (This logic is based on that in Python's configure.in)
1476 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1477   [Define this if you have any gethostbyname_r()])
1478
1479 AC_CHECK_FUNC(gethostbyname_r, [
1480   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1481   OLD_CFLAGS=$CFLAGS
1482   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1483   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1484 #include <netdb.h>
1485   ]], [[
1486     char *cp1, *cp2;
1487     struct hostent *h1, *h2;
1488     int i1, i2;
1489     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1490   ]])],[
1491     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1492     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1493      [Define this if gethostbyname_r takes 6 arguments])
1494     AC_MSG_RESULT(6)
1495   ], [
1496     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1497 #include <netdb.h>
1498     ]], [[
1499       char *cp1, *cp2;
1500       struct hostent *h1;
1501       int i1, i2;
1502       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1503     ]])], [
1504       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1505       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1506         [Define this if gethostbyname_r takes 5 arguments])
1507       AC_MSG_RESULT(5)
1508    ], [
1509       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1510 #include <netdb.h>
1511      ]], [[
1512        char *cp1;
1513        struct hostent *h1;
1514        struct hostent_data hd;
1515        (void) gethostbyname_r(cp1,h1,&hd);
1516      ]])], [
1517        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1518        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1519          [Define this if gethostbyname_r takes 3 arguments])
1520        AC_MSG_RESULT(3)
1521      ], [
1522        AC_MSG_RESULT(0)
1523      ])
1524   ])
1525  ])
1526  CFLAGS=$OLD_CFLAGS
1527 ])
1528
1529 AC_CACHE_CHECK([whether the C compiler supports __func__],
1530   tor_cv_have_func_macro,
1531   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1532 #include <stdio.h>
1533 int main(int c, char **v) { puts(__func__); }])],
1534   tor_cv_have_func_macro=yes,
1535   tor_cv_have_func_macro=no))
1536
1537 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1538   tor_cv_have_FUNC_macro,
1539   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1540 #include <stdio.h>
1541 int main(int c, char **v) { puts(__FUNC__); }])],
1542   tor_cv_have_FUNC_macro=yes,
1543   tor_cv_have_FUNC_macro=no))
1544
1545 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1546   tor_cv_have_FUNCTION_macro,
1547   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1548 #include <stdio.h>
1549 int main(int c, char **v) { puts(__FUNCTION__); }])],
1550   tor_cv_have_FUNCTION_macro=yes,
1551   tor_cv_have_FUNCTION_macro=no))
1552
1553 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1554   tor_cv_have_environ_declared,
1555   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1556 #ifdef HAVE_UNISTD_H
1557 #include <unistd.h>
1558 #endif
1559 #include <stdlib.h>
1560 int main(int c, char **v) { char **t = environ; }])],
1561   tor_cv_have_environ_declared=yes,
1562   tor_cv_have_environ_declared=no))
1563
1564 if test "$tor_cv_have_func_macro" = "yes"; then
1565   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1566 fi
1567
1568 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1569   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1570 fi
1571
1572 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1573   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1574            [Defined if the compiler supports __FUNCTION__])
1575 fi
1576
1577 if test "$tor_cv_have_environ_declared" = "yes"; then
1578   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1579            [Defined if we have extern char **environ already declared])
1580 fi
1581
1582 # $prefix stores the value of the --prefix command line option, or
1583 # NONE if the option wasn't set.  In the case that it wasn't set, make
1584 # it be the default, so that we can use it to expand directories now.
1585 if test "x$prefix" = "xNONE"; then
1586   prefix=$ac_default_prefix
1587 fi
1588
1589 # and similarly for $exec_prefix
1590 if test "x$exec_prefix" = "xNONE"; then
1591   exec_prefix=$prefix
1592 fi
1593
1594 if test "x$BUILDDIR" = "x"; then
1595   BUILDDIR=`pwd`
1596 fi
1597 AC_SUBST(BUILDDIR)
1598 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1599 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1600
1601 if test "x$CONFDIR" = "x"; then
1602   CONFDIR=`eval echo $sysconfdir/tor`
1603 fi
1604 AC_SUBST(CONFDIR)
1605 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1606 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1607
1608 BINDIR=`eval echo $bindir`
1609 AC_SUBST(BINDIR)
1610 LOCALSTATEDIR=`eval echo $localstatedir`
1611 AC_SUBST(LOCALSTATEDIR)
1612
1613 if test "$bwin32" = "true"; then
1614   # Test if the linker supports the --nxcompat and --dynamicbase options
1615   # for Windows
1616   save_LDFLAGS="$LDFLAGS"
1617   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1618   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1619   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1620     [AC_MSG_RESULT([yes])]
1621     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1622     [AC_MSG_RESULT([no])]
1623   )
1624   LDFLAGS="$save_LDFLAGS"
1625 fi
1626
1627 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1628 # than autoconf's macros like.
1629 if test "$GCC" = "yes"; then
1630   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1631   # accident waiting to happen.
1632   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1633 else
1634   # Override optimization level for non-gcc compilers
1635   CFLAGS="$CFLAGS -O"
1636   enable_gcc_warnings=no
1637   enable_gcc_warnings_advisory=no
1638 fi
1639
1640 # Warnings implies advisory-warnings and -Werror.
1641 if test "$enable_gcc_warnings" = "yes"; then
1642   enable_gcc_warnings_advisory=yes
1643   enable_fatal_warnings=yes
1644 fi
1645
1646 # OS X Lion started deprecating the system openssl. Let's just disable
1647 # all deprecation warnings on OS X. Also, to potentially make the binary
1648 # a little smaller, let's enable dead_strip.
1649 case "$host_os" in
1650
1651  darwin*)
1652     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1653     LDFLAGS="$LDFLAGS -dead_strip" ;;
1654 esac
1655
1656 # Add some more warnings which we use in development but not in the
1657 # released versions.  (Some relevant gcc versions can't handle these.)
1658 #
1659 # Note that we have to do this near the end  of the autoconf process, or
1660 # else we may run into problems when these warnings hit on the testing C
1661 # programs that autoconf wants to build.
1662 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1663
1664   case "$host" in
1665     *-*-openbsd* | *-*-bitrig*)
1666       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1667       # That's fine, except that the headers don't pass -Wredundant-decls.
1668       # Therefore, let's disable -Wsystem-headers when we're building
1669       # with maximal warnings on OpenBSD.
1670       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1671   esac
1672
1673   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1674   # have it work better.
1675   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1676
1677   # This warning was added in gcc 4.3, but it appears to generate
1678   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1679   #CFLAGS="$CFLAGS -Wlogical-op"
1680
1681   m4_foreach_w([warning_flag], [
1682      -Waddress
1683      -Waddress-of-array-temporary
1684      -Waddress-of-temporary
1685      -Wambiguous-macro
1686      -Wanonymous-pack-parens
1687      -Warc
1688      -Warc-abi
1689      -Warc-bridge-casts-disallowed-in-nonarc
1690      -Warc-maybe-repeated-use-of-weak
1691      -Warc-performSelector-leaks
1692      -Warc-repeated-use-of-weak
1693      -Warray-bounds
1694      -Warray-bounds-pointer-arithmetic
1695      -Wasm
1696      -Wasm-operand-widths
1697      -Watomic-properties
1698      -Watomic-property-with-user-defined-accessor
1699      -Wauto-import
1700      -Wauto-storage-class
1701      -Wauto-var-id
1702      -Wavailability
1703      -Wbackslash-newline-escape
1704      -Wbad-array-new-length
1705      -Wbind-to-temporary-copy
1706      -Wbitfield-constant-conversion
1707      -Wbool-conversion
1708      -Wbool-conversions
1709      -Wbuiltin-requires-header
1710      -Wchar-align
1711      -Wcompare-distinct-pointer-types
1712      -Wcomplex-component-init
1713      -Wconditional-type-mismatch
1714      -Wconfig-macros
1715      -Wconstant-conversion
1716      -Wconstant-logical-operand
1717      -Wconstexpr-not-const
1718      -Wcustom-atomic-properties
1719      -Wdangling-field
1720      -Wdangling-initializer-list
1721      -Wdate-time
1722      -Wdelegating-ctor-cycles
1723      -Wdeprecated-implementations
1724      -Wdeprecated-register
1725      -Wdirect-ivar-access
1726      -Wdiscard-qual
1727      -Wdistributed-object-modifiers
1728      -Wdivision-by-zero
1729      -Wdollar-in-identifier-extension
1730      -Wdouble-promotion
1731      -Wduplicate-decl-specifier
1732      -Wduplicate-enum
1733      -Wduplicate-method-arg
1734      -Wduplicate-method-match
1735      -Wduplicated-cond
1736      -Wdynamic-class-memaccess
1737      -Wembedded-directive
1738      -Wempty-translation-unit
1739      -Wenum-conversion
1740      -Wexit-time-destructors
1741      -Wexplicit-ownership-type
1742      -Wextern-initializer
1743      -Wextra
1744      -Wextra-semi
1745      -Wextra-tokens
1746      -Wflexible-array-extensions
1747      -Wfloat-conversion
1748      -Wformat-non-iso
1749      -Wfour-char-constants
1750      -Wgcc-compat
1751      -Wglobal-constructors
1752      -Wgnu-array-member-paren-init
1753      -Wgnu-designator
1754      -Wgnu-static-float-init
1755      -Wheader-guard
1756      -Wheader-hygiene
1757      -Widiomatic-parentheses
1758      -Wignored-attributes
1759      -Wimplicit-atomic-properties
1760      -Wimplicit-conversion-floating-point-to-bool
1761      -Wimplicit-exception-spec-mismatch
1762      -Wimplicit-fallthrough
1763      -Wimplicit-fallthrough-per-function
1764      -Wimplicit-retain-self
1765      -Wimport-preprocessor-directive-pedantic
1766      -Wincompatible-library-redeclaration
1767      -Wincompatible-pointer-types-discards-qualifiers
1768      -Wincomplete-implementation
1769      -Wincomplete-module
1770      -Wincomplete-umbrella
1771      -Winit-self
1772      -Wint-conversions
1773      -Wint-to-void-pointer-cast
1774      -Winteger-overflow
1775      -Winvalid-constexpr
1776      -Winvalid-iboutlet
1777      -Winvalid-noreturn
1778      -Winvalid-pp-token
1779      -Winvalid-source-encoding
1780      -Winvalid-token-paste
1781      -Wknr-promoted-parameter
1782      -Wlanguage-extension-token
1783      -Wlarge-by-value-copy
1784      -Wliteral-conversion
1785      -Wliteral-range
1786      -Wlocal-type-template-args
1787      -Wlogical-op
1788      -Wloop-analysis
1789      -Wmain-return-type
1790      -Wmalformed-warning-check
1791      -Wmethod-signatures
1792      -Wmicrosoft
1793      -Wmicrosoft-exists
1794      -Wmismatched-parameter-types
1795      -Wmismatched-return-types
1796      -Wmissing-field-initializers
1797      -Wmissing-format-attribute
1798      -Wmissing-noreturn
1799      -Wmissing-selector-name
1800      -Wmissing-sysroot
1801      -Wmissing-variable-declarations
1802      -Wmodule-conflict
1803      -Wnested-anon-types
1804      -Wnewline-eof
1805      -Wnon-literal-null-conversion
1806      -Wnon-pod-varargs
1807      -Wnonportable-cfstrings
1808      -Wnormalized=id
1809      -Wnull-arithmetic
1810      -Wnull-character
1811      -Wnull-conversion
1812      -Wnull-dereference
1813      -Wout-of-line-declaration
1814      -Wover-aligned
1815      -Woverlength-strings
1816      -Woverride-init
1817      -Woverriding-method-mismatch
1818      -Wpointer-type-mismatch
1819      -Wpredefined-identifier-outside-function
1820      -Wprotocol-property-synthesis-ambiguity
1821      -Wreadonly-iboutlet-property
1822      -Wreadonly-setter-attrs
1823      -Wreceiver-expr
1824      -Wreceiver-forward-class
1825      -Wreceiver-is-weak
1826      -Wreinterpret-base-class
1827      -Wrequires-super-attribute
1828      -Wreserved-user-defined-literal
1829      -Wreturn-stack-address
1830      -Wsection
1831      -Wselector-type-mismatch
1832      -Wsentinel
1833      -Wserialized-diagnostics
1834      -Wshadow
1835      -Wshift-count-negative
1836      -Wshift-count-overflow
1837      -Wshift-negative-value
1838      -Wshift-overflow=2
1839      -Wshift-sign-overflow
1840      -Wshorten-64-to-32
1841      -Wsizeof-array-argument
1842      -Wsource-uses-openmp
1843      -Wstatic-float-init
1844      -Wstatic-in-inline
1845      -Wstatic-local-in-inline
1846      -Wstrict-overflow=1
1847      -Wstring-compare
1848      -Wstring-conversion
1849      -Wstrlcpy-strlcat-size
1850      -Wstrncat-size
1851      -Wsuggest-attribute=format
1852      -Wsuggest-attribute=noreturn
1853      -Wsuper-class-method-mismatch
1854      -Wswitch-bool
1855      -Wsync-nand
1856      -Wtautological-constant-out-of-range-compare
1857      -Wtentative-definition-incomplete-type
1858      -Wtrampolines
1859      -Wtype-safety
1860      -Wtypedef-redefinition
1861      -Wtypename-missing
1862      -Wundefined-inline
1863      -Wundefined-internal
1864      -Wundefined-reinterpret-cast
1865      -Wunicode
1866      -Wunicode-whitespace
1867      -Wunknown-warning-option
1868      -Wunnamed-type-template-args
1869      -Wunneeded-member-function
1870      -Wunsequenced
1871      -Wunsupported-visibility
1872      -Wunused-but-set-parameter
1873      -Wunused-but-set-variable
1874      -Wunused-command-line-argument
1875      -Wunused-const-variable=2
1876      -Wunused-exception-parameter
1877      -Wunused-local-typedefs
1878      -Wunused-member-function
1879      -Wunused-sanitize-argument
1880      -Wunused-volatile-lvalue
1881      -Wuser-defined-literals
1882      -Wvariadic-macros
1883      -Wvector-conversion
1884      -Wvector-conversions
1885      -Wvexing-parse
1886      -Wvisibility
1887      -Wvla-extension
1888      -Wzero-length-array
1889   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
1890
1891 dnl    We should re-enable this in some later version.  Clang doesn't
1892 dnl    mind, but it causes trouble with GCC.
1893 dnl     -Wstrict-overflow=2
1894
1895 dnl    These seem to require annotations that we don't currently use,
1896 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
1897 dnl     -Wthread-safety
1898 dnl     -Wthread-safety-analysis
1899 dnl     -Wthread-safety-attributes
1900 dnl     -Wthread-safety-beta
1901 dnl     -Wthread-safety-precise
1902
1903   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1904   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1905   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1906   CFLAGS="$CFLAGS -Wwrite-strings"
1907   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1908   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
1909   CFLAGS="$CFLAGS -Wunused-parameter "
1910   # These interfere with building main() { return 0; }, which autoconf
1911   # likes to use as its default program.
1912   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
1913
1914   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
1915     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
1916   fi
1917   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
1918     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
1919   fi
1920
1921   if test "x$enable_fatal_warnings" = "xyes"; then
1922     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
1923     # default autoconf programs are full of errors.
1924     CFLAGS="$CFLAGS -Werror"
1925   fi
1926
1927 fi
1928
1929 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
1930    case "$host_os" in
1931     darwin*)
1932       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
1933    esac
1934 fi
1935
1936 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1937
1938 AC_CONFIG_FILES([
1939         Doxyfile
1940         Makefile
1941         contrib/dist/suse/tor.sh
1942         contrib/operator-tools/tor.logrotate
1943         contrib/dist/tor.sh
1944         contrib/dist/torctl
1945         contrib/dist/tor.service
1946         src/config/torrc.sample
1947         src/config/torrc.minimal
1948         scripts/maint/checkOptionDocs.pl
1949         scripts/maint/updateVersions.pl
1950 ])
1951
1952 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
1953   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
1954   for file in $regular_mans ; do
1955     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
1956       echo "==================================";
1957       echo;
1958       echo "Building Tor has failed since manpages cannot be built.";
1959       echo;
1960       echo "You need asciidoc installed to be able to build the manpages.";
1961       echo "To build without manpages, use the --disable-asciidoc argument";
1962       echo "when calling configure.";
1963       echo;
1964       echo "==================================";
1965       exit 1;
1966     fi
1967   done
1968 fi
1969
1970 if test "$fragile_hardening" = "yes"; then
1971   AC_MSG_WARN([
1972
1973 ============
1974 Warning!  Building Tor with --enable-fragile-hardening (also known as
1975 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
1976 other kinds of attacks easier. A Tor instance build with this option will be
1977 somewhat less vulnerable to remote code execution, arithmetic overflow, or
1978 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
1979 denial of service attacks. For more information, see
1980 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
1981 ============
1982   ])
1983 fi
1984
1985 AC_OUTPUT