configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.0.33)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45
  46
  47 if test x$enable_cell_pool != xno; then
  48   AC_DEFINE(ENABLE_CELL_POOL, 1,
  49             [Defined if we try to use the pool allocator for queued cells])
  50 fi
  51 if test x$enable_buf_freelists != xno; then
  52   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  53             [Defined if we try to use freelists for buffer RAM chunks])
  54 fi
  55 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  56
  57 AC_ARG_ENABLE(transparent,
  58      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  59      [case "${enableval}" in
  60         yes) transparent=true ;;
  61         no)  transparent=false ;;
  62         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  63       esac], [transparent=true])
  64
  65 AC_ARG_ENABLE(threads,
  66      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  67
  68 if test x$enable_threads = x; then
  69    case $host in
  70     *-*-solaris* )
  71      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  72      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  73 cpu workers lock up here, so I will disable threads.])
  74      enable_threads="no";;
  75     *)
  76      enable_threads="yes";;
  77    esac
  78 fi
  79
  80 if test "$enable_threads" = "yes"; then
  81   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  82 fi
  83
  84 case $host in
  85    *-*-solaris* )
  86      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  87      ;;
  88 esac
  89
  90 AC_ARG_ENABLE(gcc-warnings,
  91      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  92
  93 AC_PROG_CC
  94 AC_PROG_CPP
  95 AC_PROG_MAKE_SET
  96 AC_PROG_RANLIB
  97
  98 TORUSER=_tor
  99 AC_ARG_WITH(tor-user,
 100         [  --with-tor-user=NAME    Specify username for tor daemon ],
 101         [
 102            TORUSER=$withval
 103         ]
 104 )
 105 AC_SUBST(TORUSER)
 106
 107 TORGROUP=_tor
 108 AC_ARG_WITH(tor-group,
 109         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 110         [
 111            TORGROUP=$withval
 112         ]
 113 )
 114 AC_SUBST(TORGROUP)
 115
 116
 117 dnl If WIN32 is defined and non-zero, we are building for win32
 118 AC_MSG_CHECKING([for win32])
 119 AC_RUN_IFELSE([
 120 int main(int c, char **v) {
 121 #ifdef WIN32
 122 #if WIN32
 123   return 0;
 124 #else
 125   return 1;
 126 #endif
 127 #else
 128   return 2;
 129 #endif
 130 }],
 131 bwin32=true; AC_MSG_RESULT([yes]),
 132 bwin32=false; AC_MSG_RESULT([no]),
 133 bwin32=cross; AC_MSG_RESULT([cross])
 134 )
 135
 136 if test "$bwin32" = cross; then
 137 AC_MSG_CHECKING([for win32 (cross)])
 138 AC_COMPILE_IFELSE([
 139 #ifdef WIN32
 140 int main(int c, char **v) {return 0;}
 141 #else
 142 #error
 143 int main(int c, char **v) {return x(y);}
 144 #endif
 145 ],
 146 bwin32=true; AC_MSG_RESULT([yes]),
 147 bwin32=false; AC_MSG_RESULT([no]))
 148 fi
 149
 150 if test "$bwin32" = true; then
 151 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 152 fi
 153 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 154
 155 dnl Enable C99 when compiling with MIPSpro
 156 AC_MSG_CHECKING([for MIPSpro compiler])
 157 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 158 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 159 #error
 160   return x(y);
 161 #endif
 162 ]),
 163 bmipspro=false; AC_MSG_RESULT(no),
 164 bmipspro=true; AC_MSG_RESULT(yes))
 165
 166 if test "$bmipspro" = true; then
 167   CFLAGS="$CFLAGS -c99"
 168 fi
 169
 170 AC_C_BIGENDIAN
 171
 172 AC_SEARCH_LIBS(socket, [socket])
 173 AC_SEARCH_LIBS(gethostbyname, [nsl])
 174 AC_SEARCH_LIBS(dlopen, [dl])
 175 AC_SEARCH_LIBS(inet_aton, [resolv])
 176
 177 if test "$enable_threads" = "yes"; then
 178   AC_SEARCH_LIBS(pthread_create, [pthread])
 179   AC_SEARCH_LIBS(pthread_detach, [pthread])
 180 fi
 181
 182 dnl -------------------------------------------------------------------
 183 dnl Check for functions before libevent, since libevent-1.2 apparently
 184 dnl exports strlcpy without defining it in a header.
 185
 186 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop)
 187
 188 using_custom_malloc=no
 189 if test x$enable_openbsd_malloc = xyes ; then
 190    using_custom_malloc=yes
 191 fi
 192 if test x$tcmalloc = xyes ; then
 193    using_custom_malloc=yes
 194 fi
 195 if test $using_custom_malloc = no ; then
 196    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 197 fi
 198
 199 if test "$enable_threads" = "yes"; then
 200   AC_CHECK_HEADERS(pthread.h)
 201   AC_CHECK_FUNCS(pthread_create)
 202 fi
 203
 204 dnl ------------------------------------------------------
 205 dnl Where do you live, libevent?  And how do we call you?
 206
 207 if test "$bwin32" = true; then
 208   TOR_LIB_WS32=-lws2_32
 209   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 210   # think it's actually necessary.
 211   TOR_LIB_GDI=-lgdi32
 212 else
 213   TOR_LIB_WS32=
 214   TOR_LIB_GDI=
 215 fi
 216 AC_SUBST(TOR_LIB_WS32)
 217 AC_SUBST(TOR_LIB_GDI)
 218
 219 dnl We need to do this before we try our disgusting hack below.
 220 AC_CHECK_HEADERS([sys/types.h])
 221
 222 dnl This is a disgusting hack so we safely include older libevent headers.
 223 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 224 AC_CHECK_TYPE(u_int32_t, unsigned long)
 225 AC_CHECK_TYPE(u_int16_t, unsigned short)
 226 AC_CHECK_TYPE(u_int8_t, unsigned char)
 227
 228 tor_libevent_pkg_redhat="libevent"
 229 tor_libevent_pkg_debian="libevent-dev"
 230 tor_libevent_devpkg_redhat="libevent-devel"
 231 tor_libevent_devpkg_debian="libevent-dev"
 232
 233 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 234 #ifdef WIN32
 235 #include <winsock2.h>
 236 #endif
 237 #include <stdlib.h>
 238 #include <sys/time.h>
 239 #include <sys/types.h>
 240 #include <event.h>], [
 241 #ifdef WIN32
 242 #include <winsock2.h>
 243 #endif
 244 void exit(int); void *event_init(void);],
 245     [
 246 #ifdef WIN32
 247 {WSADATA d; WSAStartup(0x101,&d); }
 248 #endif
 249 event_init(); exit(0);
 250 ], [--with-libevent-dir], [/opt/libevent])
 251
 252 dnl Now check for particular libevent functions.
 253 save_LIBS="$LIBS"
 254 save_LDFLAGS="$LDFLAGS"
 255 save_CPPFLAGS="$CPPFLAGS"
 256 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 257 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 258 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 259 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 260 LIBS="$save_LIBS"
 261 LDFLAGS="$save_LDFLAGS"
 262 CPPFLAGS="$save_CPPFLAGS"
 263
 264 dnl ------------------------------------------------------
 265 dnl Where do you live, openssl?  And how do we call you?
 266
 267 tor_openssl_pkg_redhat="openssl"
 268 tor_openssl_pkg_debian="libssl"
 269 tor_openssl_devpkg_redhat="openssl-devel"
 270 tor_openssl_devpkg_debian="libssl-dev"
 271
 272 ALT_openssl_WITHVAL=""
 273 AC_ARG_WITH(ssl-dir,
 274   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 275   [
 276       if test "x$withval" != xno && test "x$withval" != "x" ; then
 277          ALT_openssl_WITHVAL="$withval"
 278       fi
 279   ])
 280
 281 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 282     [#include <openssl/rand.h>],
 283     [void RAND_add(const void *buf, int num, double entropy);],
 284     [RAND_add((void*)0,0,0); exit(0);], [],
 285     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 286
 287 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 288
 289 dnl ------------------------------------------------------
 290 dnl Where do you live, zlib?  And how do we call you?
 291
 292 tor_openssl_pkg_redhat="zlib"
 293 tor_openssl_pkg_debian="zlib1g"
 294 tor_openssl_devpkg_redhat="zlib-devel"
 295 tor_openssl_devpkg_debian="zlib1g-dev"
 296
 297 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 298     [#include <zlib.h>],
 299     [const char * zlibVersion(void);],
 300     [zlibVersion(); exit(0);], [--with-zlib-dir],
 301     [/opt/zlib])
 302
 303 dnl Make sure to enable support for large off_t if available.
 304
 305 AC_SYS_LARGEFILE
 306
 307 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 308
 309 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 310
 311 dnl These headers are not essential
 312
 313 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h)
 314
 315 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 316 [#ifdef HAVE_MALLOC_H
 317 #include <malloc.h>
 318 #endif
 319 #ifdef HAVE_MALLOC_MALLOC_H
 320 #include <malloc/malloc.h>
 321 #endif])
 322
 323 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 324 [#ifdef HAVE_SYS_TYPES_H
 325 #include <sys/types.h>
 326 #endif
 327 #ifdef HAVE_SYS_SOCKET_H
 328 #include <sys/socket.h>
 329 #endif])
 330 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 331 [#ifdef HAVE_SYS_TYPES_H
 332 #include <sys/types.h>
 333 #endif
 334 #ifdef HAVE_SYS_SOCKET_H
 335 #include <sys/socket.h>
 336 #endif
 337 #ifdef HAVE_NET_IF_H
 338 #include <net/if.h>
 339 #endif])
 340 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 341         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 342 [#ifdef HAVE_SYS_TYPES_H
 343 #include <sys/types.h>
 344 #endif
 345 #ifdef HAVE_SYS_SOCKET_H
 346 #include <sys/socket.h>
 347 #endif
 348 #ifdef HAVE_LIMITS_H
 349 #include <limits.h>
 350 #endif
 351 #ifdef HAVE_LINUX_TYPES_H
 352 #include <linux/types.h>
 353 #endif
 354 #ifdef HAVE_NETINET_IN6_H
 355 #include <netinet/in6.h>
 356 #endif
 357 #ifdef HAVE_NETINET_IN_H
 358 #include <netinet/in.h>
 359 #endif])
 360
 361 if test x$transparent = xtrue ; then
 362    transparent_ok=0
 363    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 364      transparent_ok=1
 365    fi
 366    if test x$linux_netfilter_ipv4 = x1 ; then
 367      transparent_ok=1
 368    fi
 369    if test x$transparent_ok = x1 ; then
 370      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 371      case $host in
 372        *-*-openbsd*)
 373          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 374      esac
 375    else
 376      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 377    fi
 378 fi
 379
 380 AC_FUNC_FSEEKO
 381
 382 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 383 [#ifdef HAVE_SYS_TYPES_H
 384 #include <sys/types.h>
 385 #endif
 386 #ifdef HAVE_SYS_TIME_H
 387 #include <sys/time.h>
 388 #endif])
 389
 390 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 391 dnl Watch out.
 392
 393 AC_CHECK_SIZEOF(int8_t)
 394 AC_CHECK_SIZEOF(int16_t)
 395 AC_CHECK_SIZEOF(int32_t)
 396 AC_CHECK_SIZEOF(int64_t)
 397 AC_CHECK_SIZEOF(uint8_t)
 398 AC_CHECK_SIZEOF(uint16_t)
 399 AC_CHECK_SIZEOF(uint32_t)
 400 AC_CHECK_SIZEOF(uint64_t)
 401 AC_CHECK_SIZEOF(intptr_t)
 402 AC_CHECK_SIZEOF(uintptr_t)
 403
 404 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 405
 406 AC_CHECK_SIZEOF(char)
 407 AC_CHECK_SIZEOF(short)
 408 AC_CHECK_SIZEOF(int)
 409 AC_CHECK_SIZEOF(long)
 410 AC_CHECK_SIZEOF(long long)
 411 AC_CHECK_SIZEOF(__int64)
 412 AC_CHECK_SIZEOF(void *)
 413 AC_CHECK_SIZEOF(time_t)
 414 AC_CHECK_SIZEOF(size_t)
 415
 416 AC_CHECK_TYPES([uint, u_char, ssize_t])
 417
 418 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 419 [#ifdef HAVE_SYS_TYPES_H
 420 #include <sys/types.h>
 421 #endif
 422 #ifdef HAVE_NETINET_IN_H
 423 #include <netinet/in.h>
 424 #endif
 425 #ifdef HAVE_NETINET_IN6_H
 426 #include <netinet/in6.h>
 427 #endif
 428 #ifdef HAVE_SYS_SOCKET_H
 429 #include <sys/socket.h>
 430 #endif
 431 #ifdef MS_WINDOWS
 432 #define WIN32_WINNT 0x400
 433 #define _WIN32_WINNT 0x400
 434 #define WIN32_LEAN_AND_MEAN
 435 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 436 #include <winsock.h>
 437 #else
 438 #include <winsock2.h>
 439 #include <ws2tcpip.h>
 440 #endif
 441 #endif
 442 ])
 443 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 444 [#ifdef HAVE_SYS_TYPES_H
 445 #include <sys/types.h>
 446 #endif
 447 #ifdef HAVE_NETINET_IN_H
 448 #include <netinet/in.h>
 449 #endif
 450 #ifdef HAVE_NETINET_IN6_H
 451 #include <netinet/in6.h>
 452 #endif
 453 #ifdef HAVE_SYS_SOCKET_H
 454 #include <sys/socket.h>
 455 #endif
 456 #ifdef MS_WINDOWS
 457 #define WIN32_WINNT 0x400
 458 #define _WIN32_WINNT 0x400
 459 #define WIN32_LEAN_AND_MEAN
 460 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 461 #include <winsock.h>
 462 #else
 463 #include <winsock2.h>
 464 #include <ws2tcpip.h>
 465 #endif
 466 #endif
 467 ])
 468
 469 AC_CHECK_TYPES([rlim_t], , ,
 470 [#ifdef HAVE_SYS_TYPES_H
 471 #include <sys/types.h>
 472 #endif
 473 #ifdef HAVE_SYS_TIME_H
 474 #include <sys/time.h>
 475 #endif
 476 #ifdef HAVE_SYS_RESOURCE_H
 477 #include <sys/resource.h>
 478 #endif
 479 ])
 480
 481 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 482 AC_RUN_IFELSE(AC_LANG_SOURCE([
 483 #ifdef HAVE_SYS_TYPES_H
 484 #include <sys/types.h>
 485 #endif
 486 #ifdef HAVE_SYS_TIME_H
 487 #include <sys/time.h>
 488 #endif
 489 #ifdef HAVE_TIME_H
 490 #include <time.h>
 491 #endif
 492 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 493   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 494 ])
 495
 496 if test "$tor_cv_time_t_signed" = cross; then
 497   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 498 fi
 499
 500 if test "$tor_cv_time_t_signed" != no; then
 501   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 502             [Define to 1 iff time_t is signed])
 503 fi
 504
 505 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 506 #ifdef HAVE_SYS_SOCKET_H
 507 #include <sys/socket.h>
 508 #endif
 509 ])
 510
 511 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 512
 513 AC_CHECK_SIZEOF(cell_t)
 514
 515 # Now make sure that NULL can be represented as zero bytes.
 516 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 517 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 518 [[#include <stdlib.h>
 519 #include <string.h>
 520 #include <stdio.h>
 521 #ifdef HAVE_STDDEF_H
 522 #include <stddef.h>
 523 #endif
 524 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 525 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 526        [tor_cv_null_is_zero=yes],
 527        [tor_cv_null_is_zero=no],
 528        [tor_cv_null_is_zero=cross])])
 529
 530 if test "$tor_cv_null_is_zero" = cross ; then
 531   # Cross-compiling; let's hope that the target isn't raving mad.
 532   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 533 fi
 534
 535 if test "$tor_cv_null_is_zero" != no; then
 536   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 537             [Define to 1 iff memset(0) sets pointers to NULL])
 538 fi
 539
 540 # And what happens when we malloc zero?
 541 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 542 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 543 [[#include <stdlib.h>
 544 #include <string.h>
 545 #include <stdio.h>
 546 #ifdef HAVE_STDDEF_H
 547 #include <stddef.h>
 548 #endif
 549 int main () { return malloc(0)?0:1; }]])],
 550        [tor_cv_malloc_zero_works=yes],
 551        [tor_cv_malloc_zero_works=no],
 552        [tor_cv_malloc_zero_works=cross])])
 553
 554 if test "$tor_cv_malloc_zero_works" = cross; then
 555   # Cross-compiling; let's hope that the target isn't raving mad.
 556   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 557 fi
 558
 559 if test "$tor_cv_malloc_zero_works" = yes; then
 560   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 561             [Define to 1 iff malloc(0) returns a pointer])
 562 fi
 563
 564 # whether we seem to be in a 2s-complement world.
 565 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 566 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 567 [[int main () { int problem = ((-99) != (~99)+1);
 568 return problem ? 1 : 0; }]])],
 569        [tor_cv_twos_complement=yes],
 570        [tor_cv_twos_complement=no],
 571        [tor_cv_twos_complement=cross])])
 572
 573 if test "$tor_cv_twos_complement" = cross ; then
 574   # Cross-compiling; let's hope that the target isn't raving mad.
 575   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 576 fi
 577
 578 if test "$tor_cv_twos_complement" != no ; then
 579   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 580             [Define to 1 iff we represent negative integers with two's complement])
 581 fi
 582
 583 # Whether we should use the dmalloc memory allocation debugging library.
 584 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 585 AC_ARG_WITH(dmalloc,
 586 [  --with-dmalloc          Use debug memory allocation library. ],
 587 [if [[ "$withval" = "yes" ]]; then
 588   dmalloc=1
 589   AC_MSG_RESULT(yes)
 590 else
 591   dmalloc=1
 592   AC_MSG_RESULT(no)
 593 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 594 )
 595
 596 if [[ $dmalloc -eq 1 ]]; then
 597   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 598   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 599   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 600   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 601   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 602 fi
 603
 604 AC_ARG_WITH(tcmalloc,
 605 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 606 [ tcmalloc=yes ], [ tcmalloc=no ])
 607
 608 if test x$tcmalloc = xyes ; then
 609    LDFLAGS="-ltcmalloc $LDFLAGS"
 610 fi
 611
 612 # Allow user to specify an alternate syslog facility
 613 AC_ARG_WITH(syslog-facility,
 614 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 615 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 616 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 617 AC_SUBST(LOGFACILITY)
 618
 619 # Check if we have getresuid and getresgid
 620 AC_CHECK_FUNCS(getresuid getresgid)
 621
 622 # Check for gethostbyname_r in all its glorious incompatible versions.
 623 #   (This logic is based on that in Python's configure.in)
 624 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 625   [Define this if you have any gethostbyname_r()])
 626
 627 AC_CHECK_FUNC(gethostbyname_r, [
 628   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 629   OLD_CFLAGS=$CFLAGS
 630   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 631   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 632 #include <netdb.h>
 633   ], [[
 634     char *cp1, *cp2;
 635     struct hostent *h1, *h2;
 636     int i1, i2;
 637     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 638   ]]),[
 639     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 640     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 641      [Define this if gethostbyname_r takes 6 arguments])
 642     AC_MSG_RESULT(6)
 643   ], [
 644     AC_TRY_COMPILE([
 645 #include <netdb.h>
 646     ], [
 647       char *cp1, *cp2;
 648       struct hostent *h1;
 649       int i1, i2;
 650       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 651     ], [
 652       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 653       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 654         [Define this if gethostbyname_r takes 5 arguments])
 655       AC_MSG_RESULT(5)
 656    ], [
 657       AC_TRY_COMPILE([
 658 #include <netdb.h>
 659      ], [
 660        char *cp1;
 661        struct hostent *h1;
 662        struct hostent_data hd;
 663        (void) gethostbyname_r(cp1,h1,&hd);
 664      ], [
 665        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 666        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 667          [Define this if gethostbyname_r takes 3 arguments])
 668        AC_MSG_RESULT(3)
 669      ], [
 670        AC_MSG_RESULT(0)
 671      ])
 672   ])
 673  ])
 674  CFLAGS=$OLD_CFLAGS
 675 ])
 676
 677 AC_CACHE_CHECK([whether the C compiler supports __func__],
 678   tor_cv_have_func_macro,
 679   AC_COMPILE_IFELSE([
 680 #include <stdio.h>
 681 int main(int c, char **v) { puts(__func__); }],
 682   tor_cv_have_func_macro=yes,
 683   tor_cv_have_func_macro=no))
 684
 685 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 686   tor_cv_have_FUNC_macro,
 687   AC_COMPILE_IFELSE([
 688 #include <stdio.h>
 689 int main(int c, char **v) { puts(__FUNC__); }],
 690   tor_cv_have_FUNC_macro=yes,
 691   tor_cv_have_FUNC_macro=no))
 692
 693 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 694   tor_cv_have_FUNCTION_macro,
 695   AC_COMPILE_IFELSE([
 696 #include <stdio.h>
 697 int main(int c, char **v) { puts(__FUNCTION__); }],
 698   tor_cv_have_FUNCTION_macro=yes,
 699   tor_cv_have_FUNCTION_macro=no))
 700
 701 if test "$tor_cv_have_func_macro" = 'yes'; then
 702   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 703 fi
 704
 705 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 706   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 707 fi
 708
 709 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 710   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 711            [Defined if the compiler supports __FUNCTION__])
 712 fi
 713
 714 # $prefix stores the value of the --prefix command line option, or
 715 # NONE if the option wasn't set.  In the case that it wasn't set, make
 716 # it be the default, so that we can use it to expand directories now.
 717 if test "x$prefix" = "xNONE"; then
 718   prefix=$ac_default_prefix
 719 fi
 720
 721 # and similarly for $exec_prefix
 722 if test "x$exec_prefix" = "xNONE"; then
 723   exec_prefix=$prefix
 724 fi
 725
 726 if test "x$CONFDIR" = "x"; then
 727   CONFDIR=`eval echo $sysconfdir/tor`
 728 fi
 729 AC_SUBST(CONFDIR)
 730 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 731 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 732
 733 BINDIR=`eval echo $bindir`
 734 AC_SUBST(BINDIR)
 735 LOCALSTATEDIR=`eval echo $localstatedir`
 736 AC_SUBST(LOCALSTATEDIR)
 737
 738 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 739 # than autoconf's macros like.
 740 if test "$ac_cv_c_compiler_gnu" = yes; then
 741   CFLAGS="$CFLAGS -Wall -g -O2"
 742 else
 743   CFLAGS="$CFLAGS -g -O"
 744   enable_gcc_warnings=no
 745 fi
 746
 747 # Add some more warnings which we use in development but not in the
 748 # released versions.  (Some relevant gcc versions can't handle these.)
 749 if test x$enable_gcc_warnings = xyes; then
 750
 751   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 752 #if !defined(__GNUC__) || (__GNUC__ < 4)
 753 #error
 754 #endif]), have_gcc4=yes, have_gcc4=no)
 755
 756   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 757 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 758 #error
 759 #endif]), have_gcc42=yes, have_gcc42=no)
 760
 761   save_CFLAGS="$CFLAGS"
 762   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 763   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 764                     have_shorten64_flag=no)
 765   CFLAGS="$save_CFLAGS"
 766
 767   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 768   # Disabled, so we can use mallinfo(): -Waggregate-return
 769
 770   if test x$have_gcc4 = xyes ; then
 771     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 772     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 773   fi
 774
 775   if test x$have_gcc42 = xyes ; then
 776     # These warnings break gcc 4.0.2 and work on gcc 4.2
 777     # XXXX020 Use -fstack-protector.
 778     # XXXX020 See if any of these work with earlier versions.
 779     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 780     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 781   fi
 782
 783   if test x$have_shorten64_flag = xyes ; then
 784     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 785   fi
 786
 787 ##This will break the world on some 64-bit architectures
 788 # CFLAGS="$CFLAGS -Winline"
 789 fi
 790
 791
 792
 793 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 794
 795 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 796 AC_OUTPUT
 797
 798 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 799   ./contrib/updateVersions.pl
 800 fi
 801