configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2015, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT([tor],[0.2.7.2-alpha-dev])
   7 AC_CONFIG_SRCDIR([src/or/main.c])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_INIT_AUTOMAKE
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AC_CONFIG_HEADERS([orconfig.h])
  12
  13 AC_CANONICAL_HOST
  14
  15 PKG_PROG_PKG_CONFIG
  16
  17 if test -f /etc/redhat-release ; then
  18   if test -f /usr/kerberos/include ; then
  19     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  20   fi
  21 fi
  22
  23 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  24 # the += operator on it in src/or/Makefile.am
  25 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  26
  27 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  28 AC_ARG_ENABLE(openbsd-malloc,
  29    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  30 AC_ARG_ENABLE(instrument-downloads,
  31    AS_HELP_STRING(--enable-instrument-downloads, [instrument downloads of directory resources etc.]))
  32 AC_ARG_ENABLE(static-openssl,
  33    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  34 AC_ARG_ENABLE(static-libevent,
  35    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  36 AC_ARG_ENABLE(static-zlib,
  37    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  38 AC_ARG_ENABLE(static-tor,
  39    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  40 AC_ARG_ENABLE(unittests,
  41    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  42 AC_ARG_ENABLE(coverage,
  43    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  44 AC_ARG_ENABLE(system-torrc,
  45    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  46
  47 AM_CONDITIONAL(UNITTESTS_ENABLED, test x$enable_unittests != xno)
  48 AM_CONDITIONAL(COVERAGE_ENABLED, test x$enable_coverage = xyes)
  49
  50 if test "$enable_static_tor" = "yes"; then
  51   enable_static_libevent="yes";
  52   enable_static_openssl="yes";
  53   enable_static_zlib="yes";
  54   CFLAGS="$CFLAGS -static"
  55 fi
  56
  57 if test "$enable_system_torrc" = "no"; then
  58   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  59             [Defined if we're not going to look for a torrc in SYSCONF])
  60 fi
  61
  62 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  63 if test x$enable_instrument_downloads = xyes; then
  64   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  65             [Defined if we want to keep track of how much of each kind of resource we download.])
  66 fi
  67
  68 AC_ARG_ENABLE(transparent,
  69      AS_HELP_STRING(--disable-transparent, [disable transparent proxy support]),
  70      [case "${enableval}" in
  71         yes) transparent=true ;;
  72         no)  transparent=false ;;
  73         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  74       esac], [transparent=true])
  75
  76 AC_ARG_ENABLE(asciidoc,
  77      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  78      [case "${enableval}" in
  79         yes) asciidoc=true ;;
  80         no)  asciidoc=false ;;
  81         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  82       esac], [asciidoc=true])
  83
  84 # systemd notify support
  85 AC_ARG_ENABLE(systemd,
  86       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  87       [case "${enableval}" in
  88         yes) systemd=true ;;
  89         no)  systemd=false ;;
  90         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
  91       esac], [systemd=auto])
  92
  93
  94
  95 # systemd support
  96 if test x$enable_systemd = xno ; then
  97     have_systemd=no;
  98 else
  99     PKG_CHECK_MODULES(SYSTEMD,
 100         [libsystemd-daemon],
 101         have_systemd=yes,
 102         have_systemd=no)
 103     if test x$have_systemd=xno; then
 104         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 105         PKG_CHECK_MODULES(SYSTEMD,
 106             [libsystemd],
 107             have_systemd=yes,
 108             have_systemd=no)
 109     fi
 110 fi
 111
 112 if test x$have_systemd = xyes; then
 113     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 114     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 115     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 116     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 117          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 118 fi
 119 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 120 AC_SUBST(TOR_SYSTEMD_LIBS)
 121
 122 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
 123     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 124 fi
 125
 126 case $host in
 127    *-*-solaris* )
 128      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 129      ;;
 130 esac
 131
 132 AC_ARG_ENABLE(gcc-warnings,
 133      AS_HELP_STRING(--enable-gcc-warnings, [enable verbose warnings]))
 134 AC_ARG_ENABLE(gcc-warnings-advisory,
 135      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
 136
 137 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 138 AC_ARG_ENABLE(gcc-hardening,
 139     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 140
 141 AC_ARG_ENABLE(expensive-hardening,
 142     AS_HELP_STRING(--enable-expensive-hardening, [enable more expensive compiler hardening; makes Tor slower]))
 143
 144 dnl Linker hardening options
 145 dnl Currently these options are ELF specific - you can't use this with MacOSX
 146 AC_ARG_ENABLE(linker-hardening,
 147     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 148
 149 AC_ARG_ENABLE(local-appdata,
 150    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 151 if test "$enable_local_appdata" = "yes"; then
 152   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 153             [Defined if we default to host local appdata paths on Windows])
 154 fi
 155
 156 # Tor2web mode flag
 157 AC_ARG_ENABLE(tor2web-mode,
 158      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 159 [if test x$enableval = xyes; then
 160     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 161 fi])
 162
 163 AC_ARG_ENABLE(bufferevents,
 164      AS_HELP_STRING(--enable-bufferevents, [use Libevent's buffered IO]))
 165
 166 AC_ARG_ENABLE(tool-name-check,
 167      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 168
 169 AC_ARG_ENABLE(seccomp,
 170      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 171
 172 AC_ARG_ENABLE(libscrypt,
 173      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 174
 175 dnl check for the correct "ar" when cross-compiling
 176 AN_MAKEVAR([AR], [AC_PROG_AR])
 177 AN_PROGRAM([ar], [AC_PROG_AR])
 178 AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
 179 AC_PROG_AR
 180
 181 dnl Check whether the above macro has settled for a simply named tool even
 182 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 183 dnl because that will find any cc on the system, not only the cross-compiler,
 184 dnl and then verify that a binary built with this compiler runs on the
 185 dnl build system. It will then come to the false conclusion that we're not
 186 dnl cross-compiling.
 187 if test x$enable_tool_name_check != xno; then
 188     if test x$ac_tool_warned = xyes; then
 189         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 190         elif test "x$ac_ct_AR" != x -a x$cross_compiling = xmaybe; then
 191                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 192         fi
 193 fi
 194
 195 AC_PROG_CC
 196 AC_PROG_CPP
 197 AC_PROG_MAKE_SET
 198 AC_PROG_RANLIB
 199
 200 AC_PATH_PROG([PERL], [perl])
 201
 202 dnl autoconf 2.59 appears not to support AC_PROG_SED
 203 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 204
 205 dnl check for asciidoc and a2x
 206 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 207 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 208
 209 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 210
 211 AM_CONDITIONAL(USE_FW_HELPER, test x$natpmp = xtrue || test x$upnp = xtrue)
 212 AM_CONDITIONAL(NAT_PMP, test x$natpmp = xtrue)
 213 AM_CONDITIONAL(MINIUPNPC, test x$upnp = xtrue)
 214 AM_PROG_CC_C_O
 215 AC_PROG_CC_C99
 216
 217 AC_ARG_VAR([PYTHON], [path to Python binary])
 218 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 219 if test "x$PYTHON" = "x"; then
 220   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 221 fi
 222 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 223
 224 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 225 AC_C_FLEXIBLE_ARRAY_MEMBER
 226 ], [
 227  dnl Maybe we've got an old autoconf...
 228  AC_CACHE_CHECK([for flexible array members],
 229      tor_cv_c_flexarray,
 230      [AC_COMPILE_IFELSE(
 231        AC_LANG_PROGRAM([
 232  struct abc { int a; char b[]; };
 233 ], [
 234  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 235  def->b[0] = 33;
 236 ]),
 237   [tor_cv_c_flexarray=yes],
 238   [tor_cv_c_flexarray=no])])
 239  if test $tor_cv_flexarray = yes ; then
 240    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 241  else
 242    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 243  fi
 244 ])
 245
 246 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 247       tor_cv_c_c99_decl,
 248       [AC_COMPILE_IFELSE(
 249          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 250          [tor_cv_c_c99_decl=yes],
 251          [tor_cv_c_c99_decl=no] )])
 252 if test "$tor_cv_c_c99_decl" != "yes"; then
 253   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 254 fi
 255
 256 AC_CACHE_CHECK([for working C99 designated initializers],
 257       tor_cv_c_c99_designated_init,
 258       [AC_COMPILE_IFELSE(
 259          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 260                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 261          [tor_cv_c_c99_designated_init=yes],
 262          [tor_cv_c_c99_designated_init=no] )])
 263
 264 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 265   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 266 fi
 267
 268 TORUSER=_tor
 269 AC_ARG_WITH(tor-user,
 270         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 271         [
 272            TORUSER=$withval
 273         ]
 274 )
 275 AC_SUBST(TORUSER)
 276
 277 TORGROUP=_tor
 278 AC_ARG_WITH(tor-group,
 279         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 280         [
 281            TORGROUP=$withval
 282         ]
 283 )
 284 AC_SUBST(TORGROUP)
 285
 286
 287 dnl If _WIN32 is defined and non-zero, we are building for win32
 288 AC_MSG_CHECKING([for win32])
 289 AC_RUN_IFELSE([AC_LANG_SOURCE([
 290 int main(int c, char **v) {
 291 #ifdef _WIN32
 292 #if _WIN32
 293   return 0;
 294 #else
 295   return 1;
 296 #endif
 297 #else
 298   return 2;
 299 #endif
 300 }])],
 301 bwin32=true; AC_MSG_RESULT([yes]),
 302 bwin32=false; AC_MSG_RESULT([no]),
 303 bwin32=cross; AC_MSG_RESULT([cross])
 304 )
 305
 306 if test "$bwin32" = cross; then
 307 AC_MSG_CHECKING([for win32 (cross)])
 308 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 309 #ifdef _WIN32
 310 int main(int c, char **v) {return 0;}
 311 #else
 312 #error
 313 int main(int c, char **v) {return x(y);}
 314 #endif
 315 ])],
 316 bwin32=true; AC_MSG_RESULT([yes]),
 317 bwin32=false; AC_MSG_RESULT([no]))
 318 fi
 319
 320 AH_BOTTOM([
 321 #ifdef _WIN32
 322 /* Defined to access windows functions and definitions for >=WinXP */
 323 # ifndef WINVER
 324 #  define WINVER 0x0501
 325 # endif
 326
 327 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 328 # ifndef _WIN32_WINNT
 329 #  define _WIN32_WINNT 0x0501
 330 # endif
 331
 332 /* Defined to avoid including some windows headers as part of Windows.h */
 333 # ifndef WIN32_LEAN_AND_MEAN
 334 #  define WIN32_LEAN_AND_MEAN 1
 335 # endif
 336 #endif
 337 ])
 338
 339
 340 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 341
 342 dnl Enable C99 when compiling with MIPSpro
 343 AC_MSG_CHECKING([for MIPSpro compiler])
 344 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 345 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 346 #error
 347   return x(y);
 348 #endif
 349 ])],
 350 bmipspro=false; AC_MSG_RESULT(no),
 351 bmipspro=true; AC_MSG_RESULT(yes))
 352
 353 if test "$bmipspro" = true; then
 354   CFLAGS="$CFLAGS -c99"
 355 fi
 356
 357 AC_C_BIGENDIAN
 358
 359 AC_SEARCH_LIBS(socket, [socket network])
 360 AC_SEARCH_LIBS(gethostbyname, [nsl])
 361 AC_SEARCH_LIBS(dlopen, [dl])
 362 AC_SEARCH_LIBS(inet_aton, [resolv])
 363 saved_LIBS="$LIBS"
 364 AC_SEARCH_LIBS([clock_gettime], [rt])
 365 if test "$LIBS" != "$saved_LIBS"; then
 366    # Looks like we need -lrt for clock_gettime().
 367    have_rt=yes
 368 fi
 369
 370 AC_SEARCH_LIBS(pthread_create, [pthread])
 371 AC_SEARCH_LIBS(pthread_detach, [pthread])
 372
 373 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 374 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 375
 376 dnl -------------------------------------------------------------------
 377 dnl Check for functions before libevent, since libevent-1.2 apparently
 378 dnl exports strlcpy without defining it in a header.
 379
 380 AC_CHECK_FUNCS(
 381         _NSGetEnviron \
 382         accept4 \
 383         backtrace \
 384         backtrace_symbols_fd \
 385         clock_gettime \
 386         eventfd \
 387         flock \
 388         ftime \
 389         getaddrinfo \
 390         getifaddrs \
 391         getpass \
 392         getrlimit \
 393         gettimeofday \
 394         gmtime_r \
 395         inet_aton \
 396         ioctl \
 397         issetugid \
 398         llround \
 399         localtime_r \
 400         lround \
 401         memmem \
 402         pipe \
 403         pipe2 \
 404         prctl \
 405         readpassphrase \
 406         rint \
 407         sigaction \
 408         socketpair \
 409         statvfs \
 410         strlcat \
 411         strlcpy \
 412         strnlen \
 413         strptime \
 414         strtok_r \
 415         strtoull \
 416         sysconf \
 417         sysctl \
 418         uname \
 419         usleep \
 420         vasprintf \
 421         _vscprintf
 422 )
 423
 424 if test "$bwin32" != true; then
 425   AC_CHECK_HEADERS(pthread.h)
 426   AC_CHECK_FUNCS(pthread_create)
 427 fi
 428
 429 if test "$bwin32" = true; then
 430   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 431 #include <windows.h>
 432 #include <conio.h>
 433 #include <wchar.h>
 434                  ])
 435 fi
 436
 437 AM_CONDITIONAL(BUILD_READPASSPHRASE_C, test x$ac_cv_func_readpassphrase = xno && test $bwin32 = false)
 438
 439 dnl ------------------------------------------------------
 440 dnl Where do you live, libevent?  And how do we call you?
 441
 442 if test "$bwin32" = true; then
 443   TOR_LIB_WS32=-lws2_32
 444   TOR_LIB_IPHLPAPI=-liphlpapi
 445   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 446   # think it's actually necessary.
 447   TOR_LIB_GDI=-lgdi32
 448 else
 449   TOR_LIB_WS32=
 450   TOR_LIB_GDI=
 451 fi
 452 AC_SUBST(TOR_LIB_WS32)
 453 AC_SUBST(TOR_LIB_GDI)
 454 AC_SUBST(TOR_LIB_IPHLPAPI)
 455
 456 tor_libevent_pkg_redhat="libevent"
 457 tor_libevent_pkg_debian="libevent-dev"
 458 tor_libevent_devpkg_redhat="libevent-devel"
 459 tor_libevent_devpkg_debian="libevent-dev"
 460
 461 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 462 dnl linking for static builds.
 463 STATIC_LIBEVENT_FLAGS=""
 464 if test "$enable_static_libevent" = "yes"; then
 465     if test "$have_rt" = yes; then
 466       STATIC_LIBEVENT_FLAGS=" -lrt "
 467     fi
 468 fi
 469
 470 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 471 #ifdef _WIN32
 472 #include <winsock2.h>
 473 #endif
 474 #include <stdlib.h>
 475 #include <sys/time.h>
 476 #include <sys/types.h>
 477 #include <event.h>], [
 478 #ifdef _WIN32
 479 #include <winsock2.h>
 480 #endif
 481 void exit(int); void *event_init(void);],
 482     [
 483 #ifdef _WIN32
 484 {WSADATA d; WSAStartup(0x101,&d); }
 485 #endif
 486 event_init(); exit(0);
 487 ], [--with-libevent-dir], [/opt/libevent])
 488
 489 dnl Now check for particular libevent functions.
 490 save_LIBS="$LIBS"
 491 save_LDFLAGS="$LDFLAGS"
 492 save_CPPFLAGS="$CPPFLAGS"
 493 LIBS="-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $LIBS"
 494 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 495 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 496 AC_CHECK_FUNCS([event_get_version_number \
 497                 evutil_secure_rng_set_urandom_device_file \
 498                 evutil_secure_rng_init \
 499                ])
 500 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 501 [#include <event.h>
 502 ])
 503
 504 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 505
 506 LIBS="$save_LIBS"
 507 LDFLAGS="$save_LDFLAGS"
 508 CPPFLAGS="$save_CPPFLAGS"
 509
 510
 511 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 512
 513 if test "$enable_static_libevent" = "yes"; then
 514    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 515      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 516    else
 517      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 518    fi
 519 else
 520      TOR_LIBEVENT_LIBS="-levent"
 521 fi
 522
 523 dnl This isn't the best test for Libevent 2.0.3-alpha.  Once it's released,
 524 dnl we can do much better.
 525 if test "$enable_bufferevents" = "yes" ; then
 526   if test "$ac_cv_header_event2_bufferevent_ssl_h" != "yes" ; then
 527     AC_MSG_ERROR([You've asked for bufferevent support, but you're using a version of Libevent without SSL support.  This won't work.  We need Libevent 2.0.8-rc or later, and you don't seem to even have Libevent 2.0.3-alpha.])
 528   else
 529
 530     CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 531
 532     # Check for the right version.  First see if version detection works.
 533     AC_MSG_CHECKING([whether we can detect the Libevent version])
 534     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 535 #include <event2/event.h>
 536 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 10
 537 #error
 538 int x = y(zz);
 539 #else
 540 int x = 1;
 541 #endif
 542   ])], [event_version_number_works=yes; AC_MSG_RESULT([yes]) ],
 543      [event_version_number_works=no;  AC_MSG_RESULT([no])])
 544     if test "$event_version_number_works" != 'yes'; then
 545       AC_MSG_WARN([Version detection on Libevent seems broken.  Your Libevent installation is probably screwed up or very old.])
 546     else
 547       AC_MSG_CHECKING([whether Libevent is new enough for bufferevents])
 548       AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 549 #include <event2/event.h>
 550 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000d00
 551 #error
 552 int x = y(zz);
 553 #else
 554 int x = 1;
 555 #endif
 556    ])], [ AC_MSG_RESULT([yes]) ],
 557       [ AC_MSG_RESULT([no])
 558         AC_MSG_ERROR([Libevent does not seem new enough to support bufferevents.  We require 2.0.13-stable or later]) ] )
 559     fi
 560   fi
 561 fi
 562
 563 LIBS="$save_LIBS"
 564 LDFLAGS="$save_LDFLAGS"
 565 CPPFLAGS="$save_CPPFLAGS"
 566
 567 AM_CONDITIONAL(USE_BUFFEREVENTS, test "$enable_bufferevents" = "yes")
 568 if test "$enable_bufferevents" = "yes"; then
 569   AC_DEFINE(USE_BUFFEREVENTS, 1, [Defined if we're going to use Libevent's buffered IO API])
 570   if test "$enable_static_libevent" = "yes"; then
 571     TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent_openssl.a $TOR_LIBEVENT_LIBS"
 572   else
 573     TOR_LIBEVENT_LIBS="-levent_openssl $TOR_LIBEVENT_LIBS"
 574   fi
 575 fi
 576 AC_SUBST(TOR_LIBEVENT_LIBS)
 577
 578 dnl ------------------------------------------------------
 579 dnl Where do you live, libm?
 580
 581 dnl On some platforms (Haiku/BeOS) the math library is
 582 dnl part of libroot. In which case don't link against lm
 583 TOR_LIB_MATH=""
 584 save_LIBS="$LIBS"
 585 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 586 if test "$ac_cv_search_pow" != "none required"; then
 587     TOR_LIB_MATH="$ac_cv_search_pow"
 588 fi
 589 LIBS="$save_LIBS"
 590 AC_SUBST(TOR_LIB_MATH)
 591
 592 dnl ------------------------------------------------------
 593 dnl Where do you live, openssl?  And how do we call you?
 594
 595 tor_openssl_pkg_redhat="openssl"
 596 tor_openssl_pkg_debian="libssl-dev"
 597 tor_openssl_devpkg_redhat="openssl-devel"
 598 tor_openssl_devpkg_debian="libssl-dev"
 599
 600 ALT_openssl_WITHVAL=""
 601 AC_ARG_WITH(ssl-dir,
 602   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 603   [
 604       if test "x$withval" != xno && test "x$withval" != "x" ; then
 605          ALT_openssl_WITHVAL="$withval"
 606       fi
 607   ])
 608
 609 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 610     [#include <openssl/rand.h>],
 611     [void RAND_add(const void *buf, int num, double entropy);],
 612     [RAND_add((void*)0,0,0); exit(0);], [],
 613     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 614
 615 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 616
 617 if test "$enable_static_openssl" = "yes"; then
 618    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 619      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 620    else
 621      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 622    fi
 623 else
 624      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 625 fi
 626 AC_SUBST(TOR_OPENSSL_LIBS)
 627
 628 dnl Now check for particular openssl functions.
 629 save_LIBS="$LIBS"
 630 save_LDFLAGS="$LDFLAGS"
 631 save_CPPFLAGS="$CPPFLAGS"
 632 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 633 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 634 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 635
 636 AC_TRY_COMPILE([
 637 #include <openssl/opensslv.h>
 638 #if OPENSSL_VERSION_NUMBER < 0x1000000fL
 639 #error "too old"
 640 #endif
 641    ], [],
 642    [ /bin/true ],
 643    [ AC_ERROR([OpenSSL is too old. We require 1.0.0 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 644
 645 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 646 [#include <openssl/ssl.h>
 647 ])
 648
 649 AC_CHECK_FUNCS([ \
 650                 SSL_SESSION_get_master_key \
 651                 SSL_get_server_random \
 652                 SSL_get_client_ciphers \
 653                 SSL_get_client_random \
 654                 SSL_CIPHER_find \
 655                 TLS_method
 656                ])
 657
 658 dnl Check if OpenSSL has scrypt implementation.
 659 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 660
 661 LIBS="$save_LIBS"
 662 LDFLAGS="$save_LDFLAGS"
 663 CPPFLAGS="$save_CPPFLAGS"
 664
 665 dnl ------------------------------------------------------
 666 dnl Where do you live, zlib?  And how do we call you?
 667
 668 tor_zlib_pkg_redhat="zlib"
 669 tor_zlib_pkg_debian="zlib1g"
 670 tor_zlib_devpkg_redhat="zlib-devel"
 671 tor_zlib_devpkg_debian="zlib1g-dev"
 672
 673 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 674     [#include <zlib.h>],
 675     [const char * zlibVersion(void);],
 676     [zlibVersion(); exit(0);], [--with-zlib-dir],
 677     [/opt/zlib])
 678
 679 if test "$enable_static_zlib" = "yes"; then
 680    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 681      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 682  using --enable-static-zlib")
 683    else
 684      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 685    fi
 686 else
 687      TOR_ZLIB_LIBS="-lz"
 688 fi
 689 AC_SUBST(TOR_ZLIB_LIBS)
 690
 691 dnl ---------------------------------------------------------------------
 692 dnl Now that we know about our major libraries, we can check for compiler
 693 dnl and linker hardening options.  We need to do this with the libraries known,
 694 dnl since sometimes the linker will like an option but not be willing to
 695 dnl use it with a build of a library.
 696
 697 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 698 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI"
 699
 700 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 701 #if !defined(__clang__)
 702 #error
 703 #endif])], have_clang=yes, have_clang=no)
 704
 705 if test x$enable_gcc_hardening != xno; then
 706     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2"
 707     if test x$have_clang = xyes; then
 708         TOR_CHECK_CFLAGS(-Qunused-arguments)
 709     fi
 710     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 711     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 712     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 713 m4_ifdef([AS_VAR_IF],[
 714     AS_VAR_IF(can_compile, [yes],
 715         AS_VAR_IF(can_link, [yes],
 716                   [],
 717                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 718         )])
 719     AS_VAR_POPDEF([can_link])
 720     AS_VAR_POPDEF([can_compile])
 721     TOR_CHECK_CFLAGS(-Wstack-protector)
 722     TOR_CHECK_CFLAGS(-fwrapv)
 723     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 724     if test "$bwin32" = "false"; then
 725        TOR_CHECK_CFLAGS(-fPIE)
 726        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 727     fi
 728 fi
 729
 730 if test x$enable_expensive_hardening = xyes ; then
 731    TOR_CHECK_CFLAGS([-fsanitize=address])
 732    TOR_CHECK_CFLAGS([-fsanitize=undefined])
 733    TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
 734 fi
 735
 736 if test x$enable_linker_hardening != xno; then
 737     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
 738 fi
 739
 740 # For backtrace support
 741 TOR_CHECK_LDFLAGS(-rdynamic)
 742
 743 dnl ------------------------------------------------------
 744 dnl Now see if we have a -fomit-frame-pointer compiler option.
 745
 746 saved_CFLAGS="$CFLAGS"
 747 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
 748 F_OMIT_FRAME_POINTER=''
 749 if test "$saved_CFLAGS" != "$CFLAGS"; then
 750   if test x$enable_expensive_hardening != xyes ; then
 751     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
 752   fi
 753 fi
 754 CFLAGS="$saved_CFLAGS"
 755 AC_SUBST(F_OMIT_FRAME_POINTER)
 756
 757 dnl ------------------------------------------------------
 758 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
 759 dnl for us, as GCC 4.6 and later do at many optimization levels), then
 760 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
 761 dnl code will work.
 762 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
 763
 764 dnl ============================================================
 765 dnl Check for libseccomp
 766
 767 if test "x$enable_seccomp" != "xno"; then
 768   AC_CHECK_HEADERS([seccomp.h])
 769   AC_SEARCH_LIBS(seccomp_init, [seccomp])
 770 fi
 771
 772 dnl ============================================================
 773 dnl Check for libscrypt
 774
 775 if test "x$enable_libscrypt" != "xno"; then
 776   AC_CHECK_HEADERS([libscrypt.h])
 777   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
 778 fi
 779
 780 dnl ============================================================
 781 dnl We need an implementation of curve25519.
 782
 783 dnl set these defaults.
 784 build_curve25519_donna=no
 785 build_curve25519_donna_c64=no
 786 use_curve25519_donna=no
 787 use_curve25519_nacl=no
 788 CURVE25519_LIBS=
 789
 790 dnl The best choice is using curve25519-donna-c64, but that requires
 791 dnl that we
 792 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
 793   tor_cv_can_use_curve25519_donna_c64,
 794   [AC_RUN_IFELSE(
 795     [AC_LANG_PROGRAM([dnl
 796       #include <stdint.h>
 797       typedef unsigned uint128_t __attribute__((mode(TI)));
 798   int func(uint64_t a, uint64_t b) {
 799            uint128_t c = ((uint128_t)a) * b;
 800            int ok = ((uint64_t)(c>>96)) == 522859 &&
 801              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 802                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 803                  (((uint64_t)(c))&0xffffffffL) == 0;
 804            return ok;
 805       }
 806   ], [dnl
 807     int ok = func( ((uint64_t)2000000000) * 1000000000,
 808                    ((uint64_t)1234567890) << 24);
 809         return !ok;
 810       ])],
 811   [tor_cv_can_use_curve25519_donna_c64=yes],
 812       [tor_cv_can_use_curve25519_donna_c64=no],
 813   [AC_LINK_IFELSE(
 814         [AC_LANG_PROGRAM([dnl
 815       #include <stdint.h>
 816       typedef unsigned uint128_t __attribute__((mode(TI)));
 817   int func(uint64_t a, uint64_t b) {
 818            uint128_t c = ((uint128_t)a) * b;
 819            int ok = ((uint64_t)(c>>96)) == 522859 &&
 820              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
 821                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
 822                  (((uint64_t)(c))&0xffffffffL) == 0;
 823            return ok;
 824       }
 825   ], [dnl
 826     int ok = func( ((uint64_t)2000000000) * 1000000000,
 827                  ((uint64_t)1234567890) << 24);
 828         return !ok;
 829       ])],
 830           [tor_cv_can_use_curve25519_donna_c64=cross],
 831       [tor_cv_can_use_curve25519_donna_c64=no])])])
 832
 833 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
 834                   nacl/crypto_scalarmult_curve25519.h])
 835
 836 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
 837   tor_cv_can_use_curve25519_nacl,
 838   [tor_saved_LIBS="$LIBS"
 839    LIBS="$LIBS -lnacl"
 840    AC_LINK_IFELSE(
 841      [AC_LANG_PROGRAM([dnl
 842        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
 843        #include <crypto_scalarmult_curve25519.h>
 844    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
 845    #include <nacl/crypto_scalarmult_curve25519.h>
 846    #endif
 847        #ifdef crypto_scalarmult_curve25519_ref_BYTES
 848    #error Hey, this is the reference implementation! That's not fast.
 849    #endif
 850      ], [
 851    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
 852      ])], [tor_cv_can_use_curve25519_nacl=yes],
 853      [tor_cv_can_use_curve25519_nacl=no])
 854    LIBS="$tor_saved_LIBS" ])
 855
 856  dnl Okay, now we need to figure out which one to actually use. Fall back
 857  dnl to curve25519-donna.c
 858
 859  if test x$tor_cv_can_use_curve25519_donna_c64 != xno; then
 860    build_curve25519_donna_c64=yes
 861    use_curve25519_donna=yes
 862  elif test x$tor_cv_can_use_curve25519_nacl = xyes; then
 863    use_curve25519_nacl=yes
 864    CURVE25519_LIBS=-lnacl
 865  else
 866    build_curve25519_donna=yes
 867    use_curve25519_donna=yes
 868  fi
 869
 870 if test x$use_curve25519_donna = xyes; then
 871   AC_DEFINE(USE_CURVE25519_DONNA, 1,
 872             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
 873 fi
 874 if test x$use_curve25519_nacl = xyes; then
 875   AC_DEFINE(USE_CURVE25519_NACL, 1,
 876             [Defined if we should use a curve25519 from nacl])
 877 fi
 878 AM_CONDITIONAL(BUILD_CURVE25519_DONNA, test x$build_curve25519_donna = xyes)
 879 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64, test x$build_curve25519_donna_c64 = xyes)
 880 AC_SUBST(CURVE25519_LIBS)
 881
 882 dnl Make sure to enable support for large off_t if available.
 883 AC_SYS_LARGEFILE
 884
 885 AC_CHECK_HEADERS(
 886         assert.h \
 887         errno.h \
 888         fcntl.h \
 889         signal.h \
 890         string.h \
 891         sys/fcntl.h \
 892         sys/stat.h \
 893         sys/time.h \
 894         sys/types.h \
 895         time.h \
 896         unistd.h
 897  , , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 898
 899 dnl These headers are not essential
 900
 901 AC_CHECK_HEADERS(
 902         arpa/inet.h \
 903         crt_externs.h \
 904         execinfo.h \
 905         grp.h \
 906         ifaddrs.h \
 907         inttypes.h \
 908         limits.h \
 909         linux/types.h \
 910         machine/limits.h \
 911         malloc.h \
 912         malloc/malloc.h \
 913         malloc_np.h \
 914         netdb.h \
 915         netinet/in.h \
 916         netinet/in6.h \
 917         pwd.h \
 918         readpassphrase.h \
 919         stdint.h \
 920         sys/eventfd.h \
 921         sys/file.h \
 922         sys/ioctl.h \
 923         sys/limits.h \
 924         sys/mman.h \
 925         sys/param.h \
 926         sys/prctl.h \
 927         sys/resource.h \
 928         sys/select.h \
 929         sys/socket.h \
 930         sys/statvfs.h \
 931         sys/sysctl.h \
 932         sys/syslimits.h \
 933         sys/time.h \
 934         sys/types.h \
 935         sys/un.h \
 936         sys/utime.h \
 937         sys/wait.h \
 938         syslog.h \
 939         utime.h
 940 )
 941
 942 AC_CHECK_HEADERS(sys/param.h)
 943
 944 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 945 [#ifdef HAVE_SYS_TYPES_H
 946 #include <sys/types.h>
 947 #endif
 948 #ifdef HAVE_SYS_SOCKET_H
 949 #include <sys/socket.h>
 950 #endif])
 951 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 952 [#ifdef HAVE_SYS_TYPES_H
 953 #include <sys/types.h>
 954 #endif
 955 #ifdef HAVE_SYS_SOCKET_H
 956 #include <sys/socket.h>
 957 #endif
 958 #ifdef HAVE_NET_IF_H
 959 #include <net/if.h>
 960 #endif])
 961
 962 AC_CHECK_HEADERS(linux/if.h,[],[],
 963 [
 964 #ifdef HAVE_SYS_SOCKET_H
 965 #include <sys/socket.h>
 966 #endif
 967 ])
 968
 969 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 970         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 971 [#ifdef HAVE_SYS_TYPES_H
 972 #include <sys/types.h>
 973 #endif
 974 #ifdef HAVE_SYS_SOCKET_H
 975 #include <sys/socket.h>
 976 #endif
 977 #ifdef HAVE_LIMITS_H
 978 #include <limits.h>
 979 #endif
 980 #ifdef HAVE_LINUX_TYPES_H
 981 #include <linux/types.h>
 982 #endif
 983 #ifdef HAVE_NETINET_IN6_H
 984 #include <netinet/in6.h>
 985 #endif
 986 #ifdef HAVE_NETINET_IN_H
 987 #include <netinet/in.h>
 988 #endif])
 989
 990 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
 991         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
 992 [#ifdef HAVE_SYS_TYPES_H
 993 #include <sys/types.h>
 994 #endif
 995 #ifdef HAVE_SYS_SOCKET_H
 996 #include <sys/socket.h>
 997 #endif
 998 #ifdef HAVE_LIMITS_H
 999 #include <limits.h>
1000 #endif
1001 #ifdef HAVE_LINUX_TYPES_H
1002 #include <linux/types.h>
1003 #endif
1004 #ifdef HAVE_NETINET_IN6_H
1005 #include <netinet/in6.h>
1006 #endif
1007 #ifdef HAVE_NETINET_IN_H
1008 #include <netinet/in.h>
1009 #endif
1010 #ifdef HAVE_LINUX_IF_H
1011 #include <linux/if.h>
1012 #endif])
1013
1014 if test x$transparent = xtrue ; then
1015    transparent_ok=0
1016    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
1017      transparent_ok=1
1018    fi
1019    if test x$linux_netfilter_ipv4 = x1 ; then
1020      transparent_ok=1
1021    fi
1022    if test x$linux_netfilter_ipv6_ip6_tables = x1 ; then
1023      transparent_ok=1
1024    fi
1025    if test x$transparent_ok = x1 ; then
1026      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1027      case $host in
1028        *-*-openbsd* | *-*-bitrig*)
1029          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
1030      esac
1031    else
1032      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1033    fi
1034 fi
1035
1036 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1037 [#ifdef HAVE_SYS_TYPES_H
1038 #include <sys/types.h>
1039 #endif
1040 #ifdef HAVE_SYS_TIME_H
1041 #include <sys/time.h>
1042 #endif])
1043
1044 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1045 dnl Watch out.
1046
1047 AC_CHECK_SIZEOF(int8_t)
1048 AC_CHECK_SIZEOF(int16_t)
1049 AC_CHECK_SIZEOF(int32_t)
1050 AC_CHECK_SIZEOF(int64_t)
1051 AC_CHECK_SIZEOF(uint8_t)
1052 AC_CHECK_SIZEOF(uint16_t)
1053 AC_CHECK_SIZEOF(uint32_t)
1054 AC_CHECK_SIZEOF(uint64_t)
1055 AC_CHECK_SIZEOF(intptr_t)
1056 AC_CHECK_SIZEOF(uintptr_t)
1057
1058 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1059
1060 AC_CHECK_SIZEOF(char)
1061 AC_CHECK_SIZEOF(short)
1062 AC_CHECK_SIZEOF(int)
1063 AC_CHECK_SIZEOF(long)
1064 AC_CHECK_SIZEOF(long long)
1065 AC_CHECK_SIZEOF(__int64)
1066 AC_CHECK_SIZEOF(void *)
1067 AC_CHECK_SIZEOF(time_t)
1068 AC_CHECK_SIZEOF(size_t)
1069 AC_CHECK_SIZEOF(pid_t)
1070
1071 AC_CHECK_TYPES([uint, u_char, ssize_t])
1072
1073 AC_PC_FROM_UCONTEXT([/bin/true])
1074
1075 dnl used to include sockaddr_storage, but everybody has that.
1076 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1077 [#ifdef HAVE_SYS_TYPES_H
1078 #include <sys/types.h>
1079 #endif
1080 #ifdef HAVE_NETINET_IN_H
1081 #include <netinet/in.h>
1082 #endif
1083 #ifdef HAVE_NETINET_IN6_H
1084 #include <netinet/in6.h>
1085 #endif
1086 #ifdef HAVE_SYS_SOCKET_H
1087 #include <sys/socket.h>
1088 #endif
1089 #ifdef _WIN32
1090 #define _WIN32_WINNT 0x0501
1091 #define WIN32_LEAN_AND_MEAN
1092 #include <winsock2.h>
1093 #include <ws2tcpip.h>
1094 #endif
1095 ])
1096 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1097 [#ifdef HAVE_SYS_TYPES_H
1098 #include <sys/types.h>
1099 #endif
1100 #ifdef HAVE_NETINET_IN_H
1101 #include <netinet/in.h>
1102 #endif
1103 #ifdef HAVE_NETINET_IN6_H
1104 #include <netinet/in6.h>
1105 #endif
1106 #ifdef HAVE_SYS_SOCKET_H
1107 #include <sys/socket.h>
1108 #endif
1109 #ifdef _WIN32
1110 #define _WIN32_WINNT 0x0501
1111 #define WIN32_LEAN_AND_MEAN
1112 #include <winsock2.h>
1113 #include <ws2tcpip.h>
1114 #endif
1115 #endif
1116 ])
1117
1118 AC_CHECK_TYPES([rlim_t], , ,
1119 [#ifdef HAVE_SYS_TYPES_H
1120 #include <sys/types.h>
1121 #endif
1122 #ifdef HAVE_SYS_TIME_H
1123 #include <sys/time.h>
1124 #endif
1125 #ifdef HAVE_SYS_RESOURCE_H
1126 #include <sys/resource.h>
1127 #endif
1128 ])
1129
1130 AX_CHECK_SIGN([time_t],
1131        [ AC_DEFINE(TIME_T_IS_SIGNED, 1, [Define if time_t is signed]) ],
1132        [ : ], [
1133 #ifdef HAVE_SYS_TYPES_H
1134 #include <sys/types.h>
1135 #endif
1136 #ifdef HAVE_SYS_TIME_H
1137 #include <sys/time.h>
1138 #endif
1139 #ifdef HAVE_TIME_H
1140 #include <time.h>
1141 #endif
1142 ])
1143
1144 if test "$ax_cv_decl_time_t_signed" = no; then
1145   AC_MSG_WARN([You have an unsigned time_t; some things will probably break. Please tell the Tor developers about your interesting platform.])
1146 fi
1147
1148 AX_CHECK_SIGN([size_t],
1149        [ tor_cv_size_t_signed=yes ],
1150        [ tor_cv_size_t_signed=no ], [
1151 #ifdef HAVE_SYS_TYPES_H
1152 #include <sys/types.h>
1153 #endif
1154 ])
1155
1156 if test "$ax_cv_decl_size_t_signed" = yes; then
1157   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1158 fi
1159
1160 AX_CHECK_SIGN([enum always],
1161        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1162        [ : ], [
1163  enum always { AAA, BBB, CCC };
1164 ])
1165
1166 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1167 #ifdef HAVE_SYS_SOCKET_H
1168 #include <sys/socket.h>
1169 #endif
1170 ])
1171
1172 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1173
1174 AC_CHECK_SIZEOF(cell_t)
1175
1176 # Now make sure that NULL can be represented as zero bytes.
1177 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1178 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1179 [[#include <stdlib.h>
1180 #include <string.h>
1181 #include <stdio.h>
1182 #ifdef HAVE_STDDEF_H
1183 #include <stddef.h>
1184 #endif
1185 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1186 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1187        [tor_cv_null_is_zero=yes],
1188        [tor_cv_null_is_zero=no],
1189        [tor_cv_null_is_zero=cross])])
1190
1191 if test "$tor_cv_null_is_zero" = cross ; then
1192   # Cross-compiling; let's hope that the target isn't raving mad.
1193   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1194 fi
1195
1196 if test "$tor_cv_null_is_zero" != no; then
1197   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1198             [Define to 1 iff memset(0) sets pointers to NULL])
1199 fi
1200
1201 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1202 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1203 [[#include <stdlib.h>
1204 #include <string.h>
1205 #include <stdio.h>
1206 #ifdef HAVE_STDDEF_H
1207 #include <stddef.h>
1208 #endif
1209 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1210 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1211        [tor_cv_dbl0_is_zero=yes],
1212        [tor_cv_dbl0_is_zero=no],
1213        [tor_cv_dbl0_is_zero=cross])])
1214
1215 if test "$tor_cv_dbl0_is_zero" = cross ; then
1216   # Cross-compiling; let's hope that the target isn't raving mad.
1217   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1218 fi
1219
1220 if test "$tor_cv_dbl0_is_zero" != no; then
1221   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1222             [Define to 1 iff memset(0) sets doubles to 0.0])
1223 fi
1224
1225 # And what happens when we malloc zero?
1226 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1227 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1228 [[#include <stdlib.h>
1229 #include <string.h>
1230 #include <stdio.h>
1231 #ifdef HAVE_STDDEF_H
1232 #include <stddef.h>
1233 #endif
1234 int main () { return malloc(0)?0:1; }]])],
1235        [tor_cv_malloc_zero_works=yes],
1236        [tor_cv_malloc_zero_works=no],
1237        [tor_cv_malloc_zero_works=cross])])
1238
1239 if test "$tor_cv_malloc_zero_works" = cross; then
1240   # Cross-compiling; let's hope that the target isn't raving mad.
1241   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1242 fi
1243
1244 if test "$tor_cv_malloc_zero_works" = yes; then
1245   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1246             [Define to 1 iff malloc(0) returns a pointer])
1247 fi
1248
1249 # whether we seem to be in a 2s-complement world.
1250 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1251 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1252 [[int main () { int problem = ((-99) != (~99)+1);
1253 return problem ? 1 : 0; }]])],
1254        [tor_cv_twos_complement=yes],
1255        [tor_cv_twos_complement=no],
1256        [tor_cv_twos_complement=cross])])
1257
1258 if test "$tor_cv_twos_complement" = cross ; then
1259   # Cross-compiling; let's hope that the target isn't raving mad.
1260   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1261 fi
1262
1263 if test "$tor_cv_twos_complement" != no ; then
1264   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1265             [Define to 1 iff we represent negative integers with two's complement])
1266 fi
1267
1268 # What does shifting a negative value do?
1269 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1270 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1271 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1272        [tor_cv_sign_extend=yes],
1273        [tor_cv_sign_extend=no],
1274        [tor_cv_sign_extend=cross])])
1275
1276 if test "$tor_cv_sign_extend" = cross ; then
1277   # Cross-compiling; let's hope that the target isn't raving mad.
1278   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1279 fi
1280
1281 if test "$tor_cv_sign_extend" != no ; then
1282   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1283             [Define to 1 iff right-shifting a negative value performs sign-extension])
1284 fi
1285
1286 # Whether we should use the dmalloc memory allocation debugging library.
1287 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1288 AC_ARG_WITH(dmalloc,
1289 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1290 [if [[ "$withval" = "yes" ]]; then
1291   dmalloc=1
1292   AC_MSG_RESULT(yes)
1293 else
1294   dmalloc=1
1295   AC_MSG_RESULT(no)
1296 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1297 )
1298
1299 if [[ $dmalloc -eq 1 ]]; then
1300   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1301   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1302   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1303   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1304 fi
1305
1306 AC_ARG_WITH(tcmalloc,
1307 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1308 [ tcmalloc=yes ], [ tcmalloc=no ])
1309
1310 if test x$tcmalloc = xyes ; then
1311    LDFLAGS="-ltcmalloc $LDFLAGS"
1312 fi
1313
1314 using_custom_malloc=no
1315 if test x$enable_openbsd_malloc = xyes ; then
1316    using_custom_malloc=yes
1317 fi
1318 if test x$tcmalloc = xyes ; then
1319    using_custom_malloc=yes
1320 fi
1321 if test $using_custom_malloc = no ; then
1322    AC_CHECK_FUNCS(mallinfo)
1323 fi
1324
1325 # By default, we're going to assume we don't have mlockall()
1326 # bionic and other platforms have various broken mlockall subsystems.
1327 # Some systems don't have a working mlockall, some aren't linkable,
1328 # and some have it but don't declare it.
1329 AC_CHECK_FUNCS(mlockall)
1330 AC_CHECK_DECLS([mlockall], , , [
1331 #ifdef HAVE_SYS_MMAN_H
1332 #include <sys/mman.h>
1333 #endif])
1334
1335 # Allow user to specify an alternate syslog facility
1336 AC_ARG_WITH(syslog-facility,
1337 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1338 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1339 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1340 AC_SUBST(LOGFACILITY)
1341
1342 # Check if we have getresuid and getresgid
1343 AC_CHECK_FUNCS(getresuid getresgid)
1344
1345 # Check for gethostbyname_r in all its glorious incompatible versions.
1346 #   (This logic is based on that in Python's configure.in)
1347 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1348   [Define this if you have any gethostbyname_r()])
1349
1350 AC_CHECK_FUNC(gethostbyname_r, [
1351   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1352   OLD_CFLAGS=$CFLAGS
1353   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1354   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1355 #include <netdb.h>
1356   ], [[
1357     char *cp1, *cp2;
1358     struct hostent *h1, *h2;
1359     int i1, i2;
1360     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1361   ]])],[
1362     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1363     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1364      [Define this if gethostbyname_r takes 6 arguments])
1365     AC_MSG_RESULT(6)
1366   ], [
1367     AC_TRY_COMPILE([
1368 #include <netdb.h>
1369     ], [
1370       char *cp1, *cp2;
1371       struct hostent *h1;
1372       int i1, i2;
1373       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1374     ], [
1375       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1376       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1377         [Define this if gethostbyname_r takes 5 arguments])
1378       AC_MSG_RESULT(5)
1379    ], [
1380       AC_TRY_COMPILE([
1381 #include <netdb.h>
1382      ], [
1383        char *cp1;
1384        struct hostent *h1;
1385        struct hostent_data hd;
1386        (void) gethostbyname_r(cp1,h1,&hd);
1387      ], [
1388        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1389        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1390          [Define this if gethostbyname_r takes 3 arguments])
1391        AC_MSG_RESULT(3)
1392      ], [
1393        AC_MSG_RESULT(0)
1394      ])
1395   ])
1396  ])
1397  CFLAGS=$OLD_CFLAGS
1398 ])
1399
1400 AC_CACHE_CHECK([whether the C compiler supports __func__],
1401   tor_cv_have_func_macro,
1402   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1403 #include <stdio.h>
1404 int main(int c, char **v) { puts(__func__); }])],
1405   tor_cv_have_func_macro=yes,
1406   tor_cv_have_func_macro=no))
1407
1408 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1409   tor_cv_have_FUNC_macro,
1410   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1411 #include <stdio.h>
1412 int main(int c, char **v) { puts(__FUNC__); }])],
1413   tor_cv_have_FUNC_macro=yes,
1414   tor_cv_have_FUNC_macro=no))
1415
1416 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1417   tor_cv_have_FUNCTION_macro,
1418   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1419 #include <stdio.h>
1420 int main(int c, char **v) { puts(__FUNCTION__); }])],
1421   tor_cv_have_FUNCTION_macro=yes,
1422   tor_cv_have_FUNCTION_macro=no))
1423
1424 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1425   tor_cv_have_environ_declared,
1426   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1427 /* We define _GNU_SOURCE here because it is also defined in compat.c.
1428  * Without it environ doesn't get declared. */
1429 #define _GNU_SOURCE
1430 #ifdef HAVE_UNISTD_H
1431 #include <unistd.h>
1432 #endif
1433 #include <stdlib.h>
1434 int main(int c, char **v) { char **t = environ; }])],
1435   tor_cv_have_environ_declared=yes,
1436   tor_cv_have_environ_declared=no))
1437
1438 if test "$tor_cv_have_func_macro" = 'yes'; then
1439   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1440 fi
1441
1442 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
1443   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1444 fi
1445
1446 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
1447   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1448            [Defined if the compiler supports __FUNCTION__])
1449 fi
1450
1451 if test "$tor_cv_have_environ_declared" = 'yes'; then
1452   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1453            [Defined if we have extern char **environ already declared])
1454 fi
1455
1456 # $prefix stores the value of the --prefix command line option, or
1457 # NONE if the option wasn't set.  In the case that it wasn't set, make
1458 # it be the default, so that we can use it to expand directories now.
1459 if test "x$prefix" = "xNONE"; then
1460   prefix=$ac_default_prefix
1461 fi
1462
1463 # and similarly for $exec_prefix
1464 if test "x$exec_prefix" = "xNONE"; then
1465   exec_prefix=$prefix
1466 fi
1467
1468 if test "x$BUILDDIR" = "x"; then
1469   BUILDDIR=`pwd`
1470 fi
1471 AC_SUBST(BUILDDIR)
1472 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1473 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1474
1475 if test "x$CONFDIR" = "x"; then
1476   CONFDIR=`eval echo $sysconfdir/tor`
1477 fi
1478 AC_SUBST(CONFDIR)
1479 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1480 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1481
1482 BINDIR=`eval echo $bindir`
1483 AC_SUBST(BINDIR)
1484 LOCALSTATEDIR=`eval echo $localstatedir`
1485 AC_SUBST(LOCALSTATEDIR)
1486
1487 if test "$bwin32" = true; then
1488   # Test if the linker supports the --nxcompat and --dynamicbase options
1489   # for Windows
1490   save_LDFLAGS="$LDFLAGS"
1491   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1492   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1493   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1494     [AC_MSG_RESULT([yes])]
1495     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1496     [AC_MSG_RESULT([no])]
1497   )
1498   LDFLAGS="$save_LDFLAGS"
1499 fi
1500
1501 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1502 # than autoconf's macros like.
1503 if test "$GCC" = yes; then
1504   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1505   # accident waiting to happen.
1506   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1507 else
1508   # Override optimization level for non-gcc compilers
1509   CFLAGS="$CFLAGS -O"
1510   enable_gcc_warnings=no
1511   enable_gcc_warnings_advisory=no
1512 fi
1513
1514 # OS X Lion started deprecating the system openssl. Let's just disable
1515 # all deprecation warnings on OS X. Also, to potentially make the binary
1516 # a little smaller, let's enable dead_strip.
1517 case "$host_os" in
1518
1519  darwin*)
1520     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1521     LDFLAGS="$LDFLAGS -dead_strip" ;;
1522 esac
1523
1524 # Add some more warnings which we use in development but not in the
1525 # released versions.  (Some relevant gcc versions can't handle these.)
1526 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
1527
1528   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1529 #if !defined(__GNUC__) || (__GNUC__ < 4)
1530 #error
1531 #endif])], have_gcc4=yes, have_gcc4=no)
1532
1533   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1534 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
1535 #error
1536 #endif])], have_gcc42=yes, have_gcc42=no)
1537
1538   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1539 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
1540 #error
1541 #endif])], have_gcc43=yes, have_gcc43=no)
1542
1543   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1544 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 6)
1545 #error
1546 #endif])], have_gcc46=yes, have_gcc46=no)
1547
1548
1549   save_CFLAGS="$CFLAGS"
1550   CFLAGS="$CFLAGS -Wshorten-64-to-32"
1551   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
1552                     have_shorten64_flag=no)
1553   CFLAGS="$save_CFLAGS"
1554
1555   case $host in
1556     *-*-openbsd* | *-*-bitrig*)
1557       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1558       # That's fine, except that the headers don't pass -Wredundant-decls.
1559       # Therefore, let's disable -Wsystem-headers when we're building
1560       # with maximal warnings on OpenBSD.
1561       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1562   esac
1563
1564   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
1565   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
1566   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
1567   CFLAGS="$CFLAGS -Wwrite-strings -Wmissing-declarations -Wredundant-decls"
1568   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
1569
1570   if test x$enable_gcc_warnings = xyes; then
1571     CFLAGS="$CFLAGS -Werror"
1572   fi
1573
1574   # Disabled, so we can use mallinfo(): -Waggregate-return
1575
1576   if test x$have_gcc4 = xyes ; then
1577     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
1578     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wold-style-definition"
1579   fi
1580
1581   if test x$have_gcc42 = xyes ; then
1582     # These warnings break gcc 4.0.2 and work on gcc 4.2
1583     # XXXX020 See if any of these work with earlier versions.
1584     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wstrict-overflow=1"
1585
1586     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
1587   fi
1588
1589   if test x$have_gcc42 = xyes && test x$have_clang = xno; then
1590     # These warnings break gcc 4.0.2 and clang, but work on gcc 4.2
1591     CFLAGS="$CFLAGS -Wnormalized=id -Woverride-init"
1592   fi
1593
1594   if test x$have_gcc43 = xyes ; then
1595     # These warnings break gcc 4.2 and work on gcc 4.3
1596     # XXXX020 See if any of these work with earlier versions.
1597     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
1598   fi
1599
1600   if test x$have_gcc46 = xyes ; then
1601     # This warning was added in gcc 4.3, but it appears to generate
1602     # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1603     CFLAGS="$CFLAGS -Wlogical-op"
1604   fi
1605
1606   if test x$have_shorten64_flag = xyes ; then
1607     CFLAGS="$CFLAGS -Wshorten-64-to-32"
1608   fi
1609
1610
1611
1612 ##This will break the world on some 64-bit architectures
1613 # CFLAGS="$CFLAGS -Winline"
1614 fi
1615
1616 if test "$enable_coverage" = yes && test "$have_clang" = "no"; then
1617    case "$host_os" in
1618     darwin*)
1619       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-profiling.])
1620    esac
1621 fi
1622
1623 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
1624
1625 AC_CONFIG_FILES([
1626         Doxyfile
1627         Makefile
1628         contrib/dist/suse/tor.sh
1629         contrib/operator-tools/tor.logrotate
1630         contrib/dist/tor.sh
1631         contrib/dist/torctl
1632         contrib/dist/tor.service
1633         src/config/torrc.sample
1634         src/config/torrc.minimal
1635         scripts/maint/checkOptionDocs.pl
1636         scripts/maint/updateVersions.pl
1637         src/test/test_zero_length_keys.sh
1638         src/test/test_ntor.sh
1639         src/test/test_bt.sh
1640 ])
1641
1642 if test x$asciidoc = xtrue && test "$ASCIIDOC" = "none" ; then
1643   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
1644   for file in $regular_mans ; do
1645     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
1646       echo "==================================";
1647       echo;
1648       echo "Building Tor has failed since manpages cannot be built.";
1649       echo;
1650       echo "You need asciidoc installed to be able to build the manpages.";
1651       echo "To build without manpages, use the --disable-asciidoc argument";
1652       echo "when calling configure.";
1653       echo;
1654       echo "==================================";
1655       exit 1;
1656     fi
1657   done
1658 fi
1659
1660 AC_OUTPUT