release/src-rt-6.x.4708/shared/cfez_arm_shmoo.lds.in

   1 /*
   2  * This is the "template" linker script.  It gets run through the C preprocessor
   3  * (via cpp) to construct the real linker script.
   4  */
   5
   6 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
   7 OUTPUT_ARCH(arm)
   8 ENTRY(startup)
   9 SECTIONS
  10 {
  11         . = TEXT_START;
  12         . = ALIGN(4);
  13         .text : {
  14                 _ftext = . ;
  15                 text_start = .;
  16                 *(.text.startup)
  17                 *(.text)
  18                 *(.text.*)
  19                 _etext = .;
  20                 text_end = .;
  21         }
  22
  23         . = ALIGN(4);
  24         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  25
  26         . = ALIGN(4);
  27         .data1 : {
  28                 data1_start = .;
  29                 _fdata = .;
  30                 *(.data.*)
  31                 data1_end = .;
  32         }
  33
  34         . = ALIGN(4);
  35         _fbss = .;
  36         .bss : {
  37                 bss_start = .;
  38                 *(.bss)
  39                 *(.bss.*)
  40                 *(.sbss)
  41                 *(.scommon)
  42                 *(COMMON)
  43                  . = ALIGN(4);
  44                 bss_end = .;
  45         }
  46
  47         .mmu_table : {
  48                 . = ALIGN(0x10000);
  49                 *(section_mmu_table)
  50         }
  51
  52         . = ALIGN(4);
  53         .data : {
  54                 data_start = .;
  55                 *(.data)
  56                 data_end = .;
  57         }
  58
  59         . = ALIGN(4);
  60         _edata = .;
  61
  62         /DISCARD/ : { *(.dynstr*) }
  63         /DISCARD/ : { *(.dynamic*) }
  64         /DISCARD/ : { *(.plt*) }
  65         /DISCARD/ : { *(.interp*) }
  66         /DISCARD/ : { *(.gnu*) }
  67
  68         _end = .;
  69 }