configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2015, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT([tor],[0.2.8.0-alpha-dev])
   7 AC_CONFIG_SRCDIR([src/or/main.c])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_INIT_AUTOMAKE
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AC_CONFIG_HEADERS([orconfig.h])
  12
  13 AC_CANONICAL_HOST
  14
  15 PKG_PROG_PKG_CONFIG
  16
  17 if test -f /etc/redhat-release ; then
  18   if test -f /usr/kerberos/include ; then
  19     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  20   fi
  21 fi
  22
  23 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  24 # the += operator on it in src/or/Makefile.am
  25 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  26
  27 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  28 AC_ARG_ENABLE(openbsd-malloc,
  29    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  30 AC_ARG_ENABLE(instrument-downloads,
  31    AS_HELP_STRING(--enable-instrument-downloads, [instrument downloads of directory resources etc.]))
  32 AC_ARG_ENABLE(static-openssl,
  33    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  34 AC_ARG_ENABLE(static-libevent,
  35    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  36 AC_ARG_ENABLE(static-zlib,
  37    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  38 AC_ARG_ENABLE(static-tor,
  39    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  40 AC_ARG_ENABLE(unittests,
  41    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  42 AC_ARG_ENABLE(coverage,
  43    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  44 AC_ARG_ENABLE(system-torrc,
  45    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  46
  47 AM_CONDITIONAL(UNITTESTS_ENABLED, test x$enable_unittests != xno)
  48 AM_CONDITIONAL(COVERAGE_ENABLED, test x$enable_coverage = xyes)
  49
  50 if test "$enable_static_tor" = "yes"; then
  51   enable_static_libevent="yes";
  52   enable_static_openssl="yes";
  53   enable_static_zlib="yes";
  54   CFLAGS="$CFLAGS -static"
  55 fi
  56
  57 if test "$enable_system_torrc" = "no"; then
  58   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  59             [Defined if we're not going to look for a torrc in SYSCONF])
  60 fi
  61
  62 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  63 if test x$enable_instrument_downloads = xyes; then
  64   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  65             [Defined if we want to keep track of how much of each kind of resource we download.])
  66 fi
  67
  68 AC_ARG_ENABLE(transparent,
  69      AS_HELP_STRING(--disable-transparent, [disable transparent proxy support]),
  70      [case "${enableval}" in
  71         yes) transparent=true ;;
  72         no)  transparent=false ;;
  73         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  74       esac], [transparent=true])
  75
  76 AC_ARG_ENABLE(asciidoc,
  77      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  78      [case "${enableval}" in
  79         yes) asciidoc=true ;;
  80         no)  asciidoc=false ;;
  81         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  82       esac], [asciidoc=true])
  83
  84 # systemd notify support
  85 AC_ARG_ENABLE(systemd,
  86       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  87       [case "${enableval}" in
  88         yes) systemd=true ;;
  89         no)  systemd=false ;;
  90         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
  91       esac], [systemd=auto])
  92
  93
  94
  95 # systemd support
  96 if test x$enable_systemd = xno ; then
  97     have_systemd=no;
  98 else
  99     PKG_CHECK_MODULES(SYSTEMD,
 100         [libsystemd-daemon],
 101         have_systemd=yes,
 102         have_systemd=no)
 103     if test x$have_systemd=xno; then
 104         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 105         PKG_CHECK_MODULES(SYSTEMD,
 106             [libsystemd],
 107             have_systemd=yes,
 108             have_systemd=no)
 109     fi
 110 fi
 111
 112 if test x$have_systemd = xyes; then
 113     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 114     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 115     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 116     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 117          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 118 fi
 119 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 120 AC_SUBST(TOR_SYSTEMD_LIBS)
 121
 122 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
 123     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 124 fi
 125
 126 case $host in
 127    *-*-solaris* )
 128      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 129      ;;
 130 esac
 131
 132 AC_ARG_ENABLE(gcc-warnings,
 133      AS_HELP_STRING(--enable-gcc-warnings, [enable verbose warnings]))
 134 AC_ARG_ENABLE(gcc-warnings-advisory,
 135      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
 136
 137 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 138 AC_ARG_ENABLE(gcc-hardening,
 139     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 140
 141 AC_ARG_ENABLE(expensive-hardening,
 142     AS_HELP_STRING(--enable-expensive-hardening, [enable more expensive compiler hardening; makes Tor slower]))
 143
 144 dnl Linker hardening options
 145 dnl Currently these options are ELF specific - you can't use this with MacOSX
 146 AC_ARG_ENABLE(linker-hardening,
 147     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 148
 149 AC_ARG_ENABLE(local-appdata,
 150    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 151 if test "$enable_local_appdata" = "yes"; then
 152   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 153             [Defined if we default to host local appdata paths on Windows])
 154 fi
 155
 156 # Tor2web mode flag
 157 AC_ARG_ENABLE(tor2web-mode,
 158      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 159 [if test x$enableval = xyes; then
 160     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 161 fi])
 162
 163 AC_ARG_ENABLE(bufferevents,
 164      AS_HELP_STRING(--enable-bufferevents, [use Libevent's buffered IO]))
 165
 166 AC_ARG_ENABLE(tool-name-check,
 167      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 168
 169 AC_ARG_ENABLE(seccomp,
 170      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 171
 172 AC_ARG_ENABLE(libscrypt,
 173      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 174
 175 dnl check for the correct "ar" when cross-compiling
 176 AN_MAKEVAR([AR], [AC_PROG_AR])
 177 AN_PROGRAM([ar], [AC_PROG_AR])
 178 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
 179 AC_PROG_AR
 180
 181 dnl Check whether the above macro has settled for a simply named tool even
 182 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 183 dnl because that will find any cc on the system, not only the cross-compiler,
 184 dnl and then verify that a binary built with this compiler runs on the
 185 dnl build system. It will then come to the false conclusion that we're not
 186 dnl cross-compiling.
 187 if test x$enable_tool_name_check != xno; then
 188     if test x$ac_tool_warned = xyes; then
 189         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 190         elif test "x$ac_ct_AR" != x -a x$cross_compiling = xmaybe; then
 191                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 192         fi
 193 fi
 194
 195 AC_PROG_CC
 196 AC_PROG_CPP
 197 AC_PROG_MAKE_SET
 198 AC_PROG_RANLIB
 199
 200 AC_PATH_PROG([PERL], [perl])
 201
 202 dnl autoconf 2.59 appears not to support AC_PROG_SED
 203 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 204
 205 dnl check for asciidoc and a2x
 206 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 207 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 208
 209 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 210
 211 AM_CONDITIONAL(USE_FW_HELPER, test x$natpmp = xtrue || test x$upnp = xtrue)
 212 AM_CONDITIONAL(NAT_PMP, test x$natpmp = xtrue)
 213 AM_CONDITIONAL(MINIUPNPC, test x$upnp = xtrue)
 214 AM_PROG_CC_C_O
 215 AC_PROG_CC_C99
 216
 217 AC_ARG_VAR([PYTHON], [path to Python binary])
 218 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 219 if test "x$PYTHON" = "x"; then
 220   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 221 fi
 222 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 223
 224 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 225 AC_C_FLEXIBLE_ARRAY_MEMBER
 226 ], [
 227  dnl Maybe we've got an old autoconf...
 228  AC_CACHE_CHECK([for flexible array members],
 229      tor_cv_c_flexarray,
 230      [AC_COMPILE_IFELSE(
 231        AC_LANG_PROGRAM([
 232  struct abc { int a; char b[]; };
 233 ], [
 234  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 235  def->b[0] = 33;
 236 ]),
 237   [tor_cv_c_flexarray=yes],
 238   [tor_cv_c_flexarray=no])])
 239  if test $tor_cv_flexarray = yes ; then
 240    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 241  else
 242    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 243  fi
 244 ])
 245
 246 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 247       tor_cv_c_c99_decl,
 248       [AC_COMPILE_IFELSE(
 249          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 250          [tor_cv_c_c99_decl=yes],
 251          [tor_cv_c_c99_decl=no] )])
 252 if test "$tor_cv_c_c99_decl" != "yes"; then
 253   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 254 fi
 255
 256 AC_CACHE_CHECK([for working C99 designated initializers],
 257       tor_cv_c_c99_designated_init,
 258       [AC_COMPILE_IFELSE(
 259          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 260                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 261          [tor_cv_c_c99_designated_init=yes],
 262          [tor_cv_c_c99_designated_init=no] )])
 263
 264 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 265   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 266 fi
 267
 268 TORUSER=_tor
 269 AC_ARG_WITH(tor-user,
 270         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 271         [
 272            TORUSER=$withval
 273         ]
 274 )
 275 AC_SUBST(TORUSER)
 276
 277 TORGROUP=_tor
 278 AC_ARG_WITH(tor-group,
 279         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 280         [
 281            TORGROUP=$withval
 282         ]
 283 )
 284 AC_SUBST(TORGROUP)
 285
 286
 287 dnl If _WIN32 is defined and non-zero, we are building for win32
 288 AC_MSG_CHECKING([for win32])
 289 AC_RUN_IFELSE([AC_LANG_SOURCE([
 290 int main(int c, char **v) {
 291 #ifdef _WIN32
 292 #if _WIN32
 293   return 0;
 294 #else
 295   return 1;
 296 #endif
 297 #else
 298   return 2;
 299 #endif
 300 }])],
 301 bwin32=true; AC_MSG_RESULT([yes]),
 302 bwin32=false; AC_MSG_RESULT([no]),
 303 bwin32=cross; AC_MSG_RESULT([cross])
 304 )
 305
 306 if test "$bwin32" = cross; then
 307 AC_MSG_CHECKING([for win32 (cross)])
 308 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 309 #ifdef _WIN32
 310 int main(int c, char **v) {return 0;}
 311 #else
 312 #error
 313 int main(int c, char **v) {return x(y);}
 314 #endif
 315 ])],
 316 bwin32=true; AC_MSG_RESULT([yes]),
 317 bwin32=false; AC_MSG_RESULT([no]))
 318 fi
 319
 320 AH_BOTTOM([
 321 #ifdef _WIN32
 322 /* Defined to access windows functions and definitions for >=WinXP */
 323 # ifndef WINVER
 324 #  define WINVER 0x0501
 325 # endif
 326
 327 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 328 # ifndef _WIN32_WINNT
 329 #  define _WIN32_WINNT 0x0501
 330 # endif
 331
 332 /* Defined to avoid including some windows headers as part of Windows.h */
 333 # ifndef WIN32_LEAN_AND_MEAN
 334 #  define WIN32_LEAN_AND_MEAN 1
 335 # endif
 336 #endif
 337 ])
 338
 339
 340 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 341
 342 dnl Enable C99 when compiling with MIPSpro
 343 AC_MSG_CHECKING([for MIPSpro compiler])
 344 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 345 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 346 #error
 347   return x(y);
 348 #endif
 349 ])],
 350 bmipspro=false; AC_MSG_RESULT(no),
 351 bmipspro=true; AC_MSG_RESULT(yes))
 352
 353 if test "$bmipspro" = true; then
 354   CFLAGS="$CFLAGS -c99"
 355 fi
 356
 357 AC_C_BIGENDIAN
 358
 359 AC_SEARCH_LIBS(socket, [socket network])
 360 AC_SEARCH_LIBS(gethostbyname, [nsl])
 361 AC_SEARCH_LIBS(dlopen, [dl])
 362 AC_SEARCH_LIBS(inet_aton, [resolv])
 363 AC_SEARCH_LIBS(backtrace, [execinfo])
 364 saved_LIBS="$LIBS"
 365 AC_SEARCH_LIBS([clock_gettime], [rt])
 366 if test "$LIBS" != "$saved_LIBS"; then
 367    # Looks like we need -lrt for clock_gettime().
 368    have_rt=yes
 369 fi
 370
 371 AC_SEARCH_LIBS(pthread_create, [pthread])
 372 AC_SEARCH_LIBS(pthread_detach, [pthread])
 373
 374 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 375 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 376
 377 AC_CHECK_FUNCS(
 378         _NSGetEnviron \
 379         accept4 \
 380         backtrace \
 381         backtrace_symbols_fd \
 382         clock_gettime \
 383         eventfd \
 384         flock \
 385         ftime \
 386         getaddrinfo \
 387         getifaddrs \
 388         getpass \
 389         getrlimit \
 390         gettimeofday \
 391         gmtime_r \
 392         inet_aton \
 393         ioctl \
 394         issetugid \
 395         llround \
 396         localtime_r \
 397         lround \
 398         memmem \
 399         pipe \
 400         pipe2 \
 401         prctl \
 402         readpassphrase \
 403         rint \
 404         sigaction \
 405         socketpair \
 406         statvfs \
 407         strlcat \
 408         strlcpy \
 409         strnlen \
 410         strptime \
 411         strtok_r \
 412         strtoull \
 413         sysconf \
 414         sysctl \
 415         uname \
 416         usleep \
 417         vasprintf \
 418         _vscprintf
 419 )
 420
 421 if test "$bwin32" != true; then
 422   AC_CHECK_HEADERS(pthread.h)
 423   AC_CHECK_FUNCS(pthread_create)
 424 fi
 425
 426 if test "$bwin32" = true; then
 427   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 428 #include <windows.h>
 429 #include <conio.h>
 430 #include <wchar.h>
 431                  ])
 432 fi
 433
 434 AM_CONDITIONAL(BUILD_READPASSPHRASE_C, test x$ac_cv_func_readpassphrase = xno && test $bwin32 = false)
 435
 436 dnl ------------------------------------------------------
 437 dnl Where do you live, libevent?  And how do we call you?
 438
 439 if test "$bwin32" = true; then
 440   TOR_LIB_WS32=-lws2_32
 441   TOR_LIB_IPHLPAPI=-liphlpapi
 442   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 443   # think it's actually necessary.
 444   TOR_LIB_GDI=-lgdi32
 445 else
 446   TOR_LIB_WS32=
 447   TOR_LIB_GDI=
 448 fi
 449 AC_SUBST(TOR_LIB_WS32)
 450 AC_SUBST(TOR_LIB_GDI)
 451 AC_SUBST(TOR_LIB_IPHLPAPI)
 452
 453 tor_libevent_pkg_redhat="libevent"
 454 tor_libevent_pkg_debian="libevent-dev"
 455 tor_libevent_devpkg_redhat="libevent-devel"
 456 tor_libevent_devpkg_debian="libevent-dev"
 457
 458 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 459 dnl linking for static builds.
 460 STATIC_LIBEVENT_FLAGS=""
 461 if test "$enable_static_libevent" = "yes"; then
 462     if test "$have_rt" = yes; then
 463       STATIC_LIBEVENT_FLAGS=" -lrt "
 464     fi
 465 fi
 466
 467 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 468 #ifdef _WIN32
 469 #include <winsock2.h>
 470 #endif
 471 #include <stdlib.h>
 472 #include <sys/time.h>
 473 #include <sys/types.h>
 474 #include <event.h>], [
 475 #ifdef _WIN32
 476 #include <winsock2.h>
 477 #endif
 478 void exit(int); void *event_init(void);],
 479     [
 480 #ifdef _WIN32
 481 {WSADATA d; WSAStartup(0x101,&d); }
 482 #endif
 483 event_init(); exit(0);
 484 ], [--with-libevent-dir], [/opt/libevent])
 485
 486 dnl Now check for particular libevent functions.
 487 save_LIBS="$LIBS"
 488 save_LDFLAGS="$LDFLAGS"
 489 save_CPPFLAGS="$CPPFLAGS"
 490 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
 491 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 492 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 493 AC_CHECK_FUNCS([event_get_version_number \
 494                 evutil_secure_rng_set_urandom_device_file \
 495                 evutil_secure_rng_init \
 496                ])
 497 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 498 [#include <event.h>
 499 ])
 500
 501 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 502
 503 LIBS="$save_LIBS"
 504 LDFLAGS="$save_LDFLAGS"
 505 CPPFLAGS="$save_CPPFLAGS"
 506
 507
 508 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 509
 510 if test "$enable_static_libevent" = "yes"; then
 511    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 512      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 513    else
 514      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 515    fi
 516 else
 517      TOR_LIBEVENT_LIBS="-levent"
 518 fi
 519
 520 dnl This isn't the best test for Libevent 2.0.3-alpha.  Once it's released,
 521 dnl we can do much better.
 522 if test "$enable_bufferevents" = "yes" ; then
 523   if test "$ac_cv_header_event2_bufferevent_ssl_h" != "yes" ; then
 524     AC_MSG_ERROR([You've asked for bufferevent support, but you're using a version of Libevent without SSL support.  This won't work.  We need Libevent 2.0.8-rc or later, and you don't seem to even have Libevent 2.0.3-alpha.])
 525   else
 526
 527     CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 528
 529     # Check for the right version.  First see if version detection works.
 530     AC_MSG_CHECKING([whether we can detect the Libevent version])
 531     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 532 #include <event2/event.h>
 533 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 10
 534 #error
 535 int x = y(zz);
 536 #else
 537 int x = 1;
 538 #endif
 539   ])], [event_version_number_works=yes; AC_MSG_RESULT([yes]) ],
 540      [event_version_number_works=no;  AC_MSG_RESULT([no])])
 541     if test "$event_version_number_works" != 'yes'; then
 542       AC_MSG_WARN([Version detection on Libevent seems broken.  Your Libevent installation is probably screwed up or very old.])
 543     else
 544       AC_MSG_CHECKING([whether Libevent is new enough for bufferevents])
 545       AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 546 #include <event2/event.h>
 547 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000d00
 548 #error
 549 int x = y(zz);
 550 #else
 551 int x = 1;
 552 #endif
 553    ])], [ AC_MSG_RESULT([yes]) ],
 554       [ AC_MSG_RESULT([no])
 555         AC_MSG_ERROR([Libevent does not seem new enough to support bufferevents.  We require 2.0.13-stable or later]) ] )
 556     fi
 557   fi
 558 fi
 559
 560 LIBS="$save_LIBS"
 561 LDFLAGS="$save_LDFLAGS"
 562 CPPFLAGS="$save_CPPFLAGS"
 563
 564 AM_CONDITIONAL(USE_BUFFEREVENTS, test "$enable_bufferevents" = "yes")
 565 if test "$enable_bufferevents" = "yes"; then
 566   AC_DEFINE(USE_BUFFEREVENTS, 1, [Defined if we're going to use Libevent's buffered IO API])
 567   if test "$enable_static_libevent" = "yes"; then
 568     TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent_openssl.a $TOR_LIBEVENT_LIBS"
 569   else
 570     TOR_LIBEVENT_LIBS="-levent_openssl $TOR_LIBEVENT_LIBS"
 571   fi
 572 fi
 573 AC_SUBST(TOR_LIBEVENT_LIBS)
 574
 575 dnl ------------------------------------------------------
 576 dnl Where do you live, libm?
 577
 578 dnl On some platforms (Haiku/BeOS) the math library is
 579 dnl part of libroot. In which case don't link against lm
 580 TOR_LIB_MATH=""
 581 save_LIBS="$LIBS"
 582 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 583 if test "$ac_cv_search_pow" != "none required"; then
 584     TOR_LIB_MATH="$ac_cv_search_pow"
 585 fi
 586 LIBS="$save_LIBS"
 587 AC_SUBST(TOR_LIB_MATH)
 588
 589 dnl ------------------------------------------------------
 590 dnl Where do you live, openssl?  And how do we call you?
 591
 592 tor_openssl_pkg_redhat="openssl"
 593 tor_openssl_pkg_debian="libssl-dev"
 594 tor_openssl_devpkg_redhat="openssl-devel"
 595 tor_openssl_devpkg_debian="libssl-dev"
 596
 597 ALT_openssl_WITHVAL=""
 598 AC_ARG_WITH(ssl-dir,
 599   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 600   [
 601       if test "x$withval" != xno && test "x$withval" != "x" ; then
 602          ALT_openssl_WITHVAL="$withval"
 603       fi
 604   ])
 605
 606 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 607     [#include <openssl/rand.h>],
 608     [void RAND_add(const void *buf, int num, double entropy);],
 609     [RAND_add((void*)0,0,0); exit(0);], [],
 610     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 611
 612 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 613
 614 if test "$enable_static_openssl" = "yes"; then
 615    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 616      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 617    else
 618      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 619    fi
 620 else
 621      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 622 fi
 623 AC_SUBST(TOR_OPENSSL_LIBS)
 624
 625 dnl Now check for particular openssl functions.
 626 save_LIBS="$LIBS"
 627 save_LDFLAGS="$LDFLAGS"
 628 save_CPPFLAGS="$CPPFLAGS"
 629 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 630 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 631 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 632
 633 AC_TRY_COMPILE([
 634 #include <openssl/opensslv.h>
 635 #if OPENSSL_VERSION_NUMBER < 0x1000000fL
 636 #error "too old"
 637 #endif
 638    ], [],
 639    [ : ],
 640    [ AC_ERROR([OpenSSL is too old. We require 1.0.0 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 641
 642 AC_TRY_COMPILE([
 643 #include <openssl/opensslv.h>
 644 #include <openssl/evp.h>
 645 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 646 #error "no ECC"
 647 #endif
 648 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 649 #error "curves unavailable"
 650 #endif
 651    ], [],
 652    [ : ],
 653    [ AC_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 654
 655 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 656 [#include <openssl/ssl.h>
 657 ])
 658
 659 AC_CHECK_FUNCS([ \
 660                 SSL_SESSION_get_master_key \
 661                 SSL_get_server_random \
 662                 SSL_get_client_ciphers \
 663                 SSL_get_client_random \
 664                 SSL_CIPHER_find \
 665                 TLS_method
 666                ])
 667
 668 dnl Check if OpenSSL has scrypt implementation.
 669 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 670
 671 LIBS="$save_LIBS"
 672 LDFLAGS="$save_LDFLAGS"
 673 CPPFLAGS="$save_CPPFLAGS"
 674
 675 dnl ------------------------------------------------------
 676 dnl Where do you live, zlib?  And how do we call you?
 677
 678 tor_zlib_pkg_redhat="zlib"
 679 tor_zlib_pkg_debian="zlib1g"
 680 tor_zlib_devpkg_redhat="zlib-devel"
 681 tor_zlib_devpkg_debian="zlib1g-dev"
 682
 683 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 684     [#include <zlib.h>],
 685     [const char * zlibVersion(void);],
 686     [zlibVersion(); exit(0);], [--with-zlib-dir],
 687     [/opt/zlib])
 688
 689 if test "$enable_static_zlib" = "yes"; then
 690    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 691      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 692  using --enable-static-zlib")
 693    else
 694      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 695    fi
 696 else
 697      TOR_ZLIB_LIBS="-lz"
 698 fi
 699 AC_SUBST(TOR_ZLIB_LIBS)
 700
 701 dnl ---------------------------------------------------------------------
 702 dnl Now that we know about our major libraries, we can check for compiler
 703 dnl and linker hardening options.  We need to do this with the libraries known,
 704 dnl since sometimes the linker will like an option but not be willing to
 705 dnl use it with a build of a library.
 706
 707 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 708 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI"
 709
 710 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 711 #if !defined(__clang__)
 712 #error
 713 #endif])], have_clang=yes, have_clang=no)
 714
 715 if test x$enable_gcc_hardening != xno; then
 716     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2"
 717     if test x$have_clang = xyes; then
 718         TOR_CHECK_CFLAGS(-Qunused-arguments)
 719     fi
 720     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 721     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 722     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 723 m4_ifdef([AS_VAR_IF],[
 724     AS_VAR_IF(can_compile, [yes],
 725         AS_VAR_IF(can_link, [yes],
 726                   [],
 727                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 728         )])
 729     AS_VAR_POPDEF([can_link])
 730     AS_VAR_POPDEF([can_compile])
 731     TOR_CHECK_CFLAGS(-Wstack-protector)
 732     TOR_CHECK_CFLAGS(-fwrapv)
 733     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 734     if test "$bwin32" = "false"; then
 735        TOR_CHECK_CFLAGS(-fPIE)
 736        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 737     fi
 738 fi
 739
 740 if test x$enable_expensive_hardening = xyes ; then
 741    TOR_CHECK_CFLAGS([-fsanitize=address])
 742    TOR_CHECK_CFLAGS([-fsanitize=undefined])
 743    TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 744 fi
 745
 746 if test x$enable_linker_hardening != xno; then
 747     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
 748 fi
 749
 750 # For backtrace support
 751 TOR_CHECK_LDFLAGS(-rdynamic)
 752
 753 dnl ------------------------------------------------------
 754 dnl Now see if we have a -fomit-frame-pointer compiler option.
 755
 756 saved_CFLAGS="$CFLAGS"
 757 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
 758 F_OMIT_FRAME_POINTER=''
 759 if test "$saved_CFLAGS" != "$CFLAGS"; then
 760   if test x$enable_expensive_hardening != xyes ; then
 761     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
 762   fi
 763 fi
 764 CFLAGS="$saved_CFLAGS"
 765 AC_SUBST(F_OMIT_FRAME_POINTER)
 766
 767 dnl ------------------------------------------------------
 768 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
 769 dnl for us, as GCC 4.6 and later do at many optimization levels), then
 770 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
 771 dnl code will work.
 772 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
 773
 774 dnl ============================================================
 775 dnl Check for libseccomp
 776
 777 if test "x$enable_seccomp" != "xno"; then
 778   AC_CHECK_HEADERS([seccomp.h])
 779   AC_SEARCH_LIBS(seccomp_init, [seccomp])
 780 fi
 781
 782 dnl ============================================================
 783 dnl Check for libscrypt
 784
 785 if test "x$enable_libscrypt" != "xno"; then
 786   AC_CHECK_HEADERS([libscrypt.h])
 787   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
 788 fi
 789
 790 dnl ============================================================
 791 dnl We need an implementation of curve25519.
 792
 793 dnl set these defaults.
 794 build_curve25519_donna=no
 795 build_curve25519_donna_c64=no
 796 use_curve25519_donna=no
 797 use_curve25519_nacl=no
 798 CURVE25519_LIBS=
 799
 800 dnl The best choice is using curve25519-donna-c64, but that requires
 801 dnl that we
 802 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
 803   tor_cv_can_use_curve25519_donna_c64,
 804   [AC_RUN_IFELSE(
 805     [AC_LANG_PROGRAM([dnl
 806       #include <stdint.h>
 807       typedef unsigned uint128_t __attribute__((mode(TI)));
 808   int func(uint64_t a, uint64_t b) {
 809            uint128_t c = ((uint128_t)a) * b;
 810            int ok = ((uint64_t)(c>>96)) == 522859 &&
 811              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 812                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 813                  (((uint64_t)(c))&0xffffffffL) == 0;
 814            return ok;
 815       }
 816   ], [dnl
 817     int ok = func( ((uint64_t)2000000000) * 1000000000,
 818                    ((uint64_t)1234567890) << 24);
 819         return !ok;
 820       ])],
 821   [tor_cv_can_use_curve25519_donna_c64=yes],
 822       [tor_cv_can_use_curve25519_donna_c64=no],
 823   [AC_LINK_IFELSE(
 824         [AC_LANG_PROGRAM([dnl
 825       #include <stdint.h>
 826       typedef unsigned uint128_t __attribute__((mode(TI)));
 827   int func(uint64_t a, uint64_t b) {
 828            uint128_t c = ((uint128_t)a) * b;
 829            int ok = ((uint64_t)(c>>96)) == 522859 &&
 830              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 831                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 832                  (((uint64_t)(c))&0xffffffffL) == 0;
 833            return ok;
 834       }
 835   ], [dnl
 836     int ok = func( ((uint64_t)2000000000) * 1000000000,
 837                  ((uint64_t)1234567890) << 24);
 838         return !ok;
 839       ])],
 840           [tor_cv_can_use_curve25519_donna_c64=cross],
 841       [tor_cv_can_use_curve25519_donna_c64=no])])])
 842
 843 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
 844                   nacl/crypto_scalarmult_curve25519.h])
 845
 846 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
 847   tor_cv_can_use_curve25519_nacl,
 848   [tor_saved_LIBS="$LIBS"
 849    LIBS="$LIBS -lnacl"
 850    AC_LINK_IFELSE(
 851      [AC_LANG_PROGRAM([dnl
 852        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
 853        #include <crypto_scalarmult_curve25519.h>
 854    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
 855    #include <nacl/crypto_scalarmult_curve25519.h>
 856    #endif
 857        #ifdef crypto_scalarmult_curve25519_ref_BYTES
 858    #error Hey, this is the reference implementation! That's not fast.
 859    #endif
 860      ], [
 861    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
 862      ])], [tor_cv_can_use_curve25519_nacl=yes],
 863      [tor_cv_can_use_curve25519_nacl=no])
 864    LIBS="$tor_saved_LIBS" ])
 865
 866  dnl Okay, now we need to figure out which one to actually use. Fall back
 867  dnl to curve25519-donna.c
 868
 869  if test x$tor_cv_can_use_curve25519_donna_c64 != xno; then
 870    build_curve25519_donna_c64=yes
 871    use_curve25519_donna=yes
 872  elif test x$tor_cv_can_use_curve25519_nacl = xyes; then
 873    use_curve25519_nacl=yes
 874    CURVE25519_LIBS=-lnacl
 875  else
 876    build_curve25519_donna=yes
 877    use_curve25519_donna=yes
 878  fi
 879
 880 if test x$use_curve25519_donna = xyes; then
 881   AC_DEFINE(USE_CURVE25519_DONNA, 1,
 882             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
 883 fi
 884 if test x$use_curve25519_nacl = xyes; then
 885   AC_DEFINE(USE_CURVE25519_NACL, 1,
 886             [Defined if we should use a curve25519 from nacl])
 887 fi
 888 AM_CONDITIONAL(BUILD_CURVE25519_DONNA, test x$build_curve25519_donna = xyes)
 889 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64, test x$build_curve25519_donna_c64 = xyes)
 890 AC_SUBST(CURVE25519_LIBS)
 891
 892 dnl Make sure to enable support for large off_t if available.
 893 AC_SYS_LARGEFILE
 894
 895 AC_CHECK_HEADERS(
 896         assert.h \
 897         errno.h \
 898         fcntl.h \
 899         signal.h \
 900         string.h \
 901         sys/fcntl.h \
 902         sys/stat.h \
 903         sys/time.h \
 904         sys/types.h \
 905         time.h \
 906         unistd.h
 907  , , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 908
 909 dnl These headers are not essential
 910
 911 AC_CHECK_HEADERS(
 912         arpa/inet.h \
 913         crt_externs.h \
 914         execinfo.h \
 915         grp.h \
 916         ifaddrs.h \
 917         inttypes.h \
 918         limits.h \
 919         linux/types.h \
 920         machine/limits.h \
 921         malloc.h \
 922         malloc/malloc.h \
 923         malloc_np.h \
 924         netdb.h \
 925         netinet/in.h \
 926         netinet/in6.h \
 927         pwd.h \
 928         readpassphrase.h \
 929         stdint.h \
 930         sys/eventfd.h \
 931         sys/file.h \
 932         sys/ioctl.h \
 933         sys/limits.h \
 934         sys/mman.h \
 935         sys/param.h \
 936         sys/prctl.h \
 937         sys/resource.h \
 938         sys/select.h \
 939         sys/socket.h \
 940         sys/statvfs.h \
 941         sys/sysctl.h \
 942         sys/syslimits.h \
 943         sys/time.h \
 944         sys/types.h \
 945         sys/un.h \
 946         sys/utime.h \
 947         sys/wait.h \
 948         syslog.h \
 949         utime.h
 950 )
 951
 952 AC_CHECK_HEADERS(sys/param.h)
 953
 954 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 955 [#ifdef HAVE_SYS_TYPES_H
 956 #include <sys/types.h>
 957 #endif
 958 #ifdef HAVE_SYS_SOCKET_H
 959 #include <sys/socket.h>
 960 #endif])
 961 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 962 [#ifdef HAVE_SYS_TYPES_H
 963 #include <sys/types.h>
 964 #endif
 965 #ifdef HAVE_SYS_SOCKET_H
 966 #include <sys/socket.h>
 967 #endif
 968 #ifdef HAVE_NET_IF_H
 969 #include <net/if.h>
 970 #endif])
 971
 972 AC_CHECK_HEADERS(linux/if.h,[],[],
 973 [
 974 #ifdef HAVE_SYS_SOCKET_H
 975 #include <sys/socket.h>
 976 #endif
 977 ])
 978
 979 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 980         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 981 [#ifdef HAVE_SYS_TYPES_H
 982 #include <sys/types.h>
 983 #endif
 984 #ifdef HAVE_SYS_SOCKET_H
 985 #include <sys/socket.h>
 986 #endif
 987 #ifdef HAVE_LIMITS_H
 988 #include <limits.h>
 989 #endif
 990 #ifdef HAVE_LINUX_TYPES_H
 991 #include <linux/types.h>
 992 #endif
 993 #ifdef HAVE_NETINET_IN6_H
 994 #include <netinet/in6.h>
 995 #endif
 996 #ifdef HAVE_NETINET_IN_H
 997 #include <netinet/in.h>
 998 #endif])
 999
1000 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1001         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1002 [#ifdef HAVE_SYS_TYPES_H
1003 #include <sys/types.h>
1004 #endif
1005 #ifdef HAVE_SYS_SOCKET_H
1006 #include <sys/socket.h>
1007 #endif
1008 #ifdef HAVE_LIMITS_H
1009 #include <limits.h>
1010 #endif
1011 #ifdef HAVE_LINUX_TYPES_H
1012 #include <linux/types.h>
1013 #endif
1014 #ifdef HAVE_NETINET_IN6_H
1015 #include <netinet/in6.h>
1016 #endif
1017 #ifdef HAVE_NETINET_IN_H
1018 #include <netinet/in.h>
1019 #endif
1020 #ifdef HAVE_LINUX_IF_H
1021 #include <linux/if.h>
1022 #endif])
1023
1024 if test x$transparent = xtrue ; then
1025    transparent_ok=0
1026    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
1027      transparent_ok=1
1028    fi
1029    if test x$linux_netfilter_ipv4 = x1 ; then
1030      transparent_ok=1
1031    fi
1032    if test x$linux_netfilter_ipv6_ip6_tables = x1 ; then
1033      transparent_ok=1
1034    fi
1035    if test x$transparent_ok = x1 ; then
1036      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1037      case $host in
1038        *-*-openbsd* | *-*-bitrig*)
1039          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
1040      esac
1041    else
1042      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1043    fi
1044 fi
1045
1046 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1047 [#ifdef HAVE_SYS_TYPES_H
1048 #include <sys/types.h>
1049 #endif
1050 #ifdef HAVE_SYS_TIME_H
1051 #include <sys/time.h>
1052 #endif])
1053
1054 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1055 dnl Watch out.
1056
1057 AC_CHECK_SIZEOF(int8_t)
1058 AC_CHECK_SIZEOF(int16_t)
1059 AC_CHECK_SIZEOF(int32_t)
1060 AC_CHECK_SIZEOF(int64_t)
1061 AC_CHECK_SIZEOF(uint8_t)
1062 AC_CHECK_SIZEOF(uint16_t)
1063 AC_CHECK_SIZEOF(uint32_t)
1064 AC_CHECK_SIZEOF(uint64_t)
1065 AC_CHECK_SIZEOF(intptr_t)
1066 AC_CHECK_SIZEOF(uintptr_t)
1067
1068 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1069
1070 AC_CHECK_SIZEOF(char)
1071 AC_CHECK_SIZEOF(short)
1072 AC_CHECK_SIZEOF(int)
1073 AC_CHECK_SIZEOF(long)
1074 AC_CHECK_SIZEOF(long long)
1075 AC_CHECK_SIZEOF(__int64)
1076 AC_CHECK_SIZEOF(void *)
1077 AC_CHECK_SIZEOF(time_t)
1078 AC_CHECK_SIZEOF(size_t)
1079 AC_CHECK_SIZEOF(pid_t)
1080
1081 AC_CHECK_TYPES([uint, u_char, ssize_t])
1082
1083 AC_PC_FROM_UCONTEXT([:])
1084
1085 dnl used to include sockaddr_storage, but everybody has that.
1086 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1087 [#ifdef HAVE_SYS_TYPES_H
1088 #include <sys/types.h>
1089 #endif
1090 #ifdef HAVE_NETINET_IN_H
1091 #include <netinet/in.h>
1092 #endif
1093 #ifdef HAVE_NETINET_IN6_H
1094 #include <netinet/in6.h>
1095 #endif
1096 #ifdef HAVE_SYS_SOCKET_H
1097 #include <sys/socket.h>
1098 #endif
1099 #ifdef _WIN32
1100 #define _WIN32_WINNT 0x0501
1101 #define WIN32_LEAN_AND_MEAN
1102 #include <winsock2.h>
1103 #include <ws2tcpip.h>
1104 #endif
1105 ])
1106 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1107 [#ifdef HAVE_SYS_TYPES_H
1108 #include <sys/types.h>
1109 #endif
1110 #ifdef HAVE_NETINET_IN_H
1111 #include <netinet/in.h>
1112 #endif
1113 #ifdef HAVE_NETINET_IN6_H
1114 #include <netinet/in6.h>
1115 #endif
1116 #ifdef HAVE_SYS_SOCKET_H
1117 #include <sys/socket.h>
1118 #endif
1119 #ifdef _WIN32
1120 #define _WIN32_WINNT 0x0501
1121 #define WIN32_LEAN_AND_MEAN
1122 #include <winsock2.h>
1123 #include <ws2tcpip.h>
1124 #endif
1125 #endif
1126 ])
1127
1128 AC_CHECK_TYPES([rlim_t], , ,
1129 [#ifdef HAVE_SYS_TYPES_H
1130 #include <sys/types.h>
1131 #endif
1132 #ifdef HAVE_SYS_TIME_H
1133 #include <sys/time.h>
1134 #endif
1135 #ifdef HAVE_SYS_RESOURCE_H
1136 #include <sys/resource.h>
1137 #endif
1138 ])
1139
1140 AX_CHECK_SIGN([time_t],
1141        [ AC_DEFINE(TIME_T_IS_SIGNED, 1, [Define if time_t is signed]) ],
1142        [ : ], [
1143 #ifdef HAVE_SYS_TYPES_H
1144 #include <sys/types.h>
1145 #endif
1146 #ifdef HAVE_SYS_TIME_H
1147 #include <sys/time.h>
1148 #endif
1149 #ifdef HAVE_TIME_H
1150 #include <time.h>
1151 #endif
1152 ])
1153
1154 if test "$ax_cv_decl_time_t_signed" = no; then
1155   AC_MSG_WARN([You have an unsigned time_t; some things will probably break. Please tell the Tor developers about your interesting platform.])
1156 fi
1157
1158 AX_CHECK_SIGN([size_t],
1159        [ tor_cv_size_t_signed=yes ],
1160        [ tor_cv_size_t_signed=no ], [
1161 #ifdef HAVE_SYS_TYPES_H
1162 #include <sys/types.h>
1163 #endif
1164 ])
1165
1166 if test "$ax_cv_decl_size_t_signed" = yes; then
1167   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1168 fi
1169
1170 AX_CHECK_SIGN([enum always],
1171        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1172        [ : ], [
1173  enum always { AAA, BBB, CCC };
1174 ])
1175
1176 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1177 #ifdef HAVE_SYS_SOCKET_H
1178 #include <sys/socket.h>
1179 #endif
1180 ])
1181
1182 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1183
1184 AC_CHECK_SIZEOF(cell_t)
1185
1186 # Now make sure that NULL can be represented as zero bytes.
1187 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1188 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1189 [[#include <stdlib.h>
1190 #include <string.h>
1191 #include <stdio.h>
1192 #ifdef HAVE_STDDEF_H
1193 #include <stddef.h>
1194 #endif
1195 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1196 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1197        [tor_cv_null_is_zero=yes],
1198        [tor_cv_null_is_zero=no],
1199        [tor_cv_null_is_zero=cross])])
1200
1201 if test "$tor_cv_null_is_zero" = cross ; then
1202   # Cross-compiling; let's hope that the target isn't raving mad.
1203   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1204 fi
1205
1206 if test "$tor_cv_null_is_zero" != no; then
1207   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1208             [Define to 1 iff memset(0) sets pointers to NULL])
1209 fi
1210
1211 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1212 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1213 [[#include <stdlib.h>
1214 #include <string.h>
1215 #include <stdio.h>
1216 #ifdef HAVE_STDDEF_H
1217 #include <stddef.h>
1218 #endif
1219 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1220 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1221        [tor_cv_dbl0_is_zero=yes],
1222        [tor_cv_dbl0_is_zero=no],
1223        [tor_cv_dbl0_is_zero=cross])])
1224
1225 if test "$tor_cv_dbl0_is_zero" = cross ; then
1226   # Cross-compiling; let's hope that the target isn't raving mad.
1227   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1228 fi
1229
1230 if test "$tor_cv_dbl0_is_zero" != no; then
1231   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1232             [Define to 1 iff memset(0) sets doubles to 0.0])
1233 fi
1234
1235 # And what happens when we malloc zero?
1236 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1237 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1238 [[#include <stdlib.h>
1239 #include <string.h>
1240 #include <stdio.h>
1241 #ifdef HAVE_STDDEF_H
1242 #include <stddef.h>
1243 #endif
1244 int main () { return malloc(0)?0:1; }]])],
1245        [tor_cv_malloc_zero_works=yes],
1246        [tor_cv_malloc_zero_works=no],
1247        [tor_cv_malloc_zero_works=cross])])
1248
1249 if test "$tor_cv_malloc_zero_works" = cross; then
1250   # Cross-compiling; let's hope that the target isn't raving mad.
1251   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1252 fi
1253
1254 if test "$tor_cv_malloc_zero_works" = yes; then
1255   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1256             [Define to 1 iff malloc(0) returns a pointer])
1257 fi
1258
1259 # whether we seem to be in a 2s-complement world.
1260 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1261 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1262 [[int main () { int problem = ((-99) != (~99)+1);
1263 return problem ? 1 : 0; }]])],
1264        [tor_cv_twos_complement=yes],
1265        [tor_cv_twos_complement=no],
1266        [tor_cv_twos_complement=cross])])
1267
1268 if test "$tor_cv_twos_complement" = cross ; then
1269   # Cross-compiling; let's hope that the target isn't raving mad.
1270   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1271 fi
1272
1273 if test "$tor_cv_twos_complement" != no ; then
1274   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1275             [Define to 1 iff we represent negative integers with two's complement])
1276 fi
1277
1278 # What does shifting a negative value do?
1279 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1280 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1281 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1282        [tor_cv_sign_extend=yes],
1283        [tor_cv_sign_extend=no],
1284        [tor_cv_sign_extend=cross])])
1285
1286 if test "$tor_cv_sign_extend" = cross ; then
1287   # Cross-compiling; let's hope that the target isn't raving mad.
1288   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1289 fi
1290
1291 if test "$tor_cv_sign_extend" != no ; then
1292   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1293             [Define to 1 iff right-shifting a negative value performs sign-extension])
1294 fi
1295
1296 # Whether we should use the dmalloc memory allocation debugging library.
1297 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1298 AC_ARG_WITH(dmalloc,
1299 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1300 [if [[ "$withval" = "yes" ]]; then
1301   dmalloc=1
1302   AC_MSG_RESULT(yes)
1303 else
1304   dmalloc=1
1305   AC_MSG_RESULT(no)
1306 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1307 )
1308
1309 if [[ $dmalloc -eq 1 ]]; then
1310   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1311   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1312   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1313   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1314 fi
1315
1316 AC_ARG_WITH(tcmalloc,
1317 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1318 [ tcmalloc=yes ], [ tcmalloc=no ])
1319
1320 if test x$tcmalloc = xyes ; then
1321    LDFLAGS="-ltcmalloc $LDFLAGS"
1322 fi
1323
1324 using_custom_malloc=no
1325 if test x$enable_openbsd_malloc = xyes ; then
1326    using_custom_malloc=yes
1327 fi
1328 if test x$tcmalloc = xyes ; then
1329    using_custom_malloc=yes
1330 fi
1331 if test $using_custom_malloc = no ; then
1332    AC_CHECK_FUNCS(mallinfo)
1333 fi
1334
1335 # By default, we're going to assume we don't have mlockall()
1336 # bionic and other platforms have various broken mlockall subsystems.
1337 # Some systems don't have a working mlockall, some aren't linkable,
1338 # and some have it but don't declare it.
1339 AC_CHECK_FUNCS(mlockall)
1340 AC_CHECK_DECLS([mlockall], , , [
1341 #ifdef HAVE_SYS_MMAN_H
1342 #include <sys/mman.h>
1343 #endif])
1344
1345 # Allow user to specify an alternate syslog facility
1346 AC_ARG_WITH(syslog-facility,
1347 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1348 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1349 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1350 AC_SUBST(LOGFACILITY)
1351
1352 # Check if we have getresuid and getresgid
1353 AC_CHECK_FUNCS(getresuid getresgid)
1354
1355 # Check for gethostbyname_r in all its glorious incompatible versions.
1356 #   (This logic is based on that in Python's configure.in)
1357 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1358   [Define this if you have any gethostbyname_r()])
1359
1360 AC_CHECK_FUNC(gethostbyname_r, [
1361   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1362   OLD_CFLAGS=$CFLAGS
1363   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1364   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1365 #include <netdb.h>
1366   ], [[
1367     char *cp1, *cp2;
1368     struct hostent *h1, *h2;
1369     int i1, i2;
1370     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1371   ]])],[
1372     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1373     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1374      [Define this if gethostbyname_r takes 6 arguments])
1375     AC_MSG_RESULT(6)
1376   ], [
1377     AC_TRY_COMPILE([
1378 #include <netdb.h>
1379     ], [
1380       char *cp1, *cp2;
1381       struct hostent *h1;
1382       int i1, i2;
1383       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1384     ], [
1385       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1386       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1387         [Define this if gethostbyname_r takes 5 arguments])
1388       AC_MSG_RESULT(5)
1389    ], [
1390       AC_TRY_COMPILE([
1391 #include <netdb.h>
1392      ], [
1393        char *cp1;
1394        struct hostent *h1;
1395        struct hostent_data hd;
1396        (void) gethostbyname_r(cp1,h1,&hd);
1397      ], [
1398        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1399        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1400          [Define this if gethostbyname_r takes 3 arguments])
1401        AC_MSG_RESULT(3)
1402      ], [
1403        AC_MSG_RESULT(0)
1404      ])
1405   ])
1406  ])
1407  CFLAGS=$OLD_CFLAGS
1408 ])
1409
1410 AC_CACHE_CHECK([whether the C compiler supports __func__],
1411   tor_cv_have_func_macro,
1412   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1413 #include <stdio.h>
1414 int main(int c, char **v) { puts(__func__); }])],
1415   tor_cv_have_func_macro=yes,
1416   tor_cv_have_func_macro=no))
1417
1418 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1419   tor_cv_have_FUNC_macro,
1420   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1421 #include <stdio.h>
1422 int main(int c, char **v) { puts(__FUNC__); }])],
1423   tor_cv_have_FUNC_macro=yes,
1424   tor_cv_have_FUNC_macro=no))
1425
1426 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1427   tor_cv_have_FUNCTION_macro,
1428   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1429 #include <stdio.h>
1430 int main(int c, char **v) { puts(__FUNCTION__); }])],
1431   tor_cv_have_FUNCTION_macro=yes,
1432   tor_cv_have_FUNCTION_macro=no))
1433
1434 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1435   tor_cv_have_environ_declared,
1436   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1437 /* We define _GNU_SOURCE here because it is also defined in compat.c.
1438  * Without it environ doesn't get declared. */
1439 #define _GNU_SOURCE
1440 #ifdef HAVE_UNISTD_H
1441 #include <unistd.h>
1442 #endif
1443 #include <stdlib.h>
1444 int main(int c, char **v) { char **t = environ; }])],
1445   tor_cv_have_environ_declared=yes,
1446   tor_cv_have_environ_declared=no))
1447
1448 if test "$tor_cv_have_func_macro" = 'yes'; then
1449   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1450 fi
1451
1452 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
1453   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1454 fi
1455
1456 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
1457   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1458            [Defined if the compiler supports __FUNCTION__])
1459 fi
1460
1461 if test "$tor_cv_have_environ_declared" = 'yes'; then
1462   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1463            [Defined if we have extern char **environ already declared])
1464 fi
1465
1466 # $prefix stores the value of the --prefix command line option, or
1467 # NONE if the option wasn't set.  In the case that it wasn't set, make
1468 # it be the default, so that we can use it to expand directories now.
1469 if test "x$prefix" = "xNONE"; then
1470   prefix=$ac_default_prefix
1471 fi
1472
1473 # and similarly for $exec_prefix
1474 if test "x$exec_prefix" = "xNONE"; then
1475   exec_prefix=$prefix
1476 fi
1477
1478 if test "x$BUILDDIR" = "x"; then
1479   BUILDDIR=`pwd`
1480 fi
1481 AC_SUBST(BUILDDIR)
1482 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1483 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1484
1485 if test "x$CONFDIR" = "x"; then
1486   CONFDIR=`eval echo $sysconfdir/tor`
1487 fi
1488 AC_SUBST(CONFDIR)
1489 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1490 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1491
1492 BINDIR=`eval echo $bindir`
1493 AC_SUBST(BINDIR)
1494 LOCALSTATEDIR=`eval echo $localstatedir`
1495 AC_SUBST(LOCALSTATEDIR)
1496
1497 if test "$bwin32" = true; then
1498   # Test if the linker supports the --nxcompat and --dynamicbase options
1499   # for Windows
1500   save_LDFLAGS="$LDFLAGS"
1501   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1502   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1503   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1504     [AC_MSG_RESULT([yes])]
1505     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1506     [AC_MSG_RESULT([no])]
1507   )
1508   LDFLAGS="$save_LDFLAGS"
1509 fi
1510
1511 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1512 # than autoconf's macros like.
1513 if test "$GCC" = yes; then
1514   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1515   # accident waiting to happen.
1516   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1517 else
1518   # Override optimization level for non-gcc compilers
1519   CFLAGS="$CFLAGS -O"
1520   enable_gcc_warnings=no
1521   enable_gcc_warnings_advisory=no
1522 fi
1523
1524 # OS X Lion started deprecating the system openssl. Let's just disable
1525 # all deprecation warnings on OS X. Also, to potentially make the binary
1526 # a little smaller, let's enable dead_strip.
1527 case "$host_os" in
1528
1529  darwin*)
1530     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1531     LDFLAGS="$LDFLAGS -dead_strip" ;;
1532 esac
1533
1534 # Add some more warnings which we use in development but not in the
1535 # released versions.  (Some relevant gcc versions can't handle these.)
1536 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
1537
1538   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1539 #if !defined(__GNUC__) || (__GNUC__ < 4)
1540 #error
1541 #endif])], have_gcc4=yes, have_gcc4=no)
1542
1543   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1544 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
1545 #error
1546 #endif])], have_gcc42=yes, have_gcc42=no)
1547
1548   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1549 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
1550 #error
1551 #endif])], have_gcc43=yes, have_gcc43=no)
1552
1553   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1554 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 6)
1555 #error
1556 #endif])], have_gcc46=yes, have_gcc46=no)
1557
1558
1559   save_CFLAGS="$CFLAGS"
1560   CFLAGS="$CFLAGS -Wshorten-64-to-32"
1561   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
1562                     have_shorten64_flag=no)
1563   CFLAGS="$save_CFLAGS"
1564
1565   case $host in
1566     *-*-openbsd* | *-*-bitrig*)
1567       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1568       # That's fine, except that the headers don't pass -Wredundant-decls.
1569       # Therefore, let's disable -Wsystem-headers when we're building
1570       # with maximal warnings on OpenBSD.
1571       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1572   esac
1573
1574   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1575   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1576   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1577   CFLAGS="$CFLAGS -Wwrite-strings -Wmissing-declarations -Wredundant-decls"
1578   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1579
1580   if test x$enable_gcc_warnings = xyes; then
1581     CFLAGS="$CFLAGS -Werror"
1582   fi
1583
1584   # Disabled, so we can use mallinfo(): -Waggregate-return
1585
1586   if test x$have_gcc4 = xyes ; then
1587     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
1588     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wold-style-definition"
1589   fi
1590
1591   if test x$have_gcc42 = xyes ; then
1592     # These warnings break gcc 4.0.2 and work on gcc 4.2
1593     # XXXX020 See if any of these work with earlier versions.
1594     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wstrict-overflow=1"
1595
1596     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
1597   fi
1598
1599   if test x$have_gcc42 = xyes && test x$have_clang = xno; then
1600     # These warnings break gcc 4.0.2 and clang, but work on gcc 4.2
1601     CFLAGS="$CFLAGS -Wnormalized=id -Woverride-init"
1602   fi
1603
1604   if test x$have_gcc43 = xyes ; then
1605     # These warnings break gcc 4.2 and work on gcc 4.3
1606     # XXXX020 See if any of these work with earlier versions.
1607     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
1608   fi
1609
1610   if test x$have_gcc46 = xyes ; then
1611     # This warning was added in gcc 4.3, but it appears to generate
1612     # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1613     CFLAGS="$CFLAGS -Wlogical-op"
1614   fi
1615
1616   if test x$have_shorten64_flag = xyes ; then
1617     CFLAGS="$CFLAGS -Wshorten-64-to-32"
1618   fi
1619
1620
1621
1622 ##This will break the world on some 64-bit architectures
1623 # CFLAGS="$CFLAGS -Winline"
1624 fi
1625
1626 if test "$enable_coverage" = yes && test "$have_clang" = "no"; then
1627    case "$host_os" in
1628     darwin*)
1629       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-profiling.])
1630    esac
1631 fi
1632
1633 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1634
1635 AC_CONFIG_FILES([
1636         Doxyfile
1637         Makefile
1638         contrib/dist/suse/tor.sh
1639         contrib/operator-tools/tor.logrotate
1640         contrib/dist/tor.sh
1641         contrib/dist/torctl
1642         contrib/dist/tor.service
1643         src/config/torrc.sample
1644         src/config/torrc.minimal
1645         scripts/maint/checkOptionDocs.pl
1646         scripts/maint/updateVersions.pl
1647 ])
1648
1649 if test x$asciidoc = xtrue && test "$ASCIIDOC" = "none" ; then
1650   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
1651   for file in $regular_mans ; do
1652     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
1653       echo "==================================";
1654       echo;
1655       echo "Building Tor has failed since manpages cannot be built.";
1656       echo;
1657       echo "You need asciidoc installed to be able to build the manpages.";
1658       echo "To build without manpages, use the --disable-asciidoc argument";
1659       echo "when calling configure.";
1660       echo;
1661       echo "==================================";
1662       exit 1;
1663     fi
1664   done
1665 fi
1666
1667 AC_OUTPUT