release/src/router/lzo/configure.ac

   1 #
   2 #  configure.ac -- autoconf configuration for the LZO library
   3 #
   4 #  This file is part of the LZO data compression library.
   5 #
   6 #  Copyright (C) 1996-2011 Markus Franz Xaver Johannes Oberhumer
   7 #  All Rights Reserved.
   8 #
   9 #  The LZO library is free software; you can redistribute it and/or
  10 #  modify it under the terms of the GNU General Public License as
  11 #  published by the Free Software Foundation; either version 2 of
  12 #  the License, or (at your option) any later version.
  13 #
  14 #  The LZO library is distributed in the hope that it will be useful,
  15 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 #  GNU General Public License for more details.
  18 #
  19 #  You should have received a copy of the GNU General Public License
  20 #  along with the LZO library; see the file COPYING.
  21 #  If not, write to the Free Software Foundation, Inc.,
  22 #  51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  23 #
  24 #  Markus F.X.J. Oberhumer
  25 #  <markus@oberhumer.com>
  26 #  http://www.oberhumer.com/opensource/lzo/
  27 #
  28
  29
  30 # /***********************************************************************
  31 # // Init
  32 # ************************************************************************/
  33
  34 AC_COPYRIGHT([Copyright (C) 1996-2011 Markus Franz Xaver Johannes Oberhumer.
  35 All Rights Reserved.
  36 This configure script may be copied, distributed and modified under the
  37 terms of the GNU General Public License; see COPYING for more details.])
  38
  39 AC_PREREQ(2.67)
  40 AC_INIT([LZO],[2.06],[markus@oberhumer.com],[lzo],[http://www.oberhumer.com/opensource/lzo/])
  41 AC_MSG_NOTICE([Configuring LZO $PACKAGE_VERSION])
  42 AC_CONFIG_SRCDIR(src/lzo_init.c)
  43 AC_CONFIG_AUX_DIR(autoconf)
  44 m4_include([autoconf/local.m4])
  45 AC_PREFIX_DEFAULT(/usr/local)
  46 AC_CANONICAL_BUILD
  47 AC_CANONICAL_HOST
  48 AC_CANONICAL_TARGET
  49 AM_MAINTAINER_MODE
  50
  51 if test -z "$ac_abs_top_srcdir"; then
  52     _AC_SRCDIRS([.])
  53 fi
  54 if test -z "$ac_abs_top_srcdir"; then
  55     as_fn_error 1 "internal error: ac_abs_top_srcdir is not set"
  56 fi
  57 if test -r .Conf.settings1; then
  58     . ./.Conf.settings1
  59 fi
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AM_PROG_AS
  64 AC_PROG_CPP
  65 mfx_PROG_CPPFLAGS
  66 AC_C_CONST
  67 mfx_LZO_CHECK_ENDIAN
  68 AC_SYS_LARGEFILE
  69
  70 AM_INIT_AUTOMAKE([1.11.1 gnu subdir-objects])
  71 AM_SILENT_RULES([yes])
  72 AC_CONFIG_HEADERS([config.h:config.hin])
  73
  74 AC_ENABLE_STATIC
  75 AC_DISABLE_SHARED
  76 LT_INIT
  77
  78
  79 # /***********************************************************************
  80 # // Checks for header files
  81 # ************************************************************************/
  82
  83 mfx_ACC_CHECK_HEADERS
  84 dnl AC_CHECK_HEADERS([sys/param.h sys/resource.h sys/times.h])
  85 if test "X$ac_cv_header_limits_h" != Xyes; then
  86     AC_MSG_ERROR([<limits.h> header not found])
  87 fi
  88 mfx_CHECK_HEADER_SANE_LIMITS_H
  89 if test "X$mfx_cv_header_sane_limits_h" != Xyes; then
  90     AC_MSG_ERROR([your <limits.h> header is broken - for details see config.log])
  91 fi
  92
  93
  94 # /***********************************************************************
  95 # // Checks for typedefs and structures
  96 # ************************************************************************/
  97
  98 AC_TYPE_OFF_T
  99 AC_CHECK_TYPE(ptrdiff_t,long)
 100 AC_TYPE_SIZE_T
 101 AC_TYPE_SIGNAL
 102
 103 mfx_ACC_CHECK_SIZEOF
 104 mfx_CHECK_SIZEOF
 105
 106
 107 # /***********************************************************************
 108 # // Checks for library functions
 109 # ************************************************************************/
 110
 111 mfx_ACC_CHECK_FUNCS
 112 mfx_CHECK_LIB_WINMM
 113
 114
 115 # /***********************************************************************
 116 # // Checks for assembler
 117 # ************************************************************************/
 118
 119 AC_ARG_ENABLE(asm, AS_HELP_STRING(--disable-asm,disable assembly versions))
 120
 121 asm_arch=
 122 asm_dir=
 123 asm_msg_amd64=no
 124 asm_msg_i386=no
 125
 126 case "$host_cpu-$ac_cv_sizeof_void_p" in
 127     amd64-8 | x86_64-8) asm_arch="amd64"; asm_dir="asm/amd64/src_gas/elf64"; asm_mode="amd64_src_gas_elf64" ;;
 128     i?86-4) asm_arch="i386"; asm_dir="asm/i386/src_gas"; asm_mode="i386_src_gas" ;;
 129     *) enable_asm=no ;;
 130 esac
 131 LZO_USE_ASM_i386_src_gas=no
 132
 133 AC_MSG_CHECKING([whether to build assembly versions])
 134 if test "X$enable_asm" != Xno; then
 135 mfx_compile_S='${CCAS} ${CCASFLAGS} -c conftest.S 1>&AS_MESSAGE_LOG_FD'
 136 cat > conftest.S <<EOF
 137 #include "$ac_abs_top_srcdir/$asm_dir/lzo1x_f1.S"
 138 EOF
 139 enable_asm=no
 140 if AC_TRY_EVAL(mfx_compile_S); then
 141     if AC_TRY_COMMAND([test -s conftest.$ac_objext]); then
 142         enable_asm=yes
 143         eval asm_msg_$asm_arch="'yes [[$asm_dir]]'"
 144         eval LZO_USE_ASM_$asm_mode=yes
 145     fi
 146 fi
 147 if test "X$enable_asm" = Xno; then
 148     echo "configure: failed program was:" >&AS_MESSAGE_LOG_FD
 149     cat conftest.S >&AS_MESSAGE_LOG_FD
 150 fi
 151 rm -rf conftest*
 152 fi
 153 AC_MSG_RESULT([$enable_asm])
 154
 155 AM_CONDITIONAL(LZO_USE_ASM_i386_src_gas, [test "X$LZO_USE_ASM_i386_src_gas" != Xno])
 156 AM_CONDITIONAL(LZO_USE_ASM_i386_obj_elf32, [false])
 157
 158
 159 # /***********************************************************************
 160 # // Write output files
 161 # ************************************************************************/
 162
 163 mfx_MINIACC_ACCCHK(["-I$srcdir"],["src/miniacc.h"])
 164
 165 if test -r .Conf.settings2; then
 166     . ./.Conf.settings2
 167 fi
 168
 169 my_DEFS="-DLZO_HAVE_CONFIG_H=1"
 170 if test "X$enable_asm" != Xno; then
 171     my_DEFS="$my_DEFS -DLZO_USE_ASM=1"
 172 fi
 173
 174 AC_CONFIG_COMMANDS_PRE([
 175     test "X$DEFS" = "X-DHAVE_CONFIG_H" && DEFS=
 176     test "X$DEFS" != "X" && DEFS="$DEFS "
 177     DEFS="${DEFS}${my_DEFS}"
 178 ])
 179 AC_CONFIG_FILES([Makefile])
 180 AC_OUTPUT
 181
 182
 183 ##   enable AMD64 assembly code : ${asm_msg_amd64}
 184 cat <<EOF
 185
 186    LZO configuration summary
 187    -------------------------
 188    LZO version                : ${PACKAGE_VERSION}
 189    configured for host        : ${host_cpu}-${host_vendor}-${host_os}
 190    source code location       : ${srcdir}
 191    compiler                   : ${CC}
 192    preprocessor definitions   : ${DEFS}
 193    preprocessor flags         : ${CPPFLAGS}
 194    compiler flags             : ${CFLAGS}
 195    build static library       : ${enable_static}
 196    build shared library       : ${enable_shared}
 197    enable i386 assembly code  : ${asm_msg_i386}
 198
 199
 200    LZO ${PACKAGE_VERSION} configured.
 201
 202    Copyright (C) 1996-2011 Markus Franz Xaver Johannes Oberhumer
 203    All Rights Reserved.
 204
 205    The LZO library is free software; you can redistribute it and/or
 206    modify it under the terms of the GNU General Public License as
 207    published by the Free Software Foundation; either version 2 of
 208    the License, or (at your option) any later version.
 209
 210    The LZO library is distributed in the hope that it will be useful,
 211    but WITHOUT ANY WARRANTY; without even the implied warranty of
 212    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 213    GNU General Public License for more details.
 214
 215    Markus F.X.J. Oberhumer
 216    <markus@oberhumer.com>
 217    http://www.oberhumer.com/opensource/lzo/
 218
 219
 220 Type \`make' to build LZO. Type \`make install' to install LZO.
 221 After installing LZO, please read the accompanied documentation.
 222
 223 EOF
 224
 225 # vi:ts=4:et