configure.in

   1 dnl $Id$
   2 dnl Copyright 2001-2004 Roger Dingledine
   3 dnl Copyright 2004-2005 Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.1.1.0-alpha-cvs)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release; then
  13     CFLAGS="$CFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 AC_ARG_ENABLE(debug,
  17  AC_HELP_STRING(--enable-debug, compile with debugging info),
  18 [if test x$enableval = xyes; then
  19     CFLAGS="$CFLAGS -g"
  20 fi])
  21
  22 AC_ARG_ENABLE(threads,
  23      AC_HELP_STRING(--disable-threads, disable multi-threading support))
  24
  25 if test x$enable_threads = x; then
  26    case $host in
  27     *-*-netbsd* | *-*-openbsd* )
  28      # Don't try multithreading on netbsd -- there is no threadsafe DNS
  29      # lookup function there.
  30      AC_MSG_NOTICE([You are running OpenBSD or NetBSD; I am assuming that
  31 getaddrinfo is not threadsafe here, so I will disable threads.])
  32      enable_threads="no";;
  33     *-*-solaris* )
  34      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  35      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  36 cpu workers lock up here, so I will disable threads.])
  37      enable_threads="no";;
  38     *)
  39      enable_threads="yes";;
  40    esac
  41 fi
  42
  43 if test $enable_threads = "yes"; then
  44   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  45 fi
  46
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 AC_PROG_RANLIB
  50
  51 # The big search for OpenSSL
  52 # copied from openssh's configure.ac
  53 AC_ARG_WITH(ssl-dir,
  54         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
  55         [
  56                 if test "x$withval" != "xno" ; then
  57                         tryssldir=$withval
  58                 fi
  59         ]
  60 )
  61
  62 AC_SEARCH_LIBS(socket, [socket])
  63 AC_SEARCH_LIBS(gethostbyname, [nsl])
  64 AC_SEARCH_LIBS(pthread_create, [pthread])
  65 AC_SEARCH_LIBS(pthread_detach, [pthread])
  66
  67 dnl ------------------------------------------------------
  68 dnl Where do you live, libevent?  And how do we call you?
  69
  70
  71 # Step 1. Try to link and run a program using libevent.  If it works,
  72 #         great!  Just add -levent.
  73 AC_CACHE_CHECK([for a normal libevent], ac_cv_libevent_normal, [
  74    saved_LIBS="$LIBS"
  75    LIBS="$LIBS -levent"
  76    AC_TRY_RUN([
  77 void *event_init(void);
  78 int main(void)
  79 {
  80         event_init();
  81         return 0;
  82 }], ac_cv_libevent_normal=yes, ac_cv_libevent_normal=no)
  83    LIBS="$saved_LIBS"
  84 ])
  85
  86 if test "$ac_cv_libevent_normal" = yes; then
  87   LIBS="$LIBS -levent"
  88 else
  89   AC_CACHE_CHECK([for libevent in /usr/local/lib], ac_cv_libevent_local, [
  90      saved_LIBS="$LIBS"
  91      saved_LDFLAGS="$LDFLAGS"
  92      LIBS="$LIBS -levent"
  93      LDFLAGS="$LDFLAGS -L/usr/local/lib"
  94      # Step 2.  Otherwise, check whether adding -L/usr/local/lib allows
  95      #          us to link.  If not, assume we have no libevent at all.
  96      AC_TRY_LINK([], [ void *event_init(void); event_init(); ],
  97         [ libevent_is_in_local=yes ], [ libevent_is_in_local=no ])
  98      if test $libevent_is_in_local = no ; then
  99        ac_cv_libevent_local=no
 100      else
 101        # Step 3.  Does adding -L/usr/local/lib allow us to run, too?
 102        #          If so, all we have to do as adjust LDFLAGS and CFLAGS.
 103        AC_TRY_RUN([
 104 void *event_init(void);
 105 int main(void)
 106 {
 107         event_init();
 108         return 0;
 109 }], [ ac_cv_libevent_local=yes ], [ ac_cv_libevent_local=unlinked ])
 110     fi
 111     if test "$GCC" = yes -a $ac_cv_libevent_local = unlinked ; then
 112        # Step 4.  Okay, so we can link but not run.  This probably means
 113        #          that the dynamic linker doesn't have /usr/local/lib in
 114        #          its search path.  If we're lucky enough to be running
 115        #          GCC on an ELF system, we might have a workaround for that.
 116        #          See whether -Wl,-R/usr/local/lib makes things better.
 117        LDFLAGS="$LDFLAGS -Wl,-R/usr/local/lib"
 118        AC_TRY_RUN([
 119 void *event_init(void);
 120 int main(void)
 121 {
 122         event_init();
 123         return 0;
 124 }], [ ac_cv_libevent_local=unlinked_gcc_elf ])
 125     fi
 126
 127     LIBS="$saved_LIBS"
 128     LDFLAGS="$saved_LDFLAGS" ])
 129
 130   # Now we're done.  ac_vc_libevent_local could be:
 131   #    yes -- Add -L/usr/local/lib and we can link fine.
 132   #    unlinked_gcc_elf -- We can link, but we need to use the GCC-ELF
 133   #        workaround.  Complain a little.
 134   #    unlinked -- We can link, but we can't run.  Complain a lot.
 135   #    no -- we can't link at all.  Give an error and die.
 136
 137   if test $ac_cv_libevent_local != no; then
 138       LIBS="$LIBS -levent"
 139       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 140       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 141   fi
 142   if test $ac_cv_libevent_local = unlinked_gcc_elf; then
 143       LDFLAGS="$LDFLAGS -Wl,-R/usr/local/lib"
 144       if test -f /etc/ld.so.conf ; then
 145         AC_MSG_NOTICE([
 146 Apparently, you don't have /usr/local/lib in your /etc/ld.so.conf.
 147 Tor is smart enought to deal this now, but other applications aren't.
 148 You might want to add it in.])
 149       fi
 150   fi
 151
 152   if test $ac_cv_libevent_local = unlinked ; then
 153     if test -f /etc/ld.so.conf ; then
 154       AC_MSG_NOTICE([
 155 =================================================
 156 Your libevent library is installed in /usr/local/lib,
 157 but your dynamic linker isn't configured to look for
 158 it there.
 159
 160 Maybe you need to add /usr/local/lib to /etc/ld.so.conf,
 161 and then run ldconfig -v ?
 162 =================================================])
 163     else
 164       AC_MSG_NOTICE([
 165 =================================================
 166 Your libevent library is installed in /usr/local/lib,
 167 but your dynamic linker isn't configured to look for
 168 it there.
 169 =================================================])
 170     fi
 171   fi
 172
 173   if test $ac_cv_libevent_local = no ; then
 174       AC_MSG_ERROR([
 175 Tor requires libevent to build.  You can download the latest
 176 version of libevent from http://monkey.org/~provos/libevent/])
 177   fi
 178
 179 fi
 180
 181 dnl ------------------------------------------------------
 182 dnl Where do you live, OpenSSL?
 183
 184 saved_LIBS="$LIBS"
 185 saved_LDFLAGS="$LDFLAGS"
 186 saved_CPPFLAGS="$CPPFLAGS"
 187 if test "x$prefix" != "xNONE" ; then
 188         tryssldir="$tryssldir $prefix"
 189 fi
 190 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 191         for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /usr/pkg /opt /opt/openssl ; do
 192                 CPPFLAGS="$saved_CPPFLAGS"
 193                 LDFLAGS="$saved_LDFLAGS"
 194                 LIBS="$saved_LIBS -lssl -lcrypto"
 195
 196                 # Skip directories if they don't exist
 197                 if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 198                         continue;
 199                 fi
 200                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 201                         # Try to use $ssldir/lib if it exists, otherwise
 202                         # $ssldir
 203                         if test -d "$ssldir/lib" ; then
 204                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 205                                 if test ! -z "$need_dash_r" ; then
 206                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 207                                 fi
 208                         else
 209                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 210                                 if test ! -z "$need_dash_r" ; then
 211                                         LDFLAGS="-R$ssldir $LDFLAGS"
 212                                 fi
 213                         fi
 214                         # Try to use $ssldir/include if it exists, otherwise
 215                         # $ssldir
 216                         if test -d "$ssldir/include" ; then
 217                                 CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 218                         else
 219                                 CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 220                         fi
 221                 fi
 222
 223                 # Basic test to check for compatible version and correct linking
 224                 # *does not* test for RSA - that comes later.
 225                 AC_TRY_RUN(
 226                         [
 227 #include <string.h>
 228 #include <openssl/rand.h>
 229 int main(void)
 230 {
 231         char a[2048];
 232         memset(a, 0, sizeof(a));
 233         RAND_add(a, sizeof(a), sizeof(a));
 234         return(RAND_status() <= 0);
 235 }
 236                         ],
 237                         [
 238                                 found_crypto=1
 239                                 break;
 240                         ], []
 241                 )
 242
 243                 if test ! -z "$found_crypto" ; then
 244                         break;
 245                 fi
 246         done
 247
 248         if test -z "$found_crypto" ; then
 249                 AC_MSG_ERROR([Could not find working OpenSSL library, please install or check config.log])
 250         fi
 251         if test -z "$ssldir" ; then
 252                 ssldir="(system)"
 253         fi
 254
 255         ac_cv_openssldir=$ssldir
 256 ])
 257 if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ;
 258  then
 259         dnl Need to recover ssldir - test above runs in subshell
 260         ssldir=$ac_cv_openssldir
 261         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 262                 # Try to use $ssldir/lib if it exists, otherwise
 263                 # $ssldir
 264                 if test -d "$ssldir/lib" ; then
 265                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 266                         if test ! -z "$need_dash_r" ; then
 267                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 268                         fi
 269                 else
 270                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 271                         if test ! -z "$need_dash_r" ; then
 272                                 LDFLAGS="-R$ssldir $LDFLAGS"
 273                         fi
 274                 fi
 275                 # Try to use $ssldir/include if it exists, otherwise
 276                 # $ssldir
 277                 if test -d "$ssldir/include" ; then
 278                         CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 279                 else
 280                         CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 281                 fi
 282         fi
 283 fi
 284 LIBS="$saved_LIBS"
 285
 286 AC_SYS_LARGEFILE
 287
 288 dnl The warning message here is no longer strictly accurate.
 289
 290 AC_CHECK_HEADERS(unistd.h string.h signal.h netdb.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/ioctl.h sys/socket.h sys/time.h netinet/in.h arpa/inet.h errno.h assert.h time.h pwd.h grp.h, , AC_MSG_WARN(some headers were not found, compilation may fail))
 291
 292 AC_CHECK_HEADERS(event.h, , AC_MSG_ERROR(Libevent header (event.h) not found. Tor requires libevent to build.))
 293
 294 AC_CHECK_HEADERS(zlib.h, , AC_MSG_ERROR(Zlib header (zlib.h) not found. Tor requires zlib to build. You may need to install a zlib development package.))
 295
 296 dnl These headers are not essential
 297
 298 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h pthread.h stddef.h inttypes.h)
 299
 300 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit setrlimit strlcat strlcpy strtoull getpwnam ftello pthread_create getaddrinfo localtime_r gmtime_r event_get_version event_get_method event_set_log_callback)
 301 AC_FUNC_FSEEKO
 302
 303 AC_CHECK_MEMBERS([struct timeval.tv_sec])
 304
 305
 306 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 307 dnl Watch out.
 308
 309 AC_CHECK_SIZEOF(int8_t)
 310 AC_CHECK_SIZEOF(int16_t)
 311 AC_CHECK_SIZEOF(int32_t)
 312 AC_CHECK_SIZEOF(int64_t)
 313 AC_CHECK_SIZEOF(uint8_t)
 314 AC_CHECK_SIZEOF(uint16_t)
 315 AC_CHECK_SIZEOF(uint32_t)
 316 AC_CHECK_SIZEOF(uint64_t)
 317 AC_CHECK_SIZEOF(intptr_t)
 318 AC_CHECK_SIZEOF(uintptr_t)
 319
 320 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 321
 322 AC_CHECK_SIZEOF(char)
 323 AC_CHECK_SIZEOF(short)
 324 AC_CHECK_SIZEOF(int)
 325 AC_CHECK_SIZEOF(long)
 326 AC_CHECK_SIZEOF(long long)
 327 AC_CHECK_SIZEOF(__int64)
 328 AC_CHECK_SIZEOF(void *)
 329 AC_CHECK_SIZEOF(time_t)
 330 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 331 #ifdef HAVE_SYS_SOCKET_H
 332 #include <sys/socket.h>
 333 #endif
 334 ])
 335
 336 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 337
 338 AC_CHECK_SIZEOF(cell_t)
 339
 340 # Now, let's see about alignment requirements.  On some platforms, we override
 341 # the default.
 342 case $host in
 343  ia64-*-* | arm-*-* )
 344     tor_cv_unaligned_ok=no
 345     ;;
 346  *)
 347 AC_CACHE_CHECK([whether unaligned int access is allowed], tor_cv_unaligned_ok,
 348 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 349 [[int main () { char s[] = "A\x00\x00\x00\x00\x00\x00\x00";
 350 return *(int*)(&s[1]); }]])],
 351        [tor_cv_unaligned_ok=yes],
 352        [tor_cv_unaligned_ok=no],
 353        [tor_cv_unaligned_ok=cross])])
 354 esac
 355
 356 if test $tor_cv_unaligned_ok = yes; then
 357   AC_DEFINE([UNALIGNED_INT_ACCESS_OK], 1,
 358             [Define to 1 iff unaligned int access is allowed])
 359 fi
 360
 361 # Now make sure that NULL can be represented as zero bytes.
 362 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 363 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 364 [[#include <stdlib.h>
 365 #include <string.h>
 366 #include <stdio.h>
 367 #ifdef HAVE_STDDEF_H
 368 #include <stddef.h>
 369 #endif
 370 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 371 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 372        [tor_cv_null_is_zero=yes],
 373        [tor_cv_null_is_zero=no],
 374        [tor_cv_null_is_zero=cross])])
 375
 376 if test $tor_cv_null_is_zero = yes; then
 377   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 378             [Define to 1 iff memset(0) sets pointers to NULL])
 379 fi
 380
 381 # Whether we should use the dmalloc memory allocation debugging library.
 382 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 383 AC_ARG_WITH(dmalloc,
 384 [  --with-dmalloc          Use debug memory allocation library. ],
 385 [if [[ "$withval" = "yes" ]]; then
 386   dmalloc=1
 387   AC_MSG_RESULT(yes)
 388 else
 389   dmalloc=1
 390   AC_MSG_RESULT(no)
 391 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 392 )
 393
 394 if [[ $dmalloc -eq 1 ]]; then
 395   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 396   AC_SEARCH_LIBS(dmalloc_malloc, [dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 397   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 398   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 399 fi
 400
 401 # Check for gethostbyname_r in all its glorious incompatible versions.
 402 #   (This logic is based on that in Python's configure.in)
 403 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 404   [Define this if you have any gethostbyname_r()])
 405
 406 AC_CHECK_FUNC(gethostbyname_r, [
 407   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 408   OLD_CFLAGS=$CFLAGS
 409   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 410   AC_TRY_COMPILE([
 411 #include <netdb.h>
 412   ], [
 413     char *cp1, *cp2;
 414     struct hostent *h1, *h2;
 415     int i1, i2;
 416     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 417   ], [
 418     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 419     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 420      [Define this if gethostbyname_r takes 6 arguments])
 421     AC_MSG_RESULT(6)
 422   ], [
 423     AC_TRY_COMPILE([
 424 #include <netdb.h>
 425     ], [
 426       char *cp1, *cp2;
 427       struct hostent *h1;
 428       int i1, i2;
 429       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 430     ], [
 431       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 432       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 433         [Define this if gethostbyname_r takes 5 arguments])
 434       AC_MSG_RESULT(5)
 435    ], [
 436       AC_TRY_COMPILE([
 437 #include <netdb.h>
 438      ], [
 439        char *cp1;
 440        struct hostent *h1;
 441        struct hostent_data hd;
 442        (void) gethostbyname_r(cp1,h1,&hd);
 443      ], [
 444        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 445        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 446          [Define this if gethostbyname_r takes 3 arguments])
 447        AC_MSG_RESULT(3)
 448      ], [
 449        AC_MSG_RESULT(0)
 450      ])
 451   ])
 452  ])
 453  CFLAGS=$OLD_CFLAGS
 454 ])
 455
 456 # $prefix stores the value of the --prefix command line option, or
 457 # NONE if the option wasn't set.  In the case that it wasn't set, make
 458 # it be the default, so that we can use it to expand directories now.
 459 if test "x$prefix" = "xNONE"; then
 460   prefix=$ac_default_prefix
 461 fi
 462
 463 # and similarly for $exec_prefix
 464 if test "x$exec_prefix" = "xNONE"; then
 465   exec_prefix=$prefix
 466 fi
 467
 468 CONFDIR=`eval echo $sysconfdir/tor`
 469 AC_SUBST(CONFDIR)
 470 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 471 AC_DEFINE([CONFDIR], [], [tor's configuration directory])
 472
 473 BINDIR=`eval echo $bindir`
 474 AC_SUBST(BINDIR)
 475
 476 LOCALSTATEDIR=`eval echo $localstatedir`
 477 AC_SUBST(LOCALSTATEDIR)
 478 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 479 AC_DEFINE([LOCALSTATEDIR], [], [Default location to store state files.])
 480
 481 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 482 # than autoconf's macros like.
 483 CFLAGS="$CFLAGS -Wall -g -O2"
 484 # Add some more warnings which we use in the cvs version but not in the
 485 # released versions.  (Some relevant gcc versions can't handle these.)
 486 #CFLAGS="$CFLAGS -W -Wno-unused-parameter -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls"
 487 # Add these in when you feel like fun.
 488 #CFLAGS="$CFLAGS -Wbad-function-cast -Werror -Wdeclaration-after-statement"
 489
 490 echo "confdir: $CONFDIR"
 491
 492 AC_OUTPUT(Makefile tor.spec contrib/tor.sh contrib/torctl contrib/torify contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile)
 493
 494 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 495   ./contrib/updateVersions.pl
 496 fi
 497