release/src-rt-6.x.4708/toolchains/hndtools-arm-linux-2.6.36-uclibc-4.5.3/share/aclocal-1.11/missing.m4

   1 # Fake the existence of programs that GNU maintainers use.  -*- Autoconf -*-
   2
   3 # Copyright (C) 1997, 1999, 2000, 2001, 2003, 2004, 2005, 2008
   4 # Free Software Foundation, Inc.
   5 #
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 # serial 6
  11
  12 # AM_MISSING_PROG(NAME, PROGRAM)
  13 # ------------------------------
  14 AC_DEFUN([AM_MISSING_PROG],
  15 [AC_REQUIRE([AM_MISSING_HAS_RUN])
  16 $1=${$1-"${am_missing_run}$2"}
  17 AC_SUBST($1)])
  18
  19
  20 # AM_MISSING_HAS_RUN
  21 # ------------------
  22 # Define MISSING if not defined so far and test if it supports --run.
  23 # If it does, set am_missing_run to use it, otherwise, to nothing.
  24 AC_DEFUN([AM_MISSING_HAS_RUN],
  25 [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
  26 AC_REQUIRE_AUX_FILE([missing])dnl
  27 if test x"${MISSING+set}" != xset; then
  28   case $am_aux_dir in
  29   *\ * | *\     *)
  30     MISSING="\${SHELL} \"$am_aux_dir/missing\"" ;;
  31   *)
  32     MISSING="\${SHELL} $am_aux_dir/missing" ;;
  33   esac
  34 fi
  35 # Use eval to expand $SHELL
  36 if eval "$MISSING --run true"; then
  37   am_missing_run="$MISSING --run "
  38 else
  39   am_missing_run=
  40   AC_MSG_WARN([`missing' script is too old or missing])
  41 fi
  42 ])