release/src/router/libid3tag/genre.dat.sed

   1 #
   2 # libid3tag - ID3 tag manipulation library
   3 # Copyright (C) 2000-2004 Underbit Technologies, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19 # $Id: genre.dat.sed,v 1.10 2004/01/23 09:41:32 rob Exp $
  20 #
  21
  22 1i\
  23 /* Automatically generated from genre.dat.in */
  24
  25 # generate an array from a string
  26 /^[A-Za-z]/{
  27 H
  28 y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/
  29 s/[^A-Z0-9]/_/g
  30 s/.*/static id3_ucs4_t const genre_&[] =/p
  31 g
  32 s/.*\n//
  33 s/./'&', /g
  34 s/.*/  { &0 };/
  35 }
  36
  37 # write the final table of arrays
  38 ${
  39 p
  40 i\
  41 \
  42 static id3_ucs4_t const *const genre_table[] = {
  43 g
  44 s/^\(\n\)\(.*\)$/\2\1/
  45 y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/
  46 s/[^A-Z0-9\n]/_/g
  47 s/\([^\n]*\)\(\n\)/  genre_\1,\2/g
  48 s/,\n$//
  49 a\
  50 };
  51 }
  52
  53 # print the pattern space (assumes -n)
  54 p