configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.0.23-rc)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45
  46
  47 if test x$enable_cell_pool != xno; then
  48   AC_DEFINE(ENABLE_CELL_POOL, 1,
  49             [Defined if we try to use the pool allocator for queued cells])
  50 fi
  51 if test x$enable_buf_freelists != xno; then
  52   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  53             [Defined if we try to use freelists for buffer RAM chunks])
  54 fi
  55 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  56
  57 AC_ARG_ENABLE(transparent,
  58      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  59      [case "${enableval}" in
  60         yes) transparent=true ;;
  61         no)  transparent=false ;;
  62         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  63       esac], [transparent=true])
  64
  65 AC_ARG_ENABLE(threads,
  66      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  67
  68 if test x$enable_threads = x; then
  69    case $host in
  70     *-*-solaris* )
  71      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  72      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  73 cpu workers lock up here, so I will disable threads.])
  74      enable_threads="no";;
  75     *)
  76      enable_threads="yes";;
  77    esac
  78 fi
  79
  80 if test "$enable_threads" = "yes"; then
  81   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  82 fi
  83
  84 case $host in
  85    *-*-solaris* )
  86      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  87      ;;
  88 esac
  89
  90 AC_ARG_ENABLE(gcc-warnings,
  91      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  92
  93 AC_PROG_CC
  94 AC_PROG_CPP
  95 AC_PROG_MAKE_SET
  96 AC_PROG_RANLIB
  97
  98 TORUSER=_tor
  99 AC_ARG_WITH(tor-user,
 100         [  --with-tor-user=NAME    Specify username for tor daemon ],
 101         [
 102            TORUSER=$withval
 103         ]
 104 )
 105 AC_SUBST(TORUSER)
 106
 107 TORGROUP=_tor
 108 AC_ARG_WITH(tor-group,
 109         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 110         [
 111            TORGROUP=$withval
 112         ]
 113 )
 114 AC_SUBST(TORGROUP)
 115
 116
 117 dnl If WIN32 is defined and non-zero, we are building for win32
 118 AC_MSG_CHECKING([for win32])
 119 AC_RUN_IFELSE([
 120 int main(int c, char **v) {
 121 #ifdef WIN32
 122 #if WIN32
 123   return 0;
 124 #else
 125   return 1;
 126 #endif
 127 #else
 128   return 2;
 129 #endif
 130 }],
 131 bwin32=true; AC_MSG_RESULT([yes]),
 132 bwin32=false; AC_MSG_RESULT([no]),
 133 bwin32=cross; AC_MSG_RESULT([cross])
 134 )
 135
 136 if test "$bwin32" = cross; then
 137 AC_MSG_CHECKING([for win32 (cross)])
 138 AC_COMPILE_IFELSE([
 139 #ifdef WIN32
 140 int main(int c, char **v) {return 0;}
 141 #else
 142 #error
 143 int main(int c, char **v) {return x(y);}
 144 #endif
 145 ],
 146 bwin32=true; AC_MSG_RESULT([yes]),
 147 bwin32=false; AC_MSG_RESULT([no]))
 148 fi
 149
 150 if test "$bwin32" = true; then
 151 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 152 fi
 153 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 154
 155 dnl Enable C99 when compiling with MIPSpro
 156 AC_MSG_CHECKING([for MIPSpro compiler])
 157 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 158 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 159 #error
 160   return x(y);
 161 #endif
 162 ]),
 163 bmipspro=false; AC_MSG_RESULT(no),
 164 bmipspro=true; AC_MSG_RESULT(yes))
 165
 166 if test "$bmipspro" = true; then
 167   CFLAGS="$CFLAGS -c99"
 168 fi
 169
 170 AC_C_BIGENDIAN
 171
 172 AC_SEARCH_LIBS(socket, [socket])
 173 AC_SEARCH_LIBS(gethostbyname, [nsl])
 174 AC_SEARCH_LIBS(dlopen, [dl])
 175 AC_SEARCH_LIBS(inet_aton, [resolv])
 176
 177 if test "$enable_threads" = "yes"; then
 178   AC_SEARCH_LIBS(pthread_create, [pthread])
 179   AC_SEARCH_LIBS(pthread_detach, [pthread])
 180 fi
 181
 182 dnl -------------------------------------------------------------------
 183 dnl Check for functions before libevent, since libevent-1.2 apparently
 184 dnl exports strlcpy without defining it in a header.
 185
 186 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop)
 187
 188 using_custom_malloc=no
 189 if test x$enable_openbsd_malloc = xyes ; then
 190    using_custom_malloc=yes
 191 fi
 192 if test x$tcmalloc = xyes ; then
 193    using_custom_malloc=yes
 194 fi
 195 if test $using_custom_malloc = no ; then
 196    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 197 fi
 198
 199 if test "$enable_threads" = "yes"; then
 200   AC_CHECK_HEADERS(pthread.h)
 201   AC_CHECK_FUNCS(pthread_create)
 202 fi
 203
 204 dnl ------------------------------------------------------
 205 dnl Where do you live, libevent?  And how do we call you?
 206
 207 if test "$bwin32" = true; then
 208   TOR_LIB_WS32=-lws2_32
 209   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 210   # think it's actually necessary.
 211   TOR_LIB_GDI=-lgdi32
 212 else
 213   TOR_LIB_WS32=
 214   TOR_LIB_GDI=
 215 fi
 216 AC_SUBST(TOR_LIB_WS32)
 217 AC_SUBST(TOR_LIB_GDI)
 218
 219 dnl We need to do this before we try our disgusting hack below.
 220 AC_CHECK_HEADERS([sys/types.h])
 221
 222 dnl This is a disgusting hack so we safely include older libevent headers.
 223 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 224 AC_CHECK_TYPE(u_int32_t, unsigned long)
 225 AC_CHECK_TYPE(u_int16_t, unsigned short)
 226 AC_CHECK_TYPE(u_int8_t, unsigned char)
 227
 228 tor_libevent_pkg_redhat="libevent"
 229 tor_libevent_pkg_debian="libevent-dev"
 230 tor_libevent_devpkg_redhat="libevent-devel"
 231 tor_libevent_devpkg_debian="libevent-dev"
 232
 233 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 234 #include <stdlib.h>
 235 #include <sys/time.h>
 236 #include <sys/types.h>
 237 #include <event.h>], [void exit(int); void *event_init(void);],
 238     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 239
 240 dnl Now check for particular libevent functions.
 241 save_LIBS="$LIBS"
 242 save_LDFLAGS="$LDFLAGS"
 243 save_CPPFLAGS="$CPPFLAGS"
 244 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 245 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 246 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 247 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 248 LIBS="$save_LIBS"
 249 LDFLAGS="$save_LDFLAGS"
 250 CPPFLAGS="$save_CPPFLAGS"
 251
 252 dnl ------------------------------------------------------
 253 dnl Where do you live, openssl?  And how do we call you?
 254
 255 tor_openssl_pkg_redhat="openssl"
 256 tor_openssl_pkg_debian="libssl"
 257 tor_openssl_devpkg_redhat="openssl-devel"
 258 tor_openssl_devpkg_debian="libssl-dev"
 259
 260 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 261     [#include <openssl/rand.h>],
 262     [void RAND_add(const void *buf, int num, double entropy);],
 263     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 264     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 265
 266 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 267
 268 dnl ------------------------------------------------------
 269 dnl Where do you live, zlib?  And how do we call you?
 270
 271 tor_openssl_pkg_redhat="zlib"
 272 tor_openssl_pkg_debian="zlib1g"
 273 tor_openssl_devpkg_redhat="zlib-devel"
 274 tor_openssl_devpkg_debian="zlib1g-dev"
 275
 276 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 277     [#include <zlib.h>],
 278     [const char * zlibVersion(void);],
 279     [zlibVersion(); exit(0);], [--with-zlib-dir],
 280     [/opt/zlib])
 281
 282 dnl Make sure to enable support for large off_t if available.
 283
 284 AC_SYS_LARGEFILE
 285
 286 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 287
 288 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 289
 290 dnl These headers are not essential
 291
 292 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 293
 294 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 295 [#ifdef HAVE_MALLOC_H
 296 #include <malloc.h>
 297 #endif
 298 #ifdef HAVE_MALLOC_MALLOC_H
 299 #include <malloc/malloc.h>
 300 #endif])
 301
 302 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 303 [#ifdef HAVE_SYS_TYPES_H
 304 #include <sys/types.h>
 305 #endif
 306 #ifdef HAVE_SYS_SOCKET_H
 307 #include <sys/socket.h>
 308 #endif])
 309 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 310 [#ifdef HAVE_SYS_TYPES_H
 311 #include <sys/types.h>
 312 #endif
 313 #ifdef HAVE_SYS_SOCKET_H
 314 #include <sys/socket.h>
 315 #endif
 316 #ifdef HAVE_NET_IF_H
 317 #include <net/if.h>
 318 #endif])
 319 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 320         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 321 [#ifdef HAVE_SYS_TYPES_H
 322 #include <sys/types.h>
 323 #endif
 324 #ifdef HAVE_SYS_SOCKET_H
 325 #include <sys/socket.h>
 326 #endif])
 327
 328 if test x$transparent = xtrue ; then
 329    transparent_ok=0
 330    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 331      transparent_ok=1
 332    fi
 333    if test x$linux_netfilter_ipv4 = x1 ; then
 334      transparent_ok=1
 335    fi
 336    if test x$transparent_ok = x1 ; then
 337      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 338      case $host in
 339        *-*-openbsd*)
 340          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 341      esac
 342    else
 343      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 344    fi
 345 fi
 346
 347 AC_FUNC_FSEEKO
 348
 349 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 350 [#ifdef HAVE_SYS_TYPES_H
 351 #include <sys/types.h>
 352 #endif
 353 #ifdef HAVE_SYS_TIME_H
 354 #include <sys/time.h>
 355 #endif])
 356
 357 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 358 dnl Watch out.
 359
 360 AC_CHECK_SIZEOF(int8_t)
 361 AC_CHECK_SIZEOF(int16_t)
 362 AC_CHECK_SIZEOF(int32_t)
 363 AC_CHECK_SIZEOF(int64_t)
 364 AC_CHECK_SIZEOF(uint8_t)
 365 AC_CHECK_SIZEOF(uint16_t)
 366 AC_CHECK_SIZEOF(uint32_t)
 367 AC_CHECK_SIZEOF(uint64_t)
 368 AC_CHECK_SIZEOF(intptr_t)
 369 AC_CHECK_SIZEOF(uintptr_t)
 370
 371 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 372
 373 AC_CHECK_SIZEOF(char)
 374 AC_CHECK_SIZEOF(short)
 375 AC_CHECK_SIZEOF(int)
 376 AC_CHECK_SIZEOF(long)
 377 AC_CHECK_SIZEOF(long long)
 378 AC_CHECK_SIZEOF(__int64)
 379 AC_CHECK_SIZEOF(void *)
 380 AC_CHECK_SIZEOF(time_t)
 381 AC_CHECK_SIZEOF(size_t)
 382
 383 AC_CHECK_TYPES([uint, u_char, ssize_t])
 384
 385 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 386 [#ifdef HAVE_SYS_TYPES_H
 387 #include <sys/types.h>
 388 #endif
 389 #ifdef HAVE_NETINET_IN_H
 390 #include <netinet/in.h>
 391 #endif
 392 #ifdef HAVE_NETINET_IN6_H
 393 #include <netinet/in6.h>
 394 #endif
 395 #ifdef HAVE_SYS_SOCKET_H
 396 #include <sys/socket.h>
 397 #endif
 398 #ifdef MS_WINDOWS
 399 #define WIN32_WINNT 0x400
 400 #define _WIN32_WINNT 0x400
 401 #define WIN32_LEAN_AND_MEAN
 402 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 403 #include <winsock.h>
 404 #else
 405 #include <winsock2.h>
 406 #include <ws2tcpip.h>
 407 #endif
 408 #endif
 409 ])
 410 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 411 [#ifdef HAVE_SYS_TYPES_H
 412 #include <sys/types.h>
 413 #endif
 414 #ifdef HAVE_NETINET_IN_H
 415 #include <netinet/in.h>
 416 #endif
 417 #ifdef HAVE_NETINET_IN6_H
 418 #include <netinet/in6.h>
 419 #endif
 420 #ifdef HAVE_SYS_SOCKET_H
 421 #include <sys/socket.h>
 422 #endif
 423 #ifdef MS_WINDOWS
 424 #define WIN32_WINNT 0x400
 425 #define _WIN32_WINNT 0x400
 426 #define WIN32_LEAN_AND_MEAN
 427 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 428 #include <winsock.h>
 429 #else
 430 #include <winsock2.h>
 431 #include <ws2tcpip.h>
 432 #endif
 433 #endif
 434 ])
 435
 436 AC_CHECK_TYPES([rlim_t], , ,
 437 [#ifdef HAVE_SYS_TYPES_H
 438 #include <sys/types.h>
 439 #endif
 440 #ifdef HAVE_SYS_TIME_H
 441 #include <sys/time.h>
 442 #endif
 443 #ifdef HAVE_SYS_RESOURCE_H
 444 #include <sys/resource.h>
 445 #endif
 446 ])
 447
 448 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 449 AC_RUN_IFELSE(AC_LANG_SOURCE([
 450 #ifdef HAVE_SYS_TYPES_H
 451 #include <sys/types.h>
 452 #endif
 453 #ifdef HAVE_SYS_TIME_H
 454 #include <sys/time.h>
 455 #endif
 456 #ifdef HAVE_TIME_H
 457 #include <time.h>
 458 #endif
 459 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 460   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 461 ])
 462
 463 if test "$tor_cv_time_t_signed" = cross; then
 464   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 465 fi
 466
 467 if test "$tor_cv_time_t_signed" != no; then
 468   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 469             [Define to 1 iff time_t is signed])
 470 fi
 471
 472 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 473 #ifdef HAVE_SYS_SOCKET_H
 474 #include <sys/socket.h>
 475 #endif
 476 ])
 477
 478 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 479
 480 AC_CHECK_SIZEOF(cell_t)
 481
 482 # Now make sure that NULL can be represented as zero bytes.
 483 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 484 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 485 [[#include <stdlib.h>
 486 #include <string.h>
 487 #include <stdio.h>
 488 #ifdef HAVE_STDDEF_H
 489 #include <stddef.h>
 490 #endif
 491 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 492 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 493        [tor_cv_null_is_zero=yes],
 494        [tor_cv_null_is_zero=no],
 495        [tor_cv_null_is_zero=cross])])
 496
 497 if test "$tor_cv_null_is_zero" = cross ; then
 498   # Cross-compiling; let's hope that the target isn't raving mad.
 499   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 500 fi
 501
 502 if test "$tor_cv_null_is_zero" != no; then
 503   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 504             [Define to 1 iff memset(0) sets pointers to NULL])
 505 fi
 506
 507 # And what happens when we malloc zero?
 508 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 509 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 510 [[#include <stdlib.h>
 511 #include <string.h>
 512 #include <stdio.h>
 513 #ifdef HAVE_STDDEF_H
 514 #include <stddef.h>
 515 #endif
 516 int main () { return malloc(0)?0:1; }]])],
 517        [tor_cv_malloc_zero_works=yes],
 518        [tor_cv_malloc_zero_works=no],
 519        [tor_cv_malloc_zero_works=cross])])
 520
 521 if test "$tor_cv_malloc_zero_works" = cross; then
 522   # Cross-compiling; let's hope that the target isn't raving mad.
 523   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 524 fi
 525
 526 if test "$tor_cv_malloc_zero_works" = yes; then
 527   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 528             [Define to 1 iff malloc(0) returns a pointer])
 529 fi
 530
 531 # whether we seem to be in a 2s-complement world.
 532 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 533 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 534 [[int main () { int problem = ((-99) != (~99)+1);
 535 return problem ? 1 : 0; }]])],
 536        [tor_cv_twos_complement=yes],
 537        [tor_cv_twos_complement=no],
 538        [tor_cv_twos_complement=cross])])
 539
 540 if test "$tor_cv_twos_complement" = cross ; then
 541   # Cross-compiling; let's hope that the target isn't raving mad.
 542   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 543 fi
 544
 545 if test "$tor_cv_twos_complement" != no ; then
 546   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 547             [Define to 1 iff we represent negative integers with two's complement])
 548 fi
 549
 550 # Whether we should use the dmalloc memory allocation debugging library.
 551 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 552 AC_ARG_WITH(dmalloc,
 553 [  --with-dmalloc          Use debug memory allocation library. ],
 554 [if [[ "$withval" = "yes" ]]; then
 555   dmalloc=1
 556   AC_MSG_RESULT(yes)
 557 else
 558   dmalloc=1
 559   AC_MSG_RESULT(no)
 560 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 561 )
 562
 563 if [[ $dmalloc -eq 1 ]]; then
 564   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 565   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 566   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 567   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 568   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 569 fi
 570
 571 AC_ARG_WITH(tcmalloc,
 572 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 573 [ tcmalloc=yes ], [ tcmalloc=no ])
 574
 575 if test x$tcmalloc = xyes ; then
 576    LDFLAGS="-ltcmalloc $LDFLAGS"
 577 fi
 578
 579 # Allow user to specify an alternate syslog facility
 580 AC_ARG_WITH(syslog-facility,
 581 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 582 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 583 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 584 AC_SUBST(LOGFACILITY)
 585
 586 # Check for gethostbyname_r in all its glorious incompatible versions.
 587 #   (This logic is based on that in Python's configure.in)
 588 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 589   [Define this if you have any gethostbyname_r()])
 590
 591 AC_CHECK_FUNC(gethostbyname_r, [
 592   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 593   OLD_CFLAGS=$CFLAGS
 594   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 595   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 596 #include <netdb.h>
 597   ], [[
 598     char *cp1, *cp2;
 599     struct hostent *h1, *h2;
 600     int i1, i2;
 601     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 602   ]]),[
 603     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 604     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 605      [Define this if gethostbyname_r takes 6 arguments])
 606     AC_MSG_RESULT(6)
 607   ], [
 608     AC_TRY_COMPILE([
 609 #include <netdb.h>
 610     ], [
 611       char *cp1, *cp2;
 612       struct hostent *h1;
 613       int i1, i2;
 614       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 615     ], [
 616       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 617       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 618         [Define this if gethostbyname_r takes 5 arguments])
 619       AC_MSG_RESULT(5)
 620    ], [
 621       AC_TRY_COMPILE([
 622 #include <netdb.h>
 623      ], [
 624        char *cp1;
 625        struct hostent *h1;
 626        struct hostent_data hd;
 627        (void) gethostbyname_r(cp1,h1,&hd);
 628      ], [
 629        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 630        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 631          [Define this if gethostbyname_r takes 3 arguments])
 632        AC_MSG_RESULT(3)
 633      ], [
 634        AC_MSG_RESULT(0)
 635      ])
 636   ])
 637  ])
 638  CFLAGS=$OLD_CFLAGS
 639 ])
 640
 641 AC_CACHE_CHECK([whether the C compiler supports __func__],
 642   tor_cv_have_func_macro,
 643   AC_COMPILE_IFELSE([
 644 #include <stdio.h>
 645 int main(int c, char **v) { puts(__func__); }],
 646   tor_cv_have_func_macro=yes,
 647   tor_cv_have_func_macro=no))
 648
 649 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 650   tor_cv_have_FUNC_macro,
 651   AC_COMPILE_IFELSE([
 652 #include <stdio.h>
 653 int main(int c, char **v) { puts(__FUNC__); }],
 654   tor_cv_have_FUNC_macro=yes,
 655   tor_cv_have_FUNC_macro=no))
 656
 657 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 658   tor_cv_have_FUNCTION_macro,
 659   AC_COMPILE_IFELSE([
 660 #include <stdio.h>
 661 int main(int c, char **v) { puts(__FUNCTION__); }],
 662   tor_cv_have_FUNCTION_macro=yes,
 663   tor_cv_have_FUNCTION_macro=no))
 664
 665 if test "$tor_cv_have_func_macro" = 'yes'; then
 666   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 667 fi
 668
 669 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 670   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 671 fi
 672
 673 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 674   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 675            [Defined if the compiler supports __FUNCTION__])
 676 fi
 677
 678 # $prefix stores the value of the --prefix command line option, or
 679 # NONE if the option wasn't set.  In the case that it wasn't set, make
 680 # it be the default, so that we can use it to expand directories now.
 681 if test "x$prefix" = "xNONE"; then
 682   prefix=$ac_default_prefix
 683 fi
 684
 685 # and similarly for $exec_prefix
 686 if test "x$exec_prefix" = "xNONE"; then
 687   exec_prefix=$prefix
 688 fi
 689
 690 if test "x$CONFDIR" = "x"; then
 691   CONFDIR=`eval echo $sysconfdir/tor`
 692 fi
 693 AC_SUBST(CONFDIR)
 694 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 695 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 696
 697 BINDIR=`eval echo $bindir`
 698 AC_SUBST(BINDIR)
 699 LOCALSTATEDIR=`eval echo $localstatedir`
 700 AC_SUBST(LOCALSTATEDIR)
 701
 702 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 703 # than autoconf's macros like.
 704 if test "$ac_cv_c_compiler_gnu" = yes; then
 705   CFLAGS="$CFLAGS -Wall -g -O2"
 706 else
 707   CFLAGS="$CFLAGS -g -O"
 708   enable_gcc_warnings=no
 709 fi
 710
 711 # Add some more warnings which we use in development but not in the
 712 # released versions.  (Some relevant gcc versions can't handle these.)
 713 if test x$enable_gcc_warnings = xyes; then
 714
 715   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 716 #if !defined(__GNUC__) || (__GNUC__ < 4)
 717 #error
 718 #endif]), have_gcc4=yes, have_gcc4=no)
 719
 720   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 721 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 722 #error
 723 #endif]), have_gcc42=yes, have_gcc42=no)
 724
 725   save_CFLAGS="$CFLAGS"
 726   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 727   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 728                     have_shorten64_flag=no)
 729   CFLAGS="$save_CFLAGS"
 730
 731   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 732   # Disabled, so we can use mallinfo(): -Waggregate-return
 733
 734   if test x$have_gcc4 = xyes ; then
 735     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 736     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 737   fi
 738
 739   if test x$have_gcc42 = xyes ; then
 740     # These warnings break gcc 4.0.2 and work on gcc 4.2
 741     # XXXX020 Use -fstack-protector.
 742     # XXXX020 See if any of these work with earlier versions.
 743     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 744   fi
 745
 746   if test x$have_shorten64_flag = xyes ; then
 747     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 748   fi
 749
 750 ##This will break the world on some 64-bit architectures
 751 # CFLAGS="$CFLAGS -Winline"
 752 fi
 753
 754
 755
 756 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 757
 758 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 759 AC_OUTPUT
 760
 761 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 762   ./contrib/updateVersions.pl
 763 fi
 764