configure.ac

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2019, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_PREREQ([2.63])
   7 AC_INIT([tor],[0.4.4.7-dev])
   8 AC_CONFIG_SRCDIR([src/app/main/tor_main.c])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 configure_flags="$*"
  12
  13 # DO NOT EDIT THIS DEFINITION BY HAND UNLESS YOU KNOW WHAT YOU'RE DOING.
  14 #
  15 # The update_versions.py script updates this definition when the
  16 # version number changes.  Tor uses it to make sure that it
  17 # only shuts down for missing "required protocols" when those protocols
  18 # are listed as required by a consensus after this date.
  19 AC_DEFINE(APPROX_RELEASE_DATE, ["2021-02-03"], # for 0.4.4.7-dev
  20           [Approximate date when this software was released. (Updated when the version changes.)])
  21
  22 # "foreign" means we don't follow GNU package layout standards
  23 # "1.11" means we require automake version 1.11 or newer
  24 # "subdir-objects" means put .o files in the same directory as the .c files
  25 AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  26
  27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  28 AC_CONFIG_HEADERS([orconfig.h])
  29
  30 AC_USE_SYSTEM_EXTENSIONS
  31 AC_CANONICAL_HOST
  32
  33 PKG_PROG_PKG_CONFIG
  34 if test "x$PKG_CONFIG" = "x" ; then
  35     pkg_config_user_action="install pkg-config, and check the PKG_CONFIG_PATH environment variable"
  36     AC_MSG_NOTICE([Some libraries need pkg-config, including systemd, nss, lzma, zstd, and custom mallocs.])
  37     AC_MSG_NOTICE([To use those libraries, $pkg_config_user_action.])
  38 else
  39     pkg_config_user_action="check the PKG_CONFIG_PATH environment variable"
  40 fi
  41
  42 if test "x$PKG_CONFIG_PATH" = "x" && test "x$prefix" != "xNONE" && test "$host" != "$build"; then
  43    export PKG_CONFIG_PATH=$prefix/lib/pkgconfig
  44    AC_MSG_NOTICE([set PKG_CONFIG_PATH=$PKG_CONFIG_PATH to support cross-compiling])
  45 fi
  46
  47 AC_ARG_ENABLE(openbsd-malloc,
  48    AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD.  Linux only. Deprecated: see --with-malloc]))
  49 AC_ARG_ENABLE(static-openssl,
  50    AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  51 AC_ARG_ENABLE(static-libevent,
  52    AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  53 AC_ARG_ENABLE(static-zlib,
  54    AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  55 AC_ARG_ENABLE(static-tor,
  56    AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  57 AC_ARG_ENABLE(unittests,
  58    AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  59 AC_ARG_ENABLE(coverage,
  60    AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  61 AC_ARG_ENABLE(asserts-in-tests,
  62    AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  63 AC_ARG_ENABLE(system-torrc,
  64    AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  65 AC_ARG_ENABLE(libfuzzer,
  66    AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  67 AC_ARG_ENABLE(oss-fuzz,
  68    AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  69 AC_ARG_ENABLE(memory-sentinels,
  70    AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  71 AC_ARG_ENABLE(rust,
  72    AS_HELP_STRING(--enable-rust, [enable rust integration]))
  73 AC_ARG_ENABLE(cargo-online-mode,
  74    AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  75 AC_ARG_ENABLE(restart-debugging,
  76    AS_HELP_STRING(--enable-restart-debugging, [Build Tor with support for debugging in-process restart. Developers only.]))
  77 AC_ARG_ENABLE(zstd-advanced-apis,
  78    AS_HELP_STRING(--disable-zstd-advanced-apis, [Build without support for zstd's "static-only" APIs.]))
  79 AC_ARG_ENABLE(nss,
  80    AS_HELP_STRING(--enable-nss, [Use Mozilla's NSS TLS library. (EXPERIMENTAL)]))
  81 AC_ARG_ENABLE(pic,
  82    AS_HELP_STRING(--enable-pic, [Build Tor's binaries as position-independent code, suitable to link as a library.]))
  83
  84 AC_ARG_ENABLE(missing-doc-warnings,
  85    AS_HELP_STRING(--enable-missing-doc-warnings, [Tell doxygen to warn about missing documentation. Makes doxygen warnings nonfatal.]))
  86
  87 if test "$enable_missing_doc_warnings" = "yes"; then
  88    DOXYGEN_FATAL_WARNINGS=NO
  89    DOXYGEN_WARN_ON_MISSING=YES
  90 elif test "$enable_fatal_warnings" = "yes"; then
  91    # Fatal warnings from doxygen are nice, but not if we're warning about
  92    # missing documentation.
  93    DOXYGEN_FATAL_WARNINGS=YES
  94    DOXYGEN_WARN_ON_MISSING=NO
  95 else
  96    DOXYGEN_FATAL_WARNINGS=NO
  97    DOXYGEN_WARN_ON_MISSING=NO
  98 fi
  99 AC_SUBST(DOXYGEN_FATAL_WARNINGS)
 100 AC_SUBST(DOXYGEN_WARN_ON_MISSING)
 101
 102 if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
 103     AC_MSG_ERROR([Can't disable assertions outside of coverage build])
 104 fi
 105
 106 AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
 107 AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
 108 AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
 109 AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
 110 AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
 111 AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
 112 AM_CONDITIONAL(USE_NSS, test "x$enable_nss" = "xyes")
 113 AM_CONDITIONAL(USE_OPENSSL, test "x$enable_nss" != "xyes")
 114
 115 if test "x$enable_nss" = "xyes"; then
 116   AC_DEFINE(ENABLE_NSS, 1,
 117             [Defined if we're building with NSS.])
 118 else
 119   AC_DEFINE(ENABLE_OPENSSL, 1,
 120             [Defined if we're building with OpenSSL or LibreSSL])
 121 fi
 122
 123 if test "$enable_static_tor" = "yes"; then
 124   enable_static_libevent="yes";
 125   enable_static_openssl="yes";
 126   enable_static_zlib="yes";
 127   CFLAGS="$CFLAGS -static"
 128 fi
 129
 130 if test "$enable_system_torrc" = "no"; then
 131   AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
 132             [Defined if we're not going to look for a torrc in SYSCONF])
 133 fi
 134
 135 if test "$enable_memory_sentinels" = "no"; then
 136   AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
 137            [Defined if we're turning off memory safety code to look for bugs])
 138 fi
 139
 140 AC_ARG_ENABLE(manpage,
 141               AS_HELP_STRING(--disable-manpage, [Disable manpage generation.]))
 142
 143 AC_ARG_ENABLE(html-manual,
 144               AS_HELP_STRING(--disable-html-manual, [Disable HTML documentation.]))
 145
 146 AC_ARG_ENABLE(asciidoc,
 147      AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
 148      [case "${enableval}" in
 149         "yes") asciidoc=true ;;
 150         "no")  asciidoc=false ;;
 151         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
 152       esac], [asciidoc=true])
 153
 154 # systemd notify support
 155 AC_ARG_ENABLE(systemd,
 156       AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
 157       [case "${enableval}" in
 158         "yes") systemd=true ;;
 159         "no")  systemd=false ;;
 160         * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
 161       esac], [systemd=auto])
 162
 163 if test "$enable_restart_debugging" = "yes"; then
 164   AC_DEFINE(ENABLE_RESTART_DEBUGGING, 1,
 165             [Defined if we're building with support for in-process restart debugging.])
 166 fi
 167
 168 if test "$enable_zstd_advanced_apis" != "no"; then
 169    AC_DEFINE(ENABLE_ZSTD_ADVANCED_APIS, 1,
 170              [Defined if we're going to try to use zstd's "static-only" APIs.])
 171 fi
 172
 173 # systemd support
 174 if test "x$enable_systemd" = "xno"; then
 175     have_systemd=no;
 176 else
 177     PKG_CHECK_MODULES(SYSTEMD,
 178         [libsystemd-daemon],
 179         have_systemd=yes,
 180         have_systemd=no)
 181     if test "x$have_systemd" = "xno"; then
 182         AC_MSG_NOTICE([Okay, checking for systemd a different way...])
 183         PKG_CHECK_MODULES(SYSTEMD,
 184             [libsystemd],
 185             have_systemd=yes,
 186             have_systemd=no)
 187     fi
 188 fi
 189
 190 if test "x$have_systemd" = "xyes"; then
 191     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
 192     TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
 193     TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
 194     PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
 195          [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or greater])], [])
 196 fi
 197 AC_SUBST(TOR_SYSTEMD_CFLAGS)
 198 AC_SUBST(TOR_SYSTEMD_LIBS)
 199
 200 if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
 201     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found, $pkg_config_user_action, or set SYSTEMD_CFLAGS and SYSTEMD_LIBS.])
 202 fi
 203
 204 case "$host" in
 205    *-*-solaris* )
 206      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
 207      ;;
 208 esac
 209
 210 AC_ARG_ENABLE(gcc-warnings,
 211      AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
 212 AC_ARG_ENABLE(fatal-warnings,
 213      AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
 214 AC_ARG_ENABLE(gcc-warnings-advisory,
 215      AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
 216
 217 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
 218 AC_ARG_ENABLE(gcc-hardening,
 219     AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
 220
 221 dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
 222 AC_ARG_ENABLE(expensive-hardening,
 223     AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 224 AC_ARG_ENABLE(fragile-hardening,
 225     AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
 226 if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
 227   fragile_hardening="yes"
 228   AC_DEFINE(DEBUG_SMARTLIST, 1, [Enable smartlist debugging])
 229 fi
 230
 231 AC_ARG_ENABLE(all-bugs-are-fatal,
 232    AS_HELP_STRING(--enable-all-bugs-are-fatal, [force all soft asserts in Tor codebase (tor_assert_nonfatal(), BUG(), etc.) to act as hard asserts (tor_assert() and equivalents); makes Tor fragile; only recommended for dev builds]))
 233
 234 if test "x$enable_all_bugs_are_fatal" = "xyes"; then
 235   AC_DEFINE(ALL_BUGS_ARE_FATAL, 1, [All assert failures are fatal])
 236 fi
 237
 238 dnl Linker hardening options
 239 dnl Currently these options are ELF specific - you can't use this with MacOSX
 240 AC_ARG_ENABLE(linker-hardening,
 241     AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
 242
 243 AC_ARG_ENABLE(local-appdata,
 244    AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
 245 if test "$enable_local_appdata" = "yes"; then
 246   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 247             [Defined if we default to host local appdata paths on Windows])
 248 fi
 249
 250 AC_ARG_ENABLE(tool-name-check,
 251      AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
 252
 253 AC_ARG_ENABLE(seccomp,
 254      AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
 255
 256 AC_ARG_ENABLE(libscrypt,
 257      AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
 258
 259 dnl Enable event tracing which are transformed to debug log statement.
 260 AC_ARG_ENABLE(event-tracing-debug,
 261      AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
 262 AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
 263
 264 if test x$enable_event_tracing_debug = xyes; then
 265   AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
 266   AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
 267 fi
 268
 269 dnl Enable Android only features.
 270 AC_ARG_ENABLE(android,
 271      AS_HELP_STRING(--enable-android, [build with Android features enabled]))
 272 AM_CONDITIONAL([USE_ANDROID], [test "x$enable_android" = "xyes"])
 273
 274 if test "x$enable_android" = "xyes"; then
 275   AC_DEFINE([USE_ANDROID], [1], [Compile with Android specific features enabled])
 276
 277   dnl Check if the Android log library is available.
 278   AC_CHECK_HEADERS([android/log.h])
 279   AC_SEARCH_LIBS(__android_log_write, [log])
 280
 281 fi
 282
 283 dnl ---
 284 dnl Tor modules options. These options are namespaced with --disable-module-XXX
 285 dnl ---
 286
 287 dnl All our modules.
 288 m4_define(MODULES, relay dirauth dircache)
 289
 290 dnl Relay module.
 291 AC_ARG_ENABLE([module-relay],
 292               AS_HELP_STRING([--disable-module-relay],
 293                              [Build tor without the Relay modules: tor can not run as a relay, bridge, or authority. Implies --disable-module-dirauth]))
 294 AM_CONDITIONAL(BUILD_MODULE_RELAY, [test "x$enable_module_relay" != "xno"])
 295 AM_COND_IF(BUILD_MODULE_RELAY,
 296            AC_DEFINE([HAVE_MODULE_RELAY], [1],
 297                      [Compile with Relay feature support]))
 298
 299 dnl Dircache module.  (This cannot be enabled or disabled independently of
 300 dnl the relay module.  It is not listed by --list-modules for this reason.)
 301 AM_CONDITIONAL(BUILD_MODULE_DIRCACHE,
 302                [test "x$enable_module_relay" != "xno"])
 303 AM_COND_IF(BUILD_MODULE_DIRCACHE,
 304            AC_DEFINE([HAVE_MODULE_DIRCACHE], [1],
 305                      [Compile with directory cache support]))
 306
 307 dnl Directory Authority module.
 308 AC_ARG_ENABLE([module-dirauth],
 309               AS_HELP_STRING([--disable-module-dirauth],
 310                              [Build tor without the Directory Authority module: tor can not run as a directory authority or bridge authority]))
 311 AM_CONDITIONAL(BUILD_MODULE_DIRAUTH,[test "x$enable_module_dirauth" != "xno" && test "x$enable_module_relay" != "xno"])
 312 AM_COND_IF(BUILD_MODULE_DIRAUTH,
 313            AC_DEFINE([HAVE_MODULE_DIRAUTH], [1],
 314                      [Compile with Directory Authority feature support]))
 315
 316 dnl Helper variables.
 317 TOR_MODULES_ALL_ENABLED=
 318 AC_DEFUN([ADD_MODULE], [
 319     MODULE=m4_toupper($1)
 320     TOR_MODULES_ALL_ENABLED="${TOR_MODULES_ALL_ENABLED} -DHAVE_MODULE_${MODULE}=1"
 321 ])
 322 m4_foreach_w([module], MODULES, [ADD_MODULE([module])])
 323 AC_SUBST(TOR_MODULES_ALL_ENABLED)
 324
 325 dnl check for the correct "ar" when cross-compiling.
 326 dnl   (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
 327 dnl    so kludge up a replacement for the case where it isn't there yet.)
 328 m4_ifdef([AM_PROG_AR],
 329          [AM_PROG_AR],
 330          [AN_MAKEVAR([AR], [AC_PROG_AR])
 331           AN_PROGRAM([ar], [AC_PROG_AR])
 332           AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
 333           AC_PROG_AR])
 334
 335 dnl Check whether the above macro has settled for a simply named tool even
 336 dnl though we're cross compiling. We must do this before running AC_PROG_CC,
 337 dnl because that will find any cc on the system, not only the cross-compiler,
 338 dnl and then verify that a binary built with this compiler runs on the
 339 dnl build system. It will then come to the false conclusion that we're not
 340 dnl cross-compiling.
 341 if test "x$enable_tool_name_check" != "xno"; then
 342     if test "x$ac_tool_warned" = "xyes"; then
 343         AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 344         elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
 345                 AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
 346         fi
 347 fi
 348
 349 AC_PROG_CC
 350 AC_PROG_CPP
 351 AC_PROG_MAKE_SET
 352 AC_PROG_RANLIB
 353 AC_PROG_SED
 354
 355 AC_ARG_VAR([PERL], [path to Perl binary])
 356 AC_CHECK_PROGS([PERL], [perl])
 357 AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
 358
 359 dnl check for asciidoc and a2x
 360 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 361 AC_PATH_PROGS([A2X], [a2x a2x.py], none)
 362
 363 AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
 364 AM_CONDITIONAL(BUILD_MANPAGE, [test "x$enable_manpage" != "xno"])
 365 AM_CONDITIONAL(BUILD_HTML_DOCS, [test "x$enable_html_manual" != "xno"])
 366
 367 AM_PROG_CC_C_O
 368 AC_PROG_CC_C99
 369
 370 AC_CACHE_CHECK([for Python 3], [tor_cv_PYTHON],
 371    [AC_PATH_PROGS_FEATURE_CHECK([PYTHON], [ \
 372         python3 \
 373         python3.8 python3.7 python3.6 python3.5 python3.4 \
 374         python ],
 375    [["$ac_path_PYTHON" -c 'import sys; sys.exit(sys.version_info[0]<3)' && tor_cv_PYTHON="$ac_path_PYTHON" ac_path_PYTHON_found=:]] )])
 376 AC_SUBST([PYTHON], [$tor_cv_PYTHON])
 377
 378 PYTHON="$tor_cv_PYTHON"
 379
 380 if test "x$PYTHON" = "x"; then
 381   AC_MSG_WARN([Python 3 unavailable; some tests will not be run.])
 382 fi
 383
 384 AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
 385
 386 dnl List all external rust crates we depend on here. Include the version
 387 rust_crates=" \
 388     digest-0.7.2 \
 389     libc-0.2.39 \
 390 "
 391 AC_SUBST(rust_crates)
 392
 393 ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
 394 AC_C_FLEXIBLE_ARRAY_MEMBER
 395 ], [
 396  dnl Maybe we've got an old autoconf...
 397  AC_CACHE_CHECK([for flexible array members],
 398      tor_cv_c_flexarray,
 399      [AC_COMPILE_IFELSE(
 400        AC_LANG_PROGRAM([
 401  struct abc { int a; char b[]; };
 402 ], [
 403  struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
 404  def->b[0] = 33;
 405 ]),
 406   [tor_cv_c_flexarray=yes],
 407   [tor_cv_c_flexarray=no])])
 408  if test "$tor_cv_flexarray" = "yes"; then
 409    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 410  else
 411    AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
 412  fi
 413 ])
 414
 415 AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
 416       tor_cv_c_c99_decl,
 417       [AC_COMPILE_IFELSE(
 418          [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
 419          [tor_cv_c_c99_decl=yes],
 420          [tor_cv_c_c99_decl=no] )])
 421 if test "$tor_cv_c_c99_decl" != "yes"; then
 422   AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
 423 fi
 424
 425 AC_CACHE_CHECK([for working C99 designated initializers],
 426       tor_cv_c_c99_designated_init,
 427       [AC_COMPILE_IFELSE(
 428          [AC_LANG_PROGRAM([struct s { int a; int b; };],
 429                [[ struct s ss = { .b = 5, .a = 6 }; ]])],
 430          [tor_cv_c_c99_designated_init=yes],
 431          [tor_cv_c_c99_designated_init=no] )])
 432
 433 if test "$tor_cv_c_c99_designated_init" != "yes"; then
 434   AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
 435 fi
 436
 437 saved_CFLAGS="$CFLAGS"
 438 CFLAGS="$CFLAGS -Werror"
 439 AC_CACHE_CHECK([for __attribute__((fallthrough))],
 440       tor_cv_c_attr_fallthrough,
 441       [AC_COMPILE_IFELSE(
 442          [AC_LANG_PROGRAM([extern int x; void fn(void) ;],
 443                [[ switch (x) { case 1: fn(); __attribute__((fallthrough));
 444                                case 2: fn(); break; } ]])],
 445          [tor_cv_c_attr_fallthrough=yes],
 446          [tor_cv_c_attr_fallthrough=no] )])
 447 CFLAGS="$saved_CFLAGS"
 448
 449 if test "$tor_cv_c_attr_fallthrough" = "yes"; then
 450   AC_DEFINE(HAVE_ATTR_FALLTHROUGH, [1], [defined if we have the fallthrough attribute.])
 451 fi
 452
 453 TORUSER=_tor
 454 AC_ARG_WITH(tor-user,
 455         AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
 456         [
 457            TORUSER=$withval
 458         ]
 459 )
 460 AC_SUBST(TORUSER)
 461
 462 TORGROUP=_tor
 463 AC_ARG_WITH(tor-group,
 464         AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
 465         [
 466            TORGROUP=$withval
 467         ]
 468 )
 469 AC_SUBST(TORGROUP)
 470
 471
 472 dnl If _WIN32 is defined and non-zero, we are building for win32
 473 AC_MSG_CHECKING([for win32])
 474 AC_RUN_IFELSE([AC_LANG_SOURCE([
 475 int main(int c, char **v) {
 476 #ifdef _WIN32
 477 #if _WIN32
 478   return 0;
 479 #else
 480   return 1;
 481 #endif
 482 #else
 483   return 2;
 484 #endif
 485 }])],
 486 bwin32=true; AC_MSG_RESULT([yes]),
 487 bwin32=false; AC_MSG_RESULT([no]),
 488 bwin32=cross; AC_MSG_RESULT([cross])
 489 )
 490
 491 if test "$bwin32" = "cross"; then
 492 AC_MSG_CHECKING([for win32 (cross)])
 493 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 494 #ifdef _WIN32
 495 int main(int c, char **v) {return 0;}
 496 #else
 497 #error
 498 int main(int c, char **v) {return x(y);}
 499 #endif
 500 ])],
 501 bwin32=true; AC_MSG_RESULT([yes]),
 502 bwin32=false; AC_MSG_RESULT([no]))
 503 fi
 504
 505 AH_BOTTOM([
 506 #ifdef _WIN32
 507 /* Defined to access windows functions and definitions for >=WinXP */
 508 # ifndef WINVER
 509 #  define WINVER 0x0501
 510 # endif
 511
 512 /* Defined to access _other_ windows functions and definitions for >=WinXP */
 513 # ifndef _WIN32_WINNT
 514 #  define _WIN32_WINNT 0x0501
 515 # endif
 516
 517 /* Defined to avoid including some windows headers as part of Windows.h */
 518 # ifndef WIN32_LEAN_AND_MEAN
 519 #  define WIN32_LEAN_AND_MEAN 1
 520 # endif
 521 #endif
 522 ])
 523
 524 AM_CONDITIONAL(WIN32, test "x$bwin32" = "xtrue")
 525 AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
 526 AM_CONDITIONAL(BUILD_LIBTORRUNNER, test "x$bwin32" != "xtrue")
 527
 528 dnl Enable C99 when compiling with MIPSpro
 529 AC_MSG_CHECKING([for MIPSpro compiler])
 530 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 531 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 532 #error
 533   return x(y);
 534 #endif
 535 ])],
 536 bmipspro=false; AC_MSG_RESULT(no),
 537 bmipspro=true; AC_MSG_RESULT(yes))
 538
 539 if test "$bmipspro" = "true"; then
 540   CFLAGS="$CFLAGS -c99"
 541 fi
 542
 543 AC_C_BIGENDIAN
 544
 545 AC_ARG_VAR([TOR_RUST_TARGET], [Rust target, must be specified when cross-compiling (HOST != BUILD). example: i686-pc-windows-gnu])
 546
 547 if test "x$enable_rust" = "xyes"; then
 548   AC_ARG_VAR([RUSTC], [path to the rustc binary])
 549   AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
 550   if test "x$RUSTC" = "xno"; then
 551     AC_MSG_ERROR([rustc unavailable but rust integration requested.])
 552   fi
 553
 554   AC_ARG_VAR([CARGO], [path to the cargo binary])
 555   AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
 556   if test "x$CARGO" = "xno"; then
 557     AC_MSG_ERROR([cargo unavailable but rust integration requested.])
 558   fi
 559
 560   AC_DEFINE([HAVE_RUST], 1, [have Rust])
 561   if test "x$enable_fatal_warnings" = "xyes"; then
 562     RUST_WARN=
 563   else
 564     RUST_WARN=#
 565   fi
 566   if test "x$enable_cargo_online_mode" = "xyes"; then
 567     CARGO_ONLINE=
 568     RUST_DL=#
 569   else
 570     CARGO_ONLINE=--frozen
 571     RUST_DL=
 572
 573     dnl When we're not allowed to touch the network, we need crate dependencies
 574     dnl locally available.
 575     AC_MSG_CHECKING([rust crate dependencies])
 576     AC_ARG_VAR([TOR_RUST_DEPENDENCIES], [path to directory with local crate mirror])
 577     if test "x$TOR_RUST_DEPENDENCIES" = "x"; then
 578       TOR_RUST_DEPENDENCIES="${srcdir}/src/ext/rust/crates"
 579     fi
 580     dnl Check whether the path exists before we try to cd into it.
 581     if test ! -d "$TOR_RUST_DEPENDENCIES"; then
 582       AC_MSG_ERROR([Rust dependency directory $TOR_RUST_DEPENDENCIES does not exist. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 583       ERRORED=1
 584     fi
 585     dnl Make the path absolute, since we'll be using it from within a
 586     dnl subdirectory.
 587     TOR_RUST_DEPENDENCIES=$(cd "$TOR_RUST_DEPENDENCIES" ; pwd)
 588
 589     for dep in $rust_crates; do
 590       if test ! -d "$TOR_RUST_DEPENDENCIES"/"$dep"; then
 591         AC_MSG_ERROR([Failure to find rust dependency $TOR_RUST_DEPENDENCIES/$dep. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
 592         ERRORED=1
 593       fi
 594     done
 595     if test "x$ERRORED" = "x"; then
 596       AC_MSG_RESULT([yes])
 597     fi
 598   fi
 599
 600   dnl For now both MSVC and MinGW rust libraries will output static libs with
 601   dnl the MSVC naming convention.
 602   if test "$bwin32" = "true"; then
 603     tor_rust_static_name=tor_rust.lib
 604   else
 605     tor_rust_static_name=libtor_rust.a
 606   fi
 607
 608   AC_CANONICAL_BUILD
 609
 610   if test -n "$TOR_RUST_TARGET"; then
 611     if test "$host" = "$build"; then
 612       AC_MSG_ERROR([HOST = BUILD is invalid if TOR_RUST_TARGET is specified, see configure --help for more information.])
 613     fi
 614     RUST_TARGET_PROP="target = '$TOR_RUST_TARGET'"
 615     TOR_RUST_LIB_PATH="src/rust/target/$TOR_RUST_TARGET/release/$tor_rust_static_name"
 616   else
 617     if test "$host" != "$build"; then
 618       AC_MSG_ERROR([TOR_RUST_TARGET must be specified when cross-compiling with Rust enabled.])
 619     fi
 620     RUST_TARGET_PROP=
 621     TOR_RUST_LIB_PATH="src/rust/target/release/$tor_rust_static_name"
 622   fi
 623
 624   AC_SUBST(RUST_TARGET_PROP)
 625   AC_SUBST(TOR_RUST_LIB_PATH)
 626   AC_SUBST(CARGO_ONLINE)
 627   AC_SUBST(RUST_WARN)
 628   AC_SUBST(RUST_DL)
 629
 630   dnl Let's check the rustc version, too
 631   AC_MSG_CHECKING([rust version])
 632   RUSTC_VERSION=`$RUSTC --version`
 633   RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
 634   RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
 635   if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
 636     AC_MSG_ERROR([rustc version couldn't be identified])
 637   fi
 638   if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 31; then
 639     AC_MSG_ERROR([rustc must be at least version 1.31.0])
 640   fi
 641   AC_MSG_RESULT([$RUSTC_VERSION])
 642 fi
 643
 644 AC_SEARCH_LIBS(socket, [socket network])
 645 AC_SEARCH_LIBS(gethostbyname, [nsl])
 646 AC_SEARCH_LIBS(dlopen, [dl])
 647 AC_SEARCH_LIBS(inet_aton, [resolv])
 648 AC_SEARCH_LIBS(backtrace, [execinfo])
 649 saved_LIBS="$LIBS"
 650 AC_SEARCH_LIBS([clock_gettime], [rt])
 651 if test "$LIBS" != "$saved_LIBS"; then
 652    # Looks like we need -lrt for clock_gettime().
 653    have_rt=yes
 654 fi
 655
 656 if test "$bwin32" = "false"; then
 657   AC_SEARCH_LIBS(pthread_create, [pthread])
 658   AC_SEARCH_LIBS(pthread_detach, [pthread])
 659 fi
 660
 661 AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
 662 AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
 663
 664 AC_CHECK_FUNCS(
 665         _NSGetEnviron \
 666         RtlSecureZeroMemory \
 667         SecureZeroMemory \
 668         accept4 \
 669         backtrace \
 670         backtrace_symbols_fd \
 671         eventfd \
 672         explicit_bzero \
 673         timingsafe_memcmp \
 674         flock \
 675         fsync \
 676         ftime \
 677         get_current_dir_name \
 678         getaddrinfo \
 679         getdelim \
 680         getifaddrs \
 681         getline \
 682         getpass \
 683         getrlimit \
 684         gettimeofday \
 685         gmtime_r \
 686         gnu_get_libc_version \
 687         htonll \
 688         inet_aton \
 689         ioctl \
 690         issetugid \
 691         llround \
 692         localtime_r \
 693         lround \
 694         madvise \
 695         memmem \
 696         memset_s \
 697         minherit \
 698         mmap \
 699         pipe \
 700         pipe2 \
 701         prctl \
 702         readpassphrase \
 703         rint \
 704         sigaction \
 705         socketpair \
 706         statvfs \
 707         strncasecmp \
 708         strcasecmp \
 709         strlcat \
 710         strlcpy \
 711         strnlen \
 712         strptime \
 713         strtok_r \
 714         strtoull \
 715         sysconf \
 716         sysctl \
 717         truncate \
 718         uname \
 719         usleep \
 720         vasprintf \
 721         _vscprintf
 722 )
 723
 724 # Apple messed up when they added some functions: they
 725 # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
 726 # checks.
 727
 728 # We should only probe for these functions if we are sure that we
 729 # are not targeting OS X 10.9 or earlier.
 730 AC_MSG_CHECKING([for a pre-Yosemite OS X build target])
 731 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 732 #ifdef __APPLE__
 733 #  include <AvailabilityMacros.h>
 734 #  ifndef MAC_OS_X_VERSION_10_10
 735 #    define MAC_OS_X_VERSION_10_10 101000
 736 #  endif
 737 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 738 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_10
 739 #      error "Running on Mac OS X 10.9 or earlier"
 740 #    endif
 741 #  endif
 742 #endif
 743 ]], [[]])],
 744    [on_macos_pre_10_10=no ; AC_MSG_RESULT([no])],
 745    [on_macos_pre_10_10=yes; AC_MSG_RESULT([yes])])
 746
 747 if test "$on_macos_pre_10_10" = "no"; then
 748   AC_CHECK_FUNCS(
 749         mach_approximate_time \
 750   )
 751 fi
 752
 753 # We should only probe for these functions if we are sure that we
 754 # are not targeting OSX 10.11 or earlier.
 755 AC_MSG_CHECKING([for a pre-Sierra OSX build target])
 756 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 757 #ifdef __APPLE__
 758 #  include <AvailabilityMacros.h>
 759 #  ifndef MAC_OS_X_VERSION_10_12
 760 #    define MAC_OS_X_VERSION_10_12 101200
 761 #  endif
 762 #  if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
 763 #    if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 764 #      error "Running on Mac OSX 10.11 or earlier"
 765 #    endif
 766 #  endif
 767 #endif
 768 ]], [[]])],
 769    [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
 770    [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
 771
 772 if test "$on_macos_pre_10_12" = "no"; then
 773   AC_CHECK_FUNCS(
 774         clock_gettime \
 775         getentropy \
 776   )
 777 fi
 778
 779 if test "$bwin32" != "true"; then
 780   AC_CHECK_HEADERS(pthread.h)
 781   AC_CHECK_FUNCS(pthread_create)
 782   AC_CHECK_FUNCS(pthread_condattr_setclock)
 783 fi
 784
 785 if test "$bwin32" = "true"; then
 786   AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
 787 #include <windows.h>
 788 #include <conio.h>
 789 #include <wchar.h>
 790                  ])
 791 fi
 792
 793 AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
 794   test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
 795
 796 AC_MSG_CHECKING([whether free(NULL) works])
 797 AC_RUN_IFELSE([AC_LANG_PROGRAM([
 798   #include <stdlib.h>
 799 ], [
 800 char *p = NULL;
 801 free(p);
 802 ])],
 803 [free_null_ok=true; AC_MSG_RESULT(yes)],
 804 [free_null_ok=false; AC_MSG_RESULT(no)],
 805 [free_null_ok=cross; AC_MSG_RESULT(cross)])
 806
 807 if test "$free_null_ok" = "false"; then
 808    AC_MSG_ERROR([Your libc implementation doesn't allow free(NULL), as required by C99.])
 809 fi
 810
 811 dnl ------------------------------------------------------
 812 dnl Where do you live, libevent?  And how do we call you?
 813
 814 if test "$bwin32" = "true"; then
 815   TOR_LIB_WS32=-lws2_32
 816   TOR_LIB_IPHLPAPI=-liphlpapi
 817   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 818   # think it's actually necessary.
 819   TOR_LIB_GDI=-lgdi32
 820   TOR_LIB_USERENV=-luserenv
 821 else
 822   TOR_LIB_WS32=
 823   TOR_LIB_GDI=
 824   TOR_LIB_USERENV=
 825 fi
 826 AC_SUBST(TOR_LIB_WS32)
 827 AC_SUBST(TOR_LIB_GDI)
 828 AC_SUBST(TOR_LIB_IPHLPAPI)
 829 AC_SUBST(TOR_LIB_USERENV)
 830
 831 tor_libevent_pkg_redhat="libevent"
 832 tor_libevent_pkg_debian="libevent-dev"
 833 tor_libevent_devpkg_redhat="libevent-devel"
 834 tor_libevent_devpkg_debian="libevent-dev"
 835
 836 dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
 837 dnl linking for static builds.
 838 STATIC_LIBEVENT_FLAGS=""
 839 if test "$enable_static_libevent" = "yes"; then
 840     if test "$have_rt" = "yes"; then
 841       STATIC_LIBEVENT_FLAGS=" -lrt "
 842     fi
 843 fi
 844
 845 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
 846 #ifdef _WIN32
 847 #include <winsock2.h>
 848 #endif
 849 #include <sys/time.h>
 850 #include <sys/types.h>
 851 #include <event2/event.h>], [
 852 #ifdef _WIN32
 853 #include <winsock2.h>
 854 #endif
 855 struct event_base;
 856 struct event_base *event_base_new(void);
 857 void event_base_free(struct event_base *);],
 858     [
 859 #ifdef _WIN32
 860 {WSADATA d; WSAStartup(0x101,&d); }
 861 #endif
 862 event_base_free(event_base_new());
 863 ], [--with-libevent-dir], [/opt/libevent])
 864
 865 dnl Determine the incantation needed to link libevent.
 866 save_LIBS="$LIBS"
 867 save_LDFLAGS="$LDFLAGS"
 868 save_CPPFLAGS="$CPPFLAGS"
 869
 870 LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
 871 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 872 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 873
 874 AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
 875
 876 if test "$enable_static_libevent" = "yes"; then
 877    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 878      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 879    else
 880      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
 881    fi
 882 else
 883      if test "x$ac_cv_header_event2_event_h" = "xyes"; then
 884        AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
 885        AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
 886
 887        if test "$ac_cv_search_event_new" != "none required"; then
 888          TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
 889        fi
 890        if test "$ac_cv_search_evdns_base_new" != "none required"; then
 891          TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
 892        fi
 893      else
 894        AC_MSG_ERROR("libevent2 is required but the headers could not be found")
 895      fi
 896 fi
 897
 898 dnl Now check for particular libevent functions.
 899 AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
 900                 evutil_secure_rng_add_bytes \
 901                 evdns_base_get_nameserver_addr \
 902
 903 ])
 904
 905 LIBS="$save_LIBS"
 906 LDFLAGS="$save_LDFLAGS"
 907 CPPFLAGS="$save_CPPFLAGS"
 908
 909 dnl Check that libevent is at least at version 2.0.10, the first stable
 910 dnl release of its series
 911 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
 912 AC_MSG_CHECKING([whether Libevent is new enough])
 913 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 914 #include <event2/event.h>
 915 #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
 916 #error
 917 int x = y(zz);
 918 #else
 919 int x = 1;
 920 #endif
 921 ])], [ AC_MSG_RESULT([yes]) ],
 922    [ AC_MSG_RESULT([no])
 923      AC_MSG_ERROR([Libevent is not new enough.  We require 2.0.10-stable or later]) ] )
 924
 925 LIBS="$save_LIBS"
 926 LDFLAGS="$save_LDFLAGS"
 927 CPPFLAGS="$save_CPPFLAGS"
 928
 929 AC_SUBST(TOR_LIBEVENT_LIBS)
 930
 931 dnl ------------------------------------------------------
 932 dnl Where do you live, libm?
 933
 934 dnl On some platforms (Haiku/BeOS) the math library is
 935 dnl part of libroot. In which case don't link against lm
 936 TOR_LIB_MATH=""
 937 save_LIBS="$LIBS"
 938 AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
 939 if test "$ac_cv_search_pow" != "none required"; then
 940     TOR_LIB_MATH="$ac_cv_search_pow"
 941 fi
 942 LIBS="$save_LIBS"
 943 AC_SUBST(TOR_LIB_MATH)
 944
 945 dnl ------------------------------------------------------
 946 dnl Hello, NSS.  You're new around here.
 947 if test "x$enable_nss" = "xyes"; then
 948   PKG_CHECK_MODULES(NSS,
 949      [nss],
 950      [have_nss=yes],
 951      [have_nss=no; AC_MSG_ERROR([You asked for NSS but I can't find it, $pkg_config_user_action, or set NSS_CFLAGS and NSS_LIBS.])])
 952   AC_SUBST(NSS_CFLAGS)
 953   AC_SUBST(NSS_LIBS)
 954 fi
 955
 956 dnl ------------------------------------------------------
 957 dnl Where do you live, openssl?  And how do we call you?
 958
 959 if test "x$enable_nss" != "xyes"; then
 960
 961 tor_openssl_pkg_redhat="openssl"
 962 tor_openssl_pkg_debian="libssl-dev"
 963 tor_openssl_devpkg_redhat="openssl-devel"
 964 tor_openssl_devpkg_debian="libssl-dev"
 965
 966 ALT_openssl_WITHVAL=""
 967 AC_ARG_WITH(ssl-dir,
 968   AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
 969   [
 970       if test "x$withval" != "xno" && test "x$withval" != "x"; then
 971          ALT_openssl_WITHVAL="$withval"
 972       fi
 973   ])
 974
 975 AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
 976 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
 977     [#include <openssl/ssl.h>
 978      char *getenv(const char *);],
 979     [struct ssl_cipher_st;
 980      unsigned SSL_CIPHER_get_id(const struct ssl_cipher_st *);
 981      char *getenv(const char *);],
 982     dnl This funny-looking test program calls getenv, so that the compiler
 983     dnl will neither make code that call SSL_CIPHER_get_id(NULL) [producing
 984     dnl a crash], nor optimize out the call to SSL_CIPHER_get_id().
 985     dnl We look for SSL_cipher_get_id() because it is present in
 986     dnl OpenSSL >=1.0.1, because it is not deprecated, and because Tor
 987     dnl depends on it.
 988     [if (getenv("THIS_SHOULDNT_BE_SET_X201803")) SSL_CIPHER_get_id((void *)0);], [],
 989     [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /opt/openssl])
 990
 991 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 992
 993 if test "$enable_static_openssl" = "yes"; then
 994    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 995      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 996    else
 997      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 998    fi
 999 else
1000      TOR_OPENSSL_LIBS="-lssl -lcrypto"
1001 fi
1002 AC_SUBST(TOR_OPENSSL_LIBS)
1003
1004 dnl Now check for particular openssl functions.
1005 save_LIBS="$LIBS"
1006 save_LDFLAGS="$LDFLAGS"
1007 save_CPPFLAGS="$CPPFLAGS"
1008 LIBS="$TOR_OPENSSL_LIBS $LIBS"
1009 LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
1010 CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
1011
1012 dnl Tor currently uses a number of APIs that are deprecated in OpenSSL 3.0.0
1013 dnl and later.  We want to migrate away from them, but that will be a lot of
1014 dnl work. (See ticket tor#40166.)  For now, we disable the deprecation
1015 dnl warnings.
1016
1017 AC_MSG_CHECKING([for OpenSSL >= 3.0.0])
1018 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1019 #include <openssl/opensslv.h>
1020 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER <= 0x30000000L
1021 #error "you_have_version_3"
1022 #endif
1023    ]], [[]])],
1024    [ AC_MSG_RESULT([no]) ],
1025    [ AC_MSG_RESULT([yes]);
1026      AC_DEFINE(OPENSSL_SUPPRESS_DEPRECATED, 1, [disable openssl deprecated-function warnings]) ])
1027
1028 AC_MSG_CHECKING([for OpenSSL < 1.0.1])
1029 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1030 #include <openssl/opensslv.h>
1031 #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
1032 #error "too old"
1033 #endif
1034    ]], [[]])],
1035    [ AC_MSG_RESULT([no]) ],
1036    [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
1037
1038 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1039 #include <openssl/opensslv.h>
1040 #include <openssl/evp.h>
1041 #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
1042 #error "no ECC"
1043 #endif
1044 #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
1045 #error "curves unavailable"
1046 #endif
1047    ]], [[]])],
1048    [ : ],
1049    [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
1050
1051 AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
1052 [#include <openssl/ssl.h>
1053 ])
1054
1055 dnl OpenSSL functions which we might not have.  In theory, we could just
1056 dnl check the openssl version number, but in practice that gets pretty
1057 dnl confusing with LibreSSL, OpenSSL, and various distributions' patches
1058 dnl to them.
1059 AC_CHECK_FUNCS([ \
1060                 ERR_load_KDF_strings \
1061                 EVP_PBE_scrypt \
1062                 EVP_sha3_256 \
1063                 SSL_CIPHER_find \
1064                 SSL_CTX_set1_groups_list \
1065                 SSL_CTX_set_security_level \
1066                 SSL_SESSION_get_master_key \
1067                 SSL_get_client_ciphers \
1068                 SSL_get_client_random \
1069                 SSL_get_server_random \
1070                 TLS_method \
1071                ])
1072
1073 dnl Check if OpenSSL structures are opaque
1074 AC_CHECK_MEMBERS([SSL.state], , ,
1075 [#include <openssl/ssl.h>
1076 ])
1077
1078 AC_CHECK_SIZEOF(SHA_CTX, , [AC_INCLUDES_DEFAULT()
1079 #include <openssl/sha.h>
1080 ])
1081
1082 fi # enable_nss
1083
1084 dnl We will someday make KECCAK_TINY optional, but for now we still need
1085 dnl it for SHAKE, since OpenSSL's SHAKE can't be squeezed more than
1086 dnl once.  See comment in the definition of crypto_xof_t.
1087
1088 dnl AM_CONDITIONAL(BUILD_KECCAK_TINY,
1089 dnl   test "x$ac_cv_func_EVP_sha3_256" != "xyes")
1090
1091 AM_CONDITIONAL(BUILD_KECCAK_TINY, true)
1092
1093 dnl ======================================================================
1094 dnl Can we use KIST?
1095
1096 dnl Define the set of checks for KIST scheduler support.
1097 AC_DEFUN([CHECK_KIST_SUPPORT],[
1098   dnl KIST needs struct tcp_info and for certain members to exist.
1099   AC_CHECK_MEMBERS(
1100     [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
1101     , ,[[#include <netinet/tcp.h>]])
1102   dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
1103   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1104                      #include <linux/sockios.h>
1105                      #ifndef SIOCOUTQNSD
1106                      #error
1107                      #endif
1108                      ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
1109   if test "x$have_siocoutqnsd" = "xyes"; then
1110     if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
1111       if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
1112         have_kist_support=yes
1113       fi
1114     fi
1115   fi
1116 ])
1117 dnl Now, trigger the check.
1118 CHECK_KIST_SUPPORT
1119 AS_IF([test "x$have_kist_support" = "xyes"],
1120       [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
1121                                         on this system])],
1122       [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
1123
1124 LIBS="$save_LIBS"
1125 LDFLAGS="$save_LDFLAGS"
1126 CPPFLAGS="$save_CPPFLAGS"
1127
1128 dnl ------------------------------------------------------
1129 dnl Where do you live, zlib?  And how do we call you?
1130
1131 tor_zlib_pkg_redhat="zlib"
1132 tor_zlib_pkg_debian="zlib1g"
1133 tor_zlib_devpkg_redhat="zlib-devel"
1134 tor_zlib_devpkg_debian="zlib1g-dev"
1135
1136 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
1137     [#include <zlib.h>],
1138     [const char * zlibVersion(void);],
1139     [zlibVersion();], [--with-zlib-dir],
1140     [/opt/zlib])
1141
1142 if test "$enable_static_zlib" = "yes"; then
1143    if test "$tor_cv_library_zlib_dir" = "(system)"; then
1144      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
1145  using --enable-static-zlib")
1146    else
1147      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
1148    fi
1149 else
1150      TOR_ZLIB_LIBS="-lz"
1151 fi
1152 AC_SUBST(TOR_ZLIB_LIBS)
1153
1154 dnl ------------------------------------------------------
1155 dnl Where we do we find lzma?
1156
1157 AC_ARG_ENABLE(lzma,
1158       AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
1159       [case "${enableval}" in
1160         "yes") ;;
1161         "no")  ;;
1162         * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
1163       esac], [enable_lzma=auto])
1164
1165 if test "x$enable_lzma" = "xno"; then
1166     have_lzma=no;
1167 else
1168     PKG_CHECK_MODULES([LZMA],
1169                       [liblzma],
1170                       have_lzma=yes,
1171                       have_lzma=no)
1172
1173     if test "x$have_lzma" = "xno" ; then
1174         AC_MSG_WARN([Unable to find liblzma, $pkg_config_user_action, or set LZMA_CFLAGS and LZMA_LIBS.])
1175     fi
1176 fi
1177
1178 if test "x$have_lzma" = "xyes"; then
1179     AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
1180     TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
1181     TOR_LZMA_LIBS="${LZMA_LIBS}"
1182 fi
1183 AC_SUBST(TOR_LZMA_CFLAGS)
1184 AC_SUBST(TOR_LZMA_LIBS)
1185
1186 dnl ------------------------------------------------------
1187 dnl Where we do we find zstd?
1188
1189 AC_ARG_ENABLE(zstd,
1190       AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
1191       [case "${enableval}" in
1192         "yes") ;;
1193         "no")  ;;
1194         * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
1195       esac], [enable_zstd=auto])
1196
1197 if test "x$enable_zstd" = "xno"; then
1198     have_zstd=no;
1199 else
1200     PKG_CHECK_MODULES([ZSTD],
1201                       [libzstd >= 1.1],
1202                       have_zstd=yes,
1203                       have_zstd=no)
1204
1205     if test "x$have_zstd" = "xno" ; then
1206         AC_MSG_WARN([Unable to find libzstd, $pkg_config_user_action, or set ZSTD_CFLAGS and ZSTD_LIBS.])
1207     fi
1208 fi
1209
1210 if test "x$have_zstd" = "xyes"; then
1211     AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
1212     TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
1213     TOR_ZSTD_LIBS="${ZSTD_LIBS}"
1214
1215     dnl now check for zstd functions
1216     save_LIBS="$LIBS"
1217     save_CFLAGS="$CFLAGS"
1218     LIBS="$LIBS $ZSTD_LIBS"
1219     CFLAGS="$CFLAGS $ZSTD_CFLAGS"
1220     AC_CHECK_FUNCS(ZSTD_estimateCStreamSize \
1221                    ZSTD_estimateDCtxSize)
1222     LIBS="$save_LIBS"
1223     CFLAGS="$save_CFLAGS"
1224 fi
1225 AC_SUBST(TOR_ZSTD_CFLAGS)
1226 AC_SUBST(TOR_ZSTD_LIBS)
1227
1228 dnl ----------------------------------------------------------------------
1229 dnl Check if libcap is available for capabilities.
1230
1231 tor_cap_pkg_debian="libcap2"
1232 tor_cap_pkg_redhat="libcap"
1233 tor_cap_devpkg_debian="libcap-dev"
1234 tor_cap_devpkg_redhat="libcap-devel"
1235
1236 AC_CHECK_LIB([cap], [cap_init], [],
1237   AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
1238 )
1239 AC_CHECK_FUNCS(cap_set_proc)
1240
1241 dnl ---------------------------------------------------------------------
1242 dnl Now that we know about our major libraries, we can check for compiler
1243 dnl and linker hardening options.  We need to do this with the libraries known,
1244 dnl since sometimes the linker will like an option but not be willing to
1245 dnl use it with a build of a library.
1246
1247 all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
1248 all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
1249
1250 CFLAGS_FTRAPV=
1251 CFLAGS_FWRAPV=
1252 CFLAGS_ASAN=
1253 CFLAGS_UBSAN=
1254
1255
1256 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1257 #if !defined(__clang__)
1258 #error
1259 #endif])], have_clang=yes, have_clang=no)
1260
1261 if test "x$enable_pic" = "xyes"; then
1262     TOR_CHECK_CFLAGS(-fPIC)
1263 fi
1264
1265 if test "x$enable_gcc_hardening" != "xno"; then
1266     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
1267     if test "x$have_clang" = "xyes"; then
1268         TOR_CHECK_CFLAGS(-Qunused-arguments)
1269     fi
1270     TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
1271     AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
1272     AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
1273 m4_ifdef([AS_VAR_IF],[
1274     AS_VAR_IF(can_compile, [yes],
1275         AS_VAR_IF(can_link, [yes],
1276                   [],
1277                   AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
1278         )])
1279     AS_VAR_POPDEF([can_link])
1280     AS_VAR_POPDEF([can_compile])
1281     TOR_CHECK_CFLAGS(-Wstack-protector)
1282     TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
1283     if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
1284        if test "$enable_pic" != "yes"; then
1285            # If we have already enabled -fPIC, then we don't also need to
1286            # compile with -fPIE...
1287            TOR_CHECK_CFLAGS(-fPIE)
1288        fi
1289        # ... but we want to link our executables with -pie in any case, since
1290        # they're executables, not a library.
1291        TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
1292     fi
1293     TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
1294
1295    AC_MSG_CHECKING([whether we can run hardened binaries])
1296    AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
1297         [AC_MSG_RESULT([yes])],
1298         [AC_MSG_RESULT([no])
1299          AC_MSG_ERROR([dnl
1300  We can link with compiler hardening options, but we can't run with them.
1301  That's a bad sign! If you must, you can pass --disable-gcc-hardening to
1302  configure, but it would be better to figure out what the underlying problem
1303  is.])],
1304         [AC_MSG_RESULT([cross])])
1305 fi
1306
1307 if test "$fragile_hardening" = "yes"; then
1308     TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
1309    if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
1310       AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
1311    fi
1312
1313    if test "$tor_cv_cflags__ftrapv" != "yes"; then
1314      AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
1315    fi
1316
1317    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
1318     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1319       AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.*, and with Clang you need libclang_rt.ubsan*])
1320     fi
1321
1322    TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
1323     if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
1324       AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1325     fi
1326
1327    TOR_TRY_COMPILE_WITH_CFLAGS([-fno-sanitize=float-divide-by-zero], also_link, CFLAGS_UBSAN="-fno-sanitize=float-divide-by-zero", true)
1328     if test "$tor_cv_cflags__fno_sanitize_float_divide_by_zero" = "yes" && test "$tor_can_link__fno_sanitize_float_divide_by_zero" != "yes"; then
1329       AC_MSG_ERROR([The compiler supports -fno-sanitize=float-divide-by-zero, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
1330     fi
1331
1332 TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
1333 fi
1334
1335 dnl Find the correct libraries to add in order to use the sanitizers.
1336 dnl
1337 dnl When building Rust, Cargo will run the linker with the -nodefaultlibs
1338 dnl option, which will prevent the compiler from linking the sanitizer
1339 dnl libraries it needs.  We need to specify them manually.
1340 dnl
1341 dnl What's more, we need to specify them in a linker script rather than
1342 dnl from build.rs: these options aren't allowed in the cargo:rustc-flags
1343 dnl variable.
1344 RUST_LINKER_OPTIONS=""
1345 if test "x$have_clang" = "xyes"; then
1346         if test "x$CFLAGS_ASAN" != "x"; then
1347                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=$CFLAGS_ASAN -Cdefault-linker-libraries"
1348         fi
1349         if test "x$CFLAGS_UBSAN" != "x"; then
1350                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=$CFLAGS_UBSAN -Cdefault-linker-libraries"
1351         fi
1352 else
1353         if test "x$CFLAGS_ASAN" != "x"; then
1354                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=-fsanitize=address -Cdefault-linker-libraries"
1355         fi
1356         if test "x$CFLAGS_UBSAN" != "x"; then
1357                 RUST_LINKER_OPTIONS="$RUST_LINKER_OPTIONS -Clink-arg=-fsanitize=undefined -Cdefault-linker-libraries"
1358         fi
1359 fi
1360 AC_SUBST(RUST_LINKER_OPTIONS)
1361
1362 CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
1363 CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
1364
1365 mulodi_fixes_ftrapv=no
1366 if test "$have_clang" = "yes"; then
1367   saved_CFLAGS="$CFLAGS"
1368   CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
1369   AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
1370   AC_LINK_IFELSE([
1371       AC_LANG_SOURCE([[
1372           #include <stdint.h>
1373           #include <stdlib.h>
1374           int main(int argc, char **argv)
1375           {
1376             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1377                         * (int64_t)atoi(argv[3]);
1378             return x == 9;
1379           } ]])],
1380           [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
1381           [ftrapv_can_link=no; AC_MSG_RESULT([no])])
1382   if test "$ftrapv_can_link" = "no"; then
1383     AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
1384     AC_LINK_IFELSE([
1385       AC_LANG_SOURCE([[
1386           #include <stdint.h>
1387           #include <stdlib.h>
1388           int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
1389              *overflow=0;
1390              return a;
1391           }
1392           int main(int argc, char **argv)
1393           {
1394             int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
1395                         * (int64_t)atoi(argv[3]);
1396             return x == 9;
1397           } ]])],
1398           [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
1399           [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
1400   fi
1401   CFLAGS="$saved_CFLAGS"
1402 fi
1403
1404 AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
1405
1406 dnl These cflags add bunches of branches, and we haven't been able to
1407 dnl persuade ourselves that they're suitable for code that needs to be
1408 dnl constant time.
1409 AC_SUBST(CFLAGS_BUGTRAP)
1410 dnl These cflags are variant ones sutable for code that needs to be
1411 dnl constant-time.
1412 AC_SUBST(CFLAGS_CONSTTIME)
1413
1414 if test "x$enable_linker_hardening" != "xno"; then
1415     TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
1416 fi
1417
1418 # For backtrace support
1419 TOR_CHECK_LDFLAGS(-rdynamic)
1420
1421 dnl ------------------------------------------------------
1422 dnl Now see if we have a -fomit-frame-pointer compiler option.
1423
1424 saved_CFLAGS="$CFLAGS"
1425 TOR_CHECK_CFLAGS(-fomit-frame-pointer)
1426 F_OMIT_FRAME_POINTER=''
1427 if test "$saved_CFLAGS" != "$CFLAGS"; then
1428   if test "$fragile_hardening" = "yes"; then
1429     F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
1430   fi
1431 fi
1432 CFLAGS="$saved_CFLAGS"
1433 AC_SUBST(F_OMIT_FRAME_POINTER)
1434
1435 dnl ------------------------------------------------------
1436 dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
1437 dnl for us, as GCC 4.6 and later do at many optimization levels), then
1438 dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
1439 dnl code will work.
1440 TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
1441
1442 dnl ============================================================
1443 dnl Check for libseccomp
1444
1445 if test "x$enable_seccomp" != "xno"; then
1446   AC_CHECK_HEADERS([seccomp.h])
1447   AC_SEARCH_LIBS(seccomp_init, [seccomp])
1448 fi
1449
1450 dnl ============================================================
1451 dnl Check for libscrypt
1452
1453 if test "x$enable_libscrypt" != "xno"; then
1454   AC_CHECK_HEADERS([libscrypt.h])
1455   AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
1456   AC_CHECK_FUNCS([libscrypt_scrypt])
1457 fi
1458
1459 dnl ============================================================
1460 dnl We need an implementation of curve25519.
1461
1462 dnl set these defaults.
1463 build_curve25519_donna=no
1464 build_curve25519_donna_c64=no
1465 use_curve25519_donna=no
1466 use_curve25519_nacl=no
1467 CURVE25519_LIBS=
1468
1469 dnl The best choice is using curve25519-donna-c64, but that requires
1470 dnl that we
1471 AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
1472   tor_cv_can_use_curve25519_donna_c64,
1473   [AC_RUN_IFELSE(
1474     [AC_LANG_PROGRAM([dnl
1475       #include <stdint.h>
1476       typedef unsigned uint128_t __attribute__((mode(TI)));
1477   int func(uint64_t a, uint64_t b) {
1478            uint128_t c = ((uint128_t)a) * b;
1479            int ok = ((uint64_t)(c>>96)) == 522859 &&
1480              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1481                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1482                  (((uint64_t)(c))&0xffffffffL) == 0;
1483            return ok;
1484       }
1485   ], [dnl
1486     int ok = func( ((uint64_t)2000000000) * 1000000000,
1487                    ((uint64_t)1234567890) << 24);
1488         return !ok;
1489       ])],
1490   [tor_cv_can_use_curve25519_donna_c64=yes],
1491       [tor_cv_can_use_curve25519_donna_c64=no],
1492   [AC_LINK_IFELSE(
1493         [AC_LANG_PROGRAM([dnl
1494       #include <stdint.h>
1495       typedef unsigned uint128_t __attribute__((mode(TI)));
1496   int func(uint64_t a, uint64_t b) {
1497            uint128_t c = ((uint128_t)a) * b;
1498            int ok = ((uint64_t)(c>>96)) == 522859 &&
1499              (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
1500                  (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
1501                  (((uint64_t)(c))&0xffffffffL) == 0;
1502            return ok;
1503       }
1504   ], [dnl
1505     int ok = func( ((uint64_t)2000000000) * 1000000000,
1506                  ((uint64_t)1234567890) << 24);
1507         return !ok;
1508       ])],
1509           [tor_cv_can_use_curve25519_donna_c64=cross],
1510       [tor_cv_can_use_curve25519_donna_c64=no])])])
1511
1512 AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
1513                   nacl/crypto_scalarmult_curve25519.h])
1514
1515 AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
1516   tor_cv_can_use_curve25519_nacl,
1517   [tor_saved_LIBS="$LIBS"
1518    LIBS="$LIBS -lnacl"
1519    AC_LINK_IFELSE(
1520      [AC_LANG_PROGRAM([dnl
1521        #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
1522        #include <crypto_scalarmult_curve25519.h>
1523    #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
1524    #include <nacl/crypto_scalarmult_curve25519.h>
1525    #endif
1526        #ifdef crypto_scalarmult_curve25519_ref_BYTES
1527    #error Hey, this is the reference implementation! That's not fast.
1528    #endif
1529      ], [
1530    unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
1531      ])], [tor_cv_can_use_curve25519_nacl=yes],
1532      [tor_cv_can_use_curve25519_nacl=no])
1533    LIBS="$tor_saved_LIBS" ])
1534
1535  dnl Okay, now we need to figure out which one to actually use. Fall back
1536  dnl to curve25519-donna.c
1537
1538  if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
1539    build_curve25519_donna_c64=yes
1540    use_curve25519_donna=yes
1541  elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
1542    use_curve25519_nacl=yes
1543    CURVE25519_LIBS=-lnacl
1544  else
1545    build_curve25519_donna=yes
1546    use_curve25519_donna=yes
1547  fi
1548
1549 if test "x$use_curve25519_donna" = "xyes"; then
1550   AC_DEFINE(USE_CURVE25519_DONNA, 1,
1551             [Defined if we should use an internal curve25519_donna{,_c64} implementation])
1552 fi
1553 if test "x$use_curve25519_nacl" = "xyes"; then
1554   AC_DEFINE(USE_CURVE25519_NACL, 1,
1555             [Defined if we should use a curve25519 from nacl])
1556 fi
1557 AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
1558   test "x$build_curve25519_donna" = "xyes")
1559 AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
1560   test "x$build_curve25519_donna_c64" = "xyes")
1561 AC_SUBST(CURVE25519_LIBS)
1562
1563 dnl Make sure to enable support for large off_t if available.
1564 AC_SYS_LARGEFILE
1565
1566 AC_CHECK_HEADERS([errno.h \
1567                   fcntl.h \
1568                   signal.h \
1569                   string.h \
1570                   sys/capability.h \
1571                   sys/fcntl.h \
1572                   sys/stat.h \
1573                   sys/time.h \
1574                   sys/types.h \
1575                   time.h \
1576                   unistd.h \
1577                   arpa/inet.h \
1578                   crt_externs.h \
1579                   execinfo.h \
1580                   gnu/libc-version.h \
1581                   grp.h \
1582                   ifaddrs.h \
1583                   inttypes.h \
1584                   limits.h \
1585                   linux/types.h \
1586                   mach/vm_inherit.h \
1587                   machine/limits.h \
1588                   malloc.h \
1589                   malloc/malloc.h \
1590                   malloc_np.h \
1591                   netdb.h \
1592                   netinet/in.h \
1593                   netinet/in6.h \
1594                   pwd.h \
1595                   readpassphrase.h \
1596                   stdatomic.h \
1597                   sys/eventfd.h \
1598                   sys/file.h \
1599                   sys/ioctl.h \
1600                   sys/limits.h \
1601                   sys/mman.h \
1602                   sys/param.h \
1603                   sys/prctl.h \
1604                   sys/random.h \
1605                   sys/resource.h \
1606                   sys/select.h \
1607                   sys/socket.h \
1608                   sys/statvfs.h \
1609                   sys/syscall.h \
1610                   sys/sysctl.h \
1611                   sys/syslimits.h \
1612                   sys/time.h \
1613                   sys/types.h \
1614                   sys/un.h \
1615                   sys/utime.h \
1616                   sys/wait.h \
1617                   syslog.h \
1618                   utime.h])
1619
1620 AC_CHECK_HEADERS(sys/param.h)
1621
1622 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
1623 [#ifdef HAVE_SYS_TYPES_H
1624 #include <sys/types.h>
1625 #endif
1626 #ifdef HAVE_SYS_SOCKET_H
1627 #include <sys/socket.h>
1628 #endif])
1629 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
1630 [#ifdef HAVE_SYS_TYPES_H
1631 #include <sys/types.h>
1632 #endif
1633 #ifdef HAVE_SYS_SOCKET_H
1634 #include <sys/socket.h>
1635 #endif
1636 #ifdef HAVE_NET_IF_H
1637 #include <net/if.h>
1638 #endif
1639 #ifdef HAVE_NETINET_IN_H
1640 #include <netinet/in.h>
1641 #endif])
1642
1643 AC_CHECK_HEADERS(linux/if.h,[],[],
1644 [
1645 #ifdef HAVE_SYS_SOCKET_H
1646 #include <sys/socket.h>
1647 #endif
1648 ])
1649
1650 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
1651         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
1652 [#ifdef HAVE_SYS_TYPES_H
1653 #include <sys/types.h>
1654 #endif
1655 #ifdef HAVE_SYS_SOCKET_H
1656 #include <sys/socket.h>
1657 #endif
1658 #ifdef HAVE_LIMITS_H
1659 #include <limits.h>
1660 #endif
1661 #ifdef HAVE_LINUX_TYPES_H
1662 #include <linux/types.h>
1663 #endif
1664 #ifdef HAVE_NETINET_IN6_H
1665 #include <netinet/in6.h>
1666 #endif
1667 #ifdef HAVE_NETINET_IN_H
1668 #include <netinet/in.h>
1669 #endif])
1670
1671 AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
1672         linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
1673 [#ifdef HAVE_SYS_TYPES_H
1674 #include <sys/types.h>
1675 #endif
1676 #ifdef HAVE_SYS_SOCKET_H
1677 #include <sys/socket.h>
1678 #endif
1679 #ifdef HAVE_LIMITS_H
1680 #include <limits.h>
1681 #endif
1682 #ifdef HAVE_LINUX_TYPES_H
1683 #include <linux/types.h>
1684 #endif
1685 #ifdef HAVE_NETINET_IN6_H
1686 #include <netinet/in6.h>
1687 #endif
1688 #ifdef HAVE_NETINET_IN_H
1689 #include <netinet/in.h>
1690 #endif
1691 #ifdef HAVE_LINUX_IF_H
1692 #include <linux/if.h>
1693 #endif])
1694
1695 transparent_ok=0
1696 if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
1697   transparent_ok=1
1698 fi
1699 if test "x$linux_netfilter_ipv4" = "x1"; then
1700   transparent_ok=1
1701 fi
1702 if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
1703   transparent_ok=1
1704 fi
1705 if test "x$transparent_ok" = "x1"; then
1706   AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
1707 else
1708   AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
1709 fi
1710
1711 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
1712 [#ifdef HAVE_SYS_TYPES_H
1713 #include <sys/types.h>
1714 #endif
1715 #ifdef HAVE_SYS_TIME_H
1716 #include <sys/time.h>
1717 #endif])
1718
1719 AC_CHECK_SIZEOF(char)
1720 AC_CHECK_SIZEOF(short)
1721 AC_CHECK_SIZEOF(int)
1722 AC_CHECK_SIZEOF(unsigned int)
1723 AC_CHECK_SIZEOF(long)
1724 AC_CHECK_SIZEOF(long long)
1725 AC_CHECK_SIZEOF(__int64)
1726 AC_CHECK_SIZEOF(void *)
1727 AC_CHECK_SIZEOF(time_t)
1728 AC_CHECK_SIZEOF(size_t)
1729 AC_CHECK_SIZEOF(pid_t)
1730
1731 AC_CHECK_TYPES([uint, u_char, ssize_t])
1732
1733 AC_PC_FROM_UCONTEXT([:])
1734
1735 dnl used to include sockaddr_storage, but everybody has that.
1736 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
1737 [#ifdef HAVE_SYS_TYPES_H
1738 #include <sys/types.h>
1739 #endif
1740 #ifdef HAVE_NETINET_IN_H
1741 #include <netinet/in.h>
1742 #endif
1743 #ifdef HAVE_NETINET_IN6_H
1744 #include <netinet/in6.h>
1745 #endif
1746 #ifdef HAVE_SYS_SOCKET_H
1747 #include <sys/socket.h>
1748 #endif
1749 #ifdef _WIN32
1750 #define _WIN32_WINNT 0x0501
1751 #define WIN32_LEAN_AND_MEAN
1752 #include <winsock2.h>
1753 #include <ws2tcpip.h>
1754 #endif
1755 ])
1756 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
1757 [#ifdef HAVE_SYS_TYPES_H
1758 #include <sys/types.h>
1759 #endif
1760 #ifdef HAVE_NETINET_IN_H
1761 #include <netinet/in.h>
1762 #endif
1763 #ifdef HAVE_NETINET_IN6_H
1764 #include <netinet/in6.h>
1765 #endif
1766 #ifdef HAVE_SYS_SOCKET_H
1767 #include <sys/socket.h>
1768 #endif
1769 #ifdef _WIN32
1770 #define _WIN32_WINNT 0x0501
1771 #define WIN32_LEAN_AND_MEAN
1772 #include <winsock2.h>
1773 #include <ws2tcpip.h>
1774 #endif
1775 ])
1776
1777 AC_CHECK_TYPES([rlim_t], , ,
1778 [#ifdef HAVE_SYS_TYPES_H
1779 #include <sys/types.h>
1780 #endif
1781 #ifdef HAVE_SYS_TIME_H
1782 #include <sys/time.h>
1783 #endif
1784 #ifdef HAVE_SYS_RESOURCE_H
1785 #include <sys/resource.h>
1786 #endif
1787 ])
1788
1789 AX_CHECK_SIGN([time_t],
1790        [ : ],
1791        [ : ], [
1792 #ifdef HAVE_SYS_TYPES_H
1793 #include <sys/types.h>
1794 #endif
1795 #ifdef HAVE_SYS_TIME_H
1796 #include <sys/time.h>
1797 #endif
1798 #ifdef HAVE_TIME_H
1799 #include <time.h>
1800 #endif
1801 ])
1802
1803 if test "$ax_cv_decl_time_t_signed" = "no"; then
1804   AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
1805 fi
1806
1807 AX_CHECK_SIGN([size_t],
1808        [ tor_cv_size_t_signed=yes ],
1809        [ tor_cv_size_t_signed=no ], [
1810 #ifdef HAVE_SYS_TYPES_H
1811 #include <sys/types.h>
1812 #endif
1813 ])
1814
1815 if test "$ax_cv_decl_size_t_signed" = "yes"; then
1816   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
1817 fi
1818
1819 AX_CHECK_SIGN([enum always],
1820        [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
1821        [ : ], [
1822  enum always { AAA, BBB, CCC };
1823 ])
1824
1825 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
1826 #ifdef HAVE_SYS_SOCKET_H
1827 #include <sys/socket.h>
1828 #endif
1829 ])
1830
1831 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
1832
1833 AC_CHECK_SIZEOF(cell_t)
1834
1835 # Let's see if stdatomic works. (There are some debian clangs that screw it
1836 # up; see Tor bug #26779 and debian bug 903709.)
1837 AC_CACHE_CHECK([whether C11 stdatomic.h actually works],
1838                tor_cv_stdatomic_works,
1839 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1840 #include <stdatomic.h>
1841 struct x { atomic_size_t y; };
1842 void try_atomic_init(struct x *xx)
1843 {
1844   atomic_init(&xx->y, 99);
1845   atomic_fetch_add(&xx->y, 1);
1846 }
1847 ]])], [tor_cv_stdatomic_works=yes], [tor_cv_stdatomic_works=no])])
1848
1849 if test "$tor_cv_stdatomic_works" = "yes"; then
1850    AC_DEFINE(STDATOMIC_WORKS, 1, [Set to 1 if we can compile a simple stdatomic example.])
1851 elif test "$ac_cv_header_stdatomic_h" = "yes"; then
1852    AC_MSG_WARN([Your compiler provides the stdatomic.h header, but it doesn't seem to work.  I'll pretend it isn't there. If you are using Clang on Debian, maybe this is because of https://bugs.debian.org/903709 ])
1853 fi
1854
1855 # Now make sure that NULL can be represented as zero bytes.
1856 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
1857 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1858 [[#include <stdlib.h>
1859 #include <string.h>
1860 #include <stdio.h>
1861 #ifdef HAVE_STDDEF_H
1862 #include <stddef.h>
1863 #endif
1864 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
1865 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
1866        [tor_cv_null_is_zero=yes],
1867        [tor_cv_null_is_zero=no],
1868        [tor_cv_null_is_zero=cross])])
1869
1870 if test "$tor_cv_null_is_zero" = "cross"; then
1871   # Cross-compiling; let's hope that the target isn't raving mad.
1872   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
1873 fi
1874
1875 if test "$tor_cv_null_is_zero" != "no"; then
1876   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
1877             [Define to 1 iff memset(0) sets pointers to NULL])
1878 fi
1879
1880 AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
1881 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1882 [[#include <stdlib.h>
1883 #include <string.h>
1884 #include <stdio.h>
1885 #ifdef HAVE_STDDEF_H
1886 #include <stddef.h>
1887 #endif
1888 int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
1889 return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
1890        [tor_cv_dbl0_is_zero=yes],
1891        [tor_cv_dbl0_is_zero=no],
1892        [tor_cv_dbl0_is_zero=cross])])
1893
1894 if test "$tor_cv_dbl0_is_zero" = "cross"; then
1895   # Cross-compiling; let's hope that the target isn't raving mad.
1896   AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
1897 fi
1898
1899 if test "$tor_cv_dbl0_is_zero" != "no"; then
1900   AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
1901             [Define to 1 iff memset(0) sets doubles to 0.0])
1902 fi
1903
1904 # And what happens when we malloc zero?
1905 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
1906 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1907 [[#include <stdlib.h>
1908 #include <string.h>
1909 #include <stdio.h>
1910 #ifdef HAVE_STDDEF_H
1911 #include <stddef.h>
1912 #endif
1913 int main () { return malloc(0)?0:1; }]])],
1914        [tor_cv_malloc_zero_works=yes],
1915        [tor_cv_malloc_zero_works=no],
1916        [tor_cv_malloc_zero_works=cross])])
1917
1918 if test "$tor_cv_malloc_zero_works" = "cross"; then
1919   # Cross-compiling; let's hope that the target isn't raving mad.
1920   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
1921 fi
1922
1923 if test "$tor_cv_malloc_zero_works" = "yes"; then
1924   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
1925             [Define to 1 iff malloc(0) returns a pointer])
1926 fi
1927
1928 # whether we seem to be in a 2s-complement world.
1929 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
1930 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1931 [[int main () { int problem = ((-99) != (~99)+1);
1932 return problem ? 1 : 0; }]])],
1933        [tor_cv_twos_complement=yes],
1934        [tor_cv_twos_complement=no],
1935        [tor_cv_twos_complement=cross])])
1936
1937 if test "$tor_cv_twos_complement" = "cross"; then
1938   # Cross-compiling; let's hope that the target isn't raving mad.
1939   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
1940 fi
1941
1942 if test "$tor_cv_twos_complement" != "no"; then
1943   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
1944             [Define to 1 iff we represent negative integers with
1945              two's complement])
1946 fi
1947
1948 # What does shifting a negative value do?
1949 AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
1950 [AC_RUN_IFELSE([AC_LANG_SOURCE(
1951 [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
1952        [tor_cv_sign_extend=yes],
1953        [tor_cv_sign_extend=no],
1954        [tor_cv_sign_extend=cross])])
1955
1956 if test "$tor_cv_sign_extend" = "cross"; then
1957   # Cross-compiling; let's hope that the target isn't raving mad.
1958   AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
1959 fi
1960
1961 if test "$tor_cv_sign_extend" != "no"; then
1962   AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
1963             [Define to 1 iff right-shifting a negative value performs sign-extension])
1964 fi
1965
1966 # Is uint8_t the same type as unsigned char?
1967 AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
1968 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1969 #include <stdint.h>
1970 extern uint8_t c;
1971 unsigned char c;]])],
1972        [tor_cv_uint8_uchar=yes],
1973        [tor_cv_uint8_uchar=no],
1974        [tor_cv_uint8_uchar=cross])])
1975
1976 if test "$tor_cv_uint8_uchar" = "cross"; then
1977   AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
1978 fi
1979
1980 if test "$tor_cv_uint8_uchar" = "no"; then
1981   AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
1982 fi
1983
1984 AC_ARG_WITH(tcmalloc,
1985 AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library. Deprecated; see --with-malloc]))
1986
1987 default_malloc=system
1988
1989 if test "x$enable_openbsd_malloc" = "xyes" ; then
1990   AC_MSG_NOTICE([The --enable-openbsd-malloc argument is deprecated; use --with-malloc=openbsd instead.])
1991   default_malloc=openbsd
1992 fi
1993
1994 if test "x$with_tcmalloc" = "xyes"; then
1995   AC_MSG_NOTICE([The --with-tcmalloc argument is deprecated; use --with-malloc=tcmalloc instead.])
1996   default_malloc=tcmalloc
1997 fi
1998
1999 AC_ARG_WITH(malloc,
2000    AS_HELP_STRING([--with-malloc=[system,jemalloc,tcmalloc,openbsd]],
2001                   [select special malloc implementation [system]]),
2002    [ malloc="$with_malloc" ], [ malloc="$default_malloc" ])
2003
2004 AS_CASE([$malloc],
2005   [tcmalloc], [
2006       PKG_CHECK_MODULES([TCMALLOC],
2007                         [libtcmalloc],
2008                         have_tcmalloc=yes,
2009                         have_tcmalloc=no)
2010
2011       if test "x$have_tcmalloc" = "xno" ; then
2012           AC_MSG_ERROR([Unable to find tcmalloc requested by --with-malloc, $pkg_config_user_action, or set TCMALLOC_CFLAGS and TCMALLOC_LIBS.])
2013       fi
2014
2015       CFLAGS="$CFLAGS $TCMALLOC_CFLAGS"
2016       LIBS="$TCMALLOC_LIBS $LIBS"
2017   ],
2018
2019   [jemalloc], [
2020       PKG_CHECK_MODULES([JEMALLOC],
2021                         [jemalloc],
2022                         have_jemalloc=yes,
2023                         have_jemalloc=no)
2024
2025       if test "x$have_jemalloc" = "xno" ; then
2026           AC_MSG_ERROR([Unable to find jemalloc requested by --with-malloc, $pkg_config_user_action, or set JEMALLOC_CFLAGS and JEMALLOC_LIBS.])
2027       fi
2028
2029       CFLAGS="$CFLAGS $JEMALLOC_CFLAGS"
2030       LIBS="$JEMALLOC_LIBS $LIBS"
2031       using_custom_malloc=yes
2032   ],
2033
2034   [openbsd], [
2035     AC_MSG_WARN([The openbsd malloc port is deprecated in Tor 0.3.5 and will be removed in a future version.])
2036     enable_openbsd_malloc=yes
2037   ],
2038
2039   [system], [
2040      # handle this later, including the jemalloc fallback
2041     AC_CHECK_FUNCS(mallinfo)
2042   ],
2043
2044   [AC_MSG_ERROR([--with-malloc=`$with_malloc' not supported, see --help])
2045 ])
2046
2047 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
2048
2049 if test "$malloc" != "system"; then
2050   # Tell the C compiler not to use the system allocator functions.
2051   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
2052 fi
2053 if test "$using_custom_malloc" = "yes"; then
2054   # Tell the C compiler not to use the system allocator functions.
2055   TOR_CHECK_CFLAGS([-fno-builtin-malloc -fno-builtin-realloc -fno-builtin-calloc -fno-builtin-free])
2056 fi
2057
2058 # By default, we're going to assume we don't have mlockall()
2059 # bionic and other platforms have various broken mlockall subsystems.
2060 # Some systems don't have a working mlockall, some aren't linkable,
2061 # and some have it but don't declare it.
2062 AC_CHECK_FUNCS(mlockall)
2063 AC_CHECK_DECLS([mlockall], , , [
2064 #ifdef HAVE_SYS_MMAN_H
2065 #include <sys/mman.h>
2066 #endif])
2067
2068 # Allow user to specify an alternate syslog facility
2069 AC_ARG_WITH(syslog-facility,
2070 AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
2071 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
2072 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
2073 AC_SUBST(LOGFACILITY)
2074
2075 # Check if we have getresuid and getresgid
2076 AC_CHECK_FUNCS(getresuid getresgid)
2077
2078 # Check for gethostbyname_r in all its glorious incompatible versions.
2079 #   (This logic is based on that in Python's configure.in)
2080 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
2081   [Define this if you have any gethostbyname_r()])
2082
2083 AC_CHECK_FUNC(gethostbyname_r, [
2084   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
2085   OLD_CFLAGS=$CFLAGS
2086   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
2087   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2088 #include <netdb.h>
2089   ]], [[
2090     char *cp1, *cp2;
2091     struct hostent *h1, *h2;
2092     int i1, i2;
2093     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
2094   ]])],[
2095     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
2096     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
2097      [Define this if gethostbyname_r takes 6 arguments])
2098     AC_MSG_RESULT(6)
2099   ], [
2100     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2101 #include <netdb.h>
2102     ]], [[
2103       char *cp1, *cp2;
2104       struct hostent *h1;
2105       int i1, i2;
2106       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
2107     ]])], [
2108       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
2109       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
2110         [Define this if gethostbyname_r takes 5 arguments])
2111       AC_MSG_RESULT(5)
2112    ], [
2113       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2114 #include <netdb.h>
2115      ]], [[
2116        char *cp1;
2117        struct hostent *h1;
2118        struct hostent_data hd;
2119        (void) gethostbyname_r(cp1,h1,&hd);
2120      ]])], [
2121        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
2122        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
2123          [Define this if gethostbyname_r takes 3 arguments])
2124        AC_MSG_RESULT(3)
2125      ], [
2126        AC_MSG_RESULT(0)
2127      ])
2128   ])
2129  ])
2130  CFLAGS=$OLD_CFLAGS
2131 ])
2132
2133 AC_CACHE_CHECK([whether the C compiler supports __func__],
2134   tor_cv_have_func_macro,
2135   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2136 #include <stdio.h>
2137 int main(int c, char **v) { puts(__func__); }])],
2138   tor_cv_have_func_macro=yes,
2139   tor_cv_have_func_macro=no))
2140
2141 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
2142   tor_cv_have_FUNC_macro,
2143   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2144 #include <stdio.h>
2145 int main(int c, char **v) { puts(__FUNC__); }])],
2146   tor_cv_have_FUNC_macro=yes,
2147   tor_cv_have_FUNC_macro=no))
2148
2149 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
2150   tor_cv_have_FUNCTION_macro,
2151   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2152 #include <stdio.h>
2153 int main(int c, char **v) { puts(__FUNCTION__); }])],
2154   tor_cv_have_FUNCTION_macro=yes,
2155   tor_cv_have_FUNCTION_macro=no))
2156
2157 AC_CACHE_CHECK([whether we have extern char **environ already declared],
2158   tor_cv_have_environ_declared,
2159   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2160 #ifdef HAVE_UNISTD_H
2161 #include <unistd.h>
2162 #endif
2163 #include <stdlib.h>
2164 int main(int c, char **v) { char **t = environ; }])],
2165   tor_cv_have_environ_declared=yes,
2166   tor_cv_have_environ_declared=no))
2167
2168 if test "$tor_cv_have_func_macro" = "yes"; then
2169   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
2170 fi
2171
2172 if test "$tor_cv_have_FUNC_macro" = "yes"; then
2173   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
2174 fi
2175
2176 if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
2177   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
2178            [Defined if the compiler supports __FUNCTION__])
2179 fi
2180
2181 if test "$tor_cv_have_environ_declared" = "yes"; then
2182   AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
2183            [Defined if we have extern char **environ already declared])
2184 fi
2185
2186 # $prefix stores the value of the --prefix command line option, or
2187 # NONE if the option wasn't set.  In the case that it wasn't set, make
2188 # it be the default, so that we can use it to expand directories now.
2189 if test "x$prefix" = "xNONE"; then
2190   prefix=$ac_default_prefix
2191 fi
2192
2193 # and similarly for $exec_prefix
2194 if test "x$exec_prefix" = "xNONE"; then
2195   exec_prefix=$prefix
2196 fi
2197
2198 if test "x$BUILDDIR" = "x"; then
2199   BUILDDIR=`pwd`
2200 fi
2201 AC_SUBST(BUILDDIR)
2202 AH_TEMPLATE([BUILDDIR],[tor's build directory])
2203 AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
2204
2205 if test "x$SRCDIR" = "x"; then
2206   SRCDIR=$(cd "$srcdir"; pwd)
2207 fi
2208 AH_TEMPLATE([SRCDIR],[tor's sourcedir directory])
2209 AC_DEFINE_UNQUOTED(SRCDIR,"$SRCDIR")
2210
2211 if test "x$CONFDIR" = "x"; then
2212   CONFDIR=`eval echo $sysconfdir/tor`
2213 fi
2214 AC_SUBST(CONFDIR)
2215 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
2216 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
2217
2218 BINDIR=`eval echo $bindir`
2219 AC_SUBST(BINDIR)
2220 LOCALSTATEDIR=`eval echo $localstatedir`
2221 AC_SUBST(LOCALSTATEDIR)
2222
2223 if test "$bwin32" = "true"; then
2224   # Test if the linker supports the --nxcompat and --dynamicbase options
2225   # for Windows
2226   save_LDFLAGS="$LDFLAGS"
2227   LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
2228   AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
2229   AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
2230     [AC_MSG_RESULT([yes])]
2231     [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
2232     [AC_MSG_RESULT([no])]
2233   )
2234   LDFLAGS="$save_LDFLAGS"
2235 fi
2236
2237 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
2238 # than autoconf's macros like.
2239 if test "$GCC" = "yes"; then
2240   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
2241   # accident waiting to happen.
2242   CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
2243 else
2244   # Override optimization level for non-gcc compilers
2245   CFLAGS="$CFLAGS -O"
2246   enable_gcc_warnings=no
2247   enable_gcc_warnings_advisory=no
2248 fi
2249
2250 # Warnings implies advisory-warnings and -Werror.
2251 if test "$enable_gcc_warnings" = "yes"; then
2252   enable_gcc_warnings_advisory=yes
2253   enable_fatal_warnings=yes
2254 fi
2255
2256 # OS X Lion started deprecating the system openssl. Let's just disable
2257 # all deprecation warnings on OS X. Also, to potentially make the binary
2258 # a little smaller, let's enable dead_strip.
2259 case "$host_os" in
2260
2261  darwin*)
2262     CFLAGS="$CFLAGS -Wno-deprecated-declarations"
2263     LDFLAGS="$LDFLAGS -dead_strip" ;;
2264 esac
2265
2266 TOR_WARNING_FLAGS=""
2267
2268 # Add some more warnings which we use in development but not in the
2269 # released versions.  (Some relevant gcc versions can't handle these.)
2270 #
2271 # Note that we have to do this near the end  of the autoconf process, or
2272 # else we may run into problems when these warnings hit on the testing C
2273 # programs that autoconf wants to build.
2274 if test "x$enable_gcc_warnings_advisory" != "xno"; then
2275
2276   case "$host" in
2277     *-*-openbsd* | *-*-bitrig*)
2278       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
2279       # That's fine, except that the headers don't pass -Wredundant-decls.
2280       # Therefore, let's disable -Wsystem-headers when we're building
2281       # with maximal warnings on OpenBSD.
2282       CFLAGS="$CFLAGS -Wno-system-headers" ;;
2283   esac
2284
2285   CFLAGS_NOWARNINGS="$CFLAGS"
2286
2287   # GCC4.3 users once report trouble with -Wstrict-overflow=5.  GCC5 users
2288   # have it work better.
2289   # CFLAGS="$CFLAGS -Wstrict-overflow=1"
2290
2291   # This warning was added in gcc 4.3, but it appears to generate
2292   # spurious warnings in gcc 4.4.  I don't know if it works in 4.5.
2293   #CFLAGS="$CFLAGS -Wlogical-op"
2294
2295   m4_foreach_w([warning_flag], [
2296      -Waddress
2297      -Waddress-of-array-temporary
2298      -Waddress-of-temporary
2299      -Wambiguous-macro
2300      -Wanonymous-pack-parens
2301      -Warc
2302      -Warc-abi
2303      -Warc-bridge-casts-disallowed-in-nonarc
2304      -Warc-maybe-repeated-use-of-weak
2305      -Warc-performSelector-leaks
2306      -Warc-repeated-use-of-weak
2307      -Warray-bounds
2308      -Warray-bounds-pointer-arithmetic
2309      -Wasm
2310      -Wasm-operand-widths
2311      -Watomic-properties
2312      -Watomic-property-with-user-defined-accessor
2313      -Wauto-import
2314      -Wauto-storage-class
2315      -Wauto-var-id
2316      -Wavailability
2317      -Wbackslash-newline-escape
2318      -Wbad-array-new-length
2319      -Wbind-to-temporary-copy
2320      -Wbitfield-constant-conversion
2321      -Wbool-conversion
2322      -Wbool-conversions
2323      -Wbuiltin-requires-header
2324      -Wchar-align
2325      -Wcompare-distinct-pointer-types
2326      -Wcomplex-component-init
2327      -Wconditional-type-mismatch
2328      -Wconfig-macros
2329      -Wconstant-conversion
2330      -Wconstant-logical-operand
2331      -Wconstexpr-not-const
2332      -Wcustom-atomic-properties
2333      -Wdangling-field
2334      -Wdangling-initializer-list
2335      -Wdate-time
2336      -Wdelegating-ctor-cycles
2337      -Wdeprecated-implementations
2338      -Wdeprecated-register
2339      -Wdirect-ivar-access
2340      -Wdiscard-qual
2341      -Wdistributed-object-modifiers
2342      -Wdivision-by-zero
2343      -Wdollar-in-identifier-extension
2344      -Wdouble-promotion
2345      -Wduplicate-decl-specifier
2346      -Wduplicate-enum
2347      -Wduplicate-method-arg
2348      -Wduplicate-method-match
2349      -Wduplicated-cond
2350      -Wdynamic-class-memaccess
2351      -Wembedded-directive
2352      -Wempty-translation-unit
2353      -Wenum-conversion
2354      -Wexit-time-destructors
2355      -Wexplicit-ownership-type
2356      -Wextern-initializer
2357      -Wextra
2358      -Wextra-semi
2359      -Wextra-tokens
2360      -Wflexible-array-extensions
2361      -Wfloat-conversion
2362      -Wformat-non-iso
2363      -Wfour-char-constants
2364      -Wgcc-compat
2365      -Wglobal-constructors
2366      -Wgnu-array-member-paren-init
2367      -Wgnu-designator
2368      -Wgnu-static-float-init
2369      -Wheader-guard
2370      -Wheader-hygiene
2371      -Widiomatic-parentheses
2372      -Wignored-attributes
2373      -Wimplicit-atomic-properties
2374      -Wimplicit-conversion-floating-point-to-bool
2375      -Wimplicit-exception-spec-mismatch
2376      -Wimplicit-fallthrough
2377      -Wimplicit-fallthrough-per-function
2378      -Wimplicit-retain-self
2379      -Wimport-preprocessor-directive-pedantic
2380      -Wincompatible-library-redeclaration
2381      -Wincompatible-pointer-types-discards-qualifiers
2382      -Wincomplete-implementation
2383      -Wincomplete-module
2384      -Wincomplete-umbrella
2385      -Winit-self
2386      -Wint-conversions
2387      -Wint-to-void-pointer-cast
2388      -Winteger-overflow
2389      -Winvalid-constexpr
2390      -Winvalid-iboutlet
2391      -Winvalid-noreturn
2392      -Winvalid-pp-token
2393      -Winvalid-source-encoding
2394      -Winvalid-token-paste
2395      -Wknr-promoted-parameter
2396      -Wlarge-by-value-copy
2397      -Wliteral-conversion
2398      -Wliteral-range
2399      -Wlocal-type-template-args
2400      -Wlogical-op
2401      -Wloop-analysis
2402      -Wmain-return-type
2403      -Wmalformed-warning-check
2404      -Wmethod-signatures
2405      -Wmicrosoft
2406      -Wmicrosoft-exists
2407      -Wmismatched-parameter-types
2408      -Wmismatched-return-types
2409      -Wmissing-field-initializers
2410      -Wmissing-format-attribute
2411      -Wmissing-noreturn
2412      -Wmissing-selector-name
2413      -Wmissing-sysroot
2414      -Wmissing-variable-declarations
2415      -Wmodule-conflict
2416      -Wnested-anon-types
2417      -Wnewline-eof
2418      -Wnon-literal-null-conversion
2419      -Wnon-pod-varargs
2420      -Wnonportable-cfstrings
2421      -Wnormalized=nfkc
2422      -Wnull-arithmetic
2423      -Wnull-character
2424      -Wnull-conversion
2425      -Wnull-dereference
2426      -Wout-of-line-declaration
2427      -Wover-aligned
2428      -Woverlength-strings
2429      -Woverride-init
2430      -Woverriding-method-mismatch
2431      -Wpointer-type-mismatch
2432      -Wpredefined-identifier-outside-function
2433      -Wprotocol-property-synthesis-ambiguity
2434      -Wreadonly-iboutlet-property
2435      -Wreadonly-setter-attrs
2436      -Wreceiver-expr
2437      -Wreceiver-forward-class
2438      -Wreceiver-is-weak
2439      -Wreinterpret-base-class
2440      -Wrequires-super-attribute
2441      -Wreserved-user-defined-literal
2442      -Wreturn-stack-address
2443      -Wsection
2444      -Wselector-type-mismatch
2445      -Wsentinel
2446      -Wserialized-diagnostics
2447      -Wshadow
2448      -Wshift-count-negative
2449      -Wshift-count-overflow
2450      -Wshift-negative-value
2451      -Wshift-overflow=2
2452      -Wshift-sign-overflow
2453      -Wshorten-64-to-32
2454      -Wsizeof-array-argument
2455      -Wsource-uses-openmp
2456      -Wstatic-float-init
2457      -Wstatic-in-inline
2458      -Wstatic-local-in-inline
2459      -Wstrict-overflow=1
2460      -Wstring-compare
2461      -Wstring-conversion
2462      -Wstrlcpy-strlcat-size
2463      -Wstrncat-size
2464      -Wsuggest-attribute=format
2465      -Wsuggest-attribute=noreturn
2466      -Wsuper-class-method-mismatch
2467      -Wswitch-bool
2468      -Wsync-nand
2469      -Wtautological-constant-out-of-range-compare
2470      -Wtentative-definition-incomplete-type
2471      -Wtrampolines
2472      -Wtype-safety
2473      -Wtypedef-redefinition
2474      -Wtypename-missing
2475      -Wundefined-inline
2476      -Wundefined-internal
2477      -Wundefined-reinterpret-cast
2478      -Wunicode
2479      -Wunicode-whitespace
2480      -Wunknown-warning-option
2481      -Wunnamed-type-template-args
2482      -Wunneeded-member-function
2483      -Wunsequenced
2484      -Wunsupported-visibility
2485      -Wunused-but-set-parameter
2486      -Wunused-but-set-variable
2487      -Wunused-command-line-argument
2488      -Wunused-const-variable=2
2489      -Wunused-exception-parameter
2490      -Wunused-local-typedefs
2491      -Wunused-member-function
2492      -Wunused-sanitize-argument
2493      -Wunused-volatile-lvalue
2494      -Wuser-defined-literals
2495      -Wvariadic-macros
2496      -Wvector-conversion
2497      -Wvector-conversions
2498      -Wvexing-parse
2499      -Wvisibility
2500      -Wvla-extension
2501      -Wzero-length-array
2502   ], [ TOR_TRY_COMPILE_WITH_CFLAGS(warning_flag, [],
2503               [TOR_WARNING_FLAGS="$TOR_WARNING_FLAGS warning_flag" CFLAGS="$CFLAGS warning_flag"], true)
2504      ])
2505
2506 dnl    We should re-enable this in some later version.  Clang doesn't
2507 dnl    mind, but it causes trouble with GCC.
2508 dnl     -Wstrict-overflow=2
2509
2510 dnl    These seem to require annotations that we don't currently use,
2511 dnl    and they give false positives in our pthreads wrappers. (Clang 4)
2512 dnl     -Wthread-safety
2513 dnl     -Wthread-safety-analysis
2514 dnl     -Wthread-safety-attributes
2515 dnl     -Wthread-safety-beta
2516 dnl     -Wthread-safety-precise
2517
2518   W_FLAGS="$W_FLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
2519   W_FLAGS="$W_FLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
2520   W_FLAGS="$W_FLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
2521   W_FLAGS="$W_FLAGS -Wwrite-strings"
2522   W_FLAGS="$W_FLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
2523   W_FLAGS="$W_FLAGS -Waggregate-return -Wpacked -Wunused"
2524   W_FLAGS="$W_FLAGS -Wunused-parameter "
2525   # These interfere with building main() { return 0; }, which autoconf
2526   # likes to use as its default program.
2527   W_FLAGS="$W_FLAGS -Wold-style-definition -Wmissing-declarations"
2528
2529   TOR_WARNING_FLAGS="$TOR_WARNING_FLAGS $W_FLAGS"
2530   CFLAGS="$CFLAGS $W_FLAGS"
2531
2532   if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
2533     AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
2534   fi
2535   if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
2536     AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
2537   fi
2538   if test "$tor_cv_cflags__warn_unused_const_variable_2" = "yes"; then
2539     AC_DEFINE([HAVE_CFLAG_WUNUSED_CONST_VARIABLE], 1, [True if we have -Wunused-const-variable])
2540   fi
2541
2542   CFLAGS="$CFLAGS_NOWARNINGS"
2543
2544   if test "x$enable_fatal_warnings" = "xyes"; then
2545     # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
2546     # default autoconf programs are full of errors.
2547     CFLAGS="$CFLAGS -Werror"
2548   fi
2549
2550 fi
2551
2552 AC_SUBST(TOR_WARNING_FLAGS)
2553
2554 echo "$TOR_WARNING_FLAGS">warning_flags
2555
2556 TOR_TRY_COMPILE_WITH_CFLAGS([@warning_flags], [],
2557                             CFLAGS="$CFLAGS @warning_flags",
2558                             CFLAGS="$CFLAGS $TOR_WARNING_FLAGS")
2559
2560 if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
2561    case "$host_os" in
2562     darwin*)
2563       AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
2564    esac
2565 fi
2566
2567 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
2568
2569 AC_CONFIG_FILES([
2570         Doxyfile
2571         Makefile
2572         config.rust
2573         contrib/operator-tools/tor.logrotate
2574         contrib/dist/tor.service
2575         src/config/torrc.sample
2576         src/config/torrc.minimal
2577         src/rust/.cargo/config
2578         scripts/maint/checkOptionDocs.pl
2579         warning_flags
2580 ])
2581
2582 if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
2583   regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
2584   for file in $regular_mans ; do
2585     if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
2586       echo "==================================";
2587       echo;
2588       echo "Building Tor has failed since manpages cannot be built.";
2589       echo;
2590       echo "You need asciidoc installed to be able to build the manpages.";
2591       echo "To build without manpages, use the --disable-asciidoc argument";
2592       echo "when calling configure.";
2593       echo;
2594       echo "==================================";
2595       exit 1;
2596     fi
2597   done
2598 fi
2599
2600 if test "$fragile_hardening" = "yes"; then
2601   AC_MSG_WARN([
2602
2603 ============
2604 Warning!  Building Tor with --enable-fragile-hardening (also known as
2605 --enable-expensive-hardening) makes some kinds of attacks harder, but makes
2606 other kinds of attacks easier. A Tor instance build with this option will be
2607 somewhat less vulnerable to remote code execution, arithmetic overflow, or
2608 out-of-bounds read/writes... but at the cost of becoming more vulnerable to
2609 denial of service attacks. For more information, see
2610 https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
2611 ============
2612   ])
2613 fi
2614
2615 AC_OUTPUT
2616
2617 #
2618 # Mini-report on what will be built.
2619 #
2620
2621 PPRINT_INIT
2622 PPRINT_SET_INDENT(1)
2623 PPRINT_SET_TS(65)
2624
2625 AS_ECHO
2626 AS_ECHO("Tor Version: ${PPRINT_COLOR_BLDBLU}Tor $PACKAGE_VERSION $PPRINT_COLOR_RST")
2627 AS_ECHO
2628
2629 PPRINT_SUBTITLE([Build Features])
2630
2631 PPRINT_PROP_STRING([Compiler], [$CC])
2632 PPRINT_PROP_STRING([Host OS], [$host_os])
2633 AS_ECHO
2634
2635 test "x$enable_fatal_warnings" = "xyes" && value=1 || value=0
2636 PPRINT_PROP_BOOL([Warnings are fatal (--enable-fatal-warnings)], $value)
2637
2638 test "x$enable_rust" = "xyes" && value=1 || value=0
2639 PPRINT_PROP_BOOL([Rust support (--enable-rust)], $value)
2640
2641 test "x$enable_cargo_online_mode" = "xyes" && value=1 || value=0
2642 PPRINT_PROP_BOOL([Cargo Online Fetch (--enable-cargo-online-mode)], $value)
2643
2644 test "x$enable_android" = "xyes" && value=1 || value=0
2645 PPRINT_PROP_BOOL([Android support (--enable-android)], $value)
2646
2647 AS_ECHO
2648 PPRINT_SUBTITLE([Static Build])
2649
2650 test "x$enable_static_tor" = "xyes" && value=1 || value=0
2651 PPRINT_PROP_BOOL([tor (--enable-static-tor)], $value)
2652
2653 if test "x$enable_static_libevent" = "xyes"; then
2654   PPRINT_PROP_STRING([libevent], [$TOR_LIBDIR_libevent])
2655 else
2656   PPRINT_PROP_BOOL([libevent (--enable-static-libevent)], $value)
2657 fi
2658
2659 if test "x$enable_static_openssl" = "xyes"; then
2660   PPRINT_PROP_STRING([libssl], [$TOR_LIBDIR_openssl])
2661 else
2662   PPRINT_PROP_BOOL([libssl (--enable-static-openssl)], $value)
2663 fi
2664
2665 if test "x$enable_static_zlib" = "xyes"; then
2666   PPRINT_PROP_STRING([zlib1g], [$TOR_LIBDIR_zlib])
2667 else
2668   PPRINT_PROP_BOOL([zlib1g (--enable-static-zlib)], $value)
2669 fi
2670
2671 AS_ECHO
2672 PPRINT_SUBTITLE([Optional Libraries])
2673
2674 test "x$enable_nss" = "xyes" && value=1 || value=0
2675 PPRINT_PROP_BOOL([libnss (--enable-nss)], $value)
2676
2677 test "x$enable_seccomp" != "xno" && value=1 || value=0
2678 PPRINT_PROP_BOOL([libseccomp (--disable-seccomp)], $value)
2679
2680 test "x$enable_libscrypt" != "xno" && value=1 || value=0
2681 PPRINT_PROP_BOOL([libscrypt (--disable-libscrypt)], $value)
2682
2683 test "x$enable_systemd" = "xyes" && value=1 || value=0
2684 PPRINT_PROP_BOOL([Systemd support (--enable-systemd)], $value)
2685
2686 test "x$enable_lzma" = "xyes" && value=1 || value=0
2687 PPRINT_PROP_BOOL([liblzma (--enable-lzma)], $value)
2688
2689 test "x$enable_zstd" = "xyes" && value=1 || value=0
2690 PPRINT_PROP_BOOL([libzstd (--enable-zstd)], $value)
2691
2692 AS_ECHO
2693 PPRINT_SUBTITLE([Hardening])
2694
2695 test "x$enable_gcc_hardening" != "xno" && value=1 || value=0
2696 PPRINT_PROP_BOOL([Compiler Hardening (--disable-gcc-hardening)], $value)
2697
2698 test "x$enable_linker_hardening" != "xno" && value=1 || value=0
2699 PPRINT_PROP_BOOL([Linker Hardening (--disable-linker-hardening)], $value)
2700
2701 test "x$fragile_hardening" = "xyes" && value=1 || value=0
2702 PPRINT_PROP_BOOL([Fragile Hardening (--enable-fragile-hardening, dev only)], $value)
2703
2704 AS_ECHO
2705 PPRINT_SUBTITLE([Modules])
2706
2707 m4_foreach_w([mname], MODULES,
2708   [
2709     AM_COND_IF(m4_join([], [BUILD_MODULE_], m4_toupper([]mname[])), value=1, value=0)
2710     PPRINT_PROP_BOOL([mname (--disable-module-mname)], $value)
2711   ]
2712 )
2713
2714 AS_ECHO
2715 PPRINT_SUBTITLE([Documentation])
2716
2717 test "x$enable_asciidoc" != "xno" && value=1 || value=0
2718 PPRINT_PROP_BOOL([AsciiDoc (--disable-asciidoc)], $value)
2719
2720 test "x$enable_manpage" != "xno" && value=1 || value=0
2721 PPRINT_PROP_BOOL([Man Pages (--disable-manpage)], $value)
2722
2723 test "x$enable_html_manual" != "xno" && value=1 || value=0
2724 PPRINT_PROP_BOOL([HTML Manual (--disable-html-manual)], $value)
2725
2726 AS_ECHO
2727 PPRINT_SUBTITLE([Tests])
2728
2729 test "x$enable_unittests" != "xno" && value=1 || value=0
2730 PPRINT_PROP_BOOL([Unit tests (--disable-unittests)], $value)
2731
2732 test "x$enable_asserts_in_tests" = "xno" && value=1 || value=0
2733 PPRINT_PROP_BOOL([assert()s enabled (--enable-asserts-in-tests, dev only)], $value)
2734
2735 test "x$enable_coverage" = "xyes" && value=1 || value=0
2736 PPRINT_PROP_BOOL([Code Coverage (--enable-coverage)], $value)
2737
2738 test "x$enable_libfuzzer" = "xyes" && value=1 || value=0
2739 PPRINT_PROP_BOOL([libFuzzer support (--enable-libfuzzer)], $value)
2740
2741 test "x$enable_oss_fuzz" = "xyes" && value=1 || value=0
2742 PPRINT_PROP_BOOL([OSS-Fuzz support (--enable-oss-fuzz)], $value)
2743
2744 AS_ECHO
2745 PPRINT_SUBTITLE([Install Directories])
2746
2747 report_mandir="`eval eval echo $mandir`"
2748 PPRINT_PROP_STRING([Binaries], [$BINDIR])
2749 PPRINT_PROP_STRING([Configuration], [$CONFDIR])
2750 PPRINT_PROP_STRING([Man Pages], [$report_mandir])
2751
2752 AS_ECHO
2753 AS_ECHO(["Configure Line: ./configure $configure_flags"])