configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.0.19-alpha-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45
  46
  47 if test x$enable_cell_pool != xno; then
  48   AC_DEFINE(ENABLE_CELL_POOL, 1,
  49             [Defined if we try to use the pool allocator for queued cells])
  50 fi
  51 if test x$enable_buf_freelists != xno; then
  52   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  53             [Defined if we try to use freelists for buffer RAM chunks])
  54 fi
  55 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  56
  57 AC_ARG_ENABLE(transparent,
  58      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  59      [case "${enableval}" in
  60         yes) transparent=true ;;
  61         no)  transparent=false ;;
  62         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  63       esac], [transparent=true])
  64
  65 AC_ARG_ENABLE(threads,
  66      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  67
  68 if test x$enable_threads = x; then
  69    case $host in
  70     *-*-solaris* )
  71      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  72      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  73 cpu workers lock up here, so I will disable threads.])
  74      enable_threads="no";;
  75     *)
  76      enable_threads="yes";;
  77    esac
  78 fi
  79
  80 if test "$enable_threads" = "yes"; then
  81   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  82 fi
  83
  84 case $host in
  85    *-*-solaris* )
  86      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  87      ;;
  88 esac
  89
  90 AC_ARG_ENABLE(gcc-warnings,
  91      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  92
  93 AC_PROG_CC
  94 AC_PROG_CPP
  95 AC_PROG_MAKE_SET
  96 AC_PROG_RANLIB
  97
  98 TORUSER=_tor
  99 AC_ARG_WITH(tor-user,
 100         [  --with-tor-user=NAME    Specify username for tor daemon ],
 101         [
 102            TORUSER=$withval
 103         ]
 104 )
 105 AC_SUBST(TORUSER)
 106
 107 TORGROUP=_tor
 108 AC_ARG_WITH(tor-group,
 109         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 110         [
 111            TORGROUP=$withval
 112         ]
 113 )
 114 AC_SUBST(TORGROUP)
 115
 116
 117 dnl If WIN32 is defined and non-zero, we are building for win32
 118 AC_MSG_CHECKING([for win32])
 119 AC_RUN_IFELSE([
 120 int main(int c, char **v) {
 121 #ifdef WIN32
 122 #if WIN32
 123   return 0;
 124 #else
 125   return 1;
 126 #endif
 127 #else
 128   return 2;
 129 #endif
 130 }],
 131 bwin32=true; AC_MSG_RESULT([yes]),
 132 bwin32=false; AC_MSG_RESULT([no]),
 133 bwin32=cross; AC_MSG_RESULT([cross])
 134 )
 135
 136 if test "$bwin32" = cross; then
 137 AC_MSG_CHECKING([for win32 (cross)])
 138 AC_COMPILE_IFELSE([
 139 #ifdef WIN32
 140 int main(int c, char **v) {return 0;}
 141 #else
 142 #error
 143 int main(int c, char **v) {return x(y);}
 144 #endif
 145 ],
 146 bwin32=true; AC_MSG_RESULT([yes]),
 147 bwin32=false; AC_MSG_RESULT([no]))
 148 fi
 149
 150 if test "$bwin32" = true; then
 151 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 152 fi
 153 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 154
 155 dnl Enable C99 when compiling with MIPSpro
 156 AC_MSG_CHECKING([for MIPSpro compiler])
 157 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 158 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 159 #error
 160   return x(y);
 161 #endif
 162 ]),
 163 bmipspro=false; AC_MSG_RESULT(no),
 164 bmipspro=true; AC_MSG_RESULT(yes))
 165
 166 if test "$bmipspro" = true; then
 167   CFLAGS="$CFLAGS -c99"
 168 fi
 169
 170 AC_C_BIGENDIAN
 171
 172 AC_SEARCH_LIBS(socket, [socket])
 173 AC_SEARCH_LIBS(gethostbyname, [nsl])
 174 AC_SEARCH_LIBS(dlopen, [dl])
 175 AC_SEARCH_LIBS(inet_aton, [resolv])
 176
 177 if test "$enable_threads" = "yes"; then
 178   AC_SEARCH_LIBS(pthread_create, [pthread])
 179   AC_SEARCH_LIBS(pthread_detach, [pthread])
 180 fi
 181
 182 dnl -------------------------------------------------------------------
 183 dnl Check for functions before libevent, since libevent-1.2 apparently
 184 dnl exports strlcpy without defining it in a header.
 185
 186 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop mallinfo malloc_good_size malloc_usable_size)
 187
 188 if test "$enable_threads" = "yes"; then
 189   AC_CHECK_HEADERS(pthread.h)
 190   AC_CHECK_FUNCS(pthread_create)
 191 fi
 192
 193 dnl ------------------------------------------------------
 194 dnl Where do you live, libevent?  And how do we call you?
 195
 196 if test "$bwin32" = true; then
 197   TOR_LIB_WS32=-lws2_32
 198   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 199   # think it's actually necessary.
 200   TOR_LIB_GDI=-lgdi32
 201 else
 202   TOR_LIB_WS32=
 203   TOR_LIB_GDI=
 204 fi
 205 AC_SUBST(TOR_LIB_WS32)
 206 AC_SUBST(TOR_LIB_GDI)
 207
 208 dnl We need to do this before we try our disgusting hack below.
 209 AC_CHECK_HEADERS([sys/types.h])
 210
 211 dnl This is a disgusting hack so we safely include older libevent headers.
 212 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 213 AC_CHECK_TYPE(u_int32_t, unsigned long)
 214 AC_CHECK_TYPE(u_int16_t, unsigned short)
 215 AC_CHECK_TYPE(u_int8_t, unsigned char)
 216
 217 tor_libevent_pkg_redhat="libevent"
 218 tor_libevent_pkg_debian="libevent-dev"
 219 tor_libevent_devpkg_redhat="libevent-devel"
 220 tor_libevent_devpkg_debian="libevent-dev"
 221
 222 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 223 #include <stdlib.h>
 224 #include <sys/time.h>
 225 #include <sys/types.h>
 226 #include <event.h>], [void exit(int); void *event_init(void);],
 227     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 228
 229 dnl Now check for particular libevent functions.
 230 save_LIBS="$LIBS"
 231 save_LDFLAGS="$LDFLAGS"
 232 save_CPPFLAGS="$CPPFLAGS"
 233 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 234 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 235 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 236 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 237 LIBS="$save_LIBS"
 238 LDFLAGS="$save_LDFLAGS"
 239 CPPFLAGS="$save_CPPFLAGS"
 240
 241 dnl ------------------------------------------------------
 242 dnl Where do you live, openssl?  And how do we call you?
 243
 244 tor_openssl_pkg_redhat="openssl"
 245 tor_openssl_pkg_debian="libssl"
 246 tor_openssl_devpkg_redhat="openssl-devel"
 247 tor_openssl_devpkg_debian="libssl-dev"
 248
 249 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 250     [#include <openssl/rand.h>],
 251     [void RAND_add(const void *buf, int num, double entropy);],
 252     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 253     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 254
 255 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 256
 257 dnl ------------------------------------------------------
 258 dnl Where do you live, zlib?  And how do we call you?
 259
 260 tor_openssl_pkg_redhat="zlib"
 261 tor_openssl_pkg_debian="zlib1g"
 262 tor_openssl_devpkg_redhat="zlib-devel"
 263 tor_openssl_devpkg_debian="zlib1g-dev"
 264
 265 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 266     [#include <zlib.h>],
 267     [const char * zlibVersion(void);],
 268     [zlibVersion(); exit(0);], [--with-zlib-dir],
 269     [/opt/zlib])
 270
 271 dnl Make sure to enable support for large off_t if available.
 272
 273 AC_SYS_LARGEFILE
 274
 275 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 276
 277 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 278
 279 dnl These headers are not essential
 280
 281 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 282
 283 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 284 [#ifdef HAVE_MALLOC_H
 285 #include <malloc.h>
 286 #endif
 287 #ifdef HAVE_MALLOC_MALLOC_H
 288 #include <malloc/malloc.h>
 289 #endif])
 290
 291 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 292 [#ifdef HAVE_SYS_TYPES_H
 293 #include <sys/types.h>
 294 #endif
 295 #ifdef HAVE_SYS_SOCKET_H
 296 #include <sys/socket.h>
 297 #endif])
 298 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 299 [#ifdef HAVE_SYS_TYPES_H
 300 #include <sys/types.h>
 301 #endif
 302 #ifdef HAVE_SYS_SOCKET_H
 303 #include <sys/socket.h>
 304 #endif
 305 #ifdef HAVE_NET_IF_H
 306 #include <net/if.h>
 307 #endif])
 308 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 309         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 310 [#ifdef HAVE_SYS_TYPES_H
 311 #include <sys/types.h>
 312 #endif
 313 #ifdef HAVE_SYS_SOCKET_H
 314 #include <sys/socket.h>
 315 #endif])
 316
 317 if test x$transparent = xtrue ; then
 318    transparent_ok=0
 319    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 320      transparent_ok=1
 321    fi
 322    if test x$linux_netfilter_ipv4 = x1 ; then
 323      transparent_ok=1
 324    fi
 325    if test x$transparent_ok = x1 ; then
 326      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 327      case $host in
 328        *-*-openbsd*)
 329          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 330      esac
 331    else
 332      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 333    fi
 334 fi
 335
 336 AC_FUNC_FSEEKO
 337
 338 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 339 [#ifdef HAVE_SYS_TYPES_H
 340 #include <sys/types.h>
 341 #endif
 342 #ifdef HAVE_SYS_TIME_H
 343 #include <sys/time.h>
 344 #endif])
 345
 346 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 347 dnl Watch out.
 348
 349 AC_CHECK_SIZEOF(int8_t)
 350 AC_CHECK_SIZEOF(int16_t)
 351 AC_CHECK_SIZEOF(int32_t)
 352 AC_CHECK_SIZEOF(int64_t)
 353 AC_CHECK_SIZEOF(uint8_t)
 354 AC_CHECK_SIZEOF(uint16_t)
 355 AC_CHECK_SIZEOF(uint32_t)
 356 AC_CHECK_SIZEOF(uint64_t)
 357 AC_CHECK_SIZEOF(intptr_t)
 358 AC_CHECK_SIZEOF(uintptr_t)
 359
 360 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 361
 362 AC_CHECK_SIZEOF(char)
 363 AC_CHECK_SIZEOF(short)
 364 AC_CHECK_SIZEOF(int)
 365 AC_CHECK_SIZEOF(long)
 366 AC_CHECK_SIZEOF(long long)
 367 AC_CHECK_SIZEOF(__int64)
 368 AC_CHECK_SIZEOF(void *)
 369 AC_CHECK_SIZEOF(time_t)
 370 AC_CHECK_SIZEOF(size_t)
 371
 372 AC_CHECK_TYPES([uint, u_char])
 373
 374 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 375 [#ifdef HAVE_SYS_TYPES_H
 376 #include <sys/types.h>
 377 #endif
 378 #ifdef HAVE_NETINET_IN_H
 379 #include <netinet/in.h>
 380 #endif
 381 #ifdef HAVE_NETINET_IN6_H
 382 #include <netinet/in6.h>
 383 #endif
 384 #ifdef HAVE_SYS_SOCKET_H
 385 #include <sys/socket.h>
 386 #endif
 387 #ifdef MS_WINDOWS
 388 #define WIN32_WINNT 0x400
 389 #define _WIN32_WINNT 0x400
 390 #define WIN32_LEAN_AND_MEAN
 391 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 392 #include <winsock.h>
 393 #else
 394 #include <winsock2.h>
 395 #include <ws2tcpip.h>
 396 #endif
 397 #endif
 398 ])
 399 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 400 [#ifdef HAVE_SYS_TYPES_H
 401 #include <sys/types.h>
 402 #endif
 403 #ifdef HAVE_NETINET_IN_H
 404 #include <netinet/in.h>
 405 #endif
 406 #ifdef HAVE_NETINET_IN6_H
 407 #include <netinet/in6.h>
 408 #endif
 409 #ifdef HAVE_SYS_SOCKET_H
 410 #include <sys/socket.h>
 411 #endif
 412 #ifdef MS_WINDOWS
 413 #define WIN32_WINNT 0x400
 414 #define _WIN32_WINNT 0x400
 415 #define WIN32_LEAN_AND_MEAN
 416 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 417 #include <winsock.h>
 418 #else
 419 #include <winsock2.h>
 420 #include <ws2tcpip.h>
 421 #endif
 422 #endif
 423 ])
 424
 425 AC_CHECK_TYPES([rlim_t], , ,
 426 [#ifdef HAVE_SYS_TYPES_H
 427 #include <sys/types.h>
 428 #endif
 429 #ifdef HAVE_SYS_TIME_H
 430 #include <sys/time.h>
 431 #endif
 432 #ifdef HAVE_SYS_RESOURCE_H
 433 #include <sys/resource.h>
 434 #endif
 435 ])
 436
 437 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 438 AC_RUN_IFELSE(AC_LANG_SOURCE([
 439 #ifdef HAVE_SYS_TYPES_H
 440 #include <sys/types.h>
 441 #endif
 442 #ifdef HAVE_SYS_TIME_H
 443 #include <sys/time.h>
 444 #endif
 445 #ifdef HAVE_TIME_H
 446 #include <time.h>
 447 #endif
 448 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 449   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 450 ])
 451
 452 if test "$tor_cv_time_t_signed" = cross; then
 453   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 454 fi
 455
 456 if test "$tor_cv_time_t_signed" != no; then
 457   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 458             [Define to 1 iff time_t is signed])
 459 fi
 460
 461 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 462 #ifdef HAVE_SYS_SOCKET_H
 463 #include <sys/socket.h>
 464 #endif
 465 ])
 466
 467 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 468
 469 AC_CHECK_SIZEOF(cell_t)
 470
 471 # Now make sure that NULL can be represented as zero bytes.
 472 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 473 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 474 [[#include <stdlib.h>
 475 #include <string.h>
 476 #include <stdio.h>
 477 #ifdef HAVE_STDDEF_H
 478 #include <stddef.h>
 479 #endif
 480 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 481 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 482        [tor_cv_null_is_zero=yes],
 483        [tor_cv_null_is_zero=no],
 484        [tor_cv_null_is_zero=cross])])
 485
 486 if test "$tor_cv_null_is_zero" = cross ; then
 487   # Cross-compiling; let's hope that the target isn't raving mad.
 488   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 489 fi
 490
 491 if test "$tor_cv_null_is_zero" != no; then
 492   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 493             [Define to 1 iff memset(0) sets pointers to NULL])
 494 fi
 495
 496 # And what happens when we malloc zero?
 497 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 498 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 499 [[#include <stdlib.h>
 500 #include <string.h>
 501 #include <stdio.h>
 502 #ifdef HAVE_STDDEF_H
 503 #include <stddef.h>
 504 #endif
 505 int main () { return malloc(0)?0:1; }]])],
 506        [tor_cv_malloc_zero_works=yes],
 507        [tor_cv_malloc_zero_works=no],
 508        [tor_cv_malloc_zero_works=cross])])
 509
 510 if test "$tor_cv_malloc_zero_works" = cross; then
 511   # Cross-compiling; let's hope that the target isn't raving mad.
 512   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 513 fi
 514
 515 if test "$tor_cv_malloc_zero_works" = yes; then
 516   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 517             [Define to 1 iff malloc(0) returns a pointer])
 518 fi
 519
 520 # whether we seem to be in a 2s-complement world.
 521 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 522 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 523 [[int main () { int problem = ((-99) != (~99)+1);
 524 return problem ? 1 : 0; }]])],
 525        [tor_cv_twos_complement=yes],
 526        [tor_cv_twos_complement=no],
 527        [tor_cv_twos_complement=cross])])
 528
 529 if test "$tor_cv_twos_complement" = cross ; then
 530   # Cross-compiling; let's hope that the target isn't raving mad.
 531   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 532 fi
 533
 534 if test "$tor_cv_twos_complement" != no ; then
 535   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 536             [Define to 1 iff we represent negative integers with two's complement])
 537 fi
 538
 539 # Whether we should use the dmalloc memory allocation debugging library.
 540 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 541 AC_ARG_WITH(dmalloc,
 542 [  --with-dmalloc          Use debug memory allocation library. ],
 543 [if [[ "$withval" = "yes" ]]; then
 544   dmalloc=1
 545   AC_MSG_RESULT(yes)
 546 else
 547   dmalloc=1
 548   AC_MSG_RESULT(no)
 549 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 550 )
 551
 552 if [[ $dmalloc -eq 1 ]]; then
 553   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 554   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 555   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 556   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 557   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 558 fi
 559
 560 AC_ARG_WITH(tcmalloc,
 561 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 562 [ tcmalloc=yes ], [ tcmalloc=no ])
 563
 564 if test x$tcmalloc = xyes ; then
 565    LDFLAGS="-ltcmalloc $LDFLAGS"
 566 fi
 567
 568 # Allow user to specify an alternate syslog facility
 569 AC_ARG_WITH(syslog-facility,
 570 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 571 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 572 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 573 AC_SUBST(LOGFACILITY)
 574
 575 # Check for gethostbyname_r in all its glorious incompatible versions.
 576 #   (This logic is based on that in Python's configure.in)
 577 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 578   [Define this if you have any gethostbyname_r()])
 579
 580 AC_CHECK_FUNC(gethostbyname_r, [
 581   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 582   OLD_CFLAGS=$CFLAGS
 583   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 584   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 585 #include <netdb.h>
 586   ], [[
 587     char *cp1, *cp2;
 588     struct hostent *h1, *h2;
 589     int i1, i2;
 590     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 591   ]]),[
 592     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 593     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 594      [Define this if gethostbyname_r takes 6 arguments])
 595     AC_MSG_RESULT(6)
 596   ], [
 597     AC_TRY_COMPILE([
 598 #include <netdb.h>
 599     ], [
 600       char *cp1, *cp2;
 601       struct hostent *h1;
 602       int i1, i2;
 603       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 604     ], [
 605       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 606       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 607         [Define this if gethostbyname_r takes 5 arguments])
 608       AC_MSG_RESULT(5)
 609    ], [
 610       AC_TRY_COMPILE([
 611 #include <netdb.h>
 612      ], [
 613        char *cp1;
 614        struct hostent *h1;
 615        struct hostent_data hd;
 616        (void) gethostbyname_r(cp1,h1,&hd);
 617      ], [
 618        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 619        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 620          [Define this if gethostbyname_r takes 3 arguments])
 621        AC_MSG_RESULT(3)
 622      ], [
 623        AC_MSG_RESULT(0)
 624      ])
 625   ])
 626  ])
 627  CFLAGS=$OLD_CFLAGS
 628 ])
 629
 630 AC_CACHE_CHECK([whether the C compiler supports __func__],
 631   tor_cv_have_func_macro,
 632   AC_COMPILE_IFELSE([
 633 #include <stdio.h>
 634 int main(int c, char **v) { puts(__func__); }],
 635   tor_cv_have_func_macro=yes,
 636   tor_cv_have_func_macro=no))
 637
 638 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 639   tor_cv_have_FUNC_macro,
 640   AC_COMPILE_IFELSE([
 641 #include <stdio.h>
 642 int main(int c, char **v) { puts(__FUNC__); }],
 643   tor_cv_have_FUNC_macro=yes,
 644   tor_cv_have_FUNC_macro=no))
 645
 646 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 647   tor_cv_have_FUNCTION_macro,
 648   AC_COMPILE_IFELSE([
 649 #include <stdio.h>
 650 int main(int c, char **v) { puts(__FUNCTION__); }],
 651   tor_cv_have_FUNCTION_macro=yes,
 652   tor_cv_have_FUNCTION_macro=no))
 653
 654 if test "$tor_cv_have_func_macro" = 'yes'; then
 655   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 656 fi
 657
 658 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 659   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 660 fi
 661
 662 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 663   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 664            [Defined if the compiler supports __FUNCTION__])
 665 fi
 666
 667 # $prefix stores the value of the --prefix command line option, or
 668 # NONE if the option wasn't set.  In the case that it wasn't set, make
 669 # it be the default, so that we can use it to expand directories now.
 670 if test "x$prefix" = "xNONE"; then
 671   prefix=$ac_default_prefix
 672 fi
 673
 674 # and similarly for $exec_prefix
 675 if test "x$exec_prefix" = "xNONE"; then
 676   exec_prefix=$prefix
 677 fi
 678
 679 if test "x$CONFDIR" = "x"; then
 680   CONFDIR=`eval echo $sysconfdir/tor`
 681 fi
 682 AC_SUBST(CONFDIR)
 683 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 684 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 685
 686 BINDIR=`eval echo $bindir`
 687 AC_SUBST(BINDIR)
 688 LOCALSTATEDIR=`eval echo $localstatedir`
 689 AC_SUBST(LOCALSTATEDIR)
 690
 691 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 692 # than autoconf's macros like.
 693 if test "$ac_cv_c_compiler_gnu" = yes; then
 694   CFLAGS="$CFLAGS -Wall -g -O2"
 695 else
 696   CFLAGS="$CFLAGS -g -O"
 697   enable_gcc_warnings=no
 698 fi
 699
 700 # Add some more warnings which we use in development but not in the
 701 # released versions.  (Some relevant gcc versions can't handle these.)
 702 if test x$enable_gcc_warnings = xyes; then
 703
 704   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 705 #if !defined(__GNUC__) || (__GNUC__ < 4)
 706 #error
 707 #endif]), have_gcc4=yes, have_gcc4=no)
 708
 709   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 710 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 711 #error
 712 #endif]), have_gcc42=yes, have_gcc42=no)
 713
 714   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 715   # Disabled, so we can use mallinfo(): -Waggregate-return
 716
 717   if test x$have_gcc4 = xyes ; then
 718     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 719     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 720   fi
 721
 722   if test x$have_gcc42 = xyes ; then
 723     # These warnings break gcc 4.0.2 and work on gcc 4.2
 724     # XXXX020 Use -fstack-protector.
 725     # XXXX020 See if any of these work with earlier versions.
 726     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 727   fi
 728
 729 ##This will break the world on some 64-bit architectures
 730 # CFLAGS="$CFLAGS -Winline"
 731
 732 fi
 733
 734 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 735
 736 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 737 AC_OUTPUT
 738
 739 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 740   ./contrib/updateVersions.pl
 741 fi
 742