configure.in

   1 dnl $Id$
   2 dnl Copyright 2001-2004 Roger Dingledine
   3 dnl Copyright 2004-2005 Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.1.0.7-rc-cvs)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release; then
  13     CFLAGS="$CFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 AC_ARG_ENABLE(debug,
  17  AC_HELP_STRING(--enable-debug, compile with debugging info),
  18 [if test x$enableval = xyes; then
  19     CFLAGS="$CFLAGS -g"
  20 fi])
  21
  22 AC_ARG_ENABLE(threads,
  23      AC_HELP_STRING(--disable-threads, disable multi-threading support))
  24
  25 if test x$enable_threads = x; then
  26    case $host in
  27     *-*-netbsd*)
  28      # Don't try multithreading on netbsd -- there is no threadsafe DNS
  29      # lookup function there.
  30      enable_threads="no";;
  31     *)
  32      enable_threads="yes";;
  33    esac
  34 fi
  35
  36 if test $enable_threads = "yes"; then
  37   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  38 fi
  39
  40 AC_PROG_CC
  41 AC_PROG_MAKE_SET
  42 AC_PROG_RANLIB
  43
  44 # The big search for OpenSSL
  45 # copied from openssh's configure.ac
  46 AC_ARG_WITH(ssl-dir,
  47         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
  48         [
  49                 if test "x$withval" != "xno" ; then
  50                         tryssldir=$withval
  51                 fi
  52         ]
  53 )
  54
  55 AC_SEARCH_LIBS(socket, [socket])
  56 AC_SEARCH_LIBS(gethostbyname, [nsl])
  57 AC_SEARCH_LIBS(pthread_create, [pthread])
  58 AC_SEARCH_LIBS(pthread_detach, [pthread])
  59
  60 dnl ------------------------------------------------------
  61 dnl Where do you live, libevent?
  62
  63
  64 AC_CACHE_CHECK([for a normal libevent], ac_cv_libevent_normal, [
  65    saved_LIBS="$LIBS"
  66    LIBS="$LIBS -levent"
  67    AC_TRY_RUN([
  68 void *event_init(void);
  69 int main(void)
  70 {
  71         if (!event_init())
  72                 return -1;
  73         return 0;
  74 }], ac_cv_libevent_normal=yes, ac_cv_libevent_normal=no)
  75    LIBS="$saved_LIBS"
  76 ])
  77
  78
  79 if test "$ac_cv_libevent_normal" = yes; then
  80   LIBS="$LIBS -levent"
  81 else
  82   AC_CACHE_CHECK([for libevent in /usr/local/lib], ac_cv_libevent_local, [
  83      saved_LIBS="$LIBS"
  84      saved_LDFLAGS="$LDFLAGS"
  85      LIBS="$LIBS -levent"
  86      LDFLAGS="$LDFLAGS -L/usr/local/lib"
  87      AC_TRY_LINK([], [ void *event_init(void); event_init(); ],
  88         [ libevent_is_in_local=yes ], [ libevent_is_in_local=no ])
  89     if test $libevent_is_in_local = yes; then
  90        AC_TRY_RUN([
  91 void *event_init(void);
  92 int main(void)
  93 {
  94         if (!event_init())
  95                 return -1;
  96         return 0;
  97 }], [ ac_cv_libevent_local=yes ], [ ac_cv_libevent_local=unlinked ])
  98     else
  99        ac_cv_libevent_local=no
 100     fi
 101     if test "$GCC" = yes -a $ac_cv_libevent_local = unlinked ; then
 102        LDFLAGS="$LDFLAGS -Wl,-R/usr/local/lib"
 103        AC_TRY_RUN([
 104 void *event_init(void);
 105 int main(void)
 106 {
 107         if (!event_init())
 108                 return -1;
 109         return 0;
 110 }], [ ac_cv_libevent_local=unlinked_gcc_elf ])
 111     fi
 112
 113     LIBS="$saved_LIBS"
 114     CFLAGS="$saved_CFLAGS"
 115     LDFLAGS="$saved_LDFLAGS" ])
 116
 117   if test $ac_cv_libevent_local != no; then
 118       LIBS="$LIBS -levent"
 119       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 120       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 121   fi
 122   if test $ac_cv_libevent_local = unlinked_gcc_elf; then
 123       LDFLAGS="$LDFLAGS -Wl,-R/usr/local/lib"
 124       if test -f /etc/ld.so.conf ; then
 125         AC_MSG_NOTICE([
 126 Apparently, you don't have /usr/local/lib in your /etc/ld.so.conf.
 127 Tor is smart enought to deal this now, but other applications aren't.
 128 You might want to add it in.])
 129       fi
 130   fi
 131
 132   if test $ac_cv_libevent_local = unlinked ; then
 133     if test -f /etc/ld.so.conf ; then
 134       AC_MSG_NOTICE([
 135 =================================================
 136 Your libevent library is installed in /usr/local/lib,
 137 but your dynamic linker isn't configured to look for
 138 it there.
 139
 140 Maybe you need to add /usr/local/lib to /etc/ld.so.conf,
 141 and then run ldconfig -v ?
 142 =================================================])
 143     else
 144       AC_MSG_NOTICE([
 145 =================================================
 146 Your libevent library is installed in /usr/local/lib,
 147 but your dynamic linker isn't configured to look for
 148 it there.
 149 =================================================])
 150     fi
 151   fi
 152
 153   if test $ac_cv_libevent_local = no ; then
 154       AC_MSG_ERROR([
 155 Tor requires libevent to build.  You can download the latest
 156 version of libevent from http://monkey.org/~provos/libevent/])
 157   fi
 158
 159 fi
 160
 161 dnl ------------------------------------------------------
 162 dnl Where do you live, OpenSSL?
 163
 164 saved_LIBS="$LIBS"
 165 saved_LDFLAGS="$LDFLAGS"
 166 saved_CPPFLAGS="$CPPFLAGS"
 167 if test "x$prefix" != "xNONE" ; then
 168         tryssldir="$tryssldir $prefix"
 169 fi
 170 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 171         for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /usr/pkg /opt /opt/openssl ; do
 172                 CPPFLAGS="$saved_CPPFLAGS"
 173                 LDFLAGS="$saved_LDFLAGS"
 174                 LIBS="$saved_LIBS -lssl -lcrypto"
 175
 176                 # Skip directories if they don't exist
 177                 if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 178                         continue;
 179                 fi
 180                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 181                         # Try to use $ssldir/lib if it exists, otherwise
 182                         # $ssldir
 183                         if test -d "$ssldir/lib" ; then
 184                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 185                                 if test ! -z "$need_dash_r" ; then
 186                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 187                                 fi
 188                         else
 189                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 190                                 if test ! -z "$need_dash_r" ; then
 191                                         LDFLAGS="-R$ssldir $LDFLAGS"
 192                                 fi
 193                         fi
 194                         # Try to use $ssldir/include if it exists, otherwise
 195                         # $ssldir
 196                         if test -d "$ssldir/include" ; then
 197                                 CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 198                         else
 199                                 CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 200                         fi
 201                 fi
 202
 203                 # Basic test to check for compatible version and correct linking
 204                 # *does not* test for RSA - that comes later.
 205                 AC_TRY_RUN(
 206                         [
 207 #include <string.h>
 208 #include <openssl/rand.h>
 209 int main(void)
 210 {
 211         char a[2048];
 212         memset(a, 0, sizeof(a));
 213         RAND_add(a, sizeof(a), sizeof(a));
 214         return(RAND_status() <= 0);
 215 }
 216                         ],
 217                         [
 218                                 found_crypto=1
 219                                 break;
 220                         ], []
 221                 )
 222
 223                 if test ! -z "$found_crypto" ; then
 224                         break;
 225                 fi
 226         done
 227
 228         if test -z "$found_crypto" ; then
 229                 AC_MSG_ERROR([Could not find working OpenSSL library, please install or check config.log])
 230         fi
 231         if test -z "$ssldir" ; then
 232                 ssldir="(system)"
 233         fi
 234
 235         ac_cv_openssldir=$ssldir
 236 ])
 237 if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ;
 238  then
 239         dnl Need to recover ssldir - test above runs in subshell
 240         ssldir=$ac_cv_openssldir
 241         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 242                 # Try to use $ssldir/lib if it exists, otherwise
 243                 # $ssldir
 244                 if test -d "$ssldir/lib" ; then
 245                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 246                         if test ! -z "$need_dash_r" ; then
 247                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 248                         fi
 249                 else
 250                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 251                         if test ! -z "$need_dash_r" ; then
 252                                 LDFLAGS="-R$ssldir $LDFLAGS"
 253                         fi
 254                 fi
 255                 # Try to use $ssldir/include if it exists, otherwise
 256                 # $ssldir
 257                 if test -d "$ssldir/include" ; then
 258                         CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 259                 else
 260                         CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 261                 fi
 262         fi
 263 fi
 264 LIBS="$saved_LIBS"
 265
 266 AC_SYS_LARGEFILE
 267
 268 dnl The warning message here is no longer strictly accurate.
 269
 270 AC_CHECK_HEADERS(unistd.h string.h signal.h netdb.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/ioctl.h sys/socket.h sys/time.h netinet/in.h arpa/inet.h errno.h assert.h time.h pwd.h grp.h, , AC_MSG_WARN(some headers were not found, compilation may fail))
 271
 272 AC_CHECK_HEADERS(event.h, , AC_MSG_ERROR(Libevent header (event.h) not found. Tor requires libevent to build.))
 273
 274 AC_CHECK_HEADERS(zlib.h, , AC_MSG_ERROR(Zlib header (zlib.h) not found. Tor requires zlib to build. You may need to install a zlib development package.))
 275
 276 dnl These headers are not essential
 277
 278 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h pthread.h stddef.h inttypes.h)
 279
 280 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit setrlimit strlcat strlcpy strtoull getpwnam ftello pthread_create getaddrinfo localtime_r gmtime_r event_get_version event_get_method event_set_log_callback)
 281 AC_FUNC_FSEEKO
 282
 283 AC_CHECK_MEMBERS([struct timeval.tv_sec])
 284
 285
 286 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 287 dnl Watch out.
 288
 289 AC_CHECK_SIZEOF(int8_t)
 290 AC_CHECK_SIZEOF(int16_t)
 291 AC_CHECK_SIZEOF(int32_t)
 292 AC_CHECK_SIZEOF(int64_t)
 293 AC_CHECK_SIZEOF(uint8_t)
 294 AC_CHECK_SIZEOF(uint16_t)
 295 AC_CHECK_SIZEOF(uint32_t)
 296 AC_CHECK_SIZEOF(uint64_t)
 297 AC_CHECK_SIZEOF(intptr_t)
 298 AC_CHECK_SIZEOF(uintptr_t)
 299
 300 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 301
 302 AC_CHECK_SIZEOF(char)
 303 AC_CHECK_SIZEOF(short)
 304 AC_CHECK_SIZEOF(int)
 305 AC_CHECK_SIZEOF(long)
 306 AC_CHECK_SIZEOF(long long)
 307 AC_CHECK_SIZEOF(__int64)
 308 AC_CHECK_SIZEOF(void *)
 309 AC_CHECK_SIZEOF(time_t)
 310 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 311 #ifdef HAVE_SYS_SOCKET_H
 312 #include <sys/socket.h>
 313 #endif
 314 ])
 315
 316 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 317
 318 AC_CHECK_SIZEOF(cell_t)
 319
 320 # Now, let's see about alignment requirements.  On some platforms, we override
 321 # the default.
 322 case $host in
 323  ia64-*-* | arm-*-* )
 324     tor_cv_unaligned_ok=no
 325     ;;
 326  *)
 327 AC_CACHE_CHECK([whether unaligned int access is allowed], tor_cv_unaligned_ok,
 328 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 329 [[int main () { char s[] = "A\x00\x00\x00\x00\x00\x00\x00";
 330 return *(int*)(&s[1]); }]])],
 331        [tor_cv_unaligned_ok=yes],
 332        [tor_cv_unaligned_ok=no],
 333        [tor_cv_unaligned_ok=cross])])
 334 esac
 335
 336 if test $tor_cv_unaligned_ok = yes; then
 337   AC_DEFINE([UNALIGNED_INT_ACCESS_OK], 1,
 338             [Define to 1 iff unaligned int access is allowed])
 339 fi
 340
 341 # Now make sure that NULL can be represented as zero bytes.
 342 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 343 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 344 [[#include <stdlib.h>
 345 #include <string.h>
 346 #include <stdio.h>
 347 #ifdef HAVE_STDDEF_H
 348 #include <stddef.h>
 349 #endif
 350 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 351 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 352        [tor_cv_null_is_zero=yes],
 353        [tor_cv_null_is_zero=no],
 354        [tor_cv_null_is_zero=cross])])
 355
 356 if test $tor_cv_null_is_zero = yes; then
 357   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 358             [Define to 1 iff memset(0) sets pointers to NULL])
 359 fi
 360
 361 # Whether we should use the dmalloc memory allocation debugging library.
 362 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 363 AC_ARG_WITH(dmalloc,
 364 [  --with-dmalloc          Use debug memory allocation library. ],
 365 [if [[ "$withval" = "yes" ]]; then
 366   dmalloc=1
 367   AC_MSG_RESULT(yes)
 368 else
 369   dmalloc=1
 370   AC_MSG_RESULT(no)
 371 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 372 )
 373
 374 if [[ $dmalloc -eq 1 ]]; then
 375   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 376   AC_SEARCH_LIBS(dmalloc_malloc, [dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 377   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 378   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 379 fi
 380
 381 # Check for gethostbyname_r in all its glorious incompatible versions.
 382 #   (This logic is based on that in Python's configure.in)
 383 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 384   [Define this if you have any gethostbyname_r()])
 385
 386 AC_CHECK_FUNC(gethostbyname_r, [
 387   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 388   OLD_CFLAGS=$CFLAGS
 389   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 390   AC_TRY_COMPILE([
 391 #include <netdb.h>
 392   ], [
 393     char *cp1, *cp2;
 394     struct hostent *h1, *h2;
 395     int i1, i2;
 396     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 397   ], [
 398     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 399     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 400      [Define this if gethostbyname_r takes 6 arguments])
 401     AC_MSG_RESULT(6)
 402   ], [
 403     AC_TRY_COMPILE([
 404 #include <netdb.h>
 405     ], [
 406       char *cp1, *cp2;
 407       struct hostent *h1;
 408       int i1, i2;
 409       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 410     ], [
 411       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 412       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 413         [Define this if gethostbyname_r takes 5 arguments])
 414       AC_MSG_RESULT(5)
 415    ], [
 416       AC_TRY_COMPILE([
 417 #include <netdb.h>
 418      ], [
 419        char *cp1;
 420        struct hostent *h1;
 421        struct hostent_data hd;
 422        (void) gethostbyname_r(cp1,h1,&hd);
 423      ], [
 424        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 425        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 426          [Define this if gethostbyname_r takes 3 arguments])
 427        AC_MSG_RESULT(3)
 428      ], [
 429        AC_MSG_RESULT(0)
 430      ])
 431   ])
 432  ])
 433  CFLAGS=$OLD_CFLAGS
 434 ])
 435
 436 # $prefix stores the value of the --prefix command line option, or
 437 # NONE if the option wasn't set.  In the case that it wasn't set, make
 438 # it be the default, so that we can use it to expand directories now.
 439 if test "x$prefix" = "xNONE"; then
 440   prefix=$ac_default_prefix
 441 fi
 442
 443 # and similarly for $exec_prefix
 444 if test "x$exec_prefix" = "xNONE"; then
 445   exec_prefix=$prefix
 446 fi
 447
 448 CONFDIR=`eval echo $sysconfdir/tor`
 449 AC_SUBST(CONFDIR)
 450 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 451 AC_DEFINE([CONFDIR], [], [tor's configuration directory])
 452
 453 BINDIR=`eval echo $bindir`
 454 AC_SUBST(BINDIR)
 455
 456 LOCALSTATEDIR=`eval echo $localstatedir`
 457 AC_SUBST(LOCALSTATEDIR)
 458 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 459 AC_DEFINE([LOCALSTATEDIR], [], [Default location to store state files.])
 460
 461 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 462 # than autoconf's macros like.
 463 CFLAGS="$CFLAGS -Wall -g -O2"
 464 # Add some more warnings which we use in the cvs version but not in the
 465 # released versions.  (Some relevant gcc versions can't handle these.)
 466 #CFLAGS="$CFLAGS -W -Wno-unused-parameter -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls"
 467 # Add these in when you feel like fun.
 468 #CFLAGS="$CFLAGS -Wbad-function-cast -Werror -Wdeclaration-after-statement"
 469
 470 echo "confdir: $CONFDIR"
 471
 472 AC_OUTPUT(Makefile tor.spec contrib/tor.sh contrib/torctl contrib/torify contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile)
 473
 474 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 475   ./contrib/updateVersions.pl
 476 fi
 477