release/src-rt-6.x.4708/linux/linux-2.6.36/arch/arm/lib/csumpartialcopyuser.S

   1 /*
   2  *  linux/arch/arm/lib/csumpartialcopyuser.S
   3  *
   4  *  Copyright (C) 1995-1998 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  * 27/03/03 Ian Molton Clean up CONFIG_CPU
  11  *
  12  */
  13 #include <linux/linkage.h>
  14 #include <asm/assembler.h>
  15 #include <asm/errno.h>
  16 #include <asm/asm-offsets.h>
  17
  18                 .text
  19
  20                 .macro  save_regs
  21                 stmfd   sp!, {r1, r2, r4 - r8, lr}
  22                 .endm
  23
  24                 .macro  load_regs
  25                 ldmfd   sp!, {r1, r2, r4 - r8, pc}
  26                 .endm
  27
  28                 .macro  load1b, reg1
  29                 ldrusr  \reg1, r0, 1
  30                 .endm
  31
  32                 .macro  load2b, reg1, reg2
  33                 ldrusr  \reg1, r0, 1
  34                 ldrusr  \reg2, r0, 1
  35                 .endm
  36
  37                 .macro  load1l, reg1
  38                 ldrusr  \reg1, r0, 4
  39                 .endm
  40
  41                 .macro  load2l, reg1, reg2
  42                 ldrusr  \reg1, r0, 4
  43                 ldrusr  \reg2, r0, 4
  44                 .endm
  45
  46                 .macro  load4l, reg1, reg2, reg3, reg4
  47                 ldrusr  \reg1, r0, 4
  48                 ldrusr  \reg2, r0, 4
  49                 ldrusr  \reg3, r0, 4
  50                 ldrusr  \reg4, r0, 4
  51                 .endm
  52
  53 /*
  54  * unsigned int
  55  * csum_partial_copy_from_user(const char *src, char *dst, int len, int sum, int *err_ptr)
  56  *  r0 = src, r1 = dst, r2 = len, r3 = sum, [sp] = *err_ptr
  57  *  Returns : r0 = checksum, [[sp, #0], #0] = 0 or -EFAULT
  58  */
  59
  60 #define FN_ENTRY        ENTRY(csum_partial_copy_from_user)
  61 #define FN_EXIT         ENDPROC(csum_partial_copy_from_user)
  62
  63 #include "csumpartialcopygeneric.S"
  64
  65                 .pushsection .fixup,"ax"
  66                 .align  4
  67 9001:           mov     r4, #-EFAULT
  68                 ldr     r5, [sp, #8*4]          @ *err_ptr
  69                 str     r4, [r5]
  70                 ldmia   sp, {r1, r2}            @ retrieve dst, len
  71                 add     r2, r2, r1
  72                 mov     r0, #0                  @ zero the buffer
  73 9002:           teq     r2, r1
  74                 strneb  r0, [r1], #1
  75                 bne     9002b
  76                 load_regs
  77                 .popsection