configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2019, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.5.16-dev])
   8 AC_CONFIG_SRCDIR([src/app/main/tor_main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 AC_ARG_ENABLE(openbsd-malloc,
  25    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only. Deprecated: see --with-malloc]))
  26 AC_ARG_ENABLE(static-openssl,
  27    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  28 AC_ARG_ENABLE(static-libevent,
  29    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  30 AC_ARG_ENABLE(static-zlib,
  31    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  32 AC_ARG_ENABLE(static-tor,
  33    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  34 AC_ARG_ENABLE(unittests,
  35    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  36 AC_ARG_ENABLE(coverage,
  37    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  38 AC_ARG_ENABLE(asserts-in-tests,
  39    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  40 AC_ARG_ENABLE(system-torrc,
  41    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  42 AC_ARG_ENABLE(libfuzzer,
  43    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  44 AC_ARG_ENABLE(oss-fuzz,
  45    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  46 AC_ARG_ENABLE(memory-sentinels,
  47    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  48 AC_ARG_ENABLE(rust,
  49    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  50 AC_ARG_ENABLE(cargo-online-mode,
  51    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  52 AC_ARG_ENABLE(restart-debugging,
  53    AS_HELP_STRING(--enable-restart-debugging, [Build Tor with support for debugging in-process restart. Developers only.]))
  54 AC_ARG_ENABLE(zstd-advanced-apis,
  55    AS_HELP_STRING(--disable-zstd-advanced-apis, [Build without support for zstd's "static-only" APIs.]))
  56 AC_ARG_ENABLE(nss,
  57    AS_HELP_STRING(--enable-nss, [Use Mozilla's NSS TLS library. (EXPERIMENTAL)]))
  58 AC_ARG_ENABLE(pic,
  59    AS_HELP_STRING(--enable-pic, [Build Tor's binaries as position-independent code, suitable to link as a library.]))
  60
  61 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  62     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  63 fi
  64
  65 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  66 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  67 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  68 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  69 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  70 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  71 AM_CONDITIONAL(USE_NSS, test "x$enable_nss" = "xyes")
  72 AM_CONDITIONAL(USE_OPENSSL, test "x$enable_nss" != "xyes")
  73
  74 if test "x$enable_nss" = "xyes"; then
  75   AC_DEFINE(ENABLE_NSS, 1,
  76             [Defined if we're building with NSS.])
  77 else
  78   AC_DEFINE(ENABLE_OPENSSL, 1,
  79             [Defined if we're building with OpenSSL or LibreSSL])
  80 fi
  81
  82 if test "$enable_static_tor" = "yes"; then
  83   enable_static_libevent="yes";
  84   enable_static_openssl="yes";
  85   enable_static_zlib="yes";
  86   CFLAGS="$CFLAGS -static"
  87 fi
  88
  89 if test "$enable_system_torrc" = "no"; then
  90   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  91             [Defined if we're not going to look for a torrc in SYSCONF])
  92 fi
  93
  94 if test "$enable_memory_sentinels" = "no"; then
  95   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  96            [Defined if we're turning off memory safety code to look for bugs])
  97 fi
  98
  99 AC_ARG_ENABLE(asciidoc,
 100      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
 101      [case "${enableval}" in
 102         "yes") asciidoc=true ;;
 103         "no")  asciidoc=false ;;
 104         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
 105       esac], [asciidoc=true])
 106
 107 # systemd notify support
 108 AC_ARG_ENABLE(systemd,
 109       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 110       [case "${enableval}" in
 111         "yes") systemd=true ;;
 112         "no")  systemd=false ;;
 113         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 114       esac], [systemd=auto])
 115
 116 if test "$enable_restart_debugging" = "yes"; then
 117   AC_DEFINE(ENABLE_RESTART_DEBUGGING, 1,
 118             [Defined if we're building with support for in-process restart debugging.])
 119 fi
 120
 121 if test "$enable_zstd_advanced_apis" != "no"; then
 122    AC_DEFINE(ENABLE_ZSTD_ADVANCED_APIS, 1,
 123              [Defined if we're going to try to use zstd's "static-only" APIs.])
 124 fi
 125
 126 # systemd support
 127 if test "x$enable_systemd" = "xno"; then
 128     have_systemd=no;
 129 else
 130     PKG_CHECK_MODULES(SYSTEMD,
 131         [libsystemd-daemon],
 132         have_systemd=yes,
 133         have_systemd=no)
 134     if test "x$have_systemd" = "xno"; then
 135         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 136         PKG_CHECK_MODULES(SYSTEMD,
 137             [libsystemd],
 138             have_systemd=yes,
 139             have_systemd=no)
 140     fi
 141 fi
 142
 143 if test "x$have_systemd" = "xyes"; then
 144     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 145     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 146     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 147     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 148          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 149 fi
 150 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 151 AC_SUBST(TOR_SYSTEMD_LIBS)
 152
 153 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 154     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 155 fi
 156
 157 case "$host" in
 158    *-*-solaris* )
 159      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 160      ;;
 161 esac
 162
 163 AC_ARG_ENABLE(gcc-warnings,
 164      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 165 AC_ARG_ENABLE(fatal-warnings,
 166      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 167 AC_ARG_ENABLE(gcc-warnings-advisory,
 168      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 169
 170 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 171 AC_ARG_ENABLE(gcc-hardening,
 172     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 173
 174 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 175 AC_ARG_ENABLE(expensive-hardening,
 176     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 177 AC_ARG_ENABLE(fragile-hardening,
 178     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 179 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 180   fragile_hardening="yes"
 181   AC_DEFINE(DEBUG_SMARTLIST, 1, [Enable smartlist debugging])
 182 fi
 183
 184 dnl Linker hardening options
 185 dnl Currently these options are ELF specific - you can't use this with MacOSX
 186 AC_ARG_ENABLE(linker-hardening,
 187     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 188
 189 AC_ARG_ENABLE(local-appdata,
 190    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 191 if test "$enable_local_appdata" = "yes"; then
 192   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 193             [Defined if we default to host local appdata paths on Windows])
 194 fi
 195
 196 AC_ARG_ENABLE(tool-name-check,
 197      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 198
 199 AC_ARG_ENABLE(seccomp,
 200      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 201
 202 AC_ARG_ENABLE(libscrypt,
 203      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 204
 205 dnl Enable event tracing which are transformed to debug log statement.
 206 AC_ARG_ENABLE(event-tracing-debug,
 207      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 208 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 209
 210 if test x$enable_event_tracing_debug = xyes; then
 211   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 212   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 213 fi
 214
 215 dnl Enable Android only features.
 216 AC_ARG_ENABLE(android,
 217      AS_HELP_STRING(--enable-android, [build with Android features enabled]))
 218 AM_CONDITIONAL([USE_ANDROID], [test "x$enable_android" = "xyes"])
 219
 220 if test "x$enable_android" = "xyes"; then
 221   AC_DEFINE([USE_ANDROID], [1], [Compile with Android specific features enabled])
 222
 223   dnl Check if the Android log library is available.
 224   AC_CHECK_HEADERS([android/log.h])
 225   AC_SEARCH_LIBS(__android_log_write, [log])
 226
 227 fi
 228
 229 dnl ---
 230 dnl Tor modules options. These options are namespaced with --disable-module-XXX
 231 dnl ---
 232
 233 dnl All our modules.
 234 m4_define(MODULES, dirauth)
 235
 236 dnl Directory Authority module.
 237 AC_ARG_ENABLE([module-dirauth],
 238               AS_HELP_STRING([--disable-module-dirauth],
 239                              [Do not build tor with the dirauth module]),
 240               [], dnl Action if-given
 241               AC_DEFINE([HAVE_MODULE_DIRAUTH], [1],
 242                         [Compile with Directory Authority feature support]))
 243 AM_CONDITIONAL(BUILD_MODULE_DIRAUTH, [test "x$enable_module_dirauth" != "xno"])
 244
 245 dnl Helper variables.
 246 TOR_MODULES_ALL_ENABLED=
 247 AC_DEFUN([ADD_MODULE], [
 248     MODULE=m4_toupper($1)
 249     TOR_MODULES_ALL_ENABLED="${TOR_MODULES_ALL_ENABLED} -DHAVE_MODULE_${MODULE}=1"
 250 ])
 251 m4_foreach_w([module], MODULES, [ADD_MODULE([module])])
 252 AC_SUBST(TOR_MODULES_ALL_ENABLED)
 253
 254 dnl check for the correct "ar" when cross-compiling.
 255 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 256 dnl    so kludge up a replacement for the case where it isn't there yet.)
 257 m4_ifdef([AM_PROG_AR],
 258          [AM_PROG_AR],
 259          [AN_MAKEVAR([AR], [AC_PROG_AR])
 260           AN_PROGRAM([ar], [AC_PROG_AR])
 261           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 262           AC_PROG_AR])
 263
 264 dnl Check whether the above macro has settled for a simply named tool even
 265 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 266 dnl because that will find any cc on the system, not only the cross-compiler,
 267 dnl and then verify that a binary built with this compiler runs on the
 268 dnl build system. It will then come to the false conclusion that we're not
 269 dnl cross-compiling.
 270 if test "x$enable_tool_name_check" != "xno"; then
 271     if test "x$ac_tool_warned" = "xyes"; then
 272         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 273         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 274                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 275         fi
 276 fi
 277
 278 AC_PROG_CC
 279 AC_PROG_CPP
 280 AC_PROG_MAKE_SET
 281 AC_PROG_RANLIB
 282 AC_PROG_SED
 283
 284 AC_ARG_VAR([PERL], [path to Perl binary])
 285 AC_CHECK_PROGS([PERL], [perl])
 286 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 287
 288 dnl check for asciidoc and a2x
 289 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 290 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 291
 292 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 293
 294 AM_PROG_CC_C_O
 295 AC_PROG_CC_C99
 296
 297 AC_ARG_VAR([PYTHON], [path to Python binary])
 298 AC_CHECK_PROGS(PYTHON, [ \
 299         python3 \
 300         python3.8 python3.7 python3.6 python3.5 python3.4 \
 301         python \
 302         python2 python2.7])
 303 if test "x$PYTHON" = "x"; then
 304   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 305 fi
 306 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 307
 308 dnl List all external rust crates we depend on here. Include the version
 309 rust_crates=" \
 310     digest-0.7.2 \
 311     libc-0.2.39 \
 312 "
 313 AC_SUBST(rust_crates)
 314
 315 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 316 AC_C_FLEXIBLE_ARRAY_MEMBER
 317 ], [
 318  dnl Maybe we've got an old autoconf...
 319  AC_CACHE_CHECK([for flexible array members],
 320      tor_cv_c_flexarray,
 321      [AC_COMPILE_IFELSE(
 322        AC_LANG_PROGRAM([
 323  struct abc { int a; char b[]; };
 324 ], [
 325  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 326  def->b[0] = 33;
 327 ]),
 328   [tor_cv_c_flexarray=yes],
 329   [tor_cv_c_flexarray=no])])
 330  if test "$tor_cv_flexarray" = "yes"; then
 331    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 332  else
 333    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 334  fi
 335 ])
 336
 337 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 338       tor_cv_c_c99_decl,
 339       [AC_COMPILE_IFELSE(
 340          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 341          [tor_cv_c_c99_decl=yes],
 342          [tor_cv_c_c99_decl=no] )])
 343 if test "$tor_cv_c_c99_decl" != "yes"; then
 344   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 345 fi
 346
 347 AC_CACHE_CHECK([for working C99 designated initializers],
 348       tor_cv_c_c99_designated_init,
 349       [AC_COMPILE_IFELSE(
 350          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 351                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 352          [tor_cv_c_c99_designated_init=yes],
 353          [tor_cv_c_c99_designated_init=no] )])
 354
 355 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 356   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 357 fi
 358
 359 saved_CFLAGS="$CFLAGS"
 360 CFLAGS="$CFLAGS -Werror"
 361 AC_CACHE_CHECK([for __attribute__((fallthrough))],
 362       tor_cv_c_attr_fallthrough,
 363       [AC_COMPILE_IFELSE(
 364          [AC_LANG_PROGRAM([extern int x; void fn(void) ;],
 365                [[ switch (x) { case 1: fn(); __attribute__((fallthrough));
 366                                case 2: fn(); break; } ]])],
 367          [tor_cv_c_attr_fallthrough=yes],
 368          [tor_cv_c_attr_fallthrough=no] )])
 369 CFLAGS="$saved_CFLAGS"
 370
 371 if test "$tor_cv_c_attr_fallthrough" = "yes"; then
 372   AC_DEFINE(HAVE_ATTR_FALLTHROUGH, [1], [defined if we have the fallthrough attribute.])
 373 fi
 374
 375 TORUSER=_tor
 376 AC_ARG_WITH(tor-user,
 377         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 378         [
 379            TORUSER=$withval
 380         ]
 381 )
 382 AC_SUBST(TORUSER)
 383
 384 TORGROUP=_tor
 385 AC_ARG_WITH(tor-group,
 386         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 387         [
 388            TORGROUP=$withval
 389         ]
 390 )
 391 AC_SUBST(TORGROUP)
 392
 393
 394 dnl If _WIN32 is defined and non-zero, we are building for win32
 395 AC_MSG_CHECKING([for win32])
 396 AC_RUN_IFELSE([AC_LANG_SOURCE([
 397 int main(int c, char **v) {
 398 #ifdef _WIN32
 399 #if _WIN32
 400   return 0;
 401 #else
 402   return 1;
 403 #endif
 404 #else
 405   return 2;
 406 #endif
 407 }])],
 408 bwin32=true; AC_MSG_RESULT([yes]),
 409 bwin32=false; AC_MSG_RESULT([no]),
 410 bwin32=cross; AC_MSG_RESULT([cross])
 411 )
 412
 413 if test "$bwin32" = "cross"; then
 414 AC_MSG_CHECKING([for win32 (cross)])
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 416 #ifdef _WIN32
 417 int main(int c, char **v) {return 0;}
 418 #else
 419 #error
 420 int main(int c, char **v) {return x(y);}
 421 #endif
 422 ])],
 423 bwin32=true; AC_MSG_RESULT([yes]),
 424 bwin32=false; AC_MSG_RESULT([no]))
 425 fi
 426
 427 AH_BOTTOM([
 428 #ifdef _WIN32
 429 /* Defined to access windows functions and definitions for >=WinXP */
 430 # ifndef WINVER
 431 #  define WINVER 0x0501
 432 # endif
 433
 434 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 435 # ifndef _WIN32_WINNT
 436 #  define _WIN32_WINNT 0x0501
 437 # endif
 438
 439 /* Defined to avoid including some windows headers as part of Windows.h */
 440 # ifndef WIN32_LEAN_AND_MEAN
 441 #  define WIN32_LEAN_AND_MEAN 1
 442 # endif
 443 #endif
 444 ])
 445
 446 AM_CONDITIONAL(WIN32, test "x$bwin32" = "xtrue")
 447 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 448 AM_CONDITIONAL(BUILD_LIBTORRUNNER, test "x$bwin32" != "xtrue")
 449
 450 dnl Enable C99 when compiling with MIPSpro
 451 AC_MSG_CHECKING([for MIPSpro compiler])
 452 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 453 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 454 #error
 455   return x(y);
 456 #endif
 457 ])],
 458 bmipspro=false; AC_MSG_RESULT(no),
 459 bmipspro=true; AC_MSG_RESULT(yes))
 460
 461 if test "$bmipspro" = "true"; then
 462   CFLAGS="$CFLAGS -c99"
 463 fi
 464
 465 AC_C_BIGENDIAN
 466
 467 AC_ARG_VAR([TOR_RUST_TARGET], [Rust target, must be specified when cross-compiling (HOST != BUILD). example: i686-pc-windows-gnu])
 468
 469 if test "x$enable_rust" = "xyes"; then
 470   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 471   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 472   if test "x$RUSTC" = "xno"; then
 473     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 474   fi
 475
 476   AC_ARG_VAR([CARGO], [path to the cargo binary])
 477   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 478   if test "x$CARGO" = "xno"; then
 479     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 480   fi
 481
 482   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 483   if test "x$enable_fatal_warnings" = "xyes"; then
 484     RUST_WARN=
 485   else
 486     RUST_WARN=#
 487   fi
 488   if test "x$enable_cargo_online_mode" = "xyes"; then
 489     CARGO_ONLINE=
 490     RUST_DL=#
 491   else
 492     CARGO_ONLINE=--frozen
 493     RUST_DL=
 494
 495     dnl When we're not allowed to touch the network, we need crate dependencies
 496     dnl locally available.
 497     AC_MSG_CHECKING([rust crate dependencies])
 498     AC_ARG_VAR([TOR_RUST_DEPENDENCIES], [path to directory with local crate mirror])
 499     if test "x$TOR_RUST_DEPENDENCIES" = "x"; then
 500       TOR_RUST_DEPENDENCIES="${srcdir}/src/ext/rust/crates"
 501     fi
 502     dnl Check whether the path exists before we try to cd into it.
 503     if test ! -d "$TOR_RUST_DEPENDENCIES"; then
 504       AC_MSG_ERROR([Rust dependency directory $TOR_RUST_DEPENDENCIES does not exist. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 505       ERRORED=1
 506     fi
 507     dnl Make the path absolute, since we'll be using it from within a
 508     dnl subdirectory.
 509     TOR_RUST_DEPENDENCIES=$(cd "$TOR_RUST_DEPENDENCIES" ; pwd)
 510
 511     for dep in $rust_crates; do
 512       if test ! -d "$TOR_RUST_DEPENDENCIES"/"$dep"; then
 513         AC_MSG_ERROR([Failure to find rust dependency $TOR_RUST_DEPENDENCIES/$dep. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 514         ERRORED=1
 515       fi
 516     done
 517     if test "x$ERRORED" = "x"; then
 518       AC_MSG_RESULT([yes])
 519     fi
 520   fi
 521
 522   dnl This is a workaround for #46797
 523   dnl (a.k.a https://github.com/rust-lang/rust/issues/46797 ).  Once the
 524   dnl upstream bug is fixed, we can remove this workaround.
 525   case "$host_os" in
 526       darwin*)
 527         TOR_RUST_EXTRA_LIBS="-lresolv"
 528         ;;
 529   esac
 530
 531   dnl For now both MSVC and MinGW rust libraries will output static libs with
 532   dnl the MSVC naming convention.
 533   if test "$bwin32" = "true"; then
 534     tor_rust_static_name=tor_rust.lib
 535   else
 536     tor_rust_static_name=libtor_rust.a
 537   fi
 538
 539   AC_CANONICAL_BUILD
 540
 541   if test -n "$TOR_RUST_TARGET"; then
 542     if test "$host" = "$build"; then
 543       AC_MSG_ERROR([HOST = BUILD is invalid if TOR_RUST_TARGET is specified, see configure --help for more information.])
 544     fi
 545     RUST_TARGET_PROP="target = '$TOR_RUST_TARGET'"
 546     TOR_RUST_LIB_PATH="src/rust/target/$TOR_RUST_TARGET/release/$tor_rust_static_name"
 547   else
 548     if test "$host" != "$build"; then
 549       AC_MSG_ERROR([TOR_RUST_TARGET must be specified when cross-compiling with Rust enabled.])
 550     fi
 551     RUST_TARGET_PROP=
 552     TOR_RUST_LIB_PATH="src/rust/target/release/$tor_rust_static_name"
 553   fi
 554
 555   AC_SUBST(RUST_TARGET_PROP)
 556   AC_SUBST(TOR_RUST_LIB_PATH)
 557   AC_SUBST(CARGO_ONLINE)
 558   AC_SUBST(RUST_WARN)
 559   AC_SUBST(RUST_DL)
 560
 561   dnl Let's check the rustc version, too
 562   AC_MSG_CHECKING([rust version])
 563   RUSTC_VERSION=`$RUSTC --version`
 564   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 565   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 566   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 567     AC_MSG_ERROR([rustc version couldn't be identified])
 568   fi
 569   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 570     AC_MSG_ERROR([rustc must be at least version 1.14])
 571   fi
 572   AC_MSG_RESULT([$RUSTC_VERSION])
 573 fi
 574
 575 AC_SUBST(TOR_RUST_EXTRA_LIBS)
 576
 577 AC_SEARCH_LIBS(socket, [socket network])
 578 AC_SEARCH_LIBS(gethostbyname, [nsl])
 579 AC_SEARCH_LIBS(dlopen, [dl])
 580 AC_SEARCH_LIBS(inet_aton, [resolv])
 581 AC_SEARCH_LIBS(backtrace, [execinfo])
 582 saved_LIBS="$LIBS"
 583 AC_SEARCH_LIBS([clock_gettime], [rt])
 584 if test "$LIBS" != "$saved_LIBS"; then
 585    # Looks like we need -lrt for clock_gettime().
 586    have_rt=yes
 587 fi
 588
 589 if test "$bwin32" = "false"; then
 590   AC_SEARCH_LIBS(pthread_create, [pthread])
 591   AC_SEARCH_LIBS(pthread_detach, [pthread])
 592 fi
 593
 594 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 595 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 596
 597 AC_CHECK_FUNCS(
 598         _NSGetEnviron \
 599         RtlSecureZeroMemory \
 600         SecureZeroMemory \
 601         accept4 \
 602         backtrace \
 603         backtrace_symbols_fd \
 604         eventfd \
 605         explicit_bzero \
 606         timingsafe_memcmp \
 607         flock \
 608         ftime \
 609         get_current_dir_name \
 610         getaddrinfo \
 611         getdelim \
 612         getifaddrs \
 613         getline \
 614         getpass \
 615         getrlimit \
 616         gettimeofday \
 617         gmtime_r \
 618         gnu_get_libc_version \
 619         htonll \
 620         inet_aton \
 621         ioctl \
 622         issetugid \
 623         llround \
 624         localtime_r \
 625         lround \
 626         memmem \
 627         memset_s \
 628         mmap \
 629         pipe \
 630         pipe2 \
 631         prctl \
 632         readpassphrase \
 633         rint \
 634         sigaction \
 635         socketpair \
 636         statvfs \
 637         strncasecmp \
 638         strcasecmp \
 639         strlcat \
 640         strlcpy \
 641         strnlen \
 642         strptime \
 643         strtok_r \
 644         strtoull \
 645         sysconf \
 646         sysctl \
 647         truncate \
 648         uname \
 649         usleep \
 650         vasprintf \
 651         _vscprintf
 652 )
 653
 654 # Apple messed up when they added some functions: they
 655 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 656 # checks.
 657
 658 # We should only probe for these functions if we are sure that we
 659 # are not targeting OS X 10.9 or earlier.
 660 AC_MSG_CHECKING([for a pre-Yosemite OS X build target])
 661 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 662 #ifdef __APPLE__
 663 #  include <AvailabilityMacros.h>
 664 #  ifndef MAC_OS_X_VERSION_10_10
 665 #    define MAC_OS_X_VERSION_10_10 101000
 666 #  endif
 667 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 668 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_10
 669 #      error "Running on Mac OS X 10.9 or earlier"
 670 #    endif
 671 #  endif
 672 #endif
 673 ]], [[]])],
 674    [on_macos_pre_10_10=no ; AC_MSG_RESULT([no])],
 675    [on_macos_pre_10_10=yes; AC_MSG_RESULT([yes])])
 676
 677 if test "$on_macos_pre_10_10" = "no"; then
 678   AC_CHECK_FUNCS(
 679         mach_approximate_time \
 680   )
 681 fi
 682
 683 # We should only probe for these functions if we are sure that we
 684 # are not targeting OSX 10.11 or earlier.
 685 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 686 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 687 #ifdef __APPLE__
 688 #  include <AvailabilityMacros.h>
 689 #  ifndef MAC_OS_X_VERSION_10_12
 690 #    define MAC_OS_X_VERSION_10_12 101200
 691 #  endif
 692 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 693 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 694 #      error "Running on Mac OSX 10.11 or earlier"
 695 #    endif
 696 #  endif
 697 #endif
 698 ]], [[]])],
 699    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 700    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 701
 702 if test "$on_macos_pre_10_12" = "no"; then
 703   AC_CHECK_FUNCS(
 704         clock_gettime \
 705         getentropy \
 706   )
 707 fi
 708
 709 if test "$bwin32" != "true"; then
 710   AC_CHECK_HEADERS(pthread.h)
 711   AC_CHECK_FUNCS(pthread_create)
 712   AC_CHECK_FUNCS(pthread_condattr_setclock)
 713 fi
 714
 715 if test "$bwin32" = "true"; then
 716   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 717 #include <windows.h>
 718 #include <conio.h>
 719 #include <wchar.h>
 720                  ])
 721 fi
 722
 723 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 724   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 725
 726 AC_MSG_CHECKING([whether free(NULL) works])
 727 AC_RUN_IFELSE([AC_LANG_PROGRAM([
 728   #include <stdlib.h>
 729 ], [
 730 char *p = NULL;
 731 free(p);
 732 ])],
 733 [free_null_ok=true; AC_MSG_RESULT(yes)],
 734 [free_null_ok=false; AC_MSG_RESULT(no)],
 735 [free_null_ok=cross; AC_MSG_RESULT(cross)])
 736
 737 if test "$free_null_ok" = "false"; then
 738    AC_MSG_ERROR([Your libc implementation doesn't allow free(NULL), as required by C99.])
 739 fi
 740
 741 dnl ------------------------------------------------------
 742 dnl Where do you live, libevent?  And how do we call you?
 743
 744 if test "$bwin32" = "true"; then
 745   TOR_LIB_WS32=-lws2_32
 746   TOR_LIB_IPHLPAPI=-liphlpapi
 747   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 748   # think it's actually necessary.
 749   TOR_LIB_GDI=-lgdi32
 750   TOR_LIB_USERENV=-luserenv
 751 else
 752   TOR_LIB_WS32=
 753   TOR_LIB_GDI=
 754   TOR_LIB_USERENV=
 755 fi
 756 AC_SUBST(TOR_LIB_WS32)
 757 AC_SUBST(TOR_LIB_GDI)
 758 AC_SUBST(TOR_LIB_IPHLPAPI)
 759 AC_SUBST(TOR_LIB_USERENV)
 760
 761 tor_libevent_pkg_redhat="libevent"
 762 tor_libevent_pkg_debian="libevent-dev"
 763 tor_libevent_devpkg_redhat="libevent-devel"
 764 tor_libevent_devpkg_debian="libevent-dev"
 765
 766 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 767 dnl linking for static builds.
 768 STATIC_LIBEVENT_FLAGS=""
 769 if test "$enable_static_libevent" = "yes"; then
 770     if test "$have_rt" = "yes"; then
 771       STATIC_LIBEVENT_FLAGS=" -lrt "
 772     fi
 773 fi
 774
 775 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 776 #ifdef _WIN32
 777 #include <winsock2.h>
 778 #endif
 779 #include <sys/time.h>
 780 #include <sys/types.h>
 781 #include <event2/event.h>], [
 782 #ifdef _WIN32
 783 #include <winsock2.h>
 784 #endif
 785 struct event_base;
 786 struct event_base *event_base_new(void);
 787 void event_base_free(struct event_base *);],
 788     [
 789 #ifdef _WIN32
 790 {WSADATA d; WSAStartup(0x101,&d); }
 791 #endif
 792 event_base_free(event_base_new());
 793 ], [--with-libevent-dir], [/opt/libevent])
 794
 795 dnl Determine the incantation needed to link libevent.
 796 save_LIBS="$LIBS"
 797 save_LDFLAGS="$LDFLAGS"
 798 save_CPPFLAGS="$CPPFLAGS"
 799
 800 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 801 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 802 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 803
 804 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 805
 806 if test "$enable_static_libevent" = "yes"; then
 807    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 808      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 809    else
 810      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 811    fi
 812 else
 813      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 814        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 815        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 816
 817        if test "$ac_cv_search_event_new" != "none required"; then
 818          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 819        fi
 820        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 821          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 822        fi
 823      else
 824        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 825      fi
 826 fi
 827
 828 dnl Now check for particular libevent functions.
 829 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 830                 evutil_secure_rng_add_bytes \
 831 ])
 832
 833 LIBS="$save_LIBS"
 834 LDFLAGS="$save_LDFLAGS"
 835 CPPFLAGS="$save_CPPFLAGS"
 836
 837 dnl Check that libevent is at least at version 2.0.10, the first stable
 838 dnl release of its series
 839 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 840 AC_MSG_CHECKING([whether Libevent is new enough])
 841 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 842 #include <event2/event.h>
 843 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 844 #error
 845 int x = y(zz);
 846 #else
 847 int x = 1;
 848 #endif
 849 ])], [ AC_MSG_RESULT([yes]) ],
 850    [ AC_MSG_RESULT([no])
 851      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 852
 853 LIBS="$save_LIBS"
 854 LDFLAGS="$save_LDFLAGS"
 855 CPPFLAGS="$save_CPPFLAGS"
 856
 857 AC_SUBST(TOR_LIBEVENT_LIBS)
 858
 859 dnl ------------------------------------------------------
 860 dnl Where do you live, libm?
 861
 862 dnl On some platforms (Haiku/BeOS) the math library is
 863 dnl part of libroot. In which case don't link against lm
 864 TOR_LIB_MATH=""
 865 save_LIBS="$LIBS"
 866 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 867 if test "$ac_cv_search_pow" != "none required"; then
 868     TOR_LIB_MATH="$ac_cv_search_pow"
 869 fi
 870 LIBS="$save_LIBS"
 871 AC_SUBST(TOR_LIB_MATH)
 872
 873 dnl ------------------------------------------------------
 874 dnl Hello, NSS.  You're new around here.
 875 if test "x$enable_nss" = "xyes"; then
 876   PKG_CHECK_MODULES(NSS,
 877      [nss],
 878      [have_nss=yes],
 879      [have_nss=no; AC_MSG_ERROR([You asked for NSS but I can't find it.])])
 880   AC_SUBST(NSS_CFLAGS)
 881   AC_SUBST(NSS_LIBS)
 882 fi
 883
 884 dnl ------------------------------------------------------
 885 dnl Where do you live, openssl?  And how do we call you?
 886
 887 if test "x$enable_nss" != "xyes"; then
 888
 889 tor_openssl_pkg_redhat="openssl"
 890 tor_openssl_pkg_debian="libssl-dev"
 891 tor_openssl_devpkg_redhat="openssl-devel"
 892 tor_openssl_devpkg_debian="libssl-dev"
 893
 894 ALT_openssl_WITHVAL=""
 895 AC_ARG_WITH(ssl-dir,
 896   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 897   [
 898       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 899          ALT_openssl_WITHVAL="$withval"
 900       fi
 901   ])
 902
 903 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 904 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 905     [#include <openssl/ssl.h>
 906      char *getenv(const char *);],
 907     [struct ssl_cipher_st;
 908      unsigned SSL_CIPHER_get_id(const struct ssl_cipher_st *);
 909      char *getenv(const char *);],
 910     dnl This funny-looking test program calls getenv, so that the compiler
 911     dnl will neither make code that call SSL_CIPHER_get_id(NULL) [producing
 912     dnl a crash], nor optimize out the call to SSL_CIPHER_get_id().
 913     dnl We look for SSL_cipher_get_id() because it is present in
 914     dnl OpenSSL >=1.0.1, because it is not deprecated, and because Tor
 915     dnl depends on it.
 916     [if (getenv("THIS_SHOULDNT_BE_SET_X201803")) SSL_CIPHER_get_id((void *)0);], [],
 917     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /opt/openssl])
 918
 919 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 920
 921 if test "$enable_static_openssl" = "yes"; then
 922    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 923      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 924    else
 925      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 926    fi
 927 else
 928      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 929 fi
 930 AC_SUBST(TOR_OPENSSL_LIBS)
 931
 932 dnl Now check for particular openssl functions.
 933 save_LIBS="$LIBS"
 934 save_LDFLAGS="$LDFLAGS"
 935 save_CPPFLAGS="$CPPFLAGS"
 936 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 937 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 938 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 939
 940 dnl Tor currently uses a number of APIs that are deprecated in OpenSSL 3.0.0
 941 dnl and later.  We want to migrate away from them, but that will be a lot of
 942 dnl work. (See ticket tor#40166.)  For now, we disable the deprecation
 943 dnl warnings.
 944
 945 AC_MSG_CHECKING([for OpenSSL >= 3.0.0])
 946 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 947 #include <openssl/opensslv.h>
 948 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER <= 0x30000000L
 949 #error "you_have_version_3"
 950 #endif
 951    ]], [[]])],
 952    [ AC_MSG_RESULT([no]) ],
 953    [ AC_MSG_RESULT([yes]);
 954      AC_DEFINE(OPENSSL_SUPPRESS_DEPRECATED, 1, [disable openssl deprecated-function warnings]) ])
 955
 956 AC_MSG_CHECKING([for OpenSSL < 1.0.1])
 957 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 958 #include <openssl/opensslv.h>
 959 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 960 #error "too old"
 961 #endif
 962    ]], [[]])],
 963    [ AC_MSG_RESULT([no]) ],
 964    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 965
 966 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 967 #include <openssl/opensslv.h>
 968 #include <openssl/evp.h>
 969 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 970 #error "no ECC"
 971 #endif
 972 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 973 #error "curves unavailable"
 974 #endif
 975    ]], [[]])],
 976    [ : ],
 977    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 978
 979 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 980 [#include <openssl/ssl.h>
 981 ])
 982
 983 AC_CHECK_FUNCS([ \
 984                 ERR_load_KDF_strings \
 985                 SSL_SESSION_get_master_key \
 986                 SSL_get_server_random \
 987                 SSL_get_client_ciphers \
 988                 SSL_get_client_random \
 989                 SSL_CTX_set1_groups_list \
 990                 SSL_CIPHER_find \
 991                 SSL_CTX_set_security_level \
 992                 TLS_method
 993                ])
 994
 995 dnl Check if OpenSSL has scrypt implementation.
 996 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 997
 998 dnl Check if OpenSSL structures are opaque
 999 AC_CHECK_MEMBERS([SSL.state], , ,
1000 [#include <openssl/ssl.h>
1001 ])
1002
1003 AC_CHECK_SIZEOF(SHA_CTX, , [AC_INCLUDES_DEFAULT()
1004 #include <openssl/sha.h>
1005 ])
1006
1007 fi # enable_nss
1008
1009 dnl ======================================================================
1010 dnl Can we use KIST?
1011
1012 dnl Define the set of checks for KIST scheduler support.
1013 AC_DEFUN([CHECK_KIST_SUPPORT],[
1014   dnl KIST needs struct tcp_info and for certain members to exist.
1015   AC_CHECK_MEMBERS(
1016     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
1017     , ,[[#include <netinet/tcp.h>]])
1018   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
1019   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1020                      #include <linux/sockios.h>
1021                      #ifndef SIOCOUTQNSD
1022                      #error
1023                      #endif
1024                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
1025   if test "x$have_siocoutqnsd" = "xyes"; then
1026     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
1027       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
1028         have_kist_support=yes
1029       fi
1030     fi
1031   fi
1032 ])
1033 dnl Now, trigger the check.
1034 CHECK_KIST_SUPPORT
1035 AS_IF([test "x$have_kist_support" = "xyes"],
1036       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
1037                                         on this system])],
1038       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
1039
1040 LIBS="$save_LIBS"
1041 LDFLAGS="$save_LDFLAGS"
1042 CPPFLAGS="$save_CPPFLAGS"
1043
1044 dnl ------------------------------------------------------
1045 dnl Where do you live, zlib?  And how do we call you?
1046
1047 tor_zlib_pkg_redhat="zlib"
1048 tor_zlib_pkg_debian="zlib1g"
1049 tor_zlib_devpkg_redhat="zlib-devel"
1050 tor_zlib_devpkg_debian="zlib1g-dev"
1051
1052 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
1053     [#include <zlib.h>],
1054     [const char * zlibVersion(void);],
1055     [zlibVersion();], [--with-zlib-dir],
1056     [/opt/zlib])
1057
1058 if test "$enable_static_zlib" = "yes"; then
1059    if test "$tor_cv_library_zlib_dir" = "(system)"; then
1060      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
1061  using --enable-static-zlib")
1062    else
1063      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
1064    fi
1065 else
1066      TOR_ZLIB_LIBS="-lz"
1067 fi
1068 AC_SUBST(TOR_ZLIB_LIBS)
1069
1070 dnl ------------------------------------------------------
1071 dnl Where we do we find lzma?
1072
1073 AC_ARG_ENABLE(lzma,
1074       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
1075       [case "${enableval}" in
1076         "yes") lzma=true ;;
1077         "no")  lzma=false ;;
1078         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
1079       esac], [lzma=auto])
1080
1081 if test "x$enable_lzma" = "xno"; then
1082     have_lzma=no;
1083 else
1084     PKG_CHECK_MODULES([LZMA],
1085                       [liblzma],
1086                       have_lzma=yes,
1087                       have_lzma=no)
1088
1089     if test "x$have_lzma" = "xno" ; then
1090         AC_MSG_WARN([Unable to find liblzma.])
1091     fi
1092 fi
1093
1094 if test "x$have_lzma" = "xyes"; then
1095     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
1096     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
1097     TOR_LZMA_LIBS="${LZMA_LIBS}"
1098 fi
1099 AC_SUBST(TOR_LZMA_CFLAGS)
1100 AC_SUBST(TOR_LZMA_LIBS)
1101
1102 dnl ------------------------------------------------------
1103 dnl Where we do we find zstd?
1104
1105 AC_ARG_ENABLE(zstd,
1106       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
1107       [case "${enableval}" in
1108         "yes") zstd=true ;;
1109         "no")  zstd=false ;;
1110         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
1111       esac], [zstd=auto])
1112
1113 if test "x$enable_zstd" = "xno"; then
1114     have_zstd=no;
1115 else
1116     PKG_CHECK_MODULES([ZSTD],
1117                       [libzstd >= 1.1],
1118                       have_zstd=yes,
1119                       have_zstd=no)
1120
1121     if test "x$have_zstd" = "xno" ; then
1122         AC_MSG_WARN([Unable to find libzstd.])
1123     fi
1124 fi
1125
1126 if test "x$have_zstd" = "xyes"; then
1127     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
1128     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
1129     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
1130
1131     dnl now check for zstd functions
1132     save_LIBS="$LIBS"
1133     save_CFLAGS="$CFLAGS"
1134     LIBS="$LIBS $ZSTD_LIBS"
1135     CFLAGS="$CFLAGS $ZSTD_CFLAGS"
1136     AC_CHECK_FUNCS(ZSTD_estimateCStreamSize \
1137                    ZSTD_estimateDCtxSize)
1138     LIBS="$save_LIBS"
1139     CFLAGS="$save_CFLAGS"
1140 fi
1141 AC_SUBST(TOR_ZSTD_CFLAGS)
1142 AC_SUBST(TOR_ZSTD_LIBS)
1143
1144 dnl ----------------------------------------------------------------------
1145 dnl Check if libcap is available for capabilities.
1146
1147 tor_cap_pkg_debian="libcap2"
1148 tor_cap_pkg_redhat="libcap"
1149 tor_cap_devpkg_debian="libcap-dev"
1150 tor_cap_devpkg_redhat="libcap-devel"
1151
1152 AC_CHECK_LIB([cap], [cap_init], [],
1153   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
1154 )
1155 AC_CHECK_FUNCS(cap_set_proc)
1156
1157 dnl ---------------------------------------------------------------------
1158 dnl Now that we know about our major libraries, we can check for compiler
1159 dnl and linker hardening options.  We need to do this with the libraries known,
1160 dnl since sometimes the linker will like an option but not be willing to
1161 dnl use it with a build of a library.
1162
1163 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
1164 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
1165
1166 CFLAGS_FTRAPV=
1167 CFLAGS_FWRAPV=
1168 CFLAGS_ASAN=
1169 CFLAGS_UBSAN=
1170
1171
1172 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1173 #if !defined(__clang__)
1174 #error
1175 #endif])], have_clang=yes, have_clang=no)
1176
1177 if test "x$enable_pic" = "xyes"; then
1178     TOR_CHECK_CFLAGS(-fPIC)
1179 fi
1180
1181 if test "x$enable_gcc_hardening" != "xno"; then
1182     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
1183     if test "x$have_clang" = "xyes"; then
1184         TOR_CHECK_CFLAGS(-Qunused-arguments)
1185     fi
1186     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
1187     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
1188     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
1189 m4_ifdef([AS_VAR_IF],[
1190     AS_VAR_IF(can_compile, [yes],
1191         AS_VAR_IF(can_link, [yes],
1192                   [],
1193                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
1194         )])
1195     AS_VAR_POPDEF([can_link])
1196     AS_VAR_POPDEF([can_compile])
1197     TOR_CHECK_CFLAGS(-Wstack-protector)
1198     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
1199     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
1200        if test "$enable_pic" != "yes"; then
1201            # If we have already enabled -fPIC, then we don't also need to
1202            # compile with -fPIE...
1203            TOR_CHECK_CFLAGS(-fPIE)
1204        fi
1205        # ... but we want to link our executables with -pie in any case, since
1206        # they're executables, not a library.
1207        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
1208     fi
1209     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
1210 fi
1211
1212 if test "$fragile_hardening" = "yes"; then
1213     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
1214    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
1215       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
1216    fi
1217
1218    if test "$tor_cv_cflags__ftrapv" != "yes"; then
1219      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
1220    fi
1221
1222    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
1223     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1224       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.*, and with Clang you need libclang_rt.ubsan*])
1225     fi
1226
1227    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1228     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1229       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1230     fi
1231
1232 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1233 fi
1234
1235 dnl Find the correct libraries to add in order to use the sanitizers.
1236 dnl
1237 dnl When building Rust, Cargo will run the linker with the -nodefaultlibs
1238 dnl option, which will prevent the compiler from linking the sanitizer
1239 dnl libraries it needs.  We need to specify them manually.
1240 dnl
1241 dnl What's more, we need to specify them in a linker script rather than
1242 dnl from build.rs: these options aren't allowed in the cargo:rustc-flags
1243 dnl variable.
1244 RUST_LINKER_OPTIONS=""
1245 if test "x$have_clang" = "xyes"; then
1246         if test "x$CFLAGS_ASAN" != "x"; then
1247                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=$CFLAGS_ASAN -Cdefault-linker-libraries"
1248         fi
1249         if test "x$CFLAGS_UBSAN" != "x"; then
1250                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=$CFLAGS_UBSAN -Cdefault-linker-libraries"
1251         fi
1252 else
1253         if test "x$CFLAGS_ASAN" != "x"; then
1254                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=-fsanitize=address -Cdefault-linker-libraries"
1255         fi
1256         if test "x$CFLAGS_UBSAN" != "x"; then
1257                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=-fsanitize=undefined -Cdefault-linker-libraries"
1258         fi
1259 fi
1260 AC_SUBST(RUST_LINKER_OPTIONS)
1261
1262 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1263 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1264
1265 mulodi_fixes_ftrapv=no
1266 if test "$have_clang" = "yes"; then
1267   saved_CFLAGS="$CFLAGS"
1268   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1269   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1270   AC_LINK_IFELSE([
1271       AC_LANG_SOURCE([[
1272           #include <stdint.h>
1273           #include <stdlib.h>
1274           int main(int argc, char **argv)
1275           {
1276             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1277                         * (int64_t)atoi(argv[3]);
1278             return x == 9;
1279           } ]])],
1280           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1281           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1282   if test "$ftrapv_can_link" = "no"; then
1283     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1284     AC_LINK_IFELSE([
1285       AC_LANG_SOURCE([[
1286           #include <stdint.h>
1287           #include <stdlib.h>
1288           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1289              *overflow=0;
1290              return a;
1291           }
1292           int main(int argc, char **argv)
1293           {
1294             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1295                         * (int64_t)atoi(argv[3]);
1296             return x == 9;
1297           } ]])],
1298           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1299           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1300   fi
1301   CFLAGS="$saved_CFLAGS"
1302 fi
1303
1304 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1305
1306 dnl These cflags add bunches of branches, and we haven't been able to
1307 dnl persuade ourselves that they're suitable for code that needs to be
1308 dnl constant time.
1309 AC_SUBST(CFLAGS_BUGTRAP)
1310 dnl These cflags are variant ones sutable for code that needs to be
1311 dnl constant-time.
1312 AC_SUBST(CFLAGS_CONSTTIME)
1313
1314 if test "x$enable_linker_hardening" != "xno"; then
1315     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1316 fi
1317
1318 # For backtrace support
1319 TOR_CHECK_LDFLAGS(-rdynamic)
1320
1321 dnl ------------------------------------------------------
1322 dnl Now see if we have a -fomit-frame-pointer compiler option.
1323
1324 saved_CFLAGS="$CFLAGS"
1325 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1326 F_OMIT_FRAME_POINTER=''
1327 if test "$saved_CFLAGS" != "$CFLAGS"; then
1328   if test "$fragile_hardening" = "yes"; then
1329     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1330   fi
1331 fi
1332 CFLAGS="$saved_CFLAGS"
1333 AC_SUBST(F_OMIT_FRAME_POINTER)
1334
1335 dnl ------------------------------------------------------
1336 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1337 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1338 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1339 dnl code will work.
1340 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1341
1342 dnl ============================================================
1343 dnl Check for libseccomp
1344
1345 if test "x$enable_seccomp" != "xno"; then
1346   AC_CHECK_HEADERS([seccomp.h])
1347   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1348 fi
1349
1350 dnl ============================================================
1351 dnl Check for libscrypt
1352
1353 if test "x$enable_libscrypt" != "xno"; then
1354   AC_CHECK_HEADERS([libscrypt.h])
1355   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1356   AC_CHECK_FUNCS([libscrypt_scrypt])
1357 fi
1358
1359 dnl ============================================================
1360 dnl We need an implementation of curve25519.
1361
1362 dnl set these defaults.
1363 build_curve25519_donna=no
1364 build_curve25519_donna_c64=no
1365 use_curve25519_donna=no
1366 use_curve25519_nacl=no
1367 CURVE25519_LIBS=
1368
1369 dnl The best choice is using curve25519-donna-c64, but that requires
1370 dnl that we
1371 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1372   tor_cv_can_use_curve25519_donna_c64,
1373   [AC_RUN_IFELSE(
1374     [AC_LANG_PROGRAM([dnl
1375       #include <stdint.h>
1376       typedef unsigned uint128_t __attribute__((mode(TI)));
1377   int func(uint64_t a, uint64_t b) {
1378            uint128_t c = ((uint128_t)a) * b;
1379            int ok = ((uint64_t)(c>>96)) == 522859 &&
1380              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1381                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1382                  (((uint64_t)(c))&0xffffffffL) == 0;
1383            return ok;
1384       }
1385   ], [dnl
1386     int ok = func( ((uint64_t)2000000000) * 1000000000,
1387                    ((uint64_t)1234567890) << 24);
1388         return !ok;
1389       ])],
1390   [tor_cv_can_use_curve25519_donna_c64=yes],
1391       [tor_cv_can_use_curve25519_donna_c64=no],
1392   [AC_LINK_IFELSE(
1393         [AC_LANG_PROGRAM([dnl
1394       #include <stdint.h>
1395       typedef unsigned uint128_t __attribute__((mode(TI)));
1396   int func(uint64_t a, uint64_t b) {
1397            uint128_t c = ((uint128_t)a) * b;
1398            int ok = ((uint64_t)(c>>96)) == 522859 &&
1399              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1400                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1401                  (((uint64_t)(c))&0xffffffffL) == 0;
1402            return ok;
1403       }
1404   ], [dnl
1405     int ok = func( ((uint64_t)2000000000) * 1000000000,
1406                  ((uint64_t)1234567890) << 24);
1407         return !ok;
1408       ])],
1409           [tor_cv_can_use_curve25519_donna_c64=cross],
1410       [tor_cv_can_use_curve25519_donna_c64=no])])])
1411
1412 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1413                   nacl/crypto_scalarmult_curve25519.h])
1414
1415 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1416   tor_cv_can_use_curve25519_nacl,
1417   [tor_saved_LIBS="$LIBS"
1418    LIBS="$LIBS -lnacl"
1419    AC_LINK_IFELSE(
1420      [AC_LANG_PROGRAM([dnl
1421        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1422        #include <crypto_scalarmult_curve25519.h>
1423    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1424    #include <nacl/crypto_scalarmult_curve25519.h>
1425    #endif
1426        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1427    #error Hey, this is the reference implementation! That's not fast.
1428    #endif
1429      ], [
1430    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1431      ])], [tor_cv_can_use_curve25519_nacl=yes],
1432      [tor_cv_can_use_curve25519_nacl=no])
1433    LIBS="$tor_saved_LIBS" ])
1434
1435  dnl Okay, now we need to figure out which one to actually use. Fall back
1436  dnl to curve25519-donna.c
1437
1438  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1439    build_curve25519_donna_c64=yes
1440    use_curve25519_donna=yes
1441  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1442    use_curve25519_nacl=yes
1443    CURVE25519_LIBS=-lnacl
1444  else
1445    build_curve25519_donna=yes
1446    use_curve25519_donna=yes
1447  fi
1448
1449 if test "x$use_curve25519_donna" = "xyes"; then
1450   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1451             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1452 fi
1453 if test "x$use_curve25519_nacl" = "xyes"; then
1454   AC_DEFINE(USE_CURVE25519_NACL, 1,
1455             [Defined if we should use a curve25519 from nacl])
1456 fi
1457 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1458   test "x$build_curve25519_donna" = "xyes")
1459 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1460   test "x$build_curve25519_donna_c64" = "xyes")
1461 AC_SUBST(CURVE25519_LIBS)
1462
1463 dnl Make sure to enable support for large off_t if available.
1464 AC_SYS_LARGEFILE
1465
1466 AC_CHECK_HEADERS([errno.h \
1467                   fcntl.h \
1468                   signal.h \
1469                   string.h \
1470                   sys/capability.h \
1471                   sys/fcntl.h \
1472                   sys/stat.h \
1473                   sys/time.h \
1474                   sys/types.h \
1475                   time.h \
1476                   unistd.h \
1477                   arpa/inet.h \
1478                   crt_externs.h \
1479                   execinfo.h \
1480                   gnu/libc-version.h \
1481                   grp.h \
1482                   ifaddrs.h \
1483                   inttypes.h \
1484                   limits.h \
1485                   linux/types.h \
1486                   machine/limits.h \
1487                   malloc.h \
1488                   malloc/malloc.h \
1489                   malloc_np.h \
1490                   netdb.h \
1491                   netinet/in.h \
1492                   netinet/in6.h \
1493                   pwd.h \
1494                   readpassphrase.h \
1495                   stdatomic.h \
1496                   sys/eventfd.h \
1497                   sys/file.h \
1498                   sys/ioctl.h \
1499                   sys/limits.h \
1500                   sys/mman.h \
1501                   sys/param.h \
1502                   sys/prctl.h \
1503                   sys/random.h \
1504                   sys/resource.h \
1505                   sys/select.h \
1506                   sys/socket.h \
1507                   sys/statvfs.h \
1508                   sys/syscall.h \
1509                   sys/sysctl.h \
1510                   sys/syslimits.h \
1511                   sys/time.h \
1512                   sys/types.h \
1513                   sys/un.h \
1514                   sys/utime.h \
1515                   sys/wait.h \
1516                   syslog.h \
1517                   utime.h])
1518
1519 AC_CHECK_HEADERS(sys/param.h)
1520
1521 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1522 [#ifdef HAVE_SYS_TYPES_H
1523 #include <sys/types.h>
1524 #endif
1525 #ifdef HAVE_SYS_SOCKET_H
1526 #include <sys/socket.h>
1527 #endif])
1528 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1529 [#ifdef HAVE_SYS_TYPES_H
1530 #include <sys/types.h>
1531 #endif
1532 #ifdef HAVE_SYS_SOCKET_H
1533 #include <sys/socket.h>
1534 #endif
1535 #ifdef HAVE_NET_IF_H
1536 #include <net/if.h>
1537 #endif
1538 #ifdef HAVE_NETINET_IN_H
1539 #include <netinet/in.h>
1540 #endif])
1541
1542 AC_CHECK_HEADERS(linux/if.h,[],[],
1543 [
1544 #ifdef HAVE_SYS_SOCKET_H
1545 #include <sys/socket.h>
1546 #endif
1547 ])
1548
1549 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1550         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1551 [#ifdef HAVE_SYS_TYPES_H
1552 #include <sys/types.h>
1553 #endif
1554 #ifdef HAVE_SYS_SOCKET_H
1555 #include <sys/socket.h>
1556 #endif
1557 #ifdef HAVE_LIMITS_H
1558 #include <limits.h>
1559 #endif
1560 #ifdef HAVE_LINUX_TYPES_H
1561 #include <linux/types.h>
1562 #endif
1563 #ifdef HAVE_NETINET_IN6_H
1564 #include <netinet/in6.h>
1565 #endif
1566 #ifdef HAVE_NETINET_IN_H
1567 #include <netinet/in.h>
1568 #endif])
1569
1570 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1571         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1572 [#ifdef HAVE_SYS_TYPES_H
1573 #include <sys/types.h>
1574 #endif
1575 #ifdef HAVE_SYS_SOCKET_H
1576 #include <sys/socket.h>
1577 #endif
1578 #ifdef HAVE_LIMITS_H
1579 #include <limits.h>
1580 #endif
1581 #ifdef HAVE_LINUX_TYPES_H
1582 #include <linux/types.h>
1583 #endif
1584 #ifdef HAVE_NETINET_IN6_H
1585 #include <netinet/in6.h>
1586 #endif
1587 #ifdef HAVE_NETINET_IN_H
1588 #include <netinet/in.h>
1589 #endif
1590 #ifdef HAVE_LINUX_IF_H
1591 #include <linux/if.h>
1592 #endif])
1593
1594 transparent_ok=0
1595 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1596   transparent_ok=1
1597 fi
1598 if test "x$linux_netfilter_ipv4" = "x1"; then
1599   transparent_ok=1
1600 fi
1601 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1602   transparent_ok=1
1603 fi
1604 if test "x$transparent_ok" = "x1"; then
1605   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1606 else
1607   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1608 fi
1609
1610 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1611 [#ifdef HAVE_SYS_TYPES_H
1612 #include <sys/types.h>
1613 #endif
1614 #ifdef HAVE_SYS_TIME_H
1615 #include <sys/time.h>
1616 #endif])
1617
1618 AC_CHECK_SIZEOF(char)
1619 AC_CHECK_SIZEOF(short)
1620 AC_CHECK_SIZEOF(int)
1621 AC_CHECK_SIZEOF(long)
1622 AC_CHECK_SIZEOF(long long)
1623 AC_CHECK_SIZEOF(__int64)
1624 AC_CHECK_SIZEOF(void *)
1625 AC_CHECK_SIZEOF(time_t)
1626 AC_CHECK_SIZEOF(size_t)
1627 AC_CHECK_SIZEOF(pid_t)
1628
1629 AC_CHECK_TYPES([uint, u_char, ssize_t])
1630
1631 AC_PC_FROM_UCONTEXT([:])
1632
1633 dnl used to include sockaddr_storage, but everybody has that.
1634 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1635 [#ifdef HAVE_SYS_TYPES_H
1636 #include <sys/types.h>
1637 #endif
1638 #ifdef HAVE_NETINET_IN_H
1639 #include <netinet/in.h>
1640 #endif
1641 #ifdef HAVE_NETINET_IN6_H
1642 #include <netinet/in6.h>
1643 #endif
1644 #ifdef HAVE_SYS_SOCKET_H
1645 #include <sys/socket.h>
1646 #endif
1647 #ifdef _WIN32
1648 #define _WIN32_WINNT 0x0501
1649 #define WIN32_LEAN_AND_MEAN
1650 #include <winsock2.h>
1651 #include <ws2tcpip.h>
1652 #endif
1653 ])
1654 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1655 [#ifdef HAVE_SYS_TYPES_H
1656 #include <sys/types.h>
1657 #endif
1658 #ifdef HAVE_NETINET_IN_H
1659 #include <netinet/in.h>
1660 #endif
1661 #ifdef HAVE_NETINET_IN6_H
1662 #include <netinet/in6.h>
1663 #endif
1664 #ifdef HAVE_SYS_SOCKET_H
1665 #include <sys/socket.h>
1666 #endif
1667 #ifdef _WIN32
1668 #define _WIN32_WINNT 0x0501
1669 #define WIN32_LEAN_AND_MEAN
1670 #include <winsock2.h>
1671 #include <ws2tcpip.h>
1672 #endif
1673 ])
1674
1675 AC_CHECK_TYPES([rlim_t], , ,
1676 [#ifdef HAVE_SYS_TYPES_H
1677 #include <sys/types.h>
1678 #endif
1679 #ifdef HAVE_SYS_TIME_H
1680 #include <sys/time.h>
1681 #endif
1682 #ifdef HAVE_SYS_RESOURCE_H
1683 #include <sys/resource.h>
1684 #endif
1685 ])
1686
1687 AX_CHECK_SIGN([time_t],
1688        [ : ],
1689        [ : ], [
1690 #ifdef HAVE_SYS_TYPES_H
1691 #include <sys/types.h>
1692 #endif
1693 #ifdef HAVE_SYS_TIME_H
1694 #include <sys/time.h>
1695 #endif
1696 #ifdef HAVE_TIME_H
1697 #include <time.h>
1698 #endif
1699 ])
1700
1701 if test "$ax_cv_decl_time_t_signed" = "no"; then
1702   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1703 fi
1704
1705 AX_CHECK_SIGN([size_t],
1706        [ tor_cv_size_t_signed=yes ],
1707        [ tor_cv_size_t_signed=no ], [
1708 #ifdef HAVE_SYS_TYPES_H
1709 #include <sys/types.h>
1710 #endif
1711 ])
1712
1713 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1714   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1715 fi
1716
1717 AX_CHECK_SIGN([enum always],
1718        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1719        [ : ], [
1720  enum always { AAA, BBB, CCC };
1721 ])
1722
1723 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1724 #ifdef HAVE_SYS_SOCKET_H
1725 #include <sys/socket.h>
1726 #endif
1727 ])
1728
1729 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1730
1731 AC_CHECK_SIZEOF(cell_t)
1732
1733 # Let's see if stdatomic works. (There are some debian clangs that screw it
1734 # up; see Tor bug #26779 and debian bug 903709.)
1735 AC_CACHE_CHECK([whether C11 stdatomic.h actually works],
1736                tor_cv_stdatomic_works,
1737 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1738 #include <stdatomic.h>
1739 struct x { atomic_size_t y; };
1740 void try_atomic_init(struct x *xx)
1741 {
1742   atomic_init(&xx->y, 99);
1743   atomic_fetch_add(&xx->y, 1);
1744 }
1745 ]])], [tor_cv_stdatomic_works=yes], [tor_cv_stdatomic_works=no])])
1746
1747 if test "$tor_cv_stdatomic_works" = "yes"; then
1748    AC_DEFINE(STDATOMIC_WORKS, 1, [Set to 1 if we can compile a simple stdatomic example.])
1749 elif test "$ac_cv_header_stdatomic_h" = "yes"; then
1750    AC_MSG_WARN([Your compiler provides the stdatomic.h header, but it doesn't seem to work.  I'll pretend it isn't there. If you are using Clang on Debian, maybe this is because of https://bugs.debian.org/903709 ])
1751 fi
1752
1753 # Now make sure that NULL can be represented as zero bytes.
1754 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1755 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1756 [[#include <stdlib.h>
1757 #include <string.h>
1758 #include <stdio.h>
1759 #ifdef HAVE_STDDEF_H
1760 #include <stddef.h>
1761 #endif
1762 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1763 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1764        [tor_cv_null_is_zero=yes],
1765        [tor_cv_null_is_zero=no],
1766        [tor_cv_null_is_zero=cross])])
1767
1768 if test "$tor_cv_null_is_zero" = "cross"; then
1769   # Cross-compiling; let's hope that the target isn't raving mad.
1770   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1771 fi
1772
1773 if test "$tor_cv_null_is_zero" != "no"; then
1774   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1775             [Define to 1 iff memset(0) sets pointers to NULL])
1776 fi
1777
1778 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1779 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1780 [[#include <stdlib.h>
1781 #include <string.h>
1782 #include <stdio.h>
1783 #ifdef HAVE_STDDEF_H
1784 #include <stddef.h>
1785 #endif
1786 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1787 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1788        [tor_cv_dbl0_is_zero=yes],
1789        [tor_cv_dbl0_is_zero=no],
1790        [tor_cv_dbl0_is_zero=cross])])
1791
1792 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1793   # Cross-compiling; let's hope that the target isn't raving mad.
1794   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1795 fi
1796
1797 if test "$tor_cv_dbl0_is_zero" != "no"; then
1798   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1799             [Define to 1 iff memset(0) sets doubles to 0.0])
1800 fi
1801
1802 # And what happens when we malloc zero?
1803 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1804 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1805 [[#include <stdlib.h>
1806 #include <string.h>
1807 #include <stdio.h>
1808 #ifdef HAVE_STDDEF_H
1809 #include <stddef.h>
1810 #endif
1811 int main () { return malloc(0)?0:1; }]])],
1812        [tor_cv_malloc_zero_works=yes],
1813        [tor_cv_malloc_zero_works=no],
1814        [tor_cv_malloc_zero_works=cross])])
1815
1816 if test "$tor_cv_malloc_zero_works" = "cross"; then
1817   # Cross-compiling; let's hope that the target isn't raving mad.
1818   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1819 fi
1820
1821 if test "$tor_cv_malloc_zero_works" = "yes"; then
1822   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1823             [Define to 1 iff malloc(0) returns a pointer])
1824 fi
1825
1826 # whether we seem to be in a 2s-complement world.
1827 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1828 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1829 [[int main () { int problem = ((-99) != (~99)+1);
1830 return problem ? 1 : 0; }]])],
1831        [tor_cv_twos_complement=yes],
1832        [tor_cv_twos_complement=no],
1833        [tor_cv_twos_complement=cross])])
1834
1835 if test "$tor_cv_twos_complement" = "cross"; then
1836   # Cross-compiling; let's hope that the target isn't raving mad.
1837   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1838 fi
1839
1840 if test "$tor_cv_twos_complement" != "no"; then
1841   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1842             [Define to 1 iff we represent negative integers with
1843              two's complement])
1844 fi
1845
1846 # What does shifting a negative value do?
1847 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1848 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1849 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1850        [tor_cv_sign_extend=yes],
1851        [tor_cv_sign_extend=no],
1852        [tor_cv_sign_extend=cross])])
1853
1854 if test "$tor_cv_sign_extend" = "cross"; then
1855   # Cross-compiling; let's hope that the target isn't raving mad.
1856   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1857 fi
1858
1859 if test "$tor_cv_sign_extend" != "no"; then
1860   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1861             [Define to 1 iff right-shifting a negative value performs sign-extension])
1862 fi
1863
1864 # Is uint8_t the same type as unsigned char?
1865 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1866 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1867 #include <stdint.h>
1868 extern uint8_t c;
1869 unsigned char c;]])],
1870        [tor_cv_uint8_uchar=yes],
1871        [tor_cv_uint8_uchar=no],
1872        [tor_cv_uint8_uchar=cross])])
1873
1874 if test "$tor_cv_uint8_uchar" = "cross"; then
1875   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1876 fi
1877
1878 if test "$tor_cv_uint8_uchar" = "no"; then
1879   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1880 fi
1881
1882 AC_ARG_WITH(tcmalloc,
1883 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library. Deprecated; see --with-malloc]),
1884 [ tcmalloc=yes ], [ tcmalloc=no ])
1885
1886 default_malloc=system
1887
1888 if test "x$enable_openbsd_malloc" = "xyes" ; then
1889   AC_MSG_NOTICE([The --enable-openbsd-malloc argument is deprecated; use --with-malloc=openbsd instead.])
1890   default_malloc=openbsd
1891 fi
1892
1893 if test "x$tcmalloc" = "xyes"; then
1894   AC_MSG_NOTICE([The --with-tcmalloc argument is deprecated; use --with-malloc=tcmalloc instead.])
1895   default_malloc=tcmalloc
1896 fi
1897
1898 AC_ARG_WITH(malloc,
1899    AS_HELP_STRING([--with-malloc=[system,jemalloc,tcmalloc,openbsd]],
1900                   [select special malloc implementation [system]]),
1901    [ malloc="$with_malloc" ], [ malloc="$default_malloc" ])
1902
1903 AS_CASE([$malloc],
1904   [tcmalloc], [
1905       PKG_CHECK_MODULES([TCMALLOC],
1906                         [libtcmalloc],
1907                         have_tcmalloc=yes,
1908                         have_tcmalloc=no)
1909
1910       if test "x$have_tcmalloc" = "xno" ; then
1911           AC_MSG_ERROR([Unable to find tcmalloc requested by --with-malloc.])
1912       fi
1913
1914       CFLAGS="$CFLAGS $TCMALLOC_CFLAGS"
1915       LIBS="$TCMALLOC_LIBS $LIBS"
1916   ],
1917
1918   [jemalloc], [
1919       PKG_CHECK_MODULES([JEMALLOC],
1920                         [jemalloc],
1921                         have_jemalloc=yes,
1922                         have_jemalloc=no)
1923
1924       if test "x$have_tcmalloc" = "xno" ; then
1925           AC_MSG_ERROR([Unable to find jemalloc requested by --with-malloc.])
1926       fi
1927
1928       CFLAGS="$CFLAGS $JEMALLOC_CFLAGS"
1929       LIBS="$JEMALLOC_LIBS $LIBS"
1930       using_custom_malloc=yes
1931   ],
1932
1933   [openbsd], [
1934     AC_MSG_WARN([The openbsd malloc port is deprecated in Tor 0.3.5 and will be removed in a future version.])
1935     enable_openbsd_malloc=yes
1936   ],
1937
1938   [system], [
1939      # handle this later, including the jemalloc fallback
1940   ],
1941
1942   [AC_MSG_ERROR([--with-malloc=`$with_malloc' not supported, see --help])
1943 ])
1944
1945 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
1946
1947 if test "$malloc" != "system"; then
1948   # Tell the C compiler not to use the system allocator functions.
1949   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
1950 fi
1951 if test "$using_custom_malloc" = "yes"; then
1952   # Tell the C compiler not to use the system allocator functions.
1953   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
1954 fi
1955
1956 # By default, we're going to assume we don't have mlockall()
1957 # bionic and other platforms have various broken mlockall subsystems.
1958 # Some systems don't have a working mlockall, some aren't linkable,
1959 # and some have it but don't declare it.
1960 AC_CHECK_FUNCS(mlockall)
1961 AC_CHECK_DECLS([mlockall], , , [
1962 #ifdef HAVE_SYS_MMAN_H
1963 #include <sys/mman.h>
1964 #endif])
1965
1966 # Allow user to specify an alternate syslog facility
1967 AC_ARG_WITH(syslog-facility,
1968 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1969 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1970 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1971 AC_SUBST(LOGFACILITY)
1972
1973 # Check if we have getresuid and getresgid
1974 AC_CHECK_FUNCS(getresuid getresgid)
1975
1976 # Check for gethostbyname_r in all its glorious incompatible versions.
1977 #   (This logic is based on that in Python's configure.in)
1978 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1979   [Define this if you have any gethostbyname_r()])
1980
1981 AC_CHECK_FUNC(gethostbyname_r, [
1982   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1983   OLD_CFLAGS=$CFLAGS
1984   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1985   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1986 #include <netdb.h>
1987   ]], [[
1988     char *cp1, *cp2;
1989     struct hostent *h1, *h2;
1990     int i1, i2;
1991     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1992   ]])],[
1993     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1994     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1995      [Define this if gethostbyname_r takes 6 arguments])
1996     AC_MSG_RESULT(6)
1997   ], [
1998     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1999 #include <netdb.h>
2000     ]], [[
2001       char *cp1, *cp2;
2002       struct hostent *h1;
2003       int i1, i2;
2004       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
2005     ]])], [
2006       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
2007       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
2008         [Define this if gethostbyname_r takes 5 arguments])
2009       AC_MSG_RESULT(5)
2010    ], [
2011       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2012 #include <netdb.h>
2013      ]], [[
2014        char *cp1;
2015        struct hostent *h1;
2016        struct hostent_data hd;
2017        (void) gethostbyname_r(cp1,h1,&hd);
2018      ]])], [
2019        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
2020        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
2021          [Define this if gethostbyname_r takes 3 arguments])
2022        AC_MSG_RESULT(3)
2023      ], [
2024        AC_MSG_RESULT(0)
2025      ])
2026   ])
2027  ])
2028  CFLAGS=$OLD_CFLAGS
2029 ])
2030
2031 AC_CACHE_CHECK([whether the C compiler supports __func__],
2032   tor_cv_have_func_macro,
2033   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2034 #include <stdio.h>
2035 int main(int c, char **v) { puts(__func__); }])],
2036   tor_cv_have_func_macro=yes,
2037   tor_cv_have_func_macro=no))
2038
2039 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
2040   tor_cv_have_FUNC_macro,
2041   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2042 #include <stdio.h>
2043 int main(int c, char **v) { puts(__FUNC__); }])],
2044   tor_cv_have_FUNC_macro=yes,
2045   tor_cv_have_FUNC_macro=no))
2046
2047 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
2048   tor_cv_have_FUNCTION_macro,
2049   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2050 #include <stdio.h>
2051 int main(int c, char **v) { puts(__FUNCTION__); }])],
2052   tor_cv_have_FUNCTION_macro=yes,
2053   tor_cv_have_FUNCTION_macro=no))
2054
2055 AC_CACHE_CHECK([whether we have extern char **environ already declared],
2056   tor_cv_have_environ_declared,
2057   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2058 #ifdef HAVE_UNISTD_H
2059 #include <unistd.h>
2060 #endif
2061 #include <stdlib.h>
2062 int main(int c, char **v) { char **t = environ; }])],
2063   tor_cv_have_environ_declared=yes,
2064   tor_cv_have_environ_declared=no))
2065
2066 if test "$tor_cv_have_func_macro" = "yes"; then
2067   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
2068 fi
2069
2070 if test "$tor_cv_have_FUNC_macro" = "yes"; then
2071   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
2072 fi
2073
2074 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
2075   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
2076            [Defined if the compiler supports __FUNCTION__])
2077 fi
2078
2079 if test "$tor_cv_have_environ_declared" = "yes"; then
2080   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
2081            [Defined if we have extern char **environ already declared])
2082 fi
2083
2084 # $prefix stores the value of the --prefix command line option, or
2085 # NONE if the option wasn't set.  In the case that it wasn't set, make
2086 # it be the default, so that we can use it to expand directories now.
2087 if test "x$prefix" = "xNONE"; then
2088   prefix=$ac_default_prefix
2089 fi
2090
2091 # and similarly for $exec_prefix
2092 if test "x$exec_prefix" = "xNONE"; then
2093   exec_prefix=$prefix
2094 fi
2095
2096 if test "x$BUILDDIR" = "x"; then
2097   BUILDDIR=`pwd`
2098 fi
2099 AC_SUBST(BUILDDIR)
2100 AH_TEMPLATE([BUILDDIR],[tor's build directory])
2101 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
2102
2103 if test "x$SRCDIR" = "x"; then
2104   SRCDIR=$(cd "$srcdir"; pwd)
2105 fi
2106 AH_TEMPLATE([SRCDIR],[tor's sourcedir directory])
2107 AC_DEFINE_UNQUOTED(SRCDIR,"$SRCDIR")
2108
2109 if test "x$CONFDIR" = "x"; then
2110   CONFDIR=`eval echo $sysconfdir/tor`
2111 fi
2112 AC_SUBST(CONFDIR)
2113 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
2114 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
2115
2116 BINDIR=`eval echo $bindir`
2117 AC_SUBST(BINDIR)
2118 LOCALSTATEDIR=`eval echo $localstatedir`
2119 AC_SUBST(LOCALSTATEDIR)
2120
2121 if test "$bwin32" = "true"; then
2122   # Test if the linker supports the --nxcompat and --dynamicbase options
2123   # for Windows
2124   save_LDFLAGS="$LDFLAGS"
2125   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
2126   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
2127   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
2128     [AC_MSG_RESULT([yes])]
2129     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
2130     [AC_MSG_RESULT([no])]
2131   )
2132   LDFLAGS="$save_LDFLAGS"
2133 fi
2134
2135 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
2136 # than autoconf's macros like.
2137 if test "$GCC" = "yes"; then
2138   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
2139   # accident waiting to happen.
2140   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
2141 else
2142   # Override optimization level for non-gcc compilers
2143   CFLAGS="$CFLAGS -O"
2144   enable_gcc_warnings=no
2145   enable_gcc_warnings_advisory=no
2146 fi
2147
2148 # Warnings implies advisory-warnings and -Werror.
2149 if test "$enable_gcc_warnings" = "yes"; then
2150   enable_gcc_warnings_advisory=yes
2151   enable_fatal_warnings=yes
2152 fi
2153
2154 # OS X Lion started deprecating the system openssl. Let's just disable
2155 # all deprecation warnings on OS X. Also, to potentially make the binary
2156 # a little smaller, let's enable dead_strip.
2157 case "$host_os" in
2158
2159  darwin*)
2160     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
2161     LDFLAGS="$LDFLAGS -dead_strip" ;;
2162 esac
2163
2164 TOR_WARNING_FLAGS=""
2165
2166 # Add some more warnings which we use in development but not in the
2167 # released versions.  (Some relevant gcc versions can't handle these.)
2168 #
2169 # Note that we have to do this near the end  of the autoconf process, or
2170 # else we may run into problems when these warnings hit on the testing C
2171 # programs that autoconf wants to build.
2172 if test "x$enable_gcc_warnings_advisory" != "xno"; then
2173
2174   case "$host" in
2175     *-*-openbsd* | *-*-bitrig*)
2176       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
2177       # That's fine, except that the headers don't pass -Wredundant-decls.
2178       # Therefore, let's disable -Wsystem-headers when we're building
2179       # with maximal warnings on OpenBSD.
2180       CFLAGS="$CFLAGS -Wno-system-headers" ;;
2181   esac
2182
2183   CFLAGS_NOWARNINGS="$CFLAGS"
2184
2185   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
2186   # have it work better.
2187   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
2188
2189   # This warning was added in gcc 4.3, but it appears to generate
2190   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
2191   #CFLAGS="$CFLAGS -Wlogical-op"
2192
2193   m4_foreach_w([warning_flag], [
2194      -Waddress
2195      -Waddress-of-array-temporary
2196      -Waddress-of-temporary
2197      -Wambiguous-macro
2198      -Wanonymous-pack-parens
2199      -Warc
2200      -Warc-abi
2201      -Warc-bridge-casts-disallowed-in-nonarc
2202      -Warc-maybe-repeated-use-of-weak
2203      -Warc-performSelector-leaks
2204      -Warc-repeated-use-of-weak
2205      -Warray-bounds
2206      -Warray-bounds-pointer-arithmetic
2207      -Wasm
2208      -Wasm-operand-widths
2209      -Watomic-properties
2210      -Watomic-property-with-user-defined-accessor
2211      -Wauto-import
2212      -Wauto-storage-class
2213      -Wauto-var-id
2214      -Wavailability
2215      -Wbackslash-newline-escape
2216      -Wbad-array-new-length
2217      -Wbind-to-temporary-copy
2218      -Wbitfield-constant-conversion
2219      -Wbool-conversion
2220      -Wbool-conversions
2221      -Wbuiltin-requires-header
2222      -Wchar-align
2223      -Wcompare-distinct-pointer-types
2224      -Wcomplex-component-init
2225      -Wconditional-type-mismatch
2226      -Wconfig-macros
2227      -Wconstant-conversion
2228      -Wconstant-logical-operand
2229      -Wconstexpr-not-const
2230      -Wcustom-atomic-properties
2231      -Wdangling-field
2232      -Wdangling-initializer-list
2233      -Wdate-time
2234      -Wdelegating-ctor-cycles
2235      -Wdeprecated-implementations
2236      -Wdeprecated-register
2237      -Wdirect-ivar-access
2238      -Wdiscard-qual
2239      -Wdistributed-object-modifiers
2240      -Wdivision-by-zero
2241      -Wdollar-in-identifier-extension
2242      -Wdouble-promotion
2243      -Wduplicate-decl-specifier
2244      -Wduplicate-enum
2245      -Wduplicate-method-arg
2246      -Wduplicate-method-match
2247      -Wduplicated-cond
2248      -Wdynamic-class-memaccess
2249      -Wembedded-directive
2250      -Wempty-translation-unit
2251      -Wenum-conversion
2252      -Wexit-time-destructors
2253      -Wexplicit-ownership-type
2254      -Wextern-initializer
2255      -Wextra
2256      -Wextra-semi
2257      -Wextra-tokens
2258      -Wflexible-array-extensions
2259      -Wfloat-conversion
2260      -Wformat-non-iso
2261      -Wfour-char-constants
2262      -Wgcc-compat
2263      -Wglobal-constructors
2264      -Wgnu-array-member-paren-init
2265      -Wgnu-designator
2266      -Wgnu-static-float-init
2267      -Wheader-guard
2268      -Wheader-hygiene
2269      -Widiomatic-parentheses
2270      -Wignored-attributes
2271      -Wimplicit-atomic-properties
2272      -Wimplicit-conversion-floating-point-to-bool
2273      -Wimplicit-exception-spec-mismatch
2274      -Wimplicit-fallthrough
2275      -Wimplicit-fallthrough-per-function
2276      -Wimplicit-retain-self
2277      -Wimport-preprocessor-directive-pedantic
2278      -Wincompatible-library-redeclaration
2279      -Wincompatible-pointer-types-discards-qualifiers
2280      -Wincomplete-implementation
2281      -Wincomplete-module
2282      -Wincomplete-umbrella
2283      -Winit-self
2284      -Wint-conversions
2285      -Wint-to-void-pointer-cast
2286      -Winteger-overflow
2287      -Winvalid-constexpr
2288      -Winvalid-iboutlet
2289      -Winvalid-noreturn
2290      -Winvalid-pp-token
2291      -Winvalid-source-encoding
2292      -Winvalid-token-paste
2293      -Wknr-promoted-parameter
2294      -Wlarge-by-value-copy
2295      -Wliteral-conversion
2296      -Wliteral-range
2297      -Wlocal-type-template-args
2298      -Wlogical-op
2299      -Wloop-analysis
2300      -Wmain-return-type
2301      -Wmalformed-warning-check
2302      -Wmethod-signatures
2303      -Wmicrosoft
2304      -Wmicrosoft-exists
2305      -Wmismatched-parameter-types
2306      -Wmismatched-return-types
2307      -Wmissing-field-initializers
2308      -Wmissing-format-attribute
2309      -Wmissing-noreturn
2310      -Wmissing-selector-name
2311      -Wmissing-sysroot
2312      -Wmissing-variable-declarations
2313      -Wmodule-conflict
2314      -Wnested-anon-types
2315      -Wnewline-eof
2316      -Wnon-literal-null-conversion
2317      -Wnon-pod-varargs
2318      -Wnonportable-cfstrings
2319      -Wnormalized=nfkc
2320      -Wnull-arithmetic
2321      -Wnull-character
2322      -Wnull-conversion
2323      -Wnull-dereference
2324      -Wout-of-line-declaration
2325      -Wover-aligned
2326      -Woverlength-strings
2327      -Woverride-init
2328      -Woverriding-method-mismatch
2329      -Wpointer-type-mismatch
2330      -Wpredefined-identifier-outside-function
2331      -Wprotocol-property-synthesis-ambiguity
2332      -Wreadonly-iboutlet-property
2333      -Wreadonly-setter-attrs
2334      -Wreceiver-expr
2335      -Wreceiver-forward-class
2336      -Wreceiver-is-weak
2337      -Wreinterpret-base-class
2338      -Wrequires-super-attribute
2339      -Wreserved-user-defined-literal
2340      -Wreturn-stack-address
2341      -Wsection
2342      -Wselector-type-mismatch
2343      -Wsentinel
2344      -Wserialized-diagnostics
2345      -Wshadow
2346      -Wshift-count-negative
2347      -Wshift-count-overflow
2348      -Wshift-negative-value
2349      -Wshift-overflow=2
2350      -Wshift-sign-overflow
2351      -Wshorten-64-to-32
2352      -Wsizeof-array-argument
2353      -Wsource-uses-openmp
2354      -Wstatic-float-init
2355      -Wstatic-in-inline
2356      -Wstatic-local-in-inline
2357      -Wstrict-overflow=1
2358      -Wstring-compare
2359      -Wstring-conversion
2360      -Wstrlcpy-strlcat-size
2361      -Wstrncat-size
2362      -Wsuggest-attribute=format
2363      -Wsuggest-attribute=noreturn
2364      -Wsuper-class-method-mismatch
2365      -Wswitch-bool
2366      -Wsync-nand
2367      -Wtautological-constant-out-of-range-compare
2368      -Wtentative-definition-incomplete-type
2369      -Wtrampolines
2370      -Wtype-safety
2371      -Wtypedef-redefinition
2372      -Wtypename-missing
2373      -Wundefined-inline
2374      -Wundefined-internal
2375      -Wundefined-reinterpret-cast
2376      -Wunicode
2377      -Wunicode-whitespace
2378      -Wunknown-warning-option
2379      -Wunnamed-type-template-args
2380      -Wunneeded-member-function
2381      -Wunsequenced
2382      -Wunsupported-visibility
2383      -Wunused-but-set-parameter
2384      -Wunused-but-set-variable
2385      -Wunused-command-line-argument
2386      -Wunused-const-variable=2
2387      -Wunused-exception-parameter
2388      -Wunused-local-typedefs
2389      -Wunused-member-function
2390      -Wunused-sanitize-argument
2391      -Wunused-volatile-lvalue
2392      -Wuser-defined-literals
2393      -Wvariadic-macros
2394      -Wvector-conversion
2395      -Wvector-conversions
2396      -Wvexing-parse
2397      -Wvisibility
2398      -Wvla-extension
2399      -Wzero-length-array
2400   ], [ TOR_TRY_COMPILE_WITH_CFLAGS(warning_flag, [],
2401               [TOR_WARNING_FLAGS="$TOR_WARNING_FLAGS warning_flag" CFLAGS="$CFLAGS warning_flag"], true)
2402      ])
2403
2404 dnl    We should re-enable this in some later version.  Clang doesn't
2405 dnl    mind, but it causes trouble with GCC.
2406 dnl     -Wstrict-overflow=2
2407
2408 dnl    These seem to require annotations that we don't currently use,
2409 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2410 dnl     -Wthread-safety
2411 dnl     -Wthread-safety-analysis
2412 dnl     -Wthread-safety-attributes
2413 dnl     -Wthread-safety-beta
2414 dnl     -Wthread-safety-precise
2415
2416   W_FLAGS="$W_FLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2417   W_FLAGS="$W_FLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2418   W_FLAGS="$W_FLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2419   W_FLAGS="$W_FLAGS -Wwrite-strings"
2420   W_FLAGS="$W_FLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2421   W_FLAGS="$W_FLAGS -Waggregate-return -Wpacked -Wunused"
2422   W_FLAGS="$W_FLAGS -Wunused-parameter "
2423   # These interfere with building main() { return 0; }, which autoconf
2424   # likes to use as its default program.
2425   W_FLAGS="$W_FLAGS -Wold-style-definition -Wmissing-declarations"
2426
2427   TOR_WARNING_FLAGS="$TOR_WARNING_FLAGS $W_FLAGS"
2428   CFLAGS="$CFLAGS $W_FLAGS"
2429
2430   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2431     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2432   fi
2433   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2434     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2435   fi
2436   if test "$tor_cv_cflags__warn_unused_const_variable_2" = "yes"; then
2437     AC_DEFINE([HAVE_CFLAG_WUNUSED_CONST_VARIABLE], 1, [True if we have -Wunused-const-variable])
2438   fi
2439
2440   CFLAGS="$CFLAGS_NOWARNINGS"
2441
2442   if test "x$enable_fatal_warnings" = "xyes"; then
2443     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2444     # default autoconf programs are full of errors.
2445     CFLAGS="$CFLAGS -Werror"
2446   fi
2447
2448 fi
2449
2450 AC_SUBST(TOR_WARNING_FLAGS)
2451
2452 echo "$TOR_WARNING_FLAGS">warning_flags
2453
2454 TOR_TRY_COMPILE_WITH_CFLAGS([@warning_flags], [],
2455                             CFLAGS="$CFLAGS @warning_flags",
2456                             CFLAGS="$CFLAGS $TOR_WARNING_FLAGS")
2457
2458 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2459    case "$host_os" in
2460     darwin*)
2461       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2462    esac
2463 fi
2464
2465 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2466
2467 AC_CONFIG_FILES([
2468         Doxyfile
2469         Makefile
2470         config.rust
2471         contrib/dist/suse/tor.sh
2472         contrib/operator-tools/tor.logrotate
2473         contrib/dist/tor.sh
2474         contrib/dist/torctl
2475         contrib/dist/tor.service
2476         src/config/torrc.sample
2477         src/config/torrc.minimal
2478         src/rust/.cargo/config
2479         scripts/maint/checkOptionDocs.pl
2480         scripts/maint/updateVersions.pl
2481         warning_flags
2482 ])
2483
2484 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2485   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2486   for file in $regular_mans ; do
2487     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2488       echo "==================================";
2489       echo;
2490       echo "Building Tor has failed since manpages cannot be built.";
2491       echo;
2492       echo "You need asciidoc installed to be able to build the manpages.";
2493       echo "To build without manpages, use the --disable-asciidoc argument";
2494       echo "when calling configure.";
2495       echo;
2496       echo "==================================";
2497       exit 1;
2498     fi
2499   done
2500 fi
2501
2502 if test "$fragile_hardening" = "yes"; then
2503   AC_MSG_WARN([
2504
2505 ============
2506 Warning!  Building Tor with --enable-fragile-hardening (also known as
2507 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2508 other kinds of attacks easier. A Tor instance build with this option will be
2509 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2510 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2511 denial of service attacks. For more information, see
2512 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2513 ============
2514   ])
2515 fi
2516
2517 AC_OUTPUT