configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2015, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT([tor],[0.2.7.6-dev])
   7 AC_CONFIG_SRCDIR([src/or/main.c])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_INIT_AUTOMAKE
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AC_CONFIG_HEADERS([orconfig.h])
  12
  13 AC_CANONICAL_HOST
  14
  15 PKG_PROG_PKG_CONFIG
  16
  17 if test -f /etc/redhat-release ; then
  18   if test -f /usr/kerberos/include ; then
  19     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  20   fi
  21 fi
  22
  23 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  24 # the += operator on it in src/or/Makefile.am
  25 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  26
  27 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  28 AC_ARG_ENABLE(openbsd-malloc,
  29    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  30 AC_ARG_ENABLE(instrument-downloads,
  31    AS_HELP_STRING(--enable-instrument-downloads, [instrument downloads of directory resources etc.]))
  32 AC_ARG_ENABLE(static-openssl,
  33    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  34 AC_ARG_ENABLE(static-libevent,
  35    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  36 AC_ARG_ENABLE(static-zlib,
  37    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  38 AC_ARG_ENABLE(static-tor,
  39    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  40 AC_ARG_ENABLE(unittests,
  41    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  42 AC_ARG_ENABLE(coverage,
  43    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  44 AC_ARG_ENABLE(system-torrc,
  45    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  46
  47 AM_CONDITIONAL(UNITTESTS_ENABLED, test x$enable_unittests != xno)
  48 AM_CONDITIONAL(COVERAGE_ENABLED, test x$enable_coverage = xyes)
  49
  50 if test "$enable_static_tor" = "yes"; then
  51   enable_static_libevent="yes";
  52   enable_static_openssl="yes";
  53   enable_static_zlib="yes";
  54   CFLAGS="$CFLAGS -static"
  55 fi
  56
  57 if test "$enable_system_torrc" = "no"; then
  58   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  59             [Defined if we're not going to look for a torrc in SYSCONF])
  60 fi
  61
  62 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  63 if test x$enable_instrument_downloads = xyes; then
  64   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  65             [Defined if we want to keep track of how much of each kind of resource we download.])
  66 fi
  67
  68 AC_ARG_ENABLE(transparent,
  69      AS_HELP_STRING(--disable-transparent, [disable transparent proxy support]),
  70      [case "${enableval}" in
  71         yes) transparent=true ;;
  72         no)  transparent=false ;;
  73         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  74       esac], [transparent=true])
  75
  76 AC_ARG_ENABLE(asciidoc,
  77      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  78      [case "${enableval}" in
  79         yes) asciidoc=true ;;
  80         no)  asciidoc=false ;;
  81         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  82       esac], [asciidoc=true])
  83
  84 # systemd notify support
  85 AC_ARG_ENABLE(systemd,
  86       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  87       [case "${enableval}" in
  88         yes) systemd=true ;;
  89         no)  systemd=false ;;
  90         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
  91       esac], [systemd=auto])
  92
  93
  94
  95 # systemd support
  96 if test x$enable_systemd = xno ; then
  97     have_systemd=no;
  98 else
  99     PKG_CHECK_MODULES(SYSTEMD,
 100         [libsystemd-daemon],
 101         have_systemd=yes,
 102         have_systemd=no)
 103     if test x$have_systemd=xno; then
 104         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 105         PKG_CHECK_MODULES(SYSTEMD,
 106             [libsystemd],
 107             have_systemd=yes,
 108             have_systemd=no)
 109     fi
 110 fi
 111
 112 if test x$have_systemd = xyes; then
 113     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 114     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 115     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 116     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 117          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 118 fi
 119 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 120 AC_SUBST(TOR_SYSTEMD_LIBS)
 121
 122 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
 123     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 124 fi
 125
 126 case $host in
 127    *-*-solaris* )
 128      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 129      ;;
 130 esac
 131
 132 AC_ARG_ENABLE(gcc-warnings,
 133      AS_HELP_STRING(--enable-gcc-warnings, [enable verbose warnings]))
 134 AC_ARG_ENABLE(gcc-warnings-advisory,
 135      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
 136
 137 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 138 AC_ARG_ENABLE(gcc-hardening,
 139     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 140
 141 AC_ARG_ENABLE(expensive-hardening,
 142     AS_HELP_STRING(--enable-expensive-hardening, [enable more expensive compiler hardening; makes Tor slower]))
 143
 144 dnl Linker hardening options
 145 dnl Currently these options are ELF specific - you can't use this with MacOSX
 146 AC_ARG_ENABLE(linker-hardening,
 147     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 148
 149 AC_ARG_ENABLE(local-appdata,
 150    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 151 if test "$enable_local_appdata" = "yes"; then
 152   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 153             [Defined if we default to host local appdata paths on Windows])
 154 fi
 155
 156 # Tor2web mode flag
 157 AC_ARG_ENABLE(tor2web-mode,
 158      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 159 [if test x$enableval = xyes; then
 160     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 161 fi])
 162
 163 AC_ARG_ENABLE(bufferevents,
 164      AS_HELP_STRING(--enable-bufferevents, [use Libevent's buffered IO]))
 165
 166 AC_ARG_ENABLE(tool-name-check,
 167      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 168
 169 AC_ARG_ENABLE(seccomp,
 170      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 171
 172 AC_ARG_ENABLE(libscrypt,
 173      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 174
 175 dnl check for the correct "ar" when cross-compiling
 176 AN_MAKEVAR([AR], [AC_PROG_AR])
 177 AN_PROGRAM([ar], [AC_PROG_AR])
 178 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
 179 AC_PROG_AR
 180
 181 dnl Check whether the above macro has settled for a simply named tool even
 182 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 183 dnl because that will find any cc on the system, not only the cross-compiler,
 184 dnl and then verify that a binary built with this compiler runs on the
 185 dnl build system. It will then come to the false conclusion that we're not
 186 dnl cross-compiling.
 187 if test x$enable_tool_name_check != xno; then
 188     if test x$ac_tool_warned = xyes; then
 189         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 190         elif test "x$ac_ct_AR" != x -a x$cross_compiling = xmaybe; then
 191                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 192         fi
 193 fi
 194
 195 AC_PROG_CC
 196 AC_PROG_CPP
 197 AC_PROG_MAKE_SET
 198 AC_PROG_RANLIB
 199
 200 AC_PATH_PROG([PERL], [perl])
 201
 202 dnl autoconf 2.59 appears not to support AC_PROG_SED
 203 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 204
 205 dnl check for asciidoc and a2x
 206 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 207 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 208
 209 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 210
 211 AM_CONDITIONAL(USE_FW_HELPER, test x$natpmp = xtrue || test x$upnp = xtrue)
 212 AM_CONDITIONAL(NAT_PMP, test x$natpmp = xtrue)
 213 AM_CONDITIONAL(MINIUPNPC, test x$upnp = xtrue)
 214 AM_PROG_CC_C_O
 215 AC_PROG_CC_C99
 216
 217 AC_ARG_VAR([PYTHON], [path to Python binary])
 218 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 219 if test "x$PYTHON" = "x"; then
 220   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 221 fi
 222 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 223
 224 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 225 AC_C_FLEXIBLE_ARRAY_MEMBER
 226 ], [
 227  dnl Maybe we've got an old autoconf...
 228  AC_CACHE_CHECK([for flexible array members],
 229      tor_cv_c_flexarray,
 230      [AC_COMPILE_IFELSE(
 231        AC_LANG_PROGRAM([
 232  struct abc { int a; char b[]; };
 233 ], [
 234  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 235  def->b[0] = 33;
 236 ]),
 237   [tor_cv_c_flexarray=yes],
 238   [tor_cv_c_flexarray=no])])
 239  if test $tor_cv_flexarray = yes ; then
 240    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 241  else
 242    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 243  fi
 244 ])
 245
 246 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 247       tor_cv_c_c99_decl,
 248       [AC_COMPILE_IFELSE(
 249          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 250          [tor_cv_c_c99_decl=yes],
 251          [tor_cv_c_c99_decl=no] )])
 252 if test "$tor_cv_c_c99_decl" != "yes"; then
 253   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 254 fi
 255
 256 AC_CACHE_CHECK([for working C99 designated initializers],
 257       tor_cv_c_c99_designated_init,
 258       [AC_COMPILE_IFELSE(
 259          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 260                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 261          [tor_cv_c_c99_designated_init=yes],
 262          [tor_cv_c_c99_designated_init=no] )])
 263
 264 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 265   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 266 fi
 267
 268 TORUSER=_tor
 269 AC_ARG_WITH(tor-user,
 270         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 271         [
 272            TORUSER=$withval
 273         ]
 274 )
 275 AC_SUBST(TORUSER)
 276
 277 TORGROUP=_tor
 278 AC_ARG_WITH(tor-group,
 279         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 280         [
 281            TORGROUP=$withval
 282         ]
 283 )
 284 AC_SUBST(TORGROUP)
 285
 286
 287 dnl If _WIN32 is defined and non-zero, we are building for win32
 288 AC_MSG_CHECKING([for win32])
 289 AC_RUN_IFELSE([AC_LANG_SOURCE([
 290 int main(int c, char **v) {
 291 #ifdef _WIN32
 292 #if _WIN32
 293   return 0;
 294 #else
 295   return 1;
 296 #endif
 297 #else
 298   return 2;
 299 #endif
 300 }])],
 301 bwin32=true; AC_MSG_RESULT([yes]),
 302 bwin32=false; AC_MSG_RESULT([no]),
 303 bwin32=cross; AC_MSG_RESULT([cross])
 304 )
 305
 306 if test "$bwin32" = cross; then
 307 AC_MSG_CHECKING([for win32 (cross)])
 308 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 309 #ifdef _WIN32
 310 int main(int c, char **v) {return 0;}
 311 #else
 312 #error
 313 int main(int c, char **v) {return x(y);}
 314 #endif
 315 ])],
 316 bwin32=true; AC_MSG_RESULT([yes]),
 317 bwin32=false; AC_MSG_RESULT([no]))
 318 fi
 319
 320 AH_BOTTOM([
 321 #ifdef _WIN32
 322 /* Defined to access windows functions and definitions for >=WinXP */
 323 # ifndef WINVER
 324 #  define WINVER 0x0501
 325 # endif
 326
 327 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 328 # ifndef _WIN32_WINNT
 329 #  define _WIN32_WINNT 0x0501
 330 # endif
 331
 332 /* Defined to avoid including some windows headers as part of Windows.h */
 333 # ifndef WIN32_LEAN_AND_MEAN
 334 #  define WIN32_LEAN_AND_MEAN 1
 335 # endif
 336 #endif
 337 ])
 338
 339
 340 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 341
 342 dnl Enable C99 when compiling with MIPSpro
 343 AC_MSG_CHECKING([for MIPSpro compiler])
 344 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 345 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 346 #error
 347   return x(y);
 348 #endif
 349 ])],
 350 bmipspro=false; AC_MSG_RESULT(no),
 351 bmipspro=true; AC_MSG_RESULT(yes))
 352
 353 if test "$bmipspro" = true; then
 354   CFLAGS="$CFLAGS -c99"
 355 fi
 356
 357 AC_C_BIGENDIAN
 358
 359 AC_SEARCH_LIBS(socket, [socket network])
 360 AC_SEARCH_LIBS(gethostbyname, [nsl])
 361 AC_SEARCH_LIBS(dlopen, [dl])
 362 AC_SEARCH_LIBS(inet_aton, [resolv])
 363 AC_SEARCH_LIBS(backtrace, [execinfo])
 364 saved_LIBS="$LIBS"
 365 AC_SEARCH_LIBS([clock_gettime], [rt])
 366 if test "$LIBS" != "$saved_LIBS"; then
 367    # Looks like we need -lrt for clock_gettime().
 368    have_rt=yes
 369 fi
 370
 371 AC_SEARCH_LIBS(pthread_create, [pthread])
 372 AC_SEARCH_LIBS(pthread_detach, [pthread])
 373
 374 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 375 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 376
 377 dnl -------------------------------------------------------------------
 378 dnl Check for functions before libevent, since libevent-1.2 apparently
 379 dnl exports strlcpy without defining it in a header.
 380
 381 AC_CHECK_FUNCS(
 382         _NSGetEnviron \
 383         accept4 \
 384         backtrace \
 385         backtrace_symbols_fd \
 386         clock_gettime \
 387         eventfd \
 388         flock \
 389         ftime \
 390         getaddrinfo \
 391         getifaddrs \
 392         getpass \
 393         getrlimit \
 394         gettimeofday \
 395         gmtime_r \
 396         inet_aton \
 397         ioctl \
 398         issetugid \
 399         llround \
 400         localtime_r \
 401         lround \
 402         memmem \
 403         pipe \
 404         pipe2 \
 405         prctl \
 406         readpassphrase \
 407         rint \
 408         sigaction \
 409         socketpair \
 410         statvfs \
 411         strlcat \
 412         strlcpy \
 413         strnlen \
 414         strptime \
 415         strtok_r \
 416         strtoull \
 417         sysconf \
 418         sysctl \
 419         uname \
 420         usleep \
 421         vasprintf \
 422         _vscprintf
 423 )
 424
 425 if test "$bwin32" != true; then
 426   AC_CHECK_HEADERS(pthread.h)
 427   AC_CHECK_FUNCS(pthread_create)
 428 fi
 429
 430 if test "$bwin32" = true; then
 431   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 432 #include <windows.h>
 433 #include <conio.h>
 434 #include <wchar.h>
 435                  ])
 436 fi
 437
 438 AM_CONDITIONAL(BUILD_READPASSPHRASE_C, test x$ac_cv_func_readpassphrase = xno && test $bwin32 = false)
 439
 440 dnl ------------------------------------------------------
 441 dnl Where do you live, libevent?  And how do we call you?
 442
 443 if test "$bwin32" = true; then
 444   TOR_LIB_WS32=-lws2_32
 445   TOR_LIB_IPHLPAPI=-liphlpapi
 446   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 447   # think it's actually necessary.
 448   TOR_LIB_GDI=-lgdi32
 449 else
 450   TOR_LIB_WS32=
 451   TOR_LIB_GDI=
 452 fi
 453 AC_SUBST(TOR_LIB_WS32)
 454 AC_SUBST(TOR_LIB_GDI)
 455 AC_SUBST(TOR_LIB_IPHLPAPI)
 456
 457 tor_libevent_pkg_redhat="libevent"
 458 tor_libevent_pkg_debian="libevent-dev"
 459 tor_libevent_devpkg_redhat="libevent-devel"
 460 tor_libevent_devpkg_debian="libevent-dev"
 461
 462 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 463 dnl linking for static builds.
 464 STATIC_LIBEVENT_FLAGS=""
 465 if test "$enable_static_libevent" = "yes"; then
 466     if test "$have_rt" = yes; then
 467       STATIC_LIBEVENT_FLAGS=" -lrt "
 468     fi
 469 fi
 470
 471 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 472 #ifdef _WIN32
 473 #include <winsock2.h>
 474 #endif
 475 #include <stdlib.h>
 476 #include <sys/time.h>
 477 #include <sys/types.h>
 478 #include <event.h>], [
 479 #ifdef _WIN32
 480 #include <winsock2.h>
 481 #endif
 482 void exit(int); void *event_init(void);],
 483     [
 484 #ifdef _WIN32
 485 {WSADATA d; WSAStartup(0x101,&d); }
 486 #endif
 487 event_init(); exit(0);
 488 ], [--with-libevent-dir], [/opt/libevent])
 489
 490 dnl Now check for particular libevent functions.
 491 save_LIBS="$LIBS"
 492 save_LDFLAGS="$LDFLAGS"
 493 save_CPPFLAGS="$CPPFLAGS"
 494 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
 495 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 496 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 497 AC_CHECK_FUNCS([event_get_version_number \
 498                 evutil_secure_rng_set_urandom_device_file \
 499                 evutil_secure_rng_init \
 500                ])
 501 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 502 [#include <event.h>
 503 ])
 504
 505 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 506
 507 LIBS="$save_LIBS"
 508 LDFLAGS="$save_LDFLAGS"
 509 CPPFLAGS="$save_CPPFLAGS"
 510
 511
 512 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 513
 514 if test "$enable_static_libevent" = "yes"; then
 515    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 516      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 517    else
 518      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 519    fi
 520 else
 521      TOR_LIBEVENT_LIBS="-levent"
 522 fi
 523
 524 dnl This isn't the best test for Libevent 2.0.3-alpha.  Once it's released,
 525 dnl we can do much better.
 526 if test "$enable_bufferevents" = "yes" ; then
 527   if test "$ac_cv_header_event2_bufferevent_ssl_h" != "yes" ; then
 528     AC_MSG_ERROR([You've asked for bufferevent support, but you're using a version of Libevent without SSL support.  This won't work.  We need Libevent 2.0.8-rc or later, and you don't seem to even have Libevent 2.0.3-alpha.])
 529   else
 530
 531     CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 532
 533     # Check for the right version.  First see if version detection works.
 534     AC_MSG_CHECKING([whether we can detect the Libevent version])
 535     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 536 #include <event2/event.h>
 537 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 10
 538 #error
 539 int x = y(zz);
 540 #else
 541 int x = 1;
 542 #endif
 543   ])], [event_version_number_works=yes; AC_MSG_RESULT([yes]) ],
 544      [event_version_number_works=no;  AC_MSG_RESULT([no])])
 545     if test "$event_version_number_works" != 'yes'; then
 546       AC_MSG_WARN([Version detection on Libevent seems broken.  Your Libevent installation is probably screwed up or very old.])
 547     else
 548       AC_MSG_CHECKING([whether Libevent is new enough for bufferevents])
 549       AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 550 #include <event2/event.h>
 551 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000d00
 552 #error
 553 int x = y(zz);
 554 #else
 555 int x = 1;
 556 #endif
 557    ])], [ AC_MSG_RESULT([yes]) ],
 558       [ AC_MSG_RESULT([no])
 559         AC_MSG_ERROR([Libevent does not seem new enough to support bufferevents.  We require 2.0.13-stable or later]) ] )
 560     fi
 561   fi
 562 fi
 563
 564 LIBS="$save_LIBS"
 565 LDFLAGS="$save_LDFLAGS"
 566 CPPFLAGS="$save_CPPFLAGS"
 567
 568 AM_CONDITIONAL(USE_BUFFEREVENTS, test "$enable_bufferevents" = "yes")
 569 if test "$enable_bufferevents" = "yes"; then
 570   AC_DEFINE(USE_BUFFEREVENTS, 1, [Defined if we're going to use Libevent's buffered IO API])
 571   if test "$enable_static_libevent" = "yes"; then
 572     TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent_openssl.a $TOR_LIBEVENT_LIBS"
 573   else
 574     TOR_LIBEVENT_LIBS="-levent_openssl $TOR_LIBEVENT_LIBS"
 575   fi
 576 fi
 577 AC_SUBST(TOR_LIBEVENT_LIBS)
 578
 579 dnl ------------------------------------------------------
 580 dnl Where do you live, libm?
 581
 582 dnl On some platforms (Haiku/BeOS) the math library is
 583 dnl part of libroot. In which case don't link against lm
 584 TOR_LIB_MATH=""
 585 save_LIBS="$LIBS"
 586 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 587 if test "$ac_cv_search_pow" != "none required"; then
 588     TOR_LIB_MATH="$ac_cv_search_pow"
 589 fi
 590 LIBS="$save_LIBS"
 591 AC_SUBST(TOR_LIB_MATH)
 592
 593 dnl ------------------------------------------------------
 594 dnl Where do you live, openssl?  And how do we call you?
 595
 596 tor_openssl_pkg_redhat="openssl"
 597 tor_openssl_pkg_debian="libssl-dev"
 598 tor_openssl_devpkg_redhat="openssl-devel"
 599 tor_openssl_devpkg_debian="libssl-dev"
 600
 601 ALT_openssl_WITHVAL=""
 602 AC_ARG_WITH(ssl-dir,
 603   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 604   [
 605       if test "x$withval" != xno && test "x$withval" != "x" ; then
 606          ALT_openssl_WITHVAL="$withval"
 607       fi
 608   ])
 609
 610 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 611     [#include <openssl/rand.h>],
 612     [void RAND_add(const void *buf, int num, double entropy);],
 613     [RAND_add((void*)0,0,0); exit(0);], [],
 614     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 615
 616 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 617
 618 if test "$enable_static_openssl" = "yes"; then
 619    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 620      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 621    else
 622      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 623    fi
 624 else
 625      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 626 fi
 627 AC_SUBST(TOR_OPENSSL_LIBS)
 628
 629 dnl Now check for particular openssl functions.
 630 save_LIBS="$LIBS"
 631 save_LDFLAGS="$LDFLAGS"
 632 save_CPPFLAGS="$CPPFLAGS"
 633 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 634 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 635 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 636
 637 AC_TRY_COMPILE([
 638 #include <openssl/opensslv.h>
 639 #if OPENSSL_VERSION_NUMBER < 0x1000000fL
 640 #error "too old"
 641 #endif
 642    ], [],
 643    [ : ],
 644    [ AC_ERROR([OpenSSL is too old. We require 1.0.0 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 645
 646 AC_TRY_COMPILE([
 647 #include <openssl/opensslv.h>
 648 #include <openssl/evp.h>
 649 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 650 #error "no ECC"
 651 #endif
 652 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 653 #error "curves unavailable"
 654 #endif
 655    ], [],
 656    [ : ],
 657    [ AC_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 658
 659 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 660 [#include <openssl/ssl.h>
 661 ])
 662
 663 AC_CHECK_FUNCS([ \
 664                 SSL_SESSION_get_master_key \
 665                 SSL_get_server_random \
 666                 SSL_get_client_ciphers \
 667                 SSL_get_client_random \
 668                 SSL_CIPHER_find \
 669                 TLS_method
 670                ])
 671
 672 dnl Check if OpenSSL has scrypt implementation.
 673 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 674
 675 LIBS="$save_LIBS"
 676 LDFLAGS="$save_LDFLAGS"
 677 CPPFLAGS="$save_CPPFLAGS"
 678
 679 dnl ------------------------------------------------------
 680 dnl Where do you live, zlib?  And how do we call you?
 681
 682 tor_zlib_pkg_redhat="zlib"
 683 tor_zlib_pkg_debian="zlib1g"
 684 tor_zlib_devpkg_redhat="zlib-devel"
 685 tor_zlib_devpkg_debian="zlib1g-dev"
 686
 687 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 688     [#include <zlib.h>],
 689     [const char * zlibVersion(void);],
 690     [zlibVersion(); exit(0);], [--with-zlib-dir],
 691     [/opt/zlib])
 692
 693 if test "$enable_static_zlib" = "yes"; then
 694    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 695      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 696  using --enable-static-zlib")
 697    else
 698      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 699    fi
 700 else
 701      TOR_ZLIB_LIBS="-lz"
 702 fi
 703 AC_SUBST(TOR_ZLIB_LIBS)
 704
 705 dnl ---------------------------------------------------------------------
 706 dnl Now that we know about our major libraries, we can check for compiler
 707 dnl and linker hardening options.  We need to do this with the libraries known,
 708 dnl since sometimes the linker will like an option but not be willing to
 709 dnl use it with a build of a library.
 710
 711 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 712 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI"
 713
 714 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 715 #if !defined(__clang__)
 716 #error
 717 #endif])], have_clang=yes, have_clang=no)
 718
 719 if test x$enable_gcc_hardening != xno; then
 720     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2"
 721     if test x$have_clang = xyes; then
 722         TOR_CHECK_CFLAGS(-Qunused-arguments)
 723     fi
 724     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 725     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 726     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 727 m4_ifdef([AS_VAR_IF],[
 728     AS_VAR_IF(can_compile, [yes],
 729         AS_VAR_IF(can_link, [yes],
 730                   [],
 731                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 732         )])
 733     AS_VAR_POPDEF([can_link])
 734     AS_VAR_POPDEF([can_compile])
 735     TOR_CHECK_CFLAGS(-Wstack-protector)
 736     TOR_CHECK_CFLAGS(-fwrapv)
 737     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 738     if test "$bwin32" = "false"; then
 739        TOR_CHECK_CFLAGS(-fPIE)
 740        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 741     fi
 742 fi
 743
 744 if test x$enable_expensive_hardening = xyes ; then
 745    TOR_CHECK_CFLAGS([-fsanitize=address])
 746    TOR_CHECK_CFLAGS([-fsanitize=undefined])
 747    TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 748 fi
 749
 750 if test x$enable_linker_hardening != xno; then
 751     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
 752 fi
 753
 754 # For backtrace support
 755 TOR_CHECK_LDFLAGS(-rdynamic)
 756
 757 dnl ------------------------------------------------------
 758 dnl Now see if we have a -fomit-frame-pointer compiler option.
 759
 760 saved_CFLAGS="$CFLAGS"
 761 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
 762 F_OMIT_FRAME_POINTER=''
 763 if test "$saved_CFLAGS" != "$CFLAGS"; then
 764   if test x$enable_expensive_hardening != xyes ; then
 765     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
 766   fi
 767 fi
 768 CFLAGS="$saved_CFLAGS"
 769 AC_SUBST(F_OMIT_FRAME_POINTER)
 770
 771 dnl ------------------------------------------------------
 772 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
 773 dnl for us, as GCC 4.6 and later do at many optimization levels), then
 774 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
 775 dnl code will work.
 776 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
 777
 778 dnl ============================================================
 779 dnl Check for libseccomp
 780
 781 if test "x$enable_seccomp" != "xno"; then
 782   AC_CHECK_HEADERS([seccomp.h])
 783   AC_SEARCH_LIBS(seccomp_init, [seccomp])
 784 fi
 785
 786 dnl ============================================================
 787 dnl Check for libscrypt
 788
 789 if test "x$enable_libscrypt" != "xno"; then
 790   AC_CHECK_HEADERS([libscrypt.h])
 791   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
 792 fi
 793
 794 dnl ============================================================
 795 dnl We need an implementation of curve25519.
 796
 797 dnl set these defaults.
 798 build_curve25519_donna=no
 799 build_curve25519_donna_c64=no
 800 use_curve25519_donna=no
 801 use_curve25519_nacl=no
 802 CURVE25519_LIBS=
 803
 804 dnl The best choice is using curve25519-donna-c64, but that requires
 805 dnl that we
 806 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
 807   tor_cv_can_use_curve25519_donna_c64,
 808   [AC_RUN_IFELSE(
 809     [AC_LANG_PROGRAM([dnl
 810       #include <stdint.h>
 811       typedef unsigned uint128_t __attribute__((mode(TI)));
 812   int func(uint64_t a, uint64_t b) {
 813            uint128_t c = ((uint128_t)a) * b;
 814            int ok = ((uint64_t)(c>>96)) == 522859 &&
 815              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 816                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 817                  (((uint64_t)(c))&0xffffffffL) == 0;
 818            return ok;
 819       }
 820   ], [dnl
 821     int ok = func( ((uint64_t)2000000000) * 1000000000,
 822                    ((uint64_t)1234567890) << 24);
 823         return !ok;
 824       ])],
 825   [tor_cv_can_use_curve25519_donna_c64=yes],
 826       [tor_cv_can_use_curve25519_donna_c64=no],
 827   [AC_LINK_IFELSE(
 828         [AC_LANG_PROGRAM([dnl
 829       #include <stdint.h>
 830       typedef unsigned uint128_t __attribute__((mode(TI)));
 831   int func(uint64_t a, uint64_t b) {
 832            uint128_t c = ((uint128_t)a) * b;
 833            int ok = ((uint64_t)(c>>96)) == 522859 &&
 834              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 835                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 836                  (((uint64_t)(c))&0xffffffffL) == 0;
 837            return ok;
 838       }
 839   ], [dnl
 840     int ok = func( ((uint64_t)2000000000) * 1000000000,
 841                  ((uint64_t)1234567890) << 24);
 842         return !ok;
 843       ])],
 844           [tor_cv_can_use_curve25519_donna_c64=cross],
 845       [tor_cv_can_use_curve25519_donna_c64=no])])])
 846
 847 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
 848                   nacl/crypto_scalarmult_curve25519.h])
 849
 850 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
 851   tor_cv_can_use_curve25519_nacl,
 852   [tor_saved_LIBS="$LIBS"
 853    LIBS="$LIBS -lnacl"
 854    AC_LINK_IFELSE(
 855      [AC_LANG_PROGRAM([dnl
 856        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
 857        #include <crypto_scalarmult_curve25519.h>
 858    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
 859    #include <nacl/crypto_scalarmult_curve25519.h>
 860    #endif
 861        #ifdef crypto_scalarmult_curve25519_ref_BYTES
 862    #error Hey, this is the reference implementation! That's not fast.
 863    #endif
 864      ], [
 865    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
 866      ])], [tor_cv_can_use_curve25519_nacl=yes],
 867      [tor_cv_can_use_curve25519_nacl=no])
 868    LIBS="$tor_saved_LIBS" ])
 869
 870  dnl Okay, now we need to figure out which one to actually use. Fall back
 871  dnl to curve25519-donna.c
 872
 873  if test x$tor_cv_can_use_curve25519_donna_c64 != xno; then
 874    build_curve25519_donna_c64=yes
 875    use_curve25519_donna=yes
 876  elif test x$tor_cv_can_use_curve25519_nacl = xyes; then
 877    use_curve25519_nacl=yes
 878    CURVE25519_LIBS=-lnacl
 879  else
 880    build_curve25519_donna=yes
 881    use_curve25519_donna=yes
 882  fi
 883
 884 if test x$use_curve25519_donna = xyes; then
 885   AC_DEFINE(USE_CURVE25519_DONNA, 1,
 886             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
 887 fi
 888 if test x$use_curve25519_nacl = xyes; then
 889   AC_DEFINE(USE_CURVE25519_NACL, 1,
 890             [Defined if we should use a curve25519 from nacl])
 891 fi
 892 AM_CONDITIONAL(BUILD_CURVE25519_DONNA, test x$build_curve25519_donna = xyes)
 893 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64, test x$build_curve25519_donna_c64 = xyes)
 894 AC_SUBST(CURVE25519_LIBS)
 895
 896 dnl Make sure to enable support for large off_t if available.
 897 AC_SYS_LARGEFILE
 898
 899 AC_CHECK_HEADERS(
 900         assert.h \
 901         errno.h \
 902         fcntl.h \
 903         signal.h \
 904         string.h \
 905         sys/fcntl.h \
 906         sys/stat.h \
 907         sys/time.h \
 908         sys/types.h \
 909         time.h \
 910         unistd.h
 911  , , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 912
 913 dnl These headers are not essential
 914
 915 AC_CHECK_HEADERS(
 916         arpa/inet.h \
 917         crt_externs.h \
 918         execinfo.h \
 919         grp.h \
 920         ifaddrs.h \
 921         inttypes.h \
 922         limits.h \
 923         linux/types.h \
 924         machine/limits.h \
 925         malloc.h \
 926         malloc/malloc.h \
 927         malloc_np.h \
 928         netdb.h \
 929         netinet/in.h \
 930         netinet/in6.h \
 931         pwd.h \
 932         readpassphrase.h \
 933         stdint.h \
 934         sys/eventfd.h \
 935         sys/file.h \
 936         sys/ioctl.h \
 937         sys/limits.h \
 938         sys/mman.h \
 939         sys/param.h \
 940         sys/prctl.h \
 941         sys/resource.h \
 942         sys/select.h \
 943         sys/socket.h \
 944         sys/statvfs.h \
 945         sys/sysctl.h \
 946         sys/syslimits.h \
 947         sys/time.h \
 948         sys/types.h \
 949         sys/un.h \
 950         sys/utime.h \
 951         sys/wait.h \
 952         syslog.h \
 953         utime.h
 954 )
 955
 956 AC_CHECK_HEADERS(sys/param.h)
 957
 958 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 959 [#ifdef HAVE_SYS_TYPES_H
 960 #include <sys/types.h>
 961 #endif
 962 #ifdef HAVE_SYS_SOCKET_H
 963 #include <sys/socket.h>
 964 #endif])
 965 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 966 [#ifdef HAVE_SYS_TYPES_H
 967 #include <sys/types.h>
 968 #endif
 969 #ifdef HAVE_SYS_SOCKET_H
 970 #include <sys/socket.h>
 971 #endif
 972 #ifdef HAVE_NET_IF_H
 973 #include <net/if.h>
 974 #endif
 975 #ifdef HAVE_NETINET_IN_H
 976 #include <netinet/in.h>
 977 #endif])
 978
 979 AC_CHECK_HEADERS(linux/if.h,[],[],
 980 [
 981 #ifdef HAVE_SYS_SOCKET_H
 982 #include <sys/socket.h>
 983 #endif
 984 ])
 985
 986 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 987         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 988 [#ifdef HAVE_SYS_TYPES_H
 989 #include <sys/types.h>
 990 #endif
 991 #ifdef HAVE_SYS_SOCKET_H
 992 #include <sys/socket.h>
 993 #endif
 994 #ifdef HAVE_LIMITS_H
 995 #include <limits.h>
 996 #endif
 997 #ifdef HAVE_LINUX_TYPES_H
 998 #include <linux/types.h>
 999 #endif
1000 #ifdef HAVE_NETINET_IN6_H
1001 #include <netinet/in6.h>
1002 #endif
1003 #ifdef HAVE_NETINET_IN_H
1004 #include <netinet/in.h>
1005 #endif])
1006
1007 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1008         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1009 [#ifdef HAVE_SYS_TYPES_H
1010 #include <sys/types.h>
1011 #endif
1012 #ifdef HAVE_SYS_SOCKET_H
1013 #include <sys/socket.h>
1014 #endif
1015 #ifdef HAVE_LIMITS_H
1016 #include <limits.h>
1017 #endif
1018 #ifdef HAVE_LINUX_TYPES_H
1019 #include <linux/types.h>
1020 #endif
1021 #ifdef HAVE_NETINET_IN6_H
1022 #include <netinet/in6.h>
1023 #endif
1024 #ifdef HAVE_NETINET_IN_H
1025 #include <netinet/in.h>
1026 #endif
1027 #ifdef HAVE_LINUX_IF_H
1028 #include <linux/if.h>
1029 #endif])
1030
1031 if test x$transparent = xtrue ; then
1032    transparent_ok=0
1033    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
1034      transparent_ok=1
1035    fi
1036    if test x$linux_netfilter_ipv4 = x1 ; then
1037      transparent_ok=1
1038    fi
1039    if test x$linux_netfilter_ipv6_ip6_tables = x1 ; then
1040      transparent_ok=1
1041    fi
1042    if test x$transparent_ok = x1 ; then
1043      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1044      case $host in
1045        *-*-openbsd* | *-*-bitrig*)
1046          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
1047      esac
1048    else
1049      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1050    fi
1051 fi
1052
1053 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1054 [#ifdef HAVE_SYS_TYPES_H
1055 #include <sys/types.h>
1056 #endif
1057 #ifdef HAVE_SYS_TIME_H
1058 #include <sys/time.h>
1059 #endif])
1060
1061 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1062 dnl Watch out.
1063
1064 AC_CHECK_SIZEOF(int8_t)
1065 AC_CHECK_SIZEOF(int16_t)
1066 AC_CHECK_SIZEOF(int32_t)
1067 AC_CHECK_SIZEOF(int64_t)
1068 AC_CHECK_SIZEOF(uint8_t)
1069 AC_CHECK_SIZEOF(uint16_t)
1070 AC_CHECK_SIZEOF(uint32_t)
1071 AC_CHECK_SIZEOF(uint64_t)
1072 AC_CHECK_SIZEOF(intptr_t)
1073 AC_CHECK_SIZEOF(uintptr_t)
1074
1075 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1076
1077 AC_CHECK_SIZEOF(char)
1078 AC_CHECK_SIZEOF(short)
1079 AC_CHECK_SIZEOF(int)
1080 AC_CHECK_SIZEOF(long)
1081 AC_CHECK_SIZEOF(long long)
1082 AC_CHECK_SIZEOF(__int64)
1083 AC_CHECK_SIZEOF(void *)
1084 AC_CHECK_SIZEOF(time_t)
1085 AC_CHECK_SIZEOF(size_t)
1086 AC_CHECK_SIZEOF(pid_t)
1087
1088 AC_CHECK_TYPES([uint, u_char, ssize_t])
1089
1090 AC_PC_FROM_UCONTEXT([:])
1091
1092 dnl used to include sockaddr_storage, but everybody has that.
1093 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1094 [#ifdef HAVE_SYS_TYPES_H
1095 #include <sys/types.h>
1096 #endif
1097 #ifdef HAVE_NETINET_IN_H
1098 #include <netinet/in.h>
1099 #endif
1100 #ifdef HAVE_NETINET_IN6_H
1101 #include <netinet/in6.h>
1102 #endif
1103 #ifdef HAVE_SYS_SOCKET_H
1104 #include <sys/socket.h>
1105 #endif
1106 #ifdef _WIN32
1107 #define _WIN32_WINNT 0x0501
1108 #define WIN32_LEAN_AND_MEAN
1109 #include <winsock2.h>
1110 #include <ws2tcpip.h>
1111 #endif
1112 ])
1113 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1114 [#ifdef HAVE_SYS_TYPES_H
1115 #include <sys/types.h>
1116 #endif
1117 #ifdef HAVE_NETINET_IN_H
1118 #include <netinet/in.h>
1119 #endif
1120 #ifdef HAVE_NETINET_IN6_H
1121 #include <netinet/in6.h>
1122 #endif
1123 #ifdef HAVE_SYS_SOCKET_H
1124 #include <sys/socket.h>
1125 #endif
1126 #ifdef _WIN32
1127 #define _WIN32_WINNT 0x0501
1128 #define WIN32_LEAN_AND_MEAN
1129 #include <winsock2.h>
1130 #include <ws2tcpip.h>
1131 #endif
1132 #endif
1133 ])
1134
1135 AC_CHECK_TYPES([rlim_t], , ,
1136 [#ifdef HAVE_SYS_TYPES_H
1137 #include <sys/types.h>
1138 #endif
1139 #ifdef HAVE_SYS_TIME_H
1140 #include <sys/time.h>
1141 #endif
1142 #ifdef HAVE_SYS_RESOURCE_H
1143 #include <sys/resource.h>
1144 #endif
1145 ])
1146
1147 AX_CHECK_SIGN([time_t],
1148        [ AC_DEFINE(TIME_T_IS_SIGNED, 1, [Define if time_t is signed]) ],
1149        [ : ], [
1150 #ifdef HAVE_SYS_TYPES_H
1151 #include <sys/types.h>
1152 #endif
1153 #ifdef HAVE_SYS_TIME_H
1154 #include <sys/time.h>
1155 #endif
1156 #ifdef HAVE_TIME_H
1157 #include <time.h>
1158 #endif
1159 ])
1160
1161 if test "$ax_cv_decl_time_t_signed" = no; then
1162   AC_MSG_WARN([You have an unsigned time_t; some things will probably break. Please tell the Tor developers about your interesting platform.])
1163 fi
1164
1165 AX_CHECK_SIGN([size_t],
1166        [ tor_cv_size_t_signed=yes ],
1167        [ tor_cv_size_t_signed=no ], [
1168 #ifdef HAVE_SYS_TYPES_H
1169 #include <sys/types.h>
1170 #endif
1171 ])
1172
1173 if test "$ax_cv_decl_size_t_signed" = yes; then
1174   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1175 fi
1176
1177 AX_CHECK_SIGN([enum always],
1178        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1179        [ : ], [
1180  enum always { AAA, BBB, CCC };
1181 ])
1182
1183 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1184 #ifdef HAVE_SYS_SOCKET_H
1185 #include <sys/socket.h>
1186 #endif
1187 ])
1188
1189 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1190
1191 AC_CHECK_SIZEOF(cell_t)
1192
1193 # Now make sure that NULL can be represented as zero bytes.
1194 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1195 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1196 [[#include <stdlib.h>
1197 #include <string.h>
1198 #include <stdio.h>
1199 #ifdef HAVE_STDDEF_H
1200 #include <stddef.h>
1201 #endif
1202 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1203 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1204        [tor_cv_null_is_zero=yes],
1205        [tor_cv_null_is_zero=no],
1206        [tor_cv_null_is_zero=cross])])
1207
1208 if test "$tor_cv_null_is_zero" = cross ; then
1209   # Cross-compiling; let's hope that the target isn't raving mad.
1210   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1211 fi
1212
1213 if test "$tor_cv_null_is_zero" != no; then
1214   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1215             [Define to 1 iff memset(0) sets pointers to NULL])
1216 fi
1217
1218 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1219 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1220 [[#include <stdlib.h>
1221 #include <string.h>
1222 #include <stdio.h>
1223 #ifdef HAVE_STDDEF_H
1224 #include <stddef.h>
1225 #endif
1226 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1227 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1228        [tor_cv_dbl0_is_zero=yes],
1229        [tor_cv_dbl0_is_zero=no],
1230        [tor_cv_dbl0_is_zero=cross])])
1231
1232 if test "$tor_cv_dbl0_is_zero" = cross ; then
1233   # Cross-compiling; let's hope that the target isn't raving mad.
1234   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1235 fi
1236
1237 if test "$tor_cv_dbl0_is_zero" != no; then
1238   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1239             [Define to 1 iff memset(0) sets doubles to 0.0])
1240 fi
1241
1242 # And what happens when we malloc zero?
1243 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1244 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1245 [[#include <stdlib.h>
1246 #include <string.h>
1247 #include <stdio.h>
1248 #ifdef HAVE_STDDEF_H
1249 #include <stddef.h>
1250 #endif
1251 int main () { return malloc(0)?0:1; }]])],
1252        [tor_cv_malloc_zero_works=yes],
1253        [tor_cv_malloc_zero_works=no],
1254        [tor_cv_malloc_zero_works=cross])])
1255
1256 if test "$tor_cv_malloc_zero_works" = cross; then
1257   # Cross-compiling; let's hope that the target isn't raving mad.
1258   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1259 fi
1260
1261 if test "$tor_cv_malloc_zero_works" = yes; then
1262   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1263             [Define to 1 iff malloc(0) returns a pointer])
1264 fi
1265
1266 # whether we seem to be in a 2s-complement world.
1267 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1268 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1269 [[int main () { int problem = ((-99) != (~99)+1);
1270 return problem ? 1 : 0; }]])],
1271        [tor_cv_twos_complement=yes],
1272        [tor_cv_twos_complement=no],
1273        [tor_cv_twos_complement=cross])])
1274
1275 if test "$tor_cv_twos_complement" = cross ; then
1276   # Cross-compiling; let's hope that the target isn't raving mad.
1277   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1278 fi
1279
1280 if test "$tor_cv_twos_complement" != no ; then
1281   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1282             [Define to 1 iff we represent negative integers with two's complement])
1283 fi
1284
1285 # What does shifting a negative value do?
1286 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1287 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1288 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1289        [tor_cv_sign_extend=yes],
1290        [tor_cv_sign_extend=no],
1291        [tor_cv_sign_extend=cross])])
1292
1293 if test "$tor_cv_sign_extend" = cross ; then
1294   # Cross-compiling; let's hope that the target isn't raving mad.
1295   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1296 fi
1297
1298 if test "$tor_cv_sign_extend" != no ; then
1299   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1300             [Define to 1 iff right-shifting a negative value performs sign-extension])
1301 fi
1302
1303 # Whether we should use the dmalloc memory allocation debugging library.
1304 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1305 AC_ARG_WITH(dmalloc,
1306 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1307 [if [[ "$withval" = "yes" ]]; then
1308   dmalloc=1
1309   AC_MSG_RESULT(yes)
1310 else
1311   dmalloc=1
1312   AC_MSG_RESULT(no)
1313 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1314 )
1315
1316 if [[ $dmalloc -eq 1 ]]; then
1317   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1318   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1319   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1320   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1321 fi
1322
1323 AC_ARG_WITH(tcmalloc,
1324 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1325 [ tcmalloc=yes ], [ tcmalloc=no ])
1326
1327 if test x$tcmalloc = xyes ; then
1328    LDFLAGS="-ltcmalloc $LDFLAGS"
1329 fi
1330
1331 using_custom_malloc=no
1332 if test x$enable_openbsd_malloc = xyes ; then
1333    using_custom_malloc=yes
1334 fi
1335 if test x$tcmalloc = xyes ; then
1336    using_custom_malloc=yes
1337 fi
1338 if test $using_custom_malloc = no ; then
1339    AC_CHECK_FUNCS(mallinfo)
1340 fi
1341
1342 # By default, we're going to assume we don't have mlockall()
1343 # bionic and other platforms have various broken mlockall subsystems.
1344 # Some systems don't have a working mlockall, some aren't linkable,
1345 # and some have it but don't declare it.
1346 AC_CHECK_FUNCS(mlockall)
1347 AC_CHECK_DECLS([mlockall], , , [
1348 #ifdef HAVE_SYS_MMAN_H
1349 #include <sys/mman.h>
1350 #endif])
1351
1352 # Allow user to specify an alternate syslog facility
1353 AC_ARG_WITH(syslog-facility,
1354 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1355 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1356 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1357 AC_SUBST(LOGFACILITY)
1358
1359 # Check if we have getresuid and getresgid
1360 AC_CHECK_FUNCS(getresuid getresgid)
1361
1362 # Check for gethostbyname_r in all its glorious incompatible versions.
1363 #   (This logic is based on that in Python's configure.in)
1364 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1365   [Define this if you have any gethostbyname_r()])
1366
1367 AC_CHECK_FUNC(gethostbyname_r, [
1368   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1369   OLD_CFLAGS=$CFLAGS
1370   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1371   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1372 #include <netdb.h>
1373   ], [[
1374     char *cp1, *cp2;
1375     struct hostent *h1, *h2;
1376     int i1, i2;
1377     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1378   ]])],[
1379     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1380     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1381      [Define this if gethostbyname_r takes 6 arguments])
1382     AC_MSG_RESULT(6)
1383   ], [
1384     AC_TRY_COMPILE([
1385 #include <netdb.h>
1386     ], [
1387       char *cp1, *cp2;
1388       struct hostent *h1;
1389       int i1, i2;
1390       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1391     ], [
1392       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1393       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1394         [Define this if gethostbyname_r takes 5 arguments])
1395       AC_MSG_RESULT(5)
1396    ], [
1397       AC_TRY_COMPILE([
1398 #include <netdb.h>
1399      ], [
1400        char *cp1;
1401        struct hostent *h1;
1402        struct hostent_data hd;
1403        (void) gethostbyname_r(cp1,h1,&hd);
1404      ], [
1405        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1406        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1407          [Define this if gethostbyname_r takes 3 arguments])
1408        AC_MSG_RESULT(3)
1409      ], [
1410        AC_MSG_RESULT(0)
1411      ])
1412   ])
1413  ])
1414  CFLAGS=$OLD_CFLAGS
1415 ])
1416
1417 AC_CACHE_CHECK([whether the C compiler supports __func__],
1418   tor_cv_have_func_macro,
1419   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1420 #include <stdio.h>
1421 int main(int c, char **v) { puts(__func__); }])],
1422   tor_cv_have_func_macro=yes,
1423   tor_cv_have_func_macro=no))
1424
1425 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1426   tor_cv_have_FUNC_macro,
1427   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1428 #include <stdio.h>
1429 int main(int c, char **v) { puts(__FUNC__); }])],
1430   tor_cv_have_FUNC_macro=yes,
1431   tor_cv_have_FUNC_macro=no))
1432
1433 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1434   tor_cv_have_FUNCTION_macro,
1435   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1436 #include <stdio.h>
1437 int main(int c, char **v) { puts(__FUNCTION__); }])],
1438   tor_cv_have_FUNCTION_macro=yes,
1439   tor_cv_have_FUNCTION_macro=no))
1440
1441 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1442   tor_cv_have_environ_declared,
1443   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1444 /* We define _GNU_SOURCE here because it is also defined in compat.c.
1445  * Without it environ doesn't get declared. */
1446 #define _GNU_SOURCE
1447 #ifdef HAVE_UNISTD_H
1448 #include <unistd.h>
1449 #endif
1450 #include <stdlib.h>
1451 int main(int c, char **v) { char **t = environ; }])],
1452   tor_cv_have_environ_declared=yes,
1453   tor_cv_have_environ_declared=no))
1454
1455 if test "$tor_cv_have_func_macro" = 'yes'; then
1456   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1457 fi
1458
1459 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
1460   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1461 fi
1462
1463 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
1464   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1465            [Defined if the compiler supports __FUNCTION__])
1466 fi
1467
1468 if test "$tor_cv_have_environ_declared" = 'yes'; then
1469   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1470            [Defined if we have extern char **environ already declared])
1471 fi
1472
1473 # $prefix stores the value of the --prefix command line option, or
1474 # NONE if the option wasn't set.  In the case that it wasn't set, make
1475 # it be the default, so that we can use it to expand directories now.
1476 if test "x$prefix" = "xNONE"; then
1477   prefix=$ac_default_prefix
1478 fi
1479
1480 # and similarly for $exec_prefix
1481 if test "x$exec_prefix" = "xNONE"; then
1482   exec_prefix=$prefix
1483 fi
1484
1485 if test "x$BUILDDIR" = "x"; then
1486   BUILDDIR=`pwd`
1487 fi
1488 AC_SUBST(BUILDDIR)
1489 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1490 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1491
1492 if test "x$CONFDIR" = "x"; then
1493   CONFDIR=`eval echo $sysconfdir/tor`
1494 fi
1495 AC_SUBST(CONFDIR)
1496 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1497 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1498
1499 BINDIR=`eval echo $bindir`
1500 AC_SUBST(BINDIR)
1501 LOCALSTATEDIR=`eval echo $localstatedir`
1502 AC_SUBST(LOCALSTATEDIR)
1503
1504 if test "$bwin32" = true; then
1505   # Test if the linker supports the --nxcompat and --dynamicbase options
1506   # for Windows
1507   save_LDFLAGS="$LDFLAGS"
1508   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1509   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1510   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1511     [AC_MSG_RESULT([yes])]
1512     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1513     [AC_MSG_RESULT([no])]
1514   )
1515   LDFLAGS="$save_LDFLAGS"
1516 fi
1517
1518 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1519 # than autoconf's macros like.
1520 if test "$GCC" = yes; then
1521   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1522   # accident waiting to happen.
1523   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1524 else
1525   # Override optimization level for non-gcc compilers
1526   CFLAGS="$CFLAGS -O"
1527   enable_gcc_warnings=no
1528   enable_gcc_warnings_advisory=no
1529 fi
1530
1531 # OS X Lion started deprecating the system openssl. Let's just disable
1532 # all deprecation warnings on OS X. Also, to potentially make the binary
1533 # a little smaller, let's enable dead_strip.
1534 case "$host_os" in
1535
1536  darwin*)
1537     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1538     LDFLAGS="$LDFLAGS -dead_strip" ;;
1539 esac
1540
1541 # Add some more warnings which we use in development but not in the
1542 # released versions.  (Some relevant gcc versions can't handle these.)
1543 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
1544
1545   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1546 #if !defined(__GNUC__) || (__GNUC__ < 4)
1547 #error
1548 #endif])], have_gcc4=yes, have_gcc4=no)
1549
1550   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1551 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
1552 #error
1553 #endif])], have_gcc42=yes, have_gcc42=no)
1554
1555   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1556 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
1557 #error
1558 #endif])], have_gcc43=yes, have_gcc43=no)
1559
1560   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1561 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 6)
1562 #error
1563 #endif])], have_gcc46=yes, have_gcc46=no)
1564
1565
1566   save_CFLAGS="$CFLAGS"
1567   CFLAGS="$CFLAGS -Wshorten-64-to-32"
1568   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
1569                     have_shorten64_flag=no)
1570   CFLAGS="$save_CFLAGS"
1571
1572   case $host in
1573     *-*-openbsd* | *-*-bitrig*)
1574       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1575       # That's fine, except that the headers don't pass -Wredundant-decls.
1576       # Therefore, let's disable -Wsystem-headers when we're building
1577       # with maximal warnings on OpenBSD.
1578       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1579   esac
1580
1581   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1582   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1583   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1584   CFLAGS="$CFLAGS -Wwrite-strings -Wmissing-declarations -Wredundant-decls"
1585   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1586
1587   if test x$enable_gcc_warnings = xyes; then
1588     CFLAGS="$CFLAGS -Werror"
1589   fi
1590
1591   # Disabled, so we can use mallinfo(): -Waggregate-return
1592
1593   if test x$have_gcc4 = xyes ; then
1594     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
1595     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wold-style-definition"
1596   fi
1597
1598   if test x$have_gcc42 = xyes ; then
1599     # These warnings break gcc 4.0.2 and work on gcc 4.2
1600     # XXXX020 See if any of these work with earlier versions.
1601     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wstrict-overflow=1"
1602
1603     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
1604   fi
1605
1606   if test x$have_gcc42 = xyes && test x$have_clang = xno; then
1607     # These warnings break gcc 4.0.2 and clang, but work on gcc 4.2
1608     CFLAGS="$CFLAGS -Wnormalized=id -Woverride-init"
1609   fi
1610
1611   if test x$have_gcc43 = xyes ; then
1612     # These warnings break gcc 4.2 and work on gcc 4.3
1613     # XXXX020 See if any of these work with earlier versions.
1614     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
1615   fi
1616
1617   if test x$have_gcc46 = xyes ; then
1618     # This warning was added in gcc 4.3, but it appears to generate
1619     # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1620     CFLAGS="$CFLAGS -Wlogical-op"
1621   fi
1622
1623   if test x$have_shorten64_flag = xyes ; then
1624     CFLAGS="$CFLAGS -Wshorten-64-to-32"
1625   fi
1626
1627
1628
1629 ##This will break the world on some 64-bit architectures
1630 # CFLAGS="$CFLAGS -Winline"
1631 fi
1632
1633 if test "$enable_coverage" = yes && test "$have_clang" = "no"; then
1634    case "$host_os" in
1635     darwin*)
1636       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-profiling.])
1637    esac
1638 fi
1639
1640 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1641
1642 AC_CONFIG_FILES([
1643         Doxyfile
1644         Makefile
1645         contrib/dist/suse/tor.sh
1646         contrib/operator-tools/tor.logrotate
1647         contrib/dist/tor.sh
1648         contrib/dist/torctl
1649         contrib/dist/tor.service
1650         src/config/torrc.sample
1651         src/config/torrc.minimal
1652         scripts/maint/checkOptionDocs.pl
1653         scripts/maint/updateVersions.pl
1654 ])
1655
1656 if test x$asciidoc = xtrue && test "$ASCIIDOC" = "none" ; then
1657   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
1658   for file in $regular_mans ; do
1659     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
1660       echo "==================================";
1661       echo;
1662       echo "Building Tor has failed since manpages cannot be built.";
1663       echo;
1664       echo "You need asciidoc installed to be able to build the manpages.";
1665       echo "To build without manpages, use the --disable-asciidoc argument";
1666       echo "when calling configure.";
1667       echo;
1668       echo "==================================";
1669       exit 1;
1670     fi
1671   done
1672 fi
1673
1674 AC_OUTPUT