release/src-rt-6.x.4708/linux/linux-2.6.36/arch/arm/mach-sa1100/sleep.S

   1 /*
   2  * SA11x0 Assembler Sleep/WakeUp Management Routines
   3  *
   4  * Copyright (c) 2001 Cliff Brake <cbrake@accelent.com>
   5  *
   6  * This program is free software; you can redistribute it and/or
   7  * modify it under the terms of the GNU General Public License.
   8  *
   9  * History:
  10  *
  11  * 2001-02-06: Cliff Brake         Initial code
  12  *
  13  * 2001-08-29:  Nicolas Pitre   Simplified.
  14  *
  15  * 2002-05-27:  Nicolas Pitre   Revisited, more cleanup and simplification.
  16  *                              Storage is on the stack now.
  17  */
  18
  19 #include <linux/linkage.h>
  20 #include <asm/assembler.h>
  21 #include <mach/hardware.h>
  22
  23
  24
  25                 .text
  26
  27
  28
  29 /*
  30  * sa1100_cpu_suspend()
  31  *
  32  * Causes sa11x0 to enter sleep state
  33  *
  34  */
  35
  36 ENTRY(sa1100_cpu_suspend)
  37
  38         stmfd   sp!, {r4 - r12, lr}             @ save registers on stack
  39
  40         @ get coprocessor registers
  41         mrc     p15, 0, r4, c3, c0, 0           @ domain ID
  42         mrc     p15, 0, r5, c2, c0, 0           @ translation table base addr
  43         mrc     p15, 0, r6, c13, c0, 0          @ PID
  44         mrc     p15, 0, r7, c1, c0, 0           @ control reg
  45
  46         @ store them plus current virtual stack ptr on stack
  47         mov     r8, sp
  48         stmfd   sp!, {r4 - r8}
  49
  50         @ preserve phys address of stack
  51         mov     r0, sp
  52         bl      sleep_phys_sp
  53         ldr     r1, =sleep_save_sp
  54         str     r0, [r1]
  55
  56         @ clean data cache and invalidate WB
  57         bl      v4wb_flush_kern_cache_all
  58
  59         @ disable clock switching
  60         mcr     p15, 0, r1, c15, c2, 2
  61
  62         @ Adjust memory timing before lowering CPU clock
  63         @ Clock speed adjustment without changing memory timing makes
  64         @ CPU hang in some cases
  65         ldr     r0, =MDREFR
  66         ldr     r1, [r0]
  67         orr     r1, r1, #MDREFR_K1DB2
  68         str     r1, [r0]
  69
  70         @ delay 90us and set CPU PLL to lowest speed
  71         @ fixes resume problem on high speed SA1110
  72         mov     r0, #90
  73         bl      __udelay
  74         ldr     r0, =PPCR
  75         mov     r1, #0
  76         str     r1, [r0]
  77         mov     r0, #90
  78         bl      __udelay
  79
  80
  81         ldr     r0, =MSC0
  82         ldr     r1, =MSC1
  83         ldr     r2, =MSC2
  84
  85         ldr     r3, [r0]
  86         bic     r3, r3, #FMsk(MSC_RT)
  87         bic     r3, r3, #FMsk(MSC_RT)<<16
  88
  89         ldr     r4, [r1]
  90         bic     r4, r4, #FMsk(MSC_RT)
  91         bic     r4, r4, #FMsk(MSC_RT)<<16
  92
  93         ldr     r5, [r2]
  94         bic     r5, r5, #FMsk(MSC_RT)
  95         bic     r5, r5, #FMsk(MSC_RT)<<16
  96
  97         ldr     r6, =MDREFR
  98
  99         ldr     r7, [r6]
 100 bic     r7, r7, #0x0000FF00
 101 bic     r7, r7, #0x000000F0
 102 orr     r8, r7, #MDREFR_SLFRSH
 103
 104         ldr     r9, =MDCNFG
 105         ldr     r10, [r9]
 106         bic     r10, r10, #(MDCNFG_DE0+MDCNFG_DE1)
 107         bic     r10, r10, #(MDCNFG_DE2+MDCNFG_DE3)
 108
 109         bic     r11, r8, #MDREFR_SLFRSH
 110         bic     r11, r11, #MDREFR_E1PIN
 111
 112         ldr     r12, =PMCR
 113
 114         mov     r13, #PMCR_SF
 115
 116         b       sa1110_sdram_controller_fix
 117
 118         .align 5
 119 sa1110_sdram_controller_fix:
 120
 121         @ Step 1 clear RT field of all MSCx registers
 122         str     r3, [r0]
 123         str     r4, [r1]
 124         str     r5, [r2]
 125
 126         @ Step 2 clear DRI field in MDREFR
 127         str     r7, [r6]
 128
 129         @ Step 3 set SLFRSH bit in MDREFR
 130         str     r8, [r6]
 131
 132         @ Step 4 clear DE bis in MDCNFG
 133         str     r10, [r9]
 134
 135         @ Step 5 clear DRAM refresh control register
 136         str     r11, [r6]
 137
 138         @ Wow, now the hardware suspend request pins can be used, that makes them functional for
 139         @ about 7 ns out of the entire time that the CPU is running!
 140
 141         @ Step 6 set force sleep bit in PMCR
 142
 143         str     r13, [r12]
 144
 145 20:     b       20b                     @ loop waiting for sleep
 146
 147 /*
 148  * cpu_sa1100_resume()
 149  *
 150  * entry point from bootloader into kernel during resume
 151  *
 152  * Note: Yes, part of the following code is located into the .data section.
 153  *       This is to allow sleep_save_sp to be accessed with a relative load
 154  *       while we can't rely on any MMU translation.  We could have put
 155  *       sleep_save_sp in the .text section as well, but some setups might
 156  *       insist on it to be truly read-only.
 157  */
 158
 159         .data
 160         .align 5
 161 ENTRY(sa1100_cpu_resume)
 162         mov     r0, #PSR_F_BIT | PSR_I_BIT | SVC_MODE
 163         msr     cpsr_c, r0                      @ set SVC, irqs off
 164
 165         ldr     r0, sleep_save_sp               @ stack phys addr
 166         ldr     r2, =resume_after_mmu           @ its absolute virtual address
 167         ldmfd   r0, {r4 - r7, sp}               @ CP regs + virt stack ptr
 168
 169         mov     r1, #0
 170         mcr     p15, 0, r1, c8, c7, 0           @ flush I+D TLBs
 171         mcr     p15, 0, r1, c7, c7, 0           @ flush I&D cache
 172         mcr     p15, 0, r1, c9, c0, 0           @ invalidate RB
 173         mcr     p15, 0, r1, c9, c0, 5           @ allow user space to use RB
 174
 175         mcr     p15, 0, r4, c3, c0, 0           @ domain ID
 176         mcr     p15, 0, r5, c2, c0, 0           @ translation table base addr
 177         mcr     p15, 0, r6, c13, c0, 0          @ PID
 178         b       resume_turn_on_mmu              @ cache align execution
 179
 180         .align 5
 181 resume_turn_on_mmu:
 182         mcr     p15, 0, r7, c1, c0, 0           @ turn on MMU, caches, etc.
 183         nop
 184         mov     pc, r2                          @ jump to virtual addr
 185         nop
 186         nop
 187         nop
 188
 189 sleep_save_sp:
 190         .word   0                               @ preserve stack phys ptr here
 191
 192         .text
 193 resume_after_mmu:
 194         mcr     p15, 0, r1, c15, c1, 2          @ enable clock switching
 195         ldmfd   sp!, {r4 - r12, pc}             @ return to caller