configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2007, Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.0.6-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  17 # the += operator on it in src/or/Makefile.am
  18 CPPFLAGS="$CPPFLAGS -I../common"
  19
  20 AC_ARG_ENABLE(debug,
  21  AS_HELP_STRING(--enable-debug, compile with debugging info),
  22 [if test x$enableval = xyes; then
  23     CFLAGS="$CFLAGS -g"
  24 fi])
  25
  26 AC_ARG_ENABLE(cell-pool,
  27      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  28
  29 if test x$enable_cell_pool != xno; then
  30   AC_DEFINE(ENABLE_CELL_POOL, 1,
  31             [Defined if we try to use the pool allocator for queued cells])
  32 fi
  33
  34 AC_ARG_ENABLE(transparent,
  35      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  36      [case "${enableval}" in
  37         yes) transparent=true ;;
  38         no)  transparent=false ;;
  39         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  40       esac], [transparent=true])
  41
  42 AC_ARG_ENABLE(threads,
  43      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  44
  45 if test x$enable_threads = x; then
  46    case $host in
  47     *-*-solaris* )
  48      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  49      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  50 cpu workers lock up here, so I will disable threads.])
  51      enable_threads="no";;
  52     *)
  53      enable_threads="yes";;
  54    esac
  55 fi
  56
  57 if test $enable_threads = "yes"; then
  58   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  59 fi
  60
  61 case $host in
  62    *-*-solaris* )
  63      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  64      ;;
  65 esac
  66
  67 AC_ARG_ENABLE(gcc-warnings,
  68      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  69
  70 AC_PROG_CC
  71 AC_PROG_MAKE_SET
  72 AC_PROG_RANLIB
  73
  74 TORUSER=_tor
  75 AC_ARG_WITH(tor-user,
  76         [  --with-tor-user=NAME    Specify username for tor daemon ],
  77         [
  78            TORUSER=$withval
  79         ]
  80 )
  81 AC_SUBST(TORUSER)
  82
  83 TORGROUP=_tor
  84 AC_ARG_WITH(tor-group,
  85         [  --with-tor-group=NAME   Specify group name for tor daemon ],
  86         [
  87            TORGROUP=$withval
  88         ]
  89 )
  90 AC_SUBST(TORGROUP)
  91
  92
  93 dnl If WIN32 is defined and non-zero, we are building for win32
  94 AC_MSG_CHECKING([for win32])
  95 AC_RUN_IFELSE([
  96 int main(int c, char **v) {
  97 #ifdef WIN32
  98 #if WIN32
  99   return 0;
 100 #else
 101   return 1;
 102 #endif
 103 #else
 104   return 2;
 105 #endif
 106 }],
 107 bwin32=true; AC_MSG_RESULT([yes]),
 108 bwin32=false; AC_MSG_RESULT([no]),
 109 bwin32=cross; AC_MSG_RESULT([cross])
 110 )
 111
 112 if test $bwin32 = cross; then
 113 AC_MSG_CHECKING([for win32 (cross)])
 114 AC_COMPILE_IFELSE([
 115 #ifdef WIN32
 116 int main(int c, char **v) {return 0;}
 117 #else
 118 #error
 119 int main(int c, char **v) {return x(y);}
 120 #endif
 121 ],
 122 bwin32=true; AC_MSG_RESULT([yes]),
 123 bwin32=false; AC_MSG_RESULT([no]))
 124 fi
 125
 126 if test $bwin32 = true; then
 127 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 128 fi
 129 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 130
 131 dnl Enable C99 when compiling with MIPSpro
 132 AC_MSG_CHECKING([for MIPSpro compiler])
 133 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 134 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 135 #error
 136   return x(y);
 137 #endif
 138 ]),
 139 bmipspro=false; AC_MSG_RESULT(no),
 140 bmipspro=true; AC_MSG_RESULT(yes))
 141
 142 if test $bmipspro = true; then
 143   CFLAGS="$CFLAGS -c99"
 144 fi
 145
 146 AC_SEARCH_LIBS(socket, [socket])
 147 AC_SEARCH_LIBS(gethostbyname, [nsl])
 148 AC_SEARCH_LIBS(dlopen, [dl])
 149 AC_SEARCH_LIBS(inet_aton, [resolv])
 150
 151 if test $enable_threads = "yes"; then
 152   AC_SEARCH_LIBS(pthread_create, [pthread])
 153   AC_SEARCH_LIBS(pthread_detach, [pthread])
 154 fi
 155
 156 dnl -------------------------------------------------------------------
 157 dnl Check for functions before libevent, since libevent-1.2 apparently
 158 dnl exports strlcpy without defining it in a header.
 159
 160 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop mallinfo)
 161
 162 if test $enable_threads = "yes"; then
 163   AC_CHECK_HEADERS(pthread.h)
 164   AC_CHECK_FUNCS(pthread_create)
 165 fi
 166
 167 dnl ------------------------------------------------------
 168 dnl Where do you live, libevent?  And how do we call you?
 169
 170 if test $bwin32 = true; then
 171   TOR_LIB_WS32=-lws2_32
 172   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 173   # think it's actually necessary.
 174   TOR_LIB_GDI=-lgdi32
 175 else
 176   TOR_LIB_WS32=
 177   TOR_LIB_GDI=
 178 fi
 179 AC_SUBST(TOR_LIB_WS32)
 180 AC_SUBST(TOR_LIB_GDI)
 181
 182 dnl This is a disgusting hack so we safely include recent libevent headers.
 183 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 184 AC_CHECK_TYPE(u_int32_t, unsigned long)
 185 AC_CHECK_TYPE(u_int16_t, unsigned short)
 186 AC_CHECK_TYPE(u_int8_t, unsigned char)
 187
 188 tor_libevent_pkg_redhat="libevent"
 189 tor_libevent_pkg_debian="libevent-dev"
 190 tor_libevent_devpkg_redhat="libevent-devel"
 191 tor_libevent_devpkg_debian="libevent-dev"
 192
 193 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 194 #include <stdlib.h>
 195 #include <sys/time.h>
 196 #include <sys/types.h>
 197 #include <event.h>], [void exit(int); void *event_init(void);],
 198     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 199
 200 dnl Now check for particular libevent functions.
 201 save_LIBS="$LIBS"
 202 save_LDFLAGS="$LDFLAGS"
 203 save_CPPFLAGS="$CPPFLAGS"
 204 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 205 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 206 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 207 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 208 LIBS="$save_LIBS"
 209 LDFLAGS="$save_LDFLAGS"
 210 CPPFLAGS="$save_CPPFLAGS"
 211
 212 dnl ------------------------------------------------------
 213 dnl Where do you live, openssl?  And how do we call you?
 214
 215 tor_openssl_pkg_redhat="openssl"
 216 tor_openssl_pkg_debian="libssl"
 217 tor_openssl_devpkg_redhat="openssl-devel"
 218 tor_openssl_devpkg_debian="libssl-dev"
 219
 220 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 221     [#include <openssl/rand.h>],
 222     [void RAND_add(const void *buf, int num, double entropy);],
 223     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 224     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 225
 226 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 227
 228 dnl ------------------------------------------------------
 229 dnl Where do you live, zlib?  And how do we call you?
 230
 231 tor_openssl_pkg_redhat="zlib"
 232 tor_openssl_pkg_debian="zlib1g"
 233 tor_openssl_devpkg_redhat="zlib-devel"
 234 tor_openssl_devpkg_debian="zlib1g-dev"
 235
 236 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 237     [#include <zlib.h>],
 238     [const char * zlibVersion(void);],
 239     [zlibVersion(); exit(0);], [--with-zlib-dir],
 240     [/opt/zlib])
 241
 242 dnl Make sure to enable support for large off_t if avalable.
 243
 244 AC_SYS_LARGEFILE
 245
 246 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 247
 248 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 249
 250 dnl These headers are not essential
 251
 252 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h)
 253
 254 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 255 [#ifdef HAVE_SYS_TYPES_H
 256 #include <sys/types.h>
 257 #endif
 258 #ifdef HAVE_SYS_SOCKET_H
 259 #include <sys/socket.h>
 260 #endif])
 261 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 262 [#ifdef HAVE_SYS_TYPES_H
 263 #include <sys/types.h>
 264 #endif
 265 #ifdef HAVE_SYS_SOCKET_H
 266 #include <sys/socket.h>
 267 #endif
 268 #ifdef HAVE_NET_IF_H
 269 #include <net/if.h>
 270 #endif])
 271 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 272         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 273 [#ifdef HAVE_SYS_TYPES_H
 274 #include <sys/types.h>
 275 #endif
 276 #ifdef HAVE_SYS_SOCKET_H
 277 #include <sys/socket.h>
 278 #endif])
 279
 280 if test x$transparent = xtrue ; then
 281    transparent_ok=0
 282    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 283      transparent_ok=1
 284    fi
 285    if test x$linux_netfilter_ipv4 = x1 ; then
 286      transparent_ok=1
 287    fi
 288    if test x$transparent_ok = x1 ; then
 289      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 290      case $host in
 291        *-*-openbsd*)
 292          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 293      esac
 294    else
 295      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 296    fi
 297 fi
 298
 299 AC_FUNC_FSEEKO
 300
 301 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 302 [#ifdef HAVE_SYS_TYPES_H
 303 #include <sys/types.h>
 304 #endif
 305 #ifdef HAVE_SYS_TIME_H
 306 #include <sys/time.h>
 307 #endif])
 308
 309 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 310 dnl Watch out.
 311
 312 AC_CHECK_SIZEOF(int8_t)
 313 AC_CHECK_SIZEOF(int16_t)
 314 AC_CHECK_SIZEOF(int32_t)
 315 AC_CHECK_SIZEOF(int64_t)
 316 AC_CHECK_SIZEOF(uint8_t)
 317 AC_CHECK_SIZEOF(uint16_t)
 318 AC_CHECK_SIZEOF(uint32_t)
 319 AC_CHECK_SIZEOF(uint64_t)
 320 AC_CHECK_SIZEOF(intptr_t)
 321 AC_CHECK_SIZEOF(uintptr_t)
 322
 323 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 324
 325 AC_CHECK_SIZEOF(char)
 326 AC_CHECK_SIZEOF(short)
 327 AC_CHECK_SIZEOF(int)
 328 AC_CHECK_SIZEOF(long)
 329 AC_CHECK_SIZEOF(long long)
 330 AC_CHECK_SIZEOF(__int64)
 331 AC_CHECK_SIZEOF(void *)
 332 AC_CHECK_SIZEOF(time_t)
 333 AC_CHECK_SIZEOF(size_t)
 334
 335 AC_CHECK_TYPES([uint, u_char])
 336
 337 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 338 [#ifdef HAVE_SYS_TYPES_H
 339 #include <sys/types.h>
 340 #endif
 341 #ifdef HAVE_NETINET_IN_H
 342 #include <netinet/in.h>
 343 #endif
 344 #ifdef HAVE_NETINET_IN6_H
 345 #include <netinet/in6.h>
 346 #endif
 347 #ifdef HAVE_SYS_SOCKET_H
 348 #include <sys/socket.h>
 349 #endif
 350 #ifdef MS_WINDOWS
 351 #define WIN32_WINNT 0x400
 352 #define _WIN32_WINNT 0x400
 353 #define WIN32_LEAN_AND_MEAN
 354 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 355 #include <winsock.h>
 356 #else
 357 #include <winsock2.h>
 358 #include <ws2tcpip.h>
 359 #endif
 360 #endif
 361 ])
 362
 363 if test -z "$CROSS_COMPILE"; then
 364 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 365 AC_RUN_IFELSE(AC_LANG_SOURCE([
 366 #ifdef HAVE_SYS_TYPES_H
 367 #include <sys/types.h>
 368 #endif
 369 #ifdef HAVE_SYS_TIME_H
 370 #include <sys/time.h>
 371 #endif
 372 #ifdef HAVE_TIME_H
 373 #include <time.h>
 374 #endif
 375 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 376   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes)
 377 ])
 378 else
 379   # Cross-compiling; let's hope the target platform isn't loony.
 380   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 381   tor_cv_time_t_signed=yes
 382 fi
 383
 384 if test $tor_cv_time_t_signed = yes; then
 385   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 386             [Define to 1 iff time_t is signed])
 387 fi
 388
 389 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 390 #ifdef HAVE_SYS_SOCKET_H
 391 #include <sys/socket.h>
 392 #endif
 393 ])
 394
 395 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 396
 397 AC_CHECK_SIZEOF(cell_t)
 398
 399 # Now make sure that NULL can be represented as zero bytes.
 400 if test -z "$CROSS_COMPILE"; then
 401 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 402 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 403 [[#include <stdlib.h>
 404 #include <string.h>
 405 #include <stdio.h>
 406 #ifdef HAVE_STDDEF_H
 407 #include <stddef.h>
 408 #endif
 409 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 410 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 411        [tor_cv_null_is_zero=yes],
 412        [tor_cv_null_is_zero=no],
 413        [tor_cv_null_is_zero=cross])])
 414
 415 else
 416   # Cross-compiling; let's hope that the target isn't raving mad.
 417   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 418   tor_cv_null_is_zero=yes
 419 fi
 420
 421 if test $tor_cv_null_is_zero = yes; then
 422   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 423             [Define to 1 iff memset(0) sets pointers to NULL])
 424 fi
 425
 426 # And what happens when we malloc zero?
 427
 428 if test -z "$CROSS_COMPILE"; then
 429 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 430 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 431 [[#include <stdlib.h>
 432 #include <string.h>
 433 #include <stdio.h>
 434 #ifdef HAVE_STDDEF_H
 435 #include <stddef.h>
 436 #endif
 437 int main () { return malloc(0)?0:1; }]])],
 438        [tor_cv_malloc_zero_works=yes],
 439        [tor_cv_malloc_zero_works=no],
 440        [tor_cv_malloc_zero_works=cross])])
 441
 442 else
 443   # Cross-compiling; let's hope that the target isn't raving mad.
 444   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 445   tor_cv_malloc_zero_works=no
 446 fi
 447
 448 if test $tor_cv_malloc_zero_works = yes; then
 449   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 450             [Define to 1 iff malloc(0) returns a pointer])
 451 fi
 452
 453 # whether we seem to be in a 2s-complement world.
 454 if test -z "$CROSS_COMPILE"; then
 455 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 456 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 457 [[int main () { int problem = ((-99) != (~99)+1);
 458 return problem ? 1 : 0; }]])],
 459        [tor_cv_twos_complement=yes],
 460        [tor_cv_twos_complement=no],
 461        [tor_cv_twos_complement=cross])])
 462
 463 else
 464   # Cross-compiling; let's hope that the target isn't raving mad.
 465   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 466   tor_cv_twos_complement=yes
 467 fi
 468
 469 if test $tor_cv_twos_complement = yes; then
 470   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 471             [Define to 1 iff we represent negative integers with two's complement])
 472 fi
 473
 474 # Whether we should use the dmalloc memory allocation debugging library.
 475 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 476 AC_ARG_WITH(dmalloc,
 477 [  --with-dmalloc          Use debug memory allocation library. ],
 478 [if [[ "$withval" = "yes" ]]; then
 479   dmalloc=1
 480   AC_MSG_RESULT(yes)
 481 else
 482   dmalloc=1
 483   AC_MSG_RESULT(no)
 484 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 485 )
 486
 487 if [[ $dmalloc -eq 1 ]]; then
 488   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 489   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 490   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 491   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 492 fi
 493
 494 # Allow user to specify an alternate syslog facility
 495 AC_ARG_WITH(syslog-facility,
 496 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 497 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 498 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 499 AC_SUBST(LOGFACILITY)
 500
 501 # Check for gethostbyname_r in all its glorious incompatible versions.
 502 #   (This logic is based on that in Python's configure.in)
 503 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 504   [Define this if you have any gethostbyname_r()])
 505
 506 AC_CHECK_FUNC(gethostbyname_r, [
 507   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 508   OLD_CFLAGS=$CFLAGS
 509   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 510   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 511 #include <netdb.h>
 512   ], [[
 513     char *cp1, *cp2;
 514     struct hostent *h1, *h2;
 515     int i1, i2;
 516     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 517   ]]),[
 518     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 519     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 520      [Define this if gethostbyname_r takes 6 arguments])
 521     AC_MSG_RESULT(6)
 522   ], [
 523     AC_TRY_COMPILE([
 524 #include <netdb.h>
 525     ], [
 526       char *cp1, *cp2;
 527       struct hostent *h1;
 528       int i1, i2;
 529       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 530     ], [
 531       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 532       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 533         [Define this if gethostbyname_r takes 5 arguments])
 534       AC_MSG_RESULT(5)
 535    ], [
 536       AC_TRY_COMPILE([
 537 #include <netdb.h>
 538      ], [
 539        char *cp1;
 540        struct hostent *h1;
 541        struct hostent_data hd;
 542        (void) gethostbyname_r(cp1,h1,&hd);
 543      ], [
 544        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 545        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 546          [Define this if gethostbyname_r takes 3 arguments])
 547        AC_MSG_RESULT(3)
 548      ], [
 549        AC_MSG_RESULT(0)
 550      ])
 551   ])
 552  ])
 553  CFLAGS=$OLD_CFLAGS
 554 ])
 555
 556 AC_CACHE_CHECK([whether the C compiler supports __func__],
 557   tor_cv_have_func_macro,
 558   AC_COMPILE_IFELSE([
 559 #include <stdio.h>
 560 int main(int c, char **v) { puts(__func__); }],
 561   tor_cv_have_func_macro=yes,
 562   tor_cv_have_func_macro=no))
 563
 564 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 565   tor_cv_have_FUNC_macro,
 566   AC_COMPILE_IFELSE([
 567 #include <stdio.h>
 568 int main(int c, char **v) { puts(__FUNC__); }],
 569   tor_cv_have_FUNC_macro=yes,
 570   tor_cv_have_FUNC_macro=no))
 571
 572 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 573   tor_cv_have_FUNCTION_macro,
 574   AC_COMPILE_IFELSE([
 575 #include <stdio.h>
 576 int main(int c, char **v) { puts(__FUNCTION__); }],
 577   tor_cv_have_FUNCTION_macro=yes,
 578   tor_cv_have_FUNCTION_macro=no))
 579
 580 if test $tor_cv_have_func_macro = 'yes'; then
 581   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 582 fi
 583
 584 if test $tor_cv_have_FUNC_macro = 'yes'; then
 585   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 586 fi
 587
 588 if test $tor_cv_have_FUNCTION_macro = 'yes'; then
 589   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 590            [Defined if the compiler supports __FUNCTION__])
 591 fi
 592
 593 # $prefix stores the value of the --prefix command line option, or
 594 # NONE if the option wasn't set.  In the case that it wasn't set, make
 595 # it be the default, so that we can use it to expand directories now.
 596 if test "x$prefix" = "xNONE"; then
 597   prefix=$ac_default_prefix
 598 fi
 599
 600 # and similarly for $exec_prefix
 601 if test "x$exec_prefix" = "xNONE"; then
 602   exec_prefix=$prefix
 603 fi
 604
 605 if test "x$CONFDIR" = "x"; then
 606   CONFDIR=`eval echo $sysconfdir/tor`
 607 fi
 608 AC_SUBST(CONFDIR)
 609 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 610 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 611
 612 BINDIR=`eval echo $bindir`
 613 AC_SUBST(BINDIR)
 614
 615 LOCALSTATEDIR=`eval echo $localstatedir`
 616 AC_SUBST(LOCALSTATEDIR)
 617 AH_TEMPLATE([LOCALSTATEDIR], [Default location to store state files.])
 618 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 619
 620 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 621 # than autoconf's macros like.
 622 if test $ac_cv_c_compiler_gnu = yes; then
 623   CFLAGS="$CFLAGS -Wall -g -O2"
 624 else
 625   CFLAGS="$CFLAGS -g -O"
 626   enable_gcc_warnings=no
 627 fi
 628
 629 # Add some more warnings which we use in development but not in the
 630 # released versions.  (Some relevant gcc versions can't handle these.)
 631 if test x$enable_gcc_warnings = xyes; then
 632
 633   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 634 #if !defined(__GNUC__) || (__GNUC__ < 4)
 635 #error
 636 #endif]), have_gcc4=yes, have_gcc4=no)
 637
 638   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 639 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 640 #error
 641 #endif]), have_gcc42=yes, have_gcc42=no)
 642
 643   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 644   # Disabled, so we can use mallinfo(): -Waggregate-return
 645
 646   if test x$have_gcc4 = xyes ; then
 647     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 648     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 649   fi
 650
 651   if test x$have_gcc42 = xyes ; then
 652     # These warnings break gcc 4.0.2 and work on gcc 4.2
 653     # XXXX020 Use -fstack-protector.
 654     # XXXX020 See if any of these work with earlier versions.
 655     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 656   fi
 657
 658 ##This will break the world on some 64-bit architectures
 659 # CFLAGS="$CFLAGS -Winline"
 660
 661 fi
 662
 663 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 664
 665 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 666 AC_OUTPUT
 667
 668 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 669   ./contrib/updateVersions.pl
 670 fi
 671