configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2007, Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.0.15-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I../common"
  21
  22 AC_ARG_ENABLE(debug,
  23  AS_HELP_STRING(--enable-debug, compile with debugging info),
  24 [if test x$enableval = xyes; then
  25     CFLAGS="$CFLAGS -g"
  26 fi])
  27
  28 #XXXX ideally, we should make this into a no-op, and detect whether we're
  29 #compiling for the iphone by using $target.
  30 AC_ARG_ENABLE(iphone,
  31  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  32  [if test x$enableval = xyes ; then
  33    tor_cv_iphone=true
  34    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  35   fi])
  36
  37 AC_ARG_ENABLE(cell-pool,
  38      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  39
  40 if test x$enable_cell_pool != xno; then
  41   AC_DEFINE(ENABLE_CELL_POOL, 1,
  42             [Defined if we try to use the pool allocator for queued cells])
  43 fi
  44
  45 AC_ARG_ENABLE(transparent,
  46      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  47      [case "${enableval}" in
  48         yes) transparent=true ;;
  49         no)  transparent=false ;;
  50         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  51       esac], [transparent=true])
  52
  53 AC_ARG_ENABLE(threads,
  54      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  55
  56 if test x$enable_threads = x; then
  57    case $host in
  58     *-*-solaris* )
  59      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  60      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  61 cpu workers lock up here, so I will disable threads.])
  62      enable_threads="no";;
  63     *)
  64      enable_threads="yes";;
  65    esac
  66 fi
  67
  68 if test "$enable_threads" = "yes"; then
  69   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  70 fi
  71
  72 case $host in
  73    *-*-solaris* )
  74      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  75      ;;
  76 esac
  77
  78 AC_ARG_ENABLE(gcc-warnings,
  79      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  80
  81 AC_PROG_CC
  82 AC_PROG_CPP
  83 AC_PROG_MAKE_SET
  84 AC_PROG_RANLIB
  85
  86 TORUSER=_tor
  87 AC_ARG_WITH(tor-user,
  88         [  --with-tor-user=NAME    Specify username for tor daemon ],
  89         [
  90            TORUSER=$withval
  91         ]
  92 )
  93 AC_SUBST(TORUSER)
  94
  95 TORGROUP=_tor
  96 AC_ARG_WITH(tor-group,
  97         [  --with-tor-group=NAME   Specify group name for tor daemon ],
  98         [
  99            TORGROUP=$withval
 100         ]
 101 )
 102 AC_SUBST(TORGROUP)
 103
 104
 105 dnl If WIN32 is defined and non-zero, we are building for win32
 106 AC_MSG_CHECKING([for win32])
 107 AC_RUN_IFELSE([
 108 int main(int c, char **v) {
 109 #ifdef WIN32
 110 #if WIN32
 111   return 0;
 112 #else
 113   return 1;
 114 #endif
 115 #else
 116   return 2;
 117 #endif
 118 }],
 119 bwin32=true; AC_MSG_RESULT([yes]),
 120 bwin32=false; AC_MSG_RESULT([no]),
 121 bwin32=cross; AC_MSG_RESULT([cross])
 122 )
 123
 124 if test "$bwin32" = cross; then
 125 AC_MSG_CHECKING([for win32 (cross)])
 126 AC_COMPILE_IFELSE([
 127 #ifdef WIN32
 128 int main(int c, char **v) {return 0;}
 129 #else
 130 #error
 131 int main(int c, char **v) {return x(y);}
 132 #endif
 133 ],
 134 bwin32=true; AC_MSG_RESULT([yes]),
 135 bwin32=false; AC_MSG_RESULT([no]))
 136 fi
 137
 138 if test "$bwin32" = true; then
 139 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 140 fi
 141 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 142
 143 dnl Enable C99 when compiling with MIPSpro
 144 AC_MSG_CHECKING([for MIPSpro compiler])
 145 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 146 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 147 #error
 148   return x(y);
 149 #endif
 150 ]),
 151 bmipspro=false; AC_MSG_RESULT(no),
 152 bmipspro=true; AC_MSG_RESULT(yes))
 153
 154 if test "$bmipspro" = true; then
 155   CFLAGS="$CFLAGS -c99"
 156 fi
 157
 158 AC_C_BIGENDIAN
 159
 160 AC_SEARCH_LIBS(socket, [socket])
 161 AC_SEARCH_LIBS(gethostbyname, [nsl])
 162 AC_SEARCH_LIBS(dlopen, [dl])
 163 AC_SEARCH_LIBS(inet_aton, [resolv])
 164
 165 if test "$enable_threads" = "yes"; then
 166   AC_SEARCH_LIBS(pthread_create, [pthread])
 167   AC_SEARCH_LIBS(pthread_detach, [pthread])
 168 fi
 169
 170 dnl -------------------------------------------------------------------
 171 dnl Check for functions before libevent, since libevent-1.2 apparently
 172 dnl exports strlcpy without defining it in a header.
 173
 174 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop mallinfo malloc_good_size malloc_usable_size)
 175
 176 if test "$enable_threads" = "yes"; then
 177   AC_CHECK_HEADERS(pthread.h)
 178   AC_CHECK_FUNCS(pthread_create)
 179 fi
 180
 181 dnl ------------------------------------------------------
 182 dnl Where do you live, libevent?  And how do we call you?
 183
 184 if test "$bwin32" = true; then
 185   TOR_LIB_WS32=-lws2_32
 186   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 187   # think it's actually necessary.
 188   TOR_LIB_GDI=-lgdi32
 189 else
 190   TOR_LIB_WS32=
 191   TOR_LIB_GDI=
 192 fi
 193 AC_SUBST(TOR_LIB_WS32)
 194 AC_SUBST(TOR_LIB_GDI)
 195
 196 dnl We need to do this before we try our disgusting hack below.
 197 AC_CHECK_HEADERS([sys/types.h])
 198
 199 dnl This is a disgusting hack so we safely include older libevent headers.
 200 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 201 AC_CHECK_TYPE(u_int32_t, unsigned long)
 202 AC_CHECK_TYPE(u_int16_t, unsigned short)
 203 AC_CHECK_TYPE(u_int8_t, unsigned char)
 204
 205 tor_libevent_pkg_redhat="libevent"
 206 tor_libevent_pkg_debian="libevent-dev"
 207 tor_libevent_devpkg_redhat="libevent-devel"
 208 tor_libevent_devpkg_debian="libevent-dev"
 209
 210 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 211 #include <stdlib.h>
 212 #include <sys/time.h>
 213 #include <sys/types.h>
 214 #include <event.h>], [void exit(int); void *event_init(void);],
 215     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 216
 217 dnl Now check for particular libevent functions.
 218 save_LIBS="$LIBS"
 219 save_LDFLAGS="$LDFLAGS"
 220 save_CPPFLAGS="$CPPFLAGS"
 221 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 222 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 223 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 224 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 225 LIBS="$save_LIBS"
 226 LDFLAGS="$save_LDFLAGS"
 227 CPPFLAGS="$save_CPPFLAGS"
 228
 229 dnl ------------------------------------------------------
 230 dnl Where do you live, openssl?  And how do we call you?
 231
 232 tor_openssl_pkg_redhat="openssl"
 233 tor_openssl_pkg_debian="libssl"
 234 tor_openssl_devpkg_redhat="openssl-devel"
 235 tor_openssl_devpkg_debian="libssl-dev"
 236
 237 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 238     [#include <openssl/rand.h>],
 239     [void RAND_add(const void *buf, int num, double entropy);],
 240     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 241     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 242
 243 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 244
 245 dnl ------------------------------------------------------
 246 dnl Where do you live, zlib?  And how do we call you?
 247
 248 tor_openssl_pkg_redhat="zlib"
 249 tor_openssl_pkg_debian="zlib1g"
 250 tor_openssl_devpkg_redhat="zlib-devel"
 251 tor_openssl_devpkg_debian="zlib1g-dev"
 252
 253 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 254     [#include <zlib.h>],
 255     [const char * zlibVersion(void);],
 256     [zlibVersion(); exit(0);], [--with-zlib-dir],
 257     [/opt/zlib])
 258
 259 dnl Make sure to enable support for large off_t if available.
 260
 261 AC_SYS_LARGEFILE
 262
 263 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 264
 265 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 266
 267 dnl These headers are not essential
 268
 269 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 270
 271 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 272 [#ifdef HAVE_SYS_TYPES_H
 273 #include <sys/types.h>
 274 #endif
 275 #ifdef HAVE_SYS_SOCKET_H
 276 #include <sys/socket.h>
 277 #endif])
 278 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 279 [#ifdef HAVE_SYS_TYPES_H
 280 #include <sys/types.h>
 281 #endif
 282 #ifdef HAVE_SYS_SOCKET_H
 283 #include <sys/socket.h>
 284 #endif
 285 #ifdef HAVE_NET_IF_H
 286 #include <net/if.h>
 287 #endif])
 288 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 289         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 290 [#ifdef HAVE_SYS_TYPES_H
 291 #include <sys/types.h>
 292 #endif
 293 #ifdef HAVE_SYS_SOCKET_H
 294 #include <sys/socket.h>
 295 #endif])
 296
 297 if test x$transparent = xtrue ; then
 298    transparent_ok=0
 299    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 300      transparent_ok=1
 301    fi
 302    if test x$linux_netfilter_ipv4 = x1 ; then
 303      transparent_ok=1
 304    fi
 305    if test x$transparent_ok = x1 ; then
 306      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 307      case $host in
 308        *-*-openbsd*)
 309          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 310      esac
 311    else
 312      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 313    fi
 314 fi
 315
 316 AC_FUNC_FSEEKO
 317
 318 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 319 [#ifdef HAVE_SYS_TYPES_H
 320 #include <sys/types.h>
 321 #endif
 322 #ifdef HAVE_SYS_TIME_H
 323 #include <sys/time.h>
 324 #endif])
 325
 326 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 327 dnl Watch out.
 328
 329 AC_CHECK_SIZEOF(int8_t)
 330 AC_CHECK_SIZEOF(int16_t)
 331 AC_CHECK_SIZEOF(int32_t)
 332 AC_CHECK_SIZEOF(int64_t)
 333 AC_CHECK_SIZEOF(uint8_t)
 334 AC_CHECK_SIZEOF(uint16_t)
 335 AC_CHECK_SIZEOF(uint32_t)
 336 AC_CHECK_SIZEOF(uint64_t)
 337 AC_CHECK_SIZEOF(intptr_t)
 338 AC_CHECK_SIZEOF(uintptr_t)
 339
 340 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 341
 342 AC_CHECK_SIZEOF(char)
 343 AC_CHECK_SIZEOF(short)
 344 AC_CHECK_SIZEOF(int)
 345 AC_CHECK_SIZEOF(long)
 346 AC_CHECK_SIZEOF(long long)
 347 AC_CHECK_SIZEOF(__int64)
 348 AC_CHECK_SIZEOF(void *)
 349 AC_CHECK_SIZEOF(time_t)
 350 AC_CHECK_SIZEOF(size_t)
 351
 352 AC_CHECK_TYPES([uint, u_char])
 353
 354 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 355 [#ifdef HAVE_SYS_TYPES_H
 356 #include <sys/types.h>
 357 #endif
 358 #ifdef HAVE_NETINET_IN_H
 359 #include <netinet/in.h>
 360 #endif
 361 #ifdef HAVE_NETINET_IN6_H
 362 #include <netinet/in6.h>
 363 #endif
 364 #ifdef HAVE_SYS_SOCKET_H
 365 #include <sys/socket.h>
 366 #endif
 367 #ifdef MS_WINDOWS
 368 #define WIN32_WINNT 0x400
 369 #define _WIN32_WINNT 0x400
 370 #define WIN32_LEAN_AND_MEAN
 371 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 372 #include <winsock.h>
 373 #else
 374 #include <winsock2.h>
 375 #include <ws2tcpip.h>
 376 #endif
 377 #endif
 378 ])
 379 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 380 [#ifdef HAVE_SYS_TYPES_H
 381 #include <sys/types.h>
 382 #endif
 383 #ifdef HAVE_NETINET_IN_H
 384 #include <netinet/in.h>
 385 #endif
 386 #ifdef HAVE_NETINET_IN6_H
 387 #include <netinet/in6.h>
 388 #endif
 389 #ifdef HAVE_SYS_SOCKET_H
 390 #include <sys/socket.h>
 391 #endif
 392 #ifdef MS_WINDOWS
 393 #define WIN32_WINNT 0x400
 394 #define _WIN32_WINNT 0x400
 395 #define WIN32_LEAN_AND_MEAN
 396 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 397 #include <winsock.h>
 398 #else
 399 #include <winsock2.h>
 400 #include <ws2tcpip.h>
 401 #endif
 402 #endif
 403 ])
 404
 405 AC_CHECK_TYPES([rlim_t], , ,
 406 [#ifdef HAVE_SYS_TYPES_H
 407 #include <sys/types.h>
 408 #endif
 409 #ifdef HAVE_SYS_TIME_H
 410 #include <sys/time.h>
 411 #endif
 412 #ifdef HAVE_SYS_RESOURCE_H
 413 #include <sys/resource.h>
 414 #endif
 415 ])
 416
 417 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 418 AC_RUN_IFELSE(AC_LANG_SOURCE([
 419 #ifdef HAVE_SYS_TYPES_H
 420 #include <sys/types.h>
 421 #endif
 422 #ifdef HAVE_SYS_TIME_H
 423 #include <sys/time.h>
 424 #endif
 425 #ifdef HAVE_TIME_H
 426 #include <time.h>
 427 #endif
 428 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 429   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 430 ])
 431
 432 if test "$tor_cv_time_t_signed" = cross; then
 433   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 434 fi
 435
 436 if test "$tor_cv_time_t_signed" != no; then
 437   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 438             [Define to 1 iff time_t is signed])
 439 fi
 440
 441 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 442 #ifdef HAVE_SYS_SOCKET_H
 443 #include <sys/socket.h>
 444 #endif
 445 ])
 446
 447 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 448
 449 AC_CHECK_SIZEOF(cell_t)
 450
 451 # Now make sure that NULL can be represented as zero bytes.
 452 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 453 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 454 [[#include <stdlib.h>
 455 #include <string.h>
 456 #include <stdio.h>
 457 #ifdef HAVE_STDDEF_H
 458 #include <stddef.h>
 459 #endif
 460 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 461 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 462        [tor_cv_null_is_zero=yes],
 463        [tor_cv_null_is_zero=no],
 464        [tor_cv_null_is_zero=cross])])
 465
 466 if test "$tor_cv_null_is_zero" = cross ; then
 467   # Cross-compiling; let's hope that the target isn't raving mad.
 468   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 469 fi
 470
 471 if test "$tor_cv_null_is_zero" != no; then
 472   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 473             [Define to 1 iff memset(0) sets pointers to NULL])
 474 fi
 475
 476 # And what happens when we malloc zero?
 477 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 478 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 479 [[#include <stdlib.h>
 480 #include <string.h>
 481 #include <stdio.h>
 482 #ifdef HAVE_STDDEF_H
 483 #include <stddef.h>
 484 #endif
 485 int main () { return malloc(0)?0:1; }]])],
 486        [tor_cv_malloc_zero_works=yes],
 487        [tor_cv_malloc_zero_works=no],
 488        [tor_cv_malloc_zero_works=cross])])
 489
 490 if test "$tor_cv_malloc_zero_works" = cross; then
 491   # Cross-compiling; let's hope that the target isn't raving mad.
 492   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 493 fi
 494
 495 if test "$tor_cv_malloc_zero_works" = yes; then
 496   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 497             [Define to 1 iff malloc(0) returns a pointer])
 498 fi
 499
 500 # whether we seem to be in a 2s-complement world.
 501 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 502 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 503 [[int main () { int problem = ((-99) != (~99)+1);
 504 return problem ? 1 : 0; }]])],
 505        [tor_cv_twos_complement=yes],
 506        [tor_cv_twos_complement=no],
 507        [tor_cv_twos_complement=cross])])
 508
 509 if test "$tor_cv_twos_complement" = cross ; then
 510   # Cross-compiling; let's hope that the target isn't raving mad.
 511   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 512 fi
 513
 514 if test "$tor_cv_twos_complement" != no ; then
 515   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 516             [Define to 1 iff we represent negative integers with two's complement])
 517 fi
 518
 519 # Whether we should use the dmalloc memory allocation debugging library.
 520 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 521 AC_ARG_WITH(dmalloc,
 522 [  --with-dmalloc          Use debug memory allocation library. ],
 523 [if [[ "$withval" = "yes" ]]; then
 524   dmalloc=1
 525   AC_MSG_RESULT(yes)
 526 else
 527   dmalloc=1
 528   AC_MSG_RESULT(no)
 529 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 530 )
 531
 532 if [[ $dmalloc -eq 1 ]]; then
 533   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 534   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 535   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 536   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 537   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 538 fi
 539
 540 # Allow user to specify an alternate syslog facility
 541 AC_ARG_WITH(syslog-facility,
 542 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 543 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 544 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 545 AC_SUBST(LOGFACILITY)
 546
 547 # Check for gethostbyname_r in all its glorious incompatible versions.
 548 #   (This logic is based on that in Python's configure.in)
 549 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 550   [Define this if you have any gethostbyname_r()])
 551
 552 AC_CHECK_FUNC(gethostbyname_r, [
 553   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 554   OLD_CFLAGS=$CFLAGS
 555   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 556   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 557 #include <netdb.h>
 558   ], [[
 559     char *cp1, *cp2;
 560     struct hostent *h1, *h2;
 561     int i1, i2;
 562     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 563   ]]),[
 564     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 565     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 566      [Define this if gethostbyname_r takes 6 arguments])
 567     AC_MSG_RESULT(6)
 568   ], [
 569     AC_TRY_COMPILE([
 570 #include <netdb.h>
 571     ], [
 572       char *cp1, *cp2;
 573       struct hostent *h1;
 574       int i1, i2;
 575       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 576     ], [
 577       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 578       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 579         [Define this if gethostbyname_r takes 5 arguments])
 580       AC_MSG_RESULT(5)
 581    ], [
 582       AC_TRY_COMPILE([
 583 #include <netdb.h>
 584      ], [
 585        char *cp1;
 586        struct hostent *h1;
 587        struct hostent_data hd;
 588        (void) gethostbyname_r(cp1,h1,&hd);
 589      ], [
 590        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 591        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 592          [Define this if gethostbyname_r takes 3 arguments])
 593        AC_MSG_RESULT(3)
 594      ], [
 595        AC_MSG_RESULT(0)
 596      ])
 597   ])
 598  ])
 599  CFLAGS=$OLD_CFLAGS
 600 ])
 601
 602 AC_CACHE_CHECK([whether the C compiler supports __func__],
 603   tor_cv_have_func_macro,
 604   AC_COMPILE_IFELSE([
 605 #include <stdio.h>
 606 int main(int c, char **v) { puts(__func__); }],
 607   tor_cv_have_func_macro=yes,
 608   tor_cv_have_func_macro=no))
 609
 610 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 611   tor_cv_have_FUNC_macro,
 612   AC_COMPILE_IFELSE([
 613 #include <stdio.h>
 614 int main(int c, char **v) { puts(__FUNC__); }],
 615   tor_cv_have_FUNC_macro=yes,
 616   tor_cv_have_FUNC_macro=no))
 617
 618 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 619   tor_cv_have_FUNCTION_macro,
 620   AC_COMPILE_IFELSE([
 621 #include <stdio.h>
 622 int main(int c, char **v) { puts(__FUNCTION__); }],
 623   tor_cv_have_FUNCTION_macro=yes,
 624   tor_cv_have_FUNCTION_macro=no))
 625
 626 if test "$tor_cv_have_func_macro" = 'yes'; then
 627   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 628 fi
 629
 630 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 631   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 632 fi
 633
 634 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 635   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 636            [Defined if the compiler supports __FUNCTION__])
 637 fi
 638
 639 # $prefix stores the value of the --prefix command line option, or
 640 # NONE if the option wasn't set.  In the case that it wasn't set, make
 641 # it be the default, so that we can use it to expand directories now.
 642 if test "x$prefix" = "xNONE"; then
 643   prefix=$ac_default_prefix
 644 fi
 645
 646 # and similarly for $exec_prefix
 647 if test "x$exec_prefix" = "xNONE"; then
 648   exec_prefix=$prefix
 649 fi
 650
 651 if test "x$CONFDIR" = "x"; then
 652   CONFDIR=`eval echo $sysconfdir/tor`
 653 fi
 654 AC_SUBST(CONFDIR)
 655 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 656 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 657
 658 BINDIR=`eval echo $bindir`
 659 AC_SUBST(BINDIR)
 660 LOCALSTATEDIR=`eval echo $localstatedir`
 661 AC_SUBST(LOCALSTATEDIR)
 662
 663 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 664 # than autoconf's macros like.
 665 if test "$ac_cv_c_compiler_gnu" = yes; then
 666   CFLAGS="$CFLAGS -Wall -g -O2"
 667 else
 668   CFLAGS="$CFLAGS -g -O"
 669   enable_gcc_warnings=no
 670 fi
 671
 672 # Add some more warnings which we use in development but not in the
 673 # released versions.  (Some relevant gcc versions can't handle these.)
 674 if test x$enable_gcc_warnings = xyes; then
 675
 676   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 677 #if !defined(__GNUC__) || (__GNUC__ < 4)
 678 #error
 679 #endif]), have_gcc4=yes, have_gcc4=no)
 680
 681   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 682 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 683 #error
 684 #endif]), have_gcc42=yes, have_gcc42=no)
 685
 686   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 687   # Disabled, so we can use mallinfo(): -Waggregate-return
 688
 689   if test x$have_gcc4 = xyes ; then
 690     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 691     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 692   fi
 693
 694   if test x$have_gcc42 = xyes ; then
 695     # These warnings break gcc 4.0.2 and work on gcc 4.2
 696     # XXXX020 Use -fstack-protector.
 697     # XXXX020 See if any of these work with earlier versions.
 698     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 699   fi
 700
 701 ##This will break the world on some 64-bit architectures
 702 # CFLAGS="$CFLAGS -Winline"
 703
 704 fi
 705
 706 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 707
 708 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 709 AC_OUTPUT
 710
 711 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 712   ./contrib/updateVersions.pl
 713 fi
 714