configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2017, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.3.2.10-dev])
   8 AC_CONFIG_SRCDIR([src/or/main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # "foreign" means we don't follow GNU package layout standards
  12 # "1.11" means we require automake version 1.11 or newer
  13 # "subdir-objects" means put .o files in the same directory as the .c files
  14 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17 AC_CONFIG_HEADERS([orconfig.h])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_CANONICAL_HOST
  21
  22 PKG_PROG_PKG_CONFIG
  23
  24 if test -f "/etc/redhat-release"; then
  25   if test -f "/usr/kerberos/include"; then
  26     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  27   fi
  28 fi
  29
  30 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  31 # the += operator on it in src/or/Makefile.am
  32 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  33
  34 AC_ARG_ENABLE(openbsd-malloc,
  35    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only]))
  36 AC_ARG_ENABLE(static-openssl,
  37    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  38 AC_ARG_ENABLE(static-libevent,
  39    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  40 AC_ARG_ENABLE(static-zlib,
  41    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  42 AC_ARG_ENABLE(static-tor,
  43    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  44 AC_ARG_ENABLE(unittests,
  45    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  46 AC_ARG_ENABLE(coverage,
  47    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  48 AC_ARG_ENABLE(asserts-in-tests,
  49    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  50 AC_ARG_ENABLE(system-torrc,
  51    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  52 AC_ARG_ENABLE(libfuzzer,
  53    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  54 AC_ARG_ENABLE(oss-fuzz,
  55    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  56 AC_ARG_ENABLE(memory-sentinels,
  57    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  58 AC_ARG_ENABLE(rust,
  59    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  60 AC_ARG_ENABLE(cargo-online-mode,
  61    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  62
  63 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  64     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  65 fi
  66
  67 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  68 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  69 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  70 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  71 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  72 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  73
  74 if test "$enable_static_tor" = "yes"; then
  75   enable_static_libevent="yes";
  76   enable_static_openssl="yes";
  77   enable_static_zlib="yes";
  78   CFLAGS="$CFLAGS -static"
  79 fi
  80
  81 if test "$enable_system_torrc" = "no"; then
  82   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  83             [Defined if we're not going to look for a torrc in SYSCONF])
  84 fi
  85
  86 if test "$enable_memory_sentinels" = "no"; then
  87   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  88            [Defined if we're turning off memory safety code to look for bugs])
  89 fi
  90
  91 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  92
  93 AC_ARG_ENABLE(asciidoc,
  94      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  95      [case "${enableval}" in
  96         "yes") asciidoc=true ;;
  97         "no")  asciidoc=false ;;
  98         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  99       esac], [asciidoc=true])
 100
 101 # systemd notify support
 102 AC_ARG_ENABLE(systemd,
 103       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 104       [case "${enableval}" in
 105         "yes") systemd=true ;;
 106         "no")  systemd=false ;;
 107         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 108       esac], [systemd=auto])
 109
 110
 111
 112 # systemd support
 113 if test "x$enable_systemd" = "xno"; then
 114     have_systemd=no;
 115 else
 116     PKG_CHECK_MODULES(SYSTEMD,
 117         [libsystemd-daemon],
 118         have_systemd=yes,
 119         have_systemd=no)
 120     if test "x$have_systemd" = "xno"; then
 121         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 122         PKG_CHECK_MODULES(SYSTEMD,
 123             [libsystemd],
 124             have_systemd=yes,
 125             have_systemd=no)
 126     fi
 127 fi
 128
 129 if test "x$have_systemd" = "xyes"; then
 130     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 131     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 132     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 133     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 134          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
 135 fi
 136 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 137 AC_SUBST(TOR_SYSTEMD_LIBS)
 138
 139 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 140     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
 141 fi
 142
 143 case "$host" in
 144    *-*-solaris* )
 145      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 146      ;;
 147 esac
 148
 149 AC_ARG_ENABLE(gcc-warnings,
 150      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 151 AC_ARG_ENABLE(fatal-warnings,
 152      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 153 AC_ARG_ENABLE(gcc-warnings-advisory,
 154      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 155
 156 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 157 AC_ARG_ENABLE(gcc-hardening,
 158     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 159
 160 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 161 AC_ARG_ENABLE(expensive-hardening,
 162     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 163 AC_ARG_ENABLE(fragile-hardening,
 164     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 165 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 166   fragile_hardening="yes"
 167 fi
 168
 169 dnl Linker hardening options
 170 dnl Currently these options are ELF specific - you can't use this with MacOSX
 171 AC_ARG_ENABLE(linker-hardening,
 172     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 173
 174 AC_ARG_ENABLE(local-appdata,
 175    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 176 if test "$enable_local_appdata" = "yes"; then
 177   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 178             [Defined if we default to host local appdata paths on Windows])
 179 fi
 180
 181 # Tor2web mode flag
 182 AC_ARG_ENABLE(tor2web-mode,
 183      AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
 184 [if test "x$enableval" = "xyes"; then
 185     CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
 186 fi])
 187
 188 AC_ARG_ENABLE(tool-name-check,
 189      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 190
 191 AC_ARG_ENABLE(seccomp,
 192      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 193
 194 AC_ARG_ENABLE(libscrypt,
 195      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 196
 197 dnl Enable event tracing which are transformed to debug log statement.
 198 AC_ARG_ENABLE(event-tracing-debug,
 199      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 200 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 201
 202 if test x$enable_event_tracing_debug = xyes; then
 203   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 204   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 205 fi
 206
 207 dnl check for the correct "ar" when cross-compiling.
 208 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 209 dnl    so kludge up a replacement for the case where it isn't there yet.)
 210 m4_ifdef([AM_PROG_AR],
 211          [AM_PROG_AR],
 212          [AN_MAKEVAR([AR], [AC_PROG_AR])
 213           AN_PROGRAM([ar], [AC_PROG_AR])
 214           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 215           AC_PROG_AR])
 216
 217 dnl Check whether the above macro has settled for a simply named tool even
 218 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 219 dnl because that will find any cc on the system, not only the cross-compiler,
 220 dnl and then verify that a binary built with this compiler runs on the
 221 dnl build system. It will then come to the false conclusion that we're not
 222 dnl cross-compiling.
 223 if test "x$enable_tool_name_check" != "xno"; then
 224     if test "x$ac_tool_warned" = "xyes"; then
 225         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 226         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 227                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 228         fi
 229 fi
 230
 231 AC_PROG_CC
 232 AC_PROG_CPP
 233 AC_PROG_MAKE_SET
 234 AC_PROG_RANLIB
 235 AC_PROG_SED
 236
 237 AC_ARG_VAR([PERL], [path to Perl binary])
 238 AC_CHECK_PROGS([PERL], [perl])
 239 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 240
 241 dnl check for asciidoc and a2x
 242 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 243 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 244
 245 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 246
 247 AM_PROG_CC_C_O
 248 AC_PROG_CC_C99
 249
 250 AC_ARG_VAR([PYTHON], [path to Python binary])
 251 AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
 252 if test "x$PYTHON" = "x"; then
 253   AC_MSG_WARN([Python unavailable; some tests will not be run.])
 254 fi
 255 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 256
 257 dnl List all external rust crates we depend on here. Include the version
 258 rust_crates="libc-0.2.22"
 259 AC_SUBST(rust_crates)
 260
 261 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 262 AC_C_FLEXIBLE_ARRAY_MEMBER
 263 ], [
 264  dnl Maybe we've got an old autoconf...
 265  AC_CACHE_CHECK([for flexible array members],
 266      tor_cv_c_flexarray,
 267      [AC_COMPILE_IFELSE(
 268        AC_LANG_PROGRAM([
 269  struct abc { int a; char b[]; };
 270 ], [
 271  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 272  def->b[0] = 33;
 273 ]),
 274   [tor_cv_c_flexarray=yes],
 275   [tor_cv_c_flexarray=no])])
 276  if test "$tor_cv_flexarray" = "yes"; then
 277    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 278  else
 279    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 280  fi
 281 ])
 282
 283 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 284       tor_cv_c_c99_decl,
 285       [AC_COMPILE_IFELSE(
 286          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 287          [tor_cv_c_c99_decl=yes],
 288          [tor_cv_c_c99_decl=no] )])
 289 if test "$tor_cv_c_c99_decl" != "yes"; then
 290   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 291 fi
 292
 293 AC_CACHE_CHECK([for working C99 designated initializers],
 294       tor_cv_c_c99_designated_init,
 295       [AC_COMPILE_IFELSE(
 296          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 297                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 298          [tor_cv_c_c99_designated_init=yes],
 299          [tor_cv_c_c99_designated_init=no] )])
 300
 301 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 302   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 303 fi
 304
 305 TORUSER=_tor
 306 AC_ARG_WITH(tor-user,
 307         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 308         [
 309            TORUSER=$withval
 310         ]
 311 )
 312 AC_SUBST(TORUSER)
 313
 314 TORGROUP=_tor
 315 AC_ARG_WITH(tor-group,
 316         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 317         [
 318            TORGROUP=$withval
 319         ]
 320 )
 321 AC_SUBST(TORGROUP)
 322
 323
 324 dnl If _WIN32 is defined and non-zero, we are building for win32
 325 AC_MSG_CHECKING([for win32])
 326 AC_RUN_IFELSE([AC_LANG_SOURCE([
 327 int main(int c, char **v) {
 328 #ifdef _WIN32
 329 #if _WIN32
 330   return 0;
 331 #else
 332   return 1;
 333 #endif
 334 #else
 335   return 2;
 336 #endif
 337 }])],
 338 bwin32=true; AC_MSG_RESULT([yes]),
 339 bwin32=false; AC_MSG_RESULT([no]),
 340 bwin32=cross; AC_MSG_RESULT([cross])
 341 )
 342
 343 if test "$bwin32" = "cross"; then
 344 AC_MSG_CHECKING([for win32 (cross)])
 345 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 346 #ifdef _WIN32
 347 int main(int c, char **v) {return 0;}
 348 #else
 349 #error
 350 int main(int c, char **v) {return x(y);}
 351 #endif
 352 ])],
 353 bwin32=true; AC_MSG_RESULT([yes]),
 354 bwin32=false; AC_MSG_RESULT([no]))
 355 fi
 356
 357 AH_BOTTOM([
 358 #ifdef _WIN32
 359 /* Defined to access windows functions and definitions for >=WinXP */
 360 # ifndef WINVER
 361 #  define WINVER 0x0501
 362 # endif
 363
 364 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 365 # ifndef _WIN32_WINNT
 366 #  define _WIN32_WINNT 0x0501
 367 # endif
 368
 369 /* Defined to avoid including some windows headers as part of Windows.h */
 370 # ifndef WIN32_LEAN_AND_MEAN
 371 #  define WIN32_LEAN_AND_MEAN 1
 372 # endif
 373 #endif
 374 ])
 375
 376
 377 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 378
 379 dnl Enable C99 when compiling with MIPSpro
 380 AC_MSG_CHECKING([for MIPSpro compiler])
 381 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 382 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 383 #error
 384   return x(y);
 385 #endif
 386 ])],
 387 bmipspro=false; AC_MSG_RESULT(no),
 388 bmipspro=true; AC_MSG_RESULT(yes))
 389
 390 if test "$bmipspro" = "true"; then
 391   CFLAGS="$CFLAGS -c99"
 392 fi
 393
 394 AC_C_BIGENDIAN
 395
 396 if test "x$enable_rust" = "xyes"; then
 397   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 398   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 399   if test "x$RUSTC" = "xno"; then
 400     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 401   fi
 402
 403   AC_ARG_VAR([CARGO], [path to the cargo binary])
 404   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 405   if test "x$CARGO" = "xno"; then
 406     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 407   fi
 408
 409   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 410   if test "x$enable_cargo_online_mode" = "xyes"; then
 411     CARGO_ONLINE=
 412     RUST_DL=#
 413   else
 414     CARGO_ONLINE=--frozen
 415     RUST_DL=
 416
 417     dnl When we're not allowed to touch the network, we need crate dependencies
 418     dnl locally available.
 419     AC_MSG_CHECKING([rust crate dependencies])
 420     AC_ARG_VAR([RUST_DEPENDENCIES], [path to directory with local crate mirror])
 421     if test "x$RUST_DEPENDENCIES" = "x"; then
 422       RUST_DEPENDENCIES="$srcdir/src/ext/rust/"
 423       NEED_MOD=1
 424     fi
 425     if test ! -d "$RUST_DEPENDENCIES"; then
 426       AC_MSG_ERROR([Rust dependency directory $RUST_DEPENDENCIES does not exist. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 427     fi
 428     for dep in $rust_crates; do
 429       if test ! -d "$RUST_DEPENDENCIES"/"$dep"; then
 430         AC_MSG_ERROR([Failure to find rust dependency $RUST_DEPENDENCIES/$dep. Specify a dependency directory using the RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 431       fi
 432     done
 433     if test "x$NEED_MOD" = "x1"; then
 434       dnl When looking for dependencies from cargo, pick right directory
 435       RUST_DEPENDENCIES="../../src/ext/rust"
 436     fi
 437   fi
 438
 439   dnl This is a workaround for #46797
 440   dnl (a.k.a https://github.com/rust-lang/rust/issues/46797 ).  Once the
 441   dnl upstream bug is fixed, we can remove this workaround.
 442   case "$host_os" in
 443       darwin*)
 444         TOR_RUST_EXTRA_LIBS="-lresolv"
 445         ;;
 446   esac
 447
 448   dnl For now both MSVC and MinGW rust libraries will output static libs with
 449   dnl the MSVC naming convention.
 450   if test "$bwin32" = "true"; then
 451     TOR_RUST_UTIL_STATIC_NAME=tor_util.lib
 452   else
 453     TOR_RUST_UTIL_STATIC_NAME=libtor_util.a
 454   fi
 455
 456   AC_SUBST(TOR_RUST_UTIL_STATIC_NAME)
 457   AC_SUBST(CARGO_ONLINE)
 458   AC_SUBST(RUST_DL)
 459
 460   dnl Let's check the rustc version, too
 461   AC_MSG_CHECKING([rust version])
 462   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 463   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 464   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 465     AC_MSG_ERROR([rustc version couldn't be identified])
 466   fi
 467   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
 468     AC_MSG_ERROR([rustc must be at least version 1.14])
 469   fi
 470 fi
 471
 472 AC_SUBST(TOR_RUST_EXTRA_LIBS)
 473
 474 AC_SEARCH_LIBS(socket, [socket network])
 475 AC_SEARCH_LIBS(gethostbyname, [nsl])
 476 AC_SEARCH_LIBS(dlopen, [dl])
 477 AC_SEARCH_LIBS(inet_aton, [resolv])
 478 AC_SEARCH_LIBS(backtrace, [execinfo])
 479 saved_LIBS="$LIBS"
 480 AC_SEARCH_LIBS([clock_gettime], [rt])
 481 if test "$LIBS" != "$saved_LIBS"; then
 482    # Looks like we need -lrt for clock_gettime().
 483    have_rt=yes
 484 fi
 485
 486 AC_SEARCH_LIBS(pthread_create, [pthread])
 487 AC_SEARCH_LIBS(pthread_detach, [pthread])
 488
 489 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 490 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 491
 492 AC_CHECK_FUNCS(
 493         _NSGetEnviron \
 494         RtlSecureZeroMemory \
 495         SecureZeroMemory \
 496         accept4 \
 497         backtrace \
 498         backtrace_symbols_fd \
 499         eventfd \
 500         explicit_bzero \
 501         timingsafe_memcmp \
 502         flock \
 503         ftime \
 504         get_current_dir_name \
 505         getaddrinfo \
 506         getifaddrs \
 507         getpass \
 508         getrlimit \
 509         gettimeofday \
 510         gmtime_r \
 511         gnu_get_libc_version \
 512         htonll \
 513         inet_aton \
 514         ioctl \
 515         issetugid \
 516         llround \
 517         localtime_r \
 518         lround \
 519         memmem \
 520         memset_s \
 521         pipe \
 522         pipe2 \
 523         prctl \
 524         readpassphrase \
 525         rint \
 526         sigaction \
 527         socketpair \
 528         statvfs \
 529         strlcat \
 530         strlcpy \
 531         strnlen \
 532         strptime \
 533         strtok_r \
 534         strtoull \
 535         sysconf \
 536         sysctl \
 537         truncate \
 538         uname \
 539         usleep \
 540         vasprintf \
 541         _vscprintf
 542 )
 543
 544 # Apple messed up when they added two functions functions in Sierra: they
 545 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 546 # checks. So we should only probe for those functions if we are sure that we
 547 # are not targetting OSX 10.11 or earlier.
 548 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 549 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 550 #ifdef __APPLE__
 551 #  include <AvailabilityMacros.h>
 552 #  ifndef MAC_OS_X_VERSION_10_12
 553 #    define MAC_OS_X_VERSION_10_12 101200
 554 #  endif
 555 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 556 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 557 #      error "Running on Mac OSX 10.11 or earlier"
 558 #    endif
 559 #  endif
 560 #endif
 561 ]], [[]])],
 562    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 563    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 564
 565 if test "$on_macos_pre_10_12" = "no"; then
 566   AC_CHECK_FUNCS(
 567         clock_gettime \
 568         getentropy \
 569   )
 570 fi
 571
 572 if test "$bwin32" != "true"; then
 573   AC_CHECK_HEADERS(pthread.h)
 574   AC_CHECK_FUNCS(pthread_create)
 575   AC_CHECK_FUNCS(pthread_condattr_setclock)
 576 fi
 577
 578 if test "$bwin32" = "true"; then
 579   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 580 #include <windows.h>
 581 #include <conio.h>
 582 #include <wchar.h>
 583                  ])
 584 fi
 585
 586 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 587   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 588
 589 dnl ------------------------------------------------------
 590 dnl Where do you live, libevent?  And how do we call you?
 591
 592 if test "$bwin32" = "true"; then
 593   TOR_LIB_WS32=-lws2_32
 594   TOR_LIB_IPHLPAPI=-liphlpapi
 595   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 596   # think it's actually necessary.
 597   TOR_LIB_GDI=-lgdi32
 598   TOR_LIB_USERENV=-luserenv
 599 else
 600   TOR_LIB_WS32=
 601   TOR_LIB_GDI=
 602   TOR_LIB_USERENV=
 603 fi
 604 AC_SUBST(TOR_LIB_WS32)
 605 AC_SUBST(TOR_LIB_GDI)
 606 AC_SUBST(TOR_LIB_IPHLPAPI)
 607 AC_SUBST(TOR_LIB_USERENV)
 608
 609 tor_libevent_pkg_redhat="libevent"
 610 tor_libevent_pkg_debian="libevent-dev"
 611 tor_libevent_devpkg_redhat="libevent-devel"
 612 tor_libevent_devpkg_debian="libevent-dev"
 613
 614 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 615 dnl linking for static builds.
 616 STATIC_LIBEVENT_FLAGS=""
 617 if test "$enable_static_libevent" = "yes"; then
 618     if test "$have_rt" = "yes"; then
 619       STATIC_LIBEVENT_FLAGS=" -lrt "
 620     fi
 621 fi
 622
 623 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 624 #ifdef _WIN32
 625 #include <winsock2.h>
 626 #endif
 627 #include <sys/time.h>
 628 #include <sys/types.h>
 629 #include <event2/event.h>], [
 630 #ifdef _WIN32
 631 #include <winsock2.h>
 632 #endif
 633 struct event_base;
 634 struct event_base *event_base_new(void);
 635 void event_base_free(struct event_base *);],
 636     [
 637 #ifdef _WIN32
 638 {WSADATA d; WSAStartup(0x101,&d); }
 639 #endif
 640 event_base_free(event_base_new());
 641 ], [--with-libevent-dir], [/opt/libevent])
 642
 643 dnl Determine the incantation needed to link libevent.
 644 save_LIBS="$LIBS"
 645 save_LDFLAGS="$LDFLAGS"
 646 save_CPPFLAGS="$CPPFLAGS"
 647
 648 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 649 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 650 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 651
 652 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 653
 654 if test "$enable_static_libevent" = "yes"; then
 655    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 656      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 657    else
 658      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 659    fi
 660 else
 661      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 662        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 663        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 664
 665        if test "$ac_cv_search_event_new" != "none required"; then
 666          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 667        fi
 668        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 669          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 670        fi
 671      else
 672        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 673      fi
 674 fi
 675
 676 dnl Now check for particular libevent functions.
 677 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 678                 evutil_secure_rng_add_bytes \
 679 ])
 680
 681 LIBS="$save_LIBS"
 682 LDFLAGS="$save_LDFLAGS"
 683 CPPFLAGS="$save_CPPFLAGS"
 684
 685 dnl Check that libevent is at least at version 2.0.10, the first stable
 686 dnl release of its series
 687 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 688 AC_MSG_CHECKING([whether Libevent is new enough])
 689 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 690 #include <event2/event.h>
 691 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 692 #error
 693 int x = y(zz);
 694 #else
 695 int x = 1;
 696 #endif
 697 ])], [ AC_MSG_RESULT([yes]) ],
 698    [ AC_MSG_RESULT([no])
 699      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 700
 701 LIBS="$save_LIBS"
 702 LDFLAGS="$save_LDFLAGS"
 703 CPPFLAGS="$save_CPPFLAGS"
 704
 705 AC_SUBST(TOR_LIBEVENT_LIBS)
 706
 707 dnl ------------------------------------------------------
 708 dnl Where do you live, libm?
 709
 710 dnl On some platforms (Haiku/BeOS) the math library is
 711 dnl part of libroot. In which case don't link against lm
 712 TOR_LIB_MATH=""
 713 save_LIBS="$LIBS"
 714 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 715 if test "$ac_cv_search_pow" != "none required"; then
 716     TOR_LIB_MATH="$ac_cv_search_pow"
 717 fi
 718 LIBS="$save_LIBS"
 719 AC_SUBST(TOR_LIB_MATH)
 720
 721 dnl ------------------------------------------------------
 722 dnl Where do you live, openssl?  And how do we call you?
 723
 724 tor_openssl_pkg_redhat="openssl"
 725 tor_openssl_pkg_debian="libssl-dev"
 726 tor_openssl_devpkg_redhat="openssl-devel"
 727 tor_openssl_devpkg_debian="libssl-dev"
 728
 729 ALT_openssl_WITHVAL=""
 730 AC_ARG_WITH(ssl-dir,
 731   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 732   [
 733       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 734          ALT_openssl_WITHVAL="$withval"
 735       fi
 736   ])
 737
 738 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 739 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 740     [#include <openssl/ssl.h>],
 741     [struct ssl_method_st; const struct ssl_method_st *TLSv1_1_method(void);],
 742     [TLSv1_1_method();], [],
 743     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 744
 745 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 746
 747 if test "$enable_static_openssl" = "yes"; then
 748    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 749      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 750    else
 751      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 752    fi
 753 else
 754      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 755 fi
 756 AC_SUBST(TOR_OPENSSL_LIBS)
 757
 758 dnl Now check for particular openssl functions.
 759 save_LIBS="$LIBS"
 760 save_LDFLAGS="$LDFLAGS"
 761 save_CPPFLAGS="$CPPFLAGS"
 762 LIBS="$TOR_OPENSSL_LIBS $LIBS"
 763 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
 764 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
 765
 766 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 767 #include <openssl/opensslv.h>
 768 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
 769 #error "too old"
 770 #endif
 771    ]], [[]])],
 772    [ : ],
 773    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
 774
 775 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 776 #include <openssl/opensslv.h>
 777 #include <openssl/evp.h>
 778 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
 779 #error "no ECC"
 780 #endif
 781 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
 782 #error "curves unavailable"
 783 #endif
 784    ]], [[]])],
 785    [ : ],
 786    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
 787
 788 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
 789 [#include <openssl/ssl.h>
 790 ])
 791
 792 AC_CHECK_FUNCS([ \
 793                 SSL_SESSION_get_master_key \
 794                 SSL_get_server_random \
 795                 SSL_get_client_ciphers \
 796                 SSL_get_client_random \
 797                 SSL_CIPHER_find \
 798                 TLS_method
 799                ])
 800
 801 dnl Check if OpenSSL has scrypt implementation.
 802 AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
 803
 804 dnl Check if OpenSSL structures are opaque
 805 AC_CHECK_MEMBERS([SSL.state], , ,
 806 [#include <openssl/ssl.h>
 807 ])
 808
 809 dnl Define the set of checks for KIST scheduler support.
 810 AC_DEFUN([CHECK_KIST_SUPPORT],[
 811   dnl KIST needs struct tcp_info and for certain members to exist.
 812   AC_CHECK_MEMBERS(
 813     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
 814     , ,[[#include <netinet/tcp.h>]])
 815   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
 816   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 817                      #include <linux/sockios.h>
 818                      #ifndef SIOCOUTQNSD
 819                      #error
 820                      #endif
 821                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
 822   if test "x$have_siocoutqnsd" = "xyes"; then
 823     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
 824       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
 825         have_kist_support=yes
 826       fi
 827     fi
 828   fi
 829 ])
 830 dnl Now, trigger the check.
 831 CHECK_KIST_SUPPORT
 832 AS_IF([test "x$have_kist_support" = "xyes"],
 833       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
 834                                         on this system])],
 835       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
 836
 837 LIBS="$save_LIBS"
 838 LDFLAGS="$save_LDFLAGS"
 839 CPPFLAGS="$save_CPPFLAGS"
 840
 841 dnl ------------------------------------------------------
 842 dnl Where do you live, zlib?  And how do we call you?
 843
 844 tor_zlib_pkg_redhat="zlib"
 845 tor_zlib_pkg_debian="zlib1g"
 846 tor_zlib_devpkg_redhat="zlib-devel"
 847 tor_zlib_devpkg_debian="zlib1g-dev"
 848
 849 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 850     [#include <zlib.h>],
 851     [const char * zlibVersion(void);],
 852     [zlibVersion();], [--with-zlib-dir],
 853     [/opt/zlib])
 854
 855 if test "$enable_static_zlib" = "yes"; then
 856    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 857      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 858  using --enable-static-zlib")
 859    else
 860      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 861    fi
 862 else
 863      TOR_ZLIB_LIBS="-lz"
 864 fi
 865 AC_SUBST(TOR_ZLIB_LIBS)
 866
 867 dnl ------------------------------------------------------
 868 dnl Where we do we find lzma?
 869
 870 AC_ARG_ENABLE(lzma,
 871       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
 872       [case "${enableval}" in
 873         "yes") lzma=true ;;
 874         "no")  lzma=false ;;
 875         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
 876       esac], [lzma=auto])
 877
 878 if test "x$enable_lzma" = "xno"; then
 879     have_lzma=no;
 880 else
 881     PKG_CHECK_MODULES([LZMA],
 882                       [liblzma],
 883                       have_lzma=yes,
 884                       have_lzma=no)
 885
 886     if test "x$have_lzma" = "xno" ; then
 887         AC_MSG_WARN([Unable to find liblzma.])
 888     fi
 889 fi
 890
 891 if test "x$have_lzma" = "xyes"; then
 892     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
 893     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
 894     TOR_LZMA_LIBS="${LZMA_LIBS}"
 895 fi
 896 AC_SUBST(TOR_LZMA_CFLAGS)
 897 AC_SUBST(TOR_LZMA_LIBS)
 898
 899 dnl ------------------------------------------------------
 900 dnl Where we do we find zstd?
 901
 902 AC_ARG_ENABLE(zstd,
 903       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
 904       [case "${enableval}" in
 905         "yes") zstd=true ;;
 906         "no")  zstd=false ;;
 907         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
 908       esac], [zstd=auto])
 909
 910 if test "x$enable_zstd" = "xno"; then
 911     have_zstd=no;
 912 else
 913     PKG_CHECK_MODULES([ZSTD],
 914                       [libzstd >= 1.1],
 915                       have_zstd=yes,
 916                       have_zstd=no)
 917
 918     if test "x$have_zstd" = "xno" ; then
 919         AC_MSG_WARN([Unable to find libzstd.])
 920     fi
 921 fi
 922
 923 if test "x$have_zstd" = "xyes"; then
 924     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
 925     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
 926     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
 927 fi
 928 AC_SUBST(TOR_ZSTD_CFLAGS)
 929 AC_SUBST(TOR_ZSTD_LIBS)
 930
 931 dnl ----------------------------------------------------------------------
 932 dnl Check if libcap is available for capabilities.
 933
 934 tor_cap_pkg_debian="libcap2"
 935 tor_cap_pkg_redhat="libcap"
 936 tor_cap_devpkg_debian="libcap-dev"
 937 tor_cap_devpkg_redhat="libcap-devel"
 938
 939 AC_CHECK_LIB([cap], [cap_init], [],
 940   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
 941 )
 942 AC_CHECK_FUNCS(cap_set_proc)
 943
 944 dnl ---------------------------------------------------------------------
 945 dnl Now that we know about our major libraries, we can check for compiler
 946 dnl and linker hardening options.  We need to do this with the libraries known,
 947 dnl since sometimes the linker will like an option but not be willing to
 948 dnl use it with a build of a library.
 949
 950 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
 951 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
 952
 953 CFLAGS_FTRAPV=
 954 CFLAGS_FWRAPV=
 955 CFLAGS_ASAN=
 956 CFLAGS_UBSAN=
 957
 958
 959 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 960 #if !defined(__clang__)
 961 #error
 962 #endif])], have_clang=yes, have_clang=no)
 963
 964 if test "x$enable_gcc_hardening" != "xno"; then
 965     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
 966     if test "x$have_clang" = "xyes"; then
 967         TOR_CHECK_CFLAGS(-Qunused-arguments)
 968     fi
 969     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
 970     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
 971     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
 972 m4_ifdef([AS_VAR_IF],[
 973     AS_VAR_IF(can_compile, [yes],
 974         AS_VAR_IF(can_link, [yes],
 975                   [],
 976                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
 977         )])
 978     AS_VAR_POPDEF([can_link])
 979     AS_VAR_POPDEF([can_compile])
 980     TOR_CHECK_CFLAGS(-Wstack-protector)
 981     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
 982     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
 983        TOR_CHECK_CFLAGS(-fPIE)
 984        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
 985     fi
 986     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
 987 fi
 988
 989 if test "$fragile_hardening" = "yes"; then
 990     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
 991    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
 992       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
 993    fi
 994
 995    if test "$tor_cv_cflags__ftrapv" != "yes"; then
 996      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
 997    fi
 998
 999    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
1000     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1001       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
1002     fi
1003
1004    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1005     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1006       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
1007     fi
1008
1009 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1010 fi
1011
1012 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1013 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1014
1015 mulodi_fixes_ftrapv=no
1016 if test "$have_clang" = "yes"; then
1017   saved_CFLAGS="$CFLAGS"
1018   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1019   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1020   AC_LINK_IFELSE([
1021       AC_LANG_SOURCE([[
1022           #include <stdint.h>
1023           #include <stdlib.h>
1024           int main(int argc, char **argv)
1025           {
1026             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1027                         * (int64_t)atoi(argv[3]);
1028             return x == 9;
1029           } ]])],
1030           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1031           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1032   if test "$ftrapv_can_link" = "no"; then
1033     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1034     AC_LINK_IFELSE([
1035       AC_LANG_SOURCE([[
1036           #include <stdint.h>
1037           #include <stdlib.h>
1038           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1039              *overflow=0;
1040              return a;
1041           }
1042           int main(int argc, char **argv)
1043           {
1044             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1045                         * (int64_t)atoi(argv[3]);
1046             return x == 9;
1047           } ]])],
1048           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1049           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1050   fi
1051   CFLAGS="$saved_CFLAGS"
1052 fi
1053
1054 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1055
1056 dnl These cflags add bunches of branches, and we haven't been able to
1057 dnl persuade ourselves that they're suitable for code that needs to be
1058 dnl constant time.
1059 AC_SUBST(CFLAGS_BUGTRAP)
1060 dnl These cflags are variant ones sutable for code that needs to be
1061 dnl constant-time.
1062 AC_SUBST(CFLAGS_CONSTTIME)
1063
1064 if test "x$enable_linker_hardening" != "xno"; then
1065     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1066 fi
1067
1068 # For backtrace support
1069 TOR_CHECK_LDFLAGS(-rdynamic)
1070
1071 dnl ------------------------------------------------------
1072 dnl Now see if we have a -fomit-frame-pointer compiler option.
1073
1074 saved_CFLAGS="$CFLAGS"
1075 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1076 F_OMIT_FRAME_POINTER=''
1077 if test "$saved_CFLAGS" != "$CFLAGS"; then
1078   if test "$fragile_hardening" = "yes"; then
1079     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1080   fi
1081 fi
1082 CFLAGS="$saved_CFLAGS"
1083 AC_SUBST(F_OMIT_FRAME_POINTER)
1084
1085 dnl ------------------------------------------------------
1086 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1087 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1088 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1089 dnl code will work.
1090 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1091
1092 dnl ============================================================
1093 dnl Check for libseccomp
1094
1095 if test "x$enable_seccomp" != "xno"; then
1096   AC_CHECK_HEADERS([seccomp.h])
1097   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1098 fi
1099
1100 dnl ============================================================
1101 dnl Check for libscrypt
1102
1103 if test "x$enable_libscrypt" != "xno"; then
1104   AC_CHECK_HEADERS([libscrypt.h])
1105   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1106   AC_CHECK_FUNCS([libscrypt_scrypt])
1107 fi
1108
1109 dnl ============================================================
1110 dnl We need an implementation of curve25519.
1111
1112 dnl set these defaults.
1113 build_curve25519_donna=no
1114 build_curve25519_donna_c64=no
1115 use_curve25519_donna=no
1116 use_curve25519_nacl=no
1117 CURVE25519_LIBS=
1118
1119 dnl The best choice is using curve25519-donna-c64, but that requires
1120 dnl that we
1121 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1122   tor_cv_can_use_curve25519_donna_c64,
1123   [AC_RUN_IFELSE(
1124     [AC_LANG_PROGRAM([dnl
1125       #include <stdint.h>
1126       typedef unsigned uint128_t __attribute__((mode(TI)));
1127   int func(uint64_t a, uint64_t b) {
1128            uint128_t c = ((uint128_t)a) * b;
1129            int ok = ((uint64_t)(c>>96)) == 522859 &&
1130              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1131                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1132                  (((uint64_t)(c))&0xffffffffL) == 0;
1133            return ok;
1134       }
1135   ], [dnl
1136     int ok = func( ((uint64_t)2000000000) * 1000000000,
1137                    ((uint64_t)1234567890) << 24);
1138         return !ok;
1139       ])],
1140   [tor_cv_can_use_curve25519_donna_c64=yes],
1141       [tor_cv_can_use_curve25519_donna_c64=no],
1142   [AC_LINK_IFELSE(
1143         [AC_LANG_PROGRAM([dnl
1144       #include <stdint.h>
1145       typedef unsigned uint128_t __attribute__((mode(TI)));
1146   int func(uint64_t a, uint64_t b) {
1147            uint128_t c = ((uint128_t)a) * b;
1148            int ok = ((uint64_t)(c>>96)) == 522859 &&
1149              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1150                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1151                  (((uint64_t)(c))&0xffffffffL) == 0;
1152            return ok;
1153       }
1154   ], [dnl
1155     int ok = func( ((uint64_t)2000000000) * 1000000000,
1156                  ((uint64_t)1234567890) << 24);
1157         return !ok;
1158       ])],
1159           [tor_cv_can_use_curve25519_donna_c64=cross],
1160       [tor_cv_can_use_curve25519_donna_c64=no])])])
1161
1162 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1163                   nacl/crypto_scalarmult_curve25519.h])
1164
1165 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1166   tor_cv_can_use_curve25519_nacl,
1167   [tor_saved_LIBS="$LIBS"
1168    LIBS="$LIBS -lnacl"
1169    AC_LINK_IFELSE(
1170      [AC_LANG_PROGRAM([dnl
1171        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1172        #include <crypto_scalarmult_curve25519.h>
1173    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1174    #include <nacl/crypto_scalarmult_curve25519.h>
1175    #endif
1176        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1177    #error Hey, this is the reference implementation! That's not fast.
1178    #endif
1179      ], [
1180    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1181      ])], [tor_cv_can_use_curve25519_nacl=yes],
1182      [tor_cv_can_use_curve25519_nacl=no])
1183    LIBS="$tor_saved_LIBS" ])
1184
1185  dnl Okay, now we need to figure out which one to actually use. Fall back
1186  dnl to curve25519-donna.c
1187
1188  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1189    build_curve25519_donna_c64=yes
1190    use_curve25519_donna=yes
1191  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1192    use_curve25519_nacl=yes
1193    CURVE25519_LIBS=-lnacl
1194  else
1195    build_curve25519_donna=yes
1196    use_curve25519_donna=yes
1197  fi
1198
1199 if test "x$use_curve25519_donna" = "xyes"; then
1200   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1201             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1202 fi
1203 if test "x$use_curve25519_nacl" = "xyes"; then
1204   AC_DEFINE(USE_CURVE25519_NACL, 1,
1205             [Defined if we should use a curve25519 from nacl])
1206 fi
1207 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1208   test "x$build_curve25519_donna" = "xyes")
1209 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1210   test "x$build_curve25519_donna_c64" = "xyes")
1211 AC_SUBST(CURVE25519_LIBS)
1212
1213 dnl Make sure to enable support for large off_t if available.
1214 AC_SYS_LARGEFILE
1215
1216 AC_CHECK_HEADERS([assert.h \
1217                   errno.h \
1218                   fcntl.h \
1219                   signal.h \
1220                   string.h \
1221                   sys/capability.h \
1222                   sys/fcntl.h \
1223                   sys/stat.h \
1224                   sys/time.h \
1225                   sys/types.h \
1226                   time.h \
1227                   unistd.h \
1228                   arpa/inet.h \
1229                   crt_externs.h \
1230                   execinfo.h \
1231                   gnu/libc-version.h \
1232                   grp.h \
1233                   ifaddrs.h \
1234                   inttypes.h \
1235                   limits.h \
1236                   linux/types.h \
1237                   machine/limits.h \
1238                   malloc.h \
1239                   malloc/malloc.h \
1240                   malloc_np.h \
1241                   netdb.h \
1242                   netinet/in.h \
1243                   netinet/in6.h \
1244                   pwd.h \
1245                   readpassphrase.h \
1246                   stdint.h \
1247                   sys/eventfd.h \
1248                   sys/file.h \
1249                   sys/ioctl.h \
1250                   sys/limits.h \
1251                   sys/mman.h \
1252                   sys/param.h \
1253                   sys/prctl.h \
1254                   sys/random.h \
1255                   sys/resource.h \
1256                   sys/select.h \
1257                   sys/socket.h \
1258                   sys/statvfs.h \
1259                   sys/syscall.h \
1260                   sys/sysctl.h \
1261                   sys/syslimits.h \
1262                   sys/time.h \
1263                   sys/types.h \
1264                   sys/un.h \
1265                   sys/utime.h \
1266                   sys/wait.h \
1267                   syslog.h \
1268                   utime.h])
1269
1270 AC_CHECK_HEADERS(sys/param.h)
1271
1272 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1273 [#ifdef HAVE_SYS_TYPES_H
1274 #include <sys/types.h>
1275 #endif
1276 #ifdef HAVE_SYS_SOCKET_H
1277 #include <sys/socket.h>
1278 #endif])
1279 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1280 [#ifdef HAVE_SYS_TYPES_H
1281 #include <sys/types.h>
1282 #endif
1283 #ifdef HAVE_SYS_SOCKET_H
1284 #include <sys/socket.h>
1285 #endif
1286 #ifdef HAVE_NET_IF_H
1287 #include <net/if.h>
1288 #endif
1289 #ifdef HAVE_NETINET_IN_H
1290 #include <netinet/in.h>
1291 #endif])
1292
1293 AC_CHECK_HEADERS(linux/if.h,[],[],
1294 [
1295 #ifdef HAVE_SYS_SOCKET_H
1296 #include <sys/socket.h>
1297 #endif
1298 ])
1299
1300 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1301         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1302 [#ifdef HAVE_SYS_TYPES_H
1303 #include <sys/types.h>
1304 #endif
1305 #ifdef HAVE_SYS_SOCKET_H
1306 #include <sys/socket.h>
1307 #endif
1308 #ifdef HAVE_LIMITS_H
1309 #include <limits.h>
1310 #endif
1311 #ifdef HAVE_LINUX_TYPES_H
1312 #include <linux/types.h>
1313 #endif
1314 #ifdef HAVE_NETINET_IN6_H
1315 #include <netinet/in6.h>
1316 #endif
1317 #ifdef HAVE_NETINET_IN_H
1318 #include <netinet/in.h>
1319 #endif])
1320
1321 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1322         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1323 [#ifdef HAVE_SYS_TYPES_H
1324 #include <sys/types.h>
1325 #endif
1326 #ifdef HAVE_SYS_SOCKET_H
1327 #include <sys/socket.h>
1328 #endif
1329 #ifdef HAVE_LIMITS_H
1330 #include <limits.h>
1331 #endif
1332 #ifdef HAVE_LINUX_TYPES_H
1333 #include <linux/types.h>
1334 #endif
1335 #ifdef HAVE_NETINET_IN6_H
1336 #include <netinet/in6.h>
1337 #endif
1338 #ifdef HAVE_NETINET_IN_H
1339 #include <netinet/in.h>
1340 #endif
1341 #ifdef HAVE_LINUX_IF_H
1342 #include <linux/if.h>
1343 #endif])
1344
1345 transparent_ok=0
1346 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1347   transparent_ok=1
1348 fi
1349 if test "x$linux_netfilter_ipv4" = "x1"; then
1350   transparent_ok=1
1351 fi
1352 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1353   transparent_ok=1
1354 fi
1355 if test "x$transparent_ok" = "x1"; then
1356   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1357 else
1358   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1359 fi
1360
1361 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1362 [#ifdef HAVE_SYS_TYPES_H
1363 #include <sys/types.h>
1364 #endif
1365 #ifdef HAVE_SYS_TIME_H
1366 #include <sys/time.h>
1367 #endif])
1368
1369 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
1370 dnl Watch out.
1371
1372 AC_CHECK_SIZEOF(int8_t)
1373 AC_CHECK_SIZEOF(int16_t)
1374 AC_CHECK_SIZEOF(int32_t)
1375 AC_CHECK_SIZEOF(int64_t)
1376 AC_CHECK_SIZEOF(uint8_t)
1377 AC_CHECK_SIZEOF(uint16_t)
1378 AC_CHECK_SIZEOF(uint32_t)
1379 AC_CHECK_SIZEOF(uint64_t)
1380 AC_CHECK_SIZEOF(intptr_t)
1381 AC_CHECK_SIZEOF(uintptr_t)
1382
1383 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
1384
1385 AC_CHECK_SIZEOF(char)
1386 AC_CHECK_SIZEOF(short)
1387 AC_CHECK_SIZEOF(int)
1388 AC_CHECK_SIZEOF(long)
1389 AC_CHECK_SIZEOF(long long)
1390 AC_CHECK_SIZEOF(__int64)
1391 AC_CHECK_SIZEOF(void *)
1392 AC_CHECK_SIZEOF(time_t)
1393 AC_CHECK_SIZEOF(size_t)
1394 AC_CHECK_SIZEOF(pid_t)
1395
1396 AC_CHECK_TYPES([uint, u_char, ssize_t])
1397
1398 AC_PC_FROM_UCONTEXT([:])
1399
1400 dnl used to include sockaddr_storage, but everybody has that.
1401 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1402 [#ifdef HAVE_SYS_TYPES_H
1403 #include <sys/types.h>
1404 #endif
1405 #ifdef HAVE_NETINET_IN_H
1406 #include <netinet/in.h>
1407 #endif
1408 #ifdef HAVE_NETINET_IN6_H
1409 #include <netinet/in6.h>
1410 #endif
1411 #ifdef HAVE_SYS_SOCKET_H
1412 #include <sys/socket.h>
1413 #endif
1414 #ifdef _WIN32
1415 #define _WIN32_WINNT 0x0501
1416 #define WIN32_LEAN_AND_MEAN
1417 #include <winsock2.h>
1418 #include <ws2tcpip.h>
1419 #endif
1420 ])
1421 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1422 [#ifdef HAVE_SYS_TYPES_H
1423 #include <sys/types.h>
1424 #endif
1425 #ifdef HAVE_NETINET_IN_H
1426 #include <netinet/in.h>
1427 #endif
1428 #ifdef HAVE_NETINET_IN6_H
1429 #include <netinet/in6.h>
1430 #endif
1431 #ifdef HAVE_SYS_SOCKET_H
1432 #include <sys/socket.h>
1433 #endif
1434 #ifdef _WIN32
1435 #define _WIN32_WINNT 0x0501
1436 #define WIN32_LEAN_AND_MEAN
1437 #include <winsock2.h>
1438 #include <ws2tcpip.h>
1439 #endif
1440 ])
1441
1442 AC_CHECK_TYPES([rlim_t], , ,
1443 [#ifdef HAVE_SYS_TYPES_H
1444 #include <sys/types.h>
1445 #endif
1446 #ifdef HAVE_SYS_TIME_H
1447 #include <sys/time.h>
1448 #endif
1449 #ifdef HAVE_SYS_RESOURCE_H
1450 #include <sys/resource.h>
1451 #endif
1452 ])
1453
1454 AX_CHECK_SIGN([time_t],
1455        [ : ],
1456        [ : ], [
1457 #ifdef HAVE_SYS_TYPES_H
1458 #include <sys/types.h>
1459 #endif
1460 #ifdef HAVE_SYS_TIME_H
1461 #include <sys/time.h>
1462 #endif
1463 #ifdef HAVE_TIME_H
1464 #include <time.h>
1465 #endif
1466 ])
1467
1468 if test "$ax_cv_decl_time_t_signed" = "no"; then
1469   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1470 fi
1471
1472 AX_CHECK_SIGN([size_t],
1473        [ tor_cv_size_t_signed=yes ],
1474        [ tor_cv_size_t_signed=no ], [
1475 #ifdef HAVE_SYS_TYPES_H
1476 #include <sys/types.h>
1477 #endif
1478 ])
1479
1480 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1481   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1482 fi
1483
1484 AX_CHECK_SIGN([enum always],
1485        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1486        [ : ], [
1487  enum always { AAA, BBB, CCC };
1488 ])
1489
1490 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1491 #ifdef HAVE_SYS_SOCKET_H
1492 #include <sys/socket.h>
1493 #endif
1494 ])
1495
1496 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1497
1498 AC_CHECK_SIZEOF(cell_t)
1499
1500 # Now make sure that NULL can be represented as zero bytes.
1501 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1502 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1503 [[#include <stdlib.h>
1504 #include <string.h>
1505 #include <stdio.h>
1506 #ifdef HAVE_STDDEF_H
1507 #include <stddef.h>
1508 #endif
1509 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1510 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1511        [tor_cv_null_is_zero=yes],
1512        [tor_cv_null_is_zero=no],
1513        [tor_cv_null_is_zero=cross])])
1514
1515 if test "$tor_cv_null_is_zero" = "cross"; then
1516   # Cross-compiling; let's hope that the target isn't raving mad.
1517   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1518 fi
1519
1520 if test "$tor_cv_null_is_zero" != "no"; then
1521   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1522             [Define to 1 iff memset(0) sets pointers to NULL])
1523 fi
1524
1525 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1526 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1527 [[#include <stdlib.h>
1528 #include <string.h>
1529 #include <stdio.h>
1530 #ifdef HAVE_STDDEF_H
1531 #include <stddef.h>
1532 #endif
1533 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1534 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1535        [tor_cv_dbl0_is_zero=yes],
1536        [tor_cv_dbl0_is_zero=no],
1537        [tor_cv_dbl0_is_zero=cross])])
1538
1539 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1540   # Cross-compiling; let's hope that the target isn't raving mad.
1541   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1542 fi
1543
1544 if test "$tor_cv_dbl0_is_zero" != "no"; then
1545   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1546             [Define to 1 iff memset(0) sets doubles to 0.0])
1547 fi
1548
1549 # And what happens when we malloc zero?
1550 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1551 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1552 [[#include <stdlib.h>
1553 #include <string.h>
1554 #include <stdio.h>
1555 #ifdef HAVE_STDDEF_H
1556 #include <stddef.h>
1557 #endif
1558 int main () { return malloc(0)?0:1; }]])],
1559        [tor_cv_malloc_zero_works=yes],
1560        [tor_cv_malloc_zero_works=no],
1561        [tor_cv_malloc_zero_works=cross])])
1562
1563 if test "$tor_cv_malloc_zero_works" = "cross"; then
1564   # Cross-compiling; let's hope that the target isn't raving mad.
1565   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1566 fi
1567
1568 if test "$tor_cv_malloc_zero_works" = "yes"; then
1569   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1570             [Define to 1 iff malloc(0) returns a pointer])
1571 fi
1572
1573 # whether we seem to be in a 2s-complement world.
1574 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1575 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1576 [[int main () { int problem = ((-99) != (~99)+1);
1577 return problem ? 1 : 0; }]])],
1578        [tor_cv_twos_complement=yes],
1579        [tor_cv_twos_complement=no],
1580        [tor_cv_twos_complement=cross])])
1581
1582 if test "$tor_cv_twos_complement" = "cross"; then
1583   # Cross-compiling; let's hope that the target isn't raving mad.
1584   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1585 fi
1586
1587 if test "$tor_cv_twos_complement" != "no"; then
1588   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1589             [Define to 1 iff we represent negative integers with
1590              two's complement])
1591 fi
1592
1593 # What does shifting a negative value do?
1594 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1595 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1596 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1597        [tor_cv_sign_extend=yes],
1598        [tor_cv_sign_extend=no],
1599        [tor_cv_sign_extend=cross])])
1600
1601 if test "$tor_cv_sign_extend" = "cross"; then
1602   # Cross-compiling; let's hope that the target isn't raving mad.
1603   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1604 fi
1605
1606 if test "$tor_cv_sign_extend" != "no"; then
1607   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1608             [Define to 1 iff right-shifting a negative value performs sign-extension])
1609 fi
1610
1611 # Is uint8_t the same type as unsigned char?
1612 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1613 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1614 #include <stdint.h>
1615 extern uint8_t c;
1616 unsigned char c;]])],
1617        [tor_cv_uint8_uchar=yes],
1618        [tor_cv_uint8_uchar=no],
1619        [tor_cv_uint8_uchar=cross])])
1620
1621 if test "$tor_cv_uint8_uchar" = "cross"; then
1622   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1623 fi
1624
1625 if test "$tor_cv_uint8_uchar" = "no"; then
1626   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1627 fi
1628
1629 # Whether we should use the dmalloc memory allocation debugging library.
1630 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
1631 AC_ARG_WITH(dmalloc,
1632 AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
1633 [if [[ "$withval" = "yes" ]]; then
1634   dmalloc=1
1635   AC_MSG_RESULT(yes)
1636 else
1637   dmalloc=1
1638   AC_MSG_RESULT(no)
1639 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
1640 )
1641
1642 if [[ $dmalloc -eq 1 ]]; then
1643   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
1644   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
1645   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
1646   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
1647 fi
1648
1649 AC_ARG_WITH(tcmalloc,
1650 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
1651 [ tcmalloc=yes ], [ tcmalloc=no ])
1652
1653 if test "x$tcmalloc" = "xyes"; then
1654    LDFLAGS="-ltcmalloc $LDFLAGS"
1655 fi
1656
1657 using_custom_malloc=no
1658 if test "x$enable_openbsd_malloc" = "xyes"; then
1659    using_custom_malloc=yes
1660 fi
1661 if test "x$tcmalloc" = "xyes"; then
1662    using_custom_malloc=yes
1663 fi
1664 if test "$using_custom_malloc" = "no"; then
1665    AC_CHECK_FUNCS(mallinfo)
1666 fi
1667
1668 # By default, we're going to assume we don't have mlockall()
1669 # bionic and other platforms have various broken mlockall subsystems.
1670 # Some systems don't have a working mlockall, some aren't linkable,
1671 # and some have it but don't declare it.
1672 AC_CHECK_FUNCS(mlockall)
1673 AC_CHECK_DECLS([mlockall], , , [
1674 #ifdef HAVE_SYS_MMAN_H
1675 #include <sys/mman.h>
1676 #endif])
1677
1678 # Some MinGW environments don't have getpagesize in unistd.h. We don't use
1679 # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
1680 # using macros
1681 AC_CHECK_DECLS([getpagesize], , , [
1682 #ifdef HAVE_UNISTD_H
1683 #include <unistd.h>
1684 #endif])
1685
1686 # Allow user to specify an alternate syslog facility
1687 AC_ARG_WITH(syslog-facility,
1688 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
1689 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
1690 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
1691 AC_SUBST(LOGFACILITY)
1692
1693 # Check if we have getresuid and getresgid
1694 AC_CHECK_FUNCS(getresuid getresgid)
1695
1696 # Check for gethostbyname_r in all its glorious incompatible versions.
1697 #   (This logic is based on that in Python's configure.in)
1698 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
1699   [Define this if you have any gethostbyname_r()])
1700
1701 AC_CHECK_FUNC(gethostbyname_r, [
1702   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
1703   OLD_CFLAGS=$CFLAGS
1704   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
1705   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1706 #include <netdb.h>
1707   ]], [[
1708     char *cp1, *cp2;
1709     struct hostent *h1, *h2;
1710     int i1, i2;
1711     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
1712   ]])],[
1713     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1714     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
1715      [Define this if gethostbyname_r takes 6 arguments])
1716     AC_MSG_RESULT(6)
1717   ], [
1718     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1719 #include <netdb.h>
1720     ]], [[
1721       char *cp1, *cp2;
1722       struct hostent *h1;
1723       int i1, i2;
1724       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
1725     ]])], [
1726       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1727       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
1728         [Define this if gethostbyname_r takes 5 arguments])
1729       AC_MSG_RESULT(5)
1730    ], [
1731       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1732 #include <netdb.h>
1733      ]], [[
1734        char *cp1;
1735        struct hostent *h1;
1736        struct hostent_data hd;
1737        (void) gethostbyname_r(cp1,h1,&hd);
1738      ]])], [
1739        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
1740        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
1741          [Define this if gethostbyname_r takes 3 arguments])
1742        AC_MSG_RESULT(3)
1743      ], [
1744        AC_MSG_RESULT(0)
1745      ])
1746   ])
1747  ])
1748  CFLAGS=$OLD_CFLAGS
1749 ])
1750
1751 AC_CACHE_CHECK([whether the C compiler supports __func__],
1752   tor_cv_have_func_macro,
1753   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1754 #include <stdio.h>
1755 int main(int c, char **v) { puts(__func__); }])],
1756   tor_cv_have_func_macro=yes,
1757   tor_cv_have_func_macro=no))
1758
1759 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
1760   tor_cv_have_FUNC_macro,
1761   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1762 #include <stdio.h>
1763 int main(int c, char **v) { puts(__FUNC__); }])],
1764   tor_cv_have_FUNC_macro=yes,
1765   tor_cv_have_FUNC_macro=no))
1766
1767 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
1768   tor_cv_have_FUNCTION_macro,
1769   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1770 #include <stdio.h>
1771 int main(int c, char **v) { puts(__FUNCTION__); }])],
1772   tor_cv_have_FUNCTION_macro=yes,
1773   tor_cv_have_FUNCTION_macro=no))
1774
1775 AC_CACHE_CHECK([whether we have extern char **environ already declared],
1776   tor_cv_have_environ_declared,
1777   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1778 #ifdef HAVE_UNISTD_H
1779 #include <unistd.h>
1780 #endif
1781 #include <stdlib.h>
1782 int main(int c, char **v) { char **t = environ; }])],
1783   tor_cv_have_environ_declared=yes,
1784   tor_cv_have_environ_declared=no))
1785
1786 if test "$tor_cv_have_func_macro" = "yes"; then
1787   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
1788 fi
1789
1790 if test "$tor_cv_have_FUNC_macro" = "yes"; then
1791   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
1792 fi
1793
1794 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
1795   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
1796            [Defined if the compiler supports __FUNCTION__])
1797 fi
1798
1799 if test "$tor_cv_have_environ_declared" = "yes"; then
1800   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
1801            [Defined if we have extern char **environ already declared])
1802 fi
1803
1804 # $prefix stores the value of the --prefix command line option, or
1805 # NONE if the option wasn't set.  In the case that it wasn't set, make
1806 # it be the default, so that we can use it to expand directories now.
1807 if test "x$prefix" = "xNONE"; then
1808   prefix=$ac_default_prefix
1809 fi
1810
1811 # and similarly for $exec_prefix
1812 if test "x$exec_prefix" = "xNONE"; then
1813   exec_prefix=$prefix
1814 fi
1815
1816 if test "x$BUILDDIR" = "x"; then
1817   BUILDDIR=`pwd`
1818 fi
1819 AC_SUBST(BUILDDIR)
1820 AH_TEMPLATE([BUILDDIR],[tor's build directory])
1821 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
1822
1823 if test "x$CONFDIR" = "x"; then
1824   CONFDIR=`eval echo $sysconfdir/tor`
1825 fi
1826 AC_SUBST(CONFDIR)
1827 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
1828 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
1829
1830 BINDIR=`eval echo $bindir`
1831 AC_SUBST(BINDIR)
1832 LOCALSTATEDIR=`eval echo $localstatedir`
1833 AC_SUBST(LOCALSTATEDIR)
1834
1835 if test "$bwin32" = "true"; then
1836   # Test if the linker supports the --nxcompat and --dynamicbase options
1837   # for Windows
1838   save_LDFLAGS="$LDFLAGS"
1839   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
1840   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
1841   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
1842     [AC_MSG_RESULT([yes])]
1843     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
1844     [AC_MSG_RESULT([no])]
1845   )
1846   LDFLAGS="$save_LDFLAGS"
1847 fi
1848
1849 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
1850 # than autoconf's macros like.
1851 if test "$GCC" = "yes"; then
1852   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
1853   # accident waiting to happen.
1854   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
1855 else
1856   # Override optimization level for non-gcc compilers
1857   CFLAGS="$CFLAGS -O"
1858   enable_gcc_warnings=no
1859   enable_gcc_warnings_advisory=no
1860 fi
1861
1862 # Warnings implies advisory-warnings and -Werror.
1863 if test "$enable_gcc_warnings" = "yes"; then
1864   enable_gcc_warnings_advisory=yes
1865   enable_fatal_warnings=yes
1866 fi
1867
1868 # OS X Lion started deprecating the system openssl. Let's just disable
1869 # all deprecation warnings on OS X. Also, to potentially make the binary
1870 # a little smaller, let's enable dead_strip.
1871 case "$host_os" in
1872
1873  darwin*)
1874     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
1875     LDFLAGS="$LDFLAGS -dead_strip" ;;
1876 esac
1877
1878 # Add some more warnings which we use in development but not in the
1879 # released versions.  (Some relevant gcc versions can't handle these.)
1880 #
1881 # Note that we have to do this near the end  of the autoconf process, or
1882 # else we may run into problems when these warnings hit on the testing C
1883 # programs that autoconf wants to build.
1884 if test "x$enable_gcc_warnings_advisory" != "xno"; then
1885
1886   case "$host" in
1887     *-*-openbsd* | *-*-bitrig*)
1888       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
1889       # That's fine, except that the headers don't pass -Wredundant-decls.
1890       # Therefore, let's disable -Wsystem-headers when we're building
1891       # with maximal warnings on OpenBSD.
1892       CFLAGS="$CFLAGS -Wno-system-headers" ;;
1893   esac
1894
1895   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
1896   # have it work better.
1897   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
1898
1899   # This warning was added in gcc 4.3, but it appears to generate
1900   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
1901   #CFLAGS="$CFLAGS -Wlogical-op"
1902
1903   m4_foreach_w([warning_flag], [
1904      -Waddress
1905      -Waddress-of-array-temporary
1906      -Waddress-of-temporary
1907      -Wambiguous-macro
1908      -Wanonymous-pack-parens
1909      -Warc
1910      -Warc-abi
1911      -Warc-bridge-casts-disallowed-in-nonarc
1912      -Warc-maybe-repeated-use-of-weak
1913      -Warc-performSelector-leaks
1914      -Warc-repeated-use-of-weak
1915      -Warray-bounds
1916      -Warray-bounds-pointer-arithmetic
1917      -Wasm
1918      -Wasm-operand-widths
1919      -Watomic-properties
1920      -Watomic-property-with-user-defined-accessor
1921      -Wauto-import
1922      -Wauto-storage-class
1923      -Wauto-var-id
1924      -Wavailability
1925      -Wbackslash-newline-escape
1926      -Wbad-array-new-length
1927      -Wbind-to-temporary-copy
1928      -Wbitfield-constant-conversion
1929      -Wbool-conversion
1930      -Wbool-conversions
1931      -Wbuiltin-requires-header
1932      -Wchar-align
1933      -Wcompare-distinct-pointer-types
1934      -Wcomplex-component-init
1935      -Wconditional-type-mismatch
1936      -Wconfig-macros
1937      -Wconstant-conversion
1938      -Wconstant-logical-operand
1939      -Wconstexpr-not-const
1940      -Wcustom-atomic-properties
1941      -Wdangling-field
1942      -Wdangling-initializer-list
1943      -Wdate-time
1944      -Wdelegating-ctor-cycles
1945      -Wdeprecated-implementations
1946      -Wdeprecated-register
1947      -Wdirect-ivar-access
1948      -Wdiscard-qual
1949      -Wdistributed-object-modifiers
1950      -Wdivision-by-zero
1951      -Wdollar-in-identifier-extension
1952      -Wdouble-promotion
1953      -Wduplicate-decl-specifier
1954      -Wduplicate-enum
1955      -Wduplicate-method-arg
1956      -Wduplicate-method-match
1957      -Wduplicated-cond
1958      -Wdynamic-class-memaccess
1959      -Wembedded-directive
1960      -Wempty-translation-unit
1961      -Wenum-conversion
1962      -Wexit-time-destructors
1963      -Wexplicit-ownership-type
1964      -Wextern-initializer
1965      -Wextra
1966      -Wextra-semi
1967      -Wextra-tokens
1968      -Wflexible-array-extensions
1969      -Wfloat-conversion
1970      -Wformat-non-iso
1971      -Wfour-char-constants
1972      -Wgcc-compat
1973      -Wglobal-constructors
1974      -Wgnu-array-member-paren-init
1975      -Wgnu-designator
1976      -Wgnu-static-float-init
1977      -Wheader-guard
1978      -Wheader-hygiene
1979      -Widiomatic-parentheses
1980      -Wignored-attributes
1981      -Wimplicit-atomic-properties
1982      -Wimplicit-conversion-floating-point-to-bool
1983      -Wimplicit-exception-spec-mismatch
1984      -Wimplicit-fallthrough
1985      -Wimplicit-fallthrough-per-function
1986      -Wimplicit-retain-self
1987      -Wimport-preprocessor-directive-pedantic
1988      -Wincompatible-library-redeclaration
1989      -Wincompatible-pointer-types-discards-qualifiers
1990      -Wincomplete-implementation
1991      -Wincomplete-module
1992      -Wincomplete-umbrella
1993      -Winit-self
1994      -Wint-conversions
1995      -Wint-to-void-pointer-cast
1996      -Winteger-overflow
1997      -Winvalid-constexpr
1998      -Winvalid-iboutlet
1999      -Winvalid-noreturn
2000      -Winvalid-pp-token
2001      -Winvalid-source-encoding
2002      -Winvalid-token-paste
2003      -Wknr-promoted-parameter
2004      -Wlanguage-extension-token
2005      -Wlarge-by-value-copy
2006      -Wliteral-conversion
2007      -Wliteral-range
2008      -Wlocal-type-template-args
2009      -Wlogical-op
2010      -Wloop-analysis
2011      -Wmain-return-type
2012      -Wmalformed-warning-check
2013      -Wmethod-signatures
2014      -Wmicrosoft
2015      -Wmicrosoft-exists
2016      -Wmismatched-parameter-types
2017      -Wmismatched-return-types
2018      -Wmissing-field-initializers
2019      -Wmissing-format-attribute
2020      -Wmissing-noreturn
2021      -Wmissing-selector-name
2022      -Wmissing-sysroot
2023      -Wmissing-variable-declarations
2024      -Wmodule-conflict
2025      -Wnested-anon-types
2026      -Wnewline-eof
2027      -Wnon-literal-null-conversion
2028      -Wnon-pod-varargs
2029      -Wnonportable-cfstrings
2030      -Wnormalized=id
2031      -Wnull-arithmetic
2032      -Wnull-character
2033      -Wnull-conversion
2034      -Wnull-dereference
2035      -Wout-of-line-declaration
2036      -Wover-aligned
2037      -Woverlength-strings
2038      -Woverride-init
2039      -Woverriding-method-mismatch
2040      -Wpointer-type-mismatch
2041      -Wpredefined-identifier-outside-function
2042      -Wprotocol-property-synthesis-ambiguity
2043      -Wreadonly-iboutlet-property
2044      -Wreadonly-setter-attrs
2045      -Wreceiver-expr
2046      -Wreceiver-forward-class
2047      -Wreceiver-is-weak
2048      -Wreinterpret-base-class
2049      -Wrequires-super-attribute
2050      -Wreserved-user-defined-literal
2051      -Wreturn-stack-address
2052      -Wsection
2053      -Wselector-type-mismatch
2054      -Wsentinel
2055      -Wserialized-diagnostics
2056      -Wshadow
2057      -Wshift-count-negative
2058      -Wshift-count-overflow
2059      -Wshift-negative-value
2060      -Wshift-overflow=2
2061      -Wshift-sign-overflow
2062      -Wshorten-64-to-32
2063      -Wsizeof-array-argument
2064      -Wsource-uses-openmp
2065      -Wstatic-float-init
2066      -Wstatic-in-inline
2067      -Wstatic-local-in-inline
2068      -Wstrict-overflow=1
2069      -Wstring-compare
2070      -Wstring-conversion
2071      -Wstrlcpy-strlcat-size
2072      -Wstrncat-size
2073      -Wsuggest-attribute=format
2074      -Wsuggest-attribute=noreturn
2075      -Wsuper-class-method-mismatch
2076      -Wswitch-bool
2077      -Wsync-nand
2078      -Wtautological-constant-out-of-range-compare
2079      -Wtentative-definition-incomplete-type
2080      -Wtrampolines
2081      -Wtype-safety
2082      -Wtypedef-redefinition
2083      -Wtypename-missing
2084      -Wundefined-inline
2085      -Wundefined-internal
2086      -Wundefined-reinterpret-cast
2087      -Wunicode
2088      -Wunicode-whitespace
2089      -Wunknown-warning-option
2090      -Wunnamed-type-template-args
2091      -Wunneeded-member-function
2092      -Wunsequenced
2093      -Wunsupported-visibility
2094      -Wunused-but-set-parameter
2095      -Wunused-but-set-variable
2096      -Wunused-command-line-argument
2097      -Wunused-const-variable=2
2098      -Wunused-exception-parameter
2099      -Wunused-local-typedefs
2100      -Wunused-member-function
2101      -Wunused-sanitize-argument
2102      -Wunused-volatile-lvalue
2103      -Wuser-defined-literals
2104      -Wvariadic-macros
2105      -Wvector-conversion
2106      -Wvector-conversions
2107      -Wvexing-parse
2108      -Wvisibility
2109      -Wvla-extension
2110      -Wzero-length-array
2111   ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
2112
2113 dnl    We should re-enable this in some later version.  Clang doesn't
2114 dnl    mind, but it causes trouble with GCC.
2115 dnl     -Wstrict-overflow=2
2116
2117 dnl    These seem to require annotations that we don't currently use,
2118 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2119 dnl     -Wthread-safety
2120 dnl     -Wthread-safety-analysis
2121 dnl     -Wthread-safety-attributes
2122 dnl     -Wthread-safety-beta
2123 dnl     -Wthread-safety-precise
2124
2125   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2126   CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2127   CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2128   CFLAGS="$CFLAGS -Wwrite-strings"
2129   CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2130   CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
2131   CFLAGS="$CFLAGS -Wunused-parameter "
2132   # These interfere with building main() { return 0; }, which autoconf
2133   # likes to use as its default program.
2134   CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
2135
2136   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2137     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2138   fi
2139   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2140     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2141   fi
2142
2143   if test "x$enable_fatal_warnings" = "xyes"; then
2144     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2145     # default autoconf programs are full of errors.
2146     CFLAGS="$CFLAGS -Werror"
2147   fi
2148
2149 fi
2150
2151 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2152    case "$host_os" in
2153     darwin*)
2154       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2155    esac
2156 fi
2157
2158 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2159
2160 AC_CONFIG_FILES([
2161         Doxyfile
2162         Makefile
2163         contrib/dist/suse/tor.sh
2164         contrib/operator-tools/tor.logrotate
2165         contrib/dist/tor.sh
2166         contrib/dist/torctl
2167         contrib/dist/tor.service
2168         src/config/torrc.sample
2169         src/config/torrc.minimal
2170         src/rust/.cargo/config
2171         scripts/maint/checkOptionDocs.pl
2172         scripts/maint/updateVersions.pl
2173 ])
2174
2175 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2176   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2177   for file in $regular_mans ; do
2178     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2179       echo "==================================";
2180       echo;
2181       echo "Building Tor has failed since manpages cannot be built.";
2182       echo;
2183       echo "You need asciidoc installed to be able to build the manpages.";
2184       echo "To build without manpages, use the --disable-asciidoc argument";
2185       echo "when calling configure.";
2186       echo;
2187       echo "==================================";
2188       exit 1;
2189     fi
2190   done
2191 fi
2192
2193 if test "$fragile_hardening" = "yes"; then
2194   AC_MSG_WARN([
2195
2196 ============
2197 Warning!  Building Tor with --enable-fragile-hardening (also known as
2198 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2199 other kinds of attacks easier. A Tor instance build with this option will be
2200 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2201 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2202 denial of service attacks. For more information, see
2203 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2204 ============
2205   ])
2206 fi
2207
2208 AC_OUTPUT